AnyEvent-MP/MP/Node.pm

=head1 NAME

AnyEvent::MP::Node - represent a node

=head1 SYNOPSIS

   use AnyEvent::MP::Node;

=head1 DESCRIPTION

This is an internal utility module, horrible to look at, so don't.

=cut

package AnyEvent::MP::Node;

use common::sense;

use AE ();
use AnyEvent::Util ();
use AnyEvent::Socket ();

use AnyEvent::MP::Transport ();

sub new {
   my ($self, $id) = @_;

   $self = bless { id => $id }, $self;

   $self->init;
   $self->transport_reset;

   $self
}

sub init {
   #
}

sub send {
   &{ shift->{send} }
}

# nodes reachable via the network
package AnyEvent::MP::Node::Remote;

use base "AnyEvent::MP::Node";

# called at init time, mostly sets {send}
sub transport_reset {
   my ($self) = @_;

   delete $self->{transport};

   Scalar::Util::weaken $self;

   $self->{send} = sub {
      push @{$self->{queue}}, shift;
      $self->connect;
   };
}

# called each time we fail to establish a connection,
# or the existing connection failed
sub transport_error {
   my ($self, @reason) = @_;

   my $no_transport = !$self->{transport};

   delete $self->{connect_w};
   delete $self->{connect_to};

   delete $self->{queue};
   $self->transport_reset;

   if (my $mon = delete $self->{lmon}) {
      $_->(@reason) for map @$_, values %$mon;
   }

   AnyEvent::MP::Kernel::_inject_nodeevent ($self, 0, @reason)
      unless $no_transport;

   # if we are here and are idle, we nuke ourselves
   delete $AnyEvent::MP::Kernel::NODE{$self->{id}}
      unless $self->{transport} || $self->{connect_to};
}

# called after handshake was successful
sub transport_connect {
   my ($self, $transport) = @_;

   delete $self->{trial};

   $self->transport_error (transport_error => $self->{id}, "switched connections")
      if $self->{transport};

   delete $self->{connect_addr};
   delete $self->{connect_w};
   delete $self->{connect_to};

   $self->{transport} = $transport;

   my $transport_send = $transport->{send};

   AnyEvent::MP::Kernel::_inject_nodeevent ($self, 1);

   $self->{send} = $transport_send;

   $transport_send->($_)
      for @{ delete $self->{queue} || [] };
}

sub connect {
   my ($self) = @_;

   return if $self->{transport};

   Scalar::Util::weaken $self;

   my $monitor = $AnyEvent::MP::Kernel::CONFIG->{monitor_timeout};

   $self->{connect_to} ||= AE::timer $monitor, 0, sub {
      $self->transport_error (transport_error => $self->{id}, "unable to connect");
   };

   # maybe @$addresses?
   my @addresses = @{
      $AnyEvent::MP::Kernel::GLOBAL_ADDR->{$self->{id}}
      || $AnyEvent::MP::Kernel::NODE_ADDR->{$self->{id}}
   };

   unless (@addresses) {
      # on global nodes, all betsa re off now - we either know the node, or we don't
      unless ($AnyEvent::MP::Kernel::GLOBAL) {
         $self->{connect_w} = AnyEvent::MP::Kernel::global_req (
            global_find => $self->{id},
            sub {
               return unless $self; # just to be sure
               return unless @{ $_[0] };

               local $AnyEvent::MP::Kernel::GLOBAL_ADDR->{$self->{id}} = $_[0]; #d# UGLY
               $self->connect;
            }
         );
      }

      return;
   }

   $self->{connect_addr} = \@addresses; # a bit weird, but efficient

   $AnyEvent::MP::Kernel::WARN->(9, "connecting to $self->{id} with [@addresses]");

   my $interval = $AnyEvent::MP::Kernel::CONFIG->{connect_interval};

   $interval = ($monitor - $interval) / @addresses
      if ($monitor - $interval) / @addresses < $interval;

   $interval = 0.4 if $interval < 0.4;

   my @endpoints;

   $self->{connect_w} = AE::timer 0.050 * rand, $interval * (0.9 + 0.1 * rand), sub {
      @endpoints = @addresses
         unless @endpoints;

      my $endpoint = shift @endpoints;

      $AnyEvent::MP::Kernel::WARN->(9, "connecting to $self->{id} at $endpoint");

      $self->{trial}{$endpoint} ||= do {
         my ($host, $port) = AnyEvent::Socket::parse_hostport $endpoint
            or return $AnyEvent::MP::Kernel::WARN->(1, "$self->{id}: not a resolved node reference.");

         AnyEvent::MP::Transport::mp_connect
            $host, $port,
            sub { delete $self->{trial}{$endpoint} },
      };
   };
}

