AnyEvent-MP/MP/Node.pm

=head1 NAME

AnyEvent::MP::Node - represent a node

=head1 SYNOPSIS

   use AnyEvent::MP::Node;

=head1 DESCRIPTION

This is an internal utility module, horrible to look at, so don't.

=cut

package AnyEvent::MP::Node; # base class for nodes

use common::sense;

use AnyEvent ();
use AnyEvent::Socket ();

use AnyEvent::MP::Transport ();

sub new {
   my ($self, $id) = @_;

   $self = bless { id => $id }, $self;

   $self->init;
   $self->transport_reset;

   $self
}

sub init {
   #
}

sub send {
   &{ shift->{send} }
}

# nodes reachable via the network
package AnyEvent::MP::Node::Remote; # a remote node

use base "AnyEvent::MP::Node";

# called at init time, mostly sets {send}
sub transport_reset {
   my ($self) = @_;

   delete $self->{transport};

   Scalar::Util::weaken $self;

   $self->{send} = sub {
      push @{$self->{queue}}, shift;
      $self->connect;
   };
}

# called each time we fail to establish a connection,
# or the existing connection failed
sub transport_error {
   my ($self, @reason) = @_;

   my $no_transport = !$self->{transport};

   delete $self->{connect_w};
   delete $self->{connect_to};

   delete $self->{queue};
   $self->transport_reset;

   if (my $mon = delete $self->{lmon}) {
      $_->(@reason) for map @$_, values %$mon;
   }

   AnyEvent::MP::Kernel::_inject_nodeevent ($self, 0, @reason)
      unless $no_transport;

   # if we are here and are idle, we nuke ourselves
   delete $AnyEvent::MP::Kernel::NODE{$self->{id}}
      unless $self->{transport} || $self->{connect_to};
}

# called after handshake was successful
sub transport_connect {
   my ($self, $transport) = @_;

   delete $self->{trial};

   $self->transport_error (transport_error => $self->{id}, "switched connections")
      if $self->{transport};

   delete $self->{connect_w};
   delete $self->{connect_to};

   $self->{transport} = $transport;

   my $transport_send = $transport->{send};

   AnyEvent::MP::Kernel::_inject_nodeevent ($self, 1);

   $self->{send} = $transport_send;

   $transport_send->($_)
      for @{ delete $self->{queue} || [] };
}

sub connect {
   my ($self) = @_;

   return if $self->{transport};
   return if $self->{connect_w};

   Scalar::Util::weaken $self;
   use Carp;Carp::cluck;#d#

   $self->{connect_to} ||= AE::timer $AnyEvent::MP::Kernel::CONFIG->{connect_interval}, 0, sub {
      $self->transport_error (transport_error => $self->{id}, "unable to connect");
   };

   # maybe @$addresses?
   my $addresses = $AnyEvent::MP::Kernel::GLOBAL_DB{"'l"}{$self->{id}};

   if ($addresses) {
      $self->connect_to ($addresses);
   } else {
      # on global nodes, all bets are off now - we either know the node, or we don't
      unless ($AnyEvent::MP::Kernel::GLOBAL) {
         AnyEvent::MP::Kernel::g_find ($self->{id});
      }
   }
}

sub connect_to {
   my ($self, $addresses) = @_;

   return if $self->{transport};
   return if $self->{connect_w};

   return unless @$addresses;
   
   AE::log 9 => "connecting to $self->{id} with [@$addresses]";

   my $monitor  = $AnyEvent::MP::Kernel::CONFIG->{monitor_timeout};
   my $interval = $AnyEvent::MP::Kernel::CONFIG->{connect_interval};

   $interval = ($monitor - $interval) / @$addresses
      if ($monitor - $interval) / @$addresses < $interval;

   $interval = 0.4 if $interval < 0.4;

   my @endpoints = reverse @$addresses;

   $self->{connect_w} = AE::timer 0, $interval * (0.9 + 0.1 * rand), sub {
      my $endpoint = pop @endpoints;

      AE::log 9 => "connecting to $self->{id} at $endpoint";

      $self->{trial}{$endpoint} ||= do {
         my ($host, $port) = AnyEvent::Socket::parse_hostport $endpoint
            or return AE::log critical => "$self->{id}: '$endpoint' is not a resolved node reference.";

         AnyEvent::MP::Transport::mp_connect
            $host, $port,
            sub { delete $self->{trial}{$endpoint} },
      };
   };
}

