AnyEvent-MP/MP/Node.pm

=head1 NAME

AnyEvent::MP::Node - represent a node

=head1 SYNOPSIS

   use AnyEvent::MP::Node;

=head1 DESCRIPTION

This is an internal utility module, horrible to look at, so don't.

=cut

package AnyEvent::MP::Node; # base class for nodes

use common::sense;

use AnyEvent ();
use AnyEvent::Socket ();

use AnyEvent::MP::Transport ();

sub new {
   my ($self, $id) = @_;

   $self = bless { id => $id }, $self;

   # register
   $AnyEvent::MP::Kernel::NODE{$id} = $self;

   $self->init;
   $self->transport_reset;

   $self
}

sub DESTROY {
   # unregister
   delete $AnyEvent::MP::Kernel::NODE{$_[0]{id}};
}

sub init {
   #
}

sub send {
   &{ shift->{send} }
}

# nodes reachable via the network
package AnyEvent::MP::Node::Remote; # a remote node

use base "AnyEvent::MP::Node";

# called at init time, mostly sets {send}
sub transport_reset {
   my ($self) = @_;

   delete $self->{transport};

   Scalar::Util::weaken $self;

   $self->{send} = sub {
      push @{$self->{queue}}, shift;
      $self->connect;
   };
}

# called each time we fail to establish a connection,
# or the existing connection failed
sub transport_error {
   my ($self, @reason) = @_;

   my $no_transport = !$self->{transport};

   delete $self->{connect_w};
   delete $self->{connect_to};

   delete $self->{queue};
   $self->transport_reset;

   if (my $mon = delete $self->{lmon}) {
      $_->(@reason) for map @$_, values %$mon;
   }

   AnyEvent::MP::Kernel::_inject_nodeevent ($self, 0, @reason)
      unless $no_transport;

   # we weaken the node reference, so it can go away if unused
   Scalar::Util::weaken $AnyEvent::MP::Kernel::NODE{$self->{id}}
      unless $self->{connect_to};

   AE::log 9 => "@reason";
}

# called after handshake was successful
sub transport_connect {
   my ($self, $transport) = @_;

   delete $self->{trial};

   $self->transport_error (transport_error => $self->{id}, "switched connections")
      if $self->{transport};

   delete $self->{connect_w};
   delete $self->{connect_to};

   $self->{transport} = $transport;

   my $transport_send = $transport->{send};

   AnyEvent::MP::Kernel::_inject_nodeevent ($self, 1);

   $self->{send} = $transport_send;

   $transport_send->($_)
      for @{ delete $self->{queue} || [] };
}

sub connect {
   my ($self) = @_;

   return if $self->{transport};
   return if $self->{connect_w};

   # we unweaken the node reference, in case it was weakened before
   $AnyEvent::MP::Kernel::NODE{$self->{id}}
      = $AnyEvent::MP::Kernel::NODE{$self->{id}};

   Scalar::Util::weaken $self;

   $self->{connect_to} ||= AE::timer $AnyEvent::MP::Kernel::CONFIG->{connect_interval}, 0, sub {
      $self->transport_error (transport_error => $self->{id}, "connect timeout");
   };

   # maybe @$addresses?
   my $addresses = $AnyEvent::MP::Kernel::GLOBAL_DB{"'l"}{$self->{id}};

   if ($addresses) {
      $self->connect_to ($addresses);
   } else {
      # on global nodes, all bets are off now - we either know the node, or we don't
      if ($AnyEvent::MP::Kernel::GLOBAL) {
         $self->transport_error (transport_error => $self->{id}, "no known address");
      } else {
         AnyEvent::MP::Kernel::g_find ($self->{id});
      }
   }
}

sub connect_to {
   my ($self, $addresses) = @_;

   return if $self->{transport};
   return if $self->{connect_w};

   unless (@$addresses) {
      $self->transport_error (transport_error => $self->{id}, "no known address");
      return;
   }
   
   AE::log 9 => "connecting to $self->{id} with [@$addresses]";

   my $monitor  = $AnyEvent::MP::Kernel::CONFIG->{monitor_timeout};
   my $interval = $AnyEvent::MP::Kernel::CONFIG->{connect_interval};

   $interval = ($monitor - $interval) / @$addresses
      if ($monitor - $interval) / @$addresses < $interval;

   $interval = 0.4 if $interval < 0.4;

   my @endpoints = reverse @$addresses;

   $self->{connect_w} = AE::timer 0, $interval * (0.9 + 0.1 * rand), sub {
      my $endpoint = pop @endpoints;

      AE::log 9 => "connecting to $self->{id} at $endpoint";

      $self->{trial}{$endpoint} ||= do {
         my ($host, $port) = AnyEvent::Socket::parse_hostport $endpoint
            or return AE::log critical => "$self->{id}: '$endpoint' is not a resolved node reference.";

         AnyEvent::MP::Transport::mp_connect
            $host, $port,
            sub { delete $self->{trial}{$endpoint} },
      };
   };
}

