AnyEvent/lib/AnyEvent.pm

=head1 NAME

AnyEvent - provide framework for multiple event loops

Event, Coro, Glib, Tk, Perl - various supported event loops

=head1 SYNOPSIS

   use AnyEvent;

   my $w = AnyEvent->io (fh => $fh, poll => "r|w", cb => sub {
      ...
   });

   my $w = AnyEvent->timer (after => $seconds, cb => sub {
      ...
   });

   my $w = AnyEvent->condvar; # stores wether a condition was flagged
   $w->wait; # enters "main loop" till $condvar gets ->broadcast
   $w->broadcast; # wake up current and all future wait's

=head1 DESCRIPTION

L<AnyEvent> provides an identical interface to multiple event loops. This
allows module authors to utilise an event loop without forcing module
users to use the same event loop (as only a single event loop can coexist
peacefully at any one time).

The interface itself is vaguely similar but not identical to the Event
module.

On the first call of any method, the module tries to detect the currently
loaded event loop by probing wether any of the following modules is
loaded: L<Coro::Event>, L<Event>, L<Glib>, L<Tk>. The first one found is
used. If none is found, the module tries to load these modules in the
order given. The first one that could be successfully loaded will be
used. If still none could be found, AnyEvent will fall back to a pure-perl
event loop, which is also not very efficient.

Because AnyEvent first checks for modules that are already loaded, loading
an Event model explicitly before first using AnyEvent will likely make
that model the default. For example:

   use Tk;
   use AnyEvent;

   # .. AnyEvent will likely default to Tk

The pure-perl implementation of AnyEvent is called
C<AnyEvent::Impl::Perl>. Like other event modules you can load it
explicitly.

=head1 WATCHERS

AnyEvent has the central concept of a I<watcher>, which is an object that
stores relevant data for each kind of event you are waiting for, such as
the callback to call, the filehandle to watch, etc.

These watchers are normal Perl objects with normal Perl lifetime. After
creating a watcher it will immediately "watch" for events and invoke
the callback. To disable the watcher you have to destroy it (e.g. by
setting the variable that stores it to C<undef> or otherwise deleting all
references to it).

All watchers are created by calling a method on the C<AnyEvent> class.

=head2 IO WATCHERS

You can create I/O watcher by calling the C<< AnyEvent->io >> method with
the following mandatory arguments:

C<fh> the Perl I<filehandle> (not filedescriptor) to watch for
events. C<poll> must be a string that is either C<r> or C<w>, that creates
a watcher waiting for "r"eadable or "w"ritable events. C<cb> teh callback
to invoke everytime the filehandle becomes ready.

Only one io watcher per C<fh> and C<poll> combination is allowed (i.e. on
a socket you can have one r + one w, not any more (limitation comes from
Tk - if you are sure you are not using Tk this limitation is gone).

Filehandles will be kept alive, so as long as the watcher exists, the
filehandle exists, too.

Example:

   # wait for readability of STDIN, then read a line and disable the watcher
   my $w; $w = AnyEvent->io (fh => \*STDIN, poll => 'r', cb => sub {
      chomp (my $input = <STDIN>);
      warn "read: $input\n";
      undef $w;
   });

=head2 TIME WATCHERS

You can create a time watcher by calling the C<< AnyEvent->timer >>
method with the following mandatory arguments:

C<after> after how many seconds (fractions are supported) should the timer
activate. C<cb> the callback to invoke.

The timer callback will be invoked at most once: if you want a repeating
timer you have to create a new watcher (this is a limitation by both Tk
and Glib).

Example:

   # fire an event after 7.7 seconds
   my $w = AnyEvent->timer (after => 7.7, cb => sub {
      warn "timeout\n";
   });

   # to cancel the timer:
   undef $w

=head2 CONDITION WATCHERS

Condition watchers can be created by calling the C<< AnyEvent->condvar >>
method without any arguments.

A condition watcher watches for a condition - precisely that the C<<
->broadcast >> method has been called.

The watcher has only two methods:

=over 4

=item $cv->wait

Wait (blocking if necessary) until the C<< ->broadcast >> method has been
called on c<$cv>, while servicing other watchers normally.

Not all event models support a blocking wait - some die in that case, so
if you are using this from a module, never require a blocking wait, but
let the caller decide wether the call will block or not (for example,
by coupling condition variables with some kind of request results and
supporting callbacks so the caller knows that getting the result will not
block, while still suppporting blockign waits if the caller so desires).

You can only wait once on a condition - additional calls will return
immediately.

=item $cv->broadcast

Flag the condition as ready - a running C<< ->wait >> and all further
calls to C<wait> will return after this method has been called. If nobody
is waiting the broadcast will be remembered..

Example:

   # wait till the result is ready
   my $result_ready = AnyEvent->condvar;

   # do something such as adding a timer
   # or socket watcher the calls $result_ready->broadcast
   # when the "result" is ready.

   $result_ready->wait;

=back

=head2 SIGNAL WATCHERS

You can listen for signals using a signal watcher, C<signal> is the signal
I<name> without any C<SIG> prefix. Multiple signals events can be clumped
together into one callback invocation, and callback invocation might or
might not be asynchronous.

These watchers might use C<%SIG>, so programs overwriting those signals
directly will likely not work correctly.

Example: exit on SIGINT

   my $w = AnyEvent->signal (signal => "INT", cb => sub { exit 1 });

=head2 CHILD PROCESS WATCHERS

You can also listen for the status of a child process specified by the
C<pid> argument. The watcher will only trigger once. This works by
installing a signal handler for C<SIGCHLD>.

Example: wait for pid 1333

  my $w = AnyEvent->child (pid => 1333, cb => sub { warn "exit status $?" });

=head1 GLOBALS

=over 4

=item $AnyEvent::MODEL

Contains C<undef> until the first watcher is being created. Then it
contains the event model that is being used, which is the name of the
Perl class implementing the model. This class is usually one of the
C<AnyEvent::Impl:xxx> modules, but can be any other class in the case
AnyEvent has been extended at runtime (e.g. in I<rxvt-unicode>).

The known classes so far are:

   AnyEvent::Impl::Coro      based on Coro::Event, best choice.
   EV::AnyEvent              based on EV (an interface to libevent)
   AnyEvent::Impl::Event     based on Event, also best choice :)
   AnyEvent::Impl::Glib      based on Glib, second-best choice.
   AnyEvent::Impl::Tk        based on Tk, very bad choice.
   AnyEvent::Impl::Perl      pure-perl implementation, inefficient.

