=head1 NAME

AnyEvent::Fork::Pool - simple process pool manager on top of AnyEvent::Fork

=head1 SYNOPSIS

   use AnyEvent;
   use AnyEvent::Fork::Pool;
   # use AnyEvent::Fork is not needed

   # all parameters with default values
   my $pool = new AnyEvent::Fork::Pool
      "MyWorker::run",

      # pool management
      min        => 0, # minimum # of processes
      max        => 4, # maximum # of processes
      max_queue  => 2, # queue at most this number of jobs per process
      min_delay  => 0, # wait this many seconds before starting a new process
      min_idle   => 0, # try to have at least this amount of idle processes
      max_idle   => 1, # at most this many idle processes
      idle_time  => 1, # wait this many seconds before killing an idle process
      on_destroy => (my $finish = AE::cv),

      # template process
      template   => AnyEvent::Fork->new, # the template process to use
      require    => [MyWorker::], # module(s) to load
      eval       => "# perl code to execute in template",

      # parameters passed to AnyEvent::Fork::RPC
      async      => 0,
      on_error   => sub { die "FATAL: $_[0]\n" },
      on_event   => sub { my @ev = @_ },
      init       => "MyWorker::init",
      serialiser => $AnyEvent::Fork::RPC::STRING_SERIALISER,
   ;

   for (1..10) {
      $pool->call (doit => $_, sub {
         print "MyWorker::run returned @_\n";
      });
   }

   undef $pool;

   $finish->recv;

=head1 DESCRIPTION

This module uses processes created via L<AnyEvent::Fork> and the RPC
protocol implement in L<AnyEvent::Fork::RPC> to create a load-balanced
pool of processes that handles jobs.

Understanding of L<AnyEvent::Fork> is helpful but not critical to be able
to use this module, but a thorough understanding of L<AnyEvent::Fork::RPC>
is, as it defines the actual API that needs to be implemented in the
children.

=head1 EXAMPLES

=head1 PARENT USAGE

=over 4

=cut

package AnyEvent::Fork::Pool;

use common::sense;

use Scalar::Util ();

use Array::Heap ();

use AnyEvent;
use AnyEvent::Fork; # we don't actually depend on it, this is for convenience
use AnyEvent::Fork::RPC;

my $magic0 = ':t6Z@HK1N%Dx@_7?=~-7NQgWDdAs6a,jFN=wLO0*jD*1%P';
my $magic2 = '<~53rexz.U`!]X[A235^"fyEoiTF\T~oH1l/N6+Djep9b~bI9`\1x%B~vWO1q*';

our $VERSION = 0.1;

=item my $rpc = new AnyEvent::Fork::Pool $function, [key => value...]

Creates a new pool object with the specified C<$function> as function
(name) to call for each request.

A pool consists of a template process that contains the code and data that
the worker processes need. And a number of worker processes that have been
forked off of that template process.

You can supply your own template process, or tell C<AnyEvent::Fork::Pool>
to create one.

A relatively large number of key/value pairs can be specified to influence
the behaviour. They are grouped into the categories "pool management",
"template process" and "rpc parameters".

=over 4

=item Pool Management

The pool consists of a certain number of worker processes. These options
decide how many of these processes exist and when they are started and
stopp.ed

=over 4

=item min => $count (default: 0)

The minimum number of processes in the pool, in addition to the template
process. Even when idle, there will never be fewer than this number of
worker processes. The default means that the pool can be empty.

=item max => $count (default: 4)

The maximum number of processes in the pool, in addition to the template
process. C<AnyEvent::Fork::Pool> will never create more than this number
of processes.

=item max_queue => $count (default: 2)

The maximum number of jobs sent to a single worker process. Worker
processes that handle this number of jobs already are called "busy".

Jobs that cannot be sent to a worker immediately (because all workers are
busy) will be queued until a worker is available.

=item min_delay => $seconds (default: 0)

