| 1 |
=head1 NAME |
| 2 |
|
| 3 |
AnyEvent::MP::Transport - actual transport protocol handler |
| 4 |
|
| 5 |
=head1 SYNOPSIS |
| 6 |
|
| 7 |
use AnyEvent::MP::Transport; |
| 8 |
|
| 9 |
=head1 DESCRIPTION |
| 10 |
|
| 11 |
This module implements (and documents) the actual transport protocol for |
| 12 |
AEMP. |
| 13 |
|
| 14 |
See the "PROTOCOL" section below if you want to write another client for |
| 15 |
this protocol. |
| 16 |
|
| 17 |
=head1 FUNCTIONS/METHODS |
| 18 |
|
| 19 |
=over 4 |
| 20 |
|
| 21 |
=cut |
| 22 |
|
| 23 |
package AnyEvent::MP::Transport; |
| 24 |
|
| 25 |
use common::sense; |
| 26 |
|
| 27 |
use Scalar::Util (); |
| 28 |
use List::Util (); |
| 29 |
use MIME::Base64 (); |
| 30 |
use Storable (); |
| 31 |
use JSON::XS (); |
| 32 |
|
| 33 |
use Digest::MD6 (); |
| 34 |
use Digest::HMAC_MD6 (); |
| 35 |
|
| 36 |
use AE (); |
| 37 |
use AnyEvent::Socket (); |
| 38 |
use AnyEvent::Handle 4.92 (); |
| 39 |
|
| 40 |
use AnyEvent::MP::Config (); |
| 41 |
|
| 42 |
our $PROTOCOL_VERSION = 1; |
| 43 |
|
| 44 |
our @HOOK_CONNECT; # called at connect/accept time |
| 45 |
our @HOOK_GREETING; # called at greeting1 time |
| 46 |
our @HOOK_CONNECTED; # called at data phase |
| 47 |
our @HOOK_DESTROY; # called at destroy time |
| 48 |
|
| 49 |
=item $listener = mp_listener $host, $port, <constructor-args> |
| 50 |
|
| 51 |
Creates a listener on the given host/port using |
| 52 |
C<AnyEvent::Socket::tcp_server>. |
| 53 |
|
| 54 |
See C<new>, below, for constructor arguments. |
| 55 |
|
| 56 |
Defaults for peerhost, peerport and fh are provided. |
| 57 |
|
| 58 |
=cut |
| 59 |
|
| 60 |
sub mp_server($$;%) { |
| 61 |
my ($host, $port, %arg) = @_; |
| 62 |
|
| 63 |
AnyEvent::Socket::tcp_server $host, $port, sub { |
| 64 |
my ($fh, $host, $port) = @_; |
| 65 |
|
| 66 |
my $tp = new AnyEvent::MP::Transport |
| 67 |
fh => $fh, |
| 68 |
peerhost => $host, |
| 69 |
peerport => $port, |
| 70 |
%arg, |
| 71 |
; |
| 72 |
$tp->{keepalive} = $tp; |
| 73 |
}, delete $arg{prepare} |
| 74 |
} |
| 75 |
|
| 76 |
=item $guard = mp_connect $host, $port, <constructor-args>, $cb->($transport) |
| 77 |
|
| 78 |
=cut |
| 79 |
|
| 80 |
sub mp_connect { |
| 81 |
my $release = pop; |
| 82 |
my ($host, $port, @args) = @_; |
| 83 |
|
| 84 |
new AnyEvent::MP::Transport |
| 85 |
connect => [$host, $port], |
| 86 |
peerhost => $host, |
| 87 |
peerport => $port, |
| 88 |
release => $release, |
| 89 |
@args, |
| 90 |
; |
| 91 |
} |
| 92 |
|
| 93 |
=item new AnyEvent::MP::Transport |
| 94 |
|
| 95 |
# immediately starts negotiation |
| 96 |
my $transport = new AnyEvent::MP::Transport |
| 97 |
# mandatory |
| 98 |
fh => $filehandle, |
| 99 |
local_id => $identifier, |
| 100 |
on_recv => sub { receive-callback }, |
| 101 |
on_error => sub { error-callback }, |
| 102 |
|
| 103 |
# optional |
| 104 |
on_eof => sub { clean-close-callback }, |
| 105 |
on_connect => sub { successful-connect-callback }, |
| 106 |
greeting => { key => value }, |
| 107 |
|
| 108 |
# tls support |
| 109 |
tls_ctx => AnyEvent::TLS, |
| 110 |
peername => $peername, # for verification |
| 111 |
; |
| 112 |
|
| 113 |
=cut |
| 114 |
|
| 115 |
sub new { |
| 116 |
my ($class, %arg) = @_; |
| 117 |
|
| 118 |
my $self = bless \%arg, $class; |
| 119 |
|
| 120 |
$self->{queue} = []; |
| 121 |
|
| 122 |
{ |
| 123 |
Scalar::Util::weaken (my $self = $self); |
| 124 |
|
| 125 |
my $config = $AnyEvent::MP::Kernel::CONFIG; |
| 126 |
|
| 127 |
my $timeout = $config->{monitor_timeout}; |
| 128 |
my $lframing = $config->{data_format}; |
| 129 |
my $auth_snd = $config->{auth_offer}; |
| 130 |
my $auth_rcv = $config->{auth_accept}; |
| 131 |
|
| 132 |
$self->{secret} = $config->{secret} |
| 133 |
unless exists $self->{secret}; |
| 134 |
|
| 135 |
my $secret = $self->{secret}; |
| 136 |
|
| 137 |
if (exists $config->{cert}) { |
| 138 |
$self->{tls_ctx} = { |
| 139 |
sslv2 => 0, |
| 140 |
sslv3 => 0, |
| 141 |
tlsv1 => 1, |
| 142 |
verify => 1, |
| 143 |
cert => $config->{cert}, |
| 144 |
ca_cert => $config->{cert}, |
| 145 |
verify_require_client_cert => 1, |
| 146 |
}; |
| 147 |
} |
| 148 |
|
| 149 |
$self->{hdl} = new AnyEvent::Handle |
| 150 |
+($self->{fh} ? (fh => $self->{fh}) : (connect => $self->{connect})), |
| 151 |
autocork => 1, |
| 152 |
no_delay => 1, |
| 153 |
keepalive => 1, |
| 154 |
on_error => sub { |
| 155 |
$self->error ($_[2]); |
| 156 |
}, |
| 157 |
rtimeout => $timeout, |
| 158 |
; |
| 159 |
|
| 160 |
my $greeting_kv = $self->{local_greeting} ||= {}; |
| 161 |
|
| 162 |
$greeting_kv->{tls} = "1.0" if $self->{tls_ctx}; |
| 163 |
$greeting_kv->{provider} = "AE-$AnyEvent::MP::Kernel::VERSION"; |
| 164 |
$greeting_kv->{peeraddr} = AnyEvent::Socket::format_hostport $self->{peerhost}, $self->{peerport}; |
| 165 |
$greeting_kv->{timeout} = $self->{timeout}; |
| 166 |
|
| 167 |
# can modify greeting_kv |
| 168 |
$_->($self) for @HOOK_CONNECT; |
| 169 |
|
| 170 |
# send greeting |
| 171 |
my $lgreeting1 = "aemp;$PROTOCOL_VERSION" |
| 172 |
. ";$AnyEvent::MP::Kernel::NODE" |
| 173 |
. ";" . (join ",", @$auth_rcv) |
| 174 |
. ";" . (join ",", @$lframing) |
| 175 |
. (join "", map ";$_=$greeting_kv->{$_}", keys %$greeting_kv); |
| 176 |
|
| 177 |
my $lgreeting2 = MIME::Base64::encode_base64 AnyEvent::MP::Kernel::nonce (66), ""; |
| 178 |
|
| 179 |
$self->{hdl}->push_write ("$lgreeting1\012$lgreeting2\012"); |
| 180 |
|
| 181 |
# expect greeting |
| 182 |
$self->{hdl}->rbuf_max (4 * 1024); |
| 183 |
$self->{hdl}->push_read (line => sub { |
| 184 |
my $rgreeting1 = $_[1]; |
| 185 |
|
| 186 |
my ($aemp, $version, $rnode, $auths, $framings, @kv) = split /;/, $rgreeting1; |
| 187 |
|
| 188 |
$self->{remote_node} = $rnode; |
| 189 |
|
| 190 |
$self->{remote_greeting} = { |
| 191 |
map /^([^=]+)(?:=(.*))?/ ? ($1 => $2) : (), |
| 192 |
@kv |
| 193 |
}; |
| 194 |
|
| 195 |
$_->($self) for @HOOK_GREETING; |
| 196 |
|
| 197 |
if ($aemp ne "aemp") { |
| 198 |
return $self->error ("unparsable greeting"); |
| 199 |
} elsif ($version != $PROTOCOL_VERSION) { |
| 200 |
return $self->error ("version mismatch (we: $PROTOCOL_VERSION, they: $version)"); |
| 201 |
} elsif ($rnode eq $AnyEvent::MP::Kernel::NODE) { |
| 202 |
return $self->error ("I refuse to talk to myself"); |
| 203 |
} elsif ($AnyEvent::MP::Kernel::NODE{$rnode} && $AnyEvent::MP::Kernel::NODE{$rnode}{transport}) { |
| 204 |
return $self->error ("$rnode already connected, not connecting again."); |
| 205 |
} |
| 206 |
|
| 207 |
# read nonce |
| 208 |
$self->{hdl}->push_read (line => sub { |
| 209 |
my $rgreeting2 = $_[1]; |
| 210 |
|
| 211 |
"$lgreeting1\012$lgreeting2" ne "$rgreeting1\012$rgreeting2" # echo attack? |
| 212 |
or return $self->error ("authentication error, echo attack?"); |
| 213 |
|
| 214 |
my $tls = $self->{tls_ctx} && 1 == int $self->{remote_greeting}{tls}; |
| 215 |
|
| 216 |
my $s_auth; |
| 217 |
for my $auth_ (split /,/, $auths) { |
| 218 |
if (grep $auth_ eq $_, @$auth_snd and ($auth_ !~ /^tls_/ or $tls)) { |
| 219 |
$s_auth = $auth_; |
| 220 |
last; |
| 221 |
} |
| 222 |
} |
| 223 |
|
| 224 |
defined $s_auth |
| 225 |
or return $self->error ("$auths: no common auth type supported"); |
| 226 |
|
| 227 |
my $s_framing; |
| 228 |
for my $framing_ (split /,/, $framings) { |
| 229 |
if (grep $framing_ eq $_, @$lframing) { |
| 230 |
$s_framing = $framing_; |
| 231 |
last; |
| 232 |
} |
| 233 |
} |
| 234 |
|
| 235 |
defined $s_framing |
| 236 |
or return $self->error ("$framings: no common framing method supported"); |
| 237 |
|
| 238 |
my $key; |
| 239 |
my $lauth; |
| 240 |
|
| 241 |
if ($tls) { |
| 242 |
$self->{tls} = $lgreeting2 lt $rgreeting2 ? "connect" : "accept"; |
| 243 |
$self->{hdl}->starttls ($self->{tls}, $self->{tls_ctx}); |
| 244 |
|
| 245 |
$lauth = |
| 246 |
$s_auth eq "tls_anon" ? "" |
| 247 |
: $s_auth eq "tls_md6_64_256" ? Digest::MD6::md6_hex "$lgreeting1\012$lgreeting2\012$rgreeting1\012$rgreeting2\012" |
| 248 |
: return $self->error ("$s_auth: fatal, selected unsupported snd auth method"); |
| 249 |
|
| 250 |
} elsif (length $secret) { |
| 251 |
return $self->error ("$s_auth: fatal, selected unsupported snd auth method") |
| 252 |
unless $s_auth eq "hmac_md6_64_256"; # hardcoded atm. |
| 253 |
|
| 254 |
$key = Digest::MD6::md6 $secret; |
| 255 |
# we currently only support hmac_md6_64_256 |
| 256 |
$lauth = Digest::HMAC_MD6::hmac_md6_hex $key, "$lgreeting1\012$lgreeting2\012$rgreeting1\012$rgreeting2\012", 64, 256; |
| 257 |
|
| 258 |
} else { |
| 259 |
return $self->error ("unable to handshake TLS and no shared secret configured"); |
| 260 |
} |
| 261 |
|
| 262 |
$self->{hdl}->push_write ("$s_auth;$lauth;$s_framing\012"); |
| 263 |
|
| 264 |
# read the authentication response |
| 265 |
$self->{hdl}->push_read (line => sub { |
| 266 |
my ($hdl, $rline) = @_; |
| 267 |
|
| 268 |
my ($auth_method, $rauth2, $r_framing) = split /;/, $rline; |
| 269 |
|
| 270 |
my $rauth = |
| 271 |
$auth_method eq "hmac_md6_64_256" ? Digest::HMAC_MD6::hmac_md6_hex $key, "$rgreeting1\012$rgreeting2\012$lgreeting1\012$lgreeting2\012", 64, 256 |
| 272 |
: $auth_method eq "cleartext" ? unpack "H*", $secret |
| 273 |
: $auth_method eq "tls_anon" ? ($tls ? "" : "\012\012") # \012\012 never matches |
| 274 |
: $auth_method eq "tls_md6_64_256" ? ($tls ? Digest::MD6::md6_hex "$rgreeting1\012$rgreeting2\012$lgreeting1\012$lgreeting2\012" : "\012\012") |
| 275 |
: return $self->error ("$auth_method: fatal, selected unsupported rcv auth method"); |
| 276 |
|
| 277 |
if ($rauth2 ne $rauth) { |
| 278 |
return $self->error ("authentication failure/shared secret mismatch"); |
| 279 |
} |
| 280 |
|
| 281 |
$self->{s_framing} = $s_framing; |
| 282 |
|
| 283 |
$hdl->rbuf_max (undef); |
| 284 |
|
| 285 |
# we rely on TCP retransmit timeouts and keepalives |
| 286 |
$self->{hdl}->rtimeout (undef); |
| 287 |
|
| 288 |
# except listener-less nodes, they need to continuously probe |
| 289 |
unless (@$AnyEvent::MP::Kernel::LISTENER) { |
| 290 |
$self->{hdl}->wtimeout ($timeout); |
| 291 |
$self->{hdl}->on_wtimeout (sub { $self->send ([]) }); |
| 292 |
} |
| 293 |
|
| 294 |
$self->{remote_greeting}{untrusted} = 1 |
| 295 |
if $auth_method eq "tls_anon"; |
| 296 |
|
| 297 |
my $queue = delete $self->{queue}; # we are connected |
| 298 |
|
| 299 |
$self->connected; |
| 300 |
|
| 301 |
# send queued messages |
| 302 |
$self->send ($_) |
| 303 |
for @$queue; |
| 304 |
|
| 305 |
# receive handling |
| 306 |
my $src_node = $self->{node}; |
| 307 |
my $rmsg; $rmsg = $self->{rmsg} = sub { |
| 308 |
$_[0]->push_read ($r_framing => $rmsg); |
| 309 |
|
| 310 |
local $AnyEvent::MP::Kernel::SRCNODE = $src_node; |
| 311 |
AnyEvent::MP::Kernel::_inject (@{ $_[1] }); |
| 312 |
}; |
| 313 |
$hdl->push_read ($r_framing => $rmsg); |
| 314 |
|
| 315 |
Scalar::Util::weaken $rmsg; |
| 316 |
Scalar::Util::weaken $src_node; |
| 317 |
}); |
| 318 |
}); |
| 319 |
}); |
| 320 |
} |
| 321 |
|
| 322 |
$self |
| 323 |
} |
| 324 |
|
| 325 |
sub error { |
| 326 |
my ($self, $msg) = @_; |
| 327 |
|
| 328 |
delete $self->{keepalive}; |
| 329 |
|
| 330 |
$AnyEvent::MP::Kernel::WARN->(9, "$self->{peerhost}:$self->{peerport} $msg");#d# |
| 331 |
|
| 332 |
$self->{node}->transport_error (transport_error => $self->{node}{id}, $msg) |
| 333 |
if $self->{node} && $self->{node}{transport} == $self; |
| 334 |
|
| 335 |
(delete $self->{release})->() |
| 336 |
if exists $self->{release}; |
| 337 |
|
| 338 |
# $AnyEvent::MP::Kernel::WARN->(7, "$self->{peerhost}:$self->{peerport}: $msg"); |
| 339 |
$self->destroy; |
| 340 |
} |
| 341 |
|
| 342 |
sub connected { |
| 343 |
my ($self) = @_; |
| 344 |
|
| 345 |
delete $self->{keepalive}; |
| 346 |
|
| 347 |
(delete $self->{release})->() |
| 348 |
if exists $self->{release}; |
| 349 |
|
| 350 |
$AnyEvent::MP::Kernel::WARN->(9, "$self->{peerhost}:$self->{peerport} connected as $self->{remote_node}"); |
| 351 |
|
| 352 |
my $node = AnyEvent::MP::Kernel::add_node ($self->{remote_node}); |
| 353 |
Scalar::Util::weaken ($self->{node} = $node); |
| 354 |
$node->transport_connect ($self); |
| 355 |
|
| 356 |
$_->($self) for @HOOK_CONNECTED; |
| 357 |
} |
| 358 |
|
| 359 |
sub send { |
| 360 |
$_[0]{hdl}->push_write ($_[0]{s_framing} => $_[1]); |
| 361 |
} |
| 362 |
|
| 363 |
sub destroy { |
| 364 |
my ($self) = @_; |
| 365 |
|
| 366 |
(delete $self->{release})->() |
| 367 |
if exists $self->{release}; |
| 368 |
|
| 369 |
$self->{hdl}->destroy |
| 370 |
if $self->{hdl}; |
| 371 |
|
| 372 |
$_->($self) for @HOOK_DESTROY; |
| 373 |
} |
| 374 |
|
| 375 |
sub DESTROY { |
| 376 |
my ($self) = @_; |
| 377 |
|
| 378 |
$self->destroy; |
| 379 |
} |
| 380 |
|
| 381 |
=back |
| 382 |
|
| 383 |
=head1 PROTOCOL |
| 384 |
|
| 385 |
The AEMP protocol is relatively simple, and consists of three phases which |
| 386 |
are symmetrical for both sides: greeting (followed by optionally switching |
| 387 |
to TLS mode), authentication and packet exchange. |
| 388 |
|
| 389 |
The protocol is designed to allow both full-text and binary streams. |
| 390 |
|
| 391 |
The greeting consists of two text lines that are ended by either an ASCII |
| 392 |
CR LF pair, or a single ASCII LF (recommended). |
| 393 |
|
| 394 |
=head2 GREETING |
| 395 |
|
| 396 |
All the lines until after authentication must not exceed 4kb in length, |
| 397 |
including line delimiter. Afterwards there is no limit on the packet size |
| 398 |
that can be received. |
| 399 |
|
| 400 |
=head3 First Greeting Line |
| 401 |
|
| 402 |
Example: |
| 403 |
|
| 404 |
aemp;0;rain;tls_md6_64_256,hmac_md6_64_256,tls_anon,cleartext;json,storable;timeout=12;peeraddr=10.0.0.1:48082 |
| 405 |
|
| 406 |
The first line contains strings separated (not ended) by C<;> |
| 407 |
characters. The first five strings are fixed by the protocol, the |
| 408 |
remaining strings are C<KEY=VALUE> pairs. None of them may contain C<;> |
| 409 |
characters themselves (when escaping is needed, use C<%3b> to represent |
| 410 |
C<;> and C<%25> to represent C<%>)- |
| 411 |
|
| 412 |
The fixed strings are: |
| 413 |
|
| 414 |
=over 4 |
| 415 |
|
| 416 |
=item protocol identification |
| 417 |
|
| 418 |
The constant C<aemp> to identify this protocol. |
| 419 |
|
| 420 |
=item protocol version |
| 421 |
|
| 422 |
The protocol version supported by this end, currently C<1>. If the |
| 423 |
versions don't match then no communication is possible. Minor extensions |
| 424 |
are supposed to be handled through additional key-value pairs. |
| 425 |
|
| 426 |
=item the node ID |
| 427 |
|
| 428 |
This is the node ID of the connecting node. If it is empty, then this |
| 429 |
is not a normal node connection but a data connection or something |
| 430 |
similar. AEMP implementations that do not support these additional modes |
| 431 |
should just reject connections with empty node IDs. |
| 432 |
|
| 433 |
=item the acceptable authentication methods |
| 434 |
|
| 435 |
A comma-separated list of authentication methods supported by the |
| 436 |
node. Note that AnyEvent::MP supports a C<hex_secret> authentication |
| 437 |
method that accepts a clear-text password (hex-encoded), but will not use |
| 438 |
this authentication method itself. |
| 439 |
|
| 440 |
The receiving side should choose the first authentication method it |
| 441 |
supports. |
| 442 |
|
| 443 |
=item the acceptable framing formats |
| 444 |
|
| 445 |
A comma-separated list of packet encoding/framing formats understood. The |
| 446 |
receiving side should choose the first framing format it supports for |
| 447 |
sending packets (which might be different from the format it has to accept). |
| 448 |
|
| 449 |
=back |
| 450 |
|
| 451 |
The remaining arguments are C<KEY=VALUE> pairs. The following key-value |
| 452 |
pairs are known at this time: |
| 453 |
|
| 454 |
=over 4 |
| 455 |
|
| 456 |
=item provider=<module-version> |
| 457 |
|
| 458 |
The software provider for this implementation. For AnyEvent::MP, this is |
| 459 |
C<AE-0.0> or whatever version it currently is at. |
| 460 |
|
| 461 |
=item peeraddr=<host>:<port> |
| 462 |
|
| 463 |
The peer address (socket address of the other side) as seen locally. |
| 464 |
|
| 465 |
=item tls=<major>.<minor> |
| 466 |
|
| 467 |
Indicates that the other side supports TLS (version should be 1.0) and |
| 468 |
wishes to do a TLS handshake. |
| 469 |
|
| 470 |
=back |
| 471 |
|
| 472 |
=head3 Second Greeting Line |
| 473 |
|
| 474 |
After this greeting line there will be a second line containing a |
| 475 |
cryptographic nonce, i.e. random data of high quality. To keep the |
| 476 |
protocol text-only, these are usually 32 base64-encoded octets, but |
| 477 |
it could be anything that doesn't contain any ASCII CR or ASCII LF |
| 478 |
characters. |
| 479 |
|
| 480 |
I<< The two nonces B<must> be different, and an aemp implementation |
| 481 |
B<must> check and fail when they are identical >>. |
| 482 |
|
| 483 |
Example of a nonce line (yes, it's random-looking because it is random |
| 484 |
data): |
| 485 |
|
| 486 |
2XYhdG7/O6epFa4wuP0ujAEx1rXYWRcOypjUYK7eF6yWAQr7gwIN9m/2+mVvBrTPXz5GJDgfGm9d8QRABAbmAP/s |
| 487 |
|
| 488 |
=head2 TLS handshake |
| 489 |
|
| 490 |
I<< If, after the handshake, both sides indicate interest in TLS, then the |
| 491 |
connection B<must> use TLS, or fail to continue. >> |
| 492 |
|
| 493 |
Both sides compare their nonces, and the side who sent the lower nonce |
| 494 |
value ("string" comparison on the raw octet values) becomes the client, |
| 495 |
and the one with the higher nonce the server. |
| 496 |
|
| 497 |
=head2 AUTHENTICATION PHASE |
| 498 |
|
| 499 |
After the greeting is received (and the optional TLS handshake), |
| 500 |
the authentication phase begins, which consists of sending a single |
| 501 |
C<;>-separated line with three fixed strings and any number of |
| 502 |
C<KEY=VALUE> pairs. |
| 503 |
|
| 504 |
The three fixed strings are: |
| 505 |
|
| 506 |
=over 4 |
| 507 |
|
| 508 |
=item the authentication method chosen |
| 509 |
|
| 510 |
This must be one of the methods offered by the other side in the greeting. |
| 511 |
|
| 512 |
Note that all methods starting with C<tls_> are only valid I<iff> TLS was |
| 513 |
successfully handshaked (and to be secure the implementation must enforce |
| 514 |
this). |
| 515 |
|
| 516 |
The currently supported authentication methods are: |
| 517 |
|
| 518 |
=over 4 |
| 519 |
|
| 520 |
=item cleartext |
| 521 |
|
| 522 |
This is simply the shared secret, lowercase-hex-encoded. This method is of |
| 523 |
course very insecure if TLS is not used (and not completely secure even |
| 524 |
if TLS is used), which is why this module will accept, but not generate, |
| 525 |
cleartext auth replies. |
| 526 |
|
| 527 |
=item hmac_md6_64_256 |
| 528 |
|
| 529 |
This method uses an MD6 HMAC with 64 bit blocksize and 256 bit hash, and |
| 530 |
requires a shared secret. It is the preferred auth method when a shared |
| 531 |
secret is available. |
| 532 |
|
| 533 |
First, the shared secret is hashed with MD6: |
| 534 |
|
| 535 |
key = MD6 (secret) |
| 536 |
|
| 537 |
This secret is then used to generate the "local auth reply", by taking |
| 538 |
the two local greeting lines and the two remote greeting lines (without |
| 539 |
line endings), appending \012 to all of them, concatenating them and |
| 540 |
calculating the MD6 HMAC with the key: |
| 541 |
|
| 542 |
lauth = HMAC_MD6 key, "lgreeting1\012lgreeting2\012rgreeting1\012rgreeting2\012" |
| 543 |
|
| 544 |
This authentication token is then lowercase-hex-encoded and sent to the |
| 545 |
other side. |
| 546 |
|
| 547 |
Then the remote auth reply is generated using the same method, but local |
| 548 |
and remote greeting lines swapped: |
| 549 |
|
| 550 |
rauth = HMAC_MD6 key, "rgreeting1\012rgreeting2\012lgreeting1\012lgreeting2\012" |
| 551 |
|
| 552 |
This is the token that is expected from the other side. |
| 553 |
|
| 554 |
=item tls_anon |
| 555 |
|
| 556 |
This type is only valid I<iff> TLS was enabled and the TLS handshake |
| 557 |
was successful. It has no authentication data, as the server/client |
| 558 |
certificate was successfully verified. |
| 559 |
|
| 560 |
This authentication type is somewhat insecure, as it allows a |
| 561 |
man-in-the-middle attacker to change some of the connection parameters |
| 562 |
(such as the framing format), although there is no known attack that |
| 563 |
exploits this in a way that is worse than just denying the service. |
| 564 |
|
| 565 |
By default, this implementation accepts but never generates this auth |
| 566 |
reply. |
| 567 |
|
| 568 |
=item tls_md6_64_256 |
| 569 |
|
| 570 |
This type is only valid I<iff> TLS was enabled and the TLS handshake was |
| 571 |
successful. |
| 572 |
|
| 573 |
This authentication type simply calculates: |
| 574 |
|
| 575 |
lauth = MD6 "rgreeting1\012rgreeting2\012lgreeting1\012lgreeting2\012" |
| 576 |
|
| 577 |
and lowercase-hex encodes the result and sends it as authentication |
| 578 |
data. No shared secret is required (authentication is done by TLS). The |
| 579 |
checksum exists only to make tinkering with the greeting hard. |
| 580 |
|
| 581 |
=back |
| 582 |
|
| 583 |
=item the authentication data |
| 584 |
|
| 585 |
The authentication data itself, usually base64 or hex-encoded data, see |
| 586 |
above. |
| 587 |
|
| 588 |
=item the framing protocol chosen |
| 589 |
|
| 590 |
This must be one of the framing protocols offered by the other side in the |
| 591 |
greeting. Each side must accept the choice of the other side, and generate |
| 592 |
packets in the format it chose itself. |
| 593 |
|
| 594 |
=back |
| 595 |
|
| 596 |
Example of an authentication reply: |
| 597 |
|
| 598 |
hmac_md6_64_256;363d5175df38bd9eaddd3f6ca18aa1c0c4aa22f0da245ac638d048398c26b8d3;json |
| 599 |
|
| 600 |
=head2 DATA PHASE |
| 601 |
|
| 602 |
After this, packets get exchanged using the chosen framing protocol. It is |
| 603 |
quite possible that both sides use a different framing protocol. |
| 604 |
|
| 605 |
=head2 FULL EXAMPLE |
| 606 |
|
| 607 |
This is an actual protocol dump of a handshake, followed by a single data |
| 608 |
packet. The greater than/less than lines indicate the direction of the |
| 609 |
transfer only. |
| 610 |
|
| 611 |
> aemp;0;anon/57Cs1CggVJjzYaQp13XXg4;tls_md6_64_256,hmac_md6_64_256,tls_anon,cleartext;json,storable;provider=AE-0.8;timeout=12;peeraddr=10.0.0.17:4040 |
| 612 |
> yLgdG1ov/02shVkVQer3wzeuywZK+oraTdEQBmIqWHaegxSGDG4g+HqogLQbvdypFOsoDWJ1Sh4ImV4DMhvUBwTK |
| 613 |
|
| 614 |
< aemp;0;ruth;tls_md6_64_256,hmac_md6_64_256,tls_anon,cleartext;json,storable;provider=AE-0.8;timeout=12;peeraddr=10.0.0.1:37108 |
| 615 |
< +xMQXP8ElfNmuvEhsmcp+s2wCJOuQAsPxSg3d2Ewhs6gBnJz+ypVdWJ/wAVrXqlIJfLeVS/CBy4gEGkyWHSuVb1L |
| 616 |
|
| 617 |
> hmac_md6_64_256;5ad913855742ae5a03a5aeb7eafa4c78629de136bed6acd73eea36c9e98df44a;json |
| 618 |
|
| 619 |
< hmac_md6_64_256;84cd590976f794914c2ca26dac3a207a57a6798b9171289c114de07cf0c20401;json |
| 620 |
< ["","AnyEvent::MP::_spawn","57Cs1CggVJjzYaQp13XXg4.c","AnyEvent::MP::Global::connect",0,"anon/57Cs1CggVJjzYaQp13XXg4"] |
| 621 |
... |
| 622 |
|
| 623 |
The shared secret in use was C<8ugxrtw6H5tKnfPWfaSr4HGhE8MoJXmzTT1BWq7sLutNcD0IbXprQlZjIbl7MBKoeklG3IEfY9GlJthC0pENzk>. |
| 624 |
|
| 625 |
=head2 MONITORING |
| 626 |
|
| 627 |
Monitoring the connection itself is transport-specific. For TCP, all |
| 628 |
connection monitoring is currently left to TCP retransmit time-outs |
| 629 |
on a busy link, and TCP keepalive (which should be enabled) for idle |
| 630 |
connections. |
| 631 |
|
| 632 |
This is not sufficient for listener-less nodes, however: they need |
| 633 |
to regularly send data (30 seconds, or the monitoring interval, is |
| 634 |
recommended), so TCP actively probes. |
| 635 |
|
| 636 |
Future implementations of AnyEvent::Transport might query the kernel TCP |
| 637 |
buffer after a write timeout occurs, and if it is non-empty, shut down the |
| 638 |
connections, but this is an area of future research :) |
| 639 |
|
| 640 |
=head2 NODE PROTOCOL |
| 641 |
|
| 642 |
The transport simply transfers messages, but to implement a full node, a |
| 643 |
special node port must exist that understands a number of requests. |
| 644 |
|
| 645 |
If you are interested in implementing this, drop us a note so we finish |
| 646 |
the documentation. |
| 647 |
|
| 648 |
=head1 SEE ALSO |
| 649 |
|
| 650 |
L<AnyEvent::MP>. |
| 651 |
|
| 652 |
=head1 AUTHOR |
| 653 |
|
| 654 |
Marc Lehmann <schmorp@schmorp.de> |
| 655 |
http://home.schmorp.de/ |
| 656 |
|
| 657 |
=cut |
| 658 |
|
| 659 |
1 |
| 660 |
|