=item AnyEvent::detect

Returns C<$AnyEvent::MODEL>, forcing autodetection of the event model if
necessary. You should only call this function right before you would have
created an AnyEvent watcher anyway, that is, very late at runtime.

=back

=head1 WHAT TO DO IN A MODULE

As a module author, you should "use AnyEvent" and call AnyEvent methods
freely, but you should not load a specific event module or rely on it.

Be careful when you create watchers in the module body - Anyevent will
decide which event module to use as soon as the first method is called, so
by calling AnyEvent in your module body you force the user of your module
to load the event module first.

=head1 WHAT TO DO IN THE MAIN PROGRAM

There will always be a single main program - the only place that should
dictate which event model to use.

If it doesn't care, it can just "use AnyEvent" and use it itself, or not
do anything special and let AnyEvent decide which implementation to chose.

If the main program relies on a specific event model (for example, in Gtk2
programs you have to rely on either Glib or Glib::Event), you should load
it before loading AnyEvent or any module that uses it, generally, as early
as possible. The reason is that modules might create watchers when they
are loaded, and AnyEvent will decide on the event model to use as soon as
it creates watchers, and it might chose the wrong one unless you load the
correct one yourself.

You can chose to use a rather inefficient pure-perl implementation by
loading the C<AnyEvent::Impl::Perl> module, but letting AnyEvent chose is
generally better.

=cut

package AnyEvent;

no warnings;
use strict;

use Carp;

our $VERSION = '2.55';
our $MODEL;

our $AUTOLOAD;
our @ISA;

our $verbose = $ENV{PERL_ANYEVENT_VERBOSE}*1;

our @REGISTRY;

my @models = (
   [Coro::Event::          => AnyEvent::Impl::Coro::],
   [EV::                   => EV::AnyEvent::],
   [Event::                => AnyEvent::Impl::Event::],
   [Glib::                 => AnyEvent::Impl::Glib::],
   [Tk::                   => AnyEvent::Impl::Tk::],
   [AnyEvent::Impl::Perl:: => AnyEvent::Impl::Perl::],
);

our %method = map +($_ => 1), qw(io timer condvar broadcast wait signal one_event DESTROY);

sub detect() {
   unless ($MODEL) {
      no strict 'refs';

      # check for already loaded models
      for (@REGISTRY, @models) {
         my ($package, $model) = @$_;
         if (${"$package\::VERSION"} > 0) {
            if (eval "require $model") {
               $MODEL = $model;
               warn "AnyEvent: found model '$model', using it.\n" if $verbose > 1;
               last;
            }
         }
      }

      unless ($MODEL) {
         # try to load a model

         for (@REGISTRY, @models) {
            my ($package, $model) = @$_;
            if (eval "require $package"
                and ${"$package\::VERSION"} > 0
                and eval "require $model") {
               $MODEL = $model;
               warn "AnyEvent: autoprobed and loaded model '$model', using it.\n" if $verbose > 1;
               last;
            }
         }

         $MODEL
           or die "No event module selected for AnyEvent and autodetect failed. Install any one of these modules: Event (or Coro+Event), Glib or Tk.";
      }

      unshift @ISA, $MODEL;
      push @{"$MODEL\::ISA"}, "AnyEvent::Base";
   }

   $MODEL
}

sub AUTOLOAD {
   (my $func = $AUTOLOAD) =~ s/.*://;

   $method{$func}
      or croak "$func: not a valid method for AnyEvent objects";

   detect unless $MODEL;

   my $class = shift;
   $class->$func (@_);
}

package AnyEvent::Base;

# default implementation for ->condvar, ->wait, ->broadcast

sub condvar {
   bless \my $flag, "AnyEvent::Base::CondVar"
}

sub AnyEvent::Base::CondVar::broadcast {
   ${$_[0]}++;
}

sub AnyEvent::Base::CondVar::wait {
   AnyEvent->one_event while !${$_[0]};
}

# default implementation for ->signal

our %SIG_CB;

sub signal {
   my (undef, %arg) = @_;

   my $signal = uc $arg{signal}
      or Carp::croak "required option 'signal' is missing";

   $SIG_CB{$signal}{$arg{cb}} = $arg{cb};
   $SIG{$signal} ||= sub {
      $_->() for values %{ $SIG_CB{$signal} || {} };
   };

   bless [$signal, $arg{cb}], "AnyEvent::Base::Signal"
}