sub kill {
   my ($self, $port, @reason) = @_;

   $self->{send} (["", kil => $port, @reason]);
}

sub monitor {
   my ($self, $portid, $cb) = @_;

   my $list = $self->{lmon}{$portid} ||= [];

   $self->send (["", mon1 => $portid])
      unless @$list || !length $portid;

   push @$list, $cb;
}

sub unmonitor {
   my ($self, $portid, $cb) = @_;

   my $list = $self->{lmon}{$portid}
      or return;

   @$list = grep $_ != $cb, @$list;

   unless (@$list) {
      $self->send (["", mon0 => $portid]);
      delete $self->{monitor}{$portid};
   }
}

package AnyEvent::MP::Node::Self;

use base "AnyEvent::MP::Node";

sub connect {
   # we are trivially connected
}

# delay every so often to avoid recursion, also used to delay after spawn
our $DELAY = -50;
our @DELAY;
our $DELAY_W;

sub _send_delayed {
   local $AnyEvent::MP::Kernel::SRCNODE = $AnyEvent::MP::Kernel::NODE{""};
   (shift @DELAY)->()
      while @DELAY;
   undef $DELAY_W;
   $DELAY = -50;
}

sub transport_reset {
   my ($self) = @_;

   Scalar::Util::weaken $self;

   $self->{send} = sub {
      if ($DELAY++ >= 0) {
         my $msg = $_[0];
         push @DELAY, sub { AnyEvent::MP::Kernel::_inject (@$msg) };
         $DELAY_W ||= AE::timer 0, 0, \&_send_delayed;
         return;
      }

      local $AnyEvent::MP::Kernel::SRCNODE = $self;
      AnyEvent::MP::Kernel::_inject (@{ $_[0] });
   };
}

sub transport_connect {
   my ($self, $tp) = @_;

   $AnyEvent::MP::Kernel::WARN->(9, "I refuse to talk to myself ($tp->{peerhost}:$tp->{peerport})");
}

sub kill {
   my (undef, @args) = @_;

   # we _always_ delay kil's, to avoid calling mon callbacks
   # from anything but the event loop context.
   $DELAY = 1;
   push @DELAY, sub { AnyEvent::MP::Kernel::_kill (@args) };
   $DELAY_W ||= AE::timer 0, 0, \&_send_delayed;
}

sub monitor {
   # maybe always delay, too?
   if ($DELAY_W) {
      my @args = @_;
      push @DELAY, sub { AnyEvent::MP::Kernel::_monitor (@args) };
      return;
   }
   &AnyEvent::MP::Kernel::_monitor;
}

sub unmonitor {
   # no need to always delay
   if ($DELAY_W) {
      my @args = @_;
      push @DELAY, sub { AnyEvent::MP::Kernel::_unmonitor (@args) };
      return;
   }

   &AnyEvent::MP::Kernel::_unmonitor;
}

=head1 SEE ALSO

L<AnyEvent::MP>.

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

1

