AnyEvent-SNMP/SNMP.pm

=head1 NAME

AnyEvent::SNMP - adaptor to integrate Net::SNMP into AnyEvent.

=head1 SYNOPSIS

 use AnyEvent::SNMP;
 use Net::SNMP;

 # just use Net::SNMP and AnyEvent as you like:

 # use a condvar to transfer results, this is
 # just an example, you can use a naked callback as well.
 my $cv = AnyEvent->condvar;

 # ... start non-blocking snmp request(s)...
 Net::SNMP->session (-hostname => "127.0.0.1",
                     -community => "public",
                     -nonblocking => 1)
          ->get_request (-callback => sub { $cv->send (@_) });

 # ... do something else until the result is required
 my @result = $cv->wait;

=head1 DESCRIPTION

This module implements an alternative "event dispatcher" for Net::SNMP,
using AnyEvent as a backend. This integrates Net::SNMP into AnyEvent. That
means you can make non-blocking Net::SNMP calls and as long as other
parts of your program also use AnyEvent (or some event loop supported by
AnyEvent), they will run in parallel.

Also, the Net::SNMP scheduler is very inefficient with respect to both CPU
and memory usage. Most AnyEvent backends (including the pure-perl backend)
fare much better than the Net::SNMP dispatcher.

Another major added fetaure of this module over Net::SNMP is automatic
rate-adjustments:  Net::SNMP is so slow that firing a few thousand
requests can cause many timeouts simply because Net::SNMP cannot process
the replies in time. This module automatically adapts the send rate to
avoid false timeouts caused by slow reply processing.

A potential disadvantage of this module is that replacing the dispatcher
is not at all a documented thing to do, so future changes in Net::SNP
might break this module (or the many similar ones).

This module does not export anything and does not require you to do
anything special apart from loading it I<before doing any non-blocking
requests with Net::SNMP>. It is recommended but not required to load this
module before C<Net::SNMP>.

=head1 GLOBAL VARIABLES

=over 4

=item $AnyEvent::SNMP::MAX_OUTSTANDING (default: C<50>, dynamic)

=item AnyEvent::SNMP::set_max_outstanding $new_value

Use this package variable to restrict the number of outstanding SNMP
requests at any point in time.

Net::SNMP is very fast at creating and sending SNMP requests, but much
slower at parsing (big, bulk) responses. This makes it easy to request a
lot of data that can take many seconds to parse.

In the best case, this can lead to unnecessary delays (and even time-outs,
as the data has been received but not yet processed) and in the worst
case, this can lead to packet loss, when the receive queue overflows and
the kernel can no longer accept new packets.

To avoid this, you can (and should) limit the number of outstanding
requests to a number low enough so that parsing time doesn't introduce
noticable delays.

Unfortunately, this number depends not only on processing speed and load
of the machine running Net::SNMP, but also on the network latency and the
speed of your SNMP agents.

AnyEvent::SNMP tries to dynamically adjust this number upwards and
downwards.

Increasing C<$MAX_OUTSTANDING> will not automatically use the
extra request slots. To increase C<$MAX_OUTSTANDING> and make
C<AnyEvent::SNMP> make use of the extra paralellity, call
C<AnyEvent::SNMP::set_max_outstanding> with the new value, e.g.:

   AnyEvent::SNMP::set_max_outstanding 500;

Although due to the dynamic adjustment, this might have little lasting
effect.

Note that you can use L<Net::SNMP::XS> to speed up parsing of responses
considerably.

=item $AnyEvent::SNMP::MIN_RECVQUEUE (default: C<8>)

=item $AnyEvent::SNMP::MAX_RECVQUEUE (default: C<64>)

These values specify the minimum and maximum receive queue length (in
units of one response packet).

When AnyEvent::SNMP handles $MAX_RECVQUEUE or more packets per iteration
it will reduce $MAX_OUTSTANDING. If it handles less than $MIN_RECVQUEUE,
it increases $MAX_OUTSTANDING.

This has the result of adjusting the number of outstanding requests so that
the recv queue is between the minimum and maximu, usually.

