1 |
=head1 NAME |
2 |
|
3 |
AnyEvent::MP - erlang-style multi-processing/message-passing framework |
4 |
|
5 |
=head1 SYNOPSIS |
6 |
|
7 |
use AnyEvent::MP; |
8 |
|
9 |
$NODE # contains this node's node ID |
10 |
NODE # returns this node's node ID |
11 |
|
12 |
$SELF # receiving/own port id in rcv callbacks |
13 |
|
14 |
# initialise the node so it can send/receive messages |
15 |
configure; |
16 |
|
17 |
# ports are message destinations |
18 |
|
19 |
# sending messages |
20 |
snd $port, type => data...; |
21 |
snd $port, @msg; |
22 |
snd @msg_with_first_element_being_a_port; |
23 |
|
24 |
# creating/using ports, the simple way |
25 |
my $simple_port = port { my @msg = @_ }; |
26 |
|
27 |
# creating/using ports, tagged message matching |
28 |
my $port = port; |
29 |
rcv $port, ping => sub { snd $_[0], "pong" }; |
30 |
rcv $port, pong => sub { warn "pong received\n" }; |
31 |
|
32 |
# create a port on another node |
33 |
my $port = spawn $node, $initfunc, @initdata; |
34 |
|
35 |
# destroy a port again |
36 |
kil $port; # "normal" kill |
37 |
kil $port, my_error => "everything is broken"; # error kill |
38 |
|
39 |
# monitoring |
40 |
mon $port, $cb->(@msg) # callback is invoked on death |
41 |
mon $port, $localport # kill localport on abnormal death |
42 |
mon $port, $localport, @msg # send message on death |
43 |
|
44 |
# temporarily execute code in port context |
45 |
peval $port, sub { die "kill the port!" }; |
46 |
|
47 |
# execute callbacks in $SELF port context |
48 |
my $timer = AE::timer 1, 0, psub { |
49 |
die "kill the port, delayed"; |
50 |
}; |
51 |
|
52 |
=head1 CURRENT STATUS |
53 |
|
54 |
bin/aemp - stable. |
55 |
AnyEvent::MP - stable API, should work. |
56 |
AnyEvent::MP::Intro - explains most concepts. |
57 |
AnyEvent::MP::Kernel - mostly stable API. |
58 |
AnyEvent::MP::Global - stable API. |
59 |
|
60 |
=head1 DESCRIPTION |
61 |
|
62 |
This module (-family) implements a simple message passing framework. |
63 |
|
64 |
Despite its simplicity, you can securely message other processes running |
65 |
on the same or other hosts, and you can supervise entities remotely. |
66 |
|
67 |
For an introduction to this module family, see the L<AnyEvent::MP::Intro> |
68 |
manual page and the examples under F<eg/>. |
69 |
|
70 |
=head1 CONCEPTS |
71 |
|
72 |
=over 4 |
73 |
|
74 |
=item port |
75 |
|
76 |
Not to be confused with a TCP port, a "port" is something you can send |
77 |
messages to (with the C<snd> function). |
78 |
|
79 |
Ports allow you to register C<rcv> handlers that can match all or just |
80 |
some messages. Messages send to ports will not be queued, regardless of |
81 |
anything was listening for them or not. |
82 |
|
83 |
Ports are represented by (printable) strings called "port IDs". |
84 |
|
85 |
=item port ID - C<nodeid#portname> |
86 |
|
87 |
A port ID is the concatenation of a node ID, a hash-mark (C<#>) |
88 |
as separator, and a port name (a printable string of unspecified |
89 |
format created by AnyEvent::MP). |
90 |
|
91 |
=item node |
92 |
|
93 |
A node is a single process containing at least one port - the node port, |
94 |
which enables nodes to manage each other remotely, and to create new |
95 |
ports. |
96 |
|
97 |
Nodes are either public (have one or more listening ports) or private |
98 |
(no listening ports). Private nodes cannot talk to other private nodes |
99 |
currently, but all nodes can talk to public nodes. |
100 |
|
101 |
Nodes is represented by (printable) strings called "node IDs". |
102 |
|
103 |
=item node ID - C<[A-Za-z0-9_\-.:]*> |
104 |
|
105 |
A node ID is a string that uniquely identifies the node within a |
106 |
network. Depending on the configuration used, node IDs can look like a |
107 |
hostname, a hostname and a port, or a random string. AnyEvent::MP itself |
108 |
doesn't interpret node IDs in any way except to uniquely identify a node. |
109 |
|
110 |
=item binds - C<ip:port> |
111 |
|
112 |
Nodes can only talk to each other by creating some kind of connection to |
113 |
each other. To do this, nodes should listen on one or more local transport |
114 |
endpoints - binds. |
115 |
|
116 |
Currently, only standard C<ip:port> specifications can be used, which |
117 |
specify TCP ports to listen on. So a bind is basically just a tcp socket |
118 |
in listening mode thta accepts conenctions form other nodes. |
119 |
|
120 |
=item seed nodes |
121 |
|
122 |
When a node starts, it knows nothing about the network it is in - it |
123 |
needs to connect to at least one other node that is already in the |
124 |
network. These other nodes are called "seed nodes". |
125 |
|
126 |
Seed nodes themselves are not special - they are seed nodes only because |
127 |
some other node I<uses> them as such, but any node can be used as seed |
128 |
node for other nodes, and eahc node cna use a different set of seed nodes. |
129 |
|
130 |
In addition to discovering the network, seed nodes are also used to |
131 |
maintain the network - all nodes using the same seed node form are part of |
132 |
the same network. If a network is split into multiple subnets because e.g. |
133 |
the network link between the parts goes down, then using the same seed |
134 |
nodes for all nodes ensures that eventually the subnets get merged again. |
135 |
|
136 |
Seed nodes are expected to be long-running, and at least one seed node |
137 |
should always be available. They should also be relatively responsive - a |
138 |
seed node that blocks for long periods will slow down everybody else. |
139 |
|
140 |
For small networks, it's best if every node uses the same set of seed |
141 |
nodes. For large networks, it can be useful to specify "regional" seed |
142 |
nodes for most nodes in an area, and use all seed nodes as seed nodes for |
143 |
each other. What's important is that all seed nodes connections form a |
144 |
complete graph, so that the network cannot split into separate subnets |
145 |
forever. |
146 |
|
147 |
Seed nodes are represented by seed IDs. |
148 |
|
149 |
=item seed IDs - C<host:port> |
150 |
|
151 |
Seed IDs are transport endpoint(s) (usually a hostname/IP address and a |
152 |
TCP port) of nodes that should be used as seed nodes. |
153 |
|
154 |
=item global nodes |
155 |
|
156 |
An AEMP network needs a discovery service - nodes need to know how to |
157 |
connect to other nodes they only know by name. In addition, AEMP offers a |
158 |
distributed "group database", which maps group names to a list of strings |
159 |
- for example, to register worker ports. |
160 |
|
161 |
A network needs at least one global node to work, and allows every node to |
162 |
be a global node. |
163 |
|
164 |
Any node that loads the L<AnyEvent::MP::Global> module becomes a global |
165 |
node and tries to keep connections to all other nodes. So while it can |
166 |
make sense to make every node "global" in small networks, it usually makes |
167 |
sense to only make seed nodes into global nodes in large networks (nodes |
168 |
keep connections to seed nodes and global nodes, so makign them the same |
169 |
reduces overhead). |
170 |
|
171 |
=back |
172 |
|
173 |
=head1 VARIABLES/FUNCTIONS |
174 |
|
175 |
=over 4 |
176 |
|
177 |
=cut |
178 |
|
179 |
package AnyEvent::MP; |
180 |
|
181 |
use AnyEvent::MP::Config (); |
182 |
use AnyEvent::MP::Kernel; |
183 |
use AnyEvent::MP::Kernel qw(%NODE %PORT %PORT_DATA $UNIQ $RUNIQ $ID); |
184 |
|
185 |
use common::sense; |
186 |
|
187 |
use Carp (); |
188 |
|
189 |
use AE (); |
190 |
use Guard (); |
191 |
|
192 |
use base "Exporter"; |
193 |
|
194 |
our $VERSION = $AnyEvent::MP::Config::VERSION; |
195 |
|
196 |
our @EXPORT = qw( |
197 |
NODE $NODE *SELF node_of after |
198 |
configure |
199 |
snd rcv mon mon_guard kil psub peval spawn cal |
200 |
port |
201 |
db_set db_del db_reg |
202 |
db_mon db_family db_keys db_values |
203 |
); |
204 |
|
205 |
our $SELF; |
206 |
|
207 |
sub _self_die() { |
208 |
my $msg = $@; |
209 |
$msg =~ s/\n+$// unless ref $msg; |
210 |
kil $SELF, die => $msg; |
211 |
} |
212 |
|
213 |
=item $thisnode = NODE / $NODE |
214 |
|
215 |
The C<NODE> function returns, and the C<$NODE> variable contains, the node |
216 |
ID of the node running in the current process. This value is initialised by |
217 |
a call to C<configure>. |
218 |
|
219 |
=item $nodeid = node_of $port |
220 |
|
221 |
Extracts and returns the node ID from a port ID or a node ID. |
222 |
|
223 |
=item configure $profile, key => value... |
224 |
|
225 |
=item configure key => value... |
226 |
|
227 |
Before a node can talk to other nodes on the network (i.e. enter |
228 |
"distributed mode") it has to configure itself - the minimum a node needs |
229 |
to know is its own name, and optionally it should know the addresses of |
230 |
some other nodes in the network to discover other nodes. |
231 |
|
232 |
This function configures a node - it must be called exactly once (or |
233 |
never) before calling other AnyEvent::MP functions. |
234 |
|
235 |
The key/value pairs are basically the same ones as documented for the |
236 |
F<aemp> command line utility (sans the set/del prefix), with these additions: |
237 |
|
238 |
=over 4 |
239 |
|
240 |
=item norc => $boolean (default false) |
241 |
|
242 |
If true, then the rc file (e.g. F<~/.perl-anyevent-mp>) will I<not> |
243 |
be consulted - all configuraiton options must be specified in the |
244 |
C<configure> call. |
245 |
|
246 |
=item force => $boolean (default false) |
247 |
|
248 |
IF true, then the values specified in the C<configure> will take |
249 |
precedence over any values configured via the rc file. The default is for |
250 |
the rc file to override any options specified in the program. |
251 |
|
252 |
=item secure => $pass->(@msg) |
253 |
|
254 |
In addition to specifying a boolean, you can specify a code reference that |
255 |
is called for every code execution attempt - the execution request is |
256 |
granted iff the callback returns a true value. |
257 |
|
258 |
Most of the time the callback should look only at |
259 |
C<$AnyEvent::MP::Kernel::SRCNODE> to make a decision, and not at the |
260 |
actual message (which can be about anything, and is mostly provided for |
261 |
diagnostic purposes). |
262 |
|
263 |
See F<semp setsecure> for more info. |
264 |
|
265 |
=back |
266 |
|
267 |
=over 4 |
268 |
|
269 |
=item step 1, gathering configuration from profiles |
270 |
|
271 |
The function first looks up a profile in the aemp configuration (see the |
272 |
L<aemp> commandline utility). The profile name can be specified via the |
273 |
named C<profile> parameter or can simply be the first parameter). If it is |
274 |
missing, then the nodename (F<uname -n>) will be used as profile name. |
275 |
|
276 |
The profile data is then gathered as follows: |
277 |
|
278 |
First, all remaining key => value pairs (all of which are conveniently |
279 |
undocumented at the moment) will be interpreted as configuration |
280 |
data. Then they will be overwritten by any values specified in the global |
281 |
default configuration (see the F<aemp> utility), then the chain of |
282 |
profiles chosen by the profile name (and any C<parent> attributes). |
283 |
|
284 |
That means that the values specified in the profile have highest priority |
285 |
and the values specified directly via C<configure> have lowest priority, |
286 |
and can only be used to specify defaults. |
287 |
|
288 |
If the profile specifies a node ID, then this will become the node ID of |
289 |
this process. If not, then the profile name will be used as node ID, with |
290 |
a unique randoms tring (C</%u>) appended. |
291 |
|
292 |
The node ID can contain some C<%> sequences that are expanded: C<%n> |
293 |
is expanded to the local nodename, C<%u> is replaced by a random |
294 |
strign to make the node unique. For example, the F<aemp> commandline |
295 |
utility uses C<aemp/%n/%u> as nodename, which might expand to |
296 |
C<aemp/cerebro/ZQDGSIkRhEZQDGSIkRhE>. |
297 |
|
298 |
=item step 2, bind listener sockets |
299 |
|
300 |
The next step is to look up the binds in the profile, followed by binding |
301 |
aemp protocol listeners on all binds specified (it is possible and valid |
302 |
to have no binds, meaning that the node cannot be contacted form the |
303 |
outside. This means the node cannot talk to other nodes that also have no |
304 |
binds, but it can still talk to all "normal" nodes). |
305 |
|
306 |
If the profile does not specify a binds list, then a default of C<*> is |
307 |
used, meaning the node will bind on a dynamically-assigned port on every |
308 |
local IP address it finds. |
309 |
|
310 |
=item step 3, connect to seed nodes |
311 |
|
312 |
As the last step, the seed ID list from the profile is passed to the |
313 |
L<AnyEvent::MP::Global> module, which will then use it to keep |
314 |
connectivity with at least one node at any point in time. |
315 |
|
316 |
=back |
317 |
|
318 |
Example: become a distributed node using the local node name as profile. |
319 |
This should be the most common form of invocation for "daemon"-type nodes. |
320 |
|
321 |
configure |
322 |
|
323 |
Example: become a semi-anonymous node. This form is often used for |
324 |
commandline clients. |
325 |
|
326 |
configure nodeid => "myscript/%n/%u"; |
327 |
|
328 |
Example: configure a node using a profile called seed, which is suitable |
329 |
for a seed node as it binds on all local addresses on a fixed port (4040, |
330 |
customary for aemp). |
331 |
|
332 |
# use the aemp commandline utility |
333 |
# aemp profile seed binds '*:4040' |
334 |
|
335 |
# then use it |
336 |
configure profile => "seed"; |
337 |
|
338 |
# or simply use aemp from the shell again: |
339 |
# aemp run profile seed |
340 |
|
341 |
# or provide a nicer-to-remember nodeid |
342 |
# aemp run profile seed nodeid "$(hostname)" |
343 |
|
344 |
=item $SELF |
345 |
|
346 |
Contains the current port id while executing C<rcv> callbacks or C<psub> |
347 |
blocks. |
348 |
|
349 |
=item *SELF, SELF, %SELF, @SELF... |
350 |
|
351 |
Due to some quirks in how perl exports variables, it is impossible to |
352 |
just export C<$SELF>, all the symbols named C<SELF> are exported by this |
353 |
module, but only C<$SELF> is currently used. |
354 |
|
355 |
=item snd $port, type => @data |
356 |
|
357 |
=item snd $port, @msg |
358 |
|
359 |
Send the given message to the given port, which can identify either a |
360 |
local or a remote port, and must be a port ID. |
361 |
|
362 |
While the message can be almost anything, it is highly recommended to |
363 |
use a string as first element (a port ID, or some word that indicates a |
364 |
request type etc.) and to consist if only simple perl values (scalars, |
365 |
arrays, hashes) - if you think you need to pass an object, think again. |
366 |
|
367 |
The message data logically becomes read-only after a call to this |
368 |
function: modifying any argument (or values referenced by them) is |
369 |
forbidden, as there can be considerable time between the call to C<snd> |
370 |
and the time the message is actually being serialised - in fact, it might |
371 |
never be copied as within the same process it is simply handed to the |
372 |
receiving port. |
373 |
|
374 |
The type of data you can transfer depends on the transport protocol: when |
375 |
JSON is used, then only strings, numbers and arrays and hashes consisting |
376 |
of those are allowed (no objects). When Storable is used, then anything |
377 |
that Storable can serialise and deserialise is allowed, and for the local |
378 |
node, anything can be passed. Best rely only on the common denominator of |
379 |
these. |
380 |
|
381 |
=item $local_port = port |
382 |
|
383 |
Create a new local port object and returns its port ID. Initially it has |
384 |
no callbacks set and will throw an error when it receives messages. |
385 |
|
386 |
=item $local_port = port { my @msg = @_ } |
387 |
|
388 |
Creates a new local port, and returns its ID. Semantically the same as |
389 |
creating a port and calling C<rcv $port, $callback> on it. |
390 |
|
391 |
The block will be called for every message received on the port, with the |
392 |
global variable C<$SELF> set to the port ID. Runtime errors will cause the |
393 |
port to be C<kil>ed. The message will be passed as-is, no extra argument |
394 |
(i.e. no port ID) will be passed to the callback. |
395 |
|
396 |
If you want to stop/destroy the port, simply C<kil> it: |
397 |
|
398 |
my $port = port { |
399 |
my @msg = @_; |
400 |
... |
401 |
kil $SELF; |
402 |
}; |
403 |
|
404 |
=cut |
405 |
|
406 |
sub rcv($@); |
407 |
|
408 |
my $KILME = sub { |
409 |
(my $tag = substr $_[0], 0, 30) =~ s/([\x20-\x7e])/./g; |
410 |
kil $SELF, unhandled_message => "no callback found for message '$tag'"; |
411 |
}; |
412 |
|
413 |
sub port(;&) { |
414 |
my $id = $UNIQ . ++$ID; |
415 |
my $port = "$NODE#$id"; |
416 |
|
417 |
rcv $port, shift || $KILME; |
418 |
|
419 |
$port |
420 |
} |
421 |
|
422 |
=item rcv $local_port, $callback->(@msg) |
423 |
|
424 |
Replaces the default callback on the specified port. There is no way to |
425 |
remove the default callback: use C<sub { }> to disable it, or better |
426 |
C<kil> the port when it is no longer needed. |
427 |
|
428 |
The global C<$SELF> (exported by this module) contains C<$port> while |
429 |
executing the callback. Runtime errors during callback execution will |
430 |
result in the port being C<kil>ed. |
431 |
|
432 |
The default callback receives all messages not matched by a more specific |
433 |
C<tag> match. |
434 |
|
435 |
=item rcv $local_port, tag => $callback->(@msg_without_tag), ... |
436 |
|
437 |
Register (or replace) callbacks to be called on messages starting with the |
438 |
given tag on the given port (and return the port), or unregister it (when |
439 |
C<$callback> is C<$undef> or missing). There can only be one callback |
440 |
registered for each tag. |
441 |
|
442 |
The original message will be passed to the callback, after the first |
443 |
element (the tag) has been removed. The callback will use the same |
444 |
environment as the default callback (see above). |
445 |
|
446 |
Example: create a port and bind receivers on it in one go. |
447 |
|
448 |
my $port = rcv port, |
449 |
msg1 => sub { ... }, |
450 |
msg2 => sub { ... }, |
451 |
; |
452 |
|
453 |
Example: create a port, bind receivers and send it in a message elsewhere |
454 |
in one go: |
455 |
|
456 |
snd $otherport, reply => |
457 |
rcv port, |
458 |
msg1 => sub { ... }, |
459 |
... |
460 |
; |
461 |
|
462 |
Example: temporarily register a rcv callback for a tag matching some port |
463 |
(e.g. for an rpc reply) and unregister it after a message was received. |
464 |
|
465 |
rcv $port, $otherport => sub { |
466 |
my @reply = @_; |
467 |
|
468 |
rcv $SELF, $otherport; |
469 |
}; |
470 |
|
471 |
=cut |
472 |
|
473 |
sub rcv($@) { |
474 |
my $port = shift; |
475 |
my ($nodeid, $portid) = split /#/, $port, 2; |
476 |
|
477 |
$NODE{$nodeid} == $NODE{""} |
478 |
or Carp::croak "$port: rcv can only be called on local ports, caught"; |
479 |
|
480 |
while (@_) { |
481 |
if (ref $_[0]) { |
482 |
if (my $self = $PORT_DATA{$portid}) { |
483 |
"AnyEvent::MP::Port" eq ref $self |
484 |
or Carp::croak "$port: rcv can only be called on message matching ports, caught"; |
485 |
|
486 |
$self->[0] = shift; |
487 |
} else { |
488 |
my $cb = shift; |
489 |
$PORT{$portid} = sub { |
490 |
local $SELF = $port; |
491 |
eval { &$cb }; _self_die if $@; |
492 |
}; |
493 |
} |
494 |
} elsif (defined $_[0]) { |
495 |
my $self = $PORT_DATA{$portid} ||= do { |
496 |
my $self = bless [$PORT{$portid} || sub { }, { }, $port], "AnyEvent::MP::Port"; |
497 |
|
498 |
$PORT{$portid} = sub { |
499 |
local $SELF = $port; |
500 |
|
501 |
if (my $cb = $self->[1]{$_[0]}) { |
502 |
shift; |
503 |
eval { &$cb }; _self_die if $@; |
504 |
} else { |
505 |
&{ $self->[0] }; |
506 |
} |
507 |
}; |
508 |
|
509 |
$self |
510 |
}; |
511 |
|
512 |
"AnyEvent::MP::Port" eq ref $self |
513 |
or Carp::croak "$port: rcv can only be called on message matching ports, caught"; |
514 |
|
515 |
my ($tag, $cb) = splice @_, 0, 2; |
516 |
|
517 |
if (defined $cb) { |
518 |
$self->[1]{$tag} = $cb; |
519 |
} else { |
520 |
delete $self->[1]{$tag}; |
521 |
} |
522 |
} |
523 |
} |
524 |
|
525 |
$port |
526 |
} |
527 |
|
528 |
=item peval $port, $coderef[, @args] |
529 |
|
530 |
Evaluates the given C<$codref> within the contetx of C<$port>, that is, |
531 |
when the code throews an exception the C<$port> will be killed. |
532 |
|
533 |
Any remaining args will be passed to the callback. Any return values will |
534 |
be returned to the caller. |
535 |
|
536 |
This is useful when you temporarily want to execute code in the context of |
537 |
a port. |
538 |
|
539 |
Example: create a port and run some initialisation code in it's context. |
540 |
|
541 |
my $port = port { ... }; |
542 |
|
543 |
peval $port, sub { |
544 |
init |
545 |
or die "unable to init"; |
546 |
}; |
547 |
|
548 |
=cut |
549 |
|
550 |
sub peval($$) { |
551 |
local $SELF = shift; |
552 |
my $cb = shift; |
553 |
|
554 |
if (wantarray) { |
555 |
my @res = eval { &$cb }; |
556 |
_self_die if $@; |
557 |
@res |
558 |
} else { |
559 |
my $res = eval { &$cb }; |
560 |
_self_die if $@; |
561 |
$res |
562 |
} |
563 |
} |
564 |
|
565 |
=item $closure = psub { BLOCK } |
566 |
|
567 |
Remembers C<$SELF> and creates a closure out of the BLOCK. When the |
568 |
closure is executed, sets up the environment in the same way as in C<rcv> |
569 |
callbacks, i.e. runtime errors will cause the port to get C<kil>ed. |
570 |
|
571 |
The effect is basically as if it returned C<< sub { peval $SELF, sub { |
572 |
BLOCK }, @_ } >>. |
573 |
|
574 |
This is useful when you register callbacks from C<rcv> callbacks: |
575 |
|
576 |
rcv delayed_reply => sub { |
577 |
my ($delay, @reply) = @_; |
578 |
my $timer = AE::timer $delay, 0, psub { |
579 |
snd @reply, $SELF; |
580 |
}; |
581 |
}; |
582 |
|
583 |
=cut |
584 |
|
585 |
sub psub(&) { |
586 |
my $cb = shift; |
587 |
|
588 |
my $port = $SELF |
589 |
or Carp::croak "psub can only be called from within rcv or psub callbacks, not"; |
590 |
|
591 |
sub { |
592 |
local $SELF = $port; |
593 |
|
594 |
if (wantarray) { |
595 |
my @res = eval { &$cb }; |
596 |
_self_die if $@; |
597 |
@res |
598 |
} else { |
599 |
my $res = eval { &$cb }; |
600 |
_self_die if $@; |
601 |
$res |
602 |
} |
603 |
} |
604 |
} |
605 |
|
606 |
=item $guard = mon $port, $cb->(@reason) # call $cb when $port dies |
607 |
|
608 |
=item $guard = mon $port, $rcvport # kill $rcvport when $port dies |
609 |
|
610 |
=item $guard = mon $port # kill $SELF when $port dies |
611 |
|
612 |
=item $guard = mon $port, $rcvport, @msg # send a message when $port dies |
613 |
|
614 |
Monitor the given port and do something when the port is killed or |
615 |
messages to it were lost, and optionally return a guard that can be used |
616 |
to stop monitoring again. |
617 |
|
618 |
In the first form (callback), the callback is simply called with any |
619 |
number of C<@reason> elements (no @reason means that the port was deleted |
620 |
"normally"). Note also that I<< the callback B<must> never die >>, so use |
621 |
C<eval> if unsure. |
622 |
|
623 |
In the second form (another port given), the other port (C<$rcvport>) |
624 |
will be C<kil>'ed with C<@reason>, if a @reason was specified, i.e. on |
625 |
"normal" kils nothing happens, while under all other conditions, the other |
626 |
port is killed with the same reason. |
627 |
|
628 |
The third form (kill self) is the same as the second form, except that |
629 |
C<$rvport> defaults to C<$SELF>. |
630 |
|
631 |
In the last form (message), a message of the form C<@msg, @reason> will be |
632 |
C<snd>. |
633 |
|
634 |
Monitoring-actions are one-shot: once messages are lost (and a monitoring |
635 |
alert was raised), they are removed and will not trigger again. |
636 |
|
637 |
As a rule of thumb, monitoring requests should always monitor a port from |
638 |
a local port (or callback). The reason is that kill messages might get |
639 |
lost, just like any other message. Another less obvious reason is that |
640 |
even monitoring requests can get lost (for example, when the connection |
641 |
to the other node goes down permanently). When monitoring a port locally |
642 |
these problems do not exist. |
643 |
|
644 |
C<mon> effectively guarantees that, in the absence of hardware failures, |
645 |
after starting the monitor, either all messages sent to the port will |
646 |
arrive, or the monitoring action will be invoked after possible message |
647 |
loss has been detected. No messages will be lost "in between" (after |
648 |
the first lost message no further messages will be received by the |
649 |
port). After the monitoring action was invoked, further messages might get |
650 |
delivered again. |
651 |
|
652 |
Inter-host-connection timeouts and monitoring depend on the transport |
653 |
used. The only transport currently implemented is TCP, and AnyEvent::MP |
654 |
relies on TCP to detect node-downs (this can take 10-15 minutes on a |
655 |
non-idle connection, and usually around two hours for idle connections). |
656 |
|
657 |
This means that monitoring is good for program errors and cleaning up |
658 |
stuff eventually, but they are no replacement for a timeout when you need |
659 |
to ensure some maximum latency. |
660 |
|
661 |
Example: call a given callback when C<$port> is killed. |
662 |
|
663 |
mon $port, sub { warn "port died because of <@_>\n" }; |
664 |
|
665 |
Example: kill ourselves when C<$port> is killed abnormally. |
666 |
|
667 |
mon $port; |
668 |
|
669 |
Example: send us a restart message when another C<$port> is killed. |
670 |
|
671 |
mon $port, $self => "restart"; |
672 |
|
673 |
=cut |
674 |
|
675 |
sub mon { |
676 |
my ($nodeid, $port) = split /#/, shift, 2; |
677 |
|
678 |
my $node = $NODE{$nodeid} || add_node $nodeid; |
679 |
|
680 |
my $cb = @_ ? shift : $SELF || Carp::croak 'mon: called with one argument only, but $SELF not set,'; |
681 |
|
682 |
unless (ref $cb) { |
683 |
if (@_) { |
684 |
# send a kill info message |
685 |
my (@msg) = ($cb, @_); |
686 |
$cb = sub { snd @msg, @_ }; |
687 |
} else { |
688 |
# simply kill other port |
689 |
my $port = $cb; |
690 |
$cb = sub { kil $port, @_ if @_ }; |
691 |
} |
692 |
} |
693 |
|
694 |
$node->monitor ($port, $cb); |
695 |
|
696 |
defined wantarray |
697 |
and ($cb += 0, Guard::guard { $node->unmonitor ($port, $cb) }) |
698 |
} |
699 |
|
700 |
=item $guard = mon_guard $port, $ref, $ref... |
701 |
|
702 |
Monitors the given C<$port> and keeps the passed references. When the port |
703 |
is killed, the references will be freed. |
704 |
|
705 |
Optionally returns a guard that will stop the monitoring. |
706 |
|
707 |
This function is useful when you create e.g. timers or other watchers and |
708 |
want to free them when the port gets killed (note the use of C<psub>): |
709 |
|
710 |
$port->rcv (start => sub { |
711 |
my $timer; $timer = mon_guard $port, AE::timer 1, 1, psub { |
712 |
undef $timer if 0.9 < rand; |
713 |
}); |
714 |
}); |
715 |
|
716 |
=cut |
717 |
|
718 |
sub mon_guard { |
719 |
my ($port, @refs) = @_; |
720 |
|
721 |
#TODO: mon-less form? |
722 |
|
723 |
mon $port, sub { 0 && @refs } |
724 |
} |
725 |
|
726 |
=item kil $port[, @reason] |
727 |
|
728 |
Kill the specified port with the given C<@reason>. |
729 |
|
730 |
If no C<@reason> is specified, then the port is killed "normally" - |
731 |
monitor callback will be invoked, but the kil will not cause linked ports |
732 |
(C<mon $mport, $lport> form) to get killed. |
733 |
|
734 |
If a C<@reason> is specified, then linked ports (C<mon $mport, $lport> |
735 |
form) get killed with the same reason. |
736 |
|
737 |
Runtime errors while evaluating C<rcv> callbacks or inside C<psub> blocks |
738 |
will be reported as reason C<< die => $@ >>. |
739 |
|
740 |
Transport/communication errors are reported as C<< transport_error => |
741 |
$message >>. |
742 |
|
743 |
Common idioms: |
744 |
|
745 |
# silently remove yourself, do not kill linked ports |
746 |
kil $SELF; |
747 |
|
748 |
# report a failure in some detail |
749 |
kil $SELF, failure_mode_1 => "it failed with too high temperature"; |
750 |
|
751 |
# do not waste much time with killing, just die when something goes wrong |
752 |
open my $fh, "<file" |
753 |
or die "file: $!"; |
754 |
|
755 |
=item $port = spawn $node, $initfunc[, @initdata] |
756 |
|
757 |
Creates a port on the node C<$node> (which can also be a port ID, in which |
758 |
case it's the node where that port resides). |
759 |
|
760 |
The port ID of the newly created port is returned immediately, and it is |
761 |
possible to immediately start sending messages or to monitor the port. |
762 |
|
763 |
After the port has been created, the init function is called on the remote |
764 |
node, in the same context as a C<rcv> callback. This function must be a |
765 |
fully-qualified function name (e.g. C<MyApp::Chat::Server::init>). To |
766 |
specify a function in the main program, use C<::name>. |
767 |
|
768 |
If the function doesn't exist, then the node tries to C<require> |
769 |
the package, then the package above the package and so on (e.g. |
770 |
C<MyApp::Chat::Server>, C<MyApp::Chat>, C<MyApp>) until the function |
771 |
exists or it runs out of package names. |
772 |
|
773 |
The init function is then called with the newly-created port as context |
774 |
object (C<$SELF>) and the C<@initdata> values as arguments. It I<must> |
775 |
call one of the C<rcv> functions to set callbacks on C<$SELF>, otherwise |
776 |
the port might not get created. |
777 |
|
778 |
A common idiom is to pass a local port, immediately monitor the spawned |
779 |
port, and in the remote init function, immediately monitor the passed |
780 |
local port. This two-way monitoring ensures that both ports get cleaned up |
781 |
when there is a problem. |
782 |
|
783 |
C<spawn> guarantees that the C<$initfunc> has no visible effects on the |
784 |
caller before C<spawn> returns (by delaying invocation when spawn is |
785 |
called for the local node). |
786 |
|
787 |
Example: spawn a chat server port on C<$othernode>. |
788 |
|
789 |
# this node, executed from within a port context: |
790 |
my $server = spawn $othernode, "MyApp::Chat::Server::connect", $SELF; |
791 |
mon $server; |
792 |
|
793 |
# init function on C<$othernode> |
794 |
sub connect { |
795 |
my ($srcport) = @_; |
796 |
|
797 |
mon $srcport; |
798 |
|
799 |
rcv $SELF, sub { |
800 |
... |
801 |
}; |
802 |
} |
803 |
|
804 |
=cut |
805 |
|
806 |
sub _spawn { |
807 |
my $port = shift; |
808 |
my $init = shift; |
809 |
|
810 |
# rcv will create the actual port |
811 |
local $SELF = "$NODE#$port"; |
812 |
eval { |
813 |
&{ load_func $init } |
814 |
}; |
815 |
_self_die if $@; |
816 |
} |
817 |
|
818 |
sub spawn(@) { |
819 |
my ($nodeid, undef) = split /#/, shift, 2; |
820 |
|
821 |
my $id = $RUNIQ . ++$ID; |
822 |
|
823 |
$_[0] =~ /::/ |
824 |
or Carp::croak "spawn init function must be a fully-qualified name, caught"; |
825 |
|
826 |
snd_to_func $nodeid, "AnyEvent::MP::_spawn" => $id, @_; |
827 |
|
828 |
"$nodeid#$id" |
829 |
} |
830 |
|
831 |
|
832 |
=item after $timeout, @msg |
833 |
|
834 |
=item after $timeout, $callback |
835 |
|
836 |
Either sends the given message, or call the given callback, after the |
837 |
specified number of seconds. |
838 |
|
839 |
This is simply a utility function that comes in handy at times - the |
840 |
AnyEvent::MP author is not convinced of the wisdom of having it, though, |
841 |
so it may go away in the future. |
842 |
|
843 |
=cut |
844 |
|
845 |
sub after($@) { |
846 |
my ($timeout, @action) = @_; |
847 |
|
848 |
my $t; $t = AE::timer $timeout, 0, sub { |
849 |
undef $t; |
850 |
ref $action[0] |
851 |
? $action[0]() |
852 |
: snd @action; |
853 |
}; |
854 |
} |
855 |
|
856 |
#=item $cb2 = timeout $seconds, $cb[, @args] |
857 |
|
858 |
=item cal $port, @msg, $callback[, $timeout] |
859 |
|
860 |
A simple form of RPC - sends a message to the given C<$port> with the |
861 |
given contents (C<@msg>), but adds a reply port to the message. |
862 |
|
863 |
The reply port is created temporarily just for the purpose of receiving |
864 |
the reply, and will be C<kil>ed when no longer needed. |
865 |
|
866 |
A reply message sent to the port is passed to the C<$callback> as-is. |
867 |
|
868 |
If an optional time-out (in seconds) is given and it is not C<undef>, |
869 |
then the callback will be called without any arguments after the time-out |
870 |
elapsed and the port is C<kil>ed. |
871 |
|
872 |
If no time-out is given (or it is C<undef>), then the local port will |
873 |
monitor the remote port instead, so it eventually gets cleaned-up. |
874 |
|
875 |
Currently this function returns the temporary port, but this "feature" |
876 |
might go in future versions unless you can make a convincing case that |
877 |
this is indeed useful for something. |
878 |
|
879 |
=cut |
880 |
|
881 |
sub cal(@) { |
882 |
my $timeout = ref $_[-1] ? undef : pop; |
883 |
my $cb = pop; |
884 |
|
885 |
my $port = port { |
886 |
undef $timeout; |
887 |
kil $SELF; |
888 |
&$cb; |
889 |
}; |
890 |
|
891 |
if (defined $timeout) { |
892 |
$timeout = AE::timer $timeout, 0, sub { |
893 |
undef $timeout; |
894 |
kil $port; |
895 |
$cb->(); |
896 |
}; |
897 |
} else { |
898 |
mon $_[0], sub { |
899 |
kil $port; |
900 |
$cb->(); |
901 |
}; |
902 |
} |
903 |
|
904 |
push @_, $port; |
905 |
&snd; |
906 |
|
907 |
$port |
908 |
} |
909 |
|
910 |
=back |
911 |
|
912 |
=head1 DISTRIBUTED DATABASE |
913 |
|
914 |
AnyEvent::MP comes with a simple distributed database. The database will |
915 |
be mirrored asynchronously on all global nodes. Other nodes bind to one |
916 |
of the global nodes for their needs. Every node has a "local database" |
917 |
which contains all the values that are set locally. All local databases |
918 |
are merged together to form the global database, which can be queried. |
919 |
|
920 |
The database structure is that of a two-level hash - the database hash |
921 |
contains hashes which contain values, similarly to a perl hash of hashes, |
922 |
i.e.: |
923 |
|
924 |
$DATABASE{$family}{$subkey} = $value |
925 |
|
926 |
The top level hash key is called "family", and the second-level hash key |
927 |
is called "subkey" or simply "key". |
928 |
|
929 |
The family must be alphanumeric, i.e. start with a letter and consist |
930 |
of letters, digits, underscores and colons (C<[A-Za-z][A-Za-z0-9_:]*>, |
931 |
pretty much like Perl module names. |
932 |
|
933 |
As the family namespace is global, it is recommended to prefix family names |
934 |
with the name of the application or module using it. |
935 |
|
936 |
The subkeys must be non-empty strings, with no further restrictions. |
937 |
|
938 |
The values should preferably be strings, but other perl scalars should |
939 |
work as well (such as C<undef>, arrays and hashes). |
940 |
|
941 |
Every database entry is owned by one node - adding the same family/subkey |
942 |
combination on multiple nodes will not cause discomfort for AnyEvent::MP, |
943 |
but the result might be nondeterministic, i.e. the key might have |
944 |
different values on different nodes. |
945 |
|
946 |
Different subkeys in the same family can be owned by different nodes |
947 |
without problems, and in fact, this is the common method to create worker |
948 |
pools. For example, a worker port for image scaling might do this: |
949 |
|
950 |
db_set my_image_scalers => $port; |
951 |
|
952 |
And clients looking for an image scaler will want to get the |
953 |
C<my_image_scalers> keys from time to time: |
954 |
|
955 |
db_keys my_image_scalers => sub { |
956 |
@ports = @{ $_[0] }; |
957 |
}; |
958 |
|
959 |
Or better yet, they want to monitor the database family, so they always |
960 |
have a reasonable up-to-date copy: |
961 |
|
962 |
db_mon my_image_scalers => sub { |
963 |
@ports = keys %{ $_[0] }; |
964 |
}; |
965 |
|
966 |
In general, you can set or delete single subkeys, but query and monitor |
967 |
whole families only. |
968 |
|
969 |
If you feel the need to monitor or query a single subkey, try giving it |
970 |
it's own family. |
971 |
|
972 |
=over |
973 |
|
974 |
=item $guard = db_set $family => $subkey [=> $value] |
975 |
|
976 |
Sets (or replaces) a key to the database - if C<$value> is omitted, |
977 |
C<undef> is used instead. |
978 |
|
979 |
When called in non-void context, C<db_set> returns a guard that |
980 |
automatically calls C<db_del> when it is destroyed. |
981 |
|
982 |
=item db_del $family => $subkey... |
983 |
|
984 |
Deletes one or more subkeys from the database family. |
985 |
|
986 |
=item $guard = db_reg $family => $port => $value |
987 |
|
988 |
=item $guard = db_reg $family => $port |
989 |
|
990 |
=item $guard = db_reg $family |
991 |
|
992 |
Registers a port in the given family and optionally returns a guard to |
993 |
remove it. |
994 |
|
995 |
This function basically does the same as: |
996 |
|
997 |
db_set $family => $port => $value |
998 |
|
999 |
Except that the port is monitored and automatically removed from the |
1000 |
database family when it is kil'ed. |
1001 |
|
1002 |
If C<$value> is missing, C<undef> is used. If C<$port> is missing, then |
1003 |
C<$SELF> is used. |
1004 |
|
1005 |
This function is most useful to register a port in some port group (which |
1006 |
is just another name for a database family), and have it removed when the |
1007 |
port is gone. This works best when the port is a local port. |
1008 |
|
1009 |
=cut |
1010 |
|
1011 |
sub db_reg($$;$) { |
1012 |
my $family = shift; |
1013 |
my $port = @_ ? shift : $SELF; |
1014 |
|
1015 |
my $clr = sub { db_del $family => $port }; |
1016 |
mon $port, $clr; |
1017 |
|
1018 |
db_set $family => $port => $_[0]; |
1019 |
|
1020 |
defined wantarray |
1021 |
and &Guard::guard ($clr) |
1022 |
} |
1023 |
|
1024 |
=item db_family $family => $cb->(\%familyhash) |
1025 |
|
1026 |
Queries the named database C<$family> and call the callback with the |
1027 |
family represented as a hash. You can keep and freely modify the hash. |
1028 |
|
1029 |
=item db_keys $family => $cb->(\@keys) |
1030 |
|
1031 |
Same as C<db_family>, except it only queries the family I<subkeys> and passes |
1032 |
them as array reference to the callback. |
1033 |
|
1034 |
=item db_values $family => $cb->(\@values) |
1035 |
|
1036 |
Same as C<db_family>, except it only queries the family I<values> and passes them |
1037 |
as array reference to the callback. |
1038 |
|
1039 |
=item $guard = db_mon $family => $cb->($familyhash, \@added, \@changed, \@deleted) |
1040 |
|
1041 |
Creates a monitor on the given database family. Each time a key is set |
1042 |
or or is deleted the callback is called with a hash containing the |
1043 |
database family and three lists of added, changed and deleted subkeys, |
1044 |
respectively. If no keys have changed then the array reference might be |
1045 |
C<undef> or even missing. |
1046 |
|
1047 |
If not called in void context, a guard object is returned that, when |
1048 |
destroyed, stops the monitor. |
1049 |
|
1050 |
The family hash reference and the key arrays belong to AnyEvent::MP and |
1051 |
B<must not be modified or stored> by the callback. When in doubt, make a |
1052 |
copy. |
1053 |
|
1054 |
As soon as possible after the monitoring starts, the callback will be |
1055 |
called with the intiial contents of the family, even if it is empty, |
1056 |
i.e. there will always be a timely call to the callback with the current |
1057 |
contents. |
1058 |
|
1059 |
It is possible that the callback is called with a change event even though |
1060 |
the subkey is already present and the value has not changed. |
1061 |
|
1062 |
The monitoring stops when the guard object is destroyed. |
1063 |
|
1064 |
Example: on every change to the family "mygroup", print out all keys. |
1065 |
|
1066 |
my $guard = db_mon mygroup => sub { |
1067 |
my ($family, $a, $c, $d) = @_; |
1068 |
print "mygroup members: ", (join " ", keys %$family), "\n"; |
1069 |
}; |
1070 |
|
1071 |
Exmaple: wait until the family "My::Module::workers" is non-empty. |
1072 |
|
1073 |
my $guard; $guard = db_mon My::Module::workers => sub { |
1074 |
my ($family, $a, $c, $d) = @_; |
1075 |
return unless %$family; |
1076 |
undef $guard; |
1077 |
print "My::Module::workers now nonempty\n"; |
1078 |
}; |
1079 |
|
1080 |
Example: print all changes to the family "AnyRvent::Fantasy::Module". |
1081 |
|
1082 |
my $guard = db_mon AnyRvent::Fantasy::Module => sub { |
1083 |
my ($family, $a, $c, $d) = @_; |
1084 |
|
1085 |
print "+$_=$family->{$_}\n" for @$a; |
1086 |
print "*$_=$family->{$_}\n" for @$c; |
1087 |
print "-$_=$family->{$_}\n" for @$d; |
1088 |
}; |
1089 |
|
1090 |
=cut |
1091 |
|
1092 |
=back |
1093 |
|
1094 |
=head1 AnyEvent::MP vs. Distributed Erlang |
1095 |
|
1096 |
AnyEvent::MP got lots of its ideas from distributed Erlang (Erlang node |
1097 |
== aemp node, Erlang process == aemp port), so many of the documents and |
1098 |
programming techniques employed by Erlang apply to AnyEvent::MP. Here is a |
1099 |
sample: |
1100 |
|
1101 |
http://www.erlang.se/doc/programming_rules.shtml |
1102 |
http://erlang.org/doc/getting_started/part_frame.html # chapters 3 and 4 |
1103 |
http://erlang.org/download/erlang-book-part1.pdf # chapters 5 and 6 |
1104 |
http://erlang.org/download/armstrong_thesis_2003.pdf # chapters 4 and 5 |
1105 |
|
1106 |
Despite the similarities, there are also some important differences: |
1107 |
|
1108 |
=over 4 |
1109 |
|
1110 |
=item * Node IDs are arbitrary strings in AEMP. |
1111 |
|
1112 |
Erlang relies on special naming and DNS to work everywhere in the same |
1113 |
way. AEMP relies on each node somehow knowing its own address(es) (e.g. by |
1114 |
configuration or DNS), and possibly the addresses of some seed nodes, but |
1115 |
will otherwise discover other nodes (and their IDs) itself. |
1116 |
|
1117 |
=item * Erlang has a "remote ports are like local ports" philosophy, AEMP |
1118 |
uses "local ports are like remote ports". |
1119 |
|
1120 |
The failure modes for local ports are quite different (runtime errors |
1121 |
only) then for remote ports - when a local port dies, you I<know> it dies, |
1122 |
when a connection to another node dies, you know nothing about the other |
1123 |
port. |
1124 |
|
1125 |
Erlang pretends remote ports are as reliable as local ports, even when |
1126 |
they are not. |
1127 |
|
1128 |
AEMP encourages a "treat remote ports differently" philosophy, with local |
1129 |
ports being the special case/exception, where transport errors cannot |
1130 |
occur. |
1131 |
|
1132 |
=item * Erlang uses processes and a mailbox, AEMP does not queue. |
1133 |
|
1134 |
Erlang uses processes that selectively receive messages out of order, and |
1135 |
therefore needs a queue. AEMP is event based, queuing messages would serve |
1136 |
no useful purpose. For the same reason the pattern-matching abilities |
1137 |
of AnyEvent::MP are more limited, as there is little need to be able to |
1138 |
filter messages without dequeuing them. |
1139 |
|
1140 |
This is not a philosophical difference, but simply stems from AnyEvent::MP |
1141 |
being event-based, while Erlang is process-based. |
1142 |
|
1143 |
You cna have a look at L<Coro::MP> for a more Erlang-like process model on |
1144 |
top of AEMP and Coro threads. |
1145 |
|
1146 |
=item * Erlang sends are synchronous, AEMP sends are asynchronous. |
1147 |
|
1148 |
Sending messages in Erlang is synchronous and blocks the process until |
1149 |
a conenction has been established and the message sent (and so does not |
1150 |
need a queue that can overflow). AEMP sends return immediately, connection |
1151 |
establishment is handled in the background. |
1152 |
|
1153 |
=item * Erlang suffers from silent message loss, AEMP does not. |
1154 |
|
1155 |
Erlang implements few guarantees on messages delivery - messages can get |
1156 |
lost without any of the processes realising it (i.e. you send messages a, |
1157 |
b, and c, and the other side only receives messages a and c). |
1158 |
|
1159 |
AEMP guarantees (modulo hardware errors) correct ordering, and the |
1160 |
guarantee that after one message is lost, all following ones sent to the |
1161 |
same port are lost as well, until monitoring raises an error, so there are |
1162 |
no silent "holes" in the message sequence. |
1163 |
|
1164 |
If you want your software to be very reliable, you have to cope with |
1165 |
corrupted and even out-of-order messages in both Erlang and AEMP. AEMP |
1166 |
simply tries to work better in common error cases, such as when a network |
1167 |
link goes down. |
1168 |
|
1169 |
=item * Erlang can send messages to the wrong port, AEMP does not. |
1170 |
|
1171 |
In Erlang it is quite likely that a node that restarts reuses an Erlang |
1172 |
process ID known to other nodes for a completely different process, |
1173 |
causing messages destined for that process to end up in an unrelated |
1174 |
process. |
1175 |
|
1176 |
AEMP does not reuse port IDs, so old messages or old port IDs floating |
1177 |
around in the network will not be sent to an unrelated port. |
1178 |
|
1179 |
=item * Erlang uses unprotected connections, AEMP uses secure |
1180 |
authentication and can use TLS. |
1181 |
|
1182 |
AEMP can use a proven protocol - TLS - to protect connections and |
1183 |
securely authenticate nodes. |
1184 |
|
1185 |
=item * The AEMP protocol is optimised for both text-based and binary |
1186 |
communications. |
1187 |
|
1188 |
The AEMP protocol, unlike the Erlang protocol, supports both programming |
1189 |
language independent text-only protocols (good for debugging), and binary, |
1190 |
language-specific serialisers (e.g. Storable). By default, unless TLS is |
1191 |
used, the protocol is actually completely text-based. |
1192 |
|
1193 |
It has also been carefully designed to be implementable in other languages |
1194 |
with a minimum of work while gracefully degrading functionality to make the |
1195 |
protocol simple. |
1196 |
|
1197 |
=item * AEMP has more flexible monitoring options than Erlang. |
1198 |
|
1199 |
In Erlang, you can chose to receive I<all> exit signals as messages or |
1200 |
I<none>, there is no in-between, so monitoring single Erlang processes is |
1201 |
difficult to implement. |
1202 |
|
1203 |
Monitoring in AEMP is more flexible than in Erlang, as one can choose |
1204 |
between automatic kill, exit message or callback on a per-port basis. |
1205 |
|
1206 |
=item * Erlang tries to hide remote/local connections, AEMP does not. |
1207 |
|
1208 |
Monitoring in Erlang is not an indicator of process death/crashes, in the |
1209 |
same way as linking is (except linking is unreliable in Erlang). |
1210 |
|
1211 |
In AEMP, you don't "look up" registered port names or send to named ports |
1212 |
that might or might not be persistent. Instead, you normally spawn a port |
1213 |
on the remote node. The init function monitors you, and you monitor the |
1214 |
remote port. Since both monitors are local to the node, they are much more |
1215 |
reliable (no need for C<spawn_link>). |
1216 |
|
1217 |
This also saves round-trips and avoids sending messages to the wrong port |
1218 |
(hard to do in Erlang). |
1219 |
|
1220 |
=back |
1221 |
|
1222 |
=head1 RATIONALE |
1223 |
|
1224 |
=over 4 |
1225 |
|
1226 |
=item Why strings for port and node IDs, why not objects? |
1227 |
|
1228 |
We considered "objects", but found that the actual number of methods |
1229 |
that can be called are quite low. Since port and node IDs travel over |
1230 |
the network frequently, the serialising/deserialising would add lots of |
1231 |
overhead, as well as having to keep a proxy object everywhere. |
1232 |
|
1233 |
Strings can easily be printed, easily serialised etc. and need no special |
1234 |
procedures to be "valid". |
1235 |
|
1236 |
And as a result, a port with just a default receiver consists of a single |
1237 |
code reference stored in a global hash - it can't become much cheaper. |
1238 |
|
1239 |
=item Why favour JSON, why not a real serialising format such as Storable? |
1240 |
|
1241 |
In fact, any AnyEvent::MP node will happily accept Storable as framing |
1242 |
format, but currently there is no way to make a node use Storable by |
1243 |
default (although all nodes will accept it). |
1244 |
|
1245 |
The default framing protocol is JSON because a) JSON::XS is many times |
1246 |
faster for small messages and b) most importantly, after years of |
1247 |
experience we found that object serialisation is causing more problems |
1248 |
than it solves: Just like function calls, objects simply do not travel |
1249 |
easily over the network, mostly because they will always be a copy, so you |
1250 |
always have to re-think your design. |
1251 |
|
1252 |
Keeping your messages simple, concentrating on data structures rather than |
1253 |
objects, will keep your messages clean, tidy and efficient. |
1254 |
|
1255 |
=back |
1256 |
|
1257 |
=head1 PORTING FROM AnyEvent::MP VERSION 1.X |
1258 |
|
1259 |
AEMP version 2 has three major incompatible changes compared to version 1: |
1260 |
|
1261 |
=over 4 |
1262 |
|
1263 |
=item AnyEvent::MP::Global no longer has group management functions. |
1264 |
|
1265 |
AnyEvent::MP now comes with a distributed database that is more |
1266 |
powerful. It's database families map closely to ports, but the API has |
1267 |
minor differences: |
1268 |
|
1269 |
grp_reg $group, $port # old |
1270 |
db_reg $group, $port # new |
1271 |
|
1272 |
$list = grp_get $group # old |
1273 |
db_keys $group, sub { my $list = shift } # new |
1274 |
|
1275 |
grp_mon $group, $cb->(\@ports, $add, $del) # old |
1276 |
db_mon $group, $cb->(\%ports, $add, $change, $del) # new |
1277 |
|
1278 |
C<grp_reg> is a no-brainer (just replace by C<db_reg>), but C<grp_get> |
1279 |
is no longer instant, because the local node might not have a copy of |
1280 |
the group. This can be partially remedied by using C<db_mon> to keep an |
1281 |
updated copy of the group: |
1282 |
|
1283 |
my $local_group_copy; |
1284 |
db_mon $group => sub { $local_group_copy = shift }; |
1285 |
|
1286 |
# no keys %$local_group_copy always returns the most up-to-date |
1287 |
# list of ports in the group. |
1288 |
|
1289 |
C<grp_mon> can almost be replaced by C<db_mon>: |
1290 |
|
1291 |
db_mon $group => sub { |
1292 |
my ($ports, $add, $chg, $lde) = @_; |
1293 |
$ports = [keys %$ports]; |
1294 |
|
1295 |
# now $ports, $add and $del are the same as |
1296 |
# were originally passed by grp_mon. |
1297 |
... |
1298 |
}; |
1299 |
|
1300 |
=item Nodes not longer connect to all other nodes. |
1301 |
|
1302 |
In AEMP 1.x, every node automatically loads the L<AnyEvent::MP::Global> |
1303 |
module, which in turn would create connections to all other nodes in the |
1304 |
network (helped by the seed nodes). |
1305 |
|
1306 |
In version 2.x, global nodes still connect to all other global nodes, but |
1307 |
other nodes don't - now every node either is a global node itself, or |
1308 |
attaches itself to another global node. |
1309 |
|
1310 |
If a node isn't a global node itself, then it attaches itself to one |
1311 |
of its seed nodes. If that seed node isn't a global node yet, it will |
1312 |
automatically be upgraded to a global node. |
1313 |
|
1314 |
So in many cases, nothing needs to be changed - one just has to make sure |
1315 |
that all seed nodes are meshed together with the other seed nodes (as with |
1316 |
AEMP 1.x), and other nodes specify them as seed nodes. |
1317 |
|
1318 |
Not opening a connection to every other node is usually an advantage, |
1319 |
except when you need the lower latency of an already established |
1320 |
connection. To ensure a node establishes a connection to another node, |
1321 |
you can monitor the node port (C<mon $node, ...>), which will attempt to |
1322 |
create the connection (and notify you when the connection fails). |
1323 |
|
1324 |
=item Listener-less nodes (nodes without binds) are gone. |
1325 |
|
1326 |
And are not coming back, at least not in their old form. If no C<binds> |
1327 |
are specified for a node, AnyEvent::MP now assumes a default of C<*:*>. |
1328 |
|
1329 |
There are vague plans to implement some form of routing domains, which |
1330 |
might or might not bring back listener-less nodes, but don't count on it. |
1331 |
|
1332 |
The fact that most connections are now optional somewhat mitigates this, |
1333 |
as a node can be effectively unreachable from the outside without any |
1334 |
problems, as long as it isn't a global node and only reaches out to other |
1335 |
nodes (as opposed to being contacted from other nodes). |
1336 |
|
1337 |
=item $AnyEvent::MP::Kernel::WARN has gone. |
1338 |
|
1339 |
AnyEvent has acquired a logging framework (L<AnyEvent::Log>), and AEMP now |
1340 |
uses this, and so should your programs. |
1341 |
|
1342 |
Every module now documents what kinds of messages it generates, with |
1343 |
AnyEvent::MP acting as a catch all. |
1344 |
|
1345 |
On the positive side, this means that instead of setting |
1346 |
C<PERL_ANYEVENT_MP_WARNLEVEL>, you can get away by setting C<AE_VERBOSE>, |
1347 |
much less to type. |
1348 |
|
1349 |
=back |
1350 |
|
1351 |
=head1 SEE ALSO |
1352 |
|
1353 |
L<AnyEvent::MP::Intro> - a gentle introduction. |
1354 |
|
1355 |
L<AnyEvent::MP::Kernel> - more, lower-level, stuff. |
1356 |
|
1357 |
L<AnyEvent::MP::Global> - network maintenance and port groups, to find |
1358 |
your applications. |
1359 |
|
1360 |
L<AnyEvent::MP::DataConn> - establish data connections between nodes. |
1361 |
|
1362 |
L<AnyEvent::MP::LogCatcher> - simple service to display log messages from |
1363 |
all nodes. |
1364 |
|
1365 |
L<AnyEvent>. |
1366 |
|
1367 |
=head1 AUTHOR |
1368 |
|
1369 |
Marc Lehmann <schmorp@schmorp.de> |
1370 |
http://home.schmorp.de/ |
1371 |
|
1372 |
=cut |
1373 |
|
1374 |
1 |
1375 |
|