sub kill {
   my ($self, $port, @reason) = @_;

   $self->{send} (["", kil1 => $port, @reason]);
}

sub monitor {
   my ($self, $portid, $cb) = @_;

   my $list = $self->{lmon}{$portid} ||= [];

   $self->send (["", mon1 => $portid])
      unless @$list || !length $portid;

   push @$list, $cb;
}

sub unmonitor {
   my ($self, $portid, $cb) = @_;

   my $list = $self->{lmon}{$portid}
      or return;

   @$list = grep $_ != $cb, @$list;

   unless (@$list) {
      $self->send (["", mon0 => $portid]);
      delete $self->{monitor}{$portid};
   }
}

package AnyEvent::MP::Node::Self; # the local node

use base "AnyEvent::MP::Node";

sub connect {
   # we are trivially connected
}

# delay every so often to avoid recursion, also used to delay after spawn
our $DELAY = -50;
our @DELAY;
our $DELAY_W;

our $send_delayed = sub {
   $AnyEvent::MP::Kernel::SRCNODE = $AnyEvent::MP::Kernel::NODE;
   (shift @DELAY)->()
      while @DELAY;
   undef $DELAY_W;
   $DELAY = -50;
};

sub transport_reset {
   my ($self) = @_;

   Scalar::Util::weaken $self;

   $self->{send} = sub {
      if (++$DELAY > 0) {
         my $msg = $_[0];
         push @DELAY, sub { AnyEvent::MP::Kernel::_inject (@$msg) };
         $DELAY_W ||= AE::timer 0, 0, $send_delayed;
         return;
      }

      local $AnyEvent::MP::Kernel::SRCNODE = $AnyEvent::MP::Kernel::NODE;
      AnyEvent::MP::Kernel::_inject (@{ $_[0] });
   };
}

sub transport_connect {
   my ($self, $tp) = @_;

   AE::log 9 => "I refuse to talk to myself ($tp->{peerhost}:$tp->{peerport})";
}

sub kill {
   my (undef, @args) = @_;

   # we _always_ delay kil's, to avoid calling mon callbacks
   # from anything but the event loop context.
   $DELAY = 1;
   push @DELAY, sub { AnyEvent::MP::Kernel::_kill (@args) };
   $DELAY_W ||= AE::timer 0, 0, $send_delayed;
}

sub monitor {
   # maybe always delay, too?
   if ($DELAY_W) {
      my @args = @_;
      push @DELAY, sub { AnyEvent::MP::Kernel::_monitor (@args) };
      return;
   }
   &AnyEvent::MP::Kernel::_monitor;
}

sub unmonitor {
   # no need to always delay
   if ($DELAY_W) {
      my @args = @_;
      push @DELAY, sub { AnyEvent::MP::Kernel::_unmonitor (@args) };
      return;
   }

   &AnyEvent::MP::Kernel::_unmonitor;
}

=head1 SEE ALSO

L<AnyEvent::MP>.

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

1

