1 |
=head1 NAME |
2 |
|
3 |
AnyEvent - provide framework for multiple event loops |
4 |
|
5 |
EV, Event, Coro::EV, Coro::Event, Glib, Tk, Perl, Event::Lib, Qt, POE - various supported event loops |
6 |
|
7 |
=head1 SYNOPSIS |
8 |
|
9 |
use AnyEvent; |
10 |
|
11 |
my $w = AnyEvent->io (fh => $fh, poll => "r|w", cb => sub { |
12 |
... |
13 |
}); |
14 |
|
15 |
my $w = AnyEvent->timer (after => $seconds, cb => sub { |
16 |
... |
17 |
}); |
18 |
|
19 |
my $w = AnyEvent->condvar; # stores whether a condition was flagged |
20 |
$w->wait; # enters "main loop" till $condvar gets ->broadcast |
21 |
$w->broadcast; # wake up current and all future wait's |
22 |
|
23 |
=head1 WHY YOU SHOULD USE THIS MODULE (OR NOT) |
24 |
|
25 |
Glib, POE, IO::Async, Event... CPAN offers event models by the dozen |
26 |
nowadays. So what is different about AnyEvent? |
27 |
|
28 |
Executive Summary: AnyEvent is I<compatible>, AnyEvent is I<free of |
29 |
policy> and AnyEvent is I<small and efficient>. |
30 |
|
31 |
First and foremost, I<AnyEvent is not an event model> itself, it only |
32 |
interfaces to whatever event model the main program happens to use in a |
33 |
pragmatic way. For event models and certain classes of immortals alike, |
34 |
the statement "there can only be one" is a bitter reality: In general, |
35 |
only one event loop can be active at the same time in a process. AnyEvent |
36 |
helps hiding the differences between those event loops. |
37 |
|
38 |
The goal of AnyEvent is to offer module authors the ability to do event |
39 |
programming (waiting for I/O or timer events) without subscribing to a |
40 |
religion, a way of living, and most importantly: without forcing your |
41 |
module users into the same thing by forcing them to use the same event |
42 |
model you use. |
43 |
|
44 |
For modules like POE or IO::Async (which is a total misnomer as it is |
45 |
actually doing all I/O I<synchronously>...), using them in your module is |
46 |
like joining a cult: After you joined, you are dependent on them and you |
47 |
cannot use anything else, as it is simply incompatible to everything that |
48 |
isn't itself. What's worse, all the potential users of your module are |
49 |
I<also> forced to use the same event loop you use. |
50 |
|
51 |
AnyEvent is different: AnyEvent + POE works fine. AnyEvent + Glib works |
52 |
fine. AnyEvent + Tk works fine etc. etc. but none of these work together |
53 |
with the rest: POE + IO::Async? no go. Tk + Event? no go. Again: if |
54 |
your module uses one of those, every user of your module has to use it, |
55 |
too. But if your module uses AnyEvent, it works transparently with all |
56 |
event models it supports (including stuff like POE and IO::Async, as long |
57 |
as those use one of the supported event loops. It is trivial to add new |
58 |
event loops to AnyEvent, too, so it is future-proof). |
59 |
|
60 |
In addition to being free of having to use I<the one and only true event |
61 |
model>, AnyEvent also is free of bloat and policy: with POE or similar |
62 |
modules, you get an enourmous amount of code and strict rules you have to |
63 |
follow. AnyEvent, on the other hand, is lean and up to the point, by only |
64 |
offering the functionality that is necessary, in as thin as a wrapper as |
65 |
technically possible. |
66 |
|
67 |
Of course, if you want lots of policy (this can arguably be somewhat |
68 |
useful) and you want to force your users to use the one and only event |
69 |
model, you should I<not> use this module. |
70 |
|
71 |
#TODO# |
72 |
|
73 |
Net::IRC3 |
74 |
AnyEvent::HTTPD |
75 |
AnyEvent::DNS |
76 |
IO::AnyEvent |
77 |
Net::FPing |
78 |
Net::XMPP2 |
79 |
Coro |
80 |
|
81 |
AnyEvent::IRC |
82 |
AnyEvent::HTTPD |
83 |
AnyEvent::DNS |
84 |
AnyEvent::Handle |
85 |
AnyEvent::Socket |
86 |
AnyEvent::FPing |
87 |
AnyEvent::XMPP |
88 |
AnyEvent::SNMP |
89 |
Coro |
90 |
|
91 |
=head1 DESCRIPTION |
92 |
|
93 |
L<AnyEvent> provides an identical interface to multiple event loops. This |
94 |
allows module authors to utilise an event loop without forcing module |
95 |
users to use the same event loop (as only a single event loop can coexist |
96 |
peacefully at any one time). |
97 |
|
98 |
The interface itself is vaguely similar, but not identical to the L<Event> |
99 |
module. |
100 |
|
101 |
During the first call of any watcher-creation method, the module tries |
102 |
to detect the currently loaded event loop by probing whether one of the |
103 |
following modules is already loaded: L<Coro::EV>, L<Coro::Event>, L<EV>, |
104 |
L<Event>, L<Glib>, L<AnyEvent::Impl::Perl>, L<Tk>, L<Event::Lib>, L<Qt>, |
105 |
L<POE>. The first one found is used. If none are found, the module tries |
106 |
to load these modules (excluding Tk, Event::Lib, Qt and POE as the pure perl |
107 |
adaptor should always succeed) in the order given. The first one that can |
108 |
be successfully loaded will be used. If, after this, still none could be |
109 |
found, AnyEvent will fall back to a pure-perl event loop, which is not |
110 |
very efficient, but should work everywhere. |
111 |
|
112 |
Because AnyEvent first checks for modules that are already loaded, loading |
113 |
an event model explicitly before first using AnyEvent will likely make |
114 |
that model the default. For example: |
115 |
|
116 |
use Tk; |
117 |
use AnyEvent; |
118 |
|
119 |
# .. AnyEvent will likely default to Tk |
120 |
|
121 |
The I<likely> means that, if any module loads another event model and |
122 |
starts using it, all bets are off. Maybe you should tell their authors to |
123 |
use AnyEvent so their modules work together with others seamlessly... |
124 |
|
125 |
The pure-perl implementation of AnyEvent is called |
126 |
C<AnyEvent::Impl::Perl>. Like other event modules you can load it |
127 |
explicitly. |
128 |
|
129 |
=head1 WATCHERS |
130 |
|
131 |
AnyEvent has the central concept of a I<watcher>, which is an object that |
132 |
stores relevant data for each kind of event you are waiting for, such as |
133 |
the callback to call, the filehandle to watch, etc. |
134 |
|
135 |
These watchers are normal Perl objects with normal Perl lifetime. After |
136 |
creating a watcher it will immediately "watch" for events and invoke the |
137 |
callback when the event occurs (of course, only when the event model |
138 |
is in control). |
139 |
|
140 |
To disable the watcher you have to destroy it (e.g. by setting the |
141 |
variable you store it in to C<undef> or otherwise deleting all references |
142 |
to it). |
143 |
|
144 |
All watchers are created by calling a method on the C<AnyEvent> class. |
145 |
|
146 |
Many watchers either are used with "recursion" (repeating timers for |
147 |
example), or need to refer to their watcher object in other ways. |
148 |
|
149 |
An any way to achieve that is this pattern: |
150 |
|
151 |
my $w; $w = AnyEvent->type (arg => value ..., cb => sub { |
152 |
# you can use $w here, for example to undef it |
153 |
undef $w; |
154 |
}); |
155 |
|
156 |
Note that C<my $w; $w => combination. This is necessary because in Perl, |
157 |
my variables are only visible after the statement in which they are |
158 |
declared. |
159 |
|
160 |
=head2 I/O WATCHERS |
161 |
|
162 |
You can create an I/O watcher by calling the C<< AnyEvent->io >> method |
163 |
with the following mandatory key-value pairs as arguments: |
164 |
|
165 |
C<fh> the Perl I<file handle> (I<not> file descriptor) to watch |
166 |
for events. C<poll> must be a string that is either C<r> or C<w>, |
167 |
which creates a watcher waiting for "r"eadable or "w"ritable events, |
168 |
respectively. C<cb> is the callback to invoke each time the file handle |
169 |
becomes ready. |
170 |
|
171 |
Although the callback might get passed parameters, their value and |
172 |
presence is undefined and you cannot rely on them. Portable AnyEvent |
173 |
callbacks cannot use arguments passed to I/O watcher callbacks. |
174 |
|
175 |
The I/O watcher might use the underlying file descriptor or a copy of it. |
176 |
You must not close a file handle as long as any watcher is active on the |
177 |
underlying file descriptor. |
178 |
|
179 |
Some event loops issue spurious readyness notifications, so you should |
180 |
always use non-blocking calls when reading/writing from/to your file |
181 |
handles. |
182 |
|
183 |
Example: |
184 |
|
185 |
# wait for readability of STDIN, then read a line and disable the watcher |
186 |
my $w; $w = AnyEvent->io (fh => \*STDIN, poll => 'r', cb => sub { |
187 |
chomp (my $input = <STDIN>); |
188 |
warn "read: $input\n"; |
189 |
undef $w; |
190 |
}); |
191 |
|
192 |
=head2 TIME WATCHERS |
193 |
|
194 |
You can create a time watcher by calling the C<< AnyEvent->timer >> |
195 |
method with the following mandatory arguments: |
196 |
|
197 |
C<after> specifies after how many seconds (fractional values are |
198 |
supported) the callback should be invoked. C<cb> is the callback to invoke |
199 |
in that case. |
200 |
|
201 |
Although the callback might get passed parameters, their value and |
202 |
presence is undefined and you cannot rely on them. Portable AnyEvent |
203 |
callbacks cannot use arguments passed to time watcher callbacks. |
204 |
|
205 |
The timer callback will be invoked at most once: if you want a repeating |
206 |
timer you have to create a new watcher (this is a limitation by both Tk |
207 |
and Glib). |
208 |
|
209 |
Example: |
210 |
|
211 |
# fire an event after 7.7 seconds |
212 |
my $w = AnyEvent->timer (after => 7.7, cb => sub { |
213 |
warn "timeout\n"; |
214 |
}); |
215 |
|
216 |
# to cancel the timer: |
217 |
undef $w; |
218 |
|
219 |
Example 2: |
220 |
|
221 |
# fire an event after 0.5 seconds, then roughly every second |
222 |
my $w; |
223 |
|
224 |
my $cb = sub { |
225 |
# cancel the old timer while creating a new one |
226 |
$w = AnyEvent->timer (after => 1, cb => $cb); |
227 |
}; |
228 |
|
229 |
# start the "loop" by creating the first watcher |
230 |
$w = AnyEvent->timer (after => 0.5, cb => $cb); |
231 |
|
232 |
=head3 TIMING ISSUES |
233 |
|
234 |
There are two ways to handle timers: based on real time (relative, "fire |
235 |
in 10 seconds") and based on wallclock time (absolute, "fire at 12 |
236 |
o'clock"). |
237 |
|
238 |
While most event loops expect timers to specified in a relative way, they |
239 |
use absolute time internally. This makes a difference when your clock |
240 |
"jumps", for example, when ntp decides to set your clock backwards from |
241 |
the wrong date of 2014-01-01 to 2008-01-01, a watcher that is supposed to |
242 |
fire "after" a second might actually take six years to finally fire. |
243 |
|
244 |
AnyEvent cannot compensate for this. The only event loop that is conscious |
245 |
about these issues is L<EV>, which offers both relative (ev_timer, based |
246 |
on true relative time) and absolute (ev_periodic, based on wallclock time) |
247 |
timers. |
248 |
|
249 |
AnyEvent always prefers relative timers, if available, matching the |
250 |
AnyEvent API. |
251 |
|
252 |
=head2 SIGNAL WATCHERS |
253 |
|
254 |
You can watch for signals using a signal watcher, C<signal> is the signal |
255 |
I<name> without any C<SIG> prefix, C<cb> is the Perl callback to |
256 |
be invoked whenever a signal occurs. |
257 |
|
258 |
Although the callback might get passed parameters, their value and |
259 |
presence is undefined and you cannot rely on them. Portable AnyEvent |
260 |
callbacks cannot use arguments passed to signal watcher callbacks. |
261 |
|
262 |
Multiple signal occurances can be clumped together into one callback |
263 |
invocation, and callback invocation will be synchronous. synchronous means |
264 |
that it might take a while until the signal gets handled by the process, |
265 |
but it is guarenteed not to interrupt any other callbacks. |
266 |
|
267 |
The main advantage of using these watchers is that you can share a signal |
268 |
between multiple watchers. |
269 |
|
270 |
This watcher might use C<%SIG>, so programs overwriting those signals |
271 |
directly will likely not work correctly. |
272 |
|
273 |
Example: exit on SIGINT |
274 |
|
275 |
my $w = AnyEvent->signal (signal => "INT", cb => sub { exit 1 }); |
276 |
|
277 |
=head2 CHILD PROCESS WATCHERS |
278 |
|
279 |
You can also watch on a child process exit and catch its exit status. |
280 |
|
281 |
The child process is specified by the C<pid> argument (if set to C<0>, it |
282 |
watches for any child process exit). The watcher will trigger as often |
283 |
as status change for the child are received. This works by installing a |
284 |
signal handler for C<SIGCHLD>. The callback will be called with the pid |
285 |
and exit status (as returned by waitpid), so unlike other watcher types, |
286 |
you I<can> rely on child watcher callback arguments. |
287 |
|
288 |
There is a slight catch to child watchers, however: you usually start them |
289 |
I<after> the child process was created, and this means the process could |
290 |
have exited already (and no SIGCHLD will be sent anymore). |
291 |
|
292 |
Not all event models handle this correctly (POE doesn't), but even for |
293 |
event models that I<do> handle this correctly, they usually need to be |
294 |
loaded before the process exits (i.e. before you fork in the first place). |
295 |
|
296 |
This means you cannot create a child watcher as the very first thing in an |
297 |
AnyEvent program, you I<have> to create at least one watcher before you |
298 |
C<fork> the child (alternatively, you can call C<AnyEvent::detect>). |
299 |
|
300 |
Example: fork a process and wait for it |
301 |
|
302 |
my $done = AnyEvent->condvar; |
303 |
|
304 |
AnyEvent::detect; # force event module to be initialised |
305 |
|
306 |
my $pid = fork or exit 5; |
307 |
|
308 |
my $w = AnyEvent->child ( |
309 |
pid => $pid, |
310 |
cb => sub { |
311 |
my ($pid, $status) = @_; |
312 |
warn "pid $pid exited with status $status"; |
313 |
$done->broadcast; |
314 |
}, |
315 |
); |
316 |
|
317 |
# do something else, then wait for process exit |
318 |
$done->wait; |
319 |
|
320 |
=head2 CONDITION VARIABLES |
321 |
|
322 |
Condition variables can be created by calling the C<< AnyEvent->condvar >> |
323 |
method without any arguments. |
324 |
|
325 |
A condition variable waits for a condition - precisely that the C<< |
326 |
->broadcast >> method has been called. |
327 |
|
328 |
They are very useful to signal that a condition has been fulfilled, for |
329 |
example, if you write a module that does asynchronous http requests, |
330 |
then a condition variable would be the ideal candidate to signal the |
331 |
availability of results. |
332 |
|
333 |
You can also use condition variables to block your main program until |
334 |
an event occurs - for example, you could C<< ->wait >> in your main |
335 |
program until the user clicks the Quit button in your app, which would C<< |
336 |
->broadcast >> the "quit" event. |
337 |
|
338 |
Note that condition variables recurse into the event loop - if you have |
339 |
two pirces of code that call C<< ->wait >> in a round-robbin fashion, you |
340 |
lose. Therefore, condition variables are good to export to your caller, but |
341 |
you should avoid making a blocking wait yourself, at least in callbacks, |
342 |
as this asks for trouble. |
343 |
|
344 |
This object has two methods: |
345 |
|
346 |
=over 4 |
347 |
|
348 |
=item $cv->wait |
349 |
|
350 |
Wait (blocking if necessary) until the C<< ->broadcast >> method has been |
351 |
called on c<$cv>, while servicing other watchers normally. |
352 |
|
353 |
You can only wait once on a condition - additional calls will return |
354 |
immediately. |
355 |
|
356 |
Not all event models support a blocking wait - some die in that case |
357 |
(programs might want to do that to stay interactive), so I<if you are |
358 |
using this from a module, never require a blocking wait>, but let the |
359 |
caller decide whether the call will block or not (for example, by coupling |
360 |
condition variables with some kind of request results and supporting |
361 |
callbacks so the caller knows that getting the result will not block, |
362 |
while still suppporting blocking waits if the caller so desires). |
363 |
|
364 |
Another reason I<never> to C<< ->wait >> in a module is that you cannot |
365 |
sensibly have two C<< ->wait >>'s in parallel, as that would require |
366 |
multiple interpreters or coroutines/threads, none of which C<AnyEvent> |
367 |
can supply (the coroutine-aware backends L<AnyEvent::Impl::CoroEV> and |
368 |
L<AnyEvent::Impl::CoroEvent> explicitly support concurrent C<< ->wait >>'s |
369 |
from different coroutines, however). |
370 |
|
371 |
=item $cv->broadcast |
372 |
|
373 |
Flag the condition as ready - a running C<< ->wait >> and all further |
374 |
calls to C<wait> will (eventually) return after this method has been |
375 |
called. If nobody is waiting the broadcast will be remembered.. |
376 |
|
377 |
=back |
378 |
|
379 |
Example: |
380 |
|
381 |
# wait till the result is ready |
382 |
my $result_ready = AnyEvent->condvar; |
383 |
|
384 |
# do something such as adding a timer |
385 |
# or socket watcher the calls $result_ready->broadcast |
386 |
# when the "result" is ready. |
387 |
# in this case, we simply use a timer: |
388 |
my $w = AnyEvent->timer ( |
389 |
after => 1, |
390 |
cb => sub { $result_ready->broadcast }, |
391 |
); |
392 |
|
393 |
# this "blocks" (while handling events) till the watcher |
394 |
# calls broadcast |
395 |
$result_ready->wait; |
396 |
|
397 |
=head1 GLOBAL VARIABLES AND FUNCTIONS |
398 |
|
399 |
=over 4 |
400 |
|
401 |
=item $AnyEvent::MODEL |
402 |
|
403 |
Contains C<undef> until the first watcher is being created. Then it |
404 |
contains the event model that is being used, which is the name of the |
405 |
Perl class implementing the model. This class is usually one of the |
406 |
C<AnyEvent::Impl:xxx> modules, but can be any other class in the case |
407 |
AnyEvent has been extended at runtime (e.g. in I<rxvt-unicode>). |
408 |
|
409 |
The known classes so far are: |
410 |
|
411 |
AnyEvent::Impl::CoroEV based on Coro::EV, best choice. |
412 |
AnyEvent::Impl::CoroEvent based on Coro::Event, second best choice. |
413 |
AnyEvent::Impl::EV based on EV (an interface to libev, best choice). |
414 |
AnyEvent::Impl::Event based on Event, second best choice. |
415 |
AnyEvent::Impl::Glib based on Glib, third-best choice. |
416 |
AnyEvent::Impl::Perl pure-perl implementation, inefficient but portable. |
417 |
AnyEvent::Impl::Tk based on Tk, very bad choice. |
418 |
AnyEvent::Impl::Qt based on Qt, cannot be autoprobed (see its docs). |
419 |
AnyEvent::Impl::EventLib based on Event::Lib, leaks memory and worse. |
420 |
AnyEvent::Impl::POE based on POE, not generic enough for full support. |
421 |
|
422 |
There is no support for WxWidgets, as WxWidgets has no support for |
423 |
watching file handles. However, you can use WxWidgets through the |
424 |
POE Adaptor, as POE has a Wx backend that simply polls 20 times per |
425 |
second, which was considered to be too horrible to even consider for |
426 |
AnyEvent. Likewise, other POE backends can be used by AnyEvent by using |
427 |
it's adaptor. |
428 |
|
429 |
AnyEvent knows about L<Prima> and L<Wx> and will try to use L<POE> when |
430 |
autodetecting them. |
431 |
|
432 |
=item AnyEvent::detect |
433 |
|
434 |
Returns C<$AnyEvent::MODEL>, forcing autodetection of the event model |
435 |
if necessary. You should only call this function right before you would |
436 |
have created an AnyEvent watcher anyway, that is, as late as possible at |
437 |
runtime. |
438 |
|
439 |
=back |
440 |
|
441 |
=head1 WHAT TO DO IN A MODULE |
442 |
|
443 |
As a module author, you should C<use AnyEvent> and call AnyEvent methods |
444 |
freely, but you should not load a specific event module or rely on it. |
445 |
|
446 |
Be careful when you create watchers in the module body - AnyEvent will |
447 |
decide which event module to use as soon as the first method is called, so |
448 |
by calling AnyEvent in your module body you force the user of your module |
449 |
to load the event module first. |
450 |
|
451 |
Never call C<< ->wait >> on a condition variable unless you I<know> that |
452 |
the C<< ->broadcast >> method has been called on it already. This is |
453 |
because it will stall the whole program, and the whole point of using |
454 |
events is to stay interactive. |
455 |
|
456 |
It is fine, however, to call C<< ->wait >> when the user of your module |
457 |
requests it (i.e. if you create a http request object ad have a method |
458 |
called C<results> that returns the results, it should call C<< ->wait >> |
459 |
freely, as the user of your module knows what she is doing. always). |
460 |
|
461 |
=head1 WHAT TO DO IN THE MAIN PROGRAM |
462 |
|
463 |
There will always be a single main program - the only place that should |
464 |
dictate which event model to use. |
465 |
|
466 |
If it doesn't care, it can just "use AnyEvent" and use it itself, or not |
467 |
do anything special (it does not need to be event-based) and let AnyEvent |
468 |
decide which implementation to chose if some module relies on it. |
469 |
|
470 |
If the main program relies on a specific event model. For example, in |
471 |
Gtk2 programs you have to rely on the Glib module. You should load the |
472 |
event module before loading AnyEvent or any module that uses it: generally |
473 |
speaking, you should load it as early as possible. The reason is that |
474 |
modules might create watchers when they are loaded, and AnyEvent will |
475 |
decide on the event model to use as soon as it creates watchers, and it |
476 |
might chose the wrong one unless you load the correct one yourself. |
477 |
|
478 |
You can chose to use a rather inefficient pure-perl implementation by |
479 |
loading the C<AnyEvent::Impl::Perl> module, which gives you similar |
480 |
behaviour everywhere, but letting AnyEvent chose is generally better. |
481 |
|
482 |
=cut |
483 |
|
484 |
package AnyEvent; |
485 |
|
486 |
no warnings; |
487 |
use strict; |
488 |
|
489 |
use Carp; |
490 |
|
491 |
our $VERSION = '3.3'; |
492 |
our $MODEL; |
493 |
|
494 |
our $AUTOLOAD; |
495 |
our @ISA; |
496 |
|
497 |
our $verbose = $ENV{PERL_ANYEVENT_VERBOSE}*1; |
498 |
|
499 |
our @REGISTRY; |
500 |
|
501 |
my @models = ( |
502 |
[Coro::EV:: => AnyEvent::Impl::CoroEV::], |
503 |
[Coro::Event:: => AnyEvent::Impl::CoroEvent::], |
504 |
[EV:: => AnyEvent::Impl::EV::], |
505 |
[Event:: => AnyEvent::Impl::Event::], |
506 |
[Glib:: => AnyEvent::Impl::Glib::], |
507 |
[Tk:: => AnyEvent::Impl::Tk::], |
508 |
[Wx:: => AnyEvent::Impl::POE::], |
509 |
[Prima:: => AnyEvent::Impl::POE::], |
510 |
[AnyEvent::Impl::Perl:: => AnyEvent::Impl::Perl::], |
511 |
# everything below here will not be autoprobed as the pureperl backend should work everywhere |
512 |
[Event::Lib:: => AnyEvent::Impl::EventLib::], # too buggy |
513 |
[Qt:: => AnyEvent::Impl::Qt::], # requires special main program |
514 |
[POE::Kernel:: => AnyEvent::Impl::POE::], # lasciate ogni speranza |
515 |
); |
516 |
|
517 |
our %method = map +($_ => 1), qw(io timer signal child condvar broadcast wait one_event DESTROY); |
518 |
|
519 |
sub detect() { |
520 |
unless ($MODEL) { |
521 |
no strict 'refs'; |
522 |
|
523 |
if ($ENV{PERL_ANYEVENT_MODEL} =~ /^([a-zA-Z]+)$/) { |
524 |
my $model = "AnyEvent::Impl::$1"; |
525 |
if (eval "require $model") { |
526 |
$MODEL = $model; |
527 |
warn "AnyEvent: loaded model '$model' (forced by \$PERL_ANYEVENT_MODEL), using it.\n" if $verbose > 1; |
528 |
} else { |
529 |
warn "AnyEvent: unable to load model '$model' (from \$PERL_ANYEVENT_MODEL):\n$@" if $verbose; |
530 |
} |
531 |
} |
532 |
|
533 |
# check for already loaded models |
534 |
unless ($MODEL) { |
535 |
for (@REGISTRY, @models) { |
536 |
my ($package, $model) = @$_; |
537 |
if (${"$package\::VERSION"} > 0) { |
538 |
if (eval "require $model") { |
539 |
$MODEL = $model; |
540 |
warn "AnyEvent: autodetected model '$model', using it.\n" if $verbose > 1; |
541 |
last; |
542 |
} |
543 |
} |
544 |
} |
545 |
|
546 |
unless ($MODEL) { |
547 |
# try to load a model |
548 |
|
549 |
for (@REGISTRY, @models) { |
550 |
my ($package, $model) = @$_; |
551 |
if (eval "require $package" |
552 |
and ${"$package\::VERSION"} > 0 |
553 |
and eval "require $model") { |
554 |
$MODEL = $model; |
555 |
warn "AnyEvent: autoprobed model '$model', using it.\n" if $verbose > 1; |
556 |
last; |
557 |
} |
558 |
} |
559 |
|
560 |
$MODEL |
561 |
or die "No event module selected for AnyEvent and autodetect failed. Install any one of these modules: EV (or Coro+EV), Event (or Coro+Event) or Glib."; |
562 |
} |
563 |
} |
564 |
|
565 |
unshift @ISA, $MODEL; |
566 |
push @{"$MODEL\::ISA"}, "AnyEvent::Base"; |
567 |
} |
568 |
|
569 |
$MODEL |
570 |
} |
571 |
|
572 |
sub AUTOLOAD { |
573 |
(my $func = $AUTOLOAD) =~ s/.*://; |
574 |
|
575 |
$method{$func} |
576 |
or croak "$func: not a valid method for AnyEvent objects"; |
577 |
|
578 |
detect unless $MODEL; |
579 |
|
580 |
my $class = shift; |
581 |
$class->$func (@_); |
582 |
} |
583 |
|
584 |
package AnyEvent::Base; |
585 |
|
586 |
# default implementation for ->condvar, ->wait, ->broadcast |
587 |
|
588 |
sub condvar { |
589 |
bless \my $flag, "AnyEvent::Base::CondVar" |
590 |
} |
591 |
|
592 |
sub AnyEvent::Base::CondVar::broadcast { |
593 |
${$_[0]}++; |
594 |
} |
595 |
|
596 |
sub AnyEvent::Base::CondVar::wait { |
597 |
AnyEvent->one_event while !${$_[0]}; |
598 |
} |
599 |
|
600 |
# default implementation for ->signal |
601 |
|
602 |
our %SIG_CB; |
603 |
|
604 |
sub signal { |
605 |
my (undef, %arg) = @_; |
606 |
|
607 |
my $signal = uc $arg{signal} |
608 |
or Carp::croak "required option 'signal' is missing"; |
609 |
|
610 |
$SIG_CB{$signal}{$arg{cb}} = $arg{cb}; |
611 |
$SIG{$signal} ||= sub { |
612 |
$_->() for values %{ $SIG_CB{$signal} || {} }; |
613 |
}; |
614 |
|
615 |
bless [$signal, $arg{cb}], "AnyEvent::Base::Signal" |
616 |
} |
617 |
|
618 |
sub AnyEvent::Base::Signal::DESTROY { |
619 |
my ($signal, $cb) = @{$_[0]}; |
620 |
|
621 |
delete $SIG_CB{$signal}{$cb}; |
622 |
|
623 |
$SIG{$signal} = 'DEFAULT' unless keys %{ $SIG_CB{$signal} }; |
624 |
} |
625 |
|
626 |
# default implementation for ->child |
627 |
|
628 |
our %PID_CB; |
629 |
our $CHLD_W; |
630 |
our $CHLD_DELAY_W; |
631 |
our $PID_IDLE; |
632 |
our $WNOHANG; |
633 |
|
634 |
sub _child_wait { |
635 |
while (0 < (my $pid = waitpid -1, $WNOHANG)) { |
636 |
$_->($pid, $?) for (values %{ $PID_CB{$pid} || {} }), |
637 |
(values %{ $PID_CB{0} || {} }); |
638 |
} |
639 |
|
640 |
undef $PID_IDLE; |
641 |
} |
642 |
|
643 |
sub _sigchld { |
644 |
# make sure we deliver these changes "synchronous" with the event loop. |
645 |
$CHLD_DELAY_W ||= AnyEvent->timer (after => 0, cb => sub { |
646 |
undef $CHLD_DELAY_W; |
647 |
&_child_wait; |
648 |
}); |
649 |
} |
650 |
|
651 |
sub child { |
652 |
my (undef, %arg) = @_; |
653 |
|
654 |
defined (my $pid = $arg{pid} + 0) |
655 |
or Carp::croak "required option 'pid' is missing"; |
656 |
|
657 |
$PID_CB{$pid}{$arg{cb}} = $arg{cb}; |
658 |
|
659 |
unless ($WNOHANG) { |
660 |
$WNOHANG = eval { require POSIX; &POSIX::WNOHANG } || 1; |
661 |
} |
662 |
|
663 |
unless ($CHLD_W) { |
664 |
$CHLD_W = AnyEvent->signal (signal => 'CHLD', cb => \&_sigchld); |
665 |
# child could be a zombie already, so make at least one round |
666 |
&_sigchld; |
667 |
} |
668 |
|
669 |
bless [$pid, $arg{cb}], "AnyEvent::Base::Child" |
670 |
} |
671 |
|
672 |
sub AnyEvent::Base::Child::DESTROY { |
673 |
my ($pid, $cb) = @{$_[0]}; |
674 |
|
675 |
delete $PID_CB{$pid}{$cb}; |
676 |
delete $PID_CB{$pid} unless keys %{ $PID_CB{$pid} }; |
677 |
|
678 |
undef $CHLD_W unless keys %PID_CB; |
679 |
} |
680 |
|
681 |
=head1 SUPPLYING YOUR OWN EVENT MODEL INTERFACE |
682 |
|
683 |
This is an advanced topic that you do not normally need to use AnyEvent in |
684 |
a module. This section is only of use to event loop authors who want to |
685 |
provide AnyEvent compatibility. |
686 |
|
687 |
If you need to support another event library which isn't directly |
688 |
supported by AnyEvent, you can supply your own interface to it by |
689 |
pushing, before the first watcher gets created, the package name of |
690 |
the event module and the package name of the interface to use onto |
691 |
C<@AnyEvent::REGISTRY>. You can do that before and even without loading |
692 |
AnyEvent, so it is reasonably cheap. |
693 |
|
694 |
Example: |
695 |
|
696 |
push @AnyEvent::REGISTRY, [urxvt => urxvt::anyevent::]; |
697 |
|
698 |
This tells AnyEvent to (literally) use the C<urxvt::anyevent::> |
699 |
package/class when it finds the C<urxvt> package/module is already loaded. |
700 |
|
701 |
When AnyEvent is loaded and asked to find a suitable event model, it |
702 |
will first check for the presence of urxvt by trying to C<use> the |
703 |
C<urxvt::anyevent> module. |
704 |
|
705 |
The class should provide implementations for all watcher types. See |
706 |
L<AnyEvent::Impl::EV> (source code), L<AnyEvent::Impl::Glib> (Source code) |
707 |
and so on for actual examples. Use C<perldoc -m AnyEvent::Impl::Glib> to |
708 |
see the sources. |
709 |
|
710 |
If you don't provide C<signal> and C<child> watchers than AnyEvent will |
711 |
provide suitable (hopefully) replacements. |
712 |
|
713 |
The above example isn't fictitious, the I<rxvt-unicode> (a.k.a. urxvt) |
714 |
terminal emulator uses the above line as-is. An interface isn't included |
715 |
in AnyEvent because it doesn't make sense outside the embedded interpreter |
716 |
inside I<rxvt-unicode>, and it is updated and maintained as part of the |
717 |
I<rxvt-unicode> distribution. |
718 |
|
719 |
I<rxvt-unicode> also cheats a bit by not providing blocking access to |
720 |
condition variables: code blocking while waiting for a condition will |
721 |
C<die>. This still works with most modules/usages, and blocking calls must |
722 |
not be done in an interactive application, so it makes sense. |
723 |
|
724 |
=head1 ENVIRONMENT VARIABLES |
725 |
|
726 |
The following environment variables are used by this module: |
727 |
|
728 |
=over 4 |
729 |
|
730 |
=item C<PERL_ANYEVENT_VERBOSE> |
731 |
|
732 |
By default, AnyEvent will be completely silent except in fatal |
733 |
conditions. You can set this environment variable to make AnyEvent more |
734 |
talkative. |
735 |
|
736 |
When set to C<1> or higher, causes AnyEvent to warn about unexpected |
737 |
conditions, such as not being able to load the event model specified by |
738 |
C<PERL_ANYEVENT_MODEL>. |
739 |
|
740 |
When set to C<2> or higher, cause AnyEvent to report to STDERR which event |
741 |
model it chooses. |
742 |
|
743 |
=item C<PERL_ANYEVENT_MODEL> |
744 |
|
745 |
This can be used to specify the event model to be used by AnyEvent, before |
746 |
autodetection and -probing kicks in. It must be a string consisting |
747 |
entirely of ASCII letters. The string C<AnyEvent::Impl::> gets prepended |
748 |
and the resulting module name is loaded and if the load was successful, |
749 |
used as event model. If it fails to load AnyEvent will proceed with |
750 |
autodetection and -probing. |
751 |
|
752 |
This functionality might change in future versions. |
753 |
|
754 |
For example, to force the pure perl model (L<AnyEvent::Impl::Perl>) you |
755 |
could start your program like this: |
756 |
|
757 |
PERL_ANYEVENT_MODEL=Perl perl ... |
758 |
|
759 |
=back |
760 |
|
761 |
=head1 EXAMPLE PROGRAM |
762 |
|
763 |
The following program uses an I/O watcher to read data from STDIN, a timer |
764 |
to display a message once per second, and a condition variable to quit the |
765 |
program when the user enters quit: |
766 |
|
767 |
use AnyEvent; |
768 |
|
769 |
my $cv = AnyEvent->condvar; |
770 |
|
771 |
my $io_watcher = AnyEvent->io ( |
772 |
fh => \*STDIN, |
773 |
poll => 'r', |
774 |
cb => sub { |
775 |
warn "io event <$_[0]>\n"; # will always output <r> |
776 |
chomp (my $input = <STDIN>); # read a line |
777 |
warn "read: $input\n"; # output what has been read |
778 |
$cv->broadcast if $input =~ /^q/i; # quit program if /^q/i |
779 |
}, |
780 |
); |
781 |
|
782 |
my $time_watcher; # can only be used once |
783 |
|
784 |
sub new_timer { |
785 |
$timer = AnyEvent->timer (after => 1, cb => sub { |
786 |
warn "timeout\n"; # print 'timeout' about every second |
787 |
&new_timer; # and restart the time |
788 |
}); |
789 |
} |
790 |
|
791 |
new_timer; # create first timer |
792 |
|
793 |
$cv->wait; # wait until user enters /^q/i |
794 |
|
795 |
=head1 REAL-WORLD EXAMPLE |
796 |
|
797 |
Consider the L<Net::FCP> module. It features (among others) the following |
798 |
API calls, which are to freenet what HTTP GET requests are to http: |
799 |
|
800 |
my $data = $fcp->client_get ($url); # blocks |
801 |
|
802 |
my $transaction = $fcp->txn_client_get ($url); # does not block |
803 |
$transaction->cb ( sub { ... } ); # set optional result callback |
804 |
my $data = $transaction->result; # possibly blocks |
805 |
|
806 |
The C<client_get> method works like C<LWP::Simple::get>: it requests the |
807 |
given URL and waits till the data has arrived. It is defined to be: |
808 |
|
809 |
sub client_get { $_[0]->txn_client_get ($_[1])->result } |
810 |
|
811 |
And in fact is automatically generated. This is the blocking API of |
812 |
L<Net::FCP>, and it works as simple as in any other, similar, module. |
813 |
|
814 |
More complicated is C<txn_client_get>: It only creates a transaction |
815 |
(completion, result, ...) object and initiates the transaction. |
816 |
|
817 |
my $txn = bless { }, Net::FCP::Txn::; |
818 |
|
819 |
It also creates a condition variable that is used to signal the completion |
820 |
of the request: |
821 |
|
822 |
$txn->{finished} = AnyAvent->condvar; |
823 |
|
824 |
It then creates a socket in non-blocking mode. |
825 |
|
826 |
socket $txn->{fh}, ...; |
827 |
fcntl $txn->{fh}, F_SETFL, O_NONBLOCK; |
828 |
connect $txn->{fh}, ... |
829 |
and !$!{EWOULDBLOCK} |
830 |
and !$!{EINPROGRESS} |
831 |
and Carp::croak "unable to connect: $!\n"; |
832 |
|
833 |
Then it creates a write-watcher which gets called whenever an error occurs |
834 |
or the connection succeeds: |
835 |
|
836 |
$txn->{w} = AnyEvent->io (fh => $txn->{fh}, poll => 'w', cb => sub { $txn->fh_ready_w }); |
837 |
|
838 |
And returns this transaction object. The C<fh_ready_w> callback gets |
839 |
called as soon as the event loop detects that the socket is ready for |
840 |
writing. |
841 |
|
842 |
The C<fh_ready_w> method makes the socket blocking again, writes the |
843 |
request data and replaces the watcher by a read watcher (waiting for reply |
844 |
data). The actual code is more complicated, but that doesn't matter for |
845 |
this example: |
846 |
|
847 |
fcntl $txn->{fh}, F_SETFL, 0; |
848 |
syswrite $txn->{fh}, $txn->{request} |
849 |
or die "connection or write error"; |
850 |
$txn->{w} = AnyEvent->io (fh => $txn->{fh}, poll => 'r', cb => sub { $txn->fh_ready_r }); |
851 |
|
852 |
Again, C<fh_ready_r> waits till all data has arrived, and then stores the |
853 |
result and signals any possible waiters that the request ahs finished: |
854 |
|
855 |
sysread $txn->{fh}, $txn->{buf}, length $txn->{$buf}; |
856 |
|
857 |
if (end-of-file or data complete) { |
858 |
$txn->{result} = $txn->{buf}; |
859 |
$txn->{finished}->broadcast; |
860 |
$txb->{cb}->($txn) of $txn->{cb}; # also call callback |
861 |
} |
862 |
|
863 |
The C<result> method, finally, just waits for the finished signal (if the |
864 |
request was already finished, it doesn't wait, of course, and returns the |
865 |
data: |
866 |
|
867 |
$txn->{finished}->wait; |
868 |
return $txn->{result}; |
869 |
|
870 |
The actual code goes further and collects all errors (C<die>s, exceptions) |
871 |
that occured during request processing. The C<result> method detects |
872 |
whether an exception as thrown (it is stored inside the $txn object) |
873 |
and just throws the exception, which means connection errors and other |
874 |
problems get reported tot he code that tries to use the result, not in a |
875 |
random callback. |
876 |
|
877 |
All of this enables the following usage styles: |
878 |
|
879 |
1. Blocking: |
880 |
|
881 |
my $data = $fcp->client_get ($url); |
882 |
|
883 |
2. Blocking, but running in parallel: |
884 |
|
885 |
my @datas = map $_->result, |
886 |
map $fcp->txn_client_get ($_), |
887 |
@urls; |
888 |
|
889 |
Both blocking examples work without the module user having to know |
890 |
anything about events. |
891 |
|
892 |
3a. Event-based in a main program, using any supported event module: |
893 |
|
894 |
use EV; |
895 |
|
896 |
$fcp->txn_client_get ($url)->cb (sub { |
897 |
my $txn = shift; |
898 |
my $data = $txn->result; |
899 |
... |
900 |
}); |
901 |
|
902 |
EV::loop; |
903 |
|
904 |
3b. The module user could use AnyEvent, too: |
905 |
|
906 |
use AnyEvent; |
907 |
|
908 |
my $quit = AnyEvent->condvar; |
909 |
|
910 |
$fcp->txn_client_get ($url)->cb (sub { |
911 |
... |
912 |
$quit->broadcast; |
913 |
}); |
914 |
|
915 |
$quit->wait; |
916 |
|
917 |
|
918 |
=head1 BENCHMARKS |
919 |
|
920 |
To give you an idea of the performance and overheads that AnyEvent adds |
921 |
over the event loops themselves and to give you an impression of the speed |
922 |
of various event loops I prepared some benchmarks. |
923 |
|
924 |
=head2 BENCHMARKING ANYEVENT OVERHEAD |
925 |
|
926 |
Here is a benchmark of various supported event models used natively and |
927 |
through anyevent. The benchmark creates a lot of timers (with a zero |
928 |
timeout) and I/O watchers (watching STDOUT, a pty, to become writable, |
929 |
which it is), lets them fire exactly once and destroys them again. |
930 |
|
931 |
Source code for this benchmark is found as F<eg/bench> in the AnyEvent |
932 |
distribution. |
933 |
|
934 |
=head3 Explanation of the columns |
935 |
|
936 |
I<watcher> is the number of event watchers created/destroyed. Since |
937 |
different event models feature vastly different performances, each event |
938 |
loop was given a number of watchers so that overall runtime is acceptable |
939 |
and similar between tested event loop (and keep them from crashing): Glib |
940 |
would probably take thousands of years if asked to process the same number |
941 |
of watchers as EV in this benchmark. |
942 |
|
943 |
I<bytes> is the number of bytes (as measured by the resident set size, |
944 |
RSS) consumed by each watcher. This method of measuring captures both C |
945 |
and Perl-based overheads. |
946 |
|
947 |
I<create> is the time, in microseconds (millionths of seconds), that it |
948 |
takes to create a single watcher. The callback is a closure shared between |
949 |
all watchers, to avoid adding memory overhead. That means closure creation |
950 |
and memory usage is not included in the figures. |
951 |
|
952 |
I<invoke> is the time, in microseconds, used to invoke a simple |
953 |
callback. The callback simply counts down a Perl variable and after it was |
954 |
invoked "watcher" times, it would C<< ->broadcast >> a condvar once to |
955 |
signal the end of this phase. |
956 |
|
957 |
I<destroy> is the time, in microseconds, that it takes to destroy a single |
958 |
watcher. |
959 |
|
960 |
=head3 Results |
961 |
|
962 |
name watchers bytes create invoke destroy comment |
963 |
EV/EV 400000 244 0.56 0.46 0.31 EV native interface |
964 |
EV/Any 100000 244 2.50 0.46 0.29 EV + AnyEvent watchers |
965 |
CoroEV/Any 100000 244 2.49 0.44 0.29 coroutines + Coro::Signal |
966 |
Perl/Any 100000 513 4.92 0.87 1.12 pure perl implementation |
967 |
Event/Event 16000 516 31.88 31.30 0.85 Event native interface |
968 |
Event/Any 16000 590 35.75 31.42 1.08 Event + AnyEvent watchers |
969 |
Glib/Any 16000 1357 98.22 12.41 54.00 quadratic behaviour |
970 |
Tk/Any 2000 1860 26.97 67.98 14.00 SEGV with >> 2000 watchers |
971 |
POE/Event 2000 6644 108.64 736.02 14.73 via POE::Loop::Event |
972 |
POE/Select 2000 6343 94.13 809.12 565.96 via POE::Loop::Select |
973 |
|
974 |
=head3 Discussion |
975 |
|
976 |
The benchmark does I<not> measure scalability of the event loop very |
977 |
well. For example, a select-based event loop (such as the pure perl one) |
978 |
can never compete with an event loop that uses epoll when the number of |
979 |
file descriptors grows high. In this benchmark, all events become ready at |
980 |
the same time, so select/poll-based implementations get an unnatural speed |
981 |
boost. |
982 |
|
983 |
Also, note that the number of watchers usually has a nonlinear effect on |
984 |
overall speed, that is, creating twice as many watchers doesn't take twice |
985 |
the time - usually it takes longer. This puts event loops tested with a |
986 |
higher number of watchers at a disadvantage. |
987 |
|
988 |
To put the range of results into perspective, consider that on the |
989 |
benchmark machine, handling an event takes roughly 1600 CPU cycles with |
990 |
EV, 3100 CPU cycles with AnyEvent's pure perl loop and almost 3000000 CPU |
991 |
cycles with POE. |
992 |
|
993 |
C<EV> is the sole leader regarding speed and memory use, which are both |
994 |
maximal/minimal, respectively. Even when going through AnyEvent, it uses |
995 |
far less memory than any other event loop and is still faster than Event |
996 |
natively. |
997 |
|
998 |
The pure perl implementation is hit in a few sweet spots (both the |
999 |
constant timeout and the use of a single fd hit optimisations in the perl |
1000 |
interpreter and the backend itself). Nevertheless this shows that it |
1001 |
adds very little overhead in itself. Like any select-based backend its |
1002 |
performance becomes really bad with lots of file descriptors (and few of |
1003 |
them active), of course, but this was not subject of this benchmark. |
1004 |
|
1005 |
The C<Event> module has a relatively high setup and callback invocation |
1006 |
cost, but overall scores in on the third place. |
1007 |
|
1008 |
C<Glib>'s memory usage is quite a bit higher, but it features a |
1009 |
faster callback invocation and overall ends up in the same class as |
1010 |
C<Event>. However, Glib scales extremely badly, doubling the number of |
1011 |
watchers increases the processing time by more than a factor of four, |
1012 |
making it completely unusable when using larger numbers of watchers |
1013 |
(note that only a single file descriptor was used in the benchmark, so |
1014 |
inefficiencies of C<poll> do not account for this). |
1015 |
|
1016 |
The C<Tk> adaptor works relatively well. The fact that it crashes with |
1017 |
more than 2000 watchers is a big setback, however, as correctness takes |
1018 |
precedence over speed. Nevertheless, its performance is surprising, as the |
1019 |
file descriptor is dup()ed for each watcher. This shows that the dup() |
1020 |
employed by some adaptors is not a big performance issue (it does incur a |
1021 |
hidden memory cost inside the kernel which is not reflected in the figures |
1022 |
above). |
1023 |
|
1024 |
C<POE>, regardless of underlying event loop (whether using its pure |
1025 |
perl select-based backend or the Event module, the POE-EV backend |
1026 |
couldn't be tested because it wasn't working) shows abysmal performance |
1027 |
and memory usage: Watchers use almost 30 times as much memory as |
1028 |
EV watchers, and 10 times as much memory as Event (the high memory |
1029 |
requirements are caused by requiring a session for each watcher). Watcher |
1030 |
invocation speed is almost 900 times slower than with AnyEvent's pure perl |
1031 |
implementation. The design of the POE adaptor class in AnyEvent can not |
1032 |
really account for this, as session creation overhead is small compared |
1033 |
to execution of the state machine, which is coded pretty optimally within |
1034 |
L<AnyEvent::Impl::POE>. POE simply seems to be abysmally slow. |
1035 |
|
1036 |
=head3 Summary |
1037 |
|
1038 |
=over 4 |
1039 |
|
1040 |
=item * Using EV through AnyEvent is faster than any other event loop |
1041 |
(even when used without AnyEvent), but most event loops have acceptable |
1042 |
performance with or without AnyEvent. |
1043 |
|
1044 |
=item * The overhead AnyEvent adds is usually much smaller than the overhead of |
1045 |
the actual event loop, only with extremely fast event loops such as EV |
1046 |
adds AnyEvent significant overhead. |
1047 |
|
1048 |
=item * You should avoid POE like the plague if you want performance or |
1049 |
reasonable memory usage. |
1050 |
|
1051 |
=back |
1052 |
|
1053 |
=head2 BENCHMARKING THE LARGE SERVER CASE |
1054 |
|
1055 |
This benchmark atcually benchmarks the event loop itself. It works by |
1056 |
creating a number of "servers": each server consists of a socketpair, a |
1057 |
timeout watcher that gets reset on activity (but never fires), and an I/O |
1058 |
watcher waiting for input on one side of the socket. Each time the socket |
1059 |
watcher reads a byte it will write that byte to a random other "server". |
1060 |
|
1061 |
The effect is that there will be a lot of I/O watchers, only part of which |
1062 |
are active at any one point (so there is a constant number of active |
1063 |
fds for each loop iterstaion, but which fds these are is random). The |
1064 |
timeout is reset each time something is read because that reflects how |
1065 |
most timeouts work (and puts extra pressure on the event loops). |
1066 |
|
1067 |
In this benchmark, we use 10000 socketpairs (20000 sockets), of which 100 |
1068 |
(1%) are active. This mirrors the activity of large servers with many |
1069 |
connections, most of which are idle at any one point in time. |
1070 |
|
1071 |
Source code for this benchmark is found as F<eg/bench2> in the AnyEvent |
1072 |
distribution. |
1073 |
|
1074 |
=head3 Explanation of the columns |
1075 |
|
1076 |
I<sockets> is the number of sockets, and twice the number of "servers" (as |
1077 |
each server has a read and write socket end). |
1078 |
|
1079 |
I<create> is the time it takes to create a socketpair (which is |
1080 |
nontrivial) and two watchers: an I/O watcher and a timeout watcher. |
1081 |
|
1082 |
I<request>, the most important value, is the time it takes to handle a |
1083 |
single "request", that is, reading the token from the pipe and forwarding |
1084 |
it to another server. This includes deleting the old timeout and creating |
1085 |
a new one that moves the timeout into the future. |
1086 |
|
1087 |
=head3 Results |
1088 |
|
1089 |
name sockets create request |
1090 |
EV 20000 69.01 11.16 |
1091 |
Perl 20000 73.32 35.87 |
1092 |
Event 20000 212.62 257.32 |
1093 |
Glib 20000 651.16 1896.30 |
1094 |
POE 20000 349.67 12317.24 uses POE::Loop::Event |
1095 |
|
1096 |
=head3 Discussion |
1097 |
|
1098 |
This benchmark I<does> measure scalability and overall performance of the |
1099 |
particular event loop. |
1100 |
|
1101 |
EV is again fastest. Since it is using epoll on my system, the setup time |
1102 |
is relatively high, though. |
1103 |
|
1104 |
Perl surprisingly comes second. It is much faster than the C-based event |
1105 |
loops Event and Glib. |
1106 |
|
1107 |
Event suffers from high setup time as well (look at its code and you will |
1108 |
understand why). Callback invocation also has a high overhead compared to |
1109 |
the C<< $_->() for .. >>-style loop that the Perl event loop uses. Event |
1110 |
uses select or poll in basically all documented configurations. |
1111 |
|
1112 |
Glib is hit hard by its quadratic behaviour w.r.t. many watchers. It |
1113 |
clearly fails to perform with many filehandles or in busy servers. |
1114 |
|
1115 |
POE is still completely out of the picture, taking over 1000 times as long |
1116 |
as EV, and over 100 times as long as the Perl implementation, even though |
1117 |
it uses a C-based event loop in this case. |
1118 |
|
1119 |
=head3 Summary |
1120 |
|
1121 |
=over 4 |
1122 |
|
1123 |
=item * The pure perl implementation performs extremely well, considering |
1124 |
that it uses select. |
1125 |
|
1126 |
=item * Avoid Glib or POE in large projects where performance matters. |
1127 |
|
1128 |
=back |
1129 |
|
1130 |
=head2 BENCHMARKING SMALL SERVERS |
1131 |
|
1132 |
While event loops should scale (and select-based ones do not...) even to |
1133 |
large servers, most programs we (or I :) actually write have only a few |
1134 |
I/O watchers. |
1135 |
|
1136 |
In this benchmark, I use the same benchmark program as in the large server |
1137 |
case, but it uses only eight "servers", of which three are active at any |
1138 |
one time. This should reflect performance for a small server relatively |
1139 |
well. |
1140 |
|
1141 |
The columns are identical to the previous table. |
1142 |
|
1143 |
=head3 Results |
1144 |
|
1145 |
name sockets create request |
1146 |
EV 16 20.00 6.54 |
1147 |
Perl 16 25.75 12.62 |
1148 |
Event 16 81.27 35.86 |
1149 |
Glib 16 32.63 15.48 |
1150 |
POE 16 261.87 276.28 uses POE::Loop::Event |
1151 |
|
1152 |
=head3 Discussion |
1153 |
|
1154 |
The benchmark tries to test the performance of a typical small |
1155 |
server. While knowing how various event loops perform is interesting, keep |
1156 |
in mind that their overhead in this case is usually not as important, due |
1157 |
to the small absolute number of watchers (that is, you need efficiency and |
1158 |
speed most when you have lots of watchers, not when you only have a few of |
1159 |
them). |
1160 |
|
1161 |
EV is again fastest. |
1162 |
|
1163 |
The C-based event loops Event and Glib come in second this time, as the |
1164 |
overhead of running an iteration is much smaller in C than in Perl (little |
1165 |
code to execute in the inner loop, and perl's function calling overhead is |
1166 |
high, and updating all the data structures is costly). |
1167 |
|
1168 |
The pure perl event loop is much slower, but still competitive. |
1169 |
|
1170 |
POE also performs much better in this case, but is is still far behind the |
1171 |
others. |
1172 |
|
1173 |
=head3 Summary |
1174 |
|
1175 |
=over 4 |
1176 |
|
1177 |
=item * C-based event loops perform very well with small number of |
1178 |
watchers, as the management overhead dominates. |
1179 |
|
1180 |
=back |
1181 |
|
1182 |
|
1183 |
=head1 FORK |
1184 |
|
1185 |
Most event libraries are not fork-safe. The ones who are usually are |
1186 |
because they are so inefficient. Only L<EV> is fully fork-aware. |
1187 |
|
1188 |
If you have to fork, you must either do so I<before> creating your first |
1189 |
watcher OR you must not use AnyEvent at all in the child. |
1190 |
|
1191 |
|
1192 |
=head1 SECURITY CONSIDERATIONS |
1193 |
|
1194 |
AnyEvent can be forced to load any event model via |
1195 |
$ENV{PERL_ANYEVENT_MODEL}. While this cannot (to my knowledge) be used to |
1196 |
execute arbitrary code or directly gain access, it can easily be used to |
1197 |
make the program hang or malfunction in subtle ways, as AnyEvent watchers |
1198 |
will not be active when the program uses a different event model than |
1199 |
specified in the variable. |
1200 |
|
1201 |
You can make AnyEvent completely ignore this variable by deleting it |
1202 |
before the first watcher gets created, e.g. with a C<BEGIN> block: |
1203 |
|
1204 |
BEGIN { delete $ENV{PERL_ANYEVENT_MODEL} } |
1205 |
|
1206 |
use AnyEvent; |
1207 |
|
1208 |
|
1209 |
=head1 SEE ALSO |
1210 |
|
1211 |
Event modules: L<Coro::EV>, L<EV>, L<EV::Glib>, L<Glib::EV>, |
1212 |
L<Coro::Event>, L<Event>, L<Glib::Event>, L<Glib>, L<Coro>, L<Tk>, |
1213 |
L<Event::Lib>, L<Qt>, L<POE>. |
1214 |
|
1215 |
Implementations: L<AnyEvent::Impl::CoroEV>, L<AnyEvent::Impl::EV>, |
1216 |
L<AnyEvent::Impl::CoroEvent>, L<AnyEvent::Impl::Event>, L<AnyEvent::Impl::Glib>, |
1217 |
L<AnyEvent::Impl::Tk>, L<AnyEvent::Impl::Perl>, L<AnyEvent::Impl::EventLib>, |
1218 |
L<AnyEvent::Impl::Qt>, L<AnyEvent::Impl::POE>. |
1219 |
|
1220 |
Nontrivial usage examples: L<Net::FCP>, L<Net::XMPP2>. |
1221 |
|
1222 |
|
1223 |
=head1 AUTHOR |
1224 |
|
1225 |
Marc Lehmann <schmorp@schmorp.de> |
1226 |
http://home.schmorp.de/ |
1227 |
|
1228 |
=cut |
1229 |
|
1230 |
1 |
1231 |
|