AnyEvent-MP/MP/Global.pm

=head1 NAME

AnyEvent::MP::Global - network backbone services

=head1 SYNOPSIS

   use AnyEvent::MP::Global;

=head1 DESCRIPTION

This module is usually run (or started on) seed nodes and provides a
variety of services to connected nodes, such as the distributed database.

The global nodes form a fully-meshed network, that is, all global nodes
currently maintain connections to all other global nodes.

Loading this module (e.g. as a service) transforms the local node into a
global node. There are no user-servicable parts inside.

For a limited time, this module also exports some AEMP 1.x compatibility
functions (C<grp_reg>, C<grp_get> and C<grp_mon>).

=cut

package AnyEvent::MP::Global;

use common::sense;
use Carp ();

use AnyEvent ();

use AnyEvent::MP;
use AnyEvent::MP::Kernel;

AE::log 7 => "starting global service.";

#############################################################################
# node protocol parts for global nodes

package AnyEvent::MP::Kernel;

# TODO: this is ugly (classical use vars vs. our),
# maybe this should go into MP::Kernel

our %NODE;
our $NODE;

our $GLOBAL;
our $MASTER;
our $MASTER_TIMER;

our %GLOBAL_SLAVE;

our %GLOBAL_DB; # global db
our %LOCAL_DBS; # local databases of other global nodes
our %LOCAL_DB;  # this node database

our $SRCNODE; # the origin node id
our %NODE_REQ;

# only in global code
our %GLOBAL_MON; # monitors {family}

# broadcasts a message to all other global nodes
sub g_broadcast {
   snd $_, @_
      for grep $_ ne $NODE && node_is_up $_, keys %{ $GLOBAL_DB{"'g"} }
}

# add/replace/del inside a family in the database
# @$del must not contain any key in %$set
sub g_upd {
   my ($node, $family, $set, $del) = @_;

   my $ldb = $LOCAL_DBS{$node}{$family} ||= {};
   my $gdb = $GLOBAL_DB       {$family} ||= {};

   # add/replace keys
   while (my ($k, $v) = each %$set) {
      $ldb->{$k} =
      $gdb->{$k} = $v;
   }

   my @del; # actual deletes

   # take care of deletes
   keydel:
   for my $k (@$del) {
      delete $ldb->{$k};
      delete $gdb->{$k};

      # check if some other node still has the key, then we don't delete, but change
      for (values %LOCAL_DBS) {
         if (exists $_->{$family}{$k}) {
            $set->{$k} = $gdb->{$k} = $_->{$family}{$k};

            next keydel;
         }
      }

      push @del, $k;
   }

   # family could be empty now
   delete $GLOBAL_DB{$family} unless %$gdb;
   delete $LOCAL_DBS{$node}{$family} unless %$ldb;

   g_broadcast g_upd => $family, $set, \@del
      if exists $GLOBAL_SLAVE{$node};

   # tell subscribers we have changed the family
   snd $_ => g_chg2 => $family, $set, \@del
      for keys %{ $GLOBAL_MON{$family} };
}

# set the whole (node-local) database - previous value must be empty
sub g_set($$) {
   my ($node, $db) = @_;

   while (my ($f, $k) = each %$db) {
      g_upd $node, $f, $k;
   }
}

# delete all keys from a database
sub g_clr($) {
   my ($node) = @_;

   my $db = $LOCAL_DBS{$node};

   while (my ($f, $k) = each %$db) {
      g_upd $node, $f, undef, [keys %$k];
   }

   delete $LOCAL_DBS{$node};
}

# gather node databases from slaves

# other node wants to make us the master
$NODE_REQ{g_slave} = sub {
   my ($db) = @_
      or return; # empty g_slave is used to start global service

   my $node = $SRCNODE;
   undef $GLOBAL_SLAVE{$node};
   g_set $node, $db;
};

# other node (global and slave) sends us their database
$NODE_REQ{g_set} = sub {
   &g_set ($SRCNODE, @_);
};