Revision:	1.53
Committed:	Tue Feb 28 18:37:24 2012 UTC (12 years, 3 months ago) by root
Branch:	MAIN
Changes since 1.52:	+23 -12 lines
Log Message:	* empty log message *
#	Content
1	=head1 NAME
2
3	AnyEvent::MP::Node - represent a node
4
5	=head1 SYNOPSIS
6
7	use AnyEvent::MP::Node;
8
9	=head1 DESCRIPTION
10
11	This is an internal utility module, horrible to look at, so don't.
12
13	=cut
14
15	package AnyEvent::MP::Node;
16
17	use common::sense;
18
19	use AE ();
20	use AnyEvent::Util ();
21	use AnyEvent::Socket ();
22
23	use AnyEvent::MP::Transport ();
24
25	sub new {
26	my ($self, $id) = @_;
27
28	$self = bless { id => $id }, $self;
29
30	$self->init;
31	$self->transport_reset;
32
33	$self
34	}
35
36	sub init {
37	#
38	}
39
40	sub send {
41	&{ shift->{send} }
42	}
43
44	# nodes reachable via the network
45	package AnyEvent::MP::Node::Remote;
46
47	use base "AnyEvent::MP::Node";
48
49	# called at init time, mostly sets {send}
50	sub transport_reset {
51	my ($self) = @_;
52
53	delete $self->{transport};
54
55	Scalar::Util::weaken $self;
56
57	$self->{send} = sub {
58	push @{$self->{queue}}, shift;
59	$self->connect;
60	};
61	}
62
63	# called each time we fail to establish a connection,
64	# or the existing connection failed
65	sub transport_error {
66	my ($self, @reason) = @_;
67
68	my $no_transport = !$self->{transport};
69
70	delete $self->{connect_w};
71	delete $self->{connect_to};
72
73	delete $self->{queue};
74	$self->transport_reset;
75
76	if (my $mon = delete $self->{lmon}) {
77	$_->(@reason) for map @$_, values %$mon;
78	}
79
80	AnyEvent::MP::Kernel::_inject_nodeevent ($self, 0, @reason)
81	unless $no_transport;
82
83	# if we are here and are idle, we nuke ourselves
84	delete $AnyEvent::MP::Kernel::NODE{$self->{id}}
85	unless $self->{transport} \|\| $self->{connect_to};
86	}
87
88	# called after handshake was successful
89	sub transport_connect {
90	my ($self, $transport) = @_;
91
92	delete $self->{trial};
93
94	$self->transport_error (transport_error => $self->{id}, "switched connections")
95	if $self->{transport};
96
97	delete $self->{connect_addr};
98	delete $self->{connect_w};
99	delete $self->{connect_to};
100
101	$self->{transport} = $transport;
102
103	my $transport_send = $transport->{send};
104
105	AnyEvent::MP::Kernel::_inject_nodeevent ($self, 1);
106
107	$self->{send} = $transport_send;
108
109	$transport_send->($_)
110	for @{ delete $self->{queue} \|\| [] };
111	}
112
113	sub connect {
114	my ($self) = @_;
115
116	return if $self->{transport};
117
118	Scalar::Util::weaken $self;
119
120	my $monitor = $AnyEvent::MP::Kernel::CONFIG->{monitor_timeout};
121
122	$self->{connect_to} \|\|= AE::timer $monitor, 0, sub {
123	$self->transport_error (transport_error => $self->{id}, "unable to connect");
124	};
125
126	# maybe @$addresses?
127	my @addresses = @{
128	$AnyEvent::MP::Kernel::GLOBAL_ADDR->{$self->{id}}
129	\|\| $AnyEvent::MP::Kernel::NODE_ADDR->{$self->{id}}
130	};
131
132	unless (@addresses) {
133	# on global nodes, all betsa re off now - we either know the node, or we don't
134	unless ($AnyEvent::MP::Kernel::GLOBAL) {
135	$self->{connect_w} = AnyEvent::MP::Kernel::global_req (
136	global_find => $self->{id},
137	sub {
138	return unless $self; # just to be sure
139	return unless @{ $_[0] };
140
141	local $AnyEvent::MP::Kernel::GLOBAL_ADDR->{$self->{id}} = $_[0]; #d# UGLY
142	$self->connect;
143	}
144	);
145	}
146
147	return;
148	}
149
150	$self->{connect_addr} = \@addresses; # a bit weird, but efficient
151
152	$AnyEvent::MP::Kernel::WARN->(9, "connecting to $self->{id} with [@addresses]");
153
154	my $interval = $AnyEvent::MP::Kernel::CONFIG->{connect_interval};
155
156	$interval = ($monitor - $interval) / @addresses
157	if ($monitor - $interval) / @addresses < $interval;
158
159	$interval = 0.4 if $interval < 0.4;
160
161	my @endpoints;
162
163	$self->{connect_w} = AE::timer 0.050 * rand, $interval * (0.9 + 0.1 * rand), sub {
164	@endpoints = @addresses
165	unless @endpoints;
166
167	my $endpoint = shift @endpoints;
168
169	$AnyEvent::MP::Kernel::WARN->(9, "connecting to $self->{id} at $endpoint");
170
171	$self->{trial}{$endpoint} \|\|= do {
172	my ($host, $port) = AnyEvent::Socket::parse_hostport $endpoint
173	or return $AnyEvent::MP::Kernel::WARN->(1, "$self->{id}: not a resolved node reference.");
174
175	AnyEvent::MP::Transport::mp_connect
176	$host, $port,
177	sub { delete $self->{trial}{$endpoint} },
178	};
179	};
180	}
181
182	sub kill {
183	my ($self, $port, @reason) = @_;
184
185	$self->{send} (["", kil => $port, @reason]);
186	}
187
188	sub monitor {
189	my ($self, $portid, $cb) = @_;
190
191	my $list = $self->{lmon}{$portid} \|\|= [];
192
193	$self->send (["", mon1 => $portid])
194	unless @$list \|\| !length $portid;
195
196	push @$list, $cb;
197	}
198
199	sub unmonitor {
200	my ($self, $portid, $cb) = @_;
201
202	my $list = $self->{lmon}{$portid}
203	or return;
204
205	@$list = grep $_ != $cb, @$list;
206
207	unless (@$list) {
208	$self->send (["", mon0 => $portid]);
209	delete $self->{monitor}{$portid};
210	}
211	}
212
213	package AnyEvent::MP::Node::Self;
214
215	use base "AnyEvent::MP::Node";
216
217	sub connect {
218	# we are trivially connected
219	}
220
221	# delay every so often to avoid recursion, also used to delay after spawn
222	our $DELAY = -50;
223	our @DELAY;
224	our $DELAY_W;
225
226	sub _send_delayed {
227	local $AnyEvent::MP::Kernel::SRCNODE = $AnyEvent::MP::Kernel::NODE{""};
228	(shift @DELAY)->()
229	while @DELAY;
230	undef $DELAY_W;
231	$DELAY = -50;
232	}
233
234	sub transport_reset {
235	my ($self) = @_;
236
237	Scalar::Util::weaken $self;
238
239	$self->{send} = sub {
240	if ($DELAY++ >= 0) {
241	my $msg = $_[0];
242	push @DELAY, sub { AnyEvent::MP::Kernel::_inject (@$msg) };
243	$DELAY_W \|\|= AE::timer 0, 0, \&_send_delayed;
244	return;
245	}
246
247	local $AnyEvent::MP::Kernel::SRCNODE = $self;
248	AnyEvent::MP::Kernel::_inject (@{ $_[0] });
249	};
250	}
251
252	sub transport_connect {
253	my ($self, $tp) = @_;
254
255	$AnyEvent::MP::Kernel::WARN->(9, "I refuse to talk to myself ($tp->{peerhost}:$tp->{peerport})");
256	}
257
258	sub kill {
259	my (undef, @args) = @_;
260
261	# we _always_ delay kil's, to avoid calling mon callbacks
262	# from anything but the event loop context.
263	$DELAY = 1;
264	push @DELAY, sub { AnyEvent::MP::Kernel::_kill (@args) };
265	$DELAY_W \|\|= AE::timer 0, 0, \&_send_delayed;
266	}
267
268	sub monitor {
269	# maybe always delay, too?
270	if ($DELAY_W) {
271	my @args = @_;
272	push @DELAY, sub { AnyEvent::MP::Kernel::_monitor (@args) };
273	return;
274	}
275	&AnyEvent::MP::Kernel::_monitor;
276	}
277
278	sub unmonitor {
279	# no need to always delay
280	if ($DELAY_W) {
281	my @args = @_;
282	push @DELAY, sub { AnyEvent::MP::Kernel::_unmonitor (@args) };
283	return;
284	}
285
286	&AnyEvent::MP::Kernel::_unmonitor;
287	}
288
289	=head1 SEE ALSO
290
291	L<AnyEvent::MP>.
292
293	=head1 AUTHOR
294
295	Marc Lehmann <schmorp@schmorp.de>
296	http://home.schmorp.de/
297
298	=cut
299
300	1
301