AnyEvent-MP/MP/Node.pm

=head1 NAME

AnyEvent::MP::Node - represent a node

=head1 SYNOPSIS

   use AnyEvent::MP::Node;

=head1 DESCRIPTION

This is an internal utility module, horrible to look at, so don't.

=cut

package AnyEvent::MP::Node;

use common::sense;

use AE ();
use AnyEvent::Util ();
use AnyEvent::Socket ();

use AnyEvent::MP::Transport ();

sub new {
   my ($self, $id) = @_;

   $self = bless { id => $id }, $self;

   $self->init;
   $self->transport_reset;

   $self
}

sub init {
   #
}

sub send {
   &{ shift->{send} }
}

# nodes reachable via the network
package AnyEvent::MP::Node::Remote;

use base "AnyEvent::MP::Node";

# called at init time, mostly sets {send}
sub transport_reset {
   my ($self) = @_;

   delete $self->{transport};

   Scalar::Util::weaken $self;

   $self->{send} = sub {
      push @{$self->{queue}}, shift;
      $self->connect;
   };
}

# called each time we fail to establish a connection,
# or the existing connection failed
sub transport_error {
   my ($self, @reason) = @_;

   my $no_transport = !$self->{transport};

   delete $self->{connect_w};
   delete $self->{connect_to};

   delete $self->{queue};
   $self->transport_reset;

   if (my $mon = delete $self->{lmon}) {
      $_->(@reason) for map @$_, values %$mon;
   }

   AnyEvent::MP::Kernel::_inject_nodeevent ($self, 0, @reason)
      unless $no_transport;

   # if we are here and are idle, we nuke ourselves
   delete $AnyEvent::MP::Kernel::NODE{$self->{id}}
      unless $self->{transport} || $self->{connect_to};
}

# called after handshake was successful
sub transport_connect {
   my ($self, $transport) = @_;

   delete $self->{trial};

   $self->transport_error (transport_error => $self->{id}, "switched connections")
      if $self->{transport};

   delete $self->{connect_addr};
   delete $self->{connect_w};
   delete $self->{connect_to};

   $self->{transport} = $transport;

   my $transport_send = $transport->{send};

   AnyEvent::MP::Kernel::_inject_nodeevent ($self, 1);

   $self->{send} = $transport_send;

   $transport_send->($_)
      for @{ delete $self->{queue} || [] };
}

sub connect {
   my ($self) = @_;

   return if $self->{transport};
   return if $self->{connect_w};

   Scalar::Util::weaken $self;

   my $monitor = $AnyEvent::MP::Kernel::CONFIG->{monitor_timeout};

   $self->{connect_to} ||= AE::timer $monitor, 0, sub {
      $self->transport_error (transport_error => $self->{id}, "unable to connect");
   };

   # maybe @$addresses?
   my @addresses = @{
      $AnyEvent::MP::Kernel::GLOBAL_ADDR->{$self->{id}}
      || $AnyEvent::MP::Kernel::NODE_ADDR->{$self->{id}}
   };

   unless (@addresses) {
      # on global nodes, all bets are off now - we either know the node, or we don't
      unless ($AnyEvent::MP::Kernel::GLOBAL) {
         $self->{connect_w} = AnyEvent::MP::Kernel::global_req (
            g_find => $self->{id},
            sub {
               return unless $self; # just to be sure
               return unless @{ $_[0] };

               local $AnyEvent::MP::Kernel::GLOBAL_ADDR->{$self->{id}} = $_[0]; #d# UGLY
               delete $self->{connect_w};
               $self->connect;
            }
         );
      }

      return;
   }

   $self->{connect_addr} = \@addresses; # a bit weird, but efficient

   $AnyEvent::MP::Kernel::WARN->(9, "connecting to $self->{id} with [@addresses]");

   my $interval = $AnyEvent::MP::Kernel::CONFIG->{connect_interval};

   $interval = ($monitor - $interval) / @addresses
      if ($monitor - $interval) / @addresses < $interval;

   $interval = 0.4 if $interval < 0.4;

   my @endpoints;

   $self->{connect_w} = AE::timer 0, $interval * (0.9 + 0.1 * rand), sub {
      @endpoints = @addresses
         unless @endpoints;

      my $endpoint = shift @endpoints;

      $AnyEvent::MP::Kernel::WARN->(9, "connecting to $self->{id} at $endpoint");

      $self->{trial}{$endpoint} ||= do {
         my ($host, $port) = AnyEvent::Socket::parse_hostport $endpoint
            or return $AnyEvent::MP::Kernel::WARN->(1, "$self->{id}: not a resolved node reference.");

         AnyEvent::MP::Transport::mp_connect
            $host, $port,
            sub { delete $self->{trial}{$endpoint} },
      };
   };
}

