| 1 |
=head1 NAME |
| 2 |
|
| 3 |
AnyEvent::MP::Transport - actual transport protocol handler |
| 4 |
|
| 5 |
=head1 SYNOPSIS |
| 6 |
|
| 7 |
use AnyEvent::MP::Transport; |
| 8 |
|
| 9 |
=head1 DESCRIPTION |
| 10 |
|
| 11 |
This module implements (and documents) the actual transport protocol for |
| 12 |
AEMP. |
| 13 |
|
| 14 |
See the "PROTOCOL" section below if you want to write another client for |
| 15 |
this protocol. |
| 16 |
|
| 17 |
=head1 FUNCTIONS/METHODS |
| 18 |
|
| 19 |
=over 4 |
| 20 |
|
| 21 |
=cut |
| 22 |
|
| 23 |
package AnyEvent::MP::Transport; |
| 24 |
|
| 25 |
use common::sense; |
| 26 |
|
| 27 |
use Scalar::Util (); |
| 28 |
use List::Util (); |
| 29 |
use MIME::Base64 (); |
| 30 |
use Storable (); |
| 31 |
use JSON::XS (); |
| 32 |
|
| 33 |
use Digest::MD6 (); |
| 34 |
use Digest::HMAC_MD6 (); |
| 35 |
|
| 36 |
use AE (); |
| 37 |
use AnyEvent::Socket (); |
| 38 |
use AnyEvent::Handle 4.92 (); |
| 39 |
|
| 40 |
use AnyEvent::MP::Config (); |
| 41 |
|
| 42 |
our $PROTOCOL_VERSION = 1; |
| 43 |
|
| 44 |
our @HOOK_CONNECT; # called at connect/accept time |
| 45 |
our @HOOK_GREETING; # called at greeting1 time |
| 46 |
our @HOOK_CONNECTED; # called at data phase |
| 47 |
our @HOOK_DESTROY; # called at destroy time |
| 48 |
our %HOOK_PROTOCOL = ( |
| 49 |
"aemp-dataconn" => sub { |
| 50 |
require AnyEvent::MP::DataConn; |
| 51 |
&AnyEvent::MP::DataConn::_inject; |
| 52 |
}, |
| 53 |
); |
| 54 |
|
| 55 |
=item $listener = mp_listener $host, $port, <constructor-args> |
| 56 |
|
| 57 |
Creates a listener on the given host/port using |
| 58 |
C<AnyEvent::Socket::tcp_server>. |
| 59 |
|
| 60 |
See C<new>, below, for constructor arguments. |
| 61 |
|
| 62 |
Defaults for peerhost, peerport and fh are provided. |
| 63 |
|
| 64 |
=cut |
| 65 |
|
| 66 |
sub mp_server($$;%) { |
| 67 |
my ($host, $port, %arg) = @_; |
| 68 |
|
| 69 |
AnyEvent::Socket::tcp_server $host, $port, sub { |
| 70 |
my ($fh, $host, $port) = @_; |
| 71 |
|
| 72 |
my $tp = new AnyEvent::MP::Transport |
| 73 |
fh => $fh, |
| 74 |
peerhost => $host, |
| 75 |
peerport => $port, |
| 76 |
%arg, |
| 77 |
; |
| 78 |
$tp->{keepalive} = $tp; |
| 79 |
}, delete $arg{prepare} |
| 80 |
} |
| 81 |
|
| 82 |
=item $guard = mp_connect $host, $port, <constructor-args>, $cb->($transport) |
| 83 |
|
| 84 |
=cut |
| 85 |
|
| 86 |
sub mp_connect { |
| 87 |
my $release = pop; |
| 88 |
my ($host, $port, @args) = @_; |
| 89 |
|
| 90 |
new AnyEvent::MP::Transport |
| 91 |
connect => [$host, $port], |
| 92 |
peerhost => $host, |
| 93 |
peerport => $port, |
| 94 |
release => $release, |
| 95 |
@args, |
| 96 |
; |
| 97 |
} |
| 98 |
|
| 99 |
=item new AnyEvent::MP::Transport |
| 100 |
|
| 101 |
# immediately starts negotiation |
| 102 |
my $transport = new AnyEvent::MP::Transport |
| 103 |
# mandatory |
| 104 |
fh => $filehandle, |
| 105 |
local_id => $identifier, |
| 106 |
on_recv => sub { receive-callback }, |
| 107 |
on_error => sub { error-callback }, |
| 108 |
|
| 109 |
# optional |
| 110 |
on_eof => sub { clean-close-callback }, |
| 111 |
on_connect => sub { successful-connect-callback }, |
| 112 |
greeting => { key => value }, |
| 113 |
|
| 114 |
# tls support |
| 115 |
tls_ctx => AnyEvent::TLS, |
| 116 |
peername => $peername, # for verification |
| 117 |
; |
| 118 |
|
| 119 |
=cut |
| 120 |
|
| 121 |
sub new { |
| 122 |
my ($class, %arg) = @_; |
| 123 |
|
| 124 |
my $self = bless \%arg, $class; |
| 125 |
|
| 126 |
{ |
| 127 |
Scalar::Util::weaken (my $self = $self); |
| 128 |
|
| 129 |
my $config = $AnyEvent::MP::Kernel::CONFIG; |
| 130 |
|
| 131 |
my $timeout = $config->{monitor_timeout}; |
| 132 |
my $lframing = $config->{data_format}; |
| 133 |
my $auth_snd = $config->{auth_offer}; |
| 134 |
my $auth_rcv = $config->{auth_accept}; |
| 135 |
|
| 136 |
$self->{secret} = $config->{secret} |
| 137 |
unless exists $self->{secret}; |
| 138 |
|
| 139 |
my $secret = $self->{secret}; |
| 140 |
|
| 141 |
if (exists $config->{cert}) { |
| 142 |
$self->{tls_ctx} = { |
| 143 |
sslv2 => 0, |
| 144 |
sslv3 => 0, |
| 145 |
tlsv1 => 1, |
| 146 |
verify => 1, |
| 147 |
cert => $config->{cert}, |
| 148 |
ca_cert => $config->{cert}, |
| 149 |
verify_require_client_cert => 1, |
| 150 |
}; |
| 151 |
} |
| 152 |
|
| 153 |
$self->{hdl} = new AnyEvent::Handle |
| 154 |
+($self->{fh} ? (fh => $self->{fh}) : (connect => $self->{connect})), |
| 155 |
autocork => $config->{autocork}, |
| 156 |
no_delay => exists $config->{nodelay} ? $config->{nodelay} : 1, |
| 157 |
keepalive => 1, |
| 158 |
on_error => sub { |
| 159 |
$self->error ($_[2]); |
| 160 |
}, |
| 161 |
rtimeout => $timeout, |
| 162 |
; |
| 163 |
|
| 164 |
my $greeting_kv = $self->{local_greeting} ||= {}; |
| 165 |
|
| 166 |
$greeting_kv->{tls} = "1.0" if $self->{tls_ctx}; |
| 167 |
$greeting_kv->{provider} = "AE-$AnyEvent::MP::VERSION"; # MP.pm might not be loaded, so best effort :( |
| 168 |
$greeting_kv->{peeraddr} = AnyEvent::Socket::format_hostport $self->{peerhost}, $self->{peerport}; |
| 169 |
|
| 170 |
my $protocol = $self->{protocol} || "aemp"; |
| 171 |
|
| 172 |
# can modify greeting_kv |
| 173 |
$_->($self) for $protocol eq "aemp" ? @HOOK_CONNECT : (); |
| 174 |
|
| 175 |
# send greeting |
| 176 |
my $lgreeting1 = "$protocol;$PROTOCOL_VERSION" |
| 177 |
. ";$AnyEvent::MP::Kernel::NODE" |
| 178 |
. ";" . (join ",", @$auth_rcv) |
| 179 |
. ";" . (join ",", @$lframing) |
| 180 |
. (join "", map ";$_=$greeting_kv->{$_}", keys %$greeting_kv); |
| 181 |
|
| 182 |
my $lgreeting2 = MIME::Base64::encode_base64 AnyEvent::MP::Kernel::nonce (66), ""; |
| 183 |
|
| 184 |
$self->{hdl}->push_write ("$lgreeting1\012$lgreeting2\012"); |
| 185 |
|
| 186 |
# expect greeting |
| 187 |
$self->{hdl}->rbuf_max (4 * 1024); |
| 188 |
$self->{hdl}->push_read (line => sub { |
| 189 |
my $rgreeting1 = $_[1]; |
| 190 |
|
| 191 |
my ($aemp, $version, $rnode, $auths, $framings, @kv) = split /;/, $rgreeting1; |
| 192 |
|
| 193 |
$self->{remote_node} = $rnode; |
| 194 |
|
| 195 |
$self->{remote_greeting} = { |
| 196 |
map /^([^=]+)(?:=(.*))?/ ? ($1 => $2) : (), |
| 197 |
@kv |
| 198 |
}; |
| 199 |
|
| 200 |
# maybe upgrade the protocol |
| 201 |
if ($protocol eq "aemp" and $aemp =~ /^aemp-\w+$/) { |
| 202 |
# maybe check for existence of the protocol handler? |
| 203 |
$self->{protocol} = $protocol = $aemp; |
| 204 |
} |
| 205 |
|
| 206 |
$_->($self) for $protocol eq "aemp" ? @HOOK_GREETING : (); |
| 207 |
|
| 208 |
if ($aemp ne $protocol and $aemp ne "aemp") { |
| 209 |
return $self->error ("unparsable greeting, expected '$protocol', got '$aemp'"); |
| 210 |
} elsif ($version != $PROTOCOL_VERSION) { |
| 211 |
return $self->error ("version mismatch (we: $PROTOCOL_VERSION, they: $version)"); |
| 212 |
} elsif ($protocol eq "aemp") { |
| 213 |
if ($rnode eq $AnyEvent::MP::Kernel::NODE) { |
| 214 |
return $self->error ("I refuse to talk to myself"); |
| 215 |
} elsif ($AnyEvent::MP::Kernel::NODE{$rnode} && $AnyEvent::MP::Kernel::NODE{$rnode}{transport}) { |
| 216 |
return $self->error ("$rnode already connected, not connecting again."); |
| 217 |
} |
| 218 |
} |
| 219 |
|
| 220 |
# read nonce |
| 221 |
$self->{hdl}->push_read (line => sub { |
| 222 |
my $rgreeting2 = $_[1]; |
| 223 |
|
| 224 |
"$lgreeting1\012$lgreeting2" ne "$rgreeting1\012$rgreeting2" # echo attack? |
| 225 |
or return $self->error ("authentication error, echo attack?"); |
| 226 |
|
| 227 |
my $tls = $self->{tls_ctx} && 1 == int $self->{remote_greeting}{tls}; |
| 228 |
|
| 229 |
my $s_auth; |
| 230 |
for my $auth_ (split /,/, $auths) { |
| 231 |
if (grep $auth_ eq $_, @$auth_snd and ($auth_ !~ /^tls_/ or $tls)) { |
| 232 |
$s_auth = $auth_; |
| 233 |
last; |
| 234 |
} |
| 235 |
} |
| 236 |
|
| 237 |
defined $s_auth |
| 238 |
or return $self->error ("$auths: no common auth type supported"); |
| 239 |
|
| 240 |
my $s_framing; |
| 241 |
for my $framing_ (split /,/, $framings) { |
| 242 |
if (grep $framing_ eq $_, @$lframing) { |
| 243 |
$s_framing = $framing_; |
| 244 |
last; |
| 245 |
} |
| 246 |
} |
| 247 |
|
| 248 |
defined $s_framing |
| 249 |
or return $self->error ("$framings: no common framing method supported"); |
| 250 |
|
| 251 |
my $key; |
| 252 |
my $lauth; |
| 253 |
|
| 254 |
if ($tls) { |
| 255 |
$self->{tls} = $lgreeting2 lt $rgreeting2 ? "connect" : "accept"; |
| 256 |
$self->{hdl}->starttls ($self->{tls}, $self->{tls_ctx}); |
| 257 |
|
| 258 |
$lauth = |
| 259 |
$s_auth eq "tls_anon" ? "" |
| 260 |
: $s_auth eq "tls_md6_64_256" ? Digest::MD6::md6_hex "$lgreeting1\012$lgreeting2\012$rgreeting1\012$rgreeting2\012" |
| 261 |
: return $self->error ("$s_auth: fatal, selected unsupported snd auth method"); |
| 262 |
|
| 263 |
} elsif (length $secret) { |
| 264 |
return $self->error ("$s_auth: fatal, selected unsupported snd auth method") |
| 265 |
unless $s_auth eq "hmac_md6_64_256"; # hardcoded atm. |
| 266 |
|
| 267 |
$key = Digest::MD6::md6 $secret; |
| 268 |
# we currently only support hmac_md6_64_256 |
| 269 |
$lauth = Digest::HMAC_MD6::hmac_md6_hex $key, "$lgreeting1\012$lgreeting2\012$rgreeting1\012$rgreeting2\012", 64, 256; |
| 270 |
|
| 271 |
} else { |
| 272 |
return $self->error ("unable to handshake TLS and no shared secret configured"); |
| 273 |
} |
| 274 |
|
| 275 |
$self->{hdl}->push_write ("$s_auth;$lauth;$s_framing\012"); |
| 276 |
|
| 277 |
# read the authentication response |
| 278 |
$self->{hdl}->push_read (line => sub { |
| 279 |
my ($hdl, $rline) = @_; |
| 280 |
|
| 281 |
my ($auth_method, $rauth2, $r_framing) = split /;/, $rline; |
| 282 |
|
| 283 |
my $rauth = |
| 284 |
$auth_method eq "hmac_md6_64_256" ? Digest::HMAC_MD6::hmac_md6_hex $key, "$rgreeting1\012$rgreeting2\012$lgreeting1\012$lgreeting2\012", 64, 256 |
| 285 |
: $auth_method eq "cleartext" ? unpack "H*", $secret |
| 286 |
: $auth_method eq "tls_anon" ? ($tls ? "" : "\012\012") # \012\012 never matches |
| 287 |
: $auth_method eq "tls_md6_64_256" ? ($tls ? Digest::MD6::md6_hex "$rgreeting1\012$rgreeting2\012$lgreeting1\012$lgreeting2\012" : "\012\012") |
| 288 |
: return $self->error ("$auth_method: fatal, selected unsupported rcv auth method"); |
| 289 |
|
| 290 |
if ($rauth2 ne $rauth) { |
| 291 |
return $self->error ("authentication failure/shared secret mismatch"); |
| 292 |
} |
| 293 |
|
| 294 |
$self->{s_framing} = $s_framing; |
| 295 |
|
| 296 |
$hdl->rbuf_max (undef); |
| 297 |
|
| 298 |
# we rely on TCP retransmit timeouts and keepalives |
| 299 |
$self->{hdl}->rtimeout (undef); |
| 300 |
|
| 301 |
$self->{remote_greeting}{untrusted} = 1 |
| 302 |
if $auth_method eq "tls_anon"; |
| 303 |
|
| 304 |
$self->connected; |
| 305 |
|
| 306 |
if ($protocol eq "aemp") { |
| 307 |
# listener-less node need to continuously probe |
| 308 |
unless (@$AnyEvent::MP::Kernel::LISTENER) { |
| 309 |
$self->{hdl}->wtimeout ($timeout); |
| 310 |
$self->{hdl}->on_wtimeout (sub { $self->send ([]) }); |
| 311 |
} |
| 312 |
|
| 313 |
# receive handling |
| 314 |
my $src_node = $self->{node}; |
| 315 |
my $rmsg; $rmsg = $self->{rmsg} = sub { |
| 316 |
$_[0]->push_read ($r_framing => $rmsg); |
| 317 |
|
| 318 |
local $AnyEvent::MP::Kernel::SRCNODE = $src_node; |
| 319 |
AnyEvent::MP::Kernel::_inject (@{ $_[1] }); |
| 320 |
}; |
| 321 |
$hdl->push_read ($r_framing => $rmsg); |
| 322 |
|
| 323 |
Scalar::Util::weaken $rmsg; |
| 324 |
Scalar::Util::weaken $src_node; |
| 325 |
} |
| 326 |
}); |
| 327 |
}); |
| 328 |
}); |
| 329 |
} |
| 330 |
|
| 331 |
$self |
| 332 |
} |
| 333 |
|
| 334 |
sub error { |
| 335 |
my ($self, $msg) = @_; |
| 336 |
|
| 337 |
delete $self->{keepalive}; |
| 338 |
|
| 339 |
if ($self->{protocol}) { |
| 340 |
$HOOK_PROTOCOL{$self->{protocol}}->($self, $msg); |
| 341 |
} else { |
| 342 |
$AnyEvent::MP::Kernel::WARN->(9, "$self->{peerhost}:$self->{peerport} $msg");#d# |
| 343 |
|
| 344 |
$self->{node}->transport_error (transport_error => $self->{node}{id}, $msg) |
| 345 |
if $self->{node} && $self->{node}{transport} == $self; |
| 346 |
} |
| 347 |
|
| 348 |
(delete $self->{release})->() |
| 349 |
if exists $self->{release}; |
| 350 |
|
| 351 |
# $AnyEvent::MP::Kernel::WARN->(7, "$self->{peerhost}:$self->{peerport}: $msg"); |
| 352 |
$self->destroy; |
| 353 |
} |
| 354 |
|
| 355 |
sub connected { |
| 356 |
my ($self) = @_; |
| 357 |
|
| 358 |
delete $self->{keepalive}; |
| 359 |
|
| 360 |
if ($self->{protocol}) { |
| 361 |
$self->{hdl}->on_error (undef); |
| 362 |
$HOOK_PROTOCOL{$self->{protocol}}->($self, undef); |
| 363 |
} else { |
| 364 |
$AnyEvent::MP::Kernel::WARN->(9, "$self->{peerhost}:$self->{peerport} connected as $self->{remote_node}"); |
| 365 |
|
| 366 |
my $node = AnyEvent::MP::Kernel::add_node ($self->{remote_node}); |
| 367 |
Scalar::Util::weaken ($self->{node} = $node); |
| 368 |
$node->transport_connect ($self); |
| 369 |
|
| 370 |
$_->($self) for @HOOK_CONNECTED; |
| 371 |
} |
| 372 |
|
| 373 |
(delete $self->{release})->() |
| 374 |
if exists $self->{release}; |
| 375 |
} |
| 376 |
|
| 377 |
sub send { |
| 378 |
$_[0]{hdl}->push_write ($_[0]{s_framing} => $_[1]); |
| 379 |
} |
| 380 |
|
| 381 |
sub destroy { |
| 382 |
my ($self) = @_; |
| 383 |
|
| 384 |
(delete $self->{release})->() |
| 385 |
if exists $self->{release}; |
| 386 |
|
| 387 |
$self->{hdl}->destroy |
| 388 |
if $self->{hdl}; |
| 389 |
|
| 390 |
$_->($self) for $self->{protocol} ? () : @HOOK_DESTROY; |
| 391 |
} |
| 392 |
|
| 393 |
sub DESTROY { |
| 394 |
my ($self) = @_; |
| 395 |
|
| 396 |
$self->destroy; |
| 397 |
} |
| 398 |
|
| 399 |
=back |
| 400 |
|
| 401 |
=head1 PROTOCOL |
| 402 |
|
| 403 |
The AEMP protocol is comparatively simple, and consists of three phases |
| 404 |
which are symmetrical for both sides: greeting (followed by optionally |
| 405 |
switching to TLS mode), authentication and packet exchange. |
| 406 |
|
| 407 |
The protocol is designed to allow both full-text and binary streams. |
| 408 |
|
| 409 |
The greeting consists of two text lines that are ended by either an ASCII |
| 410 |
CR LF pair, or a single ASCII LF (recommended). |
| 411 |
|
| 412 |
=head2 GREETING |
| 413 |
|
| 414 |
All the lines until after authentication must not exceed 4kb in length, |
| 415 |
including line delimiter. Afterwards there is no limit on the packet size |
| 416 |
that can be received. |
| 417 |
|
| 418 |
=head3 First Greeting Line |
| 419 |
|
| 420 |
Example: |
| 421 |
|
| 422 |
aemp;0;rain;tls_md6_64_256,hmac_md6_64_256,tls_anon,cleartext;json,storable;timeout=12;peeraddr=10.0.0.1:48082 |
| 423 |
|
| 424 |
The first line contains strings separated (not ended) by C<;> |
| 425 |
characters. The first five strings are fixed by the protocol, the |
| 426 |
remaining strings are C<KEY=VALUE> pairs. None of them may contain C<;> |
| 427 |
characters themselves (when escaping is needed, use C<%3b> to represent |
| 428 |
C<;> and C<%25> to represent C<%>)- |
| 429 |
|
| 430 |
The fixed strings are: |
| 431 |
|
| 432 |
=over 4 |
| 433 |
|
| 434 |
=item protocol identification |
| 435 |
|
| 436 |
The constant C<aemp> to identify this protocol. |
| 437 |
|
| 438 |
=item protocol version |
| 439 |
|
| 440 |
The protocol version supported by this end, currently C<1>. If the |
| 441 |
versions don't match then no communication is possible. Minor extensions |
| 442 |
are supposed to be handled through additional key-value pairs. |
| 443 |
|
| 444 |
=item the node ID |
| 445 |
|
| 446 |
This is the node ID of the connecting node. |
| 447 |
|
| 448 |
=item the acceptable authentication methods |
| 449 |
|
| 450 |
A comma-separated list of authentication methods supported by the |
| 451 |
node. Note that AnyEvent::MP supports a C<hex_secret> authentication |
| 452 |
method that accepts a clear-text password (hex-encoded), but will not use |
| 453 |
this authentication method itself. |
| 454 |
|
| 455 |
The receiving side should choose the first authentication method it |
| 456 |
supports. |
| 457 |
|
| 458 |
=item the acceptable framing formats |
| 459 |
|
| 460 |
A comma-separated list of packet encoding/framing formats understood. The |
| 461 |
receiving side should choose the first framing format it supports for |
| 462 |
sending packets (which might be different from the format it has to accept). |
| 463 |
|
| 464 |
=back |
| 465 |
|
| 466 |
The remaining arguments are C<KEY=VALUE> pairs. The following key-value |
| 467 |
pairs are known at this time: |
| 468 |
|
| 469 |
=over 4 |
| 470 |
|
| 471 |
=item provider=<module-version> |
| 472 |
|
| 473 |
The software provider for this implementation. For AnyEvent::MP, this is |
| 474 |
C<AE-0.0> or whatever version it currently is at. |
| 475 |
|
| 476 |
=item peeraddr=<host>:<port> |
| 477 |
|
| 478 |
The peer address (socket address of the other side) as seen locally. |
| 479 |
|
| 480 |
=item tls=<major>.<minor> |
| 481 |
|
| 482 |
Indicates that the other side supports TLS (version should be 1.0) and |
| 483 |
wishes to do a TLS handshake. |
| 484 |
|
| 485 |
=back |
| 486 |
|
| 487 |
=head3 Second Greeting Line |
| 488 |
|
| 489 |
After this greeting line there will be a second line containing a |
| 490 |
cryptographic nonce, i.e. random data of high quality. To keep the |
| 491 |
protocol text-only, these are usually 32 base64-encoded octets, but |
| 492 |
it could be anything that doesn't contain any ASCII CR or ASCII LF |
| 493 |
characters. |
| 494 |
|
| 495 |
I<< The two nonces B<must> be different, and an aemp implementation |
| 496 |
B<must> check and fail when they are identical >>. |
| 497 |
|
| 498 |
Example of a nonce line (yes, it's random-looking because it is random |
| 499 |
data): |
| 500 |
|
| 501 |
2XYhdG7/O6epFa4wuP0ujAEx1rXYWRcOypjUYK7eF6yWAQr7gwIN9m/2+mVvBrTPXz5GJDgfGm9d8QRABAbmAP/s |
| 502 |
|
| 503 |
=head2 TLS handshake |
| 504 |
|
| 505 |
I<< If, after the handshake, both sides indicate interest in TLS, then the |
| 506 |
connection B<must> use TLS, or fail to continue. >> |
| 507 |
|
| 508 |
Both sides compare their nonces, and the side who sent the lower nonce |
| 509 |
value ("string" comparison on the raw octet values) becomes the client, |
| 510 |
and the one with the higher nonce the server. |
| 511 |
|
| 512 |
=head2 AUTHENTICATION PHASE |
| 513 |
|
| 514 |
After the greeting is received (and the optional TLS handshake), |
| 515 |
the authentication phase begins, which consists of sending a single |
| 516 |
C<;>-separated line with three fixed strings and any number of |
| 517 |
C<KEY=VALUE> pairs. |
| 518 |
|
| 519 |
The three fixed strings are: |
| 520 |
|
| 521 |
=over 4 |
| 522 |
|
| 523 |
=item the authentication method chosen |
| 524 |
|
| 525 |
This must be one of the methods offered by the other side in the greeting. |
| 526 |
|
| 527 |
Note that all methods starting with C<tls_> are only valid I<iff> TLS was |
| 528 |
successfully handshaked (and to be secure the implementation must enforce |
| 529 |
this). |
| 530 |
|
| 531 |
The currently supported authentication methods are: |
| 532 |
|
| 533 |
=over 4 |
| 534 |
|
| 535 |
=item cleartext |
| 536 |
|
| 537 |
This is simply the shared secret, lowercase-hex-encoded. This method is of |
| 538 |
course very insecure if TLS is not used (and not completely secure even |
| 539 |
if TLS is used), which is why this module will accept, but not generate, |
| 540 |
cleartext auth replies. |
| 541 |
|
| 542 |
=item hmac_md6_64_256 |
| 543 |
|
| 544 |
This method uses an MD6 HMAC with 64 bit blocksize and 256 bit hash, and |
| 545 |
requires a shared secret. It is the preferred auth method when a shared |
| 546 |
secret is available. |
| 547 |
|
| 548 |
First, the shared secret is hashed with MD6: |
| 549 |
|
| 550 |
key = MD6 (secret) |
| 551 |
|
| 552 |
This secret is then used to generate the "local auth reply", by taking |
| 553 |
the two local greeting lines and the two remote greeting lines (without |
| 554 |
line endings), appending \012 to all of them, concatenating them and |
| 555 |
calculating the MD6 HMAC with the key: |
| 556 |
|
| 557 |
lauth = HMAC_MD6 key, "lgreeting1\012lgreeting2\012rgreeting1\012rgreeting2\012" |
| 558 |
|
| 559 |
This authentication token is then lowercase-hex-encoded and sent to the |
| 560 |
other side. |
| 561 |
|
| 562 |
Then the remote auth reply is generated using the same method, but local |
| 563 |
and remote greeting lines swapped: |
| 564 |
|
| 565 |
rauth = HMAC_MD6 key, "rgreeting1\012rgreeting2\012lgreeting1\012lgreeting2\012" |
| 566 |
|
| 567 |
This is the token that is expected from the other side. |
| 568 |
|
| 569 |
=item tls_anon |
| 570 |
|
| 571 |
This type is only valid I<iff> TLS was enabled and the TLS handshake |
| 572 |
was successful. It has no authentication data, as the server/client |
| 573 |
certificate was successfully verified. |
| 574 |
|
| 575 |
This authentication type is somewhat insecure, as it allows a |
| 576 |
man-in-the-middle attacker to change some of the connection parameters |
| 577 |
(such as the framing format), although there is no known attack that |
| 578 |
exploits this in a way that is worse than just denying the service. |
| 579 |
|
| 580 |
By default, this implementation accepts but never generates this auth |
| 581 |
reply. |
| 582 |
|
| 583 |
=item tls_md6_64_256 |
| 584 |
|
| 585 |
This type is only valid I<iff> TLS was enabled and the TLS handshake was |
| 586 |
successful. |
| 587 |
|
| 588 |
This authentication type simply calculates: |
| 589 |
|
| 590 |
lauth = MD6 "rgreeting1\012rgreeting2\012lgreeting1\012lgreeting2\012" |
| 591 |
|
| 592 |
and lowercase-hex encodes the result and sends it as authentication |
| 593 |
data. No shared secret is required (authentication is done by TLS). The |
| 594 |
checksum exists only to make tinkering with the greeting hard. |
| 595 |
|
| 596 |
=back |
| 597 |
|
| 598 |
=item the authentication data |
| 599 |
|
| 600 |
The authentication data itself, usually base64 or hex-encoded data, see |
| 601 |
above. |
| 602 |
|
| 603 |
=item the framing protocol chosen |
| 604 |
|
| 605 |
This must be one of the framing protocols offered by the other side in the |
| 606 |
greeting. Each side must accept the choice of the other side, and generate |
| 607 |
packets in the format it chose itself. |
| 608 |
|
| 609 |
=back |
| 610 |
|
| 611 |
Example of an authentication reply: |
| 612 |
|
| 613 |
hmac_md6_64_256;363d5175df38bd9eaddd3f6ca18aa1c0c4aa22f0da245ac638d048398c26b8d3;json |
| 614 |
|
| 615 |
=head2 DATA PHASE |
| 616 |
|
| 617 |
After this, packets get exchanged using the chosen framing protocol. It is |
| 618 |
quite possible that both sides use a different framing protocol. |
| 619 |
|
| 620 |
=head2 FULL EXAMPLE |
| 621 |
|
| 622 |
This is an actual protocol dump of a handshake, followed by a single data |
| 623 |
packet. The greater than/less than lines indicate the direction of the |
| 624 |
transfer only. |
| 625 |
|
| 626 |
> aemp;0;anon/57Cs1CggVJjzYaQp13XXg4;tls_md6_64_256,hmac_md6_64_256,tls_anon,cleartext;json,storable;provider=AE-0.8;timeout=12;peeraddr=10.0.0.17:4040 |
| 627 |
> yLgdG1ov/02shVkVQer3wzeuywZK+oraTdEQBmIqWHaegxSGDG4g+HqogLQbvdypFOsoDWJ1Sh4ImV4DMhvUBwTK |
| 628 |
|
| 629 |
< aemp;0;ruth;tls_md6_64_256,hmac_md6_64_256,tls_anon,cleartext;json,storable;provider=AE-0.8;timeout=12;peeraddr=10.0.0.1:37108 |
| 630 |
< +xMQXP8ElfNmuvEhsmcp+s2wCJOuQAsPxSg3d2Ewhs6gBnJz+ypVdWJ/wAVrXqlIJfLeVS/CBy4gEGkyWHSuVb1L |
| 631 |
|
| 632 |
> hmac_md6_64_256;5ad913855742ae5a03a5aeb7eafa4c78629de136bed6acd73eea36c9e98df44a;json |
| 633 |
|
| 634 |
< hmac_md6_64_256;84cd590976f794914c2ca26dac3a207a57a6798b9171289c114de07cf0c20401;json |
| 635 |
< ["","AnyEvent::MP::_spawn","57Cs1CggVJjzYaQp13XXg4.c","AnyEvent::MP::Global::connect",0,"anon/57Cs1CggVJjzYaQp13XXg4"] |
| 636 |
... |
| 637 |
|
| 638 |
The shared secret in use was C<8ugxrtw6H5tKnfPWfaSr4HGhE8MoJXmzTT1BWq7sLutNcD0IbXprQlZjIbl7MBKoeklG3IEfY9GlJthC0pENzk>. |
| 639 |
|
| 640 |
=head2 MONITORING |
| 641 |
|
| 642 |
Monitoring the connection itself is transport-specific. For TCP, all |
| 643 |
connection monitoring is currently left to TCP retransmit time-outs |
| 644 |
on a busy link, and TCP keepalive (which should be enabled) for idle |
| 645 |
connections. |
| 646 |
|
| 647 |
This is not sufficient for listener-less nodes, however: they need |
| 648 |
to regularly send data (30 seconds, or the monitoring interval, is |
| 649 |
recommended), so TCP actively probes. |
| 650 |
|
| 651 |
Future implementations of AnyEvent::Transport might query the kernel TCP |
| 652 |
buffer after a write timeout occurs, and if it is non-empty, shut down the |
| 653 |
connections, but this is an area of future research :) |
| 654 |
|
| 655 |
=head2 NODE PROTOCOL |
| 656 |
|
| 657 |
The transport simply transfers messages, but to implement a full node, a |
| 658 |
special node port must exist that understands a number of requests. |
| 659 |
|
| 660 |
If you are interested in implementing this, drop us a note so we finish |
| 661 |
the documentation. |
| 662 |
|
| 663 |
=head1 SEE ALSO |
| 664 |
|
| 665 |
L<AnyEvent::MP>. |
| 666 |
|
| 667 |
=head1 AUTHOR |
| 668 |
|
| 669 |
Marc Lehmann <schmorp@schmorp.de> |
| 670 |
http://home.schmorp.de/ |
| 671 |
|
| 672 |
=cut |
| 673 |
|
| 674 |
1 |
| 675 |
|