sub AnyEvent::Base::Signal::DESTROY {
   my ($signal, $cb) = @{$_[0]};

   delete $SIG_CB{$signal}{$cb};

   $SIG{$signal} = 'DEFAULT' unless keys %{ $SIG_CB{$signal} };
}

# default implementation for ->child

our %PID_CB;
our $CHLD_W;
our $PID_IDLE;
our $WNOHANG;

sub _child_wait {
   while (0 < (my $pid = waitpid -1, $WNOHANG)) {
      $_->() for values %{ (delete $PID_CB{$pid}) || {} };
   }

   undef $PID_IDLE;
}

sub child {
   my (undef, %arg) = @_;

   my $pid = uc $arg{pid}
      or Carp::croak "required option 'pid' is missing";

   $PID_CB{$pid}{$arg{cb}} = $arg{cb};

   unless ($WNOHANG) {
      $WNOHANG = eval { require POSIX; &POSIX::WNOHANG } || 1;
   }

   unless ($CHLD_W) {
      $CHLD_W = AnyEvent->signal (signal => 'CHLD', cb => \&_child_wait);
      # child could be a zombie already
      $PID_IDLE ||= AnyEvent->timer (after => 0, cb => \&_child_wait);
   }

   bless [$pid, $arg{cb}], "AnyEvent::Base::Child"
}

sub AnyEvent::Base::Child::DESTROY {
   my ($pid, $cb) = @{$_[0]};

   delete $PID_CB{$pid}{$cb};
   delete $PID_CB{$pid} unless keys %{ $PID_CB{$pid} };

   undef $CHLD_W unless keys %PID_CB;
}

=head1 SUPPLYING YOUR OWN EVENT MODEL INTERFACE

If you need to support another event library which isn't directly
supported by AnyEvent, you can supply your own interface to it by
pushing, before the first watcher gets created, the package name of
the event module and the package name of the interface to use onto
C<@AnyEvent::REGISTRY>. You can do that before and even without loading
AnyEvent.

Example:

   push @AnyEvent::REGISTRY, [urxvt => urxvt::anyevent::];

This tells AnyEvent to (literally) use the C<urxvt::anyevent::>
package/class when it finds the C<urxvt> package/module is loaded. When
AnyEvent is loaded and asked to find a suitable event model, it will
first check for the presence of urxvt.

The class should provide implementations for all watcher types (see
L<AnyEvent::Impl::Event> (source code), L<AnyEvent::Impl::Glib>
(Source code) and so on for actual examples, use C<perldoc -m
AnyEvent::Impl::Glib> to see the sources).

The above isn't fictitious, the I<rxvt-unicode> (a.k.a. urxvt)
uses the above line as-is. An interface isn't included in AnyEvent
because it doesn't make sense outside the embedded interpreter inside
I<rxvt-unicode>, and it is updated and maintained as part of the
I<rxvt-unicode> distribution.

I<rxvt-unicode> also cheats a bit by not providing blocking access to
condition variables: code blocking while waiting for a condition will
C<die>. This still works with most modules/usages, and blocking calls must
not be in an interactive application, so it makes sense.

=head1 ENVIRONMENT VARIABLES

The following environment variables are used by this module:

C<PERL_ANYEVENT_VERBOSE> when set to C<2> or higher, reports which event
model gets used.

=head1 EXAMPLE

The following program uses an io watcher to read data from stdin, a timer
to display a message once per second, and a condvar to exit the program
when the user enters quit:

   use AnyEvent;

   my $cv = AnyEvent->condvar;

   my $io_watcher = AnyEvent->io (fh => \*STDIN, poll => 'r', cb => sub {
      warn "io event <$_[0]>\n";   # will always output <r>
      chomp (my $input = <STDIN>); # read a line
      warn "read: $input\n";       # output what has been read
      $cv->broadcast if $input =~ /^q/i; # quit program if /^q/i
   });

   my $time_watcher; # can only be used once

   sub new_timer {
      $timer = AnyEvent->timer (after => 1, cb => sub {
         warn "timeout\n"; # print 'timeout' about every second
         &new_timer; # and restart the time
      });
   }

   new_timer; # create first timer

   $cv->wait; # wait until user enters /^q/i

=head1 REAL-WORLD EXAMPLE

Consider the L<Net::FCP> module. It features (among others) the following
API calls, which are to freenet what HTTP GET requests are to http:

   my $data = $fcp->client_get ($url); # blocks

   my $transaction = $fcp->txn_client_get ($url); # does not block
   $transaction->cb ( sub { ... } ); # set optional result callback
   my $data = $transaction->result; # possibly blocks

The C<client_get> method works like C<LWP::Simple::get>: it requests the
given URL and waits till the data has arrived. It is defined to be:

   sub client_get { $_[0]->txn_client_get ($_[1])->result }

And in fact is automatically generated. This is the blocking API of
L<Net::FCP>, and it works as simple as in any other, similar, module.

More complicated is C<txn_client_get>: It only creates a transaction
(completion, result, ...) object and initiates the transaction.

   my $txn = bless { }, Net::FCP::Txn::;

It also creates a condition variable that is used to signal the completion
of the request:

   $txn->{finished} = AnyAvent->condvar;