sub kill {
   my ($self, $port, @reason) = @_;

   $self->{send} (["", kil => $port, @reason]);
}

sub monitor {
   my ($self, $portid, $cb) = @_;

   my $list = $self->{lmon}{$portid} ||= [];

   $self->send (["", mon1 => $portid])
      unless @$list || !length $portid;

   push @$list, $cb;
}

sub unmonitor {
   my ($self, $portid, $cb) = @_;

   my $list = $self->{lmon}{$portid}
      or return;

   @$list = grep $_ != $cb, @$list;

   unless (@$list) {
      $self->send (["", mon0 => $portid]);
      delete $self->{monitor}{$portid};
   }
}

package AnyEvent::MP::Node::Self;

use base "AnyEvent::MP::Node";

sub connect {
   # we are trivially connected
}

# delay every so often to avoid recursion, also used to delay after spawn
our $DELAY = -50;
our @DELAY;
our $DELAY_W;

sub _send_delayed {
   local $AnyEvent::MP::Kernel::SRCNODE = $AnyEvent::MP::Kernel::NODE{""};
   (shift @DELAY)->()
      while @DELAY;
   undef $DELAY_W;
   $DELAY = -50;
}

sub transport_reset {
   my ($self) = @_;

   Scalar::Util::weaken $self;

   $self->{send} = sub {
      if ($DELAY++ >= 0) {
         my $msg = $_[0];
         push @DELAY, sub { AnyEvent::MP::Kernel::_inject (@$msg) };
         $DELAY_W ||= AE::timer 0, 0, \&_send_delayed;
         return;
      }

      local $AnyEvent::MP::Kernel::SRCNODE = $self;
      AnyEvent::MP::Kernel::_inject (@{ $_[0] });
   };
}

sub transport_connect {
   my ($self, $tp) = @_;

   $AnyEvent::MP::Kernel::WARN->(9, "I refuse to talk to myself ($tp->{peerhost}:$tp->{peerport})");
}

sub kill {
   my (undef, @args) = @_;

   # we _always_ delay kil's, to avoid calling mon callbacks
   # from anything but the event loop context.
   $DELAY = 1;
   push @DELAY, sub { AnyEvent::MP::Kernel::_kill (@args) };
   $DELAY_W ||= AE::timer 0, 0, \&_send_delayed;
}

sub monitor {
   # maybe always delay, too?
   if ($DELAY_W) {
      my @args = @_;
      push @DELAY, sub { AnyEvent::MP::Kernel::_monitor (@args) };
      return;
   }
   &AnyEvent::MP::Kernel::_monitor;
}

sub unmonitor {
   # no need to always delay
   if ($DELAY_W) {
      my @args = @_;
      push @DELAY, sub { AnyEvent::MP::Kernel::_unmonitor (@args) };
      return;
   }

   &AnyEvent::MP::Kernel::_unmonitor;
}

=head1 SEE ALSO

L<AnyEvent::MP>.

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

1