# other node (global and slave) sends us a family update
$NODE_REQ{g_upd} = sub {
   &g_upd ($SRCNODE, @_);
};

# slave node wants to know the listeners of a node
$NODE_REQ{g_find} = sub {
   my ($node) = @_;

   snd $SRCNODE, g_found => $node, $GLOBAL_DB{"'l"}{$node};
};

$NODE_REQ{g_db_family} = sub {
   my ($family, $id) = @_;
   snd $SRCNODE, g_reply => $id, $GLOBAL_DB{$family} || {};
};

$NODE_REQ{g_db_keys} = sub {
   my ($family, $id) = @_;
   snd $SRCNODE, g_reply => $id, [keys %{ $GLOBAL_DB{$family} } ];
};

$NODE_REQ{g_db_values} = sub {
   my ($family, $id) = @_;
   snd $SRCNODE, g_reply => $id, [values %{ $GLOBAL_DB{$family} } ];
};

# monitoring

sub g_disconnect($) {
   my ($node) = @_;

   g_clr $node;

   if (my $mon = delete $GLOBAL_SLAVE{$node}) {
      while (my ($f, $fv) = each %$mon) {
         delete $GLOBAL_MON{$f}{$_}
            for keys %$fv;

         delete $GLOBAL_MON{$f}
            unless %{ $GLOBAL_MON{$f} };
      }
   }
}

# g_mon0 family - stop monitoring
$NODE_REQ{g_mon0} = sub {
   delete $GLOBAL_MON{$_[0]}{$SRCNODE};
   delete $GLOBAL_MON{$_[0]} unless %{ $GLOBAL_MON{$_[0]} };

   delete $GLOBAL_SLAVE{$SRCNODE}{$_[0]};
};

# g_mon1 family key - start monitoring
$NODE_REQ{g_mon1} = sub {
   undef $GLOBAL_SLAVE{$SRCNODE}{$_[0]};
   undef $GLOBAL_MON{$_[0]}{$SRCNODE};

   snd $SRCNODE, g_chg1 => $_[0], $GLOBAL_DB{$_[0]};
};

#############################################################################
# switch to global mode

# maintain conenctions to all global nodes that we know of
db_mon "'g" => sub {
   keepalive_add $_ for @{ $_[1] };
   keepalive_del $_ for @{ $_[3] };
};

# delete data from other nodes on node-down
mon_nodes sub {
   g_disconnect $_[0] unless $_[1];
};

# tell everybody who connects that we are a global node
push @AnyEvent::MP::Transport::HOOK_GREET, sub {
   $_[0]{local_greeting}{global} = 1;
};

# connect from a global node
sub g_global_connect {
   my ($node) = @_;

   # we need to set this currently, as to avoid race conditions
   # because it takes a while until the other global node tells us it is global,
   # but we need to send updates even before that.

   undef $GLOBAL_DB       {"'g"}{$node};
   undef $LOCAL_DBS{$node}{"'g"}{$node};

   # global nodes send all local databases, merged,
   # as their local database to other global nodes
   my %db;

   for (values %LOCAL_DBS) {
      while (my ($f, $fv) = each %$_) {
         while (my ($k, $kv) = each %$fv) {
            $db{$f}{$k} = $kv;
         }
      }
   }

   snd $node => g_set => \%db;
}

# send our database to every global node that connects
push @AnyEvent::MP::Transport::HOOK_CONNECT, sub {
   return unless $_[0]{remote_greeting}{global};

   g_global_connect $_[0]{remote_node};
};

# tell other global nodes that we are global now
# TODO: there is probably a race when two conencted nodes beocme global at the same time
# very ugly.
for (values %NODE) {
   if ($_->{transport} && $_->{transport}{remote_greeting}{global}) {
      snd $_->{id} => "g_global";
      g_global_connect $_->{id};
   }
}

