1 |
=head1 NAME |
2 |
|
3 |
AnyEvent::SNMP - adaptor to integrate Net::SNMP into AnyEvent. |
4 |
|
5 |
=head1 SYNOPSIS |
6 |
|
7 |
use AnyEvent::SNMP; |
8 |
use Net::SNMP; |
9 |
|
10 |
# just use Net::SNMP and AnyEvent as you like: |
11 |
|
12 |
# use a condvar to transfer results, this is |
13 |
# just an example, you can use a naked callback as well. |
14 |
my $cv = AnyEvent->condvar; |
15 |
|
16 |
# ... start non-blocking snmp request(s)... |
17 |
Net::SNMP->session (-hostname => "127.0.0.1", |
18 |
-community => "public", |
19 |
-nonblocking => 1) |
20 |
->get_request (-callback => sub { $cv->send (@_) }); |
21 |
|
22 |
# ... do something else until the result is required |
23 |
my @result = $cv->wait; |
24 |
|
25 |
=head1 DESCRIPTION |
26 |
|
27 |
This module implements an alternative "event dispatcher" for Net::SNMP, |
28 |
using AnyEvent as a backend. This integrates Net::SNMP into AnyEvent. That |
29 |
means you can make non-blocking Net::SNMP calls and as long as other |
30 |
parts of your program also use AnyEvent (or some event loop supported by |
31 |
AnyEvent), they will run in parallel. |
32 |
|
33 |
Also, the Net::SNMP scheduler is very inefficient with respect to both CPU |
34 |
and memory usage. Most AnyEvent backends (including the pure-perl backend) |
35 |
fare much better than the Net::SNMP dispatcher. |
36 |
|
37 |
Another major added fetaure of this module over Net::SNMP is automatic |
38 |
rate-adjustments: Net::SNMP is so slow that firing a few thousand |
39 |
requests can cause many timeouts simply because Net::SNMP cannot process |
40 |
the replies in time. This module automatically adapts the send rate to |
41 |
avoid false timeouts caused by slow reply processing. |
42 |
|
43 |
A potential disadvantage of this module is that replacing the dispatcher |
44 |
is not at all a documented thing to do, so future changes in Net::SNP |
45 |
might break this module (or the many similar ones). |
46 |
|
47 |
This module does not export anything and does not require you to do |
48 |
anything special apart from loading it I<before doing any non-blocking |
49 |
requests with Net::SNMP>. It is recommended but not required to load this |
50 |
module before C<Net::SNMP>. |
51 |
|
52 |
=head1 GLOBAL VARIABLES |
53 |
|
54 |
=over 4 |
55 |
|
56 |
=item $AnyEvent::SNMP::MAX_OUTSTANDING (default: C<50>, dynamic) |
57 |
|
58 |
=item AnyEvent::SNMP::set_max_outstanding $new_value |
59 |
|
60 |
Use this package variable to restrict the number of outstanding SNMP |
61 |
requests at any point in time. |
62 |
|
63 |
Net::SNMP is very fast at creating and sending SNMP requests, but much |
64 |
slower at parsing (big, bulk) responses. This makes it easy to request a |
65 |
lot of data that can take many seconds to parse. |
66 |
|
67 |
In the best case, this can lead to unnecessary delays (and even time-outs, |
68 |
as the data has been received but not yet processed) and in the worst |
69 |
case, this can lead to packet loss, when the receive queue overflows and |
70 |
the kernel can no longer accept new packets. |
71 |
|
72 |
To avoid this, you can (and should) limit the number of outstanding |
73 |
requests to a number low enough so that parsing time doesn't introduce |
74 |
noticable delays. |
75 |
|
76 |
Unfortunately, this number depends not only on processing speed and load |
77 |
of the machine running Net::SNMP, but also on the network latency and the |
78 |
speed of your SNMP agents. |
79 |
|
80 |
AnyEvent::SNMP tries to dynamically adjust this number upwards and |
81 |
downwards. |
82 |
|
83 |
Increasing C<$MAX_OUTSTANDING> will not automatically use the |
84 |
extra request slots. To increase C<$MAX_OUTSTANDING> and make |
85 |
C<AnyEvent::SNMP> make use of the extra paralellity, call |
86 |
C<AnyEvent::SNMP::set_max_outstanding> with the new value, e.g.: |
87 |
|
88 |
AnyEvent::SNMP::set_max_outstanding 500; |
89 |
|
90 |
Although due to the dynamic adjustment, this might have little lasting |
91 |
effect. |
92 |
|
93 |
Note that you can use L<Net::SNMP::XS> to speed up parsing of responses |
94 |
considerably. |
95 |
|
96 |
=item $AnyEvent::SNMP::MIN_RECVQUEUE (default: C<8>) |
97 |
|
98 |
=item $AnyEvent::SNMP::MAX_RECVQUEUE (default: C<64>) |
99 |
|
100 |
These values specify the minimum and maximum receive queue length (in |
101 |
units of one response packet). |
102 |
|
103 |
When AnyEvent::SNMP handles $MAX_RECVQUEUE or more packets per iteration |
104 |
it will reduce $MAX_OUTSTANDING. If it handles less than $MIN_RECVQUEUE, |
105 |
it increases $MAX_OUTSTANDING. |
106 |
|
107 |
This has the result of adjusting the number of outstanding requests so that |
108 |
the recv queue is between the minimum and maximu, usually. |
109 |
|
110 |
This algorithm works reasonably well as long as the responses, response |
111 |
latencies and processing times are the same size per packet on average. |
112 |
|
113 |
=back |
114 |
|
115 |
=head1 COMPATIBILITY |
116 |
|
117 |
This module may be used as a drop in replacement for the |
118 |
Net::SNMP::Dispatcher in existing programs. You can still call |
119 |
C<snmp_dispatcher> to start the event-loop, but then you loose the benefit |
120 |
of mixing Net::SNMP events with other events. |
121 |
|
122 |
use AnyEvent::SNMP; |
123 |
use Net::SNMP; |
124 |
|
125 |
# just use Net::SNMP as before |
126 |
|
127 |
# ... start non-blocking snmp request(s)... |
128 |
Net::SNMP->session ( |
129 |
-hostname => "127.0.0.1", |
130 |
-community => "public", |
131 |
-nonblocking => 1, |
132 |
)->get_request (-callback => sub { ... }); |
133 |
|
134 |
snmp_dispatcher; |
135 |
|
136 |
=cut |
137 |
|
138 |
package AnyEvent::SNMP; |
139 |
|
140 |
use common::sense; |
141 |
|
142 |
# it is possible to do this without loading |
143 |
# Net::SNMP::Dispatcher, but much more awkward. |
144 |
use Net::SNMP::Dispatcher; |
145 |
|
146 |
sub Net::SNMP::Dispatcher::instance { |
147 |
AnyEvent::SNMP:: |
148 |
} |
149 |
|
150 |
use Net::SNMP (); |
151 |
use AnyEvent (); |
152 |
|
153 |
our $VERSION = '1.0'; |
154 |
|
155 |
$Net::SNMP::DISPATCHER = instance Net::SNMP::Dispatcher; |
156 |
|
157 |
our $MESSAGE_PROCESSING = $Net::SNMP::Dispatcher::MESSAGE_PROCESSING; |
158 |
|
159 |
our $BUSY; |
160 |
our $DONE; # finished all jobs |
161 |
our @TRANSPORT; # fileno => [count, watcher] |
162 |
our @QUEUE; |
163 |
our $MAX_OUTSTANDING = 50; |
164 |
our $MIN_RECVQUEUE = 8; |
165 |
our $MAX_RECVQUEUE = 64; |
166 |
|
167 |
sub kick_job; |
168 |
|
169 |
sub _send_pdu { |
170 |
my ($pdu, $retries) = @_; |
171 |
|
172 |
# mostly copied from Net::SNMP::Dispatch |
173 |
|
174 |
# Pass the PDU to Message Processing so that it can |
175 |
# create the new outgoing message. |
176 |
my $msg = $MESSAGE_PROCESSING->prepare_outgoing_msg ($pdu); |
177 |
|
178 |
if (!defined $msg) { |
179 |
--$BUSY; |
180 |
kick_job; |
181 |
# Inform the command generator about the Message Processing error. |
182 |
$pdu->status_information ($MESSAGE_PROCESSING->error); |
183 |
return; |
184 |
} |
185 |
|
186 |
# Actually send the message. |
187 |
if (!defined $msg->send) { |
188 |
$MESSAGE_PROCESSING->msg_handle_delete ($pdu->msg_id) |
189 |
if $pdu->expect_response; |
190 |
|
191 |
# A crude attempt to recover from temporary failures. |
192 |
if ($retries-- > 0 && ($!{EAGAIN} || $!{EWOULDBLOCK} || $!{ENOSPC})) { |
193 |
my $retry_w; $retry_w = AE::timer $pdu->timeout, 0, sub { |
194 |
undef $retry_w; |
195 |
_send_pdu ($pdu, $retries); |
196 |
}; |
197 |
} else { |
198 |
--$BUSY; |
199 |
kick_job; |
200 |
} |
201 |
|
202 |
# Inform the command generator about the send() error. |
203 |
$pdu->status_information ($msg->error); |
204 |
return; |
205 |
} |
206 |
|
207 |
# Schedule the timeout handler if the message expects a response. |
208 |
if ($pdu->expect_response) { |
209 |
my $transport = $msg->transport; |
210 |
my $fileno = $transport->fileno; |
211 |
|
212 |
# register the transport |
213 |
unless ($TRANSPORT[$fileno][0]++) { |
214 |
$TRANSPORT[$fileno][1] = AE::io $transport->socket, 0, sub { |
215 |
for my $count (1..$MAX_RECVQUEUE) { # handle up to this many requests in one go |
216 |
# Create a new Message object to receive the response |
217 |
my ($msg, $error) = Net::SNMP::Message->new (-transport => $transport); |
218 |
|
219 |
if (!defined $msg) { |
220 |
die sprintf 'Failed to create Message object [%s]', $error; |
221 |
} |
222 |
|
223 |
# Read the message from the Transport Layer |
224 |
if (!defined $msg->recv) { |
225 |
if ($transport->connectionless) { |
226 |
# if we handled very few replies and we have queued work, try |
227 |
# to increase the parallelity as we probably can handle more. |
228 |
if ($count < $MIN_RECVQUEUE && @QUEUE) { |
229 |
++$MAX_OUTSTANDING; |
230 |
kick_job; |
231 |
} |
232 |
} else { |
233 |
# for some reason, connected-oriented transports seem to need this |
234 |
delete $TRANSPORT[$fileno] |
235 |
unless --$TRANSPORT[$fileno][0]; |
236 |
} |
237 |
|
238 |
$msg->error; |
239 |
return; |
240 |
} |
241 |
|
242 |
# For connection-oriented Transport Domains, it is possible to |
243 |
# "recv" an empty buffer if reassembly is required. |
244 |
if (!$msg->length) { |
245 |
return; |
246 |
} |
247 |
|
248 |
# Hand the message over to Message Processing. |
249 |
if (!defined $MESSAGE_PROCESSING->prepare_data_elements ($msg)) { |
250 |
$MESSAGE_PROCESSING->error; |
251 |
return; |
252 |
} |
253 |
|
254 |
# Set the error if applicable. |
255 |
$msg->error ($MESSAGE_PROCESSING->error) if $MESSAGE_PROCESSING->error; |
256 |
|
257 |
# Notify the command generator to process the response. |
258 |
$msg->process_response_pdu; |
259 |
|
260 |
# Cancel the timeout. |
261 |
my $rtimeout_w = $msg->timeout_id; |
262 |
if ($$rtimeout_w) { |
263 |
undef $$rtimeout_w; |
264 |
|
265 |
--$BUSY; |
266 |
kick_job; |
267 |
|
268 |
unless (--$TRANSPORT[$fileno][0]) { |
269 |
delete $TRANSPORT[$fileno]; |
270 |
return; |
271 |
} |
272 |
} |
273 |
} |
274 |
|
275 |
# when we end up here, we successfully handled $MAX_RECVQUEUE |
276 |
# replies in one iteration, so assume we are overloaded |
277 |
# and reduce the amount of parallelity. |
278 |
$MAX_OUTSTANDING = (int $MAX_OUTSTANDING * 0.95) || 1; |
279 |
}; |
280 |
} |
281 |
|
282 |
$msg->timeout_id (\(my $rtimeout_w = |
283 |
AE::timer $pdu->timeout, 0, sub { |
284 |
my $rtimeout_w = $msg->timeout_id; |
285 |
if ($$rtimeout_w) { |
286 |
undef $$rtimeout_w; |
287 |
delete $TRANSPORT[$fileno] |
288 |
unless --$TRANSPORT[$fileno][0]; |
289 |
} |
290 |
|
291 |
if ($retries--) { |
292 |
_send_pdu ($pdu, $retries); |
293 |
} else { |
294 |
$MESSAGE_PROCESSING->msg_handle_delete ($pdu->msg_id); |
295 |
$pdu->status_information ("No response from remote host '%s'", $pdu->hostname); |
296 |
|
297 |
--$BUSY; |
298 |
kick_job; |
299 |
} |
300 |
}) |
301 |
); |
302 |
} else { |
303 |
--$BUSY; |
304 |
kick_job; |
305 |
} |
306 |
} |
307 |
|
308 |
sub kick_job { |
309 |
while ($BUSY < $MAX_OUTSTANDING) { |
310 |
my $pdu = shift @QUEUE |
311 |
or last; |
312 |
|
313 |
++$BUSY; |
314 |
_send_pdu $pdu, $pdu->retries; |
315 |
} |
316 |
|
317 |
$DONE and $DONE->() unless $BUSY; |
318 |
} |
319 |
|
320 |
sub send_pdu($$$) { |
321 |
my (undef, $pdu, $delay) = @_; |
322 |
|
323 |
# $delay is not very sensibly implemented by AnyEvent::SNMP, |
324 |
# but apparently it is not a very sensible feature. |
325 |
if ($delay > 0) { |
326 |
++$BUSY; |
327 |
my $delay_w; $delay_w = AE::timer $delay, 0, sub { |
328 |
undef $delay_w; |
329 |
push @QUEUE, $pdu; |
330 |
--$BUSY; |
331 |
kick_job; |
332 |
}; |
333 |
return 1; |
334 |
} |
335 |
|
336 |
push @QUEUE, $pdu; |
337 |
kick_job; |
338 |
|
339 |
1 |
340 |
} |
341 |
|
342 |
sub activate($) { |
343 |
while ($BUSY) { |
344 |
$DONE = AE::cv; |
345 |
$DONE->recv; |
346 |
undef $DONE; |
347 |
} |
348 |
} |
349 |
|
350 |
sub one_event($) { |
351 |
# should not ever be used |
352 |
AnyEvent->one_event; #d# todo |
353 |
} |
354 |
|
355 |
sub set_max_outstanding($) { |
356 |
$MAX_OUTSTANDING = $_[0]; |
357 |
kick_job; |
358 |
} |
359 |
|
360 |
=head1 SEE ALSO |
361 |
|
362 |
L<AnyEvent>, L<Net::SNMP>, L<Net::SNMP::XS>, L<Net::SNMP::EV>. |
363 |
|
364 |
=head1 AUTHOR |
365 |
|
366 |
Marc Lehmann <schmorp@schmorp.de> |
367 |
http://home.schmorp.de/ |
368 |
|
369 |
=cut |
370 |
|
371 |
1 |
372 |
|