Revision:	1.55
Committed:	Wed Feb 29 19:23:44 2012 UTC (12 years, 3 months ago) by root
Branch:	MAIN
Changes since 1.54:	+4 -2 lines
Log Message:	* empty log message *
#	Content
1	=head1 NAME
2
3	AnyEvent::MP::Node - represent a node
4
5	=head1 SYNOPSIS
6
7	use AnyEvent::MP::Node;
8
9	=head1 DESCRIPTION
10
11	This is an internal utility module, horrible to look at, so don't.
12
13	=cut
14
15	package AnyEvent::MP::Node;
16
17	use common::sense;
18
19	use AE ();
20	use AnyEvent::Util ();
21	use AnyEvent::Socket ();
22
23	use AnyEvent::MP::Transport ();
24
25	sub new {
26	my ($self, $id) = @_;
27
28	$self = bless { id => $id }, $self;
29
30	$self->init;
31	$self->transport_reset;
32
33	$self
34	}
35
36	sub init {
37	#
38	}
39
40	sub send {
41	&{ shift->{send} }
42	}
43
44	# nodes reachable via the network
45	package AnyEvent::MP::Node::Remote;
46
47	use base "AnyEvent::MP::Node";
48
49	# called at init time, mostly sets {send}
50	sub transport_reset {
51	my ($self) = @_;
52
53	delete $self->{transport};
54
55	Scalar::Util::weaken $self;
56
57	$self->{send} = sub {
58	push @{$self->{queue}}, shift;
59	$self->connect;
60	};
61	}
62
63	# called each time we fail to establish a connection,
64	# or the existing connection failed
65	sub transport_error {
66	my ($self, @reason) = @_;
67
68	my $no_transport = !$self->{transport};
69
70	delete $self->{connect_w};
71	delete $self->{connect_to};
72
73	delete $self->{queue};
74	$self->transport_reset;
75
76	if (my $mon = delete $self->{lmon}) {
77	$_->(@reason) for map @$_, values %$mon;
78	}
79
80	AnyEvent::MP::Kernel::_inject_nodeevent ($self, 0, @reason)
81	unless $no_transport;
82
83	# if we are here and are idle, we nuke ourselves
84	delete $AnyEvent::MP::Kernel::NODE{$self->{id}}
85	unless $self->{transport} \|\| $self->{connect_to};
86	}
87
88	# called after handshake was successful
89	sub transport_connect {
90	my ($self, $transport) = @_;
91
92	delete $self->{trial};
93
94	$self->transport_error (transport_error => $self->{id}, "switched connections")
95	if $self->{transport};
96
97	delete $self->{connect_addr};
98	delete $self->{connect_w};
99	delete $self->{connect_to};
100
101	$self->{transport} = $transport;
102
103	my $transport_send = $transport->{send};
104
105	AnyEvent::MP::Kernel::_inject_nodeevent ($self, 1);
106
107	$self->{send} = $transport_send;
108
109	$transport_send->($_)
110	for @{ delete $self->{queue} \|\| [] };
111	}
112
113	sub connect {
114	my ($self) = @_;
115
116	return if $self->{transport};
117	return if $self->{connect_w};
118
119	Scalar::Util::weaken $self;
120
121	my $monitor = $AnyEvent::MP::Kernel::CONFIG->{monitor_timeout};
122
123	$self->{connect_to} \|\|= AE::timer $monitor, 0, sub {
124	$self->transport_error (transport_error => $self->{id}, "unable to connect");
125	};
126
127	# maybe @$addresses?
128	my @addresses = @{
129	$AnyEvent::MP::Kernel::GLOBAL_ADDR->{$self->{id}}
130	\|\| $AnyEvent::MP::Kernel::NODE_ADDR->{$self->{id}}
131	};
132
133	unless (@addresses) {
134	# on global nodes, all bets are off now - we either know the node, or we don't
135	unless ($AnyEvent::MP::Kernel::GLOBAL) {
136	$self->{connect_w} = AnyEvent::MP::Kernel::global_req (
137	g_find => $self->{id},
138	sub {
139	return unless $self; # just to be sure
140	return unless @{ $_[0] };
141
142	local $AnyEvent::MP::Kernel::GLOBAL_ADDR->{$self->{id}} = $_[0]; #d# UGLY
143	delete $self->{connect_w};
144	$self->connect;
145	}
146	);
147	}
148
149	return;
150	}
151
152	$self->{connect_addr} = \@addresses; # a bit weird, but efficient
153
154	$AnyEvent::MP::Kernel::WARN->(9, "connecting to $self->{id} with [@addresses]");
155
156	my $interval = $AnyEvent::MP::Kernel::CONFIG->{connect_interval};
157
158	$interval = ($monitor - $interval) / @addresses
159	if ($monitor - $interval) / @addresses < $interval;
160
161	$interval = 0.4 if $interval < 0.4;
162
163	my @endpoints;
164
165	$self->{connect_w} = AE::timer 0, $interval * (0.9 + 0.1 * rand), sub {
166	@endpoints = @addresses
167	unless @endpoints;
168
169	my $endpoint = shift @endpoints;
170
171	$AnyEvent::MP::Kernel::WARN->(9, "connecting to $self->{id} at $endpoint");
172
173	$self->{trial}{$endpoint} \|\|= do {
174	my ($host, $port) = AnyEvent::Socket::parse_hostport $endpoint
175	or return $AnyEvent::MP::Kernel::WARN->(1, "$self->{id}: not a resolved node reference.");
176
177	AnyEvent::MP::Transport::mp_connect
178	$host, $port,
179	sub { delete $self->{trial}{$endpoint} },
180	};
181	};
182	}
183
184	sub kill {
185	my ($self, $port, @reason) = @_;
186
187	$self->{send} (["", kil => $port, @reason]);
188	}
189
190	sub monitor {
191	my ($self, $portid, $cb) = @_;
192
193	my $list = $self->{lmon}{$portid} \|\|= [];
194
195	$self->send (["", mon1 => $portid])
196	unless @$list \|\| !length $portid;
197
198	push @$list, $cb;
199	}
200
201	sub unmonitor {
202	my ($self, $portid, $cb) = @_;
203
204	my $list = $self->{lmon}{$portid}
205	or return;
206
207	@$list = grep $_ != $cb, @$list;
208
209	unless (@$list) {
210	$self->send (["", mon0 => $portid]);
211	delete $self->{monitor}{$portid};
212	}
213	}
214
215	package AnyEvent::MP::Node::Self;
216
217	use base "AnyEvent::MP::Node";
218
219	sub connect {
220	# we are trivially connected
221	}
222
223	# delay every so often to avoid recursion, also used to delay after spawn
224	our $DELAY = -50;
225	our @DELAY;
226	our $DELAY_W;
227
228	sub _send_delayed {
229	local $AnyEvent::MP::Kernel::SRCNODE = $AnyEvent::MP::Kernel::NODE{""};
230	(shift @DELAY)->()
231	while @DELAY;
232	undef $DELAY_W;
233	$DELAY = -50;
234	}
235
236	sub transport_reset {
237	my ($self) = @_;
238
239	Scalar::Util::weaken $self;
240
241	$self->{send} = sub {
242	if ($DELAY++ >= 0) {
243	my $msg = $_[0];
244	push @DELAY, sub { AnyEvent::MP::Kernel::_inject (@$msg) };
245	$DELAY_W \|\|= AE::timer 0, 0, \&_send_delayed;
246	return;
247	}
248
249	local $AnyEvent::MP::Kernel::SRCNODE = $self;
250	AnyEvent::MP::Kernel::_inject (@{ $_[0] });
251	};
252	}
253
254	sub transport_connect {
255	my ($self, $tp) = @_;
256
257	$AnyEvent::MP::Kernel::WARN->(9, "I refuse to talk to myself ($tp->{peerhost}:$tp->{peerport})");
258	}
259
260	sub kill {
261	my (undef, @args) = @_;
262
263	# we _always_ delay kil's, to avoid calling mon callbacks
264	# from anything but the event loop context.
265	$DELAY = 1;
266	push @DELAY, sub { AnyEvent::MP::Kernel::_kill (@args) };
267	$DELAY_W \|\|= AE::timer 0, 0, \&_send_delayed;
268	}
269
270	sub monitor {
271	# maybe always delay, too?
272	if ($DELAY_W) {
273	my @args = @_;
274	push @DELAY, sub { AnyEvent::MP::Kernel::_monitor (@args) };
275	return;
276	}
277	&AnyEvent::MP::Kernel::_monitor;
278	}
279
280	sub unmonitor {
281	# no need to always delay
282	if ($DELAY_W) {
283	my @args = @_;
284	push @DELAY, sub { AnyEvent::MP::Kernel::_unmonitor (@args) };
285	return;
286	}
287
288	&AnyEvent::MP::Kernel::_unmonitor;
289	}
290
291	=head1 SEE ALSO
292
293	L<AnyEvent::MP>.
294
295	=head1 AUTHOR
296
297	Marc Lehmann <schmorp@schmorp.de>
298	http://home.schmorp.de/
299
300	=cut
301
302	1
303