When a job is queued and all workers are busy, a timer is started. If the
timer elapses and there are still jobs that cannot be queued to a worker,
a new worker is started.

This configurs the time that all workers must be busy before a new worker
is started. Or, put differently, the minimum delay betwene starting new
workers.

The delay is zero by default, which means new workers will be started
without delay.

=item min_idle => $count (default: 0)

The minimum number of idle workers - when they are less, more
are started. The C<min_delay> is still respected though, and
C<min_idle>/C<min_delay> and C<max_idle>/C<idle_time> are useful to
dynamically adjust the pool.

=item max_idle => $count (default: 1)

The maximum number of idle workers. If a worker becomes idle and there are
already this many idle workers, it will be stopped immediately instead of
waiting for the idle timer to elapse.

=item idle_time => $seconds (default: 1)

When a worker has no jobs to execute it becomes idle. An idle worker that
hasn't executed a job within this amount of time will be stopped, unless
the other parameters say otherwise.

=item on_destroy => $callback->() (default: none)

When a pool object goes out of scope, it will still handle all outstanding
jobs. After that, it will destroy all workers (and also the template
process if it isn't referenced otherwise).

=back

=item Template Process

The worker processes are all forked from a single template
process. Ideally, all modules and all cdoe used by the worker, as well as
any shared data structures should be loaded into the template process, to
take advantage of data sharing via fork.

You can create your own template process by creating a L<AnyEvent::Fork>
object yourself and passing it as the C<template> parameter, but
C<AnyEvent::Fork::Pool> can create one for you, including some standard
options.

=over 4

=item template => $fork (default: C<< AnyEvent::Fork->new >>)

The template process to use, if you want to create your own.

=item require => \@modules (default: C<[]>)

The modules in this list will be laoded into the template process.

=item eval => "# perl code to execute in template" (default: none)

This is a perl string that is evaluated after creating the template
process and after requiring the modules. It can do whatever it wants to
configure the process, but it must not do anything that would keep a later
fork from working (so must not create event handlers or (real) threads for
example).

=back

=item AnyEvent::Fork::RPC Parameters

These parameters are all passed directly to L<AnyEvent::Fork::RPC>. They
are only briefly mentioned here, for their full documentation
please refer to the L<AnyEvent::Fork::RPC> documentation. Also, the
default values mentioned here are only documented as a best effort -
L<AnyEvent::Fork::RPC> documentation is binding.

=over 4

=item async => $boolean (default: 0)

Whether to sue the synchronous or asynchronous RPC backend.

=item on_error => $callback->($message) (default: die with message)

The callback to call on any (fatal) errors.

=item on_event => $callback->(...) (default: C<sub { }>, unlike L<AnyEvent::Fork::RPC>)

The callback to invoke on events.

=item init => $initfunction (default: none)

The function to call in the child, once before handling requests.

=item serialiser => $serialiser (defailt: $AnyEvent::Fork::RPC::STRING_SERIALISER)

The serialiser to use.

=back

=back

=cut

sub new {
   my ($class, $function, %arg) = @_;

   my $self = bless  {
      min        => 0,
      max        => 4,
      max_queue  => 2,
      min_delay  => 0,
      max_idle   => 1,
      idle_time  => 1,
      on_event   => sub { },
      %arg,
      pool       => [],
      queue      => [],
   }, $class;

   $self->{function} = $function;

   ($self->{template} ||= new AnyEvent::Fork)
      ->require ("AnyEvent::Fork::RPC::" . ($self->{async} ? "Async" : "Sync"))
      ->require (@{ delete $self->{require} })
      ->eval ('
           my ($magic0, $magic2) = @_;
           sub AnyEvent::Fork::Pool::quit() {
              AnyEvent::Fork::RPC::on_event $magic0, "quit", $magic2;
           }
        ', $magic0, $magic2)
      ->eval (delete $self->{eval});

   $self->start
      while @{ $self->{pool} } < $self->{min};

   $self
}

sub start {
   my ($self) = @_;
   
   warn "start\n";#d#

   Scalar::Util::weaken $self;

   my $proc = [0, undef, undef];

   $proc->[1] = $self->{template}
      ->fork
      ->AnyEvent::Fork::RPC::run ($self->{function},
           async      => $self->{async},
           init       => $self->{init},
           serialiser => $self->{serialiser},
           on_error   => $self->{on_error},
           on_event   => sub {
              if (@_ == 3 && $_[0] eq $magic0 && $_[2] eq $magic2) {
                 if ($_[1] eq "quit") {
                    my $pool = $self->{pool};
                    for (0 .. $#$pool) {
                       if ($pool->[$_] == $proc) {
                          Array::Heap::splice_heap @$pool, $_;
                          return;
                       }
                    }
                    die;
                 }
                 return;
              }

              &{ $self->{on_event} };
           },
        )
   ;

   ++$self->{idle};
   Array::Heap::push_heap @{ $self->{pool} }, $proc;
}

=item $pool->call (..., $cb->(...))

Call the RPC function of a worker with the given arguments, and when the
worker is done, call the C<$cb> with the results, like just calling the
L<AnyEvent::Fork::RPC> object directly.

If there is no free worker, the call will be queued.

Note that there can be considerable time between calling this method and
the call actually being executed. During this time, the parameters passed
to this function are effectively read-only - modifying them after the call
and before the callback is invoked causes undefined behaviour.

=cut

sub scheduler {
   my $self = shift;

   my $pool  = $self->{pool};
   my $queue = $self->{queue};

   $self->start
      unless @$pool;

   while (@$queue) {
      my $proc = $pool->[0];

      if ($proc->[0] < $self->{max_queue}) {
   warn "free $proc $proc->[0]\n";#d#
         # found free worker
         --$self->{idle}
            unless $proc->[0]++;

         undef $proc->[2];

         Array::Heap::adjust_heap @$pool, 0;

         my $job = shift @$queue;
         my $ocb = pop @$job;

         $proc->[1]->(@$job, sub {
            for (0 .. $#$pool) {
               if ($pool->[$_] == $proc) {
                  # reduce queue counter
                  unless (--$pool->[$_][0]) {
                     # worker becomes idle
                     my $to = ++$self->{idle} > $self->{max_idle}
                            ? 0
                            : $self->{idle_time};

                     $proc->[2] = AE::timer $to, 0, sub {
                        undef $proc->[2];

                        warn "destroy $proc afzer $to\n";#d#

                        for (0 .. $#$pool) {
                           if ($pool->[$_] == $proc) {
                              Array::Heap::splice_heap @$pool, $_;
                              --$self->{idle};
                              last;
                           }
                        }
                     };
                  }

                  Array::Heap::adjust_heap @$pool, $_;
                  last;
               }
            }
            &$ocb;
         });
      } else {
   warn "busy $proc->[0]\n";#d#
         # all busy, delay

         $self->{min_delay_w} ||= AE::timer $self->{min_delay}, 0, sub {
            delete $self->{min_delay_w};

            if (@{ $self->{queue} }) {
               $self->start;
               $self->scheduler;
            }
         };
         last;
      }
   }
   warn "last\n";#d#
}

sub call {
   my $self = shift;

   push @{ $self->{queue} }, [@_];
   $self->scheduler;
}

sub DESTROY {
   $_[0]{on_destroy}->();
}

=back

=head1 SEE ALSO

L<AnyEvent::Fork>, to create the processes in the first place.

L<AnyEvent::Fork::RPC>, which implements the RPC protocol and API.

=head1 AUTHOR AND CONTACT INFORMATION

 Marc Lehmann <schmorp@schmorp.de>
 http://software.schmorp.de/pkg/AnyEvent-Fork-Pool

=cut

1