1 |
=head1 NAME |
2 |
|
3 |
AnyEvent - provide framework for multiple event loops |
4 |
|
5 |
EV, Event, Coro::EV, Coro::Event, Glib, Tk, Perl, Event::Lib, Qt, POE - various supported event loops |
6 |
|
7 |
=head1 SYNOPSIS |
8 |
|
9 |
use AnyEvent; |
10 |
|
11 |
my $w = AnyEvent->io (fh => $fh, poll => "r|w", cb => sub { |
12 |
... |
13 |
}); |
14 |
|
15 |
my $w = AnyEvent->timer (after => $seconds, cb => sub { |
16 |
... |
17 |
}); |
18 |
|
19 |
my $w = AnyEvent->condvar; # stores whether a condition was flagged |
20 |
$w->wait; # enters "main loop" till $condvar gets ->broadcast |
21 |
$w->broadcast; # wake up current and all future wait's |
22 |
|
23 |
=head1 WHY YOU SHOULD USE THIS MODULE (OR NOT) |
24 |
|
25 |
Glib, POE, IO::Async, Event... CPAN offers event models by the dozen |
26 |
nowadays. So what is different about AnyEvent? |
27 |
|
28 |
Executive Summary: AnyEvent is I<compatible>, AnyEvent is I<free of |
29 |
policy> and AnyEvent is I<small and efficient>. |
30 |
|
31 |
First and foremost, I<AnyEvent is not an event model> itself, it only |
32 |
interfaces to whatever event model the main program happens to use in a |
33 |
pragmatic way. For event models and certain classes of immortals alike, |
34 |
the statement "there can only be one" is a bitter reality: In general, |
35 |
only one event loop can be active at the same time in a process. AnyEvent |
36 |
helps hiding the differences between those event loops. |
37 |
|
38 |
The goal of AnyEvent is to offer module authors the ability to do event |
39 |
programming (waiting for I/O or timer events) without subscribing to a |
40 |
religion, a way of living, and most importantly: without forcing your |
41 |
module users into the same thing by forcing them to use the same event |
42 |
model you use. |
43 |
|
44 |
For modules like POE or IO::Async (which is a total misnomer as it is |
45 |
actually doing all I/O I<synchronously>...), using them in your module is |
46 |
like joining a cult: After you joined, you are dependent on them and you |
47 |
cannot use anything else, as it is simply incompatible to everything that |
48 |
isn't itself. What's worse, all the potential users of your module are |
49 |
I<also> forced to use the same event loop you use. |
50 |
|
51 |
AnyEvent is different: AnyEvent + POE works fine. AnyEvent + Glib works |
52 |
fine. AnyEvent + Tk works fine etc. etc. but none of these work together |
53 |
with the rest: POE + IO::Async? no go. Tk + Event? no go. Again: if |
54 |
your module uses one of those, every user of your module has to use it, |
55 |
too. But if your module uses AnyEvent, it works transparently with all |
56 |
event models it supports (including stuff like POE and IO::Async, as long |
57 |
as those use one of the supported event loops. It is trivial to add new |
58 |
event loops to AnyEvent, too, so it is future-proof). |
59 |
|
60 |
In addition to being free of having to use I<the one and only true event |
61 |
model>, AnyEvent also is free of bloat and policy: with POE or similar |
62 |
modules, you get an enourmous amount of code and strict rules you have to |
63 |
follow. AnyEvent, on the other hand, is lean and up to the point, by only |
64 |
offering the functionality that is necessary, in as thin as a wrapper as |
65 |
technically possible. |
66 |
|
67 |
Of course, if you want lots of policy (this can arguably be somewhat |
68 |
useful) and you want to force your users to use the one and only event |
69 |
model, you should I<not> use this module. |
70 |
|
71 |
|
72 |
=head1 DESCRIPTION |
73 |
|
74 |
L<AnyEvent> provides an identical interface to multiple event loops. This |
75 |
allows module authors to utilise an event loop without forcing module |
76 |
users to use the same event loop (as only a single event loop can coexist |
77 |
peacefully at any one time). |
78 |
|
79 |
The interface itself is vaguely similar, but not identical to the L<Event> |
80 |
module. |
81 |
|
82 |
During the first call of any watcher-creation method, the module tries |
83 |
to detect the currently loaded event loop by probing whether one of the |
84 |
following modules is already loaded: L<Coro::EV>, L<Coro::Event>, L<EV>, |
85 |
L<Event>, L<Glib>, L<AnyEvent::Impl::Perl>, L<Tk>, L<Event::Lib>, L<Qt>, |
86 |
L<POE>. The first one found is used. If none are found, the module tries |
87 |
to load these modules (excluding Tk, Event::Lib, Qt and POE as the pure perl |
88 |
adaptor should always succeed) in the order given. The first one that can |
89 |
be successfully loaded will be used. If, after this, still none could be |
90 |
found, AnyEvent will fall back to a pure-perl event loop, which is not |
91 |
very efficient, but should work everywhere. |
92 |
|
93 |
Because AnyEvent first checks for modules that are already loaded, loading |
94 |
an event model explicitly before first using AnyEvent will likely make |
95 |
that model the default. For example: |
96 |
|
97 |
use Tk; |
98 |
use AnyEvent; |
99 |
|
100 |
# .. AnyEvent will likely default to Tk |
101 |
|
102 |
The I<likely> means that, if any module loads another event model and |
103 |
starts using it, all bets are off. Maybe you should tell their authors to |
104 |
use AnyEvent so their modules work together with others seamlessly... |
105 |
|
106 |
The pure-perl implementation of AnyEvent is called |
107 |
C<AnyEvent::Impl::Perl>. Like other event modules you can load it |
108 |
explicitly. |
109 |
|
110 |
=head1 WATCHERS |
111 |
|
112 |
AnyEvent has the central concept of a I<watcher>, which is an object that |
113 |
stores relevant data for each kind of event you are waiting for, such as |
114 |
the callback to call, the filehandle to watch, etc. |
115 |
|
116 |
These watchers are normal Perl objects with normal Perl lifetime. After |
117 |
creating a watcher it will immediately "watch" for events and invoke the |
118 |
callback when the event occurs (of course, only when the event model |
119 |
is in control). |
120 |
|
121 |
To disable the watcher you have to destroy it (e.g. by setting the |
122 |
variable you store it in to C<undef> or otherwise deleting all references |
123 |
to it). |
124 |
|
125 |
All watchers are created by calling a method on the C<AnyEvent> class. |
126 |
|
127 |
Many watchers either are used with "recursion" (repeating timers for |
128 |
example), or need to refer to their watcher object in other ways. |
129 |
|
130 |
An any way to achieve that is this pattern: |
131 |
|
132 |
my $w; $w = AnyEvent->type (arg => value ..., cb => sub { |
133 |
# you can use $w here, for example to undef it |
134 |
undef $w; |
135 |
}); |
136 |
|
137 |
Note that C<my $w; $w => combination. This is necessary because in Perl, |
138 |
my variables are only visible after the statement in which they are |
139 |
declared. |
140 |
|
141 |
=head2 I/O WATCHERS |
142 |
|
143 |
You can create an I/O watcher by calling the C<< AnyEvent->io >> method |
144 |
with the following mandatory key-value pairs as arguments: |
145 |
|
146 |
C<fh> the Perl I<file handle> (I<not> file descriptor) to watch for |
147 |
events. C<poll> must be a string that is either C<r> or C<w>, which |
148 |
creates a watcher waiting for "r"eadable or "w"ritable events, |
149 |
respectively. C<cb> is the callback to invoke each time the file handle |
150 |
becomes ready. |
151 |
|
152 |
The I/O watcher might use the underlying file descriptor or a copy of it. |
153 |
You must not close a file handle as long as any watcher is active on the |
154 |
underlying file descriptor. |
155 |
|
156 |
Some event loops issue spurious readyness notifications, so you should |
157 |
always use non-blocking calls when reading/writing from/to your file |
158 |
handles. |
159 |
|
160 |
Although the callback might get passed parameters, their value and |
161 |
presence is undefined and you cannot rely on them. Portable AnyEvent |
162 |
callbacks cannot use arguments passed to I/O watcher callbacks. |
163 |
|
164 |
Example: |
165 |
|
166 |
# wait for readability of STDIN, then read a line and disable the watcher |
167 |
my $w; $w = AnyEvent->io (fh => \*STDIN, poll => 'r', cb => sub { |
168 |
chomp (my $input = <STDIN>); |
169 |
warn "read: $input\n"; |
170 |
undef $w; |
171 |
}); |
172 |
|
173 |
=head2 TIME WATCHERS |
174 |
|
175 |
You can create a time watcher by calling the C<< AnyEvent->timer >> |
176 |
method with the following mandatory arguments: |
177 |
|
178 |
C<after> specifies after how many seconds (fractional values are |
179 |
supported) should the timer activate. C<cb> the callback to invoke in that |
180 |
case. |
181 |
|
182 |
The timer callback will be invoked at most once: if you want a repeating |
183 |
timer you have to create a new watcher (this is a limitation by both Tk |
184 |
and Glib). |
185 |
|
186 |
Although the callback might get passed parameters, their value and |
187 |
presence is undefined and you cannot rely on them. Portable AnyEvent |
188 |
callbacks cannot use arguments passed to time watcher callbacks. |
189 |
|
190 |
Example: |
191 |
|
192 |
# fire an event after 7.7 seconds |
193 |
my $w = AnyEvent->timer (after => 7.7, cb => sub { |
194 |
warn "timeout\n"; |
195 |
}); |
196 |
|
197 |
# to cancel the timer: |
198 |
undef $w; |
199 |
|
200 |
Example 2: |
201 |
|
202 |
# fire an event after 0.5 seconds, then roughly every second |
203 |
my $w; |
204 |
|
205 |
my $cb = sub { |
206 |
# cancel the old timer while creating a new one |
207 |
$w = AnyEvent->timer (after => 1, cb => $cb); |
208 |
}; |
209 |
|
210 |
# start the "loop" by creating the first watcher |
211 |
$w = AnyEvent->timer (after => 0.5, cb => $cb); |
212 |
|
213 |
=head3 TIMING ISSUES |
214 |
|
215 |
There are two ways to handle timers: based on real time (relative, "fire |
216 |
in 10 seconds") and based on wallclock time (absolute, "fire at 12 |
217 |
o'clock"). |
218 |
|
219 |
While most event loops expect timers to specified in a relative way, they |
220 |
use absolute time internally. This makes a difference when your clock |
221 |
"jumps", for example, when ntp decides to set your clock backwards from |
222 |
the wrong date of 2014-01-01 to 2008-01-01, a watcher that is supposed to |
223 |
fire "after" a second might actually take six years to finally fire. |
224 |
|
225 |
AnyEvent cannot compensate for this. The only event loop that is conscious |
226 |
about these issues is L<EV>, which offers both relative (ev_timer, based |
227 |
on true relative time) and absolute (ev_periodic, based on wallclock time) |
228 |
timers. |
229 |
|
230 |
AnyEvent always prefers relative timers, if available, matching the |
231 |
AnyEvent API. |
232 |
|
233 |
=head2 SIGNAL WATCHERS |
234 |
|
235 |
You can watch for signals using a signal watcher, C<signal> is the signal |
236 |
I<name> without any C<SIG> prefix, C<cb> is the Perl callback to |
237 |
be invoked whenever a signal occurs. |
238 |
|
239 |
Multiple signal occurances can be clumped together into one callback |
240 |
invocation, and callback invocation will be synchronous. synchronous means |
241 |
that it might take a while until the signal gets handled by the process, |
242 |
but it is guarenteed not to interrupt any other callbacks. |
243 |
|
244 |
The main advantage of using these watchers is that you can share a signal |
245 |
between multiple watchers. |
246 |
|
247 |
This watcher might use C<%SIG>, so programs overwriting those signals |
248 |
directly will likely not work correctly. |
249 |
|
250 |
Example: exit on SIGINT |
251 |
|
252 |
my $w = AnyEvent->signal (signal => "INT", cb => sub { exit 1 }); |
253 |
|
254 |
=head2 CHILD PROCESS WATCHERS |
255 |
|
256 |
You can also watch on a child process exit and catch its exit status. |
257 |
|
258 |
The child process is specified by the C<pid> argument (if set to C<0>, it |
259 |
watches for any child process exit). The watcher will trigger as often |
260 |
as status change for the child are received. This works by installing a |
261 |
signal handler for C<SIGCHLD>. The callback will be called with the pid |
262 |
and exit status (as returned by waitpid). |
263 |
|
264 |
There is a slight catch to child watchers, however: you usually start them |
265 |
I<after> the child process was created, and this means the process could |
266 |
have exited already (and no SIGCHLD will be sent anymore). |
267 |
|
268 |
Not all event models handle this correctly (POE doesn't), but even for |
269 |
event models that I<do> handle this correctly, they usually need to be |
270 |
loaded before the process exits (i.e. before you fork in the first place). |
271 |
|
272 |
This means you cannot create a child watcher as the very first thing in an |
273 |
AnyEvent program, you I<have> to create at least one watcher before you |
274 |
C<fork> the child (alternatively, you can call C<AnyEvent::detect>). |
275 |
|
276 |
Example: fork a process and wait for it |
277 |
|
278 |
my $done = AnyEvent->condvar; |
279 |
|
280 |
AnyEvent::detect; # force event module to be initialised |
281 |
|
282 |
my $pid = fork or exit 5; |
283 |
|
284 |
my $w = AnyEvent->child ( |
285 |
pid => $pid, |
286 |
cb => sub { |
287 |
my ($pid, $status) = @_; |
288 |
warn "pid $pid exited with status $status"; |
289 |
$done->broadcast; |
290 |
}, |
291 |
); |
292 |
|
293 |
# do something else, then wait for process exit |
294 |
$done->wait; |
295 |
|
296 |
=head2 CONDITION VARIABLES |
297 |
|
298 |
Condition variables can be created by calling the C<< AnyEvent->condvar >> |
299 |
method without any arguments. |
300 |
|
301 |
A condition variable waits for a condition - precisely that the C<< |
302 |
->broadcast >> method has been called. |
303 |
|
304 |
They are very useful to signal that a condition has been fulfilled, for |
305 |
example, if you write a module that does asynchronous http requests, |
306 |
then a condition variable would be the ideal candidate to signal the |
307 |
availability of results. |
308 |
|
309 |
You can also use condition variables to block your main program until |
310 |
an event occurs - for example, you could C<< ->wait >> in your main |
311 |
program until the user clicks the Quit button in your app, which would C<< |
312 |
->broadcast >> the "quit" event. |
313 |
|
314 |
Note that condition variables recurse into the event loop - if you have |
315 |
two pirces of code that call C<< ->wait >> in a round-robbin fashion, you |
316 |
lose. Therefore, condition variables are good to export to your caller, but |
317 |
you should avoid making a blocking wait yourself, at least in callbacks, |
318 |
as this asks for trouble. |
319 |
|
320 |
This object has two methods: |
321 |
|
322 |
=over 4 |
323 |
|
324 |
=item $cv->wait |
325 |
|
326 |
Wait (blocking if necessary) until the C<< ->broadcast >> method has been |
327 |
called on c<$cv>, while servicing other watchers normally. |
328 |
|
329 |
You can only wait once on a condition - additional calls will return |
330 |
immediately. |
331 |
|
332 |
Not all event models support a blocking wait - some die in that case |
333 |
(programs might want to do that to stay interactive), so I<if you are |
334 |
using this from a module, never require a blocking wait>, but let the |
335 |
caller decide whether the call will block or not (for example, by coupling |
336 |
condition variables with some kind of request results and supporting |
337 |
callbacks so the caller knows that getting the result will not block, |
338 |
while still suppporting blocking waits if the caller so desires). |
339 |
|
340 |
Another reason I<never> to C<< ->wait >> in a module is that you cannot |
341 |
sensibly have two C<< ->wait >>'s in parallel, as that would require |
342 |
multiple interpreters or coroutines/threads, none of which C<AnyEvent> |
343 |
can supply (the coroutine-aware backends L<AnyEvent::Impl::CoroEV> and |
344 |
L<AnyEvent::Impl::CoroEvent> explicitly support concurrent C<< ->wait >>'s |
345 |
from different coroutines, however). |
346 |
|
347 |
=item $cv->broadcast |
348 |
|
349 |
Flag the condition as ready - a running C<< ->wait >> and all further |
350 |
calls to C<wait> will (eventually) return after this method has been |
351 |
called. If nobody is waiting the broadcast will be remembered.. |
352 |
|
353 |
=back |
354 |
|
355 |
Example: |
356 |
|
357 |
# wait till the result is ready |
358 |
my $result_ready = AnyEvent->condvar; |
359 |
|
360 |
# do something such as adding a timer |
361 |
# or socket watcher the calls $result_ready->broadcast |
362 |
# when the "result" is ready. |
363 |
# in this case, we simply use a timer: |
364 |
my $w = AnyEvent->timer ( |
365 |
after => 1, |
366 |
cb => sub { $result_ready->broadcast }, |
367 |
); |
368 |
|
369 |
# this "blocks" (while handling events) till the watcher |
370 |
# calls broadcast |
371 |
$result_ready->wait; |
372 |
|
373 |
=head1 GLOBAL VARIABLES AND FUNCTIONS |
374 |
|
375 |
=over 4 |
376 |
|
377 |
=item $AnyEvent::MODEL |
378 |
|
379 |
Contains C<undef> until the first watcher is being created. Then it |
380 |
contains the event model that is being used, which is the name of the |
381 |
Perl class implementing the model. This class is usually one of the |
382 |
C<AnyEvent::Impl:xxx> modules, but can be any other class in the case |
383 |
AnyEvent has been extended at runtime (e.g. in I<rxvt-unicode>). |
384 |
|
385 |
The known classes so far are: |
386 |
|
387 |
AnyEvent::Impl::CoroEV based on Coro::EV, best choice. |
388 |
AnyEvent::Impl::CoroEvent based on Coro::Event, second best choice. |
389 |
AnyEvent::Impl::EV based on EV (an interface to libev, best choice). |
390 |
AnyEvent::Impl::Event based on Event, second best choice. |
391 |
AnyEvent::Impl::Glib based on Glib, third-best choice. |
392 |
AnyEvent::Impl::Perl pure-perl implementation, inefficient but portable. |
393 |
AnyEvent::Impl::Tk based on Tk, very bad choice. |
394 |
AnyEvent::Impl::Qt based on Qt, cannot be autoprobed (see its docs). |
395 |
AnyEvent::Impl::EventLib based on Event::Lib, leaks memory and worse. |
396 |
AnyEvent::Impl::POE based on POE, not generic enough for full support. |
397 |
|
398 |
There is no support for WxWidgets, as WxWidgets has no support for |
399 |
watching file handles. However, you can use WxWidgets through the |
400 |
POE Adaptor, as POE has a Wx backend that simply polls 20 times per |
401 |
second, which was considered to be too horrible to even consider for |
402 |
AnyEvent. Likewise, other POE backends can be used by AnyEvent by using |
403 |
it's adaptor. |
404 |
|
405 |
AnyEvent knows about L<Prima> and L<Wx> and will try to use L<POE> when |
406 |
autodetecting them. |
407 |
|
408 |
=item AnyEvent::detect |
409 |
|
410 |
Returns C<$AnyEvent::MODEL>, forcing autodetection of the event model |
411 |
if necessary. You should only call this function right before you would |
412 |
have created an AnyEvent watcher anyway, that is, as late as possible at |
413 |
runtime. |
414 |
|
415 |
=back |
416 |
|
417 |
=head1 WHAT TO DO IN A MODULE |
418 |
|
419 |
As a module author, you should C<use AnyEvent> and call AnyEvent methods |
420 |
freely, but you should not load a specific event module or rely on it. |
421 |
|
422 |
Be careful when you create watchers in the module body - AnyEvent will |
423 |
decide which event module to use as soon as the first method is called, so |
424 |
by calling AnyEvent in your module body you force the user of your module |
425 |
to load the event module first. |
426 |
|
427 |
Never call C<< ->wait >> on a condition variable unless you I<know> that |
428 |
the C<< ->broadcast >> method has been called on it already. This is |
429 |
because it will stall the whole program, and the whole point of using |
430 |
events is to stay interactive. |
431 |
|
432 |
It is fine, however, to call C<< ->wait >> when the user of your module |
433 |
requests it (i.e. if you create a http request object ad have a method |
434 |
called C<results> that returns the results, it should call C<< ->wait >> |
435 |
freely, as the user of your module knows what she is doing. always). |
436 |
|
437 |
=head1 WHAT TO DO IN THE MAIN PROGRAM |
438 |
|
439 |
There will always be a single main program - the only place that should |
440 |
dictate which event model to use. |
441 |
|
442 |
If it doesn't care, it can just "use AnyEvent" and use it itself, or not |
443 |
do anything special (it does not need to be event-based) and let AnyEvent |
444 |
decide which implementation to chose if some module relies on it. |
445 |
|
446 |
If the main program relies on a specific event model. For example, in |
447 |
Gtk2 programs you have to rely on the Glib module. You should load the |
448 |
event module before loading AnyEvent or any module that uses it: generally |
449 |
speaking, you should load it as early as possible. The reason is that |
450 |
modules might create watchers when they are loaded, and AnyEvent will |
451 |
decide on the event model to use as soon as it creates watchers, and it |
452 |
might chose the wrong one unless you load the correct one yourself. |
453 |
|
454 |
You can chose to use a rather inefficient pure-perl implementation by |
455 |
loading the C<AnyEvent::Impl::Perl> module, which gives you similar |
456 |
behaviour everywhere, but letting AnyEvent chose is generally better. |
457 |
|
458 |
=cut |
459 |
|
460 |
package AnyEvent; |
461 |
|
462 |
no warnings; |
463 |
use strict; |
464 |
|
465 |
use Carp; |
466 |
|
467 |
our $VERSION = '3.3'; |
468 |
our $MODEL; |
469 |
|
470 |
our $AUTOLOAD; |
471 |
our @ISA; |
472 |
|
473 |
our $verbose = $ENV{PERL_ANYEVENT_VERBOSE}*1; |
474 |
|
475 |
our @REGISTRY; |
476 |
|
477 |
my @models = ( |
478 |
[Coro::EV:: => AnyEvent::Impl::CoroEV::], |
479 |
[Coro::Event:: => AnyEvent::Impl::CoroEvent::], |
480 |
[EV:: => AnyEvent::Impl::EV::], |
481 |
[Event:: => AnyEvent::Impl::Event::], |
482 |
[Glib:: => AnyEvent::Impl::Glib::], |
483 |
[Tk:: => AnyEvent::Impl::Tk::], |
484 |
[Wx:: => AnyEvent::Impl::POE::], |
485 |
[Prima:: => AnyEvent::Impl::POE::], |
486 |
[AnyEvent::Impl::Perl:: => AnyEvent::Impl::Perl::], |
487 |
# everything below here will not be autoprobed as the pureperl backend should work everywhere |
488 |
[Event::Lib:: => AnyEvent::Impl::EventLib::], # too buggy |
489 |
[Qt:: => AnyEvent::Impl::Qt::], # requires special main program |
490 |
[POE::Kernel:: => AnyEvent::Impl::POE::], # lasciate ogni speranza |
491 |
); |
492 |
|
493 |
our %method = map +($_ => 1), qw(io timer signal child condvar broadcast wait one_event DESTROY); |
494 |
|
495 |
sub detect() { |
496 |
unless ($MODEL) { |
497 |
no strict 'refs'; |
498 |
|
499 |
if ($ENV{PERL_ANYEVENT_MODEL} =~ /^([a-zA-Z]+)$/) { |
500 |
my $model = "AnyEvent::Impl::$1"; |
501 |
if (eval "require $model") { |
502 |
$MODEL = $model; |
503 |
warn "AnyEvent: loaded model '$model' (forced by \$PERL_ANYEVENT_MODEL), using it.\n" if $verbose > 1; |
504 |
} else { |
505 |
warn "AnyEvent: unable to load model '$model' (from \$PERL_ANYEVENT_MODEL):\n$@" if $verbose; |
506 |
} |
507 |
} |
508 |
|
509 |
# check for already loaded models |
510 |
unless ($MODEL) { |
511 |
for (@REGISTRY, @models) { |
512 |
my ($package, $model) = @$_; |
513 |
if (${"$package\::VERSION"} > 0) { |
514 |
if (eval "require $model") { |
515 |
$MODEL = $model; |
516 |
warn "AnyEvent: autodetected model '$model', using it.\n" if $verbose > 1; |
517 |
last; |
518 |
} |
519 |
} |
520 |
} |
521 |
|
522 |
unless ($MODEL) { |
523 |
# try to load a model |
524 |
|
525 |
for (@REGISTRY, @models) { |
526 |
my ($package, $model) = @$_; |
527 |
if (eval "require $package" |
528 |
and ${"$package\::VERSION"} > 0 |
529 |
and eval "require $model") { |
530 |
$MODEL = $model; |
531 |
warn "AnyEvent: autoprobed model '$model', using it.\n" if $verbose > 1; |
532 |
last; |
533 |
} |
534 |
} |
535 |
|
536 |
$MODEL |
537 |
or die "No event module selected for AnyEvent and autodetect failed. Install any one of these modules: EV (or Coro+EV), Event (or Coro+Event) or Glib."; |
538 |
} |
539 |
} |
540 |
|
541 |
unshift @ISA, $MODEL; |
542 |
push @{"$MODEL\::ISA"}, "AnyEvent::Base"; |
543 |
} |
544 |
|
545 |
$MODEL |
546 |
} |
547 |
|
548 |
sub AUTOLOAD { |
549 |
(my $func = $AUTOLOAD) =~ s/.*://; |
550 |
|
551 |
$method{$func} |
552 |
or croak "$func: not a valid method for AnyEvent objects"; |
553 |
|
554 |
detect unless $MODEL; |
555 |
|
556 |
my $class = shift; |
557 |
$class->$func (@_); |
558 |
} |
559 |
|
560 |
package AnyEvent::Base; |
561 |
|
562 |
# default implementation for ->condvar, ->wait, ->broadcast |
563 |
|
564 |
sub condvar { |
565 |
bless \my $flag, "AnyEvent::Base::CondVar" |
566 |
} |
567 |
|
568 |
sub AnyEvent::Base::CondVar::broadcast { |
569 |
${$_[0]}++; |
570 |
} |
571 |
|
572 |
sub AnyEvent::Base::CondVar::wait { |
573 |
AnyEvent->one_event while !${$_[0]}; |
574 |
} |
575 |
|
576 |
# default implementation for ->signal |
577 |
|
578 |
our %SIG_CB; |
579 |
|
580 |
sub signal { |
581 |
my (undef, %arg) = @_; |
582 |
|
583 |
my $signal = uc $arg{signal} |
584 |
or Carp::croak "required option 'signal' is missing"; |
585 |
|
586 |
$SIG_CB{$signal}{$arg{cb}} = $arg{cb}; |
587 |
$SIG{$signal} ||= sub { |
588 |
$_->() for values %{ $SIG_CB{$signal} || {} }; |
589 |
}; |
590 |
|
591 |
bless [$signal, $arg{cb}], "AnyEvent::Base::Signal" |
592 |
} |
593 |
|
594 |
sub AnyEvent::Base::Signal::DESTROY { |
595 |
my ($signal, $cb) = @{$_[0]}; |
596 |
|
597 |
delete $SIG_CB{$signal}{$cb}; |
598 |
|
599 |
$SIG{$signal} = 'DEFAULT' unless keys %{ $SIG_CB{$signal} }; |
600 |
} |
601 |
|
602 |
# default implementation for ->child |
603 |
|
604 |
our %PID_CB; |
605 |
our $CHLD_W; |
606 |
our $CHLD_DELAY_W; |
607 |
our $PID_IDLE; |
608 |
our $WNOHANG; |
609 |
|
610 |
sub _child_wait { |
611 |
while (0 < (my $pid = waitpid -1, $WNOHANG)) { |
612 |
$_->($pid, $?) for (values %{ $PID_CB{$pid} || {} }), |
613 |
(values %{ $PID_CB{0} || {} }); |
614 |
} |
615 |
|
616 |
undef $PID_IDLE; |
617 |
} |
618 |
|
619 |
sub _sigchld { |
620 |
# make sure we deliver these changes "synchronous" with the event loop. |
621 |
$CHLD_DELAY_W ||= AnyEvent->timer (after => 0, cb => sub { |
622 |
undef $CHLD_DELAY_W; |
623 |
&_child_wait; |
624 |
}); |
625 |
} |
626 |
|
627 |
sub child { |
628 |
my (undef, %arg) = @_; |
629 |
|
630 |
defined (my $pid = $arg{pid} + 0) |
631 |
or Carp::croak "required option 'pid' is missing"; |
632 |
|
633 |
$PID_CB{$pid}{$arg{cb}} = $arg{cb}; |
634 |
|
635 |
unless ($WNOHANG) { |
636 |
$WNOHANG = eval { require POSIX; &POSIX::WNOHANG } || 1; |
637 |
} |
638 |
|
639 |
unless ($CHLD_W) { |
640 |
$CHLD_W = AnyEvent->signal (signal => 'CHLD', cb => \&_sigchld); |
641 |
# child could be a zombie already, so make at least one round |
642 |
&_sigchld; |
643 |
} |
644 |
|
645 |
bless [$pid, $arg{cb}], "AnyEvent::Base::Child" |
646 |
} |
647 |
|
648 |
sub AnyEvent::Base::Child::DESTROY { |
649 |
my ($pid, $cb) = @{$_[0]}; |
650 |
|
651 |
delete $PID_CB{$pid}{$cb}; |
652 |
delete $PID_CB{$pid} unless keys %{ $PID_CB{$pid} }; |
653 |
|
654 |
undef $CHLD_W unless keys %PID_CB; |
655 |
} |
656 |
|
657 |
=head1 SUPPLYING YOUR OWN EVENT MODEL INTERFACE |
658 |
|
659 |
This is an advanced topic that you do not normally need to use AnyEvent in |
660 |
a module. This section is only of use to event loop authors who want to |
661 |
provide AnyEvent compatibility. |
662 |
|
663 |
If you need to support another event library which isn't directly |
664 |
supported by AnyEvent, you can supply your own interface to it by |
665 |
pushing, before the first watcher gets created, the package name of |
666 |
the event module and the package name of the interface to use onto |
667 |
C<@AnyEvent::REGISTRY>. You can do that before and even without loading |
668 |
AnyEvent, so it is reasonably cheap. |
669 |
|
670 |
Example: |
671 |
|
672 |
push @AnyEvent::REGISTRY, [urxvt => urxvt::anyevent::]; |
673 |
|
674 |
This tells AnyEvent to (literally) use the C<urxvt::anyevent::> |
675 |
package/class when it finds the C<urxvt> package/module is already loaded. |
676 |
|
677 |
When AnyEvent is loaded and asked to find a suitable event model, it |
678 |
will first check for the presence of urxvt by trying to C<use> the |
679 |
C<urxvt::anyevent> module. |
680 |
|
681 |
The class should provide implementations for all watcher types. See |
682 |
L<AnyEvent::Impl::EV> (source code), L<AnyEvent::Impl::Glib> (Source code) |
683 |
and so on for actual examples. Use C<perldoc -m AnyEvent::Impl::Glib> to |
684 |
see the sources. |
685 |
|
686 |
If you don't provide C<signal> and C<child> watchers than AnyEvent will |
687 |
provide suitable (hopefully) replacements. |
688 |
|
689 |
The above example isn't fictitious, the I<rxvt-unicode> (a.k.a. urxvt) |
690 |
terminal emulator uses the above line as-is. An interface isn't included |
691 |
in AnyEvent because it doesn't make sense outside the embedded interpreter |
692 |
inside I<rxvt-unicode>, and it is updated and maintained as part of the |
693 |
I<rxvt-unicode> distribution. |
694 |
|
695 |
I<rxvt-unicode> also cheats a bit by not providing blocking access to |
696 |
condition variables: code blocking while waiting for a condition will |
697 |
C<die>. This still works with most modules/usages, and blocking calls must |
698 |
not be done in an interactive application, so it makes sense. |
699 |
|
700 |
=head1 ENVIRONMENT VARIABLES |
701 |
|
702 |
The following environment variables are used by this module: |
703 |
|
704 |
=over 4 |
705 |
|
706 |
=item C<PERL_ANYEVENT_VERBOSE> |
707 |
|
708 |
By default, AnyEvent will be completely silent except in fatal |
709 |
conditions. You can set this environment variable to make AnyEvent more |
710 |
talkative. |
711 |
|
712 |
When set to C<1> or higher, causes AnyEvent to warn about unexpected |
713 |
conditions, such as not being able to load the event model specified by |
714 |
C<PERL_ANYEVENT_MODEL>. |
715 |
|
716 |
When set to C<2> or higher, cause AnyEvent to report to STDERR which event |
717 |
model it chooses. |
718 |
|
719 |
=item C<PERL_ANYEVENT_MODEL> |
720 |
|
721 |
This can be used to specify the event model to be used by AnyEvent, before |
722 |
autodetection and -probing kicks in. It must be a string consisting |
723 |
entirely of ASCII letters. The string C<AnyEvent::Impl::> gets prepended |
724 |
and the resulting module name is loaded and if the load was successful, |
725 |
used as event model. If it fails to load AnyEvent will proceed with |
726 |
autodetection and -probing. |
727 |
|
728 |
This functionality might change in future versions. |
729 |
|
730 |
For example, to force the pure perl model (L<AnyEvent::Impl::Perl>) you |
731 |
could start your program like this: |
732 |
|
733 |
PERL_ANYEVENT_MODEL=Perl perl ... |
734 |
|
735 |
=back |
736 |
|
737 |
=head1 EXAMPLE PROGRAM |
738 |
|
739 |
The following program uses an I/O watcher to read data from STDIN, a timer |
740 |
to display a message once per second, and a condition variable to quit the |
741 |
program when the user enters quit: |
742 |
|
743 |
use AnyEvent; |
744 |
|
745 |
my $cv = AnyEvent->condvar; |
746 |
|
747 |
my $io_watcher = AnyEvent->io ( |
748 |
fh => \*STDIN, |
749 |
poll => 'r', |
750 |
cb => sub { |
751 |
warn "io event <$_[0]>\n"; # will always output <r> |
752 |
chomp (my $input = <STDIN>); # read a line |
753 |
warn "read: $input\n"; # output what has been read |
754 |
$cv->broadcast if $input =~ /^q/i; # quit program if /^q/i |
755 |
}, |
756 |
); |
757 |
|
758 |
my $time_watcher; # can only be used once |
759 |
|
760 |
sub new_timer { |
761 |
$timer = AnyEvent->timer (after => 1, cb => sub { |
762 |
warn "timeout\n"; # print 'timeout' about every second |
763 |
&new_timer; # and restart the time |
764 |
}); |
765 |
} |
766 |
|
767 |
new_timer; # create first timer |
768 |
|
769 |
$cv->wait; # wait until user enters /^q/i |
770 |
|
771 |
=head1 REAL-WORLD EXAMPLE |
772 |
|
773 |
Consider the L<Net::FCP> module. It features (among others) the following |
774 |
API calls, which are to freenet what HTTP GET requests are to http: |
775 |
|
776 |
my $data = $fcp->client_get ($url); # blocks |
777 |
|
778 |
my $transaction = $fcp->txn_client_get ($url); # does not block |
779 |
$transaction->cb ( sub { ... } ); # set optional result callback |
780 |
my $data = $transaction->result; # possibly blocks |
781 |
|
782 |
The C<client_get> method works like C<LWP::Simple::get>: it requests the |
783 |
given URL and waits till the data has arrived. It is defined to be: |
784 |
|
785 |
sub client_get { $_[0]->txn_client_get ($_[1])->result } |
786 |
|
787 |
And in fact is automatically generated. This is the blocking API of |
788 |
L<Net::FCP>, and it works as simple as in any other, similar, module. |
789 |
|
790 |
More complicated is C<txn_client_get>: It only creates a transaction |
791 |
(completion, result, ...) object and initiates the transaction. |
792 |
|
793 |
my $txn = bless { }, Net::FCP::Txn::; |
794 |
|
795 |
It also creates a condition variable that is used to signal the completion |
796 |
of the request: |
797 |
|
798 |
$txn->{finished} = AnyAvent->condvar; |
799 |
|
800 |
It then creates a socket in non-blocking mode. |
801 |
|
802 |
socket $txn->{fh}, ...; |
803 |
fcntl $txn->{fh}, F_SETFL, O_NONBLOCK; |
804 |
connect $txn->{fh}, ... |
805 |
and !$!{EWOULDBLOCK} |
806 |
and !$!{EINPROGRESS} |
807 |
and Carp::croak "unable to connect: $!\n"; |
808 |
|
809 |
Then it creates a write-watcher which gets called whenever an error occurs |
810 |
or the connection succeeds: |
811 |
|
812 |
$txn->{w} = AnyEvent->io (fh => $txn->{fh}, poll => 'w', cb => sub { $txn->fh_ready_w }); |
813 |
|
814 |
And returns this transaction object. The C<fh_ready_w> callback gets |
815 |
called as soon as the event loop detects that the socket is ready for |
816 |
writing. |
817 |
|
818 |
The C<fh_ready_w> method makes the socket blocking again, writes the |
819 |
request data and replaces the watcher by a read watcher (waiting for reply |
820 |
data). The actual code is more complicated, but that doesn't matter for |
821 |
this example: |
822 |
|
823 |
fcntl $txn->{fh}, F_SETFL, 0; |
824 |
syswrite $txn->{fh}, $txn->{request} |
825 |
or die "connection or write error"; |
826 |
$txn->{w} = AnyEvent->io (fh => $txn->{fh}, poll => 'r', cb => sub { $txn->fh_ready_r }); |
827 |
|
828 |
Again, C<fh_ready_r> waits till all data has arrived, and then stores the |
829 |
result and signals any possible waiters that the request ahs finished: |
830 |
|
831 |
sysread $txn->{fh}, $txn->{buf}, length $txn->{$buf}; |
832 |
|
833 |
if (end-of-file or data complete) { |
834 |
$txn->{result} = $txn->{buf}; |
835 |
$txn->{finished}->broadcast; |
836 |
$txb->{cb}->($txn) of $txn->{cb}; # also call callback |
837 |
} |
838 |
|
839 |
The C<result> method, finally, just waits for the finished signal (if the |
840 |
request was already finished, it doesn't wait, of course, and returns the |
841 |
data: |
842 |
|
843 |
$txn->{finished}->wait; |
844 |
return $txn->{result}; |
845 |
|
846 |
The actual code goes further and collects all errors (C<die>s, exceptions) |
847 |
that occured during request processing. The C<result> method detects |
848 |
whether an exception as thrown (it is stored inside the $txn object) |
849 |
and just throws the exception, which means connection errors and other |
850 |
problems get reported tot he code that tries to use the result, not in a |
851 |
random callback. |
852 |
|
853 |
All of this enables the following usage styles: |
854 |
|
855 |
1. Blocking: |
856 |
|
857 |
my $data = $fcp->client_get ($url); |
858 |
|
859 |
2. Blocking, but running in parallel: |
860 |
|
861 |
my @datas = map $_->result, |
862 |
map $fcp->txn_client_get ($_), |
863 |
@urls; |
864 |
|
865 |
Both blocking examples work without the module user having to know |
866 |
anything about events. |
867 |
|
868 |
3a. Event-based in a main program, using any supported event module: |
869 |
|
870 |
use EV; |
871 |
|
872 |
$fcp->txn_client_get ($url)->cb (sub { |
873 |
my $txn = shift; |
874 |
my $data = $txn->result; |
875 |
... |
876 |
}); |
877 |
|
878 |
EV::loop; |
879 |
|
880 |
3b. The module user could use AnyEvent, too: |
881 |
|
882 |
use AnyEvent; |
883 |
|
884 |
my $quit = AnyEvent->condvar; |
885 |
|
886 |
$fcp->txn_client_get ($url)->cb (sub { |
887 |
... |
888 |
$quit->broadcast; |
889 |
}); |
890 |
|
891 |
$quit->wait; |
892 |
|
893 |
|
894 |
=head1 BENCHMARK |
895 |
|
896 |
To give you an idea of the performance and overheads that AnyEvent adds |
897 |
over the event loops themselves (and to give you an impression of the |
898 |
speed of various event loops), here is a benchmark of various supported |
899 |
event models natively and with anyevent. The benchmark creates a lot of |
900 |
timers (with a zero timeout) and I/O watchers (watching STDOUT, a pty, to |
901 |
become writable, which it is), lets them fire exactly once and destroys |
902 |
them again. |
903 |
|
904 |
Rewriting the benchmark to use many different sockets instead of using |
905 |
the same filehandle for all I/O watchers results in a much longer runtime |
906 |
(socket creation is expensive), but qualitatively the same figures, so it |
907 |
was not used. |
908 |
|
909 |
=head2 Explanation of the columns |
910 |
|
911 |
I<watcher> is the number of event watchers created/destroyed. Since |
912 |
different event models feature vastly different performances, each event |
913 |
loop was given a number of watchers so that overall runtime is acceptable |
914 |
and similar between tested event loop (and keep them from crashing): Glib |
915 |
would probably take thousands of years if asked to process the same number |
916 |
of watchers as EV in this benchmark. |
917 |
|
918 |
I<bytes> is the number of bytes (as measured by the resident set size, |
919 |
RSS) consumed by each watcher. This method of measuring captures both C |
920 |
and Perl-based overheads. |
921 |
|
922 |
I<create> is the time, in microseconds (millionths of seconds), that it |
923 |
takes to create a single watcher. The callback is a closure shared between |
924 |
all watchers, to avoid adding memory overhead. That means closure creation |
925 |
and memory usage is not included in the figures. |
926 |
|
927 |
I<invoke> is the time, in microseconds, used to invoke a simple |
928 |
callback. The callback simply counts down a Perl variable and after it was |
929 |
invoked "watcher" times, it would C<< ->broadcast >> a condvar once to |
930 |
signal the end of this phase. |
931 |
|
932 |
I<destroy> is the time, in microseconds, that it takes to destroy a single |
933 |
watcher. |
934 |
|
935 |
=head2 Results |
936 |
|
937 |
name watchers bytes create invoke destroy comment |
938 |
EV/EV 400000 244 0.56 0.46 0.31 EV native interface |
939 |
EV/Any 100000 244 2.50 0.46 0.29 EV + AnyEvent watchers |
940 |
CoroEV/Any 100000 244 2.49 0.44 0.29 coroutines + Coro::Signal |
941 |
Perl/Any 100000 513 4.92 0.87 1.12 pure perl implementation |
942 |
Event/Event 16000 516 31.88 31.30 0.85 Event native interface |
943 |
Event/Any 16000 936 39.17 33.63 1.43 Event + AnyEvent watchers |
944 |
Glib/Any 16000 1357 98.22 12.41 54.00 quadratic behaviour |
945 |
Tk/Any 2000 1860 26.97 67.98 14.00 SEGV with >> 2000 watchers |
946 |
POE/Event 2000 6644 108.64 736.02 14.73 via POE::Loop::Event |
947 |
POE/Select 2000 6343 94.13 809.12 565.96 via POE::Loop::Select |
948 |
|
949 |
=head2 Discussion |
950 |
|
951 |
The benchmark does I<not> measure scalability of the event loop very |
952 |
well. For example, a select-based event loop (such as the pure perl one) |
953 |
can never compete with an event loop that uses epoll when the number of |
954 |
file descriptors grows high. In this benchmark, all events become ready at |
955 |
the same time, so select/poll-based implementations get an unnatural speed |
956 |
boost. |
957 |
|
958 |
C<EV> is the sole leader regarding speed and memory use, which are both |
959 |
maximal/minimal, respectively. Even when going through AnyEvent, it uses |
960 |
far less memory than any other event loop and is still faster than Event |
961 |
natively. |
962 |
|
963 |
The pure perl implementation is hit in a few sweet spots (both the |
964 |
zero timeout and the use of a single fd hit optimisations in the perl |
965 |
interpreter and the backend itself, and all watchers become ready at the |
966 |
same time). Nevertheless this shows that it adds very little overhead in |
967 |
itself. Like any select-based backend its performance becomes really bad |
968 |
with lots of file descriptors (and few of them active), of course, but |
969 |
this was not subject of this benchmark. |
970 |
|
971 |
The C<Event> module has a relatively high setup and callback invocation cost, |
972 |
but overall scores on the third place. |
973 |
|
974 |
C<Glib>'s memory usage is quite a bit bit higher, but it features a |
975 |
faster callback invocation and overall ends up in the same class as |
976 |
C<Event>. However, Glib scales extremely badly, doubling the number of |
977 |
watchers increases the processing time by more than a factor of four, |
978 |
making it completely unusable when using larger numbers of watchers |
979 |
(note that only a single file descriptor was used in the benchmark, so |
980 |
inefficiencies of C<poll> do not account for this). |
981 |
|
982 |
The C<Tk> adaptor works relatively well. The fact that it crashes with |
983 |
more than 2000 watchers is a big setback, however, as correctness takes |
984 |
precedence over speed. Nevertheless, its performance is surprising, as the |
985 |
file descriptor is dup()ed for each watcher. This shows that the dup() |
986 |
employed by some adaptors is not a big performance issue (it does incur a |
987 |
hidden memory cost inside the kernel, though, that is not reflected in the |
988 |
figures above). |
989 |
|
990 |
C<POE>, regardless of underlying event loop (wether using its pure perl |
991 |
select-based backend or the Event module) shows abysmal performance and |
992 |
memory usage: Watchers use almost 30 times as much memory as EV watchers, |
993 |
and 10 times as much memory as both Event or EV via AnyEvent. Watcher |
994 |
invocation is almost 900 times slower than with AnyEvent's pure perl |
995 |
implementation. The design of the POE adaptor class in AnyEvent can not |
996 |
really account for this, as session creation overhead is small compared |
997 |
to execution of the state machine, which is coded pretty optimally within |
998 |
L<AnyEvent::Impl::POE>. POE simply seems to be abysmally slow. |
999 |
|
1000 |
=head2 Summary |
1001 |
|
1002 |
Using EV through AnyEvent is faster than any other event loop, but most |
1003 |
event loops have acceptable performance with or without AnyEvent. |
1004 |
|
1005 |
The overhead AnyEvent adds is usually much smaller than the overhead of |
1006 |
the actual event loop, only with extremely fast event loops such as the EV |
1007 |
adds AnyEvent significant overhead. |
1008 |
|
1009 |
And you should simply avoid POE like the plague if you want performance or |
1010 |
reasonable memory usage. |
1011 |
|
1012 |
|
1013 |
=head1 FORK |
1014 |
|
1015 |
Most event libraries are not fork-safe. The ones who are usually are |
1016 |
because they are so inefficient. Only L<EV> is fully fork-aware. |
1017 |
|
1018 |
If you have to fork, you must either do so I<before> creating your first |
1019 |
watcher OR you must not use AnyEvent at all in the child. |
1020 |
|
1021 |
|
1022 |
=head1 SECURITY CONSIDERATIONS |
1023 |
|
1024 |
AnyEvent can be forced to load any event model via |
1025 |
$ENV{PERL_ANYEVENT_MODEL}. While this cannot (to my knowledge) be used to |
1026 |
execute arbitrary code or directly gain access, it can easily be used to |
1027 |
make the program hang or malfunction in subtle ways, as AnyEvent watchers |
1028 |
will not be active when the program uses a different event model than |
1029 |
specified in the variable. |
1030 |
|
1031 |
You can make AnyEvent completely ignore this variable by deleting it |
1032 |
before the first watcher gets created, e.g. with a C<BEGIN> block: |
1033 |
|
1034 |
BEGIN { delete $ENV{PERL_ANYEVENT_MODEL} } |
1035 |
|
1036 |
use AnyEvent; |
1037 |
|
1038 |
|
1039 |
=head1 SEE ALSO |
1040 |
|
1041 |
Event modules: L<Coro::EV>, L<EV>, L<EV::Glib>, L<Glib::EV>, |
1042 |
L<Coro::Event>, L<Event>, L<Glib::Event>, L<Glib>, L<Coro>, L<Tk>, |
1043 |
L<Event::Lib>, L<Qt>, L<POE>. |
1044 |
|
1045 |
Implementations: L<AnyEvent::Impl::CoroEV>, L<AnyEvent::Impl::EV>, |
1046 |
L<AnyEvent::Impl::CoroEvent>, L<AnyEvent::Impl::Event>, L<AnyEvent::Impl::Glib>, |
1047 |
L<AnyEvent::Impl::Tk>, L<AnyEvent::Impl::Perl>, L<AnyEvent::Impl::EventLib>, |
1048 |
L<AnyEvent::Impl::Qt>, L<AnyEvent::Impl::POE>. |
1049 |
|
1050 |
Nontrivial usage examples: L<Net::FCP>, L<Net::XMPP2>. |
1051 |
|
1052 |
|
1053 |
=head1 AUTHOR |
1054 |
|
1055 |
Marc Lehmann <schmorp@schmorp.de> |
1056 |
http://home.schmorp.de/ |
1057 |
|
1058 |
=cut |
1059 |
|
1060 |
1 |
1061 |
|