Revision:	1.67
Committed:	Sun Aug 28 08:23:34 2016 UTC (7 years, 9 months ago) by root
Branch:	MAIN
Changes since 1.66:	+0 -1 lines
Log Message:	* empty log message *
#	Content
1	=head1 NAME
2
3	AnyEvent::MP::Node - represent a node
4
5	=head1 SYNOPSIS
6
7	use AnyEvent::MP::Node;
8
9	=head1 DESCRIPTION
10
11	This is an internal utility module, horrible to look at, so don't.
12
13	=cut
14
15	package AnyEvent::MP::Node; # base class for nodes
16
17	use common::sense;
18
19	use AnyEvent ();
20	use AnyEvent::Socket ();
21
22	use AnyEvent::MP::Transport ();
23
24	sub new {
25	my ($self, $id) = @_;
26
27	$self = bless { id => $id }, $self;
28
29	# register
30	$AnyEvent::MP::Kernel::NODE{$id} = $self;
31
32	$self->init;
33	$self->transport_reset;
34
35	$self
36	}
37
38	sub DESTROY {
39	# unregister
40	delete $AnyEvent::MP::Kernel::NODE{$_[0]{id}};
41	}
42
43	sub init {
44	#
45	}
46
47	sub send {
48	&{ shift->{send} }
49	}
50
51	# nodes reachable via the network
52	package AnyEvent::MP::Node::Remote; # a remote node
53
54	use base "AnyEvent::MP::Node";
55
56	# called at init time, mostly sets {send}
57	sub transport_reset {
58	my ($self) = @_;
59
60	delete $self->{transport};
61
62	Scalar::Util::weaken $self;
63
64	$self->{send} = sub {
65	push @{$self->{queue}}, shift;
66	$self->connect;
67	};
68	}
69
70	# called each time we fail to establish a connection,
71	# or the existing connection failed
72	sub transport_error {
73	my ($self, @reason) = @_;
74
75	my $no_transport = !$self->{transport};
76
77	delete $self->{connect_w};
78	delete $self->{connect_to};
79
80	delete $self->{queue};
81	$self->transport_reset;
82
83	if (my $mon = delete $self->{lmon}) {
84	$_->(@reason) for map @$_, values %$mon;
85	}
86
87	AnyEvent::MP::Kernel::_inject_nodeevent ($self, 0, @reason)
88	unless $no_transport;
89
90	# we weaken the node reference, so it can go away if unused
91	Scalar::Util::weaken $AnyEvent::MP::Kernel::NODE{$self->{id}}
92	unless $self->{connect_to};
93
94	AE::log 9 => "@reason";
95	}
96
97	# called after handshake was successful
98	sub transport_connect {
99	my ($self, $transport) = @_;
100
101	delete $self->{trial};
102
103	$self->transport_error (transport_error => $self->{id}, "switched connections")
104	if $self->{transport};
105
106	delete $self->{connect_w};
107	delete $self->{connect_to};
108
109	$self->{transport} = $transport;
110
111	my $transport_send = $transport->{send};
112
113	AnyEvent::MP::Kernel::_inject_nodeevent ($self, 1);
114
115	$self->{send} = $transport_send;
116
117	$transport_send->($_)
118	for @{ delete $self->{queue} \|\| [] };
119	}
120
121	sub connect {
122	my ($self) = @_;
123
124	return if $self->{transport};
125	return if $self->{connect_w};
126
127	# we unweaken the node reference, in case it was weakened before
128	$AnyEvent::MP::Kernel::NODE{$self->{id}}
129	= $AnyEvent::MP::Kernel::NODE{$self->{id}};
130
131	Scalar::Util::weaken $self;
132
133	$self->{connect_to} \|\|= AE::timer $AnyEvent::MP::Kernel::CONFIG->{connect_interval}, 0, sub {
134	$self->transport_error (transport_error => $self->{id}, "connect timeout");
135	};
136
137	# maybe @$addresses?
138	my $addresses = $AnyEvent::MP::Kernel::GLOBAL_DB{"'l"}{$self->{id}};
139
140	if ($addresses) {
141	$self->connect_to ($addresses);
142	} else {
143	# on global nodes, all bets are off now - we either know the node, or we don't
144	if ($AnyEvent::MP::Kernel::GLOBAL) {
145	$self->transport_error (transport_error => $self->{id}, "no known address");
146	} else {
147	AnyEvent::MP::Kernel::g_find ($self->{id});
148	}
149	}
150	}
151
152	sub connect_to {
153	my ($self, $addresses) = @_;
154
155	return if $self->{transport};
156	return if $self->{connect_w};
157
158	unless (@$addresses) {
159	$self->transport_error (transport_error => $self->{id}, "no known address");
160	return;
161	}
162
163	AE::log 9 => "connecting to $self->{id} with [@$addresses]";
164
165	my $monitor = $AnyEvent::MP::Kernel::CONFIG->{monitor_timeout};
166	my $interval = $AnyEvent::MP::Kernel::CONFIG->{connect_interval};
167
168	$interval = ($monitor - $interval) / @$addresses
169	if ($monitor - $interval) / @$addresses < $interval;
170
171	$interval = 0.4 if $interval < 0.4;
172
173	my @endpoints = reverse @$addresses;
174
175	$self->{connect_w} = AE::timer 0, $interval * (0.9 + 0.1 * rand), sub {
176	my $endpoint = pop @endpoints;
177
178	AE::log 9 => "connecting to $self->{id} at $endpoint";
179
180	$self->{trial}{$endpoint} \|\|= do {
181	my ($host, $port) = AnyEvent::Socket::parse_hostport $endpoint
182	or return AE::log critical => "$self->{id}: '$endpoint' is not a resolved node reference.";
183
184	AnyEvent::MP::Transport::mp_connect
185	$host, $port,
186	sub { delete $self->{trial}{$endpoint} },
187	};
188	};
189	}
190
191	sub kill {
192	my ($self, $port, @reason) = @_;
193
194	$self->{send} (["", kil1 => $port, @reason]);
195	}
196
197	sub monitor {
198	my ($self, $portid, $cb) = @_;
199
200	my $list = $self->{lmon}{$portid} \|\|= [];
201
202	$self->send (["", mon1 => $portid])
203	unless @$list \|\| !length $portid;
204
205	push @$list, $cb;
206	}
207
208	sub unmonitor {
209	my ($self, $portid, $cb) = @_;
210
211	my $list = $self->{lmon}{$portid}
212	or return;
213
214	@$list = grep $_ != $cb, @$list;
215
216	unless (@$list) {
217	$self->send (["", mon0 => $portid]);
218	delete $self->{monitor}{$portid};
219	}
220	}
221
222	package AnyEvent::MP::Node::Self; # the local node
223
224	use base "AnyEvent::MP::Node";
225
226	sub connect {
227	# we are trivially connected
228	}
229
230	# delay every so often to avoid recursion, also used to delay after spawn
231	our $DELAY = -50;
232	our @DELAY;
233	our $DELAY_W;
234
235	our $send_delayed = sub {
236	$AnyEvent::MP::Kernel::SRCNODE = $AnyEvent::MP::Kernel::NODE;
237	(shift @DELAY)->()
238	while @DELAY;
239	undef $DELAY_W;
240	$DELAY = -50;
241	};
242
243	sub transport_reset {
244	my ($self) = @_;
245
246	Scalar::Util::weaken $self;
247
248	$self->{send} = sub {
249	if (++$DELAY > 0) {
250	my $msg = $_[0];
251	push @DELAY, sub { AnyEvent::MP::Kernel::_inject (@$msg) };
252	$DELAY_W \|\|= AE::timer 0, 0, $send_delayed;
253	return;
254	}
255
256	local $AnyEvent::MP::Kernel::SRCNODE = $AnyEvent::MP::Kernel::NODE;
257	AnyEvent::MP::Kernel::_inject (@{ $_[0] });
258	};
259	}
260
261	sub transport_connect {
262	my ($self, $tp) = @_;
263
264	AE::log 9 => "I refuse to talk to myself ($tp->{peerhost}:$tp->{peerport})";
265	}
266
267	sub kill {
268	my (undef, @args) = @_;
269
270	# we _always_ delay kil's, to avoid calling mon callbacks
271	# from anything but the event loop context.
272	$DELAY = 1;
273	push @DELAY, sub { AnyEvent::MP::Kernel::_kill (@args) };
274	$DELAY_W \|\|= AE::timer 0, 0, $send_delayed;
275	}
276
277	sub monitor {
278	# maybe always delay, too?
279	if ($DELAY_W) {
280	my @args = @_;
281	push @DELAY, sub { AnyEvent::MP::Kernel::_monitor (@args) };
282	return;
283	}
284	&AnyEvent::MP::Kernel::_monitor;
285	}
286
287	sub unmonitor {
288	# no need to always delay
289	if ($DELAY_W) {
290	my @args = @_;
291	push @DELAY, sub { AnyEvent::MP::Kernel::_unmonitor (@args) };
292	return;
293	}
294
295	&AnyEvent::MP::Kernel::_unmonitor;
296	}
297
298	=head1 SEE ALSO
299
300	L<AnyEvent::MP>.
301
302	=head1 AUTHOR
303
304	Marc Lehmann <schmorp@schmorp.de>
305	http://home.schmorp.de/
306
307	=cut
308
309	1
310