It then creates a socket in non-blocking mode.

   socket $txn->{fh}, ...;
   fcntl $txn->{fh}, F_SETFL, O_NONBLOCK;
   connect $txn->{fh}, ...
      and !$!{EWOULDBLOCK}
      and !$!{EINPROGRESS}
      and Carp::croak "unable to connect: $!\n";

Then it creates a write-watcher which gets called whenever an error occurs
or the connection succeeds:

   $txn->{w} = AnyEvent->io (fh => $txn->{fh}, poll => 'w', cb => sub { $txn->fh_ready_w });

And returns this transaction object. The C<fh_ready_w> callback gets
called as soon as the event loop detects that the socket is ready for
writing.

The C<fh_ready_w> method makes the socket blocking again, writes the
request data and replaces the watcher by a read watcher (waiting for reply
data). The actual code is more complicated, but that doesn't matter for
this example:

   fcntl $txn->{fh}, F_SETFL, 0;
   syswrite $txn->{fh}, $txn->{request}
      or die "connection or write error";
   $txn->{w} = AnyEvent->io (fh => $txn->{fh}, poll => 'r', cb => sub { $txn->fh_ready_r });

Again, C<fh_ready_r> waits till all data has arrived, and then stores the
result and signals any possible waiters that the request ahs finished:

   sysread $txn->{fh}, $txn->{buf}, length $txn->{$buf};

   if (end-of-file or data complete) {
     $txn->{result} = $txn->{buf};
     $txn->{finished}->broadcast;
     $txb->{cb}->($txn) of $txn->{cb}; # also call callback
   }

