1 |
=head1 NAME |
2 |
|
3 |
AnyEvent::HTTP - simple but non-blocking HTTP/HTTPS client |
4 |
|
5 |
=head1 SYNOPSIS |
6 |
|
7 |
use AnyEvent::HTTP; |
8 |
|
9 |
http_get "http://www.nethype.de/", sub { print $_[1] }; |
10 |
|
11 |
# ... do something else here |
12 |
|
13 |
=head1 DESCRIPTION |
14 |
|
15 |
This module is an L<AnyEvent> user, you need to make sure that you use and |
16 |
run a supported event loop. |
17 |
|
18 |
This module implements a simple, stateless and non-blocking HTTP |
19 |
client. It supports GET, POST and other request methods, cookies and more, |
20 |
all on a very low level. It can follow redirects supports proxies and |
21 |
automatically limits the number of connections to the values specified in |
22 |
the RFC. |
23 |
|
24 |
It should generally be a "good client" that is enough for most HTTP |
25 |
tasks. Simple tasks should be simple, but complex tasks should still be |
26 |
possible as the user retains control over request and response headers. |
27 |
|
28 |
The caller is responsible for authentication management, cookies (if |
29 |
the simplistic implementation in this module doesn't suffice), referer |
30 |
and other high-level protocol details for which this module offers only |
31 |
limited support. |
32 |
|
33 |
=head2 METHODS |
34 |
|
35 |
=over 4 |
36 |
|
37 |
=cut |
38 |
|
39 |
package AnyEvent::HTTP; |
40 |
|
41 |
use common::sense; |
42 |
|
43 |
use Errno (); |
44 |
|
45 |
use AnyEvent 5.0 (); |
46 |
use AnyEvent::Util (); |
47 |
use AnyEvent::Handle (); |
48 |
|
49 |
use base Exporter::; |
50 |
|
51 |
our $VERSION = '1.5'; |
52 |
|
53 |
our @EXPORT = qw(http_get http_post http_head http_request); |
54 |
|
55 |
our $USERAGENT = "Mozilla/5.0 (compatible; U; AnyEvent-HTTP/$VERSION; +http://software.schmorp.de/pkg/AnyEvent)"; |
56 |
our $MAX_RECURSE = 10; |
57 |
our $MAX_PERSISTENT = 8; |
58 |
our $PERSISTENT_TIMEOUT = 2; |
59 |
our $TIMEOUT = 300; |
60 |
|
61 |
# changing these is evil |
62 |
our $MAX_PERSISTENT_PER_HOST = 0; |
63 |
our $MAX_PER_HOST = 4; |
64 |
|
65 |
our $PROXY; |
66 |
our $ACTIVE = 0; |
67 |
|
68 |
my %KA_COUNT; # number of open keep-alive connections per host |
69 |
my %CO_SLOT; # number of open connections, and wait queue, per host |
70 |
|
71 |
=item http_get $url, key => value..., $cb->($data, $headers) |
72 |
|
73 |
Executes an HTTP-GET request. See the http_request function for details on |
74 |
additional parameters and the return value. |
75 |
|
76 |
=item http_head $url, key => value..., $cb->($data, $headers) |
77 |
|
78 |
Executes an HTTP-HEAD request. See the http_request function for details |
79 |
on additional parameters and the return value. |
80 |
|
81 |
=item http_post $url, $body, key => value..., $cb->($data, $headers) |
82 |
|
83 |
Executes an HTTP-POST request with a request body of C<$body>. See the |
84 |
http_request function for details on additional parameters and the return |
85 |
value. |
86 |
|
87 |
=item http_request $method => $url, key => value..., $cb->($data, $headers) |
88 |
|
89 |
Executes a HTTP request of type C<$method> (e.g. C<GET>, C<POST>). The URL |
90 |
must be an absolute http or https URL. |
91 |
|
92 |
When called in void context, nothing is returned. In other contexts, |
93 |
C<http_request> returns a "cancellation guard" - you have to keep the |
94 |
object at least alive until the callback get called. If the object gets |
95 |
destroyed before the callback is called, the request will be cancelled. |
96 |
|
97 |
The callback will be called with the response body data as first argument |
98 |
(or C<undef> if an error occured), and a hash-ref with response headers |
99 |
(and trailers) as second argument. |
100 |
|
101 |
All the headers in that hash are lowercased. In addition to the response |
102 |
headers, the "pseudo-headers" (uppercase to avoid clashing with possible |
103 |
response headers) C<HTTPVersion>, C<Status> and C<Reason> contain the |
104 |
three parts of the HTTP Status-Line of the same name. If an error occurs |
105 |
during the body phase of a request, then the original C<Status> and |
106 |
C<Reason> values from the header are available as C<OrigStatus> and |
107 |
C<OrigReason>. |
108 |
|
109 |
The pseudo-header C<URL> contains the actual URL (which can differ from |
110 |
the requested URL when following redirects - for example, you might get |
111 |
an error that your URL scheme is not supported even though your URL is a |
112 |
valid http URL because it redirected to an ftp URL, in which case you can |
113 |
look at the URL pseudo header). |
114 |
|
115 |
The pseudo-header C<Redirect> only exists when the request was a result |
116 |
of an internal redirect. In that case it is an array reference with |
117 |
the C<($data, $headers)> from the redirect response. Note that this |
118 |
response could in turn be the result of a redirect itself, and C<< |
119 |
$headers->{Redirect}[1]{Redirect} >> will then contain the original |
120 |
response, and so on. |
121 |
|
122 |
If the server sends a header multiple times, then their contents will be |
123 |
joined together with a comma (C<,>), as per the HTTP spec. |
124 |
|
125 |
If an internal error occurs, such as not being able to resolve a hostname, |
126 |
then C<$data> will be C<undef>, C<< $headers->{Status} >> will be |
127 |
C<590>-C<599> and the C<Reason> pseudo-header will contain an error |
128 |
message. Currently the following status codes are used: |
129 |
|
130 |
=over 4 |
131 |
|
132 |
=item 595 - errors during connection etsbalishment, proxy handshake. |
133 |
|
134 |
=item 596 - errors during TLS negotiation, request sending and header processing. |
135 |
|
136 |
=item 597 - errors during body receiving or processing. |
137 |
|
138 |
=item 598 - user aborted request via C<on_header> or C<on_body>. |
139 |
|
140 |
=item 599 - other, usually nonretryable, errors (garbled URL etc.). |
141 |
|
142 |
=back |
143 |
|
144 |
A typical callback might look like this: |
145 |
|
146 |
sub { |
147 |
my ($body, $hdr) = @_; |
148 |
|
149 |
if ($hdr->{Status} =~ /^2/) { |
150 |
... everything should be ok |
151 |
} else { |
152 |
print "error, $hdr->{Status} $hdr->{Reason}\n"; |
153 |
} |
154 |
} |
155 |
|
156 |
Additional parameters are key-value pairs, and are fully optional. They |
157 |
include: |
158 |
|
159 |
=over 4 |
160 |
|
161 |
=item recurse => $count (default: $MAX_RECURSE) |
162 |
|
163 |
Whether to recurse requests or not, e.g. on redirects, authentication |
164 |
retries and so on, and how often to do so. |
165 |
|
166 |
=item headers => hashref |
167 |
|
168 |
The request headers to use. Currently, C<http_request> may provide its own |
169 |
C<Host:>, C<Content-Length:>, C<Connection:> and C<Cookie:> headers and |
170 |
will provide defaults at least for C<TE:>, C<Referer:> and C<User-Agent:> |
171 |
(this can be suppressed by using C<undef> for these headers in which case |
172 |
they won't be sent at all). |
173 |
|
174 |
=item timeout => $seconds |
175 |
|
176 |
The time-out to use for various stages - each connect attempt will reset |
177 |
the timeout, as will read or write activity, i.e. this is not an overall |
178 |
timeout. |
179 |
|
180 |
Default timeout is 5 minutes. |
181 |
|
182 |
=item proxy => [$host, $port[, $scheme]] or undef |
183 |
|
184 |
Use the given http proxy for all requests. If not specified, then the |
185 |
default proxy (as specified by C<$ENV{http_proxy}>) is used. |
186 |
|
187 |
C<$scheme> must be either missing, C<http> for HTTP or C<https> for |
188 |
HTTPS. |
189 |
|
190 |
=item body => $string |
191 |
|
192 |
The request body, usually empty. Will be sent as-is (future versions of |
193 |
this module might offer more options). |
194 |
|
195 |
=item cookie_jar => $hash_ref |
196 |
|
197 |
Passing this parameter enables (simplified) cookie-processing, loosely |
198 |
based on the original netscape specification. |
199 |
|
200 |
The C<$hash_ref> must be an (initially empty) hash reference which |
201 |
will get updated automatically. It is possible to save the cookie jar |
202 |
to persistent storage with something like JSON or Storable - see the |
203 |
C<AnyEvent::HTTP::cookie_jar_expire> function if you wish to remove |
204 |
expired or session-only cookies, and also for documentation on the format |
205 |
of the cookie jar. |
206 |
|
207 |
Note that this cookie implementation is not meant to be complete. If |
208 |
you want complete cookie management you have to do that on your |
209 |
own. C<cookie_jar> is meant as a quick fix to get most cookie-using sites |
210 |
working. Cookies are a privacy disaster, do not use them unless required |
211 |
to. |
212 |
|
213 |
When cookie processing is enabled, the C<Cookie:> and C<Set-Cookie:> |
214 |
headers will be set and handled by this module, otherwise they will be |
215 |
left untouched. |
216 |
|
217 |
=item tls_ctx => $scheme | $tls_ctx |
218 |
|
219 |
Specifies the AnyEvent::TLS context to be used for https connections. This |
220 |
parameter follows the same rules as the C<tls_ctx> parameter to |
221 |
L<AnyEvent::Handle>, but additionally, the two strings C<low> or |
222 |
C<high> can be specified, which give you a predefined low-security (no |
223 |
verification, highest compatibility) and high-security (CA and common-name |
224 |
verification) TLS context. |
225 |
|
226 |
The default for this option is C<low>, which could be interpreted as "give |
227 |
me the page, no matter what". |
228 |
|
229 |
=item on_prepare => $callback->($fh) |
230 |
|
231 |
In rare cases you need to "tune" the socket before it is used to |
232 |
connect (for exmaple, to bind it on a given IP address). This parameter |
233 |
overrides the prepare callback passed to C<AnyEvent::Socket::tcp_connect> |
234 |
and behaves exactly the same way (e.g. it has to provide a |
235 |
timeout). See the description for the C<$prepare_cb> argument of |
236 |
C<AnyEvent::Socket::tcp_connect> for details. |
237 |
|
238 |
=item tcp_connect => $callback->($host, $service, $connect_cb, $prepare_cb) |
239 |
|
240 |
In even rarer cases you want total control over how AnyEvent::HTTP |
241 |
establishes connections. Normally it uses L<AnyEvent::Socket::tcp_connect> |
242 |
to do this, but you can provide your own C<tcp_connect> function - |
243 |
obviously, it has to follow the same calling conventions, except that it |
244 |
may always return a connection guard object. |
245 |
|
246 |
There are probably lots of weird uses for this function, starting from |
247 |
tracing the hosts C<http_request> actually tries to connect, to (inexact |
248 |
but fast) host => IP address caching or even socks protocol support. |
249 |
|
250 |
=item on_header => $callback->($headers) |
251 |
|
252 |
When specified, this callback will be called with the header hash as soon |
253 |
as headers have been successfully received from the remote server (not on |
254 |
locally-generated errors). |
255 |
|
256 |
It has to return either true (in which case AnyEvent::HTTP will continue), |
257 |
or false, in which case AnyEvent::HTTP will cancel the download (and call |
258 |
the finish callback with an error code of C<598>). |
259 |
|
260 |
This callback is useful, among other things, to quickly reject unwanted |
261 |
content, which, if it is supposed to be rare, can be faster than first |
262 |
doing a C<HEAD> request. |
263 |
|
264 |
The downside is that cancelling the request makes it impossible to re-use |
265 |
the connection. Also, the C<on_header> callback will not receive any |
266 |
trailer (headers sent after the response body). |
267 |
|
268 |
Example: cancel the request unless the content-type is "text/html". |
269 |
|
270 |
on_header => sub { |
271 |
$_[0]{"content-type"} =~ /^text\/html\s*(?:;|$)/ |
272 |
}, |
273 |
|
274 |
=item on_body => $callback->($partial_body, $headers) |
275 |
|
276 |
When specified, all body data will be passed to this callback instead of |
277 |
to the completion callback. The completion callback will get the empty |
278 |
string instead of the body data. |
279 |
|
280 |
It has to return either true (in which case AnyEvent::HTTP will continue), |
281 |
or false, in which case AnyEvent::HTTP will cancel the download (and call |
282 |
the completion callback with an error code of C<598>). |
283 |
|
284 |
The downside to cancelling the request is that it makes it impossible to |
285 |
re-use the connection. |
286 |
|
287 |
This callback is useful when the data is too large to be held in memory |
288 |
(so the callback writes it to a file) or when only some information should |
289 |
be extracted, or when the body should be processed incrementally. |
290 |
|
291 |
It is usually preferred over doing your own body handling via |
292 |
C<want_body_handle>, but in case of streaming APIs, where HTTP is |
293 |
only used to create a connection, C<want_body_handle> is the better |
294 |
alternative, as it allows you to install your own event handler, reducing |
295 |
resource usage. |
296 |
|
297 |
=item want_body_handle => $enable |
298 |
|
299 |
When enabled (default is disabled), the behaviour of AnyEvent::HTTP |
300 |
changes considerably: after parsing the headers, and instead of |
301 |
downloading the body (if any), the completion callback will be |
302 |
called. Instead of the C<$body> argument containing the body data, the |
303 |
callback will receive the L<AnyEvent::Handle> object associated with the |
304 |
connection. In error cases, C<undef> will be passed. When there is no body |
305 |
(e.g. status C<304>), the empty string will be passed. |
306 |
|
307 |
The handle object might or might not be in TLS mode, might be connected to |
308 |
a proxy, be a persistent connection etc., and configured in unspecified |
309 |
ways. The user is responsible for this handle (it will not be used by this |
310 |
module anymore). |
311 |
|
312 |
This is useful with some push-type services, where, after the initial |
313 |
headers, an interactive protocol is used (typical example would be the |
314 |
push-style twitter API which starts a JSON/XML stream). |
315 |
|
316 |
If you think you need this, first have a look at C<on_body>, to see if |
317 |
that doesn't solve your problem in a better way. |
318 |
|
319 |
=back |
320 |
|
321 |
Example: do a simple HTTP GET request for http://www.nethype.de/ and print |
322 |
the response body. |
323 |
|
324 |
http_request GET => "http://www.nethype.de/", sub { |
325 |
my ($body, $hdr) = @_; |
326 |
print "$body\n"; |
327 |
}; |
328 |
|
329 |
Example: do a HTTP HEAD request on https://www.google.com/, use a |
330 |
timeout of 30 seconds. |
331 |
|
332 |
http_request |
333 |
GET => "https://www.google.com", |
334 |
timeout => 30, |
335 |
sub { |
336 |
my ($body, $hdr) = @_; |
337 |
use Data::Dumper; |
338 |
print Dumper $hdr; |
339 |
} |
340 |
; |
341 |
|
342 |
Example: do another simple HTTP GET request, but immediately try to |
343 |
cancel it. |
344 |
|
345 |
my $request = http_request GET => "http://www.nethype.de/", sub { |
346 |
my ($body, $hdr) = @_; |
347 |
print "$body\n"; |
348 |
}; |
349 |
|
350 |
undef $request; |
351 |
|
352 |
=cut |
353 |
|
354 |
sub _slot_schedule; |
355 |
sub _slot_schedule($) { |
356 |
my $host = shift; |
357 |
|
358 |
while ($CO_SLOT{$host}[0] < $MAX_PER_HOST) { |
359 |
if (my $cb = shift @{ $CO_SLOT{$host}[1] }) { |
360 |
# somebody wants that slot |
361 |
++$CO_SLOT{$host}[0]; |
362 |
++$ACTIVE; |
363 |
|
364 |
$cb->(AnyEvent::Util::guard { |
365 |
--$ACTIVE; |
366 |
--$CO_SLOT{$host}[0]; |
367 |
_slot_schedule $host; |
368 |
}); |
369 |
} else { |
370 |
# nobody wants the slot, maybe we can forget about it |
371 |
delete $CO_SLOT{$host} unless $CO_SLOT{$host}[0]; |
372 |
last; |
373 |
} |
374 |
} |
375 |
} |
376 |
|
377 |
# wait for a free slot on host, call callback |
378 |
sub _get_slot($$) { |
379 |
push @{ $CO_SLOT{$_[0]}[1] }, $_[1]; |
380 |
|
381 |
_slot_schedule $_[0]; |
382 |
} |
383 |
|
384 |
############################################################################# |
385 |
|
386 |
# expire cookies |
387 |
sub cookie_jar_expire($;$) { |
388 |
my ($jar, $session_end) = @_; |
389 |
|
390 |
%$jar = () if $jar->{version} != 1; |
391 |
|
392 |
my $anow = AE::now; |
393 |
|
394 |
while (my ($chost, $paths) = each %$jar) { |
395 |
next unless ref $paths; |
396 |
|
397 |
while (my ($cpath, $cookies) = each %$paths) { |
398 |
while (my ($cookie, $kv) = each %$cookies) { |
399 |
if (exists $kv->{_expires}) { |
400 |
delete $cookies->{$cookie} |
401 |
if $anow > $kv->{_expires}; |
402 |
} elsif ($session_end) { |
403 |
delete $cookies->{$cookie}; |
404 |
} |
405 |
} |
406 |
|
407 |
delete $paths->{$cpath} |
408 |
unless %$cookies; |
409 |
} |
410 |
|
411 |
delete $jar->{$chost} |
412 |
unless %$paths; |
413 |
} |
414 |
} |
415 |
|
416 |
# extract cookies from jar |
417 |
sub cookie_jar_extract($$$$) { |
418 |
my ($jar, $uscheme, $uhost, $upath) = @_; |
419 |
|
420 |
$uhost = lc $uhost; |
421 |
|
422 |
%$jar = () if $jar->{version} != 1; |
423 |
|
424 |
my @cookies; |
425 |
|
426 |
while (my ($chost, $paths) = each %$jar) { |
427 |
next unless ref $paths; |
428 |
|
429 |
if ($chost =~ /^\./) { |
430 |
next unless $chost eq substr $uhost, -length $chost; |
431 |
} elsif ($chost =~ /\./) { |
432 |
next unless $chost eq $uhost; |
433 |
} else { |
434 |
next; |
435 |
} |
436 |
|
437 |
while (my ($cpath, $cookies) = each %$paths) { |
438 |
next unless $cpath eq substr $upath, 0, length $cpath; |
439 |
|
440 |
while (my ($cookie, $kv) = each %$cookies) { |
441 |
next if $uscheme ne "https" && exists $kv->{secure}; |
442 |
|
443 |
if (exists $kv->{_expires} and AE::now > $kv->{_expires}) { |
444 |
delete $cookies->{$cookie}; |
445 |
next; |
446 |
} |
447 |
|
448 |
my $value = $kv->{value}; |
449 |
|
450 |
if ($value =~ /[=;,[:space:]]/) { |
451 |
$value =~ s/([\\"])/\\$1/g; |
452 |
$value = "\"$value\""; |
453 |
} |
454 |
|
455 |
push @cookies, "$cookie=$value"; |
456 |
} |
457 |
} |
458 |
} |
459 |
|
460 |
\@cookies |
461 |
} |
462 |
|
463 |
# parse set_cookie header into jar |
464 |
sub cookie_jar_set_cookie($$$$) { |
465 |
my ($jar, $set_cookie, $uhost, $date) = @_; |
466 |
|
467 |
my $anow = int AE::now; |
468 |
my $snow; # server-now |
469 |
|
470 |
for ($set_cookie) { |
471 |
# parse NAME=VALUE |
472 |
my @kv; |
473 |
|
474 |
# expires is not http-compliant in the original cookie-spec, |
475 |
# we support the official date format and some extensions |
476 |
while ( |
477 |
m{ |
478 |
\G\s* |
479 |
(?: |
480 |
expires \s*=\s* ([A-Z][a-z][a-z]+,\ [^,;]+) |
481 |
| ([^=;,[:space:]]+) (?: \s*=\s* (?: "((?:[^\\"]+|\\.)*)" | ([^=;,[:space:]]*) ) )? |
482 |
) |
483 |
}gcxsi |
484 |
) { |
485 |
my $name = $2; |
486 |
my $value = $4; |
487 |
|
488 |
if (defined $1) { |
489 |
# expires |
490 |
$name = "expires"; |
491 |
$value = $1; |
492 |
} elsif (defined $3) { |
493 |
# quoted |
494 |
$value = $3; |
495 |
$value =~ s/\\(.)/$1/gs; |
496 |
} |
497 |
|
498 |
push @kv, lc $name, $value; |
499 |
|
500 |
last unless /\G\s*;/gc; |
501 |
} |
502 |
|
503 |
last unless @kv; |
504 |
|
505 |
my $name = shift @kv; |
506 |
my %kv = (value => shift @kv, @kv); |
507 |
|
508 |
if (exists $kv{"max-age"}) { |
509 |
$kv{_expires} = $anow + delete $kv{"max-age"}; |
510 |
} elsif (exists $kv{expires}) { |
511 |
$snow ||= parse_date ($date) || $anow; |
512 |
$kv{_expires} = $anow + (parse_date (delete $kv{expires}) - $snow); |
513 |
} else { |
514 |
delete $kv{_expires}; |
515 |
} |
516 |
|
517 |
my $cdom; |
518 |
my $cpath = (delete $kv{path}) || "/"; |
519 |
|
520 |
if (exists $kv{domain}) { |
521 |
$cdom = delete $kv{domain}; |
522 |
|
523 |
$cdom =~ s/^\.?/./; # make sure it starts with a "." |
524 |
|
525 |
next if $cdom =~ /\.$/; |
526 |
|
527 |
# this is not rfc-like and not netscape-like. go figure. |
528 |
my $ndots = $cdom =~ y/.//; |
529 |
next if $ndots < ($cdom =~ /\.[^.][^.]\.[^.][^.]$/ ? 3 : 2); |
530 |
} else { |
531 |
$cdom = $uhost; |
532 |
} |
533 |
|
534 |
# store it |
535 |
$jar->{version} = 1; |
536 |
$jar->{lc $cdom}{$cpath}{$name} = \%kv; |
537 |
|
538 |
redo if /\G\s*,/gc; |
539 |
} |
540 |
} |
541 |
|
542 |
# continue to parse $_ for headers and place them into the arg |
543 |
sub parse_hdr() { |
544 |
my %hdr; |
545 |
|
546 |
# things seen, not parsed: |
547 |
# p3pP="NON CUR OTPi OUR NOR UNI" |
548 |
|
549 |
$hdr{lc $1} .= ",$2" |
550 |
while /\G |
551 |
([^:\000-\037]*): |
552 |
[\011\040]* |
553 |
((?: [^\012]+ | \012[\011\040] )*) |
554 |
\012 |
555 |
/gxc; |
556 |
|
557 |
/\G$/ |
558 |
or return; |
559 |
|
560 |
# remove the "," prefix we added to all headers above |
561 |
substr $_, 0, 1, "" |
562 |
for values %hdr; |
563 |
|
564 |
\%hdr |
565 |
} |
566 |
|
567 |
our $qr_nlnl = qr{(?<![^\012])\015?\012}; |
568 |
|
569 |
our $TLS_CTX_LOW = { cache => 1, sslv2 => 1 }; |
570 |
our $TLS_CTX_HIGH = { cache => 1, verify => 1, verify_peername => "https" }; |
571 |
|
572 |
sub http_request($$@) { |
573 |
my $cb = pop; |
574 |
my ($method, $url, %arg) = @_; |
575 |
|
576 |
my %hdr; |
577 |
|
578 |
$arg{tls_ctx} = $TLS_CTX_LOW if $arg{tls_ctx} eq "low" || !exists $arg{tls_ctx}; |
579 |
$arg{tls_ctx} = $TLS_CTX_HIGH if $arg{tls_ctx} eq "high"; |
580 |
|
581 |
$method = uc $method; |
582 |
|
583 |
if (my $hdr = $arg{headers}) { |
584 |
while (my ($k, $v) = each %$hdr) { |
585 |
$hdr{lc $k} = $v; |
586 |
} |
587 |
} |
588 |
|
589 |
# pseudo headers for all subsequent responses |
590 |
my @pseudo = (URL => $url); |
591 |
push @pseudo, Redirect => delete $arg{Redirect} if exists $arg{Redirect}; |
592 |
|
593 |
my $recurse = exists $arg{recurse} ? delete $arg{recurse} : $MAX_RECURSE; |
594 |
|
595 |
return $cb->(undef, { @pseudo, Status => 599, Reason => "Too many redirections" }) |
596 |
if $recurse < 0; |
597 |
|
598 |
my $proxy = $arg{proxy} || $PROXY; |
599 |
my $timeout = $arg{timeout} || $TIMEOUT; |
600 |
|
601 |
my ($uscheme, $uauthority, $upath, $query, $fragment) = |
602 |
$url =~ m|(?:([^:/?#]+):)?(?://([^/?#]*))?([^?#]*)(?:(\?[^#]*))?(?:#(.*))?|; |
603 |
|
604 |
$uscheme = lc $uscheme; |
605 |
|
606 |
my $uport = $uscheme eq "http" ? 80 |
607 |
: $uscheme eq "https" ? 443 |
608 |
: return $cb->(undef, { @pseudo, Status => 599, Reason => "Only http and https URL schemes supported" }); |
609 |
|
610 |
$uauthority =~ /^(?: .*\@ )? ([^\@:]+) (?: : (\d+) )?$/x |
611 |
or return $cb->(undef, { @pseudo, Status => 599, Reason => "Unparsable URL" }); |
612 |
|
613 |
my $uhost = $1; |
614 |
$uport = $2 if defined $2; |
615 |
|
616 |
$hdr{host} = defined $2 ? "$uhost:$2" : "$uhost" |
617 |
unless exists $hdr{host}; |
618 |
|
619 |
$uhost =~ s/^\[(.*)\]$/$1/; |
620 |
$upath .= $query if length $query; |
621 |
|
622 |
$upath =~ s%^/?%/%; |
623 |
|
624 |
# cookie processing |
625 |
if (my $jar = $arg{cookie_jar}) { |
626 |
my $cookies = cookie_jar_extract $jar, $uscheme, $uhost, $upath; |
627 |
|
628 |
$hdr{cookie} = join "; ", @$cookies |
629 |
if @$cookies; |
630 |
} |
631 |
|
632 |
my ($rhost, $rport, $rscheme, $rpath); # request host, port, path |
633 |
|
634 |
if ($proxy) { |
635 |
($rpath, $rhost, $rport, $rscheme) = ($url, @$proxy); |
636 |
|
637 |
$rscheme = "http" unless defined $rscheme; |
638 |
|
639 |
# don't support https requests over https-proxy transport, |
640 |
# can't be done with tls as spec'ed, unless you double-encrypt. |
641 |
$rscheme = "http" if $uscheme eq "https" && $rscheme eq "https"; |
642 |
} else { |
643 |
($rhost, $rport, $rscheme, $rpath) = ($uhost, $uport, $uscheme, $upath); |
644 |
} |
645 |
|
646 |
# leave out fragment and query string, just a heuristic |
647 |
$hdr{referer} = "$uscheme://$uauthority$upath" unless exists $hdr{referer}; |
648 |
$hdr{"user-agent"} = $USERAGENT unless exists $hdr{"user-agent"}; |
649 |
|
650 |
$hdr{"content-length"} = length $arg{body} |
651 |
if length $arg{body} || $method ne "GET"; |
652 |
|
653 |
$hdr{connection} = "close TE"; #1.1 |
654 |
$hdr{te} = "trailers" unless exists $hdr{te}; #1.1 |
655 |
|
656 |
my %state = (connect_guard => 1); |
657 |
|
658 |
_get_slot $uhost, sub { |
659 |
$state{slot_guard} = shift; |
660 |
|
661 |
return unless $state{connect_guard}; |
662 |
|
663 |
my $ae_error = 595; # connecting |
664 |
|
665 |
# handle actual, non-tunneled, request |
666 |
my $handle_actual_request = sub { |
667 |
$ae_error = 596; # request phase |
668 |
|
669 |
$state{handle}->starttls ("connect") if $uscheme eq "https" && !exists $state{handle}{tls}; |
670 |
|
671 |
# send request |
672 |
$state{handle}->push_write ( |
673 |
"$method $rpath HTTP/1.1\015\012" |
674 |
. (join "", map "\u$_: $hdr{$_}\015\012", grep defined $hdr{$_}, keys %hdr) |
675 |
. "\015\012" |
676 |
. (delete $arg{body}) |
677 |
); |
678 |
|
679 |
# return if error occured during push_write() |
680 |
return unless %state; |
681 |
|
682 |
%hdr = (); # reduce memory usage, save a kitten, also make it possible to re-use |
683 |
|
684 |
# status line and headers |
685 |
$state{read_response} = sub { |
686 |
for ("$_[1]") { |
687 |
y/\015//d; # weed out any \015, as they show up in the weirdest of places. |
688 |
|
689 |
/^HTTP\/0*([0-9\.]+) \s+ ([0-9]{3}) (?: \s+ ([^\012]*) )? \012/gxci |
690 |
or return (%state = (), $cb->(undef, { @pseudo, Status => 599, Reason => "Invalid server response" })); |
691 |
|
692 |
# 100 Continue handling |
693 |
# should not happen as we don't send expect: 100-continue, |
694 |
# but we handle it just in case. |
695 |
# since we send the request body regardless, if we get an error |
696 |
# we are out of-sync, which we currently do NOT handle correctly. |
697 |
return $state{handle}->push_read (line => $qr_nlnl, $state{read_response}) |
698 |
if $2 eq 100; |
699 |
|
700 |
push @pseudo, |
701 |
HTTPVersion => $1, |
702 |
Status => $2, |
703 |
Reason => $3, |
704 |
; |
705 |
|
706 |
my $hdr = parse_hdr |
707 |
or return (%state = (), $cb->(undef, { @pseudo, Status => 599, Reason => "Garbled response headers" })); |
708 |
|
709 |
%hdr = (%$hdr, @pseudo); |
710 |
} |
711 |
|
712 |
# redirect handling |
713 |
# microsoft and other shitheads don't give a shit for following standards, |
714 |
# try to support some common forms of broken Location headers. |
715 |
if ($hdr{location} !~ /^(?: $ | [^:\/?\#]+ : )/x) { |
716 |
$hdr{location} =~ s/^\.\/+//; |
717 |
|
718 |
my $url = "$rscheme://$uhost:$uport"; |
719 |
|
720 |
unless ($hdr{location} =~ s/^\///) { |
721 |
$url .= $upath; |
722 |
$url =~ s/\/[^\/]*$//; |
723 |
} |
724 |
|
725 |
$hdr{location} = "$url/$hdr{location}"; |
726 |
} |
727 |
|
728 |
my $redirect; |
729 |
|
730 |
if ($recurse) { |
731 |
my $status = $hdr{Status}; |
732 |
|
733 |
# industry standard is to redirect POST as GET for |
734 |
# 301, 302 and 303, in contrast to HTTP/1.0 and 1.1. |
735 |
# also, the UA should ask the user for 301 and 307 and POST, |
736 |
# industry standard seems to be to simply follow. |
737 |
# we go with the industry standard. |
738 |
if ($status == 301 or $status == 302 or $status == 303) { |
739 |
# HTTP/1.1 is unclear on how to mutate the method |
740 |
$method = "GET" unless $method eq "HEAD"; |
741 |
$redirect = 1; |
742 |
} elsif ($status == 307) { |
743 |
$redirect = 1; |
744 |
} |
745 |
} |
746 |
|
747 |
my $finish = sub { # ($data, $err_status, $err_reason[, $keepalive]) |
748 |
my $may_keep_alive = $_[3]; |
749 |
|
750 |
$state{handle}->destroy if $state{handle}; |
751 |
%state = (); |
752 |
|
753 |
if (defined $_[1]) { |
754 |
$hdr{OrigStatus} = $hdr{Status}; $hdr{Status} = $_[1]; |
755 |
$hdr{OrigReason} = $hdr{Reason}; $hdr{Reason} = $_[2]; |
756 |
} |
757 |
|
758 |
# set-cookie processing |
759 |
if ($arg{cookie_jar}) { |
760 |
cookie_jar_set_cookie $arg{cookie_jar}, $hdr{"set-cookie"}, $uhost, $hdr{date}; |
761 |
} |
762 |
|
763 |
if ($redirect && exists $hdr{location}) { |
764 |
# we ignore any errors, as it is very common to receive |
765 |
# Content-Length != 0 but no actual body |
766 |
# we also access %hdr, as $_[1] might be an erro |
767 |
http_request ( |
768 |
$method => $hdr{location}, |
769 |
%arg, |
770 |
recurse => $recurse - 1, |
771 |
Redirect => [$_[0], \%hdr], |
772 |
$cb); |
773 |
} else { |
774 |
$cb->($_[0], \%hdr); |
775 |
} |
776 |
}; |
777 |
|
778 |
$ae_error = 597; # body phase |
779 |
|
780 |
my $len = $hdr{"content-length"}; |
781 |
|
782 |
# body handling, many different code paths |
783 |
# - no body expected |
784 |
# - want_body_handle |
785 |
# - te chunked |
786 |
# - 2x length known (with or without on_body) |
787 |
# - 2x length not known (with or without on_body) |
788 |
if (!$redirect && $arg{on_header} && !$arg{on_header}(\%hdr)) { |
789 |
$finish->(undef, 598 => "Request cancelled by on_header"); |
790 |
} elsif ( |
791 |
$hdr{Status} =~ /^(?:1..|204|205|304)$/ |
792 |
or $method eq "HEAD" |
793 |
or (defined $len && $len == 0) # == 0, not !, because "0 " is true |
794 |
) { |
795 |
# no body |
796 |
$finish->("", undef, undef, 1); |
797 |
|
798 |
} elsif (!$redirect && $arg{want_body_handle}) { |
799 |
$_[0]->on_eof (undef); |
800 |
$_[0]->on_error (undef); |
801 |
$_[0]->on_read (undef); |
802 |
|
803 |
$finish->(delete $state{handle}); |
804 |
|
805 |
} elsif ($hdr{"transfer-encoding"} =~ /\bchunked\b/i) { |
806 |
my $cl = 0; |
807 |
my $body = undef; |
808 |
my $on_body = $arg{on_body} || sub { $body .= shift; 1 }; |
809 |
|
810 |
$state{read_chunk} = sub { |
811 |
$_[1] =~ /^([0-9a-fA-F]+)/ |
812 |
or $finish->(undef, $ae_error => "Garbled chunked transfer encoding"); |
813 |
|
814 |
my $len = hex $1; |
815 |
|
816 |
if ($len) { |
817 |
$cl += $len; |
818 |
|
819 |
$_[0]->push_read (chunk => $len, sub { |
820 |
$on_body->($_[1], \%hdr) |
821 |
or return $finish->(undef, 598 => "Request cancelled by on_body"); |
822 |
|
823 |
$_[0]->push_read (line => sub { |
824 |
length $_[1] |
825 |
and return $finish->(undef, $ae_error => "Garbled chunked transfer encoding"); |
826 |
$_[0]->push_read (line => $state{read_chunk}); |
827 |
}); |
828 |
}); |
829 |
} else { |
830 |
$hdr{"content-length"} ||= $cl; |
831 |
|
832 |
$_[0]->push_read (line => $qr_nlnl, sub { |
833 |
if (length $_[1]) { |
834 |
for ("$_[1]") { |
835 |
y/\015//d; # weed out any \015, as they show up in the weirdest of places. |
836 |
|
837 |
my $hdr = parse_hdr |
838 |
or return $finish->(undef, $ae_error => "Garbled response trailers"); |
839 |
|
840 |
%hdr = (%hdr, %$hdr); |
841 |
} |
842 |
} |
843 |
|
844 |
$finish->($body, undef, undef, 1); |
845 |
}); |
846 |
} |
847 |
}; |
848 |
|
849 |
$_[0]->push_read (line => $state{read_chunk}); |
850 |
|
851 |
} elsif ($arg{on_body}) { |
852 |
if (defined $len) { |
853 |
$_[0]->on_read (sub { |
854 |
$len -= length $_[0]{rbuf}; |
855 |
|
856 |
$arg{on_body}(delete $_[0]{rbuf}, \%hdr) |
857 |
or return $finish->(undef, 598 => "Request cancelled by on_body"); |
858 |
|
859 |
$len > 0 |
860 |
or $finish->("", undef, undef, 1); |
861 |
}); |
862 |
} else { |
863 |
$_[0]->on_eof (sub { |
864 |
$finish->(""); |
865 |
}); |
866 |
$_[0]->on_read (sub { |
867 |
$arg{on_body}(delete $_[0]{rbuf}, \%hdr) |
868 |
or $finish->(undef, 598 => "Request cancelled by on_body"); |
869 |
}); |
870 |
} |
871 |
} else { |
872 |
$_[0]->on_eof (undef); |
873 |
|
874 |
if (defined $len) { |
875 |
$_[0]->on_read (sub { |
876 |
$finish->((substr delete $_[0]{rbuf}, 0, $len, ""), undef, undef, 1) |
877 |
if $len <= length $_[0]{rbuf}; |
878 |
}); |
879 |
} else { |
880 |
$_[0]->on_error (sub { |
881 |
($! == Errno::EPIPE || !$!) |
882 |
? $finish->(delete $_[0]{rbuf}) |
883 |
: $finish->(undef, $ae_error => $_[2]); |
884 |
}); |
885 |
$_[0]->on_read (sub { }); |
886 |
} |
887 |
} |
888 |
}; |
889 |
|
890 |
$state{handle}->push_read (line => $qr_nlnl, $state{read_response}); |
891 |
}; |
892 |
|
893 |
my $connect_cb = sub { |
894 |
$state{fh} = shift |
895 |
or do { |
896 |
my $err = "$!"; |
897 |
%state = (); |
898 |
return $cb->(undef, { @pseudo, Status => $ae_error, Reason => $err }); |
899 |
}; |
900 |
|
901 |
return unless delete $state{connect_guard}; |
902 |
|
903 |
# get handle |
904 |
$state{handle} = new AnyEvent::Handle |
905 |
fh => $state{fh}, |
906 |
peername => $rhost, |
907 |
tls_ctx => $arg{tls_ctx}, |
908 |
# these need to be reconfigured on keepalive handles |
909 |
timeout => $timeout, |
910 |
on_error => sub { |
911 |
%state = (); |
912 |
$cb->(undef, { @pseudo, Status => $ae_error, Reason => $_[2] }); |
913 |
}, |
914 |
on_eof => sub { |
915 |
%state = (); |
916 |
$cb->(undef, { @pseudo, Status => $ae_error, Reason => "Unexpected end-of-file" }); |
917 |
}, |
918 |
; |
919 |
|
920 |
# limit the number of persistent connections |
921 |
# keepalive not yet supported |
922 |
# if ($KA_COUNT{$_[1]} < $MAX_PERSISTENT_PER_HOST) { |
923 |
# ++$KA_COUNT{$_[1]}; |
924 |
# $state{handle}{ka_count_guard} = AnyEvent::Util::guard { |
925 |
# --$KA_COUNT{$_[1]} |
926 |
# }; |
927 |
# $hdr{connection} = "keep-alive"; |
928 |
# } |
929 |
|
930 |
$state{handle}->starttls ("connect") if $rscheme eq "https"; |
931 |
|
932 |
# now handle proxy-CONNECT method |
933 |
if ($proxy && $uscheme eq "https") { |
934 |
# oh dear, we have to wrap it into a connect request |
935 |
|
936 |
# maybe re-use $uauthority with patched port? |
937 |
$state{handle}->push_write ("CONNECT $uhost:$uport HTTP/1.0\015\012Host: $uhost\015\012\015\012"); |
938 |
$state{handle}->push_read (line => $qr_nlnl, sub { |
939 |
$_[1] =~ /^HTTP\/([0-9\.]+) \s+ ([0-9]{3}) (?: \s+ ([^\015\012]*) )?/ix |
940 |
or return (%state = (), $cb->(undef, { @pseudo, Status => 599, Reason => "Invalid proxy connect response ($_[1])" })); |
941 |
|
942 |
if ($2 == 200) { |
943 |
$rpath = $upath; |
944 |
$handle_actual_request->(); |
945 |
} else { |
946 |
%state = (); |
947 |
$cb->(undef, { @pseudo, Status => $2, Reason => $3 }); |
948 |
} |
949 |
}); |
950 |
} else { |
951 |
$handle_actual_request->(); |
952 |
} |
953 |
}; |
954 |
|
955 |
my $tcp_connect = $arg{tcp_connect} |
956 |
|| do { require AnyEvent::Socket; \&AnyEvent::Socket::tcp_connect }; |
957 |
|
958 |
$state{connect_guard} = $tcp_connect->($rhost, $rport, $connect_cb, $arg{on_prepare} || sub { $timeout }); |
959 |
}; |
960 |
|
961 |
defined wantarray && AnyEvent::Util::guard { %state = () } |
962 |
} |
963 |
|
964 |
sub http_get($@) { |
965 |
unshift @_, "GET"; |
966 |
&http_request |
967 |
} |
968 |
|
969 |
sub http_head($@) { |
970 |
unshift @_, "HEAD"; |
971 |
&http_request |
972 |
} |
973 |
|
974 |
sub http_post($$@) { |
975 |
my $url = shift; |
976 |
unshift @_, "POST", $url, "body"; |
977 |
&http_request |
978 |
} |
979 |
|
980 |
=back |
981 |
|
982 |
=head2 DNS CACHING |
983 |
|
984 |
AnyEvent::HTTP uses the AnyEvent::Socket::tcp_connect function for |
985 |
the actual connection, which in turn uses AnyEvent::DNS to resolve |
986 |
hostnames. The latter is a simple stub resolver and does no caching |
987 |
on its own. If you want DNS caching, you currently have to provide |
988 |
your own default resolver (by storing a suitable resolver object in |
989 |
C<$AnyEvent::DNS::RESOLVER>). |
990 |
|
991 |
=head2 GLOBAL FUNCTIONS AND VARIABLES |
992 |
|
993 |
=over 4 |
994 |
|
995 |
=item AnyEvent::HTTP::set_proxy "proxy-url" |
996 |
|
997 |
Sets the default proxy server to use. The proxy-url must begin with a |
998 |
string of the form C<http://host:port> (optionally C<https:...>), croaks |
999 |
otherwise. |
1000 |
|
1001 |
To clear an already-set proxy, use C<undef>. |
1002 |
|
1003 |
=item AnyEvent::HTTP::cookie_jar_expire $jar[, $session_end] |
1004 |
|
1005 |
Remove all cookies from the cookie jar that have been expired. If |
1006 |
C<$session_end> is given and true, then additionally remove all session |
1007 |
cookies. |
1008 |
|
1009 |
You should call this function (with a true C<$session_end>) before you |
1010 |
save cookies to disk, and you should call this function after loading them |
1011 |
again. If you have a long-running program you can additonally call this |
1012 |
function from time to time. |
1013 |
|
1014 |
A cookie jar is initially an empty hash-reference that is managed by this |
1015 |
module. It's format is subject to change, but currently it is like this: |
1016 |
|
1017 |
The key C<version> has to contain C<1>, otherwise the hash gets |
1018 |
emptied. All other keys are hostnames or IP addresses pointing to |
1019 |
hash-references. The key for these inner hash references is the |
1020 |
server path for which this cookie is meant, and the values are again |
1021 |
hash-references. The keys of those hash-references is the cookie name, and |
1022 |
the value, you guessed it, is another hash-reference, this time with the |
1023 |
key-value pairs from the cookie, except for C<expires> and C<max-age>, |
1024 |
which have been replaced by a C<_expires> key that contains the cookie |
1025 |
expiry timestamp. |
1026 |
|
1027 |
Here is an example of a cookie jar with a single cookie, so you have a |
1028 |
chance of understanding the above paragraph: |
1029 |
|
1030 |
{ |
1031 |
version => 1, |
1032 |
"10.0.0.1" => { |
1033 |
"/" => { |
1034 |
"mythweb_id" => { |
1035 |
_expires => 1293917923, |
1036 |
value => "ooRung9dThee3ooyXooM1Ohm", |
1037 |
}, |
1038 |
}, |
1039 |
}, |
1040 |
} |
1041 |
|
1042 |
=item $date = AnyEvent::HTTP::format_date $timestamp |
1043 |
|
1044 |
Takes a POSIX timestamp (seconds since the epoch) and formats it as a HTTP |
1045 |
Date (RFC 2616). |
1046 |
|
1047 |
=item $timestamp = AnyEvent::HTTP::parse_date $date |
1048 |
|
1049 |
Takes a HTTP Date (RFC 2616) or a Cookie date (netscape cookie spec) or a |
1050 |
bunch of minor variations of those, and returns the corresponding POSIX |
1051 |
timestamp, or C<undef> if the date cannot be parsed. |
1052 |
|
1053 |
=item $AnyEvent::HTTP::MAX_RECURSE |
1054 |
|
1055 |
The default value for the C<recurse> request parameter (default: C<10>). |
1056 |
|
1057 |
=item $AnyEvent::HTTP::USERAGENT |
1058 |
|
1059 |
The default value for the C<User-Agent> header (the default is |
1060 |
C<Mozilla/5.0 (compatible; U; AnyEvent-HTTP/$VERSION; +http://software.schmorp.de/pkg/AnyEvent)>). |
1061 |
|
1062 |
=item $AnyEvent::HTTP::MAX_PER_HOST |
1063 |
|
1064 |
The maximum number of concurrent connections to the same host (identified |
1065 |
by the hostname). If the limit is exceeded, then the additional requests |
1066 |
are queued until previous connections are closed. |
1067 |
|
1068 |
The default value for this is C<4>, and it is highly advisable to not |
1069 |
increase it. |
1070 |
|
1071 |
=item $AnyEvent::HTTP::ACTIVE |
1072 |
|
1073 |
The number of active connections. This is not the number of currently |
1074 |
running requests, but the number of currently open and non-idle TCP |
1075 |
connections. This number of can be useful for load-leveling. |
1076 |
|
1077 |
=back |
1078 |
|
1079 |
=cut |
1080 |
|
1081 |
our @month = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec); |
1082 |
our @weekday = qw(Sun Mon Tue Wed Thu Fri Sat); |
1083 |
|
1084 |
sub format_date($) { |
1085 |
my ($time) = @_; |
1086 |
|
1087 |
# RFC 822/1123 format |
1088 |
my ($S, $M, $H, $mday, $mon, $year, $wday, $yday, undef) = gmtime $time; |
1089 |
|
1090 |
sprintf "%s, %02d %s %04d %02d:%02d:%02d GMT", |
1091 |
$weekday[$wday], $mday, $month[$mon], $year + 1900, |
1092 |
$H, $M, $S; |
1093 |
} |
1094 |
|
1095 |
sub parse_date($) { |
1096 |
my ($date) = @_; |
1097 |
|
1098 |
my ($d, $m, $y, $H, $M, $S); |
1099 |
|
1100 |
if ($date =~ /^[A-Z][a-z][a-z]+, ([0-9][0-9]?)[\- ]([A-Z][a-z][a-z])[\- ]([0-9][0-9][0-9][0-9]) ([0-9][0-9]?):([0-9][0-9]?):([0-9][0-9]?) GMT$/) { |
1101 |
# RFC 822/1123, required by RFC 2616 (with " ") |
1102 |
# cookie dates (with "-") |
1103 |
|
1104 |
($d, $m, $y, $H, $M, $S) = ($1, $2, $3, $4, $5, $6); |
1105 |
|
1106 |
} elsif ($date =~ /^[A-Z][a-z][a-z]+, ([0-9][0-9]?)-([A-Z][a-z][a-z])-([0-9][0-9]) ([0-9][0-9]?):([0-9][0-9]?):([0-9][0-9]?) GMT$/) { |
1107 |
# RFC 850 |
1108 |
($d, $m, $y, $H, $M, $S) = ($1, $2, $3 < 69 ? $3 + 2000 : $3 + 1900, $4, $5, $6); |
1109 |
|
1110 |
} elsif ($date =~ /^[A-Z][a-z][a-z]+ ([A-Z][a-z][a-z]) ([0-9 ]?[0-9]) ([0-9][0-9]?):([0-9][0-9]?):([0-9][0-9]?) ([0-9][0-9][0-9][0-9])$/) { |
1111 |
# ISO C's asctime |
1112 |
($d, $m, $y, $H, $M, $S) = ($2, $1, $6, $3, $4, $5); |
1113 |
} |
1114 |
# other formats fail in the loop below |
1115 |
|
1116 |
for (0..11) { |
1117 |
if ($m eq $month[$_]) { |
1118 |
require Time::Local; |
1119 |
return Time::Local::timegm ($S, $M, $H, $d, $_, $y); |
1120 |
} |
1121 |
} |
1122 |
|
1123 |
undef |
1124 |
} |
1125 |
|
1126 |
sub set_proxy($) { |
1127 |
if (length $_[0]) { |
1128 |
$_[0] =~ m%^(https?):// ([^:/]+) (?: : (\d*) )?%ix |
1129 |
or Carp::croak "$_[0]: invalid proxy URL"; |
1130 |
$PROXY = [$2, $3 || 3128, $1] |
1131 |
} else { |
1132 |
undef $PROXY; |
1133 |
} |
1134 |
} |
1135 |
|
1136 |
# initialise proxy from environment |
1137 |
eval { |
1138 |
set_proxy $ENV{http_proxy}; |
1139 |
}; |
1140 |
|
1141 |
=head2 SOCKS PROXIES |
1142 |
|
1143 |
Socks proxies are not directly supported by AnyEvent::HTTP. You can |
1144 |
compile your perl to support socks, or use an external program such as |
1145 |
F<socksify> (dante) or F<tsocks> to make your program use a socks proxy |
1146 |
transparently. |
1147 |
|
1148 |
Alternatively, for AnyEvent::HTTP only, you can use your own |
1149 |
C<tcp_connect> function that does the proxy handshake - here is an example |
1150 |
that works with socks4a proxies: |
1151 |
|
1152 |
use Errno; |
1153 |
use AnyEvent::Util; |
1154 |
use AnyEvent::Socket; |
1155 |
use AnyEvent::Handle; |
1156 |
|
1157 |
# host, port and username of/for your socks4a proxy |
1158 |
my $socks_host = "10.0.0.23"; |
1159 |
my $socks_port = 9050; |
1160 |
my $socks_user = ""; |
1161 |
|
1162 |
sub socks4a_connect { |
1163 |
my ($host, $port, $connect_cb, $prepare_cb) = @_; |
1164 |
|
1165 |
my $hdl = new AnyEvent::Handle |
1166 |
connect => [$socks_host, $socks_port], |
1167 |
on_prepare => sub { $prepare_cb->($_[0]{fh}) }, |
1168 |
on_error => sub { $connect_cb->() }, |
1169 |
; |
1170 |
|
1171 |
$hdl->push_write (pack "CCnNZ*Z*", 4, 1, $port, 1, $socks_user, $host); |
1172 |
|
1173 |
$hdl->push_read (chunk => 8, sub { |
1174 |
my ($hdl, $chunk) = @_; |
1175 |
my ($status, $port, $ipn) = unpack "xCna4", $chunk; |
1176 |
|
1177 |
if ($status == 0x5a) { |
1178 |
$connect_cb->($hdl->{fh}, (format_address $ipn) . ":$port"); |
1179 |
} else { |
1180 |
$! = Errno::ENXIO; $connect_cb->(); |
1181 |
} |
1182 |
}); |
1183 |
|
1184 |
$hdl |
1185 |
} |
1186 |
|
1187 |
Use C<socks4a_connect> instead of C<tcp_connect> when doing C<http_request>s, |
1188 |
possibly after switching off other proxy types: |
1189 |
|
1190 |
AnyEvent::HTTP::set_proxy undef; # usually you do not want other proxies |
1191 |
|
1192 |
http_get 'http://www.google.com', tcp_connect => \&socks4a_connect, sub { |
1193 |
my ($data, $headers) = @_; |
1194 |
... |
1195 |
}; |
1196 |
|
1197 |
=head1 SEE ALSO |
1198 |
|
1199 |
L<AnyEvent>. |
1200 |
|
1201 |
=head1 AUTHOR |
1202 |
|
1203 |
Marc Lehmann <schmorp@schmorp.de> |
1204 |
http://home.schmorp.de/ |
1205 |
|
1206 |
With many thanks to Дмитрий Шалашов, who provided countless |
1207 |
testcases and bugreports. |
1208 |
|
1209 |
=cut |
1210 |
|
1211 |
1 |
1212 |
|