sub kill {
   my ($self, $port, @reason) = @_;

   $self->{send} (["", kil => $port, @reason]);
}

sub monitor {
   my ($self, $portid, $cb) = @_;

   my $list = $self->{lmon}{$portid} ||= [];

   $self->send (["", mon1 => $portid])
      unless @$list || !length $portid;

   push @$list, $cb;
}

sub unmonitor {
   my ($self, $portid, $cb) = @_;

   my $list = $self->{lmon}{$portid}
      or return;

   @$list = grep $_ != $cb, @$list;

   unless (@$list) {
      $self->send (["", mon0 => $portid]);
      delete $self->{monitor}{$portid};
   }
}

package AnyEvent::MP::Node::Self; # the local node

use base "AnyEvent::MP::Node";

sub connect {
   # we are trivially connected
}

# delay every so often to avoid recursion, also used to delay after spawn
our $DELAY = -50;
our @DELAY;
our $DELAY_W;

our $send_delayed = sub {
   $AnyEvent::MP::Kernel::SRCNODE = $AnyEvent::MP::Kernel::NODE;
   (shift @DELAY)->()
      while @DELAY;
   undef $DELAY_W;
   $DELAY = -50;
};

sub transport_reset {
   my ($self) = @_;

   Scalar::Util::weaken $self;

   $self->{send} = sub {
      if (++$DELAY > 0) {
         my $msg = $_[0];
         push @DELAY, sub { AnyEvent::MP::Kernel::_inject (@$msg) };
         $DELAY_W ||= AE::timer 0, 0, $send_delayed;
         return;
      }

      local $AnyEvent::MP::Kernel::SRCNODE = $AnyEvent::MP::Kernel::NODE;
      AnyEvent::MP::Kernel::_inject (@{ $_[0] });
   };
}

sub transport_connect {
   my ($self, $tp) = @_;

   AE::log 9 => "I refuse to talk to myself ($tp->{peerhost}:$tp->{peerport})";
}

sub kill {
   my (undef, @args) = @_;

   # we _always_ delay kil's, to avoid calling mon callbacks
   # from anything but the event loop context.
   $DELAY = 1;
   push @DELAY, sub { AnyEvent::MP::Kernel::_kill (@args) };
   $DELAY_W ||= AE::timer 0, 0, $send_delayed;
}

sub monitor {
   # maybe always delay, too?
   if ($DELAY_W) {
      my @args = @_;
      push @DELAY, sub { AnyEvent::MP::Kernel::_monitor (@args) };
      return;
   }
   &AnyEvent::MP::Kernel::_monitor;
}

sub unmonitor {
   # no need to always delay
   if ($DELAY_W) {
      my @args = @_;
      push @DELAY, sub { AnyEvent::MP::Kernel::_unmonitor (@args) };
      return;
   }

   &AnyEvent::MP::Kernel::_unmonitor;
}

=head1 SEE ALSO

L<AnyEvent::MP>.

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

1

