| 1 |
=head1 NAME |
| 2 |
|
| 3 |
AnyEvent::HTTP - simple but non-blocking HTTP/HTTPS client |
| 4 |
|
| 5 |
=head1 SYNOPSIS |
| 6 |
|
| 7 |
use AnyEvent::HTTP; |
| 8 |
|
| 9 |
http_get "http://www.nethype.de/", sub { print $_[1] }; |
| 10 |
|
| 11 |
# ... do something else here |
| 12 |
|
| 13 |
=head1 DESCRIPTION |
| 14 |
|
| 15 |
This module is an L<AnyEvent> user, you need to make sure that you use and |
| 16 |
run a supported event loop. |
| 17 |
|
| 18 |
This module implements a simple, stateless and non-blocking HTTP |
| 19 |
client. It supports GET, POST and other request methods, cookies and more, |
| 20 |
all on a very low level. It can follow redirects supports proxies and |
| 21 |
automatically limits the number of connections to the values specified in |
| 22 |
the RFC. |
| 23 |
|
| 24 |
It should generally be a "good client" that is enough for most HTTP |
| 25 |
tasks. Simple tasks should be simple, but complex tasks should still be |
| 26 |
possible as the user retains control over request and response headers. |
| 27 |
|
| 28 |
The caller is responsible for authentication management, cookies (if |
| 29 |
the simplistic implementation in this module doesn't suffice), referer |
| 30 |
and other high-level protocol details for which this module offers only |
| 31 |
limited support. |
| 32 |
|
| 33 |
=head2 METHODS |
| 34 |
|
| 35 |
=over 4 |
| 36 |
|
| 37 |
=cut |
| 38 |
|
| 39 |
package AnyEvent::HTTP; |
| 40 |
|
| 41 |
use strict; |
| 42 |
no warnings; |
| 43 |
|
| 44 |
use Errno (); |
| 45 |
|
| 46 |
use AnyEvent 5.0 (); |
| 47 |
use AnyEvent::Util (); |
| 48 |
use AnyEvent::Handle (); |
| 49 |
|
| 50 |
use base Exporter::; |
| 51 |
|
| 52 |
our $VERSION = '1.5'; |
| 53 |
|
| 54 |
our @EXPORT = qw(http_get http_post http_head http_request); |
| 55 |
|
| 56 |
our $USERAGENT = "Mozilla/5.0 (compatible; U; AnyEvent-HTTP/$VERSION; +http://software.schmorp.de/pkg/AnyEvent)"; |
| 57 |
our $MAX_RECURSE = 10; |
| 58 |
our $MAX_PERSISTENT = 8; |
| 59 |
our $PERSISTENT_TIMEOUT = 2; |
| 60 |
our $TIMEOUT = 300; |
| 61 |
|
| 62 |
# changing these is evil |
| 63 |
our $MAX_PERSISTENT_PER_HOST = 0; |
| 64 |
our $MAX_PER_HOST = 4; |
| 65 |
|
| 66 |
our $PROXY; |
| 67 |
our $ACTIVE = 0; |
| 68 |
|
| 69 |
my %KA_COUNT; # number of open keep-alive connections per host |
| 70 |
my %CO_SLOT; # number of open connections, and wait queue, per host |
| 71 |
|
| 72 |
=item http_get $url, key => value..., $cb->($data, $headers) |
| 73 |
|
| 74 |
Executes an HTTP-GET request. See the http_request function for details on |
| 75 |
additional parameters and the return value. |
| 76 |
|
| 77 |
=item http_head $url, key => value..., $cb->($data, $headers) |
| 78 |
|
| 79 |
Executes an HTTP-HEAD request. See the http_request function for details |
| 80 |
on additional parameters and the return value. |
| 81 |
|
| 82 |
=item http_post $url, $body, key => value..., $cb->($data, $headers) |
| 83 |
|
| 84 |
Executes an HTTP-POST request with a request body of C<$body>. See the |
| 85 |
http_request function for details on additional parameters and the return |
| 86 |
value. |
| 87 |
|
| 88 |
=item http_request $method => $url, key => value..., $cb->($data, $headers) |
| 89 |
|
| 90 |
Executes a HTTP request of type C<$method> (e.g. C<GET>, C<POST>). The URL |
| 91 |
must be an absolute http or https URL. |
| 92 |
|
| 93 |
When called in void context, nothing is returned. In other contexts, |
| 94 |
C<http_request> returns a "cancellation guard" - you have to keep the |
| 95 |
object at least alive until the callback get called. If the object gets |
| 96 |
destroyed before the callback is called, the request will be cancelled. |
| 97 |
|
| 98 |
The callback will be called with the response body data as first argument |
| 99 |
(or C<undef> if an error occured), and a hash-ref with response headers |
| 100 |
(and trailers) as second argument. |
| 101 |
|
| 102 |
All the headers in that hash are lowercased. In addition to the response |
| 103 |
headers, the "pseudo-headers" (uppercase to avoid clashing with possible |
| 104 |
response headers) C<HTTPVersion>, C<Status> and C<Reason> contain the |
| 105 |
three parts of the HTTP Status-Line of the same name. If an error occurs |
| 106 |
during the body phase of a request, then the original C<Status> and |
| 107 |
C<Reason> values from the header are available as C<OrigStatus> and |
| 108 |
C<OrigReason>. |
| 109 |
|
| 110 |
The pseudo-header C<URL> contains the actual URL (which can differ from |
| 111 |
the requested URL when following redirects - for example, you might get |
| 112 |
an error that your URL scheme is not supported even though your URL is a |
| 113 |
valid http URL because it redirected to an ftp URL, in which case you can |
| 114 |
look at the URL pseudo header). |
| 115 |
|
| 116 |
The pseudo-header C<Redirect> only exists when the request was a result |
| 117 |
of an internal redirect. In that case it is an array reference with |
| 118 |
the C<($data, $headers)> from the redirect response. Note that this |
| 119 |
response could in turn be the result of a redirect itself, and C<< |
| 120 |
$headers->{Redirect}[1]{Redirect} >> will then contain the original |
| 121 |
response, and so on. |
| 122 |
|
| 123 |
If the server sends a header multiple times, then their contents will be |
| 124 |
joined together with a comma (C<,>), as per the HTTP spec. |
| 125 |
|
| 126 |
If an internal error occurs, such as not being able to resolve a hostname, |
| 127 |
then C<$data> will be C<undef>, C<< $headers->{Status} >> will be C<59x> |
| 128 |
(usually C<599>) and the C<Reason> pseudo-header will contain an error |
| 129 |
message. |
| 130 |
|
| 131 |
A typical callback might look like this: |
| 132 |
|
| 133 |
sub { |
| 134 |
my ($body, $hdr) = @_; |
| 135 |
|
| 136 |
if ($hdr->{Status} =~ /^2/) { |
| 137 |
... everything should be ok |
| 138 |
} else { |
| 139 |
print "error, $hdr->{Status} $hdr->{Reason}\n"; |
| 140 |
} |
| 141 |
} |
| 142 |
|
| 143 |
Additional parameters are key-value pairs, and are fully optional. They |
| 144 |
include: |
| 145 |
|
| 146 |
=over 4 |
| 147 |
|
| 148 |
=item recurse => $count (default: $MAX_RECURSE) |
| 149 |
|
| 150 |
Whether to recurse requests or not, e.g. on redirects, authentication |
| 151 |
retries and so on, and how often to do so. |
| 152 |
|
| 153 |
=item headers => hashref |
| 154 |
|
| 155 |
The request headers to use. Currently, C<http_request> may provide its own |
| 156 |
C<Host:>, C<Content-Length:>, C<Connection:> and C<Cookie:> headers and |
| 157 |
will provide defaults at least for C<TE:>, C<Referer:> and C<User-Agent:> |
| 158 |
(this can be suppressed by using C<undef> for these headers in which case |
| 159 |
they won't be sent at all). |
| 160 |
|
| 161 |
=item timeout => $seconds |
| 162 |
|
| 163 |
The time-out to use for various stages - each connect attempt will reset |
| 164 |
the timeout, as will read or write activity, i.e. this is not an overall |
| 165 |
timeout. |
| 166 |
|
| 167 |
Default timeout is 5 minutes. |
| 168 |
|
| 169 |
=item proxy => [$host, $port[, $scheme]] or undef |
| 170 |
|
| 171 |
Use the given http proxy for all requests. If not specified, then the |
| 172 |
default proxy (as specified by C<$ENV{http_proxy}>) is used. |
| 173 |
|
| 174 |
C<$scheme> must be either missing, C<http> for HTTP or C<https> for |
| 175 |
HTTPS. |
| 176 |
|
| 177 |
=item body => $string |
| 178 |
|
| 179 |
The request body, usually empty. Will be sent as-is (future versions of |
| 180 |
this module might offer more options). |
| 181 |
|
| 182 |
=item cookie_jar => $hash_ref |
| 183 |
|
| 184 |
Passing this parameter enables (simplified) cookie-processing, loosely |
| 185 |
based on the original netscape specification. |
| 186 |
|
| 187 |
The C<$hash_ref> must be an (initially empty) hash reference which will |
| 188 |
get updated automatically. It is possible to save the cookie_jar to |
| 189 |
persistent storage with something like JSON or Storable, but this is not |
| 190 |
recommended, as expiry times are currently being ignored. |
| 191 |
|
| 192 |
Note that this cookie implementation is not of very high quality, nor |
| 193 |
meant to be complete. If you want complete cookie management you have to |
| 194 |
do that on your own. C<cookie_jar> is meant as a quick fix to get some |
| 195 |
cookie-using sites working. Cookies are a privacy disaster, do not use |
| 196 |
them unless required to. |
| 197 |
|
| 198 |
When cookie processing is enabled, the C<Cookie:> and C<Set-Cookie:> |
| 199 |
headers will be ste and handled by this module, otherwise they will be |
| 200 |
left untouched. |
| 201 |
|
| 202 |
=item tls_ctx => $scheme | $tls_ctx |
| 203 |
|
| 204 |
Specifies the AnyEvent::TLS context to be used for https connections. This |
| 205 |
parameter follows the same rules as the C<tls_ctx> parameter to |
| 206 |
L<AnyEvent::Handle>, but additionally, the two strings C<low> or |
| 207 |
C<high> can be specified, which give you a predefined low-security (no |
| 208 |
verification, highest compatibility) and high-security (CA and common-name |
| 209 |
verification) TLS context. |
| 210 |
|
| 211 |
The default for this option is C<low>, which could be interpreted as "give |
| 212 |
me the page, no matter what". |
| 213 |
|
| 214 |
=item on_prepare => $callback->($fh) |
| 215 |
|
| 216 |
In rare cases you need to "tune" the socket before it is used to |
| 217 |
connect (for exmaple, to bind it on a given IP address). This parameter |
| 218 |
overrides the prepare callback passed to C<AnyEvent::Socket::tcp_connect> |
| 219 |
and behaves exactly the same way (e.g. it has to provide a |
| 220 |
timeout). See the description for the C<$prepare_cb> argument of |
| 221 |
C<AnyEvent::Socket::tcp_connect> for details. |
| 222 |
|
| 223 |
=item tcp_connect => $callback->($host, $service, $connect_cb, $prepare_cb) |
| 224 |
|
| 225 |
In even rarer cases you want total control over how AnyEvent::HTTP |
| 226 |
establishes connections. Normally it uses L<AnyEvent::Socket::tcp_connect> |
| 227 |
to do this, but you can provide your own C<tcp_connect> function - |
| 228 |
obviously, it has to follow the same calling conventions, except that it |
| 229 |
may always return a connection guard object. |
| 230 |
|
| 231 |
There are probably lots of weird uses for this function, starting from |
| 232 |
tracing the hosts C<http_request> actually tries to connect, to (inexact |
| 233 |
but fast) host => IP address caching or even socks protocol support. |
| 234 |
|
| 235 |
=item on_header => $callback->($headers) |
| 236 |
|
| 237 |
When specified, this callback will be called with the header hash as soon |
| 238 |
as headers have been successfully received from the remote server (not on |
| 239 |
locally-generated errors). |
| 240 |
|
| 241 |
It has to return either true (in which case AnyEvent::HTTP will continue), |
| 242 |
or false, in which case AnyEvent::HTTP will cancel the download (and call |
| 243 |
the finish callback with an error code of C<598>). |
| 244 |
|
| 245 |
This callback is useful, among other things, to quickly reject unwanted |
| 246 |
content, which, if it is supposed to be rare, can be faster than first |
| 247 |
doing a C<HEAD> request. |
| 248 |
|
| 249 |
The downside is that cancelling the request makes it impossible to re-use |
| 250 |
the connection. Also, the C<on_header> callback will not receive any |
| 251 |
trailer (headers sent after the response body). |
| 252 |
|
| 253 |
Example: cancel the request unless the content-type is "text/html". |
| 254 |
|
| 255 |
on_header => sub { |
| 256 |
$_[0]{"content-type"} =~ /^text\/html\s*(?:;|$)/ |
| 257 |
}, |
| 258 |
|
| 259 |
=item on_body => $callback->($partial_body, $headers) |
| 260 |
|
| 261 |
When specified, all body data will be passed to this callback instead of |
| 262 |
to the completion callback. The completion callback will get the empty |
| 263 |
string instead of the body data. |
| 264 |
|
| 265 |
It has to return either true (in which case AnyEvent::HTTP will continue), |
| 266 |
or false, in which case AnyEvent::HTTP will cancel the download (and call |
| 267 |
the completion callback with an error code of C<598>). |
| 268 |
|
| 269 |
The downside to cancelling the request is that it makes it impossible to |
| 270 |
re-use the connection. |
| 271 |
|
| 272 |
This callback is useful when the data is too large to be held in memory |
| 273 |
(so the callback writes it to a file) or when only some information should |
| 274 |
be extracted, or when the body should be processed incrementally. |
| 275 |
|
| 276 |
It is usually preferred over doing your own body handling via |
| 277 |
C<want_body_handle>, but in case of streaming APIs, where HTTP is |
| 278 |
only used to create a connection, C<want_body_handle> is the better |
| 279 |
alternative, as it allows you to install your own event handler, reducing |
| 280 |
resource usage. |
| 281 |
|
| 282 |
=item want_body_handle => $enable |
| 283 |
|
| 284 |
When enabled (default is disabled), the behaviour of AnyEvent::HTTP |
| 285 |
changes considerably: after parsing the headers, and instead of |
| 286 |
downloading the body (if any), the completion callback will be |
| 287 |
called. Instead of the C<$body> argument containing the body data, the |
| 288 |
callback will receive the L<AnyEvent::Handle> object associated with the |
| 289 |
connection. In error cases, C<undef> will be passed. When there is no body |
| 290 |
(e.g. status C<304>), the empty string will be passed. |
| 291 |
|
| 292 |
The handle object might or might not be in TLS mode, might be connected to |
| 293 |
a proxy, be a persistent connection etc., and configured in unspecified |
| 294 |
ways. The user is responsible for this handle (it will not be used by this |
| 295 |
module anymore). |
| 296 |
|
| 297 |
This is useful with some push-type services, where, after the initial |
| 298 |
headers, an interactive protocol is used (typical example would be the |
| 299 |
push-style twitter API which starts a JSON/XML stream). |
| 300 |
|
| 301 |
If you think you need this, first have a look at C<on_body>, to see if |
| 302 |
that doesn't solve your problem in a better way. |
| 303 |
|
| 304 |
=back |
| 305 |
|
| 306 |
Example: do a simple HTTP GET request for http://www.nethype.de/ and print |
| 307 |
the response body. |
| 308 |
|
| 309 |
http_request GET => "http://www.nethype.de/", sub { |
| 310 |
my ($body, $hdr) = @_; |
| 311 |
print "$body\n"; |
| 312 |
}; |
| 313 |
|
| 314 |
Example: do a HTTP HEAD request on https://www.google.com/, use a |
| 315 |
timeout of 30 seconds. |
| 316 |
|
| 317 |
http_request |
| 318 |
GET => "https://www.google.com", |
| 319 |
timeout => 30, |
| 320 |
sub { |
| 321 |
my ($body, $hdr) = @_; |
| 322 |
use Data::Dumper; |
| 323 |
print Dumper $hdr; |
| 324 |
} |
| 325 |
; |
| 326 |
|
| 327 |
Example: do another simple HTTP GET request, but immediately try to |
| 328 |
cancel it. |
| 329 |
|
| 330 |
my $request = http_request GET => "http://www.nethype.de/", sub { |
| 331 |
my ($body, $hdr) = @_; |
| 332 |
print "$body\n"; |
| 333 |
}; |
| 334 |
|
| 335 |
undef $request; |
| 336 |
|
| 337 |
=cut |
| 338 |
|
| 339 |
sub _slot_schedule; |
| 340 |
sub _slot_schedule($) { |
| 341 |
my $host = shift; |
| 342 |
|
| 343 |
while ($CO_SLOT{$host}[0] < $MAX_PER_HOST) { |
| 344 |
if (my $cb = shift @{ $CO_SLOT{$host}[1] }) { |
| 345 |
# somebody wants that slot |
| 346 |
++$CO_SLOT{$host}[0]; |
| 347 |
++$ACTIVE; |
| 348 |
|
| 349 |
$cb->(AnyEvent::Util::guard { |
| 350 |
--$ACTIVE; |
| 351 |
--$CO_SLOT{$host}[0]; |
| 352 |
_slot_schedule $host; |
| 353 |
}); |
| 354 |
} else { |
| 355 |
# nobody wants the slot, maybe we can forget about it |
| 356 |
delete $CO_SLOT{$host} unless $CO_SLOT{$host}[0]; |
| 357 |
last; |
| 358 |
} |
| 359 |
} |
| 360 |
} |
| 361 |
|
| 362 |
# wait for a free slot on host, call callback |
| 363 |
sub _get_slot($$) { |
| 364 |
push @{ $CO_SLOT{$_[0]}[1] }, $_[1]; |
| 365 |
|
| 366 |
_slot_schedule $_[0]; |
| 367 |
} |
| 368 |
|
| 369 |
# continue to parse $_ for headers and place them into the arg |
| 370 |
sub parse_hdr() { |
| 371 |
my %hdr; |
| 372 |
|
| 373 |
# things seen, not parsed: |
| 374 |
# p3pP="NON CUR OTPi OUR NOR UNI" |
| 375 |
|
| 376 |
$hdr{lc $1} .= ",$2" |
| 377 |
while /\G |
| 378 |
([^:\000-\037]*): |
| 379 |
[\011\040]* |
| 380 |
((?: [^\012]+ | \012[\011\040] )*) |
| 381 |
\012 |
| 382 |
/gxc; |
| 383 |
|
| 384 |
/\G$/ |
| 385 |
or return; |
| 386 |
|
| 387 |
# remove the "," prefix we added to all headers above |
| 388 |
substr $_, 0, 1, "" |
| 389 |
for values %hdr; |
| 390 |
|
| 391 |
\%hdr |
| 392 |
} |
| 393 |
|
| 394 |
our $qr_nlnl = qr{(?<![^\012])\015?\012}; |
| 395 |
|
| 396 |
our $TLS_CTX_LOW = { cache => 1, sslv2 => 1 }; |
| 397 |
our $TLS_CTX_HIGH = { cache => 1, verify => 1, verify_peername => "https" }; |
| 398 |
|
| 399 |
sub http_request($$@) { |
| 400 |
my $cb = pop; |
| 401 |
my ($method, $url, %arg) = @_; |
| 402 |
|
| 403 |
my %hdr; |
| 404 |
|
| 405 |
$arg{tls_ctx} = $TLS_CTX_LOW if $arg{tls_ctx} eq "low" || !exists $arg{tls_ctx}; |
| 406 |
$arg{tls_ctx} = $TLS_CTX_HIGH if $arg{tls_ctx} eq "high"; |
| 407 |
|
| 408 |
$method = uc $method; |
| 409 |
|
| 410 |
if (my $hdr = $arg{headers}) { |
| 411 |
while (my ($k, $v) = each %$hdr) { |
| 412 |
$hdr{lc $k} = $v; |
| 413 |
} |
| 414 |
} |
| 415 |
|
| 416 |
# pseudo headers for all subsequent responses |
| 417 |
my @pseudo = (URL => $url); |
| 418 |
push @pseudo, Redirect => delete $arg{Redirect} if exists $arg{Redirect}; |
| 419 |
|
| 420 |
my $recurse = exists $arg{recurse} ? delete $arg{recurse} : $MAX_RECURSE; |
| 421 |
|
| 422 |
return $cb->(undef, { @pseudo, Status => 599, Reason => "Too many redirections" }) |
| 423 |
if $recurse < 0; |
| 424 |
|
| 425 |
my $proxy = $arg{proxy} || $PROXY; |
| 426 |
my $timeout = $arg{timeout} || $TIMEOUT; |
| 427 |
|
| 428 |
my ($uscheme, $uauthority, $upath, $query, $fragment) = |
| 429 |
$url =~ m|(?:([^:/?#]+):)?(?://([^/?#]*))?([^?#]*)(?:(\?[^#]*))?(?:#(.*))?|; |
| 430 |
|
| 431 |
$uscheme = lc $uscheme; |
| 432 |
|
| 433 |
my $uport = $uscheme eq "http" ? 80 |
| 434 |
: $uscheme eq "https" ? 443 |
| 435 |
: return $cb->(undef, { @pseudo, Status => 599, Reason => "Only http and https URL schemes supported" }); |
| 436 |
|
| 437 |
$uauthority =~ /^(?: .*\@ )? ([^\@:]+) (?: : (\d+) )?$/x |
| 438 |
or return $cb->(undef, { @pseudo, Status => 599, Reason => "Unparsable URL" }); |
| 439 |
|
| 440 |
my $uhost = $1; |
| 441 |
$uport = $2 if defined $2; |
| 442 |
|
| 443 |
$hdr{host} = defined $2 ? "$uhost:$2" : "$uhost" |
| 444 |
unless exists $hdr{host}; |
| 445 |
|
| 446 |
$uhost =~ s/^\[(.*)\]$/$1/; |
| 447 |
$upath .= $query if length $query; |
| 448 |
|
| 449 |
$upath =~ s%^/?%/%; |
| 450 |
|
| 451 |
# cookie processing |
| 452 |
if (my $jar = $arg{cookie_jar}) { |
| 453 |
%$jar = () if $jar->{version} != 1; |
| 454 |
|
| 455 |
my @cookie; |
| 456 |
|
| 457 |
while (my ($chost, $v) = each %$jar) { |
| 458 |
if ($chost =~ /^\./) { |
| 459 |
next unless $chost eq substr $uhost, -length $chost; |
| 460 |
} elsif ($chost =~ /\./) { |
| 461 |
next unless $chost eq $uhost; |
| 462 |
} else { |
| 463 |
next; |
| 464 |
} |
| 465 |
|
| 466 |
while (my ($cpath, $v) = each %$v) { |
| 467 |
next unless $cpath eq substr $upath, 0, length $cpath; |
| 468 |
|
| 469 |
while (my ($k, $v) = each %$v) { |
| 470 |
next if $uscheme ne "https" && exists $v->{secure}; |
| 471 |
my $value = $v->{value}; |
| 472 |
$value =~ s/([\\"])/\\$1/g; |
| 473 |
push @cookie, "$k=\"$value\""; |
| 474 |
} |
| 475 |
} |
| 476 |
} |
| 477 |
|
| 478 |
$hdr{cookie} = join "; ", @cookie |
| 479 |
if @cookie; |
| 480 |
} |
| 481 |
|
| 482 |
my ($rhost, $rport, $rscheme, $rpath); # request host, port, path |
| 483 |
|
| 484 |
if ($proxy) { |
| 485 |
($rpath, $rhost, $rport, $rscheme) = ($url, @$proxy); |
| 486 |
|
| 487 |
$rscheme = "http" unless defined $rscheme; |
| 488 |
|
| 489 |
# don't support https requests over https-proxy transport, |
| 490 |
# can't be done with tls as spec'ed, unless you double-encrypt. |
| 491 |
$rscheme = "http" if $uscheme eq "https" && $rscheme eq "https"; |
| 492 |
} else { |
| 493 |
($rhost, $rport, $rscheme, $rpath) = ($uhost, $uport, $uscheme, $upath); |
| 494 |
} |
| 495 |
|
| 496 |
# leave out fragment and query string, just a heuristic |
| 497 |
$hdr{referer} = "$uscheme://$uauthority$upath" unless exists $hdr{referer}; |
| 498 |
$hdr{"user-agent"} = $USERAGENT unless exists $hdr{"user-agent"}; |
| 499 |
|
| 500 |
$hdr{"content-length"} = length $arg{body} |
| 501 |
if length $arg{body} || $method ne "GET"; |
| 502 |
|
| 503 |
$hdr{connection} = "close TE"; #1.1 |
| 504 |
$hdr{te} = "trailers" unless exists $hdr{te}; #1.1 |
| 505 |
|
| 506 |
my %state = (connect_guard => 1); |
| 507 |
|
| 508 |
_get_slot $uhost, sub { |
| 509 |
$state{slot_guard} = shift; |
| 510 |
|
| 511 |
return unless $state{connect_guard}; |
| 512 |
|
| 513 |
my $connect_cb = sub { |
| 514 |
$state{fh} = shift |
| 515 |
or do { |
| 516 |
my $err = "$!"; |
| 517 |
%state = (); |
| 518 |
return $cb->(undef, { @pseudo, Status => 599, Reason => $err }); |
| 519 |
}; |
| 520 |
|
| 521 |
pop; # free memory, save a tree |
| 522 |
|
| 523 |
return unless delete $state{connect_guard}; |
| 524 |
|
| 525 |
# get handle |
| 526 |
$state{handle} = new AnyEvent::Handle |
| 527 |
fh => $state{fh}, |
| 528 |
peername => $rhost, |
| 529 |
tls_ctx => $arg{tls_ctx}, |
| 530 |
# these need to be reconfigured on keepalive handles |
| 531 |
timeout => $timeout, |
| 532 |
on_error => sub { |
| 533 |
%state = (); |
| 534 |
$cb->(undef, { @pseudo, Status => 599, Reason => $_[2] }); |
| 535 |
}, |
| 536 |
on_eof => sub { |
| 537 |
%state = (); |
| 538 |
$cb->(undef, { @pseudo, Status => 599, Reason => "Unexpected end-of-file" }); |
| 539 |
}, |
| 540 |
; |
| 541 |
|
| 542 |
# limit the number of persistent connections |
| 543 |
# keepalive not yet supported |
| 544 |
# if ($KA_COUNT{$_[1]} < $MAX_PERSISTENT_PER_HOST) { |
| 545 |
# ++$KA_COUNT{$_[1]}; |
| 546 |
# $state{handle}{ka_count_guard} = AnyEvent::Util::guard { |
| 547 |
# --$KA_COUNT{$_[1]} |
| 548 |
# }; |
| 549 |
# $hdr{connection} = "keep-alive"; |
| 550 |
# } |
| 551 |
|
| 552 |
$state{handle}->starttls ("connect") if $rscheme eq "https"; |
| 553 |
|
| 554 |
# handle actual, non-tunneled, request |
| 555 |
my $handle_actual_request = sub { |
| 556 |
$state{handle}->starttls ("connect") if $uscheme eq "https" && !exists $state{handle}{tls}; |
| 557 |
|
| 558 |
# send request |
| 559 |
$state{handle}->push_write ( |
| 560 |
"$method $rpath HTTP/1.1\015\012" |
| 561 |
. (join "", map "\u$_: $hdr{$_}\015\012", grep defined $hdr{$_}, keys %hdr) |
| 562 |
. "\015\012" |
| 563 |
. (delete $arg{body}) |
| 564 |
); |
| 565 |
|
| 566 |
# return if error occured during push_write() |
| 567 |
return unless %state; |
| 568 |
|
| 569 |
%hdr = (); # reduce memory usage, save a kitten, also make it possible to re-use |
| 570 |
|
| 571 |
# status line and headers |
| 572 |
$state{read_response} = sub { |
| 573 |
for ("$_[1]") { |
| 574 |
y/\015//d; # weed out any \015, as they show up in the weirdest of places. |
| 575 |
|
| 576 |
/^HTTP\/([0-9\.]+) \s+ ([0-9]{3}) (?: \s+ ([^\012]*) )? \012/igxc |
| 577 |
or return (%state = (), $cb->(undef, { @pseudo, Status => 599, Reason => "Invalid server response" })); |
| 578 |
|
| 579 |
# 100 Continue handling |
| 580 |
# should not happen as we don't send expect: 100-continue, |
| 581 |
# but we handle it just in case. |
| 582 |
# since we send the request body regardless, if we get an error |
| 583 |
# we are out of-sync, which we currently do NOT handle correctly. |
| 584 |
return $state{handle}->push_read (line => $qr_nlnl, $state{read_response}) |
| 585 |
if $2 eq 100; |
| 586 |
|
| 587 |
push @pseudo, |
| 588 |
HTTPVersion => $1, |
| 589 |
Status => $2, |
| 590 |
Reason => $3, |
| 591 |
; |
| 592 |
|
| 593 |
my $hdr = parse_hdr |
| 594 |
or return (%state = (), $cb->(undef, { @pseudo, Status => 599, Reason => "Garbled response headers" })); |
| 595 |
|
| 596 |
%hdr = (%$hdr, @pseudo); |
| 597 |
} |
| 598 |
|
| 599 |
# redirect handling |
| 600 |
# microsoft and other shitheads don't give a shit for following standards, |
| 601 |
# try to support some common forms of broken Location headers. |
| 602 |
if ($hdr{location} !~ /^(?: $ | [^:\/?\#]+ : )/x) { |
| 603 |
$hdr{location} =~ s/^\.\/+//; |
| 604 |
|
| 605 |
my $url = "$rscheme://$uhost:$uport"; |
| 606 |
|
| 607 |
unless ($hdr{location} =~ s/^\///) { |
| 608 |
$url .= $upath; |
| 609 |
$url =~ s/\/[^\/]*$//; |
| 610 |
} |
| 611 |
|
| 612 |
$hdr{location} = "$url/$hdr{location}"; |
| 613 |
} |
| 614 |
|
| 615 |
my $redirect; |
| 616 |
|
| 617 |
if ($recurse) { |
| 618 |
my $status = $hdr{Status}; |
| 619 |
|
| 620 |
# industry standard is to redirect POST as GET for |
| 621 |
# 301, 302 and 303, in contrast to http/1.0 and 1.1. |
| 622 |
# also, the UA should ask the user for 301 and 307 and POST, |
| 623 |
# industry standard seems to be to simply follow. |
| 624 |
# we go with the industry standard. |
| 625 |
if ($status == 301 or $status == 302 or $status == 303) { |
| 626 |
# HTTP/1.1 is unclear on how to mutate the method |
| 627 |
$method = "GET" unless $method eq "HEAD"; |
| 628 |
$redirect = 1; |
| 629 |
} elsif ($status == 307) { |
| 630 |
$redirect = 1; |
| 631 |
} |
| 632 |
} |
| 633 |
|
| 634 |
my $finish = sub { # ($data, $err_status, $err_reason[, $keepalive]) |
| 635 |
my $keepalive = pop; |
| 636 |
|
| 637 |
$state{handle}->destroy if $state{handle}; |
| 638 |
%state = (); |
| 639 |
|
| 640 |
if (defined $_[1]) { |
| 641 |
$hdr{OrigStatus} = $hdr{Status}; $hdr{Status} = $_[1]; |
| 642 |
$hdr{OrigReason} = $hdr{Reason}; $hdr{Reason} = $_[2]; |
| 643 |
} |
| 644 |
|
| 645 |
# set-cookie processing |
| 646 |
if ($arg{cookie_jar}) { |
| 647 |
for ($hdr{"set-cookie"}) { |
| 648 |
# parse NAME=VALUE |
| 649 |
my @kv; |
| 650 |
|
| 651 |
while (/\G\s* ([^=;,[:space:]]+) \s*=\s* (?: "((?:[^\\"]+|\\.)*)" | ([^=;,[:space:]]*) )/gcxs) { |
| 652 |
my $name = $1; |
| 653 |
my $value = $3; |
| 654 |
|
| 655 |
unless ($value) { |
| 656 |
$value = $2; |
| 657 |
$value =~ s/\\(.)/$1/gs; |
| 658 |
} |
| 659 |
|
| 660 |
push @kv, $name => $value; |
| 661 |
|
| 662 |
last unless /\G\s*;/gc; |
| 663 |
} |
| 664 |
|
| 665 |
last unless @kv; |
| 666 |
|
| 667 |
my $name = shift @kv; |
| 668 |
my %kv = (value => shift @kv, @kv); |
| 669 |
|
| 670 |
my $cdom; |
| 671 |
my $cpath = (delete $kv{path}) || "/"; |
| 672 |
|
| 673 |
if (exists $kv{domain}) { |
| 674 |
$cdom = delete $kv{domain}; |
| 675 |
|
| 676 |
$cdom =~ s/^\.?/./; # make sure it starts with a "." |
| 677 |
|
| 678 |
next if $cdom =~ /\.$/; |
| 679 |
|
| 680 |
# this is not rfc-like and not netscape-like. go figure. |
| 681 |
my $ndots = $cdom =~ y/.//; |
| 682 |
next if $ndots < ($cdom =~ /\.[^.][^.]\.[^.][^.]$/ ? 3 : 2); |
| 683 |
} else { |
| 684 |
$cdom = $uhost; |
| 685 |
} |
| 686 |
|
| 687 |
# store it |
| 688 |
$arg{cookie_jar}{version} = 1; |
| 689 |
$arg{cookie_jar}{$cdom}{$cpath}{$name} = \%kv; |
| 690 |
|
| 691 |
redo if /\G\s*,/gc; |
| 692 |
} |
| 693 |
} |
| 694 |
|
| 695 |
if ($redirect && exists $hdr{location}) { |
| 696 |
# we ignore any errors, as it is very common to receive |
| 697 |
# Content-Length != 0 but no actual body |
| 698 |
# we also access %hdr, as $_[1] might be an erro |
| 699 |
http_request ( |
| 700 |
$method => $hdr{location}, |
| 701 |
%arg, |
| 702 |
recurse => $recurse - 1, |
| 703 |
Redirect => [$_[0], \%hdr], |
| 704 |
$cb); |
| 705 |
} else { |
| 706 |
$cb->($_[0], \%hdr); |
| 707 |
} |
| 708 |
}; |
| 709 |
|
| 710 |
my $len = $hdr{"content-length"}; |
| 711 |
|
| 712 |
if (!$redirect && $arg{on_header} && !$arg{on_header}(\%hdr)) { |
| 713 |
$finish->(undef, 598 => "Request cancelled by on_header"); |
| 714 |
} elsif ( |
| 715 |
$hdr{Status} =~ /^(?:1..|204|205|304)$/ |
| 716 |
or $method eq "HEAD" |
| 717 |
or (defined $len && !$len) |
| 718 |
) { |
| 719 |
# no body |
| 720 |
$finish->("", undef, undef, 1); |
| 721 |
} else { |
| 722 |
# body handling, many different code paths |
| 723 |
# - no body expected |
| 724 |
# - want_body_handle |
| 725 |
# - te chunked |
| 726 |
# - 2x length known (with or without on_body) |
| 727 |
# - 2x length not known (with or without on_body) |
| 728 |
if (!$redirect && $arg{want_body_handle}) { |
| 729 |
$_[0]->on_eof (undef); |
| 730 |
$_[0]->on_error (undef); |
| 731 |
$_[0]->on_read (undef); |
| 732 |
|
| 733 |
$finish->(delete $state{handle}); |
| 734 |
|
| 735 |
} elsif ($hdr{"transfer-encoding"} =~ /\bchunked\b/i) { |
| 736 |
my $cl = 0; |
| 737 |
my $body = undef; |
| 738 |
my $on_body = $arg{on_body} || sub { $body .= shift; 1 }; |
| 739 |
|
| 740 |
$_[0]->on_error (sub { $finish->(undef, 599 => $_[2]) }); |
| 741 |
|
| 742 |
my $read_chunk; $read_chunk = sub { |
| 743 |
$_[1] =~ /^([0-9a-fA-F]+)/ |
| 744 |
or $finish->(undef, 599 => "Garbled chunked transfer encoding"); |
| 745 |
|
| 746 |
my $len = hex $1; |
| 747 |
|
| 748 |
if ($len) { |
| 749 |
$cl += $len; |
| 750 |
|
| 751 |
$_[0]->push_read (chunk => $len, sub { |
| 752 |
$on_body->($_[1], \%hdr) |
| 753 |
or return $finish->(undef, 598 => "Request cancelled by on_body"); |
| 754 |
|
| 755 |
$_[0]->push_read (line => sub { |
| 756 |
length $_[1] |
| 757 |
and return $finish->(undef, 599 => "Garbled chunked transfer encoding"); |
| 758 |
$_[0]->push_read (line => $read_chunk); |
| 759 |
}); |
| 760 |
}); |
| 761 |
} else { |
| 762 |
$hdr{"content-length"} ||= $cl; |
| 763 |
|
| 764 |
$_[0]->push_read (line => $qr_nlnl, sub { |
| 765 |
if (length $_[1]) { |
| 766 |
for ("$_[1]") { |
| 767 |
y/\015//d; # weed out any \015, as they show up in the weirdest of places. |
| 768 |
|
| 769 |
my $hdr = parse_hdr |
| 770 |
or return $finish->(undef, 599 => "Garbled response trailers"); |
| 771 |
|
| 772 |
%hdr = (%hdr, %$hdr); |
| 773 |
} |
| 774 |
} |
| 775 |
|
| 776 |
$finish->($body, undef, undef, 1); |
| 777 |
}); |
| 778 |
} |
| 779 |
}; |
| 780 |
|
| 781 |
$_[0]->push_read (line => $read_chunk); |
| 782 |
|
| 783 |
} elsif ($arg{on_body}) { |
| 784 |
$_[0]->on_error (sub { $finish->(undef, 599 => $_[2]) }); |
| 785 |
|
| 786 |
if ($len) { |
| 787 |
$_[0]->on_read (sub { |
| 788 |
$len -= length $_[0]{rbuf}; |
| 789 |
|
| 790 |
$arg{on_body}(delete $_[0]{rbuf}, \%hdr) |
| 791 |
or return $finish->(undef, 598 => "Request cancelled by on_body"); |
| 792 |
|
| 793 |
$len > 0 |
| 794 |
or $finish->("", undef, undef, 1); |
| 795 |
}); |
| 796 |
} else { |
| 797 |
$_[0]->on_eof (sub { |
| 798 |
$finish->(""); |
| 799 |
}); |
| 800 |
$_[0]->on_read (sub { |
| 801 |
$arg{on_body}(delete $_[0]{rbuf}, \%hdr) |
| 802 |
or $finish->(undef, 598 => "Request cancelled by on_body"); |
| 803 |
}); |
| 804 |
} |
| 805 |
} else { |
| 806 |
$_[0]->on_eof (undef); |
| 807 |
|
| 808 |
if ($len) { |
| 809 |
$_[0]->on_error (sub { $finish->(undef, 599 => $_[2]) }); |
| 810 |
$_[0]->on_read (sub { |
| 811 |
$finish->((substr delete $_[0]{rbuf}, 0, $len, ""), undef, undef, 1) |
| 812 |
if $len <= length $_[0]{rbuf}; |
| 813 |
}); |
| 814 |
} else { |
| 815 |
$_[0]->on_error (sub { |
| 816 |
($! == Errno::EPIPE || !$!) |
| 817 |
? $finish->(delete $_[0]{rbuf}) |
| 818 |
: $finish->(undef, 599 => $_[2]); |
| 819 |
}); |
| 820 |
$_[0]->on_read (sub { }); |
| 821 |
} |
| 822 |
} |
| 823 |
} |
| 824 |
}; |
| 825 |
|
| 826 |
$state{handle}->push_read (line => $qr_nlnl, $state{read_response}); |
| 827 |
}; |
| 828 |
|
| 829 |
# now handle proxy-CONNECT method |
| 830 |
if ($proxy && $uscheme eq "https") { |
| 831 |
# oh dear, we have to wrap it into a connect request |
| 832 |
|
| 833 |
# maybe re-use $uauthority with patched port? |
| 834 |
$state{handle}->push_write ("CONNECT $uhost:$uport HTTP/1.0\015\012Host: $uhost\015\012\015\012"); |
| 835 |
$state{handle}->push_read (line => $qr_nlnl, sub { |
| 836 |
$_[1] =~ /^HTTP\/([0-9\.]+) \s+ ([0-9]{3}) (?: \s+ ([^\015\012]*) )?/ix |
| 837 |
or return (%state = (), $cb->(undef, { @pseudo, Status => 599, Reason => "Invalid proxy connect response ($_[1])" })); |
| 838 |
|
| 839 |
if ($2 == 200) { |
| 840 |
$rpath = $upath; |
| 841 |
&$handle_actual_request; |
| 842 |
} else { |
| 843 |
%state = (); |
| 844 |
$cb->(undef, { @pseudo, Status => $2, Reason => $3 }); |
| 845 |
} |
| 846 |
}); |
| 847 |
} else { |
| 848 |
&$handle_actual_request; |
| 849 |
} |
| 850 |
}; |
| 851 |
|
| 852 |
my $tcp_connect = $arg{tcp_connect} |
| 853 |
|| do { require AnyEvent::Socket; \&AnyEvent::Socket::tcp_connect }; |
| 854 |
|
| 855 |
$state{connect_guard} = $tcp_connect->($rhost, $rport, $connect_cb, $arg{on_prepare} || sub { $timeout }); |
| 856 |
|
| 857 |
}; |
| 858 |
|
| 859 |
defined wantarray && AnyEvent::Util::guard { %state = () } |
| 860 |
} |
| 861 |
|
| 862 |
sub http_get($@) { |
| 863 |
unshift @_, "GET"; |
| 864 |
&http_request |
| 865 |
} |
| 866 |
|
| 867 |
sub http_head($@) { |
| 868 |
unshift @_, "HEAD"; |
| 869 |
&http_request |
| 870 |
} |
| 871 |
|
| 872 |
sub http_post($$@) { |
| 873 |
my $url = shift; |
| 874 |
unshift @_, "POST", $url, "body"; |
| 875 |
&http_request |
| 876 |
} |
| 877 |
|
| 878 |
=back |
| 879 |
|
| 880 |
=head2 DNS CACHING |
| 881 |
|
| 882 |
AnyEvent::HTTP uses the AnyEvent::Socket::tcp_connect function for |
| 883 |
the actual connection, which in turn uses AnyEvent::DNS to resolve |
| 884 |
hostnames. The latter is a simple stub resolver and does no caching |
| 885 |
on its own. If you want DNS caching, you currently have to provide |
| 886 |
your own default resolver (by storing a suitable resolver object in |
| 887 |
C<$AnyEvent::DNS::RESOLVER>). |
| 888 |
|
| 889 |
=head2 GLOBAL FUNCTIONS AND VARIABLES |
| 890 |
|
| 891 |
=over 4 |
| 892 |
|
| 893 |
=item AnyEvent::HTTP::set_proxy "proxy-url" |
| 894 |
|
| 895 |
Sets the default proxy server to use. The proxy-url must begin with a |
| 896 |
string of the form C<http://host:port> (optionally C<https:...>), croaks |
| 897 |
otherwise. |
| 898 |
|
| 899 |
To clear an already-set proxy, use C<undef>. |
| 900 |
|
| 901 |
=item $date = AnyEvent::HTTP::format_date $timestamp |
| 902 |
|
| 903 |
Takes a POSIX timestamp (seconds since the epoch) and formats it as a HTTP |
| 904 |
Date (RFC 2616). |
| 905 |
|
| 906 |
=item $timestamp = AnyEvent::HTTP::parse_date $date |
| 907 |
|
| 908 |
Takes a HTTP Date (RFC 2616) and returns the corresponding POSIX |
| 909 |
timestamp, or C<undef> if the date cannot be parsed. |
| 910 |
|
| 911 |
=item $AnyEvent::HTTP::MAX_RECURSE |
| 912 |
|
| 913 |
The default value for the C<recurse> request parameter (default: C<10>). |
| 914 |
|
| 915 |
=item $AnyEvent::HTTP::USERAGENT |
| 916 |
|
| 917 |
The default value for the C<User-Agent> header (the default is |
| 918 |
C<Mozilla/5.0 (compatible; U; AnyEvent-HTTP/$VERSION; +http://software.schmorp.de/pkg/AnyEvent)>). |
| 919 |
|
| 920 |
=item $AnyEvent::HTTP::MAX_PER_HOST |
| 921 |
|
| 922 |
The maximum number of concurrent connections to the same host (identified |
| 923 |
by the hostname). If the limit is exceeded, then the additional requests |
| 924 |
are queued until previous connections are closed. |
| 925 |
|
| 926 |
The default value for this is C<4>, and it is highly advisable to not |
| 927 |
increase it. |
| 928 |
|
| 929 |
=item $AnyEvent::HTTP::ACTIVE |
| 930 |
|
| 931 |
The number of active connections. This is not the number of currently |
| 932 |
running requests, but the number of currently open and non-idle TCP |
| 933 |
connections. This number of can be useful for load-leveling. |
| 934 |
|
| 935 |
=back |
| 936 |
|
| 937 |
=cut |
| 938 |
|
| 939 |
our @month = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec); |
| 940 |
our @weekday = qw(Sun Mon Tue Wed Thu Fri Sat); |
| 941 |
|
| 942 |
sub format_date($) { |
| 943 |
my ($time) = @_; |
| 944 |
|
| 945 |
# RFC 822/1123 format |
| 946 |
my ($S, $M, $H, $mday, $mon, $year, $wday, $yday, undef) = gmtime $time; |
| 947 |
|
| 948 |
sprintf "%s, %02d %s %04d %02d:%02d:%02d GMT", |
| 949 |
$weekday[$wday], $mday, $month[$mon], $year + 1900, |
| 950 |
$H, $M, $S; |
| 951 |
} |
| 952 |
|
| 953 |
sub parse_date($) { |
| 954 |
my ($date) = @_; |
| 955 |
|
| 956 |
my ($d, $m, $y, $H, $M, $S); |
| 957 |
|
| 958 |
if ($date =~ /^[A-Z][a-z][a-z], ([0-9][0-9]) ([A-Z][a-z][a-z]) ([0-9][0-9][0-9][0-9]) ([0-9][0-9]):([0-9][0-9]):([0-9][0-9]) GMT$/) { |
| 959 |
# RFC 822/1123, required by RFC 2616 |
| 960 |
($d, $m, $y, $H, $M, $S) = ($1, $2, $3, $4, $5, $6); |
| 961 |
|
| 962 |
} elsif ($date =~ /^[A-Z][a-z]+, ([0-9][0-9])-([A-Z][a-z][a-z])-([0-9][0-9]) ([0-9][0-9]):([0-9][0-9]):([0-9][0-9]) GMT$/) { |
| 963 |
# RFC 850 |
| 964 |
($d, $m, $y, $H, $M, $S) = ($1, $2, $3 < 69 ? $3 + 2000 : $3 + 1900, $4, $5, $6); |
| 965 |
|
| 966 |
} elsif ($date =~ /^[A-Z][a-z][a-z] ([A-Z][a-z][a-z]) ([0-9 ][0-9]) ([0-9][0-9]):([0-9][0-9]):([0-9][0-9]) ([0-9][0-9][0-9][0-9])$/) { |
| 967 |
# ISO C's asctime |
| 968 |
($d, $m, $y, $H, $M, $S) = ($2, $1, $6, $3, $4, $5); |
| 969 |
} |
| 970 |
# other formats fail in the loop below |
| 971 |
|
| 972 |
for (0..11) { |
| 973 |
if ($m eq $month[$_]) { |
| 974 |
require Time::Local; |
| 975 |
return Time::Local::timegm ($S, $M, $H, $d, $_, $y); |
| 976 |
} |
| 977 |
} |
| 978 |
|
| 979 |
undef |
| 980 |
} |
| 981 |
|
| 982 |
sub set_proxy($) { |
| 983 |
if (length $_[0]) { |
| 984 |
$_[0] =~ m%^(https?):// ([^:/]+) (?: : (\d*) )?%ix |
| 985 |
or Carp::croak "$_[0]: invalid proxy URL"; |
| 986 |
$PROXY = [$2, $3 || 3128, $1] |
| 987 |
} else { |
| 988 |
undef $PROXY; |
| 989 |
} |
| 990 |
} |
| 991 |
|
| 992 |
# initialise proxy from environment |
| 993 |
eval { |
| 994 |
set_proxy $ENV{http_proxy}; |
| 995 |
}; |
| 996 |
|
| 997 |
=head2 SOCKS PROXIES |
| 998 |
|
| 999 |
Socks proxies are not directly supported by AnyEvent::HTTP. You can |
| 1000 |
compile your perl to support socks, or use an external program such as |
| 1001 |
F<socksify> (dante) or F<tsocks> to make your program use a socks proxy |
| 1002 |
transparently. |
| 1003 |
|
| 1004 |
Alternatively, for AnyEvent::HTTP only, you can use your own |
| 1005 |
C<tcp_connect> function that does the proxy handshake - here is an example |
| 1006 |
that works with socks4a proxies: |
| 1007 |
|
| 1008 |
use Errno; |
| 1009 |
use AnyEvent::Util; |
| 1010 |
use AnyEvent::Socket; |
| 1011 |
use AnyEvent::Handle; |
| 1012 |
|
| 1013 |
# host, port and username of/for your socks4a proxy |
| 1014 |
my $socks_host = "10.0.0.23"; |
| 1015 |
my $socks_port = 9050; |
| 1016 |
my $socks_user = ""; |
| 1017 |
|
| 1018 |
sub socks4a_connect { |
| 1019 |
my ($host, $port, $connect_cb, $prepare_cb) = @_; |
| 1020 |
|
| 1021 |
my $hdl = new AnyEvent::Handle |
| 1022 |
connect => [$socks_host, $socks_port], |
| 1023 |
on_prepare => sub { $prepare_cb->($_[0]{fh}) }, |
| 1024 |
on_error => sub { $connect_cb->() }, |
| 1025 |
; |
| 1026 |
|
| 1027 |
$hdl->push_write (pack "CCnNZ*Z*", 4, 1, $port, 1, $socks_user, $host); |
| 1028 |
|
| 1029 |
$hdl->push_read (chunk => 8, sub { |
| 1030 |
my ($hdl, $chunk) = @_; |
| 1031 |
my ($status, $port, $ipn) = unpack "xCna4", $chunk; |
| 1032 |
|
| 1033 |
if ($status == 0x5a) { |
| 1034 |
$connect_cb->($hdl->{fh}, (format_address $ipn) . ":$port"); |
| 1035 |
} else { |
| 1036 |
$! = Errno::ENXIO; $connect_cb->(); |
| 1037 |
} |
| 1038 |
}); |
| 1039 |
|
| 1040 |
$hdl |
| 1041 |
} |
| 1042 |
|
| 1043 |
Use C<socks4a_connect> instead of C<tcp_connect> when doing C<http_request>s, |
| 1044 |
possibly after switching off other proxy types: |
| 1045 |
|
| 1046 |
AnyEvent::HTTP::set_proxy undef; # usually you do not want other proxies |
| 1047 |
|
| 1048 |
http_get 'http://www.google.com', tcp_connect => \&socks4a_connect, sub { |
| 1049 |
my ($data, $headers) = @_; |
| 1050 |
... |
| 1051 |
}; |
| 1052 |
|
| 1053 |
=head1 SEE ALSO |
| 1054 |
|
| 1055 |
L<AnyEvent>. |
| 1056 |
|
| 1057 |
=head1 AUTHOR |
| 1058 |
|
| 1059 |
Marc Lehmann <schmorp@schmorp.de> |
| 1060 |
http://home.schmorp.de/ |
| 1061 |
|
| 1062 |
With many thanks to Дмитрий Шалашов, who provided countless |
| 1063 |
testcases and bugreports. |
| 1064 |
|
| 1065 |
=cut |
| 1066 |
|
| 1067 |
1 |
| 1068 |
|