This algorithm works reasonably well as long as the responses, response
latencies and processing times are the same size per packet on average.

=back

=head1 COMPATIBILITY

This module may be used as a drop in replacement for the
Net::SNMP::Dispatcher in existing programs. You can still call
C<snmp_dispatcher> to start the event-loop, but then you loose the benefit
of mixing Net::SNMP events with other events.

   use AnyEvent::SNMP;
   use Net::SNMP;

   # just use Net::SNMP as before

   # ... start non-blocking snmp request(s)...
   Net::SNMP->session (
         -hostname    => "127.0.0.1",
         -community   => "public",
         -nonblocking => 1,
      )->get_request (-callback => sub { ... });

   snmp_dispatcher;

=cut

package AnyEvent::SNMP;

use common::sense;

# it is possible to do this without loading
# Net::SNMP::Dispatcher, but much more awkward.
use Net::SNMP::Dispatcher;

sub Net::SNMP::Dispatcher::instance {
   AnyEvent::SNMP::
}

use Net::SNMP ();
use AnyEvent ();

our $VERSION = '1.0';

$Net::SNMP::DISPATCHER = instance Net::SNMP::Dispatcher;

our $MESSAGE_PROCESSING = $Net::SNMP::Dispatcher::MESSAGE_PROCESSING;

our $BUSY;
our $DONE; # finished all jobs
our @TRANSPORT; # fileno => [count, watcher]
our @QUEUE;
our $MAX_OUTSTANDING = 50;
our $MIN_RECVQUEUE   =  8;
our $MAX_RECVQUEUE   = 64;

sub kick_job;

sub _send_pdu {
   my ($pdu, $retries) = @_;

   # mostly copied from Net::SNMP::Dispatch

   # Pass the PDU to Message Processing so that it can
   # create the new outgoing message.
   my $msg = $MESSAGE_PROCESSING->prepare_outgoing_msg ($pdu);

   if (!defined $msg) {
      --$BUSY;
      kick_job;
      # Inform the command generator about the Message Processing error.
      $pdu->status_information ($MESSAGE_PROCESSING->error);
      return; 
   }

   # Actually send the message.
   if (!defined $msg->send) {
      $MESSAGE_PROCESSING->msg_handle_delete ($pdu->msg_id)
         if $pdu->expect_response;

      # A crude attempt to recover from temporary failures.
      if ($retries-- > 0 && ($!{EAGAIN} || $!{EWOULDBLOCK} || $!{ENOSPC})) {
         my $retry_w; $retry_w = AE::timer $pdu->timeout, 0, sub {
            undef $retry_w;
            _send_pdu ($pdu, $retries);
         };
      } else {
         --$BUSY;
         kick_job;
      }

      # Inform the command generator about the send() error.
      $pdu->status_information ($msg->error);
      return;
   }

   # Schedule the timeout handler if the message expects a response.
   if ($pdu->expect_response) {
      my $transport = $msg->transport;
      my $fileno    = $transport->fileno;

      # register the transport
      unless ($TRANSPORT[$fileno][0]++) {
         $TRANSPORT[$fileno][1] = AE::io $transport->socket, 0, sub {
            for my $count (1..$MAX_RECVQUEUE) { # handle up to this many requests in one go
               # Create a new Message object to receive the response
               my ($msg, $error) = Net::SNMP::Message->new (-transport => $transport);

               if (!defined $msg) {
                  die sprintf 'Failed to create Message object [%s]', $error;
               }

               # Read the message from the Transport Layer
               if (!defined $msg->recv) {
                  if ($transport->connectionless) {
                     # if we handled very few replies and we have queued work, try
                     # to increase the parallelity as we probably can handle more.
                     if ($count < $MIN_RECVQUEUE && @QUEUE) {
                        ++$MAX_OUTSTANDING;
                        kick_job;
                     }
                  } else {
                     # for some reason, connected-oriented transports seem to need this
                     delete $TRANSPORT[$fileno]
                        unless --$TRANSPORT[$fileno][0];
                  }

                  $msg->error;
                  return;
               }

               # For connection-oriented Transport Domains, it is possible to
               # "recv" an empty buffer if reassembly is required.
               if (!$msg->length) {
                  return;
               }

               # Hand the message over to Message Processing.
               if (!defined $MESSAGE_PROCESSING->prepare_data_elements ($msg)) {
                  $MESSAGE_PROCESSING->error;
                  return;
               }

               # Set the error if applicable.
               $msg->error ($MESSAGE_PROCESSING->error) if $MESSAGE_PROCESSING->error;

               # Notify the command generator to process the response.
               $msg->process_response_pdu; 

               # Cancel the timeout.
               my $rtimeout_w = $msg->timeout_id;
               if ($$rtimeout_w) {
                  undef $$rtimeout_w;

                  --$BUSY;
                  kick_job;

                  unless (--$TRANSPORT[$fileno][0]) {
                     delete $TRANSPORT[$fileno];
                     return;
                  }
               }
            }

            # when we end up here, we successfully handled $MAX_RECVQUEUE
            # replies in one iteration, so assume we are overloaded
            # and reduce the amount of parallelity.
            $MAX_OUTSTANDING = (int $MAX_OUTSTANDING * 0.95) || 1;
         };
      }

      $msg->timeout_id (\(my $rtimeout_w =
         AE::timer $pdu->timeout, 0, sub {
            my $rtimeout_w = $msg->timeout_id;
            if ($$rtimeout_w) {
               undef $$rtimeout_w;
               delete $TRANSPORT[$fileno]
                  unless --$TRANSPORT[$fileno][0];
            }

            if ($retries--) {
               _send_pdu ($pdu, $retries);
            } else {
               $MESSAGE_PROCESSING->msg_handle_delete ($pdu->msg_id);
               $pdu->status_information ("No response from remote host '%s'", $pdu->hostname);

               --$BUSY;
               kick_job;
            }
         })
      ); 
   } else {
     --$BUSY;
     kick_job;
   }
}

