1 |
=head1 NAME |
2 |
|
3 |
AnyEvent::MP - multi-processing/message-passing framework |
4 |
|
5 |
=head1 SYNOPSIS |
6 |
|
7 |
use AnyEvent::MP; |
8 |
|
9 |
$NODE # contains this node's noderef |
10 |
NODE # returns this node's noderef |
11 |
NODE $port # returns the noderef of the port |
12 |
|
13 |
$SELF # receiving/own port id in rcv callbacks |
14 |
|
15 |
# initialise the node so it can send/receive messages |
16 |
initialise_node; |
17 |
|
18 |
# ports are message endpoints |
19 |
|
20 |
# sending messages |
21 |
snd $port, type => data...; |
22 |
snd $port, @msg; |
23 |
snd @msg_with_first_element_being_a_port; |
24 |
|
25 |
# creating/using ports, the simple way |
26 |
my $simple_port = port { my @msg = @_; 0 }; |
27 |
|
28 |
# creating/using ports, tagged message matching |
29 |
my $port = port; |
30 |
rcv $port, ping => sub { snd $_[0], "pong"; 0 }; |
31 |
rcv $port, pong => sub { warn "pong received\n"; 0 }; |
32 |
|
33 |
# create a port on another node |
34 |
my $port = spawn $node, $initfunc, @initdata; |
35 |
|
36 |
# monitoring |
37 |
mon $port, $cb->(@msg) # callback is invoked on death |
38 |
mon $port, $otherport # kill otherport on abnormal death |
39 |
mon $port, $otherport, @msg # send message on death |
40 |
|
41 |
=head1 CURRENT STATUS |
42 |
|
43 |
AnyEvent::MP - stable API, should work |
44 |
AnyEvent::MP::Intro - outdated |
45 |
AnyEvent::MP::Kernel - mostly stable |
46 |
AnyEvent::MP::Global - mostly stable |
47 |
AnyEvent::MP::Node - mostly stable, but internal anyways |
48 |
AnyEvent::MP::Transport - mostly stable, but internal anyways |
49 |
|
50 |
stay tuned. |
51 |
|
52 |
=head1 DESCRIPTION |
53 |
|
54 |
This module (-family) implements a simple message passing framework. |
55 |
|
56 |
Despite its simplicity, you can securely message other processes running |
57 |
on the same or other hosts, and you can supervise entities remotely. |
58 |
|
59 |
For an introduction to this module family, see the L<AnyEvent::MP::Intro> |
60 |
manual page and the examples under F<eg/>. |
61 |
|
62 |
At the moment, this module family is a bit underdocumented. |
63 |
|
64 |
=head1 CONCEPTS |
65 |
|
66 |
=over 4 |
67 |
|
68 |
=item port |
69 |
|
70 |
A port is something you can send messages to (with the C<snd> function). |
71 |
|
72 |
Ports allow you to register C<rcv> handlers that can match all or just |
73 |
some messages. Messages send to ports will not be queued, regardless of |
74 |
anything was listening for them or not. |
75 |
|
76 |
=item port ID - C<nodeid#portname> |
77 |
|
78 |
A port ID is the concatenation of a node ID, a hash-mark (C<#>) as |
79 |
separator, and a port name (a printable string of unspecified format). |
80 |
|
81 |
=item node |
82 |
|
83 |
A node is a single process containing at least one port - the node port, |
84 |
which enables nodes to manage each other remotely, and to create new |
85 |
ports. |
86 |
|
87 |
Nodes are either public (have one or more listening ports) or private |
88 |
(no listening ports). Private nodes cannot talk to other private nodes |
89 |
currently. |
90 |
|
91 |
=item node ID - C<[a-za-Z0-9_\-.:]+> |
92 |
|
93 |
A node ID is a string that uniquely identifies the node within a |
94 |
network. Depending on the configuration used, node IDs can look like a |
95 |
hostname, a hostname and a port, or a random string. AnyEvent::MP itself |
96 |
doesn't interpret node IDs in any way. |
97 |
|
98 |
=item binds - C<ip:port> |
99 |
|
100 |
Nodes can only talk to each other by creating some kind of connection to |
101 |
each other. To do this, nodes should listen on one or more local transport |
102 |
endpoints - binds. Currently, only standard C<ip:port> specifications can |
103 |
be used, which specify TCP ports to listen on. |
104 |
|
105 |
=item seeds - C<host:port> |
106 |
|
107 |
When a node starts, it knows nothing about the network. To teach the node |
108 |
about the network it first has to contact some other node within the |
109 |
network. This node is called a seed. |
110 |
|
111 |
Seeds are transport endpoint(s) of as many nodes as one wants. Those nodes |
112 |
are expected to be long-running, and at least one of those should always |
113 |
be available. When nodes run out of connections (e.g. due to a network |
114 |
error), they try to re-establish connections to some seednodes again to |
115 |
join the network. |
116 |
|
117 |
Apart from being sued for seeding, seednodes are not special in any way - |
118 |
every public node can be a seednode. |
119 |
|
120 |
=back |
121 |
|
122 |
=head1 VARIABLES/FUNCTIONS |
123 |
|
124 |
=over 4 |
125 |
|
126 |
=cut |
127 |
|
128 |
package AnyEvent::MP; |
129 |
|
130 |
use AnyEvent::MP::Kernel; |
131 |
|
132 |
use common::sense; |
133 |
|
134 |
use Carp (); |
135 |
|
136 |
use AE (); |
137 |
|
138 |
use base "Exporter"; |
139 |
|
140 |
our $VERSION = $AnyEvent::MP::Kernel::VERSION; |
141 |
|
142 |
our @EXPORT = qw( |
143 |
NODE $NODE *SELF node_of after |
144 |
initialise_node |
145 |
snd rcv mon mon_guard kil reg psub spawn |
146 |
port |
147 |
); |
148 |
|
149 |
our $SELF; |
150 |
|
151 |
sub _self_die() { |
152 |
my $msg = $@; |
153 |
$msg =~ s/\n+$// unless ref $msg; |
154 |
kil $SELF, die => $msg; |
155 |
} |
156 |
|
157 |
=item $thisnode = NODE / $NODE |
158 |
|
159 |
The C<NODE> function returns, and the C<$NODE> variable contains, the node |
160 |
ID of the node running in the current process. This value is initialised by |
161 |
a call to C<initialise_node>. |
162 |
|
163 |
=item $nodeid = node_of $port |
164 |
|
165 |
Extracts and returns the node ID from a port ID or a node ID. |
166 |
|
167 |
=item initialise_node $profile_name |
168 |
|
169 |
Before a node can talk to other nodes on the network (i.e. enter |
170 |
"distributed mode") it has to initialise itself - the minimum a node needs |
171 |
to know is its own name, and optionally it should know the addresses of |
172 |
some other nodes in the network to discover other nodes. |
173 |
|
174 |
This function initialises a node - it must be called exactly once (or |
175 |
never) before calling other AnyEvent::MP functions. |
176 |
|
177 |
The first argument is a profile name. If it is C<undef> or missing, then |
178 |
the current nodename will be used instead (i.e. F<uname -n>). |
179 |
|
180 |
The function then looks up the profile in the aemp configuration (see the |
181 |
L<aemp> commandline utility). |
182 |
|
183 |
If the profile specifies a node ID, then this will become the node ID of |
184 |
this process. If not, then the profile name will be used as node ID. The |
185 |
special node ID of C<anon/> will be replaced by a random node ID. |
186 |
|
187 |
The next step is to look up the binds in the profile, followed by binding |
188 |
aemp protocol listeners on all binds specified (it is possible and valid |
189 |
to have no binds, meaning that the node cannot be contacted form the |
190 |
outside. This means the node cannot talk to other nodes that also have no |
191 |
binds, but it can still talk to all "normal" nodes). |
192 |
|
193 |
If the profile does not specify a binds list, then the node ID will be |
194 |
treated as if it were of the form C<host:port>, which will be resolved and |
195 |
used as binds list. |
196 |
|
197 |
Lastly, the seeds list from the profile is passed to the |
198 |
L<AnyEvent::MP::Global> module, which will then use it to keep |
199 |
connectivity with at least on of those seed nodes at any point in time. |
200 |
|
201 |
Example: become a distributed node listening on the guessed noderef, or |
202 |
the one specified via C<aemp> for the current node. This should be the |
203 |
most common form of invocation for "daemon"-type nodes. |
204 |
|
205 |
initialise_node; |
206 |
|
207 |
Example: become an anonymous node. This form is often used for commandline |
208 |
clients. |
209 |
|
210 |
initialise_node "anon/"; |
211 |
|
212 |
Example: become a distributed node. If there is no profile of the given |
213 |
name, or no binds list was specified, resolve C<localhost:4044> and bind |
214 |
on the resulting addresses. |
215 |
|
216 |
initialise_node "localhost:4044"; |
217 |
|
218 |
=item $SELF |
219 |
|
220 |
Contains the current port id while executing C<rcv> callbacks or C<psub> |
221 |
blocks. |
222 |
|
223 |
=item *SELF, SELF, %SELF, @SELF... |
224 |
|
225 |
Due to some quirks in how perl exports variables, it is impossible to |
226 |
just export C<$SELF>, all the symbols named C<SELF> are exported by this |
227 |
module, but only C<$SELF> is currently used. |
228 |
|
229 |
=item snd $port, type => @data |
230 |
|
231 |
=item snd $port, @msg |
232 |
|
233 |
Send the given message to the given port, which can identify either a |
234 |
local or a remote port, and must be a port ID. |
235 |
|
236 |
While the message can be almost anything, it is highly recommended to |
237 |
use a string as first element (a port ID, or some word that indicates a |
238 |
request type etc.) and to consist if only simple perl values (scalars, |
239 |
arrays, hashes) - if you think you need to pass an object, think again. |
240 |
|
241 |
The message data logically becomes read-only after a call to this |
242 |
function: modifying any argument (or values referenced by them) is |
243 |
forbidden, as there can be considerable time between the call to C<snd> |
244 |
and the time the message is actually being serialised - in fact, it might |
245 |
never be copied as within the same process it is simply handed to the |
246 |
receiving port. |
247 |
|
248 |
The type of data you can transfer depends on the transport protocol: when |
249 |
JSON is used, then only strings, numbers and arrays and hashes consisting |
250 |
of those are allowed (no objects). When Storable is used, then anything |
251 |
that Storable can serialise and deserialise is allowed, and for the local |
252 |
node, anything can be passed. Best rely only on the common denominator of |
253 |
these. |
254 |
|
255 |
=item $local_port = port |
256 |
|
257 |
Create a new local port object and returns its port ID. Initially it has |
258 |
no callbacks set and will throw an error when it receives messages. |
259 |
|
260 |
=item $local_port = port { my @msg = @_ } |
261 |
|
262 |
Creates a new local port, and returns its ID. Semantically the same as |
263 |
creating a port and calling C<rcv $port, $callback> on it. |
264 |
|
265 |
The block will be called for every message received on the port, with the |
266 |
global variable C<$SELF> set to the port ID. Runtime errors will cause the |
267 |
port to be C<kil>ed. The message will be passed as-is, no extra argument |
268 |
(i.e. no port ID) will be passed to the callback. |
269 |
|
270 |
If you want to stop/destroy the port, simply C<kil> it: |
271 |
|
272 |
my $port = port { |
273 |
my @msg = @_; |
274 |
... |
275 |
kil $SELF; |
276 |
}; |
277 |
|
278 |
=cut |
279 |
|
280 |
sub rcv($@); |
281 |
|
282 |
sub _kilme { |
283 |
die "received message on port without callback"; |
284 |
} |
285 |
|
286 |
sub port(;&) { |
287 |
my $id = "$UNIQ." . $ID++; |
288 |
my $port = "$NODE#$id"; |
289 |
|
290 |
rcv $port, shift || \&_kilme; |
291 |
|
292 |
$port |
293 |
} |
294 |
|
295 |
=item rcv $local_port, $callback->(@msg) |
296 |
|
297 |
Replaces the default callback on the specified port. There is no way to |
298 |
remove the default callback: use C<sub { }> to disable it, or better |
299 |
C<kil> the port when it is no longer needed. |
300 |
|
301 |
The global C<$SELF> (exported by this module) contains C<$port> while |
302 |
executing the callback. Runtime errors during callback execution will |
303 |
result in the port being C<kil>ed. |
304 |
|
305 |
The default callback received all messages not matched by a more specific |
306 |
C<tag> match. |
307 |
|
308 |
=item rcv $local_port, tag => $callback->(@msg_without_tag), ... |
309 |
|
310 |
Register (or replace) callbacks to be called on messages starting with the |
311 |
given tag on the given port (and return the port), or unregister it (when |
312 |
C<$callback> is C<$undef> or missing). There can only be one callback |
313 |
registered for each tag. |
314 |
|
315 |
The original message will be passed to the callback, after the first |
316 |
element (the tag) has been removed. The callback will use the same |
317 |
environment as the default callback (see above). |
318 |
|
319 |
Example: create a port and bind receivers on it in one go. |
320 |
|
321 |
my $port = rcv port, |
322 |
msg1 => sub { ... }, |
323 |
msg2 => sub { ... }, |
324 |
; |
325 |
|
326 |
Example: create a port, bind receivers and send it in a message elsewhere |
327 |
in one go: |
328 |
|
329 |
snd $otherport, reply => |
330 |
rcv port, |
331 |
msg1 => sub { ... }, |
332 |
... |
333 |
; |
334 |
|
335 |
Example: temporarily register a rcv callback for a tag matching some port |
336 |
(e.g. for a rpc reply) and unregister it after a message was received. |
337 |
|
338 |
rcv $port, $otherport => sub { |
339 |
my @reply = @_; |
340 |
|
341 |
rcv $SELF, $otherport; |
342 |
}; |
343 |
|
344 |
=cut |
345 |
|
346 |
sub rcv($@) { |
347 |
my $port = shift; |
348 |
my ($noderef, $portid) = split /#/, $port, 2; |
349 |
|
350 |
$NODE{$noderef} == $NODE{""} |
351 |
or Carp::croak "$port: rcv can only be called on local ports, caught"; |
352 |
|
353 |
while (@_) { |
354 |
if (ref $_[0]) { |
355 |
if (my $self = $PORT_DATA{$portid}) { |
356 |
"AnyEvent::MP::Port" eq ref $self |
357 |
or Carp::croak "$port: rcv can only be called on message matching ports, caught"; |
358 |
|
359 |
$self->[2] = shift; |
360 |
} else { |
361 |
my $cb = shift; |
362 |
$PORT{$portid} = sub { |
363 |
local $SELF = $port; |
364 |
eval { &$cb }; _self_die if $@; |
365 |
}; |
366 |
} |
367 |
} elsif (defined $_[0]) { |
368 |
my $self = $PORT_DATA{$portid} ||= do { |
369 |
my $self = bless [$PORT{$port} || sub { }, { }, $port], "AnyEvent::MP::Port"; |
370 |
|
371 |
$PORT{$portid} = sub { |
372 |
local $SELF = $port; |
373 |
|
374 |
if (my $cb = $self->[1]{$_[0]}) { |
375 |
shift; |
376 |
eval { &$cb }; _self_die if $@; |
377 |
} else { |
378 |
&{ $self->[0] }; |
379 |
} |
380 |
}; |
381 |
|
382 |
$self |
383 |
}; |
384 |
|
385 |
"AnyEvent::MP::Port" eq ref $self |
386 |
or Carp::croak "$port: rcv can only be called on message matching ports, caught"; |
387 |
|
388 |
my ($tag, $cb) = splice @_, 0, 2; |
389 |
|
390 |
if (defined $cb) { |
391 |
$self->[1]{$tag} = $cb; |
392 |
} else { |
393 |
delete $self->[1]{$tag}; |
394 |
} |
395 |
} |
396 |
} |
397 |
|
398 |
$port |
399 |
} |
400 |
|
401 |
=item $closure = psub { BLOCK } |
402 |
|
403 |
Remembers C<$SELF> and creates a closure out of the BLOCK. When the |
404 |
closure is executed, sets up the environment in the same way as in C<rcv> |
405 |
callbacks, i.e. runtime errors will cause the port to get C<kil>ed. |
406 |
|
407 |
This is useful when you register callbacks from C<rcv> callbacks: |
408 |
|
409 |
rcv delayed_reply => sub { |
410 |
my ($delay, @reply) = @_; |
411 |
my $timer = AE::timer $delay, 0, psub { |
412 |
snd @reply, $SELF; |
413 |
}; |
414 |
}; |
415 |
|
416 |
=cut |
417 |
|
418 |
sub psub(&) { |
419 |
my $cb = shift; |
420 |
|
421 |
my $port = $SELF |
422 |
or Carp::croak "psub can only be called from within rcv or psub callbacks, not"; |
423 |
|
424 |
sub { |
425 |
local $SELF = $port; |
426 |
|
427 |
if (wantarray) { |
428 |
my @res = eval { &$cb }; |
429 |
_self_die if $@; |
430 |
@res |
431 |
} else { |
432 |
my $res = eval { &$cb }; |
433 |
_self_die if $@; |
434 |
$res |
435 |
} |
436 |
} |
437 |
} |
438 |
|
439 |
=item $guard = mon $port, $cb->(@reason) # call $cb when $port dies |
440 |
|
441 |
=item $guard = mon $port, $rcvport # kill $rcvport when $port dies |
442 |
|
443 |
=item $guard = mon $port # kill $SELF when $port dies |
444 |
|
445 |
=item $guard = mon $port, $rcvport, @msg # send a message when $port dies |
446 |
|
447 |
Monitor the given port and do something when the port is killed or |
448 |
messages to it were lost, and optionally return a guard that can be used |
449 |
to stop monitoring again. |
450 |
|
451 |
C<mon> effectively guarantees that, in the absence of hardware failures, |
452 |
after starting the monitor, either all messages sent to the port will |
453 |
arrive, or the monitoring action will be invoked after possible message |
454 |
loss has been detected. No messages will be lost "in between" (after |
455 |
the first lost message no further messages will be received by the |
456 |
port). After the monitoring action was invoked, further messages might get |
457 |
delivered again. |
458 |
|
459 |
Note that monitoring-actions are one-shot: once messages are lost (and a |
460 |
monitoring alert was raised), they are removed and will not trigger again. |
461 |
|
462 |
In the first form (callback), the callback is simply called with any |
463 |
number of C<@reason> elements (no @reason means that the port was deleted |
464 |
"normally"). Note also that I<< the callback B<must> never die >>, so use |
465 |
C<eval> if unsure. |
466 |
|
467 |
In the second form (another port given), the other port (C<$rcvport>) |
468 |
will be C<kil>'ed with C<@reason>, iff a @reason was specified, i.e. on |
469 |
"normal" kils nothing happens, while under all other conditions, the other |
470 |
port is killed with the same reason. |
471 |
|
472 |
The third form (kill self) is the same as the second form, except that |
473 |
C<$rvport> defaults to C<$SELF>. |
474 |
|
475 |
In the last form (message), a message of the form C<@msg, @reason> will be |
476 |
C<snd>. |
477 |
|
478 |
As a rule of thumb, monitoring requests should always monitor a port from |
479 |
a local port (or callback). The reason is that kill messages might get |
480 |
lost, just like any other message. Another less obvious reason is that |
481 |
even monitoring requests can get lost (for exmaple, when the connection |
482 |
to the other node goes down permanently). When monitoring a port locally |
483 |
these problems do not exist. |
484 |
|
485 |
Example: call a given callback when C<$port> is killed. |
486 |
|
487 |
mon $port, sub { warn "port died because of <@_>\n" }; |
488 |
|
489 |
Example: kill ourselves when C<$port> is killed abnormally. |
490 |
|
491 |
mon $port; |
492 |
|
493 |
Example: send us a restart message when another C<$port> is killed. |
494 |
|
495 |
mon $port, $self => "restart"; |
496 |
|
497 |
=cut |
498 |
|
499 |
sub mon { |
500 |
my ($noderef, $port) = split /#/, shift, 2; |
501 |
|
502 |
my $node = $NODE{$noderef} || add_node $noderef; |
503 |
|
504 |
my $cb = @_ ? shift : $SELF || Carp::croak 'mon: called with one argument only, but $SELF not set,'; |
505 |
|
506 |
unless (ref $cb) { |
507 |
if (@_) { |
508 |
# send a kill info message |
509 |
my (@msg) = ($cb, @_); |
510 |
$cb = sub { snd @msg, @_ }; |
511 |
} else { |
512 |
# simply kill other port |
513 |
my $port = $cb; |
514 |
$cb = sub { kil $port, @_ if @_ }; |
515 |
} |
516 |
} |
517 |
|
518 |
$node->monitor ($port, $cb); |
519 |
|
520 |
defined wantarray |
521 |
and AnyEvent::Util::guard { $node->unmonitor ($port, $cb) } |
522 |
} |
523 |
|
524 |
=item $guard = mon_guard $port, $ref, $ref... |
525 |
|
526 |
Monitors the given C<$port> and keeps the passed references. When the port |
527 |
is killed, the references will be freed. |
528 |
|
529 |
Optionally returns a guard that will stop the monitoring. |
530 |
|
531 |
This function is useful when you create e.g. timers or other watchers and |
532 |
want to free them when the port gets killed (note the use of C<psub>): |
533 |
|
534 |
$port->rcv (start => sub { |
535 |
my $timer; $timer = mon_guard $port, AE::timer 1, 1, psub { |
536 |
undef $timer if 0.9 < rand; |
537 |
}); |
538 |
}); |
539 |
|
540 |
=cut |
541 |
|
542 |
sub mon_guard { |
543 |
my ($port, @refs) = @_; |
544 |
|
545 |
#TODO: mon-less form? |
546 |
|
547 |
mon $port, sub { 0 && @refs } |
548 |
} |
549 |
|
550 |
=item kil $port[, @reason] |
551 |
|
552 |
Kill the specified port with the given C<@reason>. |
553 |
|
554 |
If no C<@reason> is specified, then the port is killed "normally" (ports |
555 |
monitoring other ports will not necessarily die because a port dies |
556 |
"normally"). |
557 |
|
558 |
Otherwise, linked ports get killed with the same reason (second form of |
559 |
C<mon>, see above). |
560 |
|
561 |
Runtime errors while evaluating C<rcv> callbacks or inside C<psub> blocks |
562 |
will be reported as reason C<< die => $@ >>. |
563 |
|
564 |
Transport/communication errors are reported as C<< transport_error => |
565 |
$message >>. |
566 |
|
567 |
=cut |
568 |
|
569 |
=item $port = spawn $node, $initfunc[, @initdata] |
570 |
|
571 |
Creates a port on the node C<$node> (which can also be a port ID, in which |
572 |
case it's the node where that port resides). |
573 |
|
574 |
The port ID of the newly created port is returned immediately, and it is |
575 |
possible to immediately start sending messages or to monitor the port. |
576 |
|
577 |
After the port has been created, the init function is called on the remote |
578 |
node, in the same context as a C<rcv> callback. This function must be a |
579 |
fully-qualified function name (e.g. C<MyApp::Chat::Server::init>). To |
580 |
specify a function in the main program, use C<::name>. |
581 |
|
582 |
If the function doesn't exist, then the node tries to C<require> |
583 |
the package, then the package above the package and so on (e.g. |
584 |
C<MyApp::Chat::Server>, C<MyApp::Chat>, C<MyApp>) until the function |
585 |
exists or it runs out of package names. |
586 |
|
587 |
The init function is then called with the newly-created port as context |
588 |
object (C<$SELF>) and the C<@initdata> values as arguments. |
589 |
|
590 |
A common idiom is to pass a local port, immediately monitor the spawned |
591 |
port, and in the remote init function, immediately monitor the passed |
592 |
local port. This two-way monitoring ensures that both ports get cleaned up |
593 |
when there is a problem. |
594 |
|
595 |
Example: spawn a chat server port on C<$othernode>. |
596 |
|
597 |
# this node, executed from within a port context: |
598 |
my $server = spawn $othernode, "MyApp::Chat::Server::connect", $SELF; |
599 |
mon $server; |
600 |
|
601 |
# init function on C<$othernode> |
602 |
sub connect { |
603 |
my ($srcport) = @_; |
604 |
|
605 |
mon $srcport; |
606 |
|
607 |
rcv $SELF, sub { |
608 |
... |
609 |
}; |
610 |
} |
611 |
|
612 |
=cut |
613 |
|
614 |
sub _spawn { |
615 |
my $port = shift; |
616 |
my $init = shift; |
617 |
|
618 |
local $SELF = "$NODE#$port"; |
619 |
eval { |
620 |
&{ load_func $init } |
621 |
}; |
622 |
_self_die if $@; |
623 |
} |
624 |
|
625 |
sub spawn(@) { |
626 |
my ($noderef, undef) = split /#/, shift, 2; |
627 |
|
628 |
my $id = "$RUNIQ." . $ID++; |
629 |
|
630 |
$_[0] =~ /::/ |
631 |
or Carp::croak "spawn init function must be a fully-qualified name, caught"; |
632 |
|
633 |
snd_to_func $noderef, "AnyEvent::MP::_spawn" => $id, @_; |
634 |
|
635 |
"$noderef#$id" |
636 |
} |
637 |
|
638 |
=item after $timeout, @msg |
639 |
|
640 |
=item after $timeout, $callback |
641 |
|
642 |
Either sends the given message, or call the given callback, after the |
643 |
specified number of seconds. |
644 |
|
645 |
This is simply a utility function that comes in handy at times - the |
646 |
AnyEvent::MP author is not convinced of the wisdom of having it, though, |
647 |
so it may go away in the future. |
648 |
|
649 |
=cut |
650 |
|
651 |
sub after($@) { |
652 |
my ($timeout, @action) = @_; |
653 |
|
654 |
my $t; $t = AE::timer $timeout, 0, sub { |
655 |
undef $t; |
656 |
ref $action[0] |
657 |
? $action[0]() |
658 |
: snd @action; |
659 |
}; |
660 |
} |
661 |
|
662 |
=back |
663 |
|
664 |
=head1 AnyEvent::MP vs. Distributed Erlang |
665 |
|
666 |
AnyEvent::MP got lots of its ideas from distributed Erlang (Erlang node |
667 |
== aemp node, Erlang process == aemp port), so many of the documents and |
668 |
programming techniques employed by Erlang apply to AnyEvent::MP. Here is a |
669 |
sample: |
670 |
|
671 |
http://www.Erlang.se/doc/programming_rules.shtml |
672 |
http://Erlang.org/doc/getting_started/part_frame.html # chapters 3 and 4 |
673 |
http://Erlang.org/download/Erlang-book-part1.pdf # chapters 5 and 6 |
674 |
http://Erlang.org/download/armstrong_thesis_2003.pdf # chapters 4 and 5 |
675 |
|
676 |
Despite the similarities, there are also some important differences: |
677 |
|
678 |
=over 4 |
679 |
|
680 |
=item * Node IDs are arbitrary strings in AEMP. |
681 |
|
682 |
Erlang relies on special naming and DNS to work everywhere in the same |
683 |
way. AEMP relies on each node somehow knowing its own address(es) (e.g. by |
684 |
configuraiton or DNS), but will otherwise discover other odes itself. |
685 |
|
686 |
=item * Erlang has a "remote ports are like local ports" philosophy, AEMP |
687 |
uses "local ports are like remote ports". |
688 |
|
689 |
The failure modes for local ports are quite different (runtime errors |
690 |
only) then for remote ports - when a local port dies, you I<know> it dies, |
691 |
when a connection to another node dies, you know nothing about the other |
692 |
port. |
693 |
|
694 |
Erlang pretends remote ports are as reliable as local ports, even when |
695 |
they are not. |
696 |
|
697 |
AEMP encourages a "treat remote ports differently" philosophy, with local |
698 |
ports being the special case/exception, where transport errors cannot |
699 |
occur. |
700 |
|
701 |
=item * Erlang uses processes and a mailbox, AEMP does not queue. |
702 |
|
703 |
Erlang uses processes that selectively receive messages, and therefore |
704 |
needs a queue. AEMP is event based, queuing messages would serve no |
705 |
useful purpose. For the same reason the pattern-matching abilities of |
706 |
AnyEvent::MP are more limited, as there is little need to be able to |
707 |
filter messages without dequeing them. |
708 |
|
709 |
(But see L<Coro::MP> for a more Erlang-like process model on top of AEMP). |
710 |
|
711 |
=item * Erlang sends are synchronous, AEMP sends are asynchronous. |
712 |
|
713 |
Sending messages in Erlang is synchronous and blocks the process (and |
714 |
so does not need a queue that can overflow). AEMP sends are immediate, |
715 |
connection establishment is handled in the background. |
716 |
|
717 |
=item * Erlang suffers from silent message loss, AEMP does not. |
718 |
|
719 |
Erlang makes few guarantees on messages delivery - messages can get lost |
720 |
without any of the processes realising it (i.e. you send messages a, b, |
721 |
and c, and the other side only receives messages a and c). |
722 |
|
723 |
AEMP guarantees correct ordering, and the guarantee that after one message |
724 |
is lost, all following ones sent to the same port are lost as well, until |
725 |
monitoring raises an error, so there are no silent "holes" in the message |
726 |
sequence. |
727 |
|
728 |
=item * Erlang can send messages to the wrong port, AEMP does not. |
729 |
|
730 |
In Erlang it is quite likely that a node that restarts reuses a process ID |
731 |
known to other nodes for a completely different process, causing messages |
732 |
destined for that process to end up in an unrelated process. |
733 |
|
734 |
AEMP never reuses port IDs, so old messages or old port IDs floating |
735 |
around in the network will not be sent to an unrelated port. |
736 |
|
737 |
=item * Erlang uses unprotected connections, AEMP uses secure |
738 |
authentication and can use TLS. |
739 |
|
740 |
AEMP can use a proven protocol - TLS - to protect connections and |
741 |
securely authenticate nodes. |
742 |
|
743 |
=item * The AEMP protocol is optimised for both text-based and binary |
744 |
communications. |
745 |
|
746 |
The AEMP protocol, unlike the Erlang protocol, supports both programming |
747 |
language independent text-only protocols (good for debugging) and binary, |
748 |
language-specific serialisers (e.g. Storable). By default, unless TLS is |
749 |
used, the protocol is actually completely text-based. |
750 |
|
751 |
It has also been carefully designed to be implementable in other languages |
752 |
with a minimum of work while gracefully degrading functionality to make the |
753 |
protocol simple. |
754 |
|
755 |
=item * AEMP has more flexible monitoring options than Erlang. |
756 |
|
757 |
In Erlang, you can chose to receive I<all> exit signals as messages |
758 |
or I<none>, there is no in-between, so monitoring single processes is |
759 |
difficult to implement. Monitoring in AEMP is more flexible than in |
760 |
Erlang, as one can choose between automatic kill, exit message or callback |
761 |
on a per-process basis. |
762 |
|
763 |
=item * Erlang tries to hide remote/local connections, AEMP does not. |
764 |
|
765 |
Monitoring in Erlang is not an indicator of process death/crashes, in the |
766 |
same way as linking is (except linking is unreliable in Erlang). |
767 |
|
768 |
In AEMP, you don't "look up" registered port names or send to named ports |
769 |
that might or might not be persistent. Instead, you normally spawn a port |
770 |
on the remote node. The init function monitors you, and you monitor the |
771 |
remote port. Since both monitors are local to the node, they are much more |
772 |
reliable (no need for C<spawn_link>). |
773 |
|
774 |
This also saves round-trips and avoids sending messages to the wrong port |
775 |
(hard to do in Erlang). |
776 |
|
777 |
=back |
778 |
|
779 |
=head1 RATIONALE |
780 |
|
781 |
=over 4 |
782 |
|
783 |
=item Why strings for port and node IDs, why not objects? |
784 |
|
785 |
We considered "objects", but found that the actual number of methods |
786 |
that can be called are quite low. Since port and node IDs travel over |
787 |
the network frequently, the serialising/deserialising would add lots of |
788 |
overhead, as well as having to keep a proxy object everywhere. |
789 |
|
790 |
Strings can easily be printed, easily serialised etc. and need no special |
791 |
procedures to be "valid". |
792 |
|
793 |
And as a result, a miniport consists of a single closure stored in a |
794 |
global hash - it can't become much cheaper. |
795 |
|
796 |
=item Why favour JSON, why not a real serialising format such as Storable? |
797 |
|
798 |
In fact, any AnyEvent::MP node will happily accept Storable as framing |
799 |
format, but currently there is no way to make a node use Storable by |
800 |
default (although all nodes will accept it). |
801 |
|
802 |
The default framing protocol is JSON because a) JSON::XS is many times |
803 |
faster for small messages and b) most importantly, after years of |
804 |
experience we found that object serialisation is causing more problems |
805 |
than it solves: Just like function calls, objects simply do not travel |
806 |
easily over the network, mostly because they will always be a copy, so you |
807 |
always have to re-think your design. |
808 |
|
809 |
Keeping your messages simple, concentrating on data structures rather than |
810 |
objects, will keep your messages clean, tidy and efficient. |
811 |
|
812 |
=back |
813 |
|
814 |
=head1 SEE ALSO |
815 |
|
816 |
L<AnyEvent>. |
817 |
|
818 |
=head1 AUTHOR |
819 |
|
820 |
Marc Lehmann <schmorp@schmorp.de> |
821 |
http://home.schmorp.de/ |
822 |
|
823 |
=cut |
824 |
|
825 |
1 |
826 |
|