$NODE_REQ{g_global} = sub {
   g_disconnect $SRCNODE;

   my $node = $NODE{$SRCNODE};
   $node->{transport}{remote_greeting}{global} = 1;

   g_global_connect $SRCNODE;
};

# enable global mode
$GLOBAL = 1;

# global nodes are their own masters - this
# resends global requests and sets the local database.
master_set $NODE;

# now add us to the set of global nodes
db_set "'g" => $NODE => undef;

#############################################################################
# compatibility functions for aemp 1.0

package AnyEvent::MP::Global;

use base "Exporter";
our @EXPORT = qw(grp_reg grp_get grp_mon);

sub grp_reg($$) {
   &db_reg
}

sub grp_get($) {
   my @ports = keys %{ $AnyEvent::MP::Kernel::GLOBAL_DB{$_[0]} };

   @ports ? \@ports : undef
}

sub grp_mon($$) {
   my ($grp, $cb) = @_;

   db_mon $grp => sub {
      my ($ports, $add, $chg, $del) = @_;

      $cb->([keys %$ports], $add, $del);
   };
}

=head1 SEE ALSO

L<AnyEvent::MP>.

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

1

Revision:	1.67
Committed:	Sat Mar 24 01:00:28 2012 UTC (12 years, 2 months ago) by root
Branch:	MAIN
Changes since 1.66:	+4 -5 lines
Log Message:	* empty log message *
#	Content
1	=head1 NAME
2
3	AnyEvent::MP::Global - network backbone services
4
5	=head1 SYNOPSIS
6
7	use AnyEvent::MP::Global;
8
9	=head1 DESCRIPTION
10
11	This module is usually run (or started on) seed nodes and provides a
12	variety of services to connected nodes, such as the distributed database.
13
14	The global nodes form a fully-meshed network, that is, all global nodes
15	currently maintain connections to all other global nodes.
16
17	Loading this module (e.g. as a service) transforms the local node into a
18	global node. There are no user-servicable parts inside.
19
20	For a limited time, this module also exports some AEMP 1.x compatibility
21	functions (C<grp_reg>, C<grp_get> and C<grp_mon>).
22
23	=cut
24
25	package AnyEvent::MP::Global;
26
27	use common::sense;
28	use Carp ();
29
30	use AnyEvent ();
31
32	use AnyEvent::MP;
33	use AnyEvent::MP::Kernel;
34
35	AE::log 7 => "starting global service.";
36
37	#############################################################################
38	# node protocol parts for global nodes
39
40	package AnyEvent::MP::Kernel;
41
42	# TODO: this is ugly (classical use vars vs. our),
43	# maybe this should go into MP::Kernel
44
45	our %NODE;
46	our $NODE;
47
48	our $GLOBAL;
49	our $MASTER;
50	our $MASTER_TIMER;
51
52	our %GLOBAL_SLAVE;
53
54	our %GLOBAL_DB; # global db
55	our %LOCAL_DBS; # local databases of other global nodes
56	our %LOCAL_DB; # this node database
57
58	our $SRCNODE; # the origin node id
59	our %NODE_REQ;
60
61	# only in global code
62	our %GLOBAL_MON; # monitors {family}
63
64	# broadcasts a message to all other global nodes
65	sub g_broadcast {
66	snd $_, @_
67	for grep $_ ne $NODE && node_is_up $_, keys %{ $GLOBAL_DB{"'g"} }
68	}
69
70	# add/replace/del inside a family in the database
71	# @$del must not contain any key in %$set
72	sub g_upd {
73	my ($node, $family, $set, $del) = @_;
74
75	my $ldb = $LOCAL_DBS{$node}{$family} \|\|= {};
76	my $gdb = $GLOBAL_DB {$family} \|\|= {};
77
78	# add/replace keys
79	while (my ($k, $v) = each %$set) {
80	$ldb->{$k} =
81	$gdb->{$k} = $v;
82	}
83
84	my @del; # actual deletes
85
86	# take care of deletes
87	keydel:
88	for my $k (@$del) {
89	delete $ldb->{$k};
90	delete $gdb->{$k};
91
92	# check if some other node still has the key, then we don't delete, but change
93	for (values %LOCAL_DBS) {
94	if (exists $_->{$family}{$k}) {
95	$set->{$k} = $gdb->{$k} = $_->{$family}{$k};
96
97	next keydel;
98	}
99	}
100
101	push @del, $k;
102	}
103
104	# family could be empty now
105	delete $GLOBAL_DB{$family} unless %$gdb;
106	delete $LOCAL_DBS{$node}{$family} unless %$ldb;
107
108	g_broadcast g_upd => $family, $set, \@del
109	if exists $GLOBAL_SLAVE{$node};
110
111	# tell subscribers we have changed the family
112	snd $_ => g_chg2 => $family, $set, \@del
113	for keys %{ $GLOBAL_MON{$family} };
114	}
115
116	# set the whole (node-local) database - previous value must be empty
117	sub g_set($$) {
118	my ($node, $db) = @_;
119
120	while (my ($f, $k) = each %$db) {
121	g_upd $node, $f, $k;
122	}
123	}
124
125	# delete all keys from a database
126	sub g_clr($) {
127	my ($node) = @_;
128
129	my $db = $LOCAL_DBS{$node};
130
131	while (my ($f, $k) = each %$db) {
132	g_upd $node, $f, undef, [keys %$k];
133	}
134
135	delete $LOCAL_DBS{$node};
136	}
137
138	# gather node databases from slaves
139
140	# other node wants to make us the master
141	$NODE_REQ{g_slave} = sub {
142	my ($db) = @_
143	or return; # empty g_slave is used to start global service
144
145	my $node = $SRCNODE;
146	undef $GLOBAL_SLAVE{$node};
147	g_set $node, $db;
148	};
149
150	# other node (global and slave) sends us their database
151	$NODE_REQ{g_set} = sub {
152	&g_set ($SRCNODE, @_);
153	};
154
155	# other node (global and slave) sends us a family update
156	$NODE_REQ{g_upd} = sub {
157	&g_upd ($SRCNODE, @_);
158	};
159
160	# slave node wants to know the listeners of a node
161	$NODE_REQ{g_find} = sub {
162	my ($node) = @_;
163
164	snd $SRCNODE, g_found => $node, $GLOBAL_DB{"'l"}{$node};
165	};
166
167	$NODE_REQ{g_db_family} = sub {
168	my ($family, $id) = @_;
169	snd $SRCNODE, g_reply => $id, $GLOBAL_DB{$family} \|\| {};
170	};
171
172	$NODE_REQ{g_db_keys} = sub {
173	my ($family, $id) = @_;
174	snd $SRCNODE, g_reply => $id, [keys %{ $GLOBAL_DB{$family} } ];
175	};
176
177	$NODE_REQ{g_db_values} = sub {
178	my ($family, $id) = @_;
179	snd $SRCNODE, g_reply => $id, [values %{ $GLOBAL_DB{$family} } ];
180	};
181
182	# monitoring
183
184	sub g_disconnect($) {
185	my ($node) = @_;
186
187	g_clr $node;
188
189	if (my $mon = delete $GLOBAL_SLAVE{$node}) {
190	while (my ($f, $fv) = each %$mon) {
191	delete $GLOBAL_MON{$f}{$_}
192	for keys %$fv;
193
194	delete $GLOBAL_MON{$f}
195	unless %{ $GLOBAL_MON{$f} };
196	}
197	}
198	}
199
200	# g_mon0 family - stop monitoring
201	$NODE_REQ{g_mon0} = sub {
202	delete $GLOBAL_MON{$_[0]}{$SRCNODE};
203	delete $GLOBAL_MON{$_[0]} unless %{ $GLOBAL_MON{$_[0]} };
204
205	delete $GLOBAL_SLAVE{$SRCNODE}{$_[0]};
206	};
207
208	# g_mon1 family key - start monitoring
209	$NODE_REQ{g_mon1} = sub {
210	undef $GLOBAL_SLAVE{$SRCNODE}{$_[0]};
211	undef $GLOBAL_MON{$_[0]}{$SRCNODE};
212
213	snd $SRCNODE, g_chg1 => $_[0], $GLOBAL_DB{$_[0]};
214	};
215
216	#############################################################################
217	# switch to global mode
218
219	# maintain conenctions to all global nodes that we know of
220	db_mon "'g" => sub {
221	keepalive_add $_ for @{ $_[1] };
222	keepalive_del $_ for @{ $_[3] };
223	};
224
225	# delete data from other nodes on node-down
226	mon_nodes sub {
227	g_disconnect $_[0] unless $_[1];
228	};
229
230	# tell everybody who connects that we are a global node
231	push @AnyEvent::MP::Transport::HOOK_GREET, sub {
232	$_[0]{local_greeting}{global} = 1;
233	};
234
235	# connect from a global node
236	sub g_global_connect {
237	my ($node) = @_;
238
239	# we need to set this currently, as to avoid race conditions
240	# because it takes a while until the other global node tells us it is global,
241	# but we need to send updates even before that.
242
243	undef $GLOBAL_DB {"'g"}{$node};
244	undef $LOCAL_DBS{$node}{"'g"}{$node};
245
246	# global nodes send all local databases, merged,
247	# as their local database to other global nodes
248	my %db;
249
250	for (values %LOCAL_DBS) {
251	while (my ($f, $fv) = each %$_) {
252	while (my ($k, $kv) = each %$fv) {
253	$db{$f}{$k} = $kv;
254	}
255	}
256	}
257
258	snd $node => g_set => \%db;
259	}
260
261	# send our database to every global node that connects
262	push @AnyEvent::MP::Transport::HOOK_CONNECT, sub {
263	return unless $_[0]{remote_greeting}{global};
264
265	g_global_connect $_[0]{remote_node};
266	};
267
268	# tell other global nodes that we are global now
269	# TODO: there is probably a race when two conencted nodes beocme global at the same time
270	# very ugly.
271	for (values %NODE) {
272	if ($_->{transport} && $_->{transport}{remote_greeting}{global}) {
273	snd $_->{id} => "g_global";
274	g_global_connect $_->{id};
275	}
276	}
277
278	$NODE_REQ{g_global} = sub {
279	g_disconnect $SRCNODE;
280
281	my $node = $NODE{$SRCNODE};
282	$node->{transport}{remote_greeting}{global} = 1;
283
284	g_global_connect $SRCNODE;
285	};
286
287	# enable global mode
288	$GLOBAL = 1;
289
290	# global nodes are their own masters - this
291	# resends global requests and sets the local database.
292	master_set $NODE;
293
294	# now add us to the set of global nodes
295	db_set "'g" => $NODE => undef;
296
297	#############################################################################
298	# compatibility functions for aemp 1.0
299
300	package AnyEvent::MP::Global;
301
302	use base "Exporter";
303	our @EXPORT = qw(grp_reg grp_get grp_mon);
304
305	sub grp_reg($$) {
306	&db_reg
307	}
308
309	sub grp_get($) {
310	my @ports = keys %{ $AnyEvent::MP::Kernel::GLOBAL_DB{$_[0]} };
311
312	@ports ? \@ports : undef
313	}
314
315	sub grp_mon($$) {
316	my ($grp, $cb) = @_;
317
318	db_mon $grp => sub {
319	my ($ports, $add, $chg, $del) = @_;
320
321	$cb->([keys %$ports], $add, $del);
322	};
323	}
324
325	=head1 SEE ALSO
326
327	L<AnyEvent::MP>.
328
329	=head1 AUTHOR
330
331	Marc Lehmann <schmorp@schmorp.de>
332	http://home.schmorp.de/
333
334	=cut
335
336	1
337