sub kick_job {
   while ($BUSY < $MAX_OUTSTANDING) {
      my $pdu = shift @QUEUE
         or last;

      ++$BUSY;
      _send_pdu $pdu, $pdu->retries;
   }

   $DONE and $DONE->() unless $BUSY;
}

sub send_pdu($$$) {
   my (undef, $pdu, $delay) = @_;

   # $delay is not very sensibly implemented by AnyEvent::SNMP,
   # but apparently it is not a very sensible feature.
   if ($delay > 0) {
      ++$BUSY;
      my $delay_w; $delay_w = AE::timer $delay, 0, sub {
         undef $delay_w;
         push @QUEUE, $pdu;
         --$BUSY;
         kick_job;
      };
      return 1;
   }

   push @QUEUE, $pdu;
   kick_job;

   1
}

sub activate($) {
   while ($BUSY) {
      $DONE = AE::cv;
      $DONE->recv;
      undef $DONE;
   }
}

sub one_event($) {
   # should not ever be used
   AnyEvent->one_event; #d# todo
}

sub set_max_outstanding($) {
   $MAX_OUTSTANDING = $_[0];
   kick_job;
}

=head1 SEE ALSO

L<AnyEvent>, L<Net::SNMP>, L<Net::SNMP::XS>, L<Net::SNMP::EV>.

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

1

