1 |
=head1 NAME |
2 |
|
3 |
AnyEvent::HTTP - simple but non-blocking HTTP/HTTPS client |
4 |
|
5 |
=head1 SYNOPSIS |
6 |
|
7 |
use AnyEvent::HTTP; |
8 |
|
9 |
http_get "http://www.nethype.de/", sub { print $_[1] }; |
10 |
|
11 |
# ... do something else here |
12 |
|
13 |
=head1 DESCRIPTION |
14 |
|
15 |
This module is an L<AnyEvent> user, you need to make sure that you use and |
16 |
run a supported event loop. |
17 |
|
18 |
This module implements a simple, stateless and non-blocking HTTP |
19 |
client. It supports GET, POST and other request methods, cookies and more, |
20 |
all on a very low level. It can follow redirects supports proxies and |
21 |
automatically limits the number of connections to the values specified in |
22 |
the RFC. |
23 |
|
24 |
It should generally be a "good client" that is enough for most HTTP |
25 |
tasks. Simple tasks should be simple, but complex tasks should still be |
26 |
possible as the user retains control over request and response headers. |
27 |
|
28 |
The caller is responsible for authentication management, cookies (if |
29 |
the simplistic implementation in this module doesn't suffice), referer |
30 |
and other high-level protocol details for which this module offers only |
31 |
limited support. |
32 |
|
33 |
=head2 METHODS |
34 |
|
35 |
=over 4 |
36 |
|
37 |
=cut |
38 |
|
39 |
package AnyEvent::HTTP; |
40 |
|
41 |
use common::sense; |
42 |
|
43 |
use Errno (); |
44 |
|
45 |
use AnyEvent 5.0 (); |
46 |
use AnyEvent::Util (); |
47 |
use AnyEvent::Handle (); |
48 |
|
49 |
use base Exporter::; |
50 |
|
51 |
our $VERSION = '1.5'; |
52 |
|
53 |
our @EXPORT = qw(http_get http_post http_head http_request); |
54 |
|
55 |
our $USERAGENT = "Mozilla/5.0 (compatible; U; AnyEvent-HTTP/$VERSION; +http://software.schmorp.de/pkg/AnyEvent)"; |
56 |
our $MAX_RECURSE = 10; |
57 |
our $MAX_PERSISTENT = 8; |
58 |
our $PERSISTENT_TIMEOUT = 2; |
59 |
our $TIMEOUT = 300; |
60 |
|
61 |
# changing these is evil |
62 |
our $MAX_PERSISTENT_PER_HOST = 2; |
63 |
our $MAX_PER_HOST = 4; |
64 |
|
65 |
our $PROXY; |
66 |
our $ACTIVE = 0; |
67 |
|
68 |
my %KA_COUNT; # number of open keep-alive connections per host |
69 |
my %CO_SLOT; # number of open connections, and wait queue, per host |
70 |
|
71 |
=item http_get $url, key => value..., $cb->($data, $headers) |
72 |
|
73 |
Executes an HTTP-GET request. See the http_request function for details on |
74 |
additional parameters and the return value. |
75 |
|
76 |
=item http_head $url, key => value..., $cb->($data, $headers) |
77 |
|
78 |
Executes an HTTP-HEAD request. See the http_request function for details |
79 |
on additional parameters and the return value. |
80 |
|
81 |
=item http_post $url, $body, key => value..., $cb->($data, $headers) |
82 |
|
83 |
Executes an HTTP-POST request with a request body of C<$body>. See the |
84 |
http_request function for details on additional parameters and the return |
85 |
value. |
86 |
|
87 |
=item http_request $method => $url, key => value..., $cb->($data, $headers) |
88 |
|
89 |
Executes a HTTP request of type C<$method> (e.g. C<GET>, C<POST>). The URL |
90 |
must be an absolute http or https URL. |
91 |
|
92 |
When called in void context, nothing is returned. In other contexts, |
93 |
C<http_request> returns a "cancellation guard" - you have to keep the |
94 |
object at least alive until the callback get called. If the object gets |
95 |
destroyed before the callback is called, the request will be cancelled. |
96 |
|
97 |
The callback will be called with the response body data as first argument |
98 |
(or C<undef> if an error occured), and a hash-ref with response headers |
99 |
(and trailers) as second argument. |
100 |
|
101 |
All the headers in that hash are lowercased. In addition to the response |
102 |
headers, the "pseudo-headers" (uppercase to avoid clashing with possible |
103 |
response headers) C<HTTPVersion>, C<Status> and C<Reason> contain the |
104 |
three parts of the HTTP Status-Line of the same name. If an error occurs |
105 |
during the body phase of a request, then the original C<Status> and |
106 |
C<Reason> values from the header are available as C<OrigStatus> and |
107 |
C<OrigReason>. |
108 |
|
109 |
The pseudo-header C<URL> contains the actual URL (which can differ from |
110 |
the requested URL when following redirects - for example, you might get |
111 |
an error that your URL scheme is not supported even though your URL is a |
112 |
valid http URL because it redirected to an ftp URL, in which case you can |
113 |
look at the URL pseudo header). |
114 |
|
115 |
The pseudo-header C<Redirect> only exists when the request was a result |
116 |
of an internal redirect. In that case it is an array reference with |
117 |
the C<($data, $headers)> from the redirect response. Note that this |
118 |
response could in turn be the result of a redirect itself, and C<< |
119 |
$headers->{Redirect}[1]{Redirect} >> will then contain the original |
120 |
response, and so on. |
121 |
|
122 |
If the server sends a header multiple times, then their contents will be |
123 |
joined together with a comma (C<,>), as per the HTTP spec. |
124 |
|
125 |
If an internal error occurs, such as not being able to resolve a hostname, |
126 |
then C<$data> will be C<undef>, C<< $headers->{Status} >> will be |
127 |
C<590>-C<599> and the C<Reason> pseudo-header will contain an error |
128 |
message. Currently the following status codes are used: |
129 |
|
130 |
=over 4 |
131 |
|
132 |
=item 595 - errors during connection etsbalishment, proxy handshake. |
133 |
|
134 |
=item 596 - errors during TLS negotiation, request sending and header processing. |
135 |
|
136 |
=item 597 - errors during body receiving or processing. |
137 |
|
138 |
=item 598 - user aborted request via C<on_header> or C<on_body>. |
139 |
|
140 |
=item 599 - other, usually nonretryable, errors (garbled URL etc.). |
141 |
|
142 |
=back |
143 |
|
144 |
A typical callback might look like this: |
145 |
|
146 |
sub { |
147 |
my ($body, $hdr) = @_; |
148 |
|
149 |
if ($hdr->{Status} =~ /^2/) { |
150 |
... everything should be ok |
151 |
} else { |
152 |
print "error, $hdr->{Status} $hdr->{Reason}\n"; |
153 |
} |
154 |
} |
155 |
|
156 |
Additional parameters are key-value pairs, and are fully optional. They |
157 |
include: |
158 |
|
159 |
=over 4 |
160 |
|
161 |
=item recurse => $count (default: $MAX_RECURSE) |
162 |
|
163 |
Whether to recurse requests or not, e.g. on redirects, authentication |
164 |
retries and so on, and how often to do so. |
165 |
|
166 |
=item headers => hashref |
167 |
|
168 |
The request headers to use. Currently, C<http_request> may provide its own |
169 |
C<Host:>, C<Content-Length:>, C<Connection:> and C<Cookie:> headers and |
170 |
will provide defaults at least for C<TE:>, C<Referer:> and C<User-Agent:> |
171 |
(this can be suppressed by using C<undef> for these headers in which case |
172 |
they won't be sent at all). |
173 |
|
174 |
=item timeout => $seconds |
175 |
|
176 |
The time-out to use for various stages - each connect attempt will reset |
177 |
the timeout, as will read or write activity, i.e. this is not an overall |
178 |
timeout. |
179 |
|
180 |
Default timeout is 5 minutes. |
181 |
|
182 |
=item proxy => [$host, $port[, $scheme]] or undef |
183 |
|
184 |
Use the given http proxy for all requests. If not specified, then the |
185 |
default proxy (as specified by C<$ENV{http_proxy}>) is used. |
186 |
|
187 |
C<$scheme> must be either missing, C<http> for HTTP or C<https> for |
188 |
HTTPS. |
189 |
|
190 |
=item body => $string |
191 |
|
192 |
The request body, usually empty. Will be sent as-is (future versions of |
193 |
this module might offer more options). |
194 |
|
195 |
=item cookie_jar => $hash_ref |
196 |
|
197 |
Passing this parameter enables (simplified) cookie-processing, loosely |
198 |
based on the original netscape specification. |
199 |
|
200 |
The C<$hash_ref> must be an (initially empty) hash reference which |
201 |
will get updated automatically. It is possible to save the cookie jar |
202 |
to persistent storage with something like JSON or Storable - see the |
203 |
C<AnyEvent::HTTP::cookie_jar_expire> function if you wish to remove |
204 |
expired or session-only cookies, and also for documentation on the format |
205 |
of the cookie jar. |
206 |
|
207 |
Note that this cookie implementation is not meant to be complete. If |
208 |
you want complete cookie management you have to do that on your |
209 |
own. C<cookie_jar> is meant as a quick fix to get most cookie-using sites |
210 |
working. Cookies are a privacy disaster, do not use them unless required |
211 |
to. |
212 |
|
213 |
When cookie processing is enabled, the C<Cookie:> and C<Set-Cookie:> |
214 |
headers will be set and handled by this module, otherwise they will be |
215 |
left untouched. |
216 |
|
217 |
=item tls_ctx => $scheme | $tls_ctx |
218 |
|
219 |
Specifies the AnyEvent::TLS context to be used for https connections. This |
220 |
parameter follows the same rules as the C<tls_ctx> parameter to |
221 |
L<AnyEvent::Handle>, but additionally, the two strings C<low> or |
222 |
C<high> can be specified, which give you a predefined low-security (no |
223 |
verification, highest compatibility) and high-security (CA and common-name |
224 |
verification) TLS context. |
225 |
|
226 |
The default for this option is C<low>, which could be interpreted as "give |
227 |
me the page, no matter what". |
228 |
|
229 |
=item on_prepare => $callback->($fh) |
230 |
|
231 |
In rare cases you need to "tune" the socket before it is used to |
232 |
connect (for exmaple, to bind it on a given IP address). This parameter |
233 |
overrides the prepare callback passed to C<AnyEvent::Socket::tcp_connect> |
234 |
and behaves exactly the same way (e.g. it has to provide a |
235 |
timeout). See the description for the C<$prepare_cb> argument of |
236 |
C<AnyEvent::Socket::tcp_connect> for details. |
237 |
|
238 |
=item tcp_connect => $callback->($host, $service, $connect_cb, $prepare_cb) |
239 |
|
240 |
In even rarer cases you want total control over how AnyEvent::HTTP |
241 |
establishes connections. Normally it uses L<AnyEvent::Socket::tcp_connect> |
242 |
to do this, but you can provide your own C<tcp_connect> function - |
243 |
obviously, it has to follow the same calling conventions, except that it |
244 |
may always return a connection guard object. |
245 |
|
246 |
There are probably lots of weird uses for this function, starting from |
247 |
tracing the hosts C<http_request> actually tries to connect, to (inexact |
248 |
but fast) host => IP address caching or even socks protocol support. |
249 |
|
250 |
=item on_header => $callback->($headers) |
251 |
|
252 |
When specified, this callback will be called with the header hash as soon |
253 |
as headers have been successfully received from the remote server (not on |
254 |
locally-generated errors). |
255 |
|
256 |
It has to return either true (in which case AnyEvent::HTTP will continue), |
257 |
or false, in which case AnyEvent::HTTP will cancel the download (and call |
258 |
the finish callback with an error code of C<598>). |
259 |
|
260 |
This callback is useful, among other things, to quickly reject unwanted |
261 |
content, which, if it is supposed to be rare, can be faster than first |
262 |
doing a C<HEAD> request. |
263 |
|
264 |
The downside is that cancelling the request makes it impossible to re-use |
265 |
the connection. Also, the C<on_header> callback will not receive any |
266 |
trailer (headers sent after the response body). |
267 |
|
268 |
Example: cancel the request unless the content-type is "text/html". |
269 |
|
270 |
on_header => sub { |
271 |
$_[0]{"content-type"} =~ /^text\/html\s*(?:;|$)/ |
272 |
}, |
273 |
|
274 |
=item on_body => $callback->($partial_body, $headers) |
275 |
|
276 |
When specified, all body data will be passed to this callback instead of |
277 |
to the completion callback. The completion callback will get the empty |
278 |
string instead of the body data. |
279 |
|
280 |
It has to return either true (in which case AnyEvent::HTTP will continue), |
281 |
or false, in which case AnyEvent::HTTP will cancel the download (and call |
282 |
the completion callback with an error code of C<598>). |
283 |
|
284 |
The downside to cancelling the request is that it makes it impossible to |
285 |
re-use the connection. |
286 |
|
287 |
This callback is useful when the data is too large to be held in memory |
288 |
(so the callback writes it to a file) or when only some information should |
289 |
be extracted, or when the body should be processed incrementally. |
290 |
|
291 |
It is usually preferred over doing your own body handling via |
292 |
C<want_body_handle>, but in case of streaming APIs, where HTTP is |
293 |
only used to create a connection, C<want_body_handle> is the better |
294 |
alternative, as it allows you to install your own event handler, reducing |
295 |
resource usage. |
296 |
|
297 |
=item want_body_handle => $enable |
298 |
|
299 |
When enabled (default is disabled), the behaviour of AnyEvent::HTTP |
300 |
changes considerably: after parsing the headers, and instead of |
301 |
downloading the body (if any), the completion callback will be |
302 |
called. Instead of the C<$body> argument containing the body data, the |
303 |
callback will receive the L<AnyEvent::Handle> object associated with the |
304 |
connection. In error cases, C<undef> will be passed. When there is no body |
305 |
(e.g. status C<304>), the empty string will be passed. |
306 |
|
307 |
The handle object might or might not be in TLS mode, might be connected to |
308 |
a proxy, be a persistent connection etc., and configured in unspecified |
309 |
ways. The user is responsible for this handle (it will not be used by this |
310 |
module anymore). |
311 |
|
312 |
This is useful with some push-type services, where, after the initial |
313 |
headers, an interactive protocol is used (typical example would be the |
314 |
push-style twitter API which starts a JSON/XML stream). |
315 |
|
316 |
If you think you need this, first have a look at C<on_body>, to see if |
317 |
that doesn't solve your problem in a better way. |
318 |
|
319 |
=back |
320 |
|
321 |
Example: do a simple HTTP GET request for http://www.nethype.de/ and print |
322 |
the response body. |
323 |
|
324 |
http_request GET => "http://www.nethype.de/", sub { |
325 |
my ($body, $hdr) = @_; |
326 |
print "$body\n"; |
327 |
}; |
328 |
|
329 |
Example: do a HTTP HEAD request on https://www.google.com/, use a |
330 |
timeout of 30 seconds. |
331 |
|
332 |
http_request |
333 |
GET => "https://www.google.com", |
334 |
timeout => 30, |
335 |
sub { |
336 |
my ($body, $hdr) = @_; |
337 |
use Data::Dumper; |
338 |
print Dumper $hdr; |
339 |
} |
340 |
; |
341 |
|
342 |
Example: do another simple HTTP GET request, but immediately try to |
343 |
cancel it. |
344 |
|
345 |
my $request = http_request GET => "http://www.nethype.de/", sub { |
346 |
my ($body, $hdr) = @_; |
347 |
print "$body\n"; |
348 |
}; |
349 |
|
350 |
undef $request; |
351 |
|
352 |
=cut |
353 |
|
354 |
sub _slot_schedule; |
355 |
sub _slot_schedule($) { |
356 |
my $host = shift; |
357 |
|
358 |
while ($CO_SLOT{$host}[0] < $MAX_PER_HOST) { |
359 |
if (my $cb = shift @{ $CO_SLOT{$host}[1] }) { |
360 |
# somebody wants that slot |
361 |
++$CO_SLOT{$host}[0]; |
362 |
++$ACTIVE; |
363 |
|
364 |
$cb->(AnyEvent::Util::guard { |
365 |
--$ACTIVE; |
366 |
--$CO_SLOT{$host}[0]; |
367 |
_slot_schedule $host; |
368 |
}); |
369 |
} else { |
370 |
# nobody wants the slot, maybe we can forget about it |
371 |
delete $CO_SLOT{$host} unless $CO_SLOT{$host}[0]; |
372 |
last; |
373 |
} |
374 |
} |
375 |
} |
376 |
|
377 |
# wait for a free slot on host, call callback |
378 |
sub _get_slot($$) { |
379 |
push @{ $CO_SLOT{$_[0]}[1] }, $_[1]; |
380 |
|
381 |
_slot_schedule $_[0]; |
382 |
} |
383 |
|
384 |
############################################################################# |
385 |
|
386 |
# expire cookies |
387 |
sub cookie_jar_expire($;$) { |
388 |
my ($jar, $session_end) = @_; |
389 |
|
390 |
%$jar = () if $jar->{version} != 1; |
391 |
|
392 |
my $anow = AE::now; |
393 |
|
394 |
while (my ($chost, $paths) = each %$jar) { |
395 |
next unless ref $paths; |
396 |
|
397 |
while (my ($cpath, $cookies) = each %$paths) { |
398 |
while (my ($cookie, $kv) = each %$cookies) { |
399 |
if (exists $kv->{_expires}) { |
400 |
delete $cookies->{$cookie} |
401 |
if $anow > $kv->{_expires}; |
402 |
} elsif ($session_end) { |
403 |
delete $cookies->{$cookie}; |
404 |
} |
405 |
} |
406 |
|
407 |
delete $paths->{$cpath} |
408 |
unless %$cookies; |
409 |
} |
410 |
|
411 |
delete $jar->{$chost} |
412 |
unless %$paths; |
413 |
} |
414 |
} |
415 |
|
416 |
# extract cookies from jar |
417 |
sub cookie_jar_extract($$$$) { |
418 |
my ($jar, $uscheme, $uhost, $upath) = @_; |
419 |
|
420 |
%$jar = () if $jar->{version} != 1; |
421 |
|
422 |
my @cookies; |
423 |
|
424 |
while (my ($chost, $paths) = each %$jar) { |
425 |
next unless ref $paths; |
426 |
|
427 |
if ($chost =~ /^\./) { |
428 |
next unless $chost eq substr $uhost, -length $chost; |
429 |
} elsif ($chost =~ /\./) { |
430 |
next unless $chost eq $uhost; |
431 |
} else { |
432 |
next; |
433 |
} |
434 |
|
435 |
while (my ($cpath, $cookies) = each %$paths) { |
436 |
next unless $cpath eq substr $upath, 0, length $cpath; |
437 |
|
438 |
while (my ($cookie, $kv) = each %$cookies) { |
439 |
next if $uscheme ne "https" && exists $kv->{secure}; |
440 |
|
441 |
if (exists $kv->{_expires} and AE::now > $kv->{_expires}) { |
442 |
delete $cookies->{$cookie}; |
443 |
next; |
444 |
} |
445 |
|
446 |
my $value = $kv->{value}; |
447 |
|
448 |
if ($value =~ /[=;,[:space:]]/) { |
449 |
$value =~ s/([\\"])/\\$1/g; |
450 |
$value = "\"$value\""; |
451 |
} |
452 |
|
453 |
push @cookies, "$cookie=$value"; |
454 |
} |
455 |
} |
456 |
} |
457 |
|
458 |
\@cookies |
459 |
} |
460 |
|
461 |
# parse set_cookie header into jar |
462 |
sub cookie_jar_set_cookie($$$$) { |
463 |
my ($jar, $set_cookie, $uhost, $date) = @_; |
464 |
|
465 |
my $anow = int AE::now; |
466 |
my $snow; # server-now |
467 |
|
468 |
for ($set_cookie) { |
469 |
# parse NAME=VALUE |
470 |
my @kv; |
471 |
|
472 |
# expires is not http-compliant in the original cookie-spec, |
473 |
# we support the official date format and some extensions |
474 |
while ( |
475 |
m{ |
476 |
\G\s* |
477 |
(?: |
478 |
expires \s*=\s* ([A-Z][a-z][a-z]+,\ [^,;]+) |
479 |
| ([^=;,[:space:]]+) (?: \s*=\s* (?: "((?:[^\\"]+|\\.)*)" | ([^=;,[:space:]]*) ) )? |
480 |
) |
481 |
}gcxsi |
482 |
) { |
483 |
my $name = $2; |
484 |
my $value = $4; |
485 |
|
486 |
if (defined $1) { |
487 |
# expires |
488 |
$name = "expires"; |
489 |
$value = $1; |
490 |
} elsif (defined $3) { |
491 |
# quoted |
492 |
$value = $3; |
493 |
$value =~ s/\\(.)/$1/gs; |
494 |
} |
495 |
|
496 |
push @kv, lc $name, $value; |
497 |
|
498 |
last unless /\G\s*;/gc; |
499 |
} |
500 |
|
501 |
last unless @kv; |
502 |
|
503 |
my $name = shift @kv; |
504 |
my %kv = (value => shift @kv, @kv); |
505 |
|
506 |
if (exists $kv{"max-age"}) { |
507 |
$kv{_expires} = $anow + delete $kv{"max-age"}; |
508 |
} elsif (exists $kv{expires}) { |
509 |
$snow ||= parse_date ($date) || $anow; |
510 |
$kv{_expires} = $anow + (parse_date (delete $kv{expires}) - $snow); |
511 |
} else { |
512 |
delete $kv{_expires}; |
513 |
} |
514 |
|
515 |
my $cdom; |
516 |
my $cpath = (delete $kv{path}) || "/"; |
517 |
|
518 |
if (exists $kv{domain}) { |
519 |
$cdom = delete $kv{domain}; |
520 |
|
521 |
$cdom =~ s/^\.?/./; # make sure it starts with a "." |
522 |
|
523 |
next if $cdom =~ /\.$/; |
524 |
|
525 |
# this is not rfc-like and not netscape-like. go figure. |
526 |
my $ndots = $cdom =~ y/.//; |
527 |
next if $ndots < ($cdom =~ /\.[^.][^.]\.[^.][^.]$/ ? 3 : 2); |
528 |
} else { |
529 |
$cdom = $uhost; |
530 |
} |
531 |
|
532 |
# store it |
533 |
$jar->{version} = 1; |
534 |
$jar->{lc $cdom}{$cpath}{$name} = \%kv; |
535 |
|
536 |
redo if /\G\s*,/gc; |
537 |
} |
538 |
} |
539 |
|
540 |
# continue to parse $_ for headers and place them into the arg |
541 |
sub parse_hdr() { |
542 |
my %hdr; |
543 |
|
544 |
# things seen, not parsed: |
545 |
# p3pP="NON CUR OTPi OUR NOR UNI" |
546 |
|
547 |
$hdr{lc $1} .= ",$2" |
548 |
while /\G |
549 |
([^:\000-\037]*): |
550 |
[\011\040]* |
551 |
((?: [^\012]+ | \012[\011\040] )*) |
552 |
\012 |
553 |
/gxc; |
554 |
|
555 |
/\G$/ |
556 |
or return; |
557 |
|
558 |
# remove the "," prefix we added to all headers above |
559 |
substr $_, 0, 1, "" |
560 |
for values %hdr; |
561 |
|
562 |
\%hdr |
563 |
} |
564 |
|
565 |
our $qr_nlnl = qr{(?<![^\012])\015?\012}; |
566 |
|
567 |
our $TLS_CTX_LOW = { cache => 1, sslv2 => 1 }; |
568 |
our $TLS_CTX_HIGH = { cache => 1, verify => 1, verify_peername => "https" }; |
569 |
|
570 |
sub http_request($$@) { |
571 |
my $cb = pop; |
572 |
my ($method, $url, %arg) = @_; |
573 |
|
574 |
my %hdr; |
575 |
|
576 |
$arg{tls_ctx} = $TLS_CTX_LOW if $arg{tls_ctx} eq "low" || !exists $arg{tls_ctx}; |
577 |
$arg{tls_ctx} = $TLS_CTX_HIGH if $arg{tls_ctx} eq "high"; |
578 |
|
579 |
$method = uc $method; |
580 |
|
581 |
if (my $hdr = $arg{headers}) { |
582 |
while (my ($k, $v) = each %$hdr) { |
583 |
$hdr{lc $k} = $v; |
584 |
} |
585 |
} |
586 |
|
587 |
# pseudo headers for all subsequent responses |
588 |
my @pseudo = (URL => $url); |
589 |
push @pseudo, Redirect => delete $arg{Redirect} if exists $arg{Redirect}; |
590 |
|
591 |
my $recurse = exists $arg{recurse} ? delete $arg{recurse} : $MAX_RECURSE; |
592 |
|
593 |
return $cb->(undef, { @pseudo, Status => 599, Reason => "Too many redirections" }) |
594 |
if $recurse < 0; |
595 |
|
596 |
my $proxy = $arg{proxy} || $PROXY; |
597 |
my $timeout = $arg{timeout} || $TIMEOUT; |
598 |
|
599 |
my ($uscheme, $uauthority, $upath, $query, $fragment) = |
600 |
$url =~ m|(?:([^:/?#]+):)?(?://([^/?#]*))?([^?#]*)(?:(\?[^#]*))?(?:#(.*))?|; |
601 |
|
602 |
$uscheme = lc $uscheme; |
603 |
|
604 |
my $uport = $uscheme eq "http" ? 80 |
605 |
: $uscheme eq "https" ? 443 |
606 |
: return $cb->(undef, { @pseudo, Status => 599, Reason => "Only http and https URL schemes supported" }); |
607 |
|
608 |
$uauthority =~ /^(?: .*\@ )? ([^\@:]+) (?: : (\d+) )?$/x |
609 |
or return $cb->(undef, { @pseudo, Status => 599, Reason => "Unparsable URL" }); |
610 |
|
611 |
my $uhost = lc $1; |
612 |
$uport = $2 if defined $2; |
613 |
|
614 |
$hdr{host} = defined $2 ? "$uhost:$2" : "$uhost" |
615 |
unless exists $hdr{host}; |
616 |
|
617 |
$uhost =~ s/^\[(.*)\]$/$1/; |
618 |
$upath .= $query if length $query; |
619 |
|
620 |
$upath =~ s%^/?%/%; |
621 |
|
622 |
# cookie processing |
623 |
if (my $jar = $arg{cookie_jar}) { |
624 |
my $cookies = cookie_jar_extract $jar, $uscheme, $uhost, $upath; |
625 |
|
626 |
$hdr{cookie} = join "; ", @$cookies |
627 |
if @$cookies; |
628 |
} |
629 |
|
630 |
my ($rhost, $rport, $rscheme, $rpath); # request host, port, path |
631 |
|
632 |
if ($proxy) { |
633 |
($rpath, $rhost, $rport, $rscheme) = ($url, @$proxy); |
634 |
|
635 |
$rscheme = "http" unless defined $rscheme; |
636 |
|
637 |
# don't support https requests over https-proxy transport, |
638 |
# can't be done with tls as spec'ed, unless you double-encrypt. |
639 |
$rscheme = "http" if $uscheme eq "https" && $rscheme eq "https"; |
640 |
|
641 |
$rhost = lc $rhost; |
642 |
$rscheme = lc $rscheme; |
643 |
} else { |
644 |
($rhost, $rport, $rscheme, $rpath) = ($uhost, $uport, $uscheme, $upath); |
645 |
} |
646 |
|
647 |
# leave out fragment and query string, just a heuristic |
648 |
$hdr{referer} = "$uscheme://$uauthority$upath" unless exists $hdr{referer}; |
649 |
$hdr{"user-agent"} = $USERAGENT unless exists $hdr{"user-agent"}; |
650 |
|
651 |
$hdr{"content-length"} = length $arg{body} |
652 |
if length $arg{body} || $method ne "GET"; |
653 |
|
654 |
my $idempotent = $method =~ /^(?:GET|HEAD|PUT|DELETE|OPTIONS|TRACE)$/; |
655 |
|
656 |
# default value for keepalive is true iff the request is for an idempotent method |
657 |
my $keepalive = exists $arg{keepalive} |
658 |
? $arg{keepalive}*1 |
659 |
: $idempotent ? $PERSISTENT_TIMEOUT : 0; |
660 |
|
661 |
$hdr{connection} = ($keepalive ? "" : "close ") . "Te"; #1.1 |
662 |
$hdr{te} = "trailers" unless exists $hdr{te}; #1.1 |
663 |
|
664 |
my %state = (connect_guard => 1); |
665 |
|
666 |
my $ae_error = 595; # connecting |
667 |
|
668 |
# handle actual, non-tunneled, request |
669 |
my $handle_actual_request = sub { |
670 |
$ae_error = 596; # request phase |
671 |
|
672 |
$state{handle}->starttls ("connect") if $uscheme eq "https" && !exists $state{handle}{tls}; |
673 |
|
674 |
# send request |
675 |
$state{handle}->push_write ( |
676 |
"$method $rpath HTTP/1.1\015\012" |
677 |
. (join "", map "\u$_: $hdr{$_}\015\012", grep defined $hdr{$_}, keys %hdr) |
678 |
. "\015\012" |
679 |
. (delete $arg{body}) |
680 |
); |
681 |
|
682 |
# return if error occured during push_write() |
683 |
return unless %state; |
684 |
|
685 |
# reduce memory usage, save a kitten, also re-use it for the response headers. |
686 |
%hdr = (); |
687 |
|
688 |
# status line and headers |
689 |
$state{read_response} = sub { |
690 |
for ("$_[1]") { |
691 |
y/\015//d; # weed out any \015, as they show up in the weirdest of places. |
692 |
|
693 |
/^HTTP\/0*([0-9\.]+) \s+ ([0-9]{3}) (?: \s+ ([^\012]*) )? \012/gxci |
694 |
or return (%state = (), $cb->(undef, { @pseudo, Status => 599, Reason => "Invalid server response" })); |
695 |
|
696 |
# 100 Continue handling |
697 |
# should not happen as we don't send expect: 100-continue, |
698 |
# but we handle it just in case. |
699 |
# since we send the request body regardless, if we get an error |
700 |
# we are out of-sync, which we currently do NOT handle correctly. |
701 |
return $state{handle}->push_read (line => $qr_nlnl, $state{read_response}) |
702 |
if $2 eq 100; |
703 |
|
704 |
push @pseudo, |
705 |
HTTPVersion => $1, |
706 |
Status => $2, |
707 |
Reason => $3, |
708 |
; |
709 |
|
710 |
my $hdr = parse_hdr |
711 |
or return (%state = (), $cb->(undef, { @pseudo, Status => 599, Reason => "Garbled response headers" })); |
712 |
|
713 |
%hdr = (%$hdr, @pseudo); |
714 |
} |
715 |
|
716 |
# redirect handling |
717 |
# microsoft and other shitheads don't give a shit for following standards, |
718 |
# try to support some common forms of broken Location headers. |
719 |
if ($hdr{location} !~ /^(?: $ | [^:\/?\#]+ : )/x) { |
720 |
$hdr{location} =~ s/^\.\/+//; |
721 |
|
722 |
my $url = "$rscheme://$uhost:$uport"; |
723 |
|
724 |
unless ($hdr{location} =~ s/^\///) { |
725 |
$url .= $upath; |
726 |
$url =~ s/\/[^\/]*$//; |
727 |
} |
728 |
|
729 |
$hdr{location} = "$url/$hdr{location}"; |
730 |
} |
731 |
|
732 |
my $redirect; |
733 |
|
734 |
if ($recurse) { |
735 |
my $status = $hdr{Status}; |
736 |
|
737 |
# industry standard is to redirect POST as GET for |
738 |
# 301, 302 and 303, in contrast to HTTP/1.0 and 1.1. |
739 |
# also, the UA should ask the user for 301 and 307 and POST, |
740 |
# industry standard seems to be to simply follow. |
741 |
# we go with the industry standard. |
742 |
if ($status == 301 or $status == 302 or $status == 303) { |
743 |
# HTTP/1.1 is unclear on how to mutate the method |
744 |
$method = "GET" unless $method eq "HEAD"; |
745 |
$redirect = 1; |
746 |
} elsif ($status == 307) { |
747 |
$redirect = 1; |
748 |
} |
749 |
} |
750 |
|
751 |
my $finish = sub { # ($data, $err_status, $err_reason[, $keepalive]) |
752 |
my $may_keep_alive = $_[3]; |
753 |
|
754 |
$state{handle}->destroy if $state{handle}; |
755 |
%state = (); |
756 |
|
757 |
if (defined $_[1]) { |
758 |
$hdr{OrigStatus} = $hdr{Status}; $hdr{Status} = $_[1]; |
759 |
$hdr{OrigReason} = $hdr{Reason}; $hdr{Reason} = $_[2]; |
760 |
} |
761 |
|
762 |
# set-cookie processing |
763 |
if ($arg{cookie_jar}) { |
764 |
cookie_jar_set_cookie $arg{cookie_jar}, $hdr{"set-cookie"}, $uhost, $hdr{date}; |
765 |
} |
766 |
|
767 |
if ($redirect && exists $hdr{location}) { |
768 |
# we ignore any errors, as it is very common to receive |
769 |
# Content-Length != 0 but no actual body |
770 |
# we also access %hdr, as $_[1] might be an erro |
771 |
http_request ( |
772 |
$method => $hdr{location}, |
773 |
%arg, |
774 |
recurse => $recurse - 1, |
775 |
Redirect => [$_[0], \%hdr], |
776 |
$cb); |
777 |
} else { |
778 |
$cb->($_[0], \%hdr); |
779 |
} |
780 |
}; |
781 |
|
782 |
$ae_error = 597; # body phase |
783 |
|
784 |
my $len = $hdr{"content-length"}; |
785 |
|
786 |
# body handling, many different code paths |
787 |
# - no body expected |
788 |
# - want_body_handle |
789 |
# - te chunked |
790 |
# - 2x length known (with or without on_body) |
791 |
# - 2x length not known (with or without on_body) |
792 |
if (!$redirect && $arg{on_header} && !$arg{on_header}(\%hdr)) { |
793 |
$finish->(undef, 598 => "Request cancelled by on_header"); |
794 |
} elsif ( |
795 |
$hdr{Status} =~ /^(?:1..|204|205|304)$/ |
796 |
or $method eq "HEAD" |
797 |
or (defined $len && $len == 0) # == 0, not !, because "0 " is true |
798 |
) { |
799 |
# no body |
800 |
$finish->("", undef, undef, 1); |
801 |
|
802 |
} elsif (!$redirect && $arg{want_body_handle}) { |
803 |
$_[0]->on_eof (undef); |
804 |
$_[0]->on_error (undef); |
805 |
$_[0]->on_read (undef); |
806 |
|
807 |
$finish->(delete $state{handle}); |
808 |
|
809 |
} elsif ($hdr{"transfer-encoding"} =~ /\bchunked\b/i) { |
810 |
my $cl = 0; |
811 |
my $body = undef; |
812 |
my $on_body = $arg{on_body} || sub { $body .= shift; 1 }; |
813 |
|
814 |
$state{read_chunk} = sub { |
815 |
$_[1] =~ /^([0-9a-fA-F]+)/ |
816 |
or $finish->(undef, $ae_error => "Garbled chunked transfer encoding"); |
817 |
|
818 |
my $len = hex $1; |
819 |
|
820 |
if ($len) { |
821 |
$cl += $len; |
822 |
|
823 |
$_[0]->push_read (chunk => $len, sub { |
824 |
$on_body->($_[1], \%hdr) |
825 |
or return $finish->(undef, 598 => "Request cancelled by on_body"); |
826 |
|
827 |
$_[0]->push_read (line => sub { |
828 |
length $_[1] |
829 |
and return $finish->(undef, $ae_error => "Garbled chunked transfer encoding"); |
830 |
$_[0]->push_read (line => $state{read_chunk}); |
831 |
}); |
832 |
}); |
833 |
} else { |
834 |
$hdr{"content-length"} ||= $cl; |
835 |
|
836 |
$_[0]->push_read (line => $qr_nlnl, sub { |
837 |
if (length $_[1]) { |
838 |
for ("$_[1]") { |
839 |
y/\015//d; # weed out any \015, as they show up in the weirdest of places. |
840 |
|
841 |
my $hdr = parse_hdr |
842 |
or return $finish->(undef, $ae_error => "Garbled response trailers"); |
843 |
|
844 |
%hdr = (%hdr, %$hdr); |
845 |
} |
846 |
} |
847 |
|
848 |
$finish->($body, undef, undef, 1); |
849 |
}); |
850 |
} |
851 |
}; |
852 |
|
853 |
$_[0]->push_read (line => $state{read_chunk}); |
854 |
|
855 |
} elsif ($arg{on_body}) { |
856 |
if (defined $len) { |
857 |
$_[0]->on_read (sub { |
858 |
$len -= length $_[0]{rbuf}; |
859 |
|
860 |
$arg{on_body}(delete $_[0]{rbuf}, \%hdr) |
861 |
or return $finish->(undef, 598 => "Request cancelled by on_body"); |
862 |
|
863 |
$len > 0 |
864 |
or $finish->("", undef, undef, 1); |
865 |
}); |
866 |
} else { |
867 |
$_[0]->on_eof (sub { |
868 |
$finish->(""); |
869 |
}); |
870 |
$_[0]->on_read (sub { |
871 |
$arg{on_body}(delete $_[0]{rbuf}, \%hdr) |
872 |
or $finish->(undef, 598 => "Request cancelled by on_body"); |
873 |
}); |
874 |
} |
875 |
} else { |
876 |
$_[0]->on_eof (undef); |
877 |
|
878 |
if (defined $len) { |
879 |
$_[0]->on_read (sub { |
880 |
$finish->((substr delete $_[0]{rbuf}, 0, $len, ""), undef, undef, 1) |
881 |
if $len <= length $_[0]{rbuf}; |
882 |
}); |
883 |
} else { |
884 |
$_[0]->on_error (sub { |
885 |
($! == Errno::EPIPE || !$!) |
886 |
? $finish->(delete $_[0]{rbuf}) |
887 |
: $finish->(undef, $ae_error => $_[2]); |
888 |
}); |
889 |
$_[0]->on_read (sub { }); |
890 |
} |
891 |
} |
892 |
}; |
893 |
|
894 |
$state{handle}->push_read (line => $qr_nlnl, $state{read_response}); |
895 |
}; |
896 |
|
897 |
my $connect_cb = sub { |
898 |
$state{fh} = shift |
899 |
or do { |
900 |
my $err = "$!"; |
901 |
%state = (); |
902 |
return $cb->(undef, { @pseudo, Status => $ae_error, Reason => $err }); |
903 |
}; |
904 |
|
905 |
return unless delete $state{connect_guard}; |
906 |
|
907 |
# get handle |
908 |
$state{handle} = new AnyEvent::Handle |
909 |
fh => $state{fh}, |
910 |
peername => $rhost, |
911 |
tls_ctx => $arg{tls_ctx}, |
912 |
# these need to be reconfigured on keepalive handles |
913 |
timeout => $timeout, |
914 |
on_error => sub { |
915 |
%state = (); |
916 |
$cb->(undef, { @pseudo, Status => $ae_error, Reason => $_[2] }); |
917 |
}, |
918 |
on_eof => sub { |
919 |
%state = (); |
920 |
$cb->(undef, { @pseudo, Status => $ae_error, Reason => "Unexpected end-of-file" }); |
921 |
}, |
922 |
; |
923 |
|
924 |
# limit the number of persistent connections |
925 |
# keepalive not yet supported |
926 |
# if ($KA_COUNT{$_[1]} < $MAX_PERSISTENT_PER_HOST) { |
927 |
# ++$KA_COUNT{$_[1]}; |
928 |
# $state{handle}{ka_count_guard} = AnyEvent::Util::guard { |
929 |
# --$KA_COUNT{$_[1]} |
930 |
# }; |
931 |
# $hdr{connection} = "keep-alive"; |
932 |
# } |
933 |
|
934 |
$state{handle}->starttls ("connect") if $rscheme eq "https"; |
935 |
|
936 |
# now handle proxy-CONNECT method |
937 |
if ($proxy && $uscheme eq "https") { |
938 |
# oh dear, we have to wrap it into a connect request |
939 |
|
940 |
# maybe re-use $uauthority with patched port? |
941 |
$state{handle}->push_write ("CONNECT $uhost:$uport HTTP/1.0\015\012\015\012"); |
942 |
$state{handle}->push_read (line => $qr_nlnl, sub { |
943 |
$_[1] =~ /^HTTP\/([0-9\.]+) \s+ ([0-9]{3}) (?: \s+ ([^\015\012]*) )?/ix |
944 |
or return (%state = (), $cb->(undef, { @pseudo, Status => 599, Reason => "Invalid proxy connect response ($_[1])" })); |
945 |
|
946 |
if ($2 == 200) { |
947 |
$rpath = $upath; |
948 |
$handle_actual_request->(); |
949 |
} else { |
950 |
%state = (); |
951 |
$cb->(undef, { @pseudo, Status => $2, Reason => $3 }); |
952 |
} |
953 |
}); |
954 |
} else { |
955 |
$handle_actual_request->(); |
956 |
} |
957 |
}; |
958 |
|
959 |
_get_slot $uhost, sub { |
960 |
$state{slot_guard} = shift; |
961 |
|
962 |
return unless $state{connect_guard}; |
963 |
|
964 |
my $tcp_connect = $arg{tcp_connect} |
965 |
|| do { require AnyEvent::Socket; \&AnyEvent::Socket::tcp_connect }; |
966 |
|
967 |
$state{connect_guard} = $tcp_connect->($rhost, $rport, $connect_cb, $arg{on_prepare} || sub { $timeout }); |
968 |
}; |
969 |
|
970 |
defined wantarray && AnyEvent::Util::guard { %state = () } |
971 |
} |
972 |
|
973 |
sub http_get($@) { |
974 |
unshift @_, "GET"; |
975 |
&http_request |
976 |
} |
977 |
|
978 |
sub http_head($@) { |
979 |
unshift @_, "HEAD"; |
980 |
&http_request |
981 |
} |
982 |
|
983 |
sub http_post($$@) { |
984 |
my $url = shift; |
985 |
unshift @_, "POST", $url, "body"; |
986 |
&http_request |
987 |
} |
988 |
|
989 |
=back |
990 |
|
991 |
=head2 DNS CACHING |
992 |
|
993 |
AnyEvent::HTTP uses the AnyEvent::Socket::tcp_connect function for |
994 |
the actual connection, which in turn uses AnyEvent::DNS to resolve |
995 |
hostnames. The latter is a simple stub resolver and does no caching |
996 |
on its own. If you want DNS caching, you currently have to provide |
997 |
your own default resolver (by storing a suitable resolver object in |
998 |
C<$AnyEvent::DNS::RESOLVER>). |
999 |
|
1000 |
=head2 GLOBAL FUNCTIONS AND VARIABLES |
1001 |
|
1002 |
=over 4 |
1003 |
|
1004 |
=item AnyEvent::HTTP::set_proxy "proxy-url" |
1005 |
|
1006 |
Sets the default proxy server to use. The proxy-url must begin with a |
1007 |
string of the form C<http://host:port> (optionally C<https:...>), croaks |
1008 |
otherwise. |
1009 |
|
1010 |
To clear an already-set proxy, use C<undef>. |
1011 |
|
1012 |
=item AnyEvent::HTTP::cookie_jar_expire $jar[, $session_end] |
1013 |
|
1014 |
Remove all cookies from the cookie jar that have been expired. If |
1015 |
C<$session_end> is given and true, then additionally remove all session |
1016 |
cookies. |
1017 |
|
1018 |
You should call this function (with a true C<$session_end>) before you |
1019 |
save cookies to disk, and you should call this function after loading them |
1020 |
again. If you have a long-running program you can additonally call this |
1021 |
function from time to time. |
1022 |
|
1023 |
A cookie jar is initially an empty hash-reference that is managed by this |
1024 |
module. It's format is subject to change, but currently it is like this: |
1025 |
|
1026 |
The key C<version> has to contain C<1>, otherwise the hash gets |
1027 |
emptied. All other keys are hostnames or IP addresses pointing to |
1028 |
hash-references. The key for these inner hash references is the |
1029 |
server path for which this cookie is meant, and the values are again |
1030 |
hash-references. The keys of those hash-references is the cookie name, and |
1031 |
the value, you guessed it, is another hash-reference, this time with the |
1032 |
key-value pairs from the cookie, except for C<expires> and C<max-age>, |
1033 |
which have been replaced by a C<_expires> key that contains the cookie |
1034 |
expiry timestamp. |
1035 |
|
1036 |
Here is an example of a cookie jar with a single cookie, so you have a |
1037 |
chance of understanding the above paragraph: |
1038 |
|
1039 |
{ |
1040 |
version => 1, |
1041 |
"10.0.0.1" => { |
1042 |
"/" => { |
1043 |
"mythweb_id" => { |
1044 |
_expires => 1293917923, |
1045 |
value => "ooRung9dThee3ooyXooM1Ohm", |
1046 |
}, |
1047 |
}, |
1048 |
}, |
1049 |
} |
1050 |
|
1051 |
=item $date = AnyEvent::HTTP::format_date $timestamp |
1052 |
|
1053 |
Takes a POSIX timestamp (seconds since the epoch) and formats it as a HTTP |
1054 |
Date (RFC 2616). |
1055 |
|
1056 |
=item $timestamp = AnyEvent::HTTP::parse_date $date |
1057 |
|
1058 |
Takes a HTTP Date (RFC 2616) or a Cookie date (netscape cookie spec) or a |
1059 |
bunch of minor variations of those, and returns the corresponding POSIX |
1060 |
timestamp, or C<undef> if the date cannot be parsed. |
1061 |
|
1062 |
=item $AnyEvent::HTTP::MAX_RECURSE |
1063 |
|
1064 |
The default value for the C<recurse> request parameter (default: C<10>). |
1065 |
|
1066 |
=item $AnyEvent::HTTP::USERAGENT |
1067 |
|
1068 |
The default value for the C<User-Agent> header (the default is |
1069 |
C<Mozilla/5.0 (compatible; U; AnyEvent-HTTP/$VERSION; +http://software.schmorp.de/pkg/AnyEvent)>). |
1070 |
|
1071 |
=item $AnyEvent::HTTP::MAX_PER_HOST |
1072 |
|
1073 |
The maximum number of concurrent connections to the same host (identified |
1074 |
by the hostname). If the limit is exceeded, then the additional requests |
1075 |
are queued until previous connections are closed. |
1076 |
|
1077 |
The default value for this is C<4>, and it is highly advisable to not |
1078 |
increase it. |
1079 |
|
1080 |
=item $AnyEvent::HTTP::ACTIVE |
1081 |
|
1082 |
The number of active connections. This is not the number of currently |
1083 |
running requests, but the number of currently open and non-idle TCP |
1084 |
connections. This number of can be useful for load-leveling. |
1085 |
|
1086 |
=back |
1087 |
|
1088 |
=cut |
1089 |
|
1090 |
our @month = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec); |
1091 |
our @weekday = qw(Sun Mon Tue Wed Thu Fri Sat); |
1092 |
|
1093 |
sub format_date($) { |
1094 |
my ($time) = @_; |
1095 |
|
1096 |
# RFC 822/1123 format |
1097 |
my ($S, $M, $H, $mday, $mon, $year, $wday, $yday, undef) = gmtime $time; |
1098 |
|
1099 |
sprintf "%s, %02d %s %04d %02d:%02d:%02d GMT", |
1100 |
$weekday[$wday], $mday, $month[$mon], $year + 1900, |
1101 |
$H, $M, $S; |
1102 |
} |
1103 |
|
1104 |
sub parse_date($) { |
1105 |
my ($date) = @_; |
1106 |
|
1107 |
my ($d, $m, $y, $H, $M, $S); |
1108 |
|
1109 |
if ($date =~ /^[A-Z][a-z][a-z]+, ([0-9][0-9]?)[\- ]([A-Z][a-z][a-z])[\- ]([0-9][0-9][0-9][0-9]) ([0-9][0-9]?):([0-9][0-9]?):([0-9][0-9]?) GMT$/) { |
1110 |
# RFC 822/1123, required by RFC 2616 (with " ") |
1111 |
# cookie dates (with "-") |
1112 |
|
1113 |
($d, $m, $y, $H, $M, $S) = ($1, $2, $3, $4, $5, $6); |
1114 |
|
1115 |
} elsif ($date =~ /^[A-Z][a-z][a-z]+, ([0-9][0-9]?)-([A-Z][a-z][a-z])-([0-9][0-9]) ([0-9][0-9]?):([0-9][0-9]?):([0-9][0-9]?) GMT$/) { |
1116 |
# RFC 850 |
1117 |
($d, $m, $y, $H, $M, $S) = ($1, $2, $3 < 69 ? $3 + 2000 : $3 + 1900, $4, $5, $6); |
1118 |
|
1119 |
} elsif ($date =~ /^[A-Z][a-z][a-z]+ ([A-Z][a-z][a-z]) ([0-9 ]?[0-9]) ([0-9][0-9]?):([0-9][0-9]?):([0-9][0-9]?) ([0-9][0-9][0-9][0-9])$/) { |
1120 |
# ISO C's asctime |
1121 |
($d, $m, $y, $H, $M, $S) = ($2, $1, $6, $3, $4, $5); |
1122 |
} |
1123 |
# other formats fail in the loop below |
1124 |
|
1125 |
for (0..11) { |
1126 |
if ($m eq $month[$_]) { |
1127 |
require Time::Local; |
1128 |
return Time::Local::timegm ($S, $M, $H, $d, $_, $y); |
1129 |
} |
1130 |
} |
1131 |
|
1132 |
undef |
1133 |
} |
1134 |
|
1135 |
sub set_proxy($) { |
1136 |
if (length $_[0]) { |
1137 |
$_[0] =~ m%^(https?):// ([^:/]+) (?: : (\d*) )?%ix |
1138 |
or Carp::croak "$_[0]: invalid proxy URL"; |
1139 |
$PROXY = [$2, $3 || 3128, $1] |
1140 |
} else { |
1141 |
undef $PROXY; |
1142 |
} |
1143 |
} |
1144 |
|
1145 |
# initialise proxy from environment |
1146 |
eval { |
1147 |
set_proxy $ENV{http_proxy}; |
1148 |
}; |
1149 |
|
1150 |
=head2 SOCKS PROXIES |
1151 |
|
1152 |
Socks proxies are not directly supported by AnyEvent::HTTP. You can |
1153 |
compile your perl to support socks, or use an external program such as |
1154 |
F<socksify> (dante) or F<tsocks> to make your program use a socks proxy |
1155 |
transparently. |
1156 |
|
1157 |
Alternatively, for AnyEvent::HTTP only, you can use your own |
1158 |
C<tcp_connect> function that does the proxy handshake - here is an example |
1159 |
that works with socks4a proxies: |
1160 |
|
1161 |
use Errno; |
1162 |
use AnyEvent::Util; |
1163 |
use AnyEvent::Socket; |
1164 |
use AnyEvent::Handle; |
1165 |
|
1166 |
# host, port and username of/for your socks4a proxy |
1167 |
my $socks_host = "10.0.0.23"; |
1168 |
my $socks_port = 9050; |
1169 |
my $socks_user = ""; |
1170 |
|
1171 |
sub socks4a_connect { |
1172 |
my ($host, $port, $connect_cb, $prepare_cb) = @_; |
1173 |
|
1174 |
my $hdl = new AnyEvent::Handle |
1175 |
connect => [$socks_host, $socks_port], |
1176 |
on_prepare => sub { $prepare_cb->($_[0]{fh}) }, |
1177 |
on_error => sub { $connect_cb->() }, |
1178 |
; |
1179 |
|
1180 |
$hdl->push_write (pack "CCnNZ*Z*", 4, 1, $port, 1, $socks_user, $host); |
1181 |
|
1182 |
$hdl->push_read (chunk => 8, sub { |
1183 |
my ($hdl, $chunk) = @_; |
1184 |
my ($status, $port, $ipn) = unpack "xCna4", $chunk; |
1185 |
|
1186 |
if ($status == 0x5a) { |
1187 |
$connect_cb->($hdl->{fh}, (format_address $ipn) . ":$port"); |
1188 |
} else { |
1189 |
$! = Errno::ENXIO; $connect_cb->(); |
1190 |
} |
1191 |
}); |
1192 |
|
1193 |
$hdl |
1194 |
} |
1195 |
|
1196 |
Use C<socks4a_connect> instead of C<tcp_connect> when doing C<http_request>s, |
1197 |
possibly after switching off other proxy types: |
1198 |
|
1199 |
AnyEvent::HTTP::set_proxy undef; # usually you do not want other proxies |
1200 |
|
1201 |
http_get 'http://www.google.com', tcp_connect => \&socks4a_connect, sub { |
1202 |
my ($data, $headers) = @_; |
1203 |
... |
1204 |
}; |
1205 |
|
1206 |
=head1 SEE ALSO |
1207 |
|
1208 |
L<AnyEvent>. |
1209 |
|
1210 |
=head1 AUTHOR |
1211 |
|
1212 |
Marc Lehmann <schmorp@schmorp.de> |
1213 |
http://home.schmorp.de/ |
1214 |
|
1215 |
With many thanks to Дмитрий Шалашов, who provided countless |
1216 |
testcases and bugreports. |
1217 |
|
1218 |
=cut |
1219 |
|
1220 |
1 |
1221 |
|