The C<result> method, finally, just waits for the finished signal (if the
request was already finished, it doesn't wait, of course, and returns the
data:

   $txn->{finished}->wait;
   return $txn->{result};

The actual code goes further and collects all errors (C<die>s, exceptions)
that occured during request processing. The C<result> method detects
wether an exception as thrown (it is stored inside the $txn object)
and just throws the exception, which means connection errors and other
problems get reported tot he code that tries to use the result, not in a
random callback.

All of this enables the following usage styles:

1. Blocking:

   my $data = $fcp->client_get ($url);

2. Blocking, but parallelizing:

   my @datas = map $_->result,
                  map $fcp->txn_client_get ($_),
                     @urls;

Both blocking examples work without the module user having to know
anything about events.

3a. Event-based in a main program, using any support Event module:

   use Event;

   $fcp->txn_client_get ($url)->cb (sub {
      my $txn = shift;
      my $data = $txn->result;
      ...
   });

   Event::loop;

3b. The module user could use AnyEvent, too:

   use AnyEvent;

   my $quit = AnyEvent->condvar;

   $fcp->txn_client_get ($url)->cb (sub {
      ...
      $quit->broadcast;
   });

   $quit->wait;

=head1 SEE ALSO

Event modules: L<Coro::Event>, L<Coro>, L<Event>, L<Glib::Event>, L<Glib>.

Implementations: L<AnyEvent::Impl::Coro>, L<AnyEvent::Impl::Event>, L<AnyEvent::Impl::Glib>, L<AnyEvent::Impl::Tk>.

Nontrivial usage example: L<Net::FCP>.

=head1

=cut

1

Revision:	1.28
Committed:	Sat Oct 27 15:10:09 2007 UTC (16 years, 8 months ago) by root
Branch:	MAIN
Changes since 1.27:	+4 -2 lines
Log Message:	* empty log message *
#	User	Rev	Content
1	root	1.1	=head1 NAME
2
3	root	1.2	AnyEvent - provide framework for multiple event loops
4
5	root	1.14	Event, Coro, Glib, Tk, Perl - various supported event loops
6	root	1.1
7			=head1 SYNOPSIS
8
9	root	1.7	use AnyEvent;
10	root	1.2
11	root	1.14	my $w = AnyEvent->io (fh => $fh, poll => "r\|w", cb => sub {
12	root	1.2	...
13			});
14	root	1.5
15			my $w = AnyEvent->timer (after => $seconds, cb => sub {
16	root	1.2	...
17			});
18
19	root	1.14	my $w = AnyEvent->condvar; # stores wether a condition was flagged
20			$w->wait; # enters "main loop" till $condvar gets ->broadcast
21	root	1.5	$w->broadcast; # wake up current and all future wait's
22
23	root	1.1	=head1 DESCRIPTION
24
25	root	1.2	L<AnyEvent> provides an identical interface to multiple event loops. This
26	root	1.13	allows module authors to utilise an event loop without forcing module
27	root	1.2	users to use the same event loop (as only a single event loop can coexist
28			peacefully at any one time).
29
30			The interface itself is vaguely similar but not identical to the Event
31			module.
32
33			On the first call of any method, the module tries to detect the currently
34			loaded event loop by probing wether any of the following modules is
35			loaded: L<Coro::Event>, L<Event>, L<Glib>, L<Tk>. The first one found is
36			used. If none is found, the module tries to load these modules in the
37			order given. The first one that could be successfully loaded will be
38	root	1.14	used. If still none could be found, AnyEvent will fall back to a pure-perl
39			event loop, which is also not very efficient.
40
41			Because AnyEvent first checks for modules that are already loaded, loading
42			an Event model explicitly before first using AnyEvent will likely make
43			that model the default. For example:
44
45			use Tk;
46			use AnyEvent;
47
48			# .. AnyEvent will likely default to Tk
49
50			The pure-perl implementation of AnyEvent is called
51			C<AnyEvent::Impl::Perl>. Like other event modules you can load it
52			explicitly.
53
54			=head1 WATCHERS
55
56			AnyEvent has the central concept of a I<watcher>, which is an object that
57			stores relevant data for each kind of event you are waiting for, such as
58			the callback to call, the filehandle to watch, etc.
59
60			These watchers are normal Perl objects with normal Perl lifetime. After
61			creating a watcher it will immediately "watch" for events and invoke
62			the callback. To disable the watcher you have to destroy it (e.g. by
63			setting the variable that stores it to C<undef> or otherwise deleting all
64			references to it).
65
66			All watchers are created by calling a method on the C<AnyEvent> class.
67
68			=head2 IO WATCHERS
69
70			You can create I/O watcher by calling the C<< AnyEvent->io >> method with
71			the following mandatory arguments:
72
73			C<fh> the Perl I<filehandle> (not filedescriptor) to watch for
74			events. C<poll> must be a string that is either C<r> or C<w>, that creates
75			a watcher waiting for "r"eadable or "w"ritable events. C<cb> teh callback
76			to invoke everytime the filehandle becomes ready.
77
78			Only one io watcher per C<fh> and C<poll> combination is allowed (i.e. on
79			a socket you can have one r + one w, not any more (limitation comes from
80			Tk - if you are sure you are not using Tk this limitation is gone).
81
82			Filehandles will be kept alive, so as long as the watcher exists, the
83			filehandle exists, too.
84
85			Example:
86
87			# wait for readability of STDIN, then read a line and disable the watcher
88			my $w; $w = AnyEvent->io (fh => \*STDIN, poll => 'r', cb => sub {
89			chomp (my $input = <STDIN>);
90			warn "read: $input\n";
91			undef $w;
92			});
93
94	root	1.19	=head2 TIME WATCHERS
95	root	1.14
96	root	1.19	You can create a time watcher by calling the C<< AnyEvent->timer >>
97	root	1.14	method with the following mandatory arguments:
98
99			C<after> after how many seconds (fractions are supported) should the timer
100			activate. C<cb> the callback to invoke.
101
102			The timer callback will be invoked at most once: if you want a repeating
103			timer you have to create a new watcher (this is a limitation by both Tk
104			and Glib).
105
106			Example:
107
108			# fire an event after 7.7 seconds
109			my $w = AnyEvent->timer (after => 7.7, cb => sub {
110			warn "timeout\n";
111			});
112
113			# to cancel the timer:
114			undef $w
115
116			=head2 CONDITION WATCHERS
117
118			Condition watchers can be created by calling the C<< AnyEvent->condvar >>
119			method without any arguments.
120
121			A condition watcher watches for a condition - precisely that the C<<
122			->broadcast >> method has been called.
123
124			The watcher has only two methods:
125	root	1.2
126	root	1.1	=over 4
127
128	root	1.14	=item $cv->wait
129
130			Wait (blocking if necessary) until the C<< ->broadcast >> method has been
131			called on c<$cv>, while servicing other watchers normally.
132
133			Not all event models support a blocking wait - some die in that case, so
134			if you are using this from a module, never require a blocking wait, but
135			let the caller decide wether the call will block or not (for example,
136			by coupling condition variables with some kind of request results and
137			supporting callbacks so the caller knows that getting the result will not
138			block, while still suppporting blockign waits if the caller so desires).
139
140			You can only wait once on a condition - additional calls will return
141			immediately.
142
143			=item $cv->broadcast
144
145			Flag the condition as ready - a running C<< ->wait >> and all further
146			calls to C<wait> will return after this method has been called. If nobody
147			is waiting the broadcast will be remembered..
148
149			Example:
150
151			# wait till the result is ready
152			my $result_ready = AnyEvent->condvar;
153
154			# do something such as adding a timer
155			# or socket watcher the calls $result_ready->broadcast
156			# when the "result" is ready.
157
158			$result_ready->wait;
159
160			=back
161
162	root	1.19	=head2 SIGNAL WATCHERS
163
164			You can listen for signals using a signal watcher, C<signal> is the signal
165	root	1.20	I<name> without any C<SIG> prefix. Multiple signals events can be clumped
166	root	1.22	together into one callback invocation, and callback invocation might or
167	root	1.20	might not be asynchronous.
168	root	1.19
169			These watchers might use C<%SIG>, so programs overwriting those signals
170			directly will likely not work correctly.
171
172			Example: exit on SIGINT
173
174			my $w = AnyEvent->signal (signal => "INT", cb => sub { exit 1 });
175
176	root	1.20	=head2 CHILD PROCESS WATCHERS
177
178			You can also listen for the status of a child process specified by the
179			C<pid> argument. The watcher will only trigger once. This works by
180			installing a signal handler for C<SIGCHLD>.
181
182			Example: wait for pid 1333
183
184			my $w = AnyEvent->child (pid => 1333, cb => sub { warn "exit status $?" });
185
186	root	1.16	=head1 GLOBALS
187
188			=over 4
189
190			=item $AnyEvent::MODEL
191
192			Contains C<undef> until the first watcher is being created. Then it
193			contains the event model that is being used, which is the name of the
194			Perl class implementing the model. This class is usually one of the
195			C<AnyEvent::Impl:xxx> modules, but can be any other class in the case
196			AnyEvent has been extended at runtime (e.g. in I<rxvt-unicode>).
197
198			The known classes so far are:
199
200	root	1.28	AnyEvent::Impl::Coro based on Coro::Event, best choice.
201			EV::AnyEvent based on EV (an interface to libevent)
202	root	1.16	AnyEvent::Impl::Event based on Event, also best choice :)
203			AnyEvent::Impl::Glib based on Glib, second-best choice.
204			AnyEvent::Impl::Tk based on Tk, very bad choice.
205			AnyEvent::Impl::Perl pure-perl implementation, inefficient.
206
207	root	1.19	=item AnyEvent::detect
208
209			Returns C<$AnyEvent::MODEL>, forcing autodetection of the event model if
210			necessary. You should only call this function right before you would have
211			created an AnyEvent watcher anyway, that is, very late at runtime.
212
213	root	1.16	=back
214
215	root	1.14	=head1 WHAT TO DO IN A MODULE
216
217			As a module author, you should "use AnyEvent" and call AnyEvent methods
218			freely, but you should not load a specific event module or rely on it.
219
220			Be careful when you create watchers in the module body - Anyevent will
221			decide which event module to use as soon as the first method is called, so
222			by calling AnyEvent in your module body you force the user of your module
223			to load the event module first.
224
225			=head1 WHAT TO DO IN THE MAIN PROGRAM
226
227			There will always be a single main program - the only place that should
228			dictate which event model to use.
229
230			If it doesn't care, it can just "use AnyEvent" and use it itself, or not
231			do anything special and let AnyEvent decide which implementation to chose.
232
233			If the main program relies on a specific event model (for example, in Gtk2
234			programs you have to rely on either Glib or Glib::Event), you should load
235			it before loading AnyEvent or any module that uses it, generally, as early
236			as possible. The reason is that modules might create watchers when they
237			are loaded, and AnyEvent will decide on the event model to use as soon as
238			it creates watchers, and it might chose the wrong one unless you load the
239			correct one yourself.
240
241			You can chose to use a rather inefficient pure-perl implementation by
242			loading the C<AnyEvent::Impl::Perl> module, but letting AnyEvent chose is
243			generally better.
244
245	root	1.1	=cut
246
247			package AnyEvent;
248
249	root	1.2	no warnings;
250	root	1.19	use strict;
251	root	1.24
252	root	1.1	use Carp;
253
254	root	1.28	our $VERSION = '2.55';
255	root	1.2	our $MODEL;
256	root	1.1
257	root	1.2	our $AUTOLOAD;
258			our @ISA;
259	root	1.1
260	root	1.7	our $verbose = $ENV{PERL_ANYEVENT_VERBOSE}*1;
261
262	root	1.8	our @REGISTRY;
263
264	root	1.1	my @models = (
265	root	1.18	[Coro::Event:: => AnyEvent::Impl::Coro::],
266	root	1.28	[EV:: => EV::AnyEvent::],
267	root	1.18	[Event:: => AnyEvent::Impl::Event::],
268			[Glib:: => AnyEvent::Impl::Glib::],
269			[Tk:: => AnyEvent::Impl::Tk::],
270			[AnyEvent::Impl::Perl:: => AnyEvent::Impl::Perl::],
271	root	1.1	);
272
273	root	1.19	our %method = map +($_ => 1), qw(io timer condvar broadcast wait signal one_event DESTROY);
274	root	1.3
275	root	1.19	sub detect() {
276			unless ($MODEL) {
277			no strict 'refs';
278	root	1.1
279	root	1.2	# check for already loaded models
280	root	1.8	for (@REGISTRY, @models) {
281			my ($package, $model) = @$_;
282	root	1.7	if (${"$package\::VERSION"} > 0) {
283	root	1.8	if (eval "require $model") {
284			$MODEL = $model;
285			warn "AnyEvent: found model '$model', using it.\n" if $verbose > 1;
286			last;
287			}
288	root	1.2	}
289	root	1.1	}
290
291	root	1.2	unless ($MODEL) {
292			# try to load a model
293
294	root	1.8	for (@REGISTRY, @models) {
295			my ($package, $model) = @$_;
296	root	1.21	if (eval "require $package"
297			and ${"$package\::VERSION"} > 0
298			and eval "require $model") {
299	root	1.8	$MODEL = $model;
300			warn "AnyEvent: autoprobed and loaded model '$model', using it.\n" if $verbose > 1;
301			last;
302			}
303	root	1.2	}
304
305			$MODEL
306	root	1.19	or die "No event module selected for AnyEvent and autodetect failed. Install any one of these modules: Event (or Coro+Event), Glib or Tk.";
307	root	1.1	}
308	root	1.19
309			unshift @ISA, $MODEL;
310			push @{"$MODEL\::ISA"}, "AnyEvent::Base";
311	root	1.1	}
312
313	root	1.19	$MODEL
314			}
315
316			sub AUTOLOAD {
317			(my $func = $AUTOLOAD) =~ s/.*://;
318
319			$method{$func}
320			or croak "$func: not a valid method for AnyEvent objects";
321
322			detect unless $MODEL;
323	root	1.2
324			my $class = shift;
325	root	1.18	$class->$func (@_);
326	root	1.1	}
327
328	root	1.19	package AnyEvent::Base;
329
330	root	1.20	# default implementation for ->condvar, ->wait, ->broadcast
331
332			sub condvar {
333			bless \my $flag, "AnyEvent::Base::CondVar"
334			}
335
336			sub AnyEvent::Base::CondVar::broadcast {
337			${$_[0]}++;
338			}
339
340			sub AnyEvent::Base::CondVar::wait {
341			AnyEvent->one_event while !${$_[0]};
342			}
343
344			# default implementation for ->signal
345	root	1.19
346			our %SIG_CB;
347
348			sub signal {
349			my (undef, %arg) = @_;
350
351			my $signal = uc $arg{signal}
352			or Carp::croak "required option 'signal' is missing";
353
354			$SIG_CB{$signal}{$arg{cb}} = $arg{cb};
355			$SIG{$signal} \|\|= sub {
356	root	1.20	$_->() for values %{ $SIG_CB{$signal} \|\| {} };
357	root	1.19	};
358
359	root	1.20	bless [$signal, $arg{cb}], "AnyEvent::Base::Signal"
360	root	1.19	}
361
362			sub AnyEvent::Base::Signal::DESTROY {
363			my ($signal, $cb) = @{$_[0]};
364
365			delete $SIG_CB{$signal}{$cb};
366
367			$SIG{$signal} = 'DEFAULT' unless keys %{ $SIG_CB{$signal} };
368			}
369
370	root	1.20	# default implementation for ->child
371
372			our %PID_CB;
373			our $CHLD_W;
374			our $PID_IDLE;
375			our $WNOHANG;
376
377			sub _child_wait {
378			while (0 < (my $pid = waitpid -1, $WNOHANG)) {
379			$_->() for values %{ (delete $PID_CB{$pid}) \|\| {} };
380			}
381
382			undef $PID_IDLE;
383			}
384
385			sub child {
386			my (undef, %arg) = @_;
387
388			my $pid = uc $arg{pid}
389			or Carp::croak "required option 'pid' is missing";
390
391			$PID_CB{$pid}{$arg{cb}} = $arg{cb};
392
393			unless ($WNOHANG) {
394			$WNOHANG = eval { require POSIX; &POSIX::WNOHANG } \|\| 1;
395			}
396
397	root	1.23	unless ($CHLD_W) {
398			$CHLD_W = AnyEvent->signal (signal => 'CHLD', cb => \&_child_wait);
399			# child could be a zombie already
400			$PID_IDLE \|\|= AnyEvent->timer (after => 0, cb => \&_child_wait);
401			}
402	root	1.20
403			bless [$pid, $arg{cb}], "AnyEvent::Base::Child"
404			}
405
406			sub AnyEvent::Base::Child::DESTROY {
407			my ($pid, $cb) = @{$_[0]};
408
409			delete $PID_CB{$pid}{$cb};
410			delete $PID_CB{$pid} unless keys %{ $PID_CB{$pid} };
411
412			undef $CHLD_W unless keys %PID_CB;
413			}
414
415	root	1.8	=head1 SUPPLYING YOUR OWN EVENT MODEL INTERFACE
416
417			If you need to support another event library which isn't directly
418			supported by AnyEvent, you can supply your own interface to it by
419	root	1.11	pushing, before the first watcher gets created, the package name of
420	root	1.8	the event module and the package name of the interface to use onto
421			C<@AnyEvent::REGISTRY>. You can do that before and even without loading
422			AnyEvent.
423
424			Example:
425
426			push @AnyEvent::REGISTRY, [urxvt => urxvt::anyevent::];
427
428	root	1.12	This tells AnyEvent to (literally) use the C<urxvt::anyevent::>
429			package/class when it finds the C<urxvt> package/module is loaded. When
430			AnyEvent is loaded and asked to find a suitable event model, it will
431			first check for the presence of urxvt.
432
433	root	1.19	The class should provide implementations for all watcher types (see
434	root	1.12	L<AnyEvent::Impl::Event> (source code), L<AnyEvent::Impl::Glib>
435			(Source code) and so on for actual examples, use C<perldoc -m
436			AnyEvent::Impl::Glib> to see the sources).
437	root	1.8
438	root	1.12	The above isn't fictitious, the I<rxvt-unicode> (a.k.a. urxvt)
439			uses the above line as-is. An interface isn't included in AnyEvent
440	root	1.8	because it doesn't make sense outside the embedded interpreter inside
441			I<rxvt-unicode>, and it is updated and maintained as part of the
442			I<rxvt-unicode> distribution.
443
444	root	1.12	I<rxvt-unicode> also cheats a bit by not providing blocking access to
445			condition variables: code blocking while waiting for a condition will
446			C<die>. This still works with most modules/usages, and blocking calls must
447	root	1.25	not be in an interactive application, so it makes sense.
448	root	1.12
449	root	1.7	=head1 ENVIRONMENT VARIABLES
450
451			The following environment variables are used by this module:
452
453			C<PERL_ANYEVENT_VERBOSE> when set to C<2> or higher, reports which event
454			model gets used.
455
456	root	1.2	=head1 EXAMPLE
457
458			The following program uses an io watcher to read data from stdin, a timer
459			to display a message once per second, and a condvar to exit the program
460			when the user enters quit:
461
462			use AnyEvent;
463
464			my $cv = AnyEvent->condvar;
465
466			my $io_watcher = AnyEvent->io (fh => \*STDIN, poll => 'r', cb => sub {
467			warn "io event <$_[0]>\n"; # will always output <r>
468			chomp (my $input = <STDIN>); # read a line
469			warn "read: $input\n"; # output what has been read
470			$cv->broadcast if $input =~ /^q/i; # quit program if /^q/i
471			});
472
473			my $time_watcher; # can only be used once
474
475			sub new_timer {
476			$timer = AnyEvent->timer (after => 1, cb => sub {
477			warn "timeout\n"; # print 'timeout' about every second
478			&new_timer; # and restart the time
479			});
480			}
481
482			new_timer; # create first timer
483
484			$cv->wait; # wait until user enters /^q/i
485
486	root	1.5	=head1 REAL-WORLD EXAMPLE
487
488			Consider the L<Net::FCP> module. It features (among others) the following
489			API calls, which are to freenet what HTTP GET requests are to http:
490
491			my $data = $fcp->client_get ($url); # blocks
492
493			my $transaction = $fcp->txn_client_get ($url); # does not block
494			$transaction->cb ( sub { ... } ); # set optional result callback
495			my $data = $transaction->result; # possibly blocks
496
497			The C<client_get> method works like C<LWP::Simple::get>: it requests the
498			given URL and waits till the data has arrived. It is defined to be:
499
500			sub client_get { $_[0]->txn_client_get ($_[1])->result }
501
502			And in fact is automatically generated. This is the blocking API of
503			L<Net::FCP>, and it works as simple as in any other, similar, module.
504
505			More complicated is C<txn_client_get>: It only creates a transaction
506			(completion, result, ...) object and initiates the transaction.
507
508			my $txn = bless { }, Net::FCP::Txn::;
509
510			It also creates a condition variable that is used to signal the completion
511			of the request:
512
513			$txn->{finished} = AnyAvent->condvar;
514
515			It then creates a socket in non-blocking mode.
516
517			socket $txn->{fh}, ...;
518			fcntl $txn->{fh}, F_SETFL, O_NONBLOCK;
519			connect $txn->{fh}, ...
520			and !$!{EWOULDBLOCK}
521			and !$!{EINPROGRESS}
522			and Carp::croak "unable to connect: $!\n";
523
524	root	1.6	Then it creates a write-watcher which gets called whenever an error occurs
525	root	1.5	or the connection succeeds:
526
527			$txn->{w} = AnyEvent->io (fh => $txn->{fh}, poll => 'w', cb => sub { $txn->fh_ready_w });
528
529			And returns this transaction object. The C<fh_ready_w> callback gets
530			called as soon as the event loop detects that the socket is ready for
531			writing.
532
533			The C<fh_ready_w> method makes the socket blocking again, writes the
534			request data and replaces the watcher by a read watcher (waiting for reply
535			data). The actual code is more complicated, but that doesn't matter for
536			this example:
537
538			fcntl $txn->{fh}, F_SETFL, 0;
539			syswrite $txn->{fh}, $txn->{request}
540			or die "connection or write error";
541			$txn->{w} = AnyEvent->io (fh => $txn->{fh}, poll => 'r', cb => sub { $txn->fh_ready_r });
542
543			Again, C<fh_ready_r> waits till all data has arrived, and then stores the
544			result and signals any possible waiters that the request ahs finished:
545
546			sysread $txn->{fh}, $txn->{buf}, length $txn->{$buf};
547
548			if (end-of-file or data complete) {
549			$txn->{result} = $txn->{buf};
550			$txn->{finished}->broadcast;
551	root	1.6	$txb->{cb}->($txn) of $txn->{cb}; # also call callback
552	root	1.5	}
553
554			The C<result> method, finally, just waits for the finished signal (if the
555			request was already finished, it doesn't wait, of course, and returns the
556			data:
557
558			$txn->{finished}->wait;
559	root	1.6	return $txn->{result};
560	root	1.5
561			The actual code goes further and collects all errors (C<die>s, exceptions)
562			that occured during request processing. The C<result> method detects
563			wether an exception as thrown (it is stored inside the $txn object)
564			and just throws the exception, which means connection errors and other
565			problems get reported tot he code that tries to use the result, not in a
566			random callback.
567
568			All of this enables the following usage styles:
569
570			1. Blocking:
571
572			my $data = $fcp->client_get ($url);
573
574			2. Blocking, but parallelizing:
575
576			my @datas = map $_->result,
577			map $fcp->txn_client_get ($_),
578			@urls;
579
580			Both blocking examples work without the module user having to know
581			anything about events.
582
583			3a. Event-based in a main program, using any support Event module:
584
585			use Event;
586
587			$fcp->txn_client_get ($url)->cb (sub {
588			my $txn = shift;
589			my $data = $txn->result;
590			...
591			});
592
593			Event::loop;
594
595			3b. The module user could use AnyEvent, too:
596
597			use AnyEvent;
598
599			my $quit = AnyEvent->condvar;
600
601			$fcp->txn_client_get ($url)->cb (sub {
602			...
603			$quit->broadcast;
604			});
605
606			$quit->wait;
607
608	root	1.2	=head1 SEE ALSO
609
610	root	1.5	Event modules: L<Coro::Event>, L<Coro>, L<Event>, L<Glib::Event>, L<Glib>.
611
612			Implementations: L<AnyEvent::Impl::Coro>, L<AnyEvent::Impl::Event>, L<AnyEvent::Impl::Glib>, L<AnyEvent::Impl::Tk>.
613
614			Nontrivial usage example: L<Net::FCP>.
615	root	1.2
616			=head1
617
618			=cut
619
620			1
621	root	1.1