Revision:	1.11
Committed:	Sun Oct 31 18:26:27 2010 UTC (13 years, 7 months ago) by root
Branch:	MAIN
Changes since 1.10:	+3 -4 lines
Log Message:	* empty log message *
#	Content
1	=head1 NAME
2
3	AnyEvent::SNMP - adaptor to integrate Net::SNMP into AnyEvent.
4
5	=head1 SYNOPSIS
6
7	use AnyEvent::SNMP;
8	use Net::SNMP;
9
10	# just use Net::SNMP and AnyEvent as you like:
11
12	# use a condvar to transfer results, this is
13	# just an example, you can use a naked callback as well.
14	my $cv = AnyEvent->condvar;
15
16	# ... start non-blocking snmp request(s)...
17	Net::SNMP->session (-hostname => "127.0.0.1",
18	-community => "public",
19	-nonblocking => 1)
20	->get_request (-callback => sub { $cv->send (@_) });
21
22	# ... do something else until the result is required
23	my @result = $cv->wait;
24
25	=head1 DESCRIPTION
26
27	This module implements an alternative "event dispatcher" for Net::SNMP,
28	using AnyEvent as a backend. This integrates Net::SNMP into AnyEvent. That
29	means you can make non-blocking Net::SNMP calls and as long as other
30	parts of your program also use AnyEvent (or some event loop supported by
31	AnyEvent), they will run in parallel.
32
33	Also, the Net::SNMP scheduler is very inefficient with respect to both CPU
34	and memory usage. Most AnyEvent backends (including the pure-perl backend)
35	fare much better than the Net::SNMP dispatcher.
36
37	Another major added fetaure of this module over Net::SNMP is automatic
38	rate-adjustments: Net::SNMP is so slow that firing a few thousand
39	requests can cause many timeouts simply because Net::SNMP cannot process
40	the replies in time. This module automatically adapts the send rate to
41	avoid false timeouts caused by slow reply processing.
42
43	A potential disadvantage of this module is that replacing the dispatcher
44	is not at all a documented thing to do, so future changes in Net::SNP
45	might break this module (or the many similar ones).
46
47	This module does not export anything and does not require you to do
48	anything special apart from loading it I<before doing any non-blocking
49	requests with Net::SNMP>. It is recommended but not required to load this
50	module before C<Net::SNMP>.
51
52	=head1 GLOBAL VARIABLES
53
54	=over 4
55
56	=item $AnyEvent::SNMP::MAX_OUTSTANDING (default: C<50>, dynamic)
57
58	=item AnyEvent::SNMP::set_max_outstanding $new_value
59
60	Use this package variable to restrict the number of outstanding SNMP
61	requests at any point in time.
62
63	Net::SNMP is very fast at creating and sending SNMP requests, but much
64	slower at parsing (big, bulk) responses. This makes it easy to request a
65	lot of data that can take many seconds to parse.
66
67	In the best case, this can lead to unnecessary delays (and even time-outs,
68	as the data has been received but not yet processed) and in the worst
69	case, this can lead to packet loss, when the receive queue overflows and
70	the kernel can no longer accept new packets.
71
72	To avoid this, you can (and should) limit the number of outstanding
73	requests to a number low enough so that parsing time doesn't introduce
74	noticable delays.
75
76	Unfortunately, this number depends not only on processing speed and load
77	of the machine running Net::SNMP, but also on the network latency and the
78	speed of your SNMP agents.
79
80	AnyEvent::SNMP tries to dynamically adjust this number upwards and
81	downwards.
82
83	Increasing C<$MAX_OUTSTANDING> will not automatically use the
84	extra request slots. To increase C<$MAX_OUTSTANDING> and make
85	C<AnyEvent::SNMP> make use of the extra paralellity, call
86	C<AnyEvent::SNMP::set_max_outstanding> with the new value, e.g.:
87
88	AnyEvent::SNMP::set_max_outstanding 500;
89
90	Although due to the dynamic adjustment, this might have little lasting
91	effect.
92
93	Note that you can use L<Net::SNMP::XS> to speed up parsing of responses
94	considerably.
95
96	=item $AnyEvent::SNMP::MIN_RECVQUEUE (default: C<8>)
97
98	=item $AnyEvent::SNMP::MAX_RECVQUEUE (default: C<64>)
99
100	These values specify the minimum and maximum receive queue length (in
101	units of one response packet).
102
103	When AnyEvent::SNMP handles $MAX_RECVQUEUE or more packets per iteration
104	it will reduce $MAX_OUTSTANDING. If it handles less than $MIN_RECVQUEUE,
105	it increases $MAX_OUTSTANDING.
106
107	This has the result of adjusting the number of outstanding requests so that
108	the recv queue is between the minimum and maximu, usually.
109
110	This algorithm works reasonably well as long as the responses, response
111	latencies and processing times are the same size per packet on average.
112
113	=back
114
115	=head1 COMPATIBILITY
116
117	This module may be used as a drop in replacement for the
118	Net::SNMP::Dispatcher in existing programs. You can still call
119	C<snmp_dispatcher> to start the event-loop, but then you loose the benefit
120	of mixing Net::SNMP events with other events.
121
122	use AnyEvent::SNMP;
123	use Net::SNMP;
124
125	# just use Net::SNMP as before
126
127	# ... start non-blocking snmp request(s)...
128	Net::SNMP->session (
129	-hostname => "127.0.0.1",
130	-community => "public",
131	-nonblocking => 1,
132	)->get_request (-callback => sub { ... });
133
134	snmp_dispatcher;
135
136	=cut
137
138	package AnyEvent::SNMP;
139
140	use common::sense;
141
142	# it is possible to do this without loading
143	# Net::SNMP::Dispatcher, but much more awkward.
144	use Net::SNMP::Dispatcher;
145
146	sub Net::SNMP::Dispatcher::instance {
147	AnyEvent::SNMP::
148	}
149
150	use Net::SNMP ();
151	use AnyEvent ();
152
153	our $VERSION = '1.0';
154
155	$Net::SNMP::DISPATCHER = instance Net::SNMP::Dispatcher;
156
157	our $MESSAGE_PROCESSING = $Net::SNMP::Dispatcher::MESSAGE_PROCESSING;
158
159	our $BUSY;
160	our $DONE; # finished all jobs
161	our @TRANSPORT; # fileno => [count, watcher]
162	our @QUEUE;
163	our $MAX_OUTSTANDING = 50;
164	our $MIN_RECVQUEUE = 8;
165	our $MAX_RECVQUEUE = 64;
166
167	sub kick_job;
168
169	sub _send_pdu {
170	my ($pdu, $retries) = @_;
171
172	# mostly copied from Net::SNMP::Dispatch
173
174	# Pass the PDU to Message Processing so that it can
175	# create the new outgoing message.
176	my $msg = $MESSAGE_PROCESSING->prepare_outgoing_msg ($pdu);
177
178	if (!defined $msg) {
179	--$BUSY;
180	kick_job;
181	# Inform the command generator about the Message Processing error.
182	$pdu->status_information ($MESSAGE_PROCESSING->error);
183	return;
184	}
185
186	# Actually send the message.
187	if (!defined $msg->send) {
188	$MESSAGE_PROCESSING->msg_handle_delete ($pdu->msg_id)
189	if $pdu->expect_response;
190
191	# A crude attempt to recover from temporary failures.
192	if ($retries-- > 0 && ($!{EAGAIN} \|\| $!{EWOULDBLOCK} \|\| $!{ENOSPC})) {
193	my $retry_w; $retry_w = AE::timer $pdu->timeout, 0, sub {
194	undef $retry_w;
195	_send_pdu ($pdu, $retries);
196	};
197	} else {
198	--$BUSY;
199	kick_job;
200	}
201
202	# Inform the command generator about the send() error.
203	$pdu->status_information ($msg->error);
204	return;
205	}
206
207	# Schedule the timeout handler if the message expects a response.
208	if ($pdu->expect_response) {
209	my $transport = $msg->transport;
210	my $fileno = $transport->fileno;
211
212	# register the transport
213	unless ($TRANSPORT[$fileno][0]++) {
214	$TRANSPORT[$fileno][1] = AE::io $transport->socket, 0, sub {
215	for my $count (1..$MAX_RECVQUEUE) { # handle up to this many requests in one go
216	# Create a new Message object to receive the response
217	my ($msg, $error) = Net::SNMP::Message->new (-transport => $transport);
218
219	if (!defined $msg) {
220	die sprintf 'Failed to create Message object [%s]', $error;
221	}
222
223	# Read the message from the Transport Layer
224	if (!defined $msg->recv) {
225	if ($transport->connectionless) {
226	# if we handled very few replies and we have queued work, try
227	# to increase the parallelity as we probably can handle more.
228	if ($count < $MIN_RECVQUEUE && @QUEUE) {
229	++$MAX_OUTSTANDING;
230	kick_job;
231	}
232	} else {
233	# for some reason, connected-oriented transports seem to need this
234	delete $TRANSPORT[$fileno]
235	unless --$TRANSPORT[$fileno][0];
236	}
237
238	$msg->error;
239	return;
240	}
241
242	# For connection-oriented Transport Domains, it is possible to
243	# "recv" an empty buffer if reassembly is required.
244	if (!$msg->length) {
245	return;
246	}
247
248	# Hand the message over to Message Processing.
249	if (!defined $MESSAGE_PROCESSING->prepare_data_elements ($msg)) {
250	$MESSAGE_PROCESSING->error;
251	return;
252	}
253
254	# Set the error if applicable.
255	$msg->error ($MESSAGE_PROCESSING->error) if $MESSAGE_PROCESSING->error;
256
257	# Notify the command generator to process the response.
258	$msg->process_response_pdu;
259
260	# Cancel the timeout.
261	my $rtimeout_w = $msg->timeout_id;
262	if ($$rtimeout_w) {
263	undef $$rtimeout_w;
264
265	--$BUSY;
266	kick_job;
267
268	unless (--$TRANSPORT[$fileno][0]) {
269	delete $TRANSPORT[$fileno];
270	return;
271	}
272	}
273	}
274
275	# when we end up here, we successfully handled $MAX_RECVQUEUE
276	# replies in one iteration, so assume we are overloaded
277	# and reduce the amount of parallelity.
278	$MAX_OUTSTANDING = (int $MAX_OUTSTANDING * 0.95) \|\| 1;
279	};
280	}
281
282	$msg->timeout_id (\(my $rtimeout_w =
283	AE::timer $pdu->timeout, 0, sub {
284	my $rtimeout_w = $msg->timeout_id;
285	if ($$rtimeout_w) {
286	undef $$rtimeout_w;
287	delete $TRANSPORT[$fileno]
288	unless --$TRANSPORT[$fileno][0];
289	}
290
291	if ($retries--) {
292	_send_pdu ($pdu, $retries);
293	} else {
294	$MESSAGE_PROCESSING->msg_handle_delete ($pdu->msg_id);
295	$pdu->status_information ("No response from remote host '%s'", $pdu->hostname);
296
297	--$BUSY;
298	kick_job;
299	}
300	})
301	);
302	} else {
303	--$BUSY;
304	kick_job;
305	}
306	}
307
308	sub kick_job {
309	while ($BUSY < $MAX_OUTSTANDING) {
310	my $pdu = shift @QUEUE
311	or last;
312
313	++$BUSY;
314	_send_pdu $pdu, $pdu->retries;
315	}
316
317	$DONE and $DONE->() unless $BUSY;
318	}
319
320	sub send_pdu($$$) {
321	my (undef, $pdu, $delay) = @_;
322
323	# $delay is not very sensibly implemented by AnyEvent::SNMP,
324	# but apparently it is not a very sensible feature.
325	if ($delay > 0) {
326	++$BUSY;
327	my $delay_w; $delay_w = AE::timer $delay, 0, sub {
328	undef $delay_w;
329	push @QUEUE, $pdu;
330	--$BUSY;
331	kick_job;
332	};
333	return 1;
334	}
335
336	push @QUEUE, $pdu;
337	kick_job;
338
339	1
340	}
341
342	sub activate($) {
343	while ($BUSY) {
344	$DONE = AE::cv;
345	$DONE->recv;
346	undef $DONE;
347	}
348	}
349
350	sub one_event($) {
351	# should not ever be used
352	AnyEvent->one_event; #d# todo
353	}
354
355	sub set_max_outstanding($) {
356	$MAX_OUTSTANDING = $_[0];
357	kick_job;
358	}
359
360	=head1 SEE ALSO
361
362	L<AnyEvent>, L<Net::SNMP>, L<Net::SNMP::XS>, L<Net::SNMP::EV>.
363
364	=head1 AUTHOR
365
366	Marc Lehmann <schmorp@schmorp.de>
367	http://home.schmorp.de/
368
369	=cut
370
371	1
372