Revision:	1.64
Committed:	Fri Mar 23 21:16:25 2012 UTC (12 years, 2 months ago) by root
Branch:	MAIN
Changes since 1.63:	+4 -3 lines
Log Message:	* empty log message *
#	Content
1	=head1 NAME
2
3	AnyEvent::MP::Node - represent a node
4
5	=head1 SYNOPSIS
6
7	use AnyEvent::MP::Node;
8
9	=head1 DESCRIPTION
10
11	This is an internal utility module, horrible to look at, so don't.
12
13	=cut
14
15	package AnyEvent::MP::Node; # base class for nodes
16
17	use common::sense;
18
19	use AnyEvent ();
20	use AnyEvent::Socket ();
21
22	use AnyEvent::MP::Transport ();
23
24	sub new {
25	my ($self, $id) = @_;
26
27	$self = bless { id => $id }, $self;
28
29	$self->init;
30	$self->transport_reset;
31
32	$self
33	}
34
35	sub init {
36	#
37	}
38
39	sub send {
40	&{ shift->{send} }
41	}
42
43	# nodes reachable via the network
44	package AnyEvent::MP::Node::Remote; # a remote node
45
46	use base "AnyEvent::MP::Node";
47
48	# called at init time, mostly sets {send}
49	sub transport_reset {
50	my ($self) = @_;
51
52	delete $self->{transport};
53
54	Scalar::Util::weaken $self;
55
56	$self->{send} = sub {
57	push @{$self->{queue}}, shift;
58	$self->connect;
59	};
60	}
61
62	# called each time we fail to establish a connection,
63	# or the existing connection failed
64	sub transport_error {
65	my ($self, @reason) = @_;
66
67	my $no_transport = !$self->{transport};
68
69	delete $self->{connect_w};
70	delete $self->{connect_to};
71
72	delete $self->{queue};
73	$self->transport_reset;
74
75	if (my $mon = delete $self->{lmon}) {
76	$_->(@reason) for map @$_, values %$mon;
77	}
78
79	AnyEvent::MP::Kernel::_inject_nodeevent ($self, 0, @reason)
80	unless $no_transport;
81
82	# if we are here and are idle, we nuke ourselves
83	delete $AnyEvent::MP::Kernel::NODE{$self->{id}}
84	unless $self->{transport} \|\| $self->{connect_to};
85	}
86
87	# called after handshake was successful
88	sub transport_connect {
89	my ($self, $transport) = @_;
90
91	delete $self->{trial};
92
93	$self->transport_error (transport_error => $self->{id}, "switched connections")
94	if $self->{transport};
95
96	delete $self->{connect_w};
97	delete $self->{connect_to};
98
99	$self->{transport} = $transport;
100
101	my $transport_send = $transport->{send};
102
103	AnyEvent::MP::Kernel::_inject_nodeevent ($self, 1);
104
105	$self->{send} = $transport_send;
106
107	$transport_send->($_)
108	for @{ delete $self->{queue} \|\| [] };
109	}
110
111	sub connect {
112	my ($self) = @_;
113
114	return if $self->{transport};
115	return if $self->{connect_w};
116
117	Scalar::Util::weaken $self;
118	use Carp;Carp::cluck;#d#
119
120	$self->{connect_to} \|\|= AE::timer $AnyEvent::MP::Kernel::CONFIG->{connect_interval}, 0, sub {
121	$self->transport_error (transport_error => $self->{id}, "unable to connect");
122	};
123
124	# maybe @$addresses?
125	my $addresses = $AnyEvent::MP::Kernel::GLOBAL_DB{"'l"}{$self->{id}};
126
127	if ($addresses) {
128	$self->connect_to ($addresses);
129	} else {
130	# on global nodes, all bets are off now - we either know the node, or we don't
131	unless ($AnyEvent::MP::Kernel::GLOBAL) {
132	AnyEvent::MP::Kernel::g_find ($self->{id});
133	}
134	}
135	}
136
137	sub connect_to {
138	my ($self, $addresses) = @_;
139
140	return if $self->{transport};
141	return if $self->{connect_w};
142
143	return unless @$addresses;
144
145	AE::log 9 => "connecting to $self->{id} with [@$addresses]";
146
147	my $monitor = $AnyEvent::MP::Kernel::CONFIG->{monitor_timeout};
148	my $interval = $AnyEvent::MP::Kernel::CONFIG->{connect_interval};
149
150	$interval = ($monitor - $interval) / @$addresses
151	if ($monitor - $interval) / @$addresses < $interval;
152
153	$interval = 0.4 if $interval < 0.4;
154
155	my @endpoints = reverse @$addresses;
156
157	$self->{connect_w} = AE::timer 0, $interval * (0.9 + 0.1 * rand), sub {
158	my $endpoint = pop @endpoints;
159
160	AE::log 9 => "connecting to $self->{id} at $endpoint";
161
162	$self->{trial}{$endpoint} \|\|= do {
163	my ($host, $port) = AnyEvent::Socket::parse_hostport $endpoint
164	or return AE::log critical => "$self->{id}: '$endpoint' is not a resolved node reference.";
165
166	AnyEvent::MP::Transport::mp_connect
167	$host, $port,
168	sub { delete $self->{trial}{$endpoint} },
169	};
170	};
171	}
172
173	sub kill {
174	my ($self, $port, @reason) = @_;
175
176	$self->{send} (["", kil => $port, @reason]);
177	}
178
179	sub monitor {
180	my ($self, $portid, $cb) = @_;
181
182	my $list = $self->{lmon}{$portid} \|\|= [];
183
184	$self->send (["", mon1 => $portid])
185	unless @$list \|\| !length $portid;
186
187	push @$list, $cb;
188	}
189
190	sub unmonitor {
191	my ($self, $portid, $cb) = @_;
192
193	my $list = $self->{lmon}{$portid}
194	or return;
195
196	@$list = grep $_ != $cb, @$list;
197
198	unless (@$list) {
199	$self->send (["", mon0 => $portid]);
200	delete $self->{monitor}{$portid};
201	}
202	}
203
204	package AnyEvent::MP::Node::Self; # the local node
205
206	use base "AnyEvent::MP::Node";
207
208	sub connect {
209	# we are trivially connected
210	}
211
212	# delay every so often to avoid recursion, also used to delay after spawn
213	our $DELAY = -50;
214	our @DELAY;
215	our $DELAY_W;
216
217	our $send_delayed = sub {
218	$AnyEvent::MP::Kernel::SRCNODE = $AnyEvent::MP::Kernel::NODE;
219	(shift @DELAY)->()
220	while @DELAY;
221	undef $DELAY_W;
222	$DELAY = -50;
223	};
224
225	sub transport_reset {
226	my ($self) = @_;
227
228	Scalar::Util::weaken $self;
229
230	$self->{send} = sub {
231	if (++$DELAY > 0) {
232	my $msg = $_[0];
233	push @DELAY, sub { AnyEvent::MP::Kernel::_inject (@$msg) };
234	$DELAY_W \|\|= AE::timer 0, 0, $send_delayed;
235	return;
236	}
237
238	local $AnyEvent::MP::Kernel::SRCNODE = $AnyEvent::MP::Kernel::NODE;
239	AnyEvent::MP::Kernel::_inject (@{ $_[0] });
240	};
241	}
242
243	sub transport_connect {
244	my ($self, $tp) = @_;
245
246	AE::log 9 => "I refuse to talk to myself ($tp->{peerhost}:$tp->{peerport})";
247	}
248
249	sub kill {
250	my (undef, @args) = @_;
251
252	# we _always_ delay kil's, to avoid calling mon callbacks
253	# from anything but the event loop context.
254	$DELAY = 1;
255	push @DELAY, sub { AnyEvent::MP::Kernel::_kill (@args) };
256	$DELAY_W \|\|= AE::timer 0, 0, $send_delayed;
257	}
258
259	sub monitor {
260	# maybe always delay, too?
261	if ($DELAY_W) {
262	my @args = @_;
263	push @DELAY, sub { AnyEvent::MP::Kernel::_monitor (@args) };
264	return;
265	}
266	&AnyEvent::MP::Kernel::_monitor;
267	}
268
269	sub unmonitor {
270	# no need to always delay
271	if ($DELAY_W) {
272	my @args = @_;
273	push @DELAY, sub { AnyEvent::MP::Kernel::_unmonitor (@args) };
274	return;
275	}
276
277	&AnyEvent::MP::Kernel::_unmonitor;
278	}
279
280	=head1 SEE ALSO
281
282	L<AnyEvent::MP>.
283
284	=head1 AUTHOR
285
286	Marc Lehmann <schmorp@schmorp.de>
287	http://home.schmorp.de/
288
289	=cut
290
291	1
292