| 1 |
=head1 NAME |
| 2 |
|
| 3 |
AnyEvent::HTTP - simple but non-blocking HTTP/HTTPS client |
| 4 |
|
| 5 |
=head1 SYNOPSIS |
| 6 |
|
| 7 |
use AnyEvent::HTTP; |
| 8 |
|
| 9 |
http_get "http://www.nethype.de/", sub { print $_[1] }; |
| 10 |
|
| 11 |
# ... do something else here |
| 12 |
|
| 13 |
=head1 DESCRIPTION |
| 14 |
|
| 15 |
This module is an L<AnyEvent> user, you need to make sure that you use and |
| 16 |
run a supported event loop. |
| 17 |
|
| 18 |
This module implements a simple, stateless and non-blocking HTTP |
| 19 |
client. It supports GET, POST and other request methods, cookies and more, |
| 20 |
all on a very low level. It can follow redirects supports proxies and |
| 21 |
automatically limits the number of connections to the values specified in |
| 22 |
the RFC. |
| 23 |
|
| 24 |
It should generally be a "good client" that is enough for most HTTP |
| 25 |
tasks. Simple tasks should be simple, but complex tasks should still be |
| 26 |
possible as the user retains control over request and response headers. |
| 27 |
|
| 28 |
The caller is responsible for authentication management, cookies (if |
| 29 |
the simplistic implementation in this module doesn't suffice), referer |
| 30 |
and other high-level protocol details for which this module offers only |
| 31 |
limited support. |
| 32 |
|
| 33 |
=head2 METHODS |
| 34 |
|
| 35 |
=over 4 |
| 36 |
|
| 37 |
=cut |
| 38 |
|
| 39 |
package AnyEvent::HTTP; |
| 40 |
|
| 41 |
use strict; |
| 42 |
no warnings; |
| 43 |
|
| 44 |
use Errno (); |
| 45 |
|
| 46 |
use AnyEvent 5.0 (); |
| 47 |
use AnyEvent::Util (); |
| 48 |
use AnyEvent::Handle (); |
| 49 |
|
| 50 |
use base Exporter::; |
| 51 |
|
| 52 |
our $VERSION = '1.5'; |
| 53 |
|
| 54 |
our @EXPORT = qw(http_get http_post http_head http_request); |
| 55 |
|
| 56 |
our $USERAGENT = "Mozilla/5.0 (compatible; U; AnyEvent-HTTP/$VERSION; +http://software.schmorp.de/pkg/AnyEvent)"; |
| 57 |
our $MAX_RECURSE = 10; |
| 58 |
our $MAX_PERSISTENT = 8; |
| 59 |
our $PERSISTENT_TIMEOUT = 2; |
| 60 |
our $TIMEOUT = 300; |
| 61 |
|
| 62 |
# changing these is evil |
| 63 |
our $MAX_PERSISTENT_PER_HOST = 0; |
| 64 |
our $MAX_PER_HOST = 4; |
| 65 |
|
| 66 |
our $PROXY; |
| 67 |
our $ACTIVE = 0; |
| 68 |
|
| 69 |
my %KA_COUNT; # number of open keep-alive connections per host |
| 70 |
my %CO_SLOT; # number of open connections, and wait queue, per host |
| 71 |
|
| 72 |
=item http_get $url, key => value..., $cb->($data, $headers) |
| 73 |
|
| 74 |
Executes an HTTP-GET request. See the http_request function for details on |
| 75 |
additional parameters and the return value. |
| 76 |
|
| 77 |
=item http_head $url, key => value..., $cb->($data, $headers) |
| 78 |
|
| 79 |
Executes an HTTP-HEAD request. See the http_request function for details |
| 80 |
on additional parameters and the return value. |
| 81 |
|
| 82 |
=item http_post $url, $body, key => value..., $cb->($data, $headers) |
| 83 |
|
| 84 |
Executes an HTTP-POST request with a request body of C<$body>. See the |
| 85 |
http_request function for details on additional parameters and the return |
| 86 |
value. |
| 87 |
|
| 88 |
=item http_request $method => $url, key => value..., $cb->($data, $headers) |
| 89 |
|
| 90 |
Executes a HTTP request of type C<$method> (e.g. C<GET>, C<POST>). The URL |
| 91 |
must be an absolute http or https URL. |
| 92 |
|
| 93 |
When called in void context, nothing is returned. In other contexts, |
| 94 |
C<http_request> returns a "cancellation guard" - you have to keep the |
| 95 |
object at least alive until the callback get called. If the object gets |
| 96 |
destroyed before the callback is called, the request will be cancelled. |
| 97 |
|
| 98 |
The callback will be called with the response body data as first argument |
| 99 |
(or C<undef> if an error occured), and a hash-ref with response headers |
| 100 |
(and trailers) as second argument. |
| 101 |
|
| 102 |
All the headers in that hash are lowercased. In addition to the response |
| 103 |
headers, the "pseudo-headers" (uppercase to avoid clashing with possible |
| 104 |
response headers) C<HTTPVersion>, C<Status> and C<Reason> contain the |
| 105 |
three parts of the HTTP Status-Line of the same name. If an error occurs |
| 106 |
during the body phase of a request, then the original C<Status> and |
| 107 |
C<Reason> values from the header are available as C<OrigStatus> and |
| 108 |
C<OrigReason>. |
| 109 |
|
| 110 |
The pseudo-header C<URL> contains the actual URL (which can differ from |
| 111 |
the requested URL when following redirects - for example, you might get |
| 112 |
an error that your URL scheme is not supported even though your URL is a |
| 113 |
valid http URL because it redirected to an ftp URL, in which case you can |
| 114 |
look at the URL pseudo header). |
| 115 |
|
| 116 |
The pseudo-header C<Redirect> only exists when the request was a result |
| 117 |
of an internal redirect. In that case it is an array reference with |
| 118 |
the C<($data, $headers)> from the redirect response. Note that this |
| 119 |
response could in turn be the result of a redirect itself, and C<< |
| 120 |
$headers->{Redirect}[1]{Redirect} >> will then contain the original |
| 121 |
response, and so on. |
| 122 |
|
| 123 |
If the server sends a header multiple times, then their contents will be |
| 124 |
joined together with a comma (C<,>), as per the HTTP spec. |
| 125 |
|
| 126 |
If an internal error occurs, such as not being able to resolve a hostname, |
| 127 |
then C<$data> will be C<undef>, C<< $headers->{Status} >> will be C<59x> |
| 128 |
(usually C<599>) and the C<Reason> pseudo-header will contain an error |
| 129 |
message. |
| 130 |
|
| 131 |
A typical callback might look like this: |
| 132 |
|
| 133 |
sub { |
| 134 |
my ($body, $hdr) = @_; |
| 135 |
|
| 136 |
if ($hdr->{Status} =~ /^2/) { |
| 137 |
... everything should be ok |
| 138 |
} else { |
| 139 |
print "error, $hdr->{Status} $hdr->{Reason}\n"; |
| 140 |
} |
| 141 |
} |
| 142 |
|
| 143 |
Additional parameters are key-value pairs, and are fully optional. They |
| 144 |
include: |
| 145 |
|
| 146 |
=over 4 |
| 147 |
|
| 148 |
=item recurse => $count (default: $MAX_RECURSE) |
| 149 |
|
| 150 |
Whether to recurse requests or not, e.g. on redirects, authentication |
| 151 |
retries and so on, and how often to do so. |
| 152 |
|
| 153 |
=item headers => hashref |
| 154 |
|
| 155 |
The request headers to use. Currently, C<http_request> may provide its own |
| 156 |
C<Host:>, C<Content-Length:>, C<Connection:> and C<Cookie:> headers and |
| 157 |
will provide defaults at least for C<TE:>, C<Referer:> and C<User-Agent:> |
| 158 |
(this can be suppressed by using C<undef> for these headers in which case |
| 159 |
they won't be sent at all). |
| 160 |
|
| 161 |
=item timeout => $seconds |
| 162 |
|
| 163 |
The time-out to use for various stages - each connect attempt will reset |
| 164 |
the timeout, as will read or write activity, i.e. this is not an overall |
| 165 |
timeout. |
| 166 |
|
| 167 |
Default timeout is 5 minutes. |
| 168 |
|
| 169 |
=item proxy => [$host, $port[, $scheme]] or undef |
| 170 |
|
| 171 |
Use the given http proxy for all requests. If not specified, then the |
| 172 |
default proxy (as specified by C<$ENV{http_proxy}>) is used. |
| 173 |
|
| 174 |
C<$scheme> must be either missing, C<http> for HTTP or C<https> for |
| 175 |
HTTPS. |
| 176 |
|
| 177 |
=item body => $string |
| 178 |
|
| 179 |
The request body, usually empty. Will be sent as-is (future versions of |
| 180 |
this module might offer more options). |
| 181 |
|
| 182 |
=item cookie_jar => $hash_ref |
| 183 |
|
| 184 |
Passing this parameter enables (simplified) cookie-processing, loosely |
| 185 |
based on the original netscape specification. |
| 186 |
|
| 187 |
The C<$hash_ref> must be an (initially empty) hash reference which will |
| 188 |
get updated automatically. It is possible to save the cookie jar to |
| 189 |
persistent storage with something like JSON or Storable, but this is not |
| 190 |
recommended, as session-only cookies might survive longer than expected. |
| 191 |
|
| 192 |
Note that this cookie implementation is not meant to be complete. If |
| 193 |
you want complete cookie management you have to do that on your |
| 194 |
own. C<cookie_jar> is meant as a quick fix to get some cookie-using sites |
| 195 |
working. Cookies are a privacy disaster, do not use them unless required |
| 196 |
to. |
| 197 |
|
| 198 |
When cookie processing is enabled, the C<Cookie:> and C<Set-Cookie:> |
| 199 |
headers will be set and handled by this module, otherwise they will be |
| 200 |
left untouched. |
| 201 |
|
| 202 |
=item tls_ctx => $scheme | $tls_ctx |
| 203 |
|
| 204 |
Specifies the AnyEvent::TLS context to be used for https connections. This |
| 205 |
parameter follows the same rules as the C<tls_ctx> parameter to |
| 206 |
L<AnyEvent::Handle>, but additionally, the two strings C<low> or |
| 207 |
C<high> can be specified, which give you a predefined low-security (no |
| 208 |
verification, highest compatibility) and high-security (CA and common-name |
| 209 |
verification) TLS context. |
| 210 |
|
| 211 |
The default for this option is C<low>, which could be interpreted as "give |
| 212 |
me the page, no matter what". |
| 213 |
|
| 214 |
=item on_prepare => $callback->($fh) |
| 215 |
|
| 216 |
In rare cases you need to "tune" the socket before it is used to |
| 217 |
connect (for exmaple, to bind it on a given IP address). This parameter |
| 218 |
overrides the prepare callback passed to C<AnyEvent::Socket::tcp_connect> |
| 219 |
and behaves exactly the same way (e.g. it has to provide a |
| 220 |
timeout). See the description for the C<$prepare_cb> argument of |
| 221 |
C<AnyEvent::Socket::tcp_connect> for details. |
| 222 |
|
| 223 |
=item tcp_connect => $callback->($host, $service, $connect_cb, $prepare_cb) |
| 224 |
|
| 225 |
In even rarer cases you want total control over how AnyEvent::HTTP |
| 226 |
establishes connections. Normally it uses L<AnyEvent::Socket::tcp_connect> |
| 227 |
to do this, but you can provide your own C<tcp_connect> function - |
| 228 |
obviously, it has to follow the same calling conventions, except that it |
| 229 |
may always return a connection guard object. |
| 230 |
|
| 231 |
There are probably lots of weird uses for this function, starting from |
| 232 |
tracing the hosts C<http_request> actually tries to connect, to (inexact |
| 233 |
but fast) host => IP address caching or even socks protocol support. |
| 234 |
|
| 235 |
=item on_header => $callback->($headers) |
| 236 |
|
| 237 |
When specified, this callback will be called with the header hash as soon |
| 238 |
as headers have been successfully received from the remote server (not on |
| 239 |
locally-generated errors). |
| 240 |
|
| 241 |
It has to return either true (in which case AnyEvent::HTTP will continue), |
| 242 |
or false, in which case AnyEvent::HTTP will cancel the download (and call |
| 243 |
the finish callback with an error code of C<598>). |
| 244 |
|
| 245 |
This callback is useful, among other things, to quickly reject unwanted |
| 246 |
content, which, if it is supposed to be rare, can be faster than first |
| 247 |
doing a C<HEAD> request. |
| 248 |
|
| 249 |
The downside is that cancelling the request makes it impossible to re-use |
| 250 |
the connection. Also, the C<on_header> callback will not receive any |
| 251 |
trailer (headers sent after the response body). |
| 252 |
|
| 253 |
Example: cancel the request unless the content-type is "text/html". |
| 254 |
|
| 255 |
on_header => sub { |
| 256 |
$_[0]{"content-type"} =~ /^text\/html\s*(?:;|$)/ |
| 257 |
}, |
| 258 |
|
| 259 |
=item on_body => $callback->($partial_body, $headers) |
| 260 |
|
| 261 |
When specified, all body data will be passed to this callback instead of |
| 262 |
to the completion callback. The completion callback will get the empty |
| 263 |
string instead of the body data. |
| 264 |
|
| 265 |
It has to return either true (in which case AnyEvent::HTTP will continue), |
| 266 |
or false, in which case AnyEvent::HTTP will cancel the download (and call |
| 267 |
the completion callback with an error code of C<598>). |
| 268 |
|
| 269 |
The downside to cancelling the request is that it makes it impossible to |
| 270 |
re-use the connection. |
| 271 |
|
| 272 |
This callback is useful when the data is too large to be held in memory |
| 273 |
(so the callback writes it to a file) or when only some information should |
| 274 |
be extracted, or when the body should be processed incrementally. |
| 275 |
|
| 276 |
It is usually preferred over doing your own body handling via |
| 277 |
C<want_body_handle>, but in case of streaming APIs, where HTTP is |
| 278 |
only used to create a connection, C<want_body_handle> is the better |
| 279 |
alternative, as it allows you to install your own event handler, reducing |
| 280 |
resource usage. |
| 281 |
|
| 282 |
=item want_body_handle => $enable |
| 283 |
|
| 284 |
When enabled (default is disabled), the behaviour of AnyEvent::HTTP |
| 285 |
changes considerably: after parsing the headers, and instead of |
| 286 |
downloading the body (if any), the completion callback will be |
| 287 |
called. Instead of the C<$body> argument containing the body data, the |
| 288 |
callback will receive the L<AnyEvent::Handle> object associated with the |
| 289 |
connection. In error cases, C<undef> will be passed. When there is no body |
| 290 |
(e.g. status C<304>), the empty string will be passed. |
| 291 |
|
| 292 |
The handle object might or might not be in TLS mode, might be connected to |
| 293 |
a proxy, be a persistent connection etc., and configured in unspecified |
| 294 |
ways. The user is responsible for this handle (it will not be used by this |
| 295 |
module anymore). |
| 296 |
|
| 297 |
This is useful with some push-type services, where, after the initial |
| 298 |
headers, an interactive protocol is used (typical example would be the |
| 299 |
push-style twitter API which starts a JSON/XML stream). |
| 300 |
|
| 301 |
If you think you need this, first have a look at C<on_body>, to see if |
| 302 |
that doesn't solve your problem in a better way. |
| 303 |
|
| 304 |
=back |
| 305 |
|
| 306 |
Example: do a simple HTTP GET request for http://www.nethype.de/ and print |
| 307 |
the response body. |
| 308 |
|
| 309 |
http_request GET => "http://www.nethype.de/", sub { |
| 310 |
my ($body, $hdr) = @_; |
| 311 |
print "$body\n"; |
| 312 |
}; |
| 313 |
|
| 314 |
Example: do a HTTP HEAD request on https://www.google.com/, use a |
| 315 |
timeout of 30 seconds. |
| 316 |
|
| 317 |
http_request |
| 318 |
GET => "https://www.google.com", |
| 319 |
timeout => 30, |
| 320 |
sub { |
| 321 |
my ($body, $hdr) = @_; |
| 322 |
use Data::Dumper; |
| 323 |
print Dumper $hdr; |
| 324 |
} |
| 325 |
; |
| 326 |
|
| 327 |
Example: do another simple HTTP GET request, but immediately try to |
| 328 |
cancel it. |
| 329 |
|
| 330 |
my $request = http_request GET => "http://www.nethype.de/", sub { |
| 331 |
my ($body, $hdr) = @_; |
| 332 |
print "$body\n"; |
| 333 |
}; |
| 334 |
|
| 335 |
undef $request; |
| 336 |
|
| 337 |
=cut |
| 338 |
|
| 339 |
sub _slot_schedule; |
| 340 |
sub _slot_schedule($) { |
| 341 |
my $host = shift; |
| 342 |
|
| 343 |
while ($CO_SLOT{$host}[0] < $MAX_PER_HOST) { |
| 344 |
if (my $cb = shift @{ $CO_SLOT{$host}[1] }) { |
| 345 |
# somebody wants that slot |
| 346 |
++$CO_SLOT{$host}[0]; |
| 347 |
++$ACTIVE; |
| 348 |
|
| 349 |
$cb->(AnyEvent::Util::guard { |
| 350 |
--$ACTIVE; |
| 351 |
--$CO_SLOT{$host}[0]; |
| 352 |
_slot_schedule $host; |
| 353 |
}); |
| 354 |
} else { |
| 355 |
# nobody wants the slot, maybe we can forget about it |
| 356 |
delete $CO_SLOT{$host} unless $CO_SLOT{$host}[0]; |
| 357 |
last; |
| 358 |
} |
| 359 |
} |
| 360 |
} |
| 361 |
|
| 362 |
# wait for a free slot on host, call callback |
| 363 |
sub _get_slot($$) { |
| 364 |
push @{ $CO_SLOT{$_[0]}[1] }, $_[1]; |
| 365 |
|
| 366 |
_slot_schedule $_[0]; |
| 367 |
} |
| 368 |
|
| 369 |
# extract cookies from jar |
| 370 |
sub cookie_jar_extract($$$$) { |
| 371 |
my ($jar, $uscheme, $uhost, $upath) = @_; |
| 372 |
|
| 373 |
%$jar = () if $jar->{version} != 1; |
| 374 |
|
| 375 |
my @cookies; |
| 376 |
|
| 377 |
while (my ($chost, $paths) = each %$jar) { |
| 378 |
next unless ref $paths; |
| 379 |
|
| 380 |
if ($chost =~ /^\./) { |
| 381 |
next unless $chost eq substr $uhost, -length $chost; |
| 382 |
} elsif ($chost =~ /\./) { |
| 383 |
next unless $chost eq $uhost; |
| 384 |
} else { |
| 385 |
next; |
| 386 |
} |
| 387 |
|
| 388 |
while (my ($cpath, $cookies) = each %$paths) { |
| 389 |
next unless $cpath eq substr $upath, 0, length $cpath; |
| 390 |
|
| 391 |
while (my ($cookie, $kv) = each %$cookies) { |
| 392 |
next if $uscheme ne "https" && exists $kv->{secure}; |
| 393 |
|
| 394 |
if (exists $kv->{expires}) { |
| 395 |
if (AE::now > parse_date ($kv->{expires})) { |
| 396 |
delete $cookies->{$cookie}; |
| 397 |
next; |
| 398 |
} |
| 399 |
} |
| 400 |
|
| 401 |
my $value = $kv->{value}; |
| 402 |
|
| 403 |
if ($value =~ /[=;,[:space:]]/) { |
| 404 |
$value =~ s/([\\"])/\\$1/g; |
| 405 |
$value = "\"$value\""; |
| 406 |
} |
| 407 |
|
| 408 |
push @cookies, "$cookie=$value"; |
| 409 |
} |
| 410 |
} |
| 411 |
} |
| 412 |
|
| 413 |
\@cookies |
| 414 |
} |
| 415 |
|
| 416 |
# parse set_cookie header into jar |
| 417 |
sub cookie_jar_set_cookie($$$) { |
| 418 |
my ($jar, $set_cookie, $uhost) = @_; |
| 419 |
|
| 420 |
for ($set_cookie) { |
| 421 |
# parse NAME=VALUE |
| 422 |
my @kv; |
| 423 |
|
| 424 |
while ( |
| 425 |
m{ |
| 426 |
\G\s* |
| 427 |
(?: |
| 428 |
expires \s*=\s* ([A-Z][a-z][a-z],\ [^,;]+) |
| 429 |
| ([^=;,[:space:]]+) \s*=\s* (?: "((?:[^\\"]+|\\.)*)" | ([^=;,[:space:]]*) ) |
| 430 |
) |
| 431 |
}gcxsi |
| 432 |
) { |
| 433 |
my $name = $2; |
| 434 |
my $value = $4; |
| 435 |
|
| 436 |
unless (defined $name) { |
| 437 |
# expires |
| 438 |
$name = "expires"; |
| 439 |
$value = $1; |
| 440 |
} elsif (!defined $value) { |
| 441 |
# quoted |
| 442 |
$value = $3; |
| 443 |
$value =~ s/\\(.)/$1/gs; |
| 444 |
} |
| 445 |
|
| 446 |
push @kv, lc $name, $value; |
| 447 |
|
| 448 |
last unless /\G\s*;/gc; |
| 449 |
} |
| 450 |
|
| 451 |
last unless @kv; |
| 452 |
|
| 453 |
my $name = shift @kv; |
| 454 |
my %kv = (value => shift @kv, @kv); |
| 455 |
|
| 456 |
$kv{expires} ||= format_date (AE::now + $kv{"max-age"}) |
| 457 |
if exists $kv{"max-age"}; |
| 458 |
|
| 459 |
my $cdom; |
| 460 |
my $cpath = (delete $kv{path}) || "/"; |
| 461 |
|
| 462 |
if (exists $kv{domain}) { |
| 463 |
$cdom = delete $kv{domain}; |
| 464 |
|
| 465 |
$cdom =~ s/^\.?/./; # make sure it starts with a "." |
| 466 |
|
| 467 |
next if $cdom =~ /\.$/; |
| 468 |
|
| 469 |
# this is not rfc-like and not netscape-like. go figure. |
| 470 |
my $ndots = $cdom =~ y/.//; |
| 471 |
next if $ndots < ($cdom =~ /\.[^.][^.]\.[^.][^.]$/ ? 3 : 2); |
| 472 |
} else { |
| 473 |
$cdom = $uhost; |
| 474 |
} |
| 475 |
|
| 476 |
# store it |
| 477 |
$jar->{version} = 1; |
| 478 |
$jar->{$cdom}{$cpath}{$name} = \%kv; |
| 479 |
|
| 480 |
redo if /\G\s*,/gc; |
| 481 |
} |
| 482 |
} |
| 483 |
|
| 484 |
# continue to parse $_ for headers and place them into the arg |
| 485 |
sub parse_hdr() { |
| 486 |
my %hdr; |
| 487 |
|
| 488 |
# things seen, not parsed: |
| 489 |
# p3pP="NON CUR OTPi OUR NOR UNI" |
| 490 |
|
| 491 |
$hdr{lc $1} .= ",$2" |
| 492 |
while /\G |
| 493 |
([^:\000-\037]*): |
| 494 |
[\011\040]* |
| 495 |
((?: [^\012]+ | \012[\011\040] )*) |
| 496 |
\012 |
| 497 |
/gxc; |
| 498 |
|
| 499 |
/\G$/ |
| 500 |
or return; |
| 501 |
|
| 502 |
# remove the "," prefix we added to all headers above |
| 503 |
substr $_, 0, 1, "" |
| 504 |
for values %hdr; |
| 505 |
|
| 506 |
\%hdr |
| 507 |
} |
| 508 |
|
| 509 |
our $qr_nlnl = qr{(?<![^\012])\015?\012}; |
| 510 |
|
| 511 |
our $TLS_CTX_LOW = { cache => 1, sslv2 => 1 }; |
| 512 |
our $TLS_CTX_HIGH = { cache => 1, verify => 1, verify_peername => "https" }; |
| 513 |
|
| 514 |
sub http_request($$@) { |
| 515 |
my $cb = pop; |
| 516 |
my ($method, $url, %arg) = @_; |
| 517 |
|
| 518 |
my %hdr; |
| 519 |
|
| 520 |
$arg{tls_ctx} = $TLS_CTX_LOW if $arg{tls_ctx} eq "low" || !exists $arg{tls_ctx}; |
| 521 |
$arg{tls_ctx} = $TLS_CTX_HIGH if $arg{tls_ctx} eq "high"; |
| 522 |
|
| 523 |
$method = uc $method; |
| 524 |
|
| 525 |
if (my $hdr = $arg{headers}) { |
| 526 |
while (my ($k, $v) = each %$hdr) { |
| 527 |
$hdr{lc $k} = $v; |
| 528 |
} |
| 529 |
} |
| 530 |
|
| 531 |
# pseudo headers for all subsequent responses |
| 532 |
my @pseudo = (URL => $url); |
| 533 |
push @pseudo, Redirect => delete $arg{Redirect} if exists $arg{Redirect}; |
| 534 |
|
| 535 |
my $recurse = exists $arg{recurse} ? delete $arg{recurse} : $MAX_RECURSE; |
| 536 |
|
| 537 |
return $cb->(undef, { @pseudo, Status => 599, Reason => "Too many redirections" }) |
| 538 |
if $recurse < 0; |
| 539 |
|
| 540 |
my $proxy = $arg{proxy} || $PROXY; |
| 541 |
my $timeout = $arg{timeout} || $TIMEOUT; |
| 542 |
|
| 543 |
my ($uscheme, $uauthority, $upath, $query, $fragment) = |
| 544 |
$url =~ m|(?:([^:/?#]+):)?(?://([^/?#]*))?([^?#]*)(?:(\?[^#]*))?(?:#(.*))?|; |
| 545 |
|
| 546 |
$uscheme = lc $uscheme; |
| 547 |
|
| 548 |
my $uport = $uscheme eq "http" ? 80 |
| 549 |
: $uscheme eq "https" ? 443 |
| 550 |
: return $cb->(undef, { @pseudo, Status => 599, Reason => "Only http and https URL schemes supported" }); |
| 551 |
|
| 552 |
$uauthority =~ /^(?: .*\@ )? ([^\@:]+) (?: : (\d+) )?$/x |
| 553 |
or return $cb->(undef, { @pseudo, Status => 599, Reason => "Unparsable URL" }); |
| 554 |
|
| 555 |
my $uhost = $1; |
| 556 |
$uport = $2 if defined $2; |
| 557 |
|
| 558 |
$hdr{host} = defined $2 ? "$uhost:$2" : "$uhost" |
| 559 |
unless exists $hdr{host}; |
| 560 |
|
| 561 |
$uhost =~ s/^\[(.*)\]$/$1/; |
| 562 |
$upath .= $query if length $query; |
| 563 |
|
| 564 |
$upath =~ s%^/?%/%; |
| 565 |
|
| 566 |
# cookie processing |
| 567 |
if (my $jar = $arg{cookie_jar}) { |
| 568 |
my $cookies = cookie_jar_extract $jar, $uscheme, $uhost, $upath; |
| 569 |
|
| 570 |
$hdr{cookie} = join "; ", @$cookies |
| 571 |
if @$cookies; |
| 572 |
} |
| 573 |
|
| 574 |
my ($rhost, $rport, $rscheme, $rpath); # request host, port, path |
| 575 |
|
| 576 |
if ($proxy) { |
| 577 |
($rpath, $rhost, $rport, $rscheme) = ($url, @$proxy); |
| 578 |
|
| 579 |
$rscheme = "http" unless defined $rscheme; |
| 580 |
|
| 581 |
# don't support https requests over https-proxy transport, |
| 582 |
# can't be done with tls as spec'ed, unless you double-encrypt. |
| 583 |
$rscheme = "http" if $uscheme eq "https" && $rscheme eq "https"; |
| 584 |
} else { |
| 585 |
($rhost, $rport, $rscheme, $rpath) = ($uhost, $uport, $uscheme, $upath); |
| 586 |
} |
| 587 |
|
| 588 |
# leave out fragment and query string, just a heuristic |
| 589 |
$hdr{referer} = "$uscheme://$uauthority$upath" unless exists $hdr{referer}; |
| 590 |
$hdr{"user-agent"} = $USERAGENT unless exists $hdr{"user-agent"}; |
| 591 |
|
| 592 |
$hdr{"content-length"} = length $arg{body} |
| 593 |
if length $arg{body} || $method ne "GET"; |
| 594 |
|
| 595 |
$hdr{connection} = "close TE"; #1.1 |
| 596 |
$hdr{te} = "trailers" unless exists $hdr{te}; #1.1 |
| 597 |
|
| 598 |
my %state = (connect_guard => 1); |
| 599 |
|
| 600 |
_get_slot $uhost, sub { |
| 601 |
$state{slot_guard} = shift; |
| 602 |
|
| 603 |
return unless $state{connect_guard}; |
| 604 |
|
| 605 |
my $connect_cb = sub { |
| 606 |
$state{fh} = shift |
| 607 |
or do { |
| 608 |
my $err = "$!"; |
| 609 |
%state = (); |
| 610 |
return $cb->(undef, { @pseudo, Status => 599, Reason => $err }); |
| 611 |
}; |
| 612 |
|
| 613 |
return unless delete $state{connect_guard}; |
| 614 |
|
| 615 |
# get handle |
| 616 |
$state{handle} = new AnyEvent::Handle |
| 617 |
fh => $state{fh}, |
| 618 |
peername => $rhost, |
| 619 |
tls_ctx => $arg{tls_ctx}, |
| 620 |
# these need to be reconfigured on keepalive handles |
| 621 |
timeout => $timeout, |
| 622 |
on_error => sub { |
| 623 |
%state = (); |
| 624 |
$cb->(undef, { @pseudo, Status => 599, Reason => $_[2] }); |
| 625 |
}, |
| 626 |
on_eof => sub { |
| 627 |
%state = (); |
| 628 |
$cb->(undef, { @pseudo, Status => 599, Reason => "Unexpected end-of-file" }); |
| 629 |
}, |
| 630 |
; |
| 631 |
|
| 632 |
# limit the number of persistent connections |
| 633 |
# keepalive not yet supported |
| 634 |
# if ($KA_COUNT{$_[1]} < $MAX_PERSISTENT_PER_HOST) { |
| 635 |
# ++$KA_COUNT{$_[1]}; |
| 636 |
# $state{handle}{ka_count_guard} = AnyEvent::Util::guard { |
| 637 |
# --$KA_COUNT{$_[1]} |
| 638 |
# }; |
| 639 |
# $hdr{connection} = "keep-alive"; |
| 640 |
# } |
| 641 |
|
| 642 |
$state{handle}->starttls ("connect") if $rscheme eq "https"; |
| 643 |
|
| 644 |
# handle actual, non-tunneled, request |
| 645 |
my $handle_actual_request = sub { |
| 646 |
$state{handle}->starttls ("connect") if $uscheme eq "https" && !exists $state{handle}{tls}; |
| 647 |
|
| 648 |
# send request |
| 649 |
$state{handle}->push_write ( |
| 650 |
"$method $rpath HTTP/1.1\015\012" |
| 651 |
. (join "", map "\u$_: $hdr{$_}\015\012", grep defined $hdr{$_}, keys %hdr) |
| 652 |
. "\015\012" |
| 653 |
. (delete $arg{body}) |
| 654 |
); |
| 655 |
|
| 656 |
# return if error occured during push_write() |
| 657 |
return unless %state; |
| 658 |
|
| 659 |
%hdr = (); # reduce memory usage, save a kitten, also make it possible to re-use |
| 660 |
|
| 661 |
# status line and headers |
| 662 |
$state{read_response} = sub { |
| 663 |
for ("$_[1]") { |
| 664 |
y/\015//d; # weed out any \015, as they show up in the weirdest of places. |
| 665 |
|
| 666 |
/^HTTP\/([0-9\.]+) \s+ ([0-9]{3}) (?: \s+ ([^\012]*) )? \012/igxc |
| 667 |
or return (%state = (), $cb->(undef, { @pseudo, Status => 599, Reason => "Invalid server response" })); |
| 668 |
|
| 669 |
# 100 Continue handling |
| 670 |
# should not happen as we don't send expect: 100-continue, |
| 671 |
# but we handle it just in case. |
| 672 |
# since we send the request body regardless, if we get an error |
| 673 |
# we are out of-sync, which we currently do NOT handle correctly. |
| 674 |
return $state{handle}->push_read (line => $qr_nlnl, $state{read_response}) |
| 675 |
if $2 eq 100; |
| 676 |
|
| 677 |
push @pseudo, |
| 678 |
HTTPVersion => $1, |
| 679 |
Status => $2, |
| 680 |
Reason => $3, |
| 681 |
; |
| 682 |
|
| 683 |
my $hdr = parse_hdr |
| 684 |
or return (%state = (), $cb->(undef, { @pseudo, Status => 599, Reason => "Garbled response headers" })); |
| 685 |
|
| 686 |
%hdr = (%$hdr, @pseudo); |
| 687 |
} |
| 688 |
|
| 689 |
# redirect handling |
| 690 |
# microsoft and other shitheads don't give a shit for following standards, |
| 691 |
# try to support some common forms of broken Location headers. |
| 692 |
if ($hdr{location} !~ /^(?: $ | [^:\/?\#]+ : )/x) { |
| 693 |
$hdr{location} =~ s/^\.\/+//; |
| 694 |
|
| 695 |
my $url = "$rscheme://$uhost:$uport"; |
| 696 |
|
| 697 |
unless ($hdr{location} =~ s/^\///) { |
| 698 |
$url .= $upath; |
| 699 |
$url =~ s/\/[^\/]*$//; |
| 700 |
} |
| 701 |
|
| 702 |
$hdr{location} = "$url/$hdr{location}"; |
| 703 |
} |
| 704 |
|
| 705 |
my $redirect; |
| 706 |
|
| 707 |
if ($recurse) { |
| 708 |
my $status = $hdr{Status}; |
| 709 |
|
| 710 |
# industry standard is to redirect POST as GET for |
| 711 |
# 301, 302 and 303, in contrast to http/1.0 and 1.1. |
| 712 |
# also, the UA should ask the user for 301 and 307 and POST, |
| 713 |
# industry standard seems to be to simply follow. |
| 714 |
# we go with the industry standard. |
| 715 |
if ($status == 301 or $status == 302 or $status == 303) { |
| 716 |
# HTTP/1.1 is unclear on how to mutate the method |
| 717 |
$method = "GET" unless $method eq "HEAD"; |
| 718 |
$redirect = 1; |
| 719 |
} elsif ($status == 307) { |
| 720 |
$redirect = 1; |
| 721 |
} |
| 722 |
} |
| 723 |
|
| 724 |
my $finish = sub { # ($data, $err_status, $err_reason[, $keepalive]) |
| 725 |
my $may_keep_alive = $_[3]; |
| 726 |
|
| 727 |
$state{handle}->destroy if $state{handle}; |
| 728 |
%state = (); |
| 729 |
|
| 730 |
if (defined $_[1]) { |
| 731 |
$hdr{OrigStatus} = $hdr{Status}; $hdr{Status} = $_[1]; |
| 732 |
$hdr{OrigReason} = $hdr{Reason}; $hdr{Reason} = $_[2]; |
| 733 |
} |
| 734 |
|
| 735 |
# set-cookie processing |
| 736 |
if ($arg{cookie_jar}) { |
| 737 |
cookie_jar_set_cookie $arg{cookie_jar}, $hdr{"set-cookie"}, $uhost; |
| 738 |
} |
| 739 |
|
| 740 |
if ($redirect && exists $hdr{location}) { |
| 741 |
# we ignore any errors, as it is very common to receive |
| 742 |
# Content-Length != 0 but no actual body |
| 743 |
# we also access %hdr, as $_[1] might be an erro |
| 744 |
http_request ( |
| 745 |
$method => $hdr{location}, |
| 746 |
%arg, |
| 747 |
recurse => $recurse - 1, |
| 748 |
Redirect => [$_[0], \%hdr], |
| 749 |
$cb); |
| 750 |
} else { |
| 751 |
$cb->($_[0], \%hdr); |
| 752 |
} |
| 753 |
}; |
| 754 |
|
| 755 |
my $len = $hdr{"content-length"}; |
| 756 |
|
| 757 |
if (!$redirect && $arg{on_header} && !$arg{on_header}(\%hdr)) { |
| 758 |
$finish->(undef, 598 => "Request cancelled by on_header"); |
| 759 |
} elsif ( |
| 760 |
$hdr{Status} =~ /^(?:1..|204|205|304)$/ |
| 761 |
or $method eq "HEAD" |
| 762 |
or (defined $len && !$len) |
| 763 |
) { |
| 764 |
# no body |
| 765 |
$finish->("", undef, undef, 1); |
| 766 |
} else { |
| 767 |
# body handling, many different code paths |
| 768 |
# - no body expected |
| 769 |
# - want_body_handle |
| 770 |
# - te chunked |
| 771 |
# - 2x length known (with or without on_body) |
| 772 |
# - 2x length not known (with or without on_body) |
| 773 |
if (!$redirect && $arg{want_body_handle}) { |
| 774 |
$_[0]->on_eof (undef); |
| 775 |
$_[0]->on_error (undef); |
| 776 |
$_[0]->on_read (undef); |
| 777 |
|
| 778 |
$finish->(delete $state{handle}); |
| 779 |
|
| 780 |
} elsif ($hdr{"transfer-encoding"} =~ /\bchunked\b/i) { |
| 781 |
my $cl = 0; |
| 782 |
my $body = undef; |
| 783 |
my $on_body = $arg{on_body} || sub { $body .= shift; 1 }; |
| 784 |
|
| 785 |
$_[0]->on_error (sub { $finish->(undef, 599 => $_[2]) }); |
| 786 |
|
| 787 |
my $read_chunk; $read_chunk = sub { |
| 788 |
$_[1] =~ /^([0-9a-fA-F]+)/ |
| 789 |
or $finish->(undef, 599 => "Garbled chunked transfer encoding"); |
| 790 |
|
| 791 |
my $len = hex $1; |
| 792 |
|
| 793 |
if ($len) { |
| 794 |
$cl += $len; |
| 795 |
|
| 796 |
$_[0]->push_read (chunk => $len, sub { |
| 797 |
$on_body->($_[1], \%hdr) |
| 798 |
or return $finish->(undef, 598 => "Request cancelled by on_body"); |
| 799 |
|
| 800 |
$_[0]->push_read (line => sub { |
| 801 |
length $_[1] |
| 802 |
and return $finish->(undef, 599 => "Garbled chunked transfer encoding"); |
| 803 |
$_[0]->push_read (line => $read_chunk); |
| 804 |
}); |
| 805 |
}); |
| 806 |
} else { |
| 807 |
$hdr{"content-length"} ||= $cl; |
| 808 |
|
| 809 |
$_[0]->push_read (line => $qr_nlnl, sub { |
| 810 |
if (length $_[1]) { |
| 811 |
for ("$_[1]") { |
| 812 |
y/\015//d; # weed out any \015, as they show up in the weirdest of places. |
| 813 |
|
| 814 |
my $hdr = parse_hdr |
| 815 |
or return $finish->(undef, 599 => "Garbled response trailers"); |
| 816 |
|
| 817 |
%hdr = (%hdr, %$hdr); |
| 818 |
} |
| 819 |
} |
| 820 |
|
| 821 |
$finish->($body, undef, undef, 1); |
| 822 |
}); |
| 823 |
} |
| 824 |
}; |
| 825 |
|
| 826 |
$_[0]->push_read (line => $read_chunk); |
| 827 |
|
| 828 |
} elsif ($arg{on_body}) { |
| 829 |
$_[0]->on_error (sub { $finish->(undef, 599 => $_[2]) }); |
| 830 |
|
| 831 |
if ($len) { |
| 832 |
$_[0]->on_read (sub { |
| 833 |
$len -= length $_[0]{rbuf}; |
| 834 |
|
| 835 |
$arg{on_body}(delete $_[0]{rbuf}, \%hdr) |
| 836 |
or return $finish->(undef, 598 => "Request cancelled by on_body"); |
| 837 |
|
| 838 |
$len > 0 |
| 839 |
or $finish->("", undef, undef, 1); |
| 840 |
}); |
| 841 |
} else { |
| 842 |
$_[0]->on_eof (sub { |
| 843 |
$finish->(""); |
| 844 |
}); |
| 845 |
$_[0]->on_read (sub { |
| 846 |
$arg{on_body}(delete $_[0]{rbuf}, \%hdr) |
| 847 |
or $finish->(undef, 598 => "Request cancelled by on_body"); |
| 848 |
}); |
| 849 |
} |
| 850 |
} else { |
| 851 |
$_[0]->on_eof (undef); |
| 852 |
|
| 853 |
if ($len) { |
| 854 |
$_[0]->on_error (sub { $finish->(undef, 599 => $_[2]) }); |
| 855 |
$_[0]->on_read (sub { |
| 856 |
$finish->((substr delete $_[0]{rbuf}, 0, $len, ""), undef, undef, 1) |
| 857 |
if $len <= length $_[0]{rbuf}; |
| 858 |
}); |
| 859 |
} else { |
| 860 |
$_[0]->on_error (sub { |
| 861 |
($! == Errno::EPIPE || !$!) |
| 862 |
? $finish->(delete $_[0]{rbuf}) |
| 863 |
: $finish->(undef, 599 => $_[2]); |
| 864 |
}); |
| 865 |
$_[0]->on_read (sub { }); |
| 866 |
} |
| 867 |
} |
| 868 |
} |
| 869 |
}; |
| 870 |
|
| 871 |
$state{handle}->push_read (line => $qr_nlnl, $state{read_response}); |
| 872 |
}; |
| 873 |
|
| 874 |
# now handle proxy-CONNECT method |
| 875 |
if ($proxy && $uscheme eq "https") { |
| 876 |
# oh dear, we have to wrap it into a connect request |
| 877 |
|
| 878 |
# maybe re-use $uauthority with patched port? |
| 879 |
$state{handle}->push_write ("CONNECT $uhost:$uport HTTP/1.0\015\012Host: $uhost\015\012\015\012"); |
| 880 |
$state{handle}->push_read (line => $qr_nlnl, sub { |
| 881 |
$_[1] =~ /^HTTP\/([0-9\.]+) \s+ ([0-9]{3}) (?: \s+ ([^\015\012]*) )?/ix |
| 882 |
or return (%state = (), $cb->(undef, { @pseudo, Status => 599, Reason => "Invalid proxy connect response ($_[1])" })); |
| 883 |
|
| 884 |
if ($2 == 200) { |
| 885 |
$rpath = $upath; |
| 886 |
&$handle_actual_request; |
| 887 |
} else { |
| 888 |
%state = (); |
| 889 |
$cb->(undef, { @pseudo, Status => $2, Reason => $3 }); |
| 890 |
} |
| 891 |
}); |
| 892 |
} else { |
| 893 |
&$handle_actual_request; |
| 894 |
} |
| 895 |
}; |
| 896 |
|
| 897 |
my $tcp_connect = $arg{tcp_connect} |
| 898 |
|| do { require AnyEvent::Socket; \&AnyEvent::Socket::tcp_connect }; |
| 899 |
|
| 900 |
$state{connect_guard} = $tcp_connect->($rhost, $rport, $connect_cb, $arg{on_prepare} || sub { $timeout }); |
| 901 |
|
| 902 |
}; |
| 903 |
|
| 904 |
defined wantarray && AnyEvent::Util::guard { %state = () } |
| 905 |
} |
| 906 |
|
| 907 |
sub http_get($@) { |
| 908 |
unshift @_, "GET"; |
| 909 |
&http_request |
| 910 |
} |
| 911 |
|
| 912 |
sub http_head($@) { |
| 913 |
unshift @_, "HEAD"; |
| 914 |
&http_request |
| 915 |
} |
| 916 |
|
| 917 |
sub http_post($$@) { |
| 918 |
my $url = shift; |
| 919 |
unshift @_, "POST", $url, "body"; |
| 920 |
&http_request |
| 921 |
} |
| 922 |
|
| 923 |
=back |
| 924 |
|
| 925 |
=head2 DNS CACHING |
| 926 |
|
| 927 |
AnyEvent::HTTP uses the AnyEvent::Socket::tcp_connect function for |
| 928 |
the actual connection, which in turn uses AnyEvent::DNS to resolve |
| 929 |
hostnames. The latter is a simple stub resolver and does no caching |
| 930 |
on its own. If you want DNS caching, you currently have to provide |
| 931 |
your own default resolver (by storing a suitable resolver object in |
| 932 |
C<$AnyEvent::DNS::RESOLVER>). |
| 933 |
|
| 934 |
=head2 GLOBAL FUNCTIONS AND VARIABLES |
| 935 |
|
| 936 |
=over 4 |
| 937 |
|
| 938 |
=item AnyEvent::HTTP::set_proxy "proxy-url" |
| 939 |
|
| 940 |
Sets the default proxy server to use. The proxy-url must begin with a |
| 941 |
string of the form C<http://host:port> (optionally C<https:...>), croaks |
| 942 |
otherwise. |
| 943 |
|
| 944 |
To clear an already-set proxy, use C<undef>. |
| 945 |
|
| 946 |
=item $date = AnyEvent::HTTP::format_date $timestamp |
| 947 |
|
| 948 |
Takes a POSIX timestamp (seconds since the epoch) and formats it as a HTTP |
| 949 |
Date (RFC 2616). |
| 950 |
|
| 951 |
=item $timestamp = AnyEvent::HTTP::parse_date $date |
| 952 |
|
| 953 |
Takes a HTTP Date (RFC 2616) or a Cookie date (netscape cookie spec) and |
| 954 |
returns the corresponding POSIX timestamp, or C<undef> if the date cannot |
| 955 |
be parsed. |
| 956 |
|
| 957 |
=item $AnyEvent::HTTP::MAX_RECURSE |
| 958 |
|
| 959 |
The default value for the C<recurse> request parameter (default: C<10>). |
| 960 |
|
| 961 |
=item $AnyEvent::HTTP::USERAGENT |
| 962 |
|
| 963 |
The default value for the C<User-Agent> header (the default is |
| 964 |
C<Mozilla/5.0 (compatible; U; AnyEvent-HTTP/$VERSION; +http://software.schmorp.de/pkg/AnyEvent)>). |
| 965 |
|
| 966 |
=item $AnyEvent::HTTP::MAX_PER_HOST |
| 967 |
|
| 968 |
The maximum number of concurrent connections to the same host (identified |
| 969 |
by the hostname). If the limit is exceeded, then the additional requests |
| 970 |
are queued until previous connections are closed. |
| 971 |
|
| 972 |
The default value for this is C<4>, and it is highly advisable to not |
| 973 |
increase it. |
| 974 |
|
| 975 |
=item $AnyEvent::HTTP::ACTIVE |
| 976 |
|
| 977 |
The number of active connections. This is not the number of currently |
| 978 |
running requests, but the number of currently open and non-idle TCP |
| 979 |
connections. This number of can be useful for load-leveling. |
| 980 |
|
| 981 |
=back |
| 982 |
|
| 983 |
=cut |
| 984 |
|
| 985 |
our @month = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec); |
| 986 |
our @weekday = qw(Sun Mon Tue Wed Thu Fri Sat); |
| 987 |
|
| 988 |
sub format_date($) { |
| 989 |
my ($time) = @_; |
| 990 |
|
| 991 |
# RFC 822/1123 format |
| 992 |
my ($S, $M, $H, $mday, $mon, $year, $wday, $yday, undef) = gmtime $time; |
| 993 |
|
| 994 |
sprintf "%s, %02d %s %04d %02d:%02d:%02d GMT", |
| 995 |
$weekday[$wday], $mday, $month[$mon], $year + 1900, |
| 996 |
$H, $M, $S; |
| 997 |
} |
| 998 |
|
| 999 |
sub parse_date($) { |
| 1000 |
my ($date) = @_; |
| 1001 |
|
| 1002 |
my ($d, $m, $y, $H, $M, $S); |
| 1003 |
|
| 1004 |
if ($date =~ /^[A-Z][a-z][a-z], ([0-9][0-9])[\- ]([A-Z][a-z][a-z])[\- ]([0-9][0-9][0-9][0-9]) ([0-9][0-9]):([0-9][0-9]):([0-9][0-9]) GMT$/) { |
| 1005 |
# RFC 822/1123, required by RFC 2616 (with " ") |
| 1006 |
# cookie dates (with "-") |
| 1007 |
|
| 1008 |
($d, $m, $y, $H, $M, $S) = ($1, $2, $3, $4, $5, $6); |
| 1009 |
|
| 1010 |
} elsif ($date =~ /^[A-Z][a-z]+, ([0-9][0-9])-([A-Z][a-z][a-z])-([0-9][0-9]) ([0-9][0-9]):([0-9][0-9]):([0-9][0-9]) GMT$/) { |
| 1011 |
# RFC 850 |
| 1012 |
($d, $m, $y, $H, $M, $S) = ($1, $2, $3 < 69 ? $3 + 2000 : $3 + 1900, $4, $5, $6); |
| 1013 |
|
| 1014 |
} elsif ($date =~ /^[A-Z][a-z][a-z] ([A-Z][a-z][a-z]) ([0-9 ][0-9]) ([0-9][0-9]):([0-9][0-9]):([0-9][0-9]) ([0-9][0-9][0-9][0-9])$/) { |
| 1015 |
# ISO C's asctime |
| 1016 |
($d, $m, $y, $H, $M, $S) = ($2, $1, $6, $3, $4, $5); |
| 1017 |
} |
| 1018 |
# other formats fail in the loop below |
| 1019 |
|
| 1020 |
for (0..11) { |
| 1021 |
if ($m eq $month[$_]) { |
| 1022 |
require Time::Local; |
| 1023 |
return Time::Local::timegm ($S, $M, $H, $d, $_, $y); |
| 1024 |
} |
| 1025 |
} |
| 1026 |
|
| 1027 |
undef |
| 1028 |
} |
| 1029 |
|
| 1030 |
sub set_proxy($) { |
| 1031 |
if (length $_[0]) { |
| 1032 |
$_[0] =~ m%^(https?):// ([^:/]+) (?: : (\d*) )?%ix |
| 1033 |
or Carp::croak "$_[0]: invalid proxy URL"; |
| 1034 |
$PROXY = [$2, $3 || 3128, $1] |
| 1035 |
} else { |
| 1036 |
undef $PROXY; |
| 1037 |
} |
| 1038 |
} |
| 1039 |
|
| 1040 |
# initialise proxy from environment |
| 1041 |
eval { |
| 1042 |
set_proxy $ENV{http_proxy}; |
| 1043 |
}; |
| 1044 |
|
| 1045 |
=head2 SOCKS PROXIES |
| 1046 |
|
| 1047 |
Socks proxies are not directly supported by AnyEvent::HTTP. You can |
| 1048 |
compile your perl to support socks, or use an external program such as |
| 1049 |
F<socksify> (dante) or F<tsocks> to make your program use a socks proxy |
| 1050 |
transparently. |
| 1051 |
|
| 1052 |
Alternatively, for AnyEvent::HTTP only, you can use your own |
| 1053 |
C<tcp_connect> function that does the proxy handshake - here is an example |
| 1054 |
that works with socks4a proxies: |
| 1055 |
|
| 1056 |
use Errno; |
| 1057 |
use AnyEvent::Util; |
| 1058 |
use AnyEvent::Socket; |
| 1059 |
use AnyEvent::Handle; |
| 1060 |
|
| 1061 |
# host, port and username of/for your socks4a proxy |
| 1062 |
my $socks_host = "10.0.0.23"; |
| 1063 |
my $socks_port = 9050; |
| 1064 |
my $socks_user = ""; |
| 1065 |
|
| 1066 |
sub socks4a_connect { |
| 1067 |
my ($host, $port, $connect_cb, $prepare_cb) = @_; |
| 1068 |
|
| 1069 |
my $hdl = new AnyEvent::Handle |
| 1070 |
connect => [$socks_host, $socks_port], |
| 1071 |
on_prepare => sub { $prepare_cb->($_[0]{fh}) }, |
| 1072 |
on_error => sub { $connect_cb->() }, |
| 1073 |
; |
| 1074 |
|
| 1075 |
$hdl->push_write (pack "CCnNZ*Z*", 4, 1, $port, 1, $socks_user, $host); |
| 1076 |
|
| 1077 |
$hdl->push_read (chunk => 8, sub { |
| 1078 |
my ($hdl, $chunk) = @_; |
| 1079 |
my ($status, $port, $ipn) = unpack "xCna4", $chunk; |
| 1080 |
|
| 1081 |
if ($status == 0x5a) { |
| 1082 |
$connect_cb->($hdl->{fh}, (format_address $ipn) . ":$port"); |
| 1083 |
} else { |
| 1084 |
$! = Errno::ENXIO; $connect_cb->(); |
| 1085 |
} |
| 1086 |
}); |
| 1087 |
|
| 1088 |
$hdl |
| 1089 |
} |
| 1090 |
|
| 1091 |
Use C<socks4a_connect> instead of C<tcp_connect> when doing C<http_request>s, |
| 1092 |
possibly after switching off other proxy types: |
| 1093 |
|
| 1094 |
AnyEvent::HTTP::set_proxy undef; # usually you do not want other proxies |
| 1095 |
|
| 1096 |
http_get 'http://www.google.com', tcp_connect => \&socks4a_connect, sub { |
| 1097 |
my ($data, $headers) = @_; |
| 1098 |
... |
| 1099 |
}; |
| 1100 |
|
| 1101 |
=head1 SEE ALSO |
| 1102 |
|
| 1103 |
L<AnyEvent>. |
| 1104 |
|
| 1105 |
=head1 AUTHOR |
| 1106 |
|
| 1107 |
Marc Lehmann <schmorp@schmorp.de> |
| 1108 |
http://home.schmorp.de/ |
| 1109 |
|
| 1110 |
With many thanks to Дмитрий Шалашов, who provided countless |
| 1111 |
testcases and bugreports. |
| 1112 |
|
| 1113 |
=cut |
| 1114 |
|
| 1115 |
1 |
| 1116 |
|
