1 |
=head1 NAME |
2 |
|
3 |
AnyEvent - provide framework for multiple event loops |
4 |
|
5 |
EV, Event, Coro::EV, Coro::Event, Glib, Tk, Perl, Event::Lib, Qt, POE - various supported event loops |
6 |
|
7 |
=head1 SYNOPSIS |
8 |
|
9 |
use AnyEvent; |
10 |
|
11 |
my $w = AnyEvent->io (fh => $fh, poll => "r|w", cb => sub { |
12 |
... |
13 |
}); |
14 |
|
15 |
my $w = AnyEvent->timer (after => $seconds, cb => sub { |
16 |
... |
17 |
}); |
18 |
|
19 |
my $w = AnyEvent->condvar; # stores whether a condition was flagged |
20 |
$w->wait; # enters "main loop" till $condvar gets ->broadcast |
21 |
$w->broadcast; # wake up current and all future wait's |
22 |
|
23 |
=head1 WHY YOU SHOULD USE THIS MODULE (OR NOT) |
24 |
|
25 |
Glib, POE, IO::Async, Event... CPAN offers event models by the dozen |
26 |
nowadays. So what is different about AnyEvent? |
27 |
|
28 |
Executive Summary: AnyEvent is I<compatible>, AnyEvent is I<free of |
29 |
policy> and AnyEvent is I<small and efficient>. |
30 |
|
31 |
First and foremost, I<AnyEvent is not an event model> itself, it only |
32 |
interfaces to whatever event model the main program happens to use in a |
33 |
pragmatic way. For event models and certain classes of immortals alike, |
34 |
the statement "there can only be one" is a bitter reality: In general, |
35 |
only one event loop can be active at the same time in a process. AnyEvent |
36 |
helps hiding the differences between those event loops. |
37 |
|
38 |
The goal of AnyEvent is to offer module authors the ability to do event |
39 |
programming (waiting for I/O or timer events) without subscribing to a |
40 |
religion, a way of living, and most importantly: without forcing your |
41 |
module users into the same thing by forcing them to use the same event |
42 |
model you use. |
43 |
|
44 |
For modules like POE or IO::Async (which is a total misnomer as it is |
45 |
actually doing all I/O I<synchronously>...), using them in your module is |
46 |
like joining a cult: After you joined, you are dependent on them and you |
47 |
cannot use anything else, as it is simply incompatible to everything that |
48 |
isn't itself. What's worse, all the potential users of your module are |
49 |
I<also> forced to use the same event loop you use. |
50 |
|
51 |
AnyEvent is different: AnyEvent + POE works fine. AnyEvent + Glib works |
52 |
fine. AnyEvent + Tk works fine etc. etc. but none of these work together |
53 |
with the rest: POE + IO::Async? no go. Tk + Event? no go. Again: if |
54 |
your module uses one of those, every user of your module has to use it, |
55 |
too. But if your module uses AnyEvent, it works transparently with all |
56 |
event models it supports (including stuff like POE and IO::Async, as long |
57 |
as those use one of the supported event loops. It is trivial to add new |
58 |
event loops to AnyEvent, too, so it is future-proof). |
59 |
|
60 |
In addition to being free of having to use I<the one and only true event |
61 |
model>, AnyEvent also is free of bloat and policy: with POE or similar |
62 |
modules, you get an enourmous amount of code and strict rules you have to |
63 |
follow. AnyEvent, on the other hand, is lean and up to the point, by only |
64 |
offering the functionality that is necessary, in as thin as a wrapper as |
65 |
technically possible. |
66 |
|
67 |
Of course, if you want lots of policy (this can arguably be somewhat |
68 |
useful) and you want to force your users to use the one and only event |
69 |
model, you should I<not> use this module. |
70 |
|
71 |
|
72 |
=head1 DESCRIPTION |
73 |
|
74 |
L<AnyEvent> provides an identical interface to multiple event loops. This |
75 |
allows module authors to utilise an event loop without forcing module |
76 |
users to use the same event loop (as only a single event loop can coexist |
77 |
peacefully at any one time). |
78 |
|
79 |
The interface itself is vaguely similar, but not identical to the L<Event> |
80 |
module. |
81 |
|
82 |
During the first call of any watcher-creation method, the module tries |
83 |
to detect the currently loaded event loop by probing whether one of the |
84 |
following modules is already loaded: L<Coro::EV>, L<Coro::Event>, L<EV>, |
85 |
L<Event>, L<Glib>, L<Tk>, L<AnyEvent::Impl::Perl>, L<Event::Lib>, L<Qt>, |
86 |
L<POE>. The first one found is used. If none are found, the module tries |
87 |
to load these modules (excluding Event::Lib, Qt and POE as the pure perl |
88 |
adaptor should always succeed) in the order given. The first one that can |
89 |
be successfully loaded will be used. If, after this, still none could be |
90 |
found, AnyEvent will fall back to a pure-perl event loop, which is not |
91 |
very efficient, but should work everywhere. |
92 |
|
93 |
Because AnyEvent first checks for modules that are already loaded, loading |
94 |
an event model explicitly before first using AnyEvent will likely make |
95 |
that model the default. For example: |
96 |
|
97 |
use Tk; |
98 |
use AnyEvent; |
99 |
|
100 |
# .. AnyEvent will likely default to Tk |
101 |
|
102 |
The I<likely> means that, if any module loads another event model and |
103 |
starts using it, all bets are off. Maybe you should tell their authors to |
104 |
use AnyEvent so their modules work together with others seamlessly... |
105 |
|
106 |
The pure-perl implementation of AnyEvent is called |
107 |
C<AnyEvent::Impl::Perl>. Like other event modules you can load it |
108 |
explicitly. |
109 |
|
110 |
=head1 WATCHERS |
111 |
|
112 |
AnyEvent has the central concept of a I<watcher>, which is an object that |
113 |
stores relevant data for each kind of event you are waiting for, such as |
114 |
the callback to call, the filehandle to watch, etc. |
115 |
|
116 |
These watchers are normal Perl objects with normal Perl lifetime. After |
117 |
creating a watcher it will immediately "watch" for events and invoke the |
118 |
callback when the event occurs (of course, only when the event model |
119 |
is in control). |
120 |
|
121 |
To disable the watcher you have to destroy it (e.g. by setting the |
122 |
variable you store it in to C<undef> or otherwise deleting all references |
123 |
to it). |
124 |
|
125 |
All watchers are created by calling a method on the C<AnyEvent> class. |
126 |
|
127 |
Many watchers either are used with "recursion" (repeating timers for |
128 |
example), or need to refer to their watcher object in other ways. |
129 |
|
130 |
An any way to achieve that is this pattern: |
131 |
|
132 |
my $w; $w = AnyEvent->type (arg => value ..., cb => sub { |
133 |
# you can use $w here, for example to undef it |
134 |
undef $w; |
135 |
}); |
136 |
|
137 |
Note that C<my $w; $w => combination. This is necessary because in Perl, |
138 |
my variables are only visible after the statement in which they are |
139 |
declared. |
140 |
|
141 |
=head2 IO WATCHERS |
142 |
|
143 |
You can create an I/O watcher by calling the C<< AnyEvent->io >> method |
144 |
with the following mandatory key-value pairs as arguments: |
145 |
|
146 |
C<fh> the Perl I<file handle> (I<not> file descriptor) to watch for |
147 |
events. C<poll> must be a string that is either C<r> or C<w>, which |
148 |
creates a watcher waiting for "r"eadable or "w"ritable events, |
149 |
respectively. C<cb> is the callback to invoke each time the file handle |
150 |
becomes ready. |
151 |
|
152 |
As long as the I/O watcher exists it will keep the file descriptor or a |
153 |
copy of it alive/open. |
154 |
|
155 |
It is not allowed to close a file handle as long as any watcher is active |
156 |
on the underlying file descriptor. |
157 |
|
158 |
Some event loops issue spurious readyness notifications, so you should |
159 |
always use non-blocking calls when reading/writing from/to your file |
160 |
handles. |
161 |
|
162 |
Example: |
163 |
|
164 |
# wait for readability of STDIN, then read a line and disable the watcher |
165 |
my $w; $w = AnyEvent->io (fh => \*STDIN, poll => 'r', cb => sub { |
166 |
chomp (my $input = <STDIN>); |
167 |
warn "read: $input\n"; |
168 |
undef $w; |
169 |
}); |
170 |
|
171 |
=head2 TIME WATCHERS |
172 |
|
173 |
You can create a time watcher by calling the C<< AnyEvent->timer >> |
174 |
method with the following mandatory arguments: |
175 |
|
176 |
C<after> specifies after how many seconds (fractional values are |
177 |
supported) should the timer activate. C<cb> the callback to invoke in that |
178 |
case. |
179 |
|
180 |
The timer callback will be invoked at most once: if you want a repeating |
181 |
timer you have to create a new watcher (this is a limitation by both Tk |
182 |
and Glib). |
183 |
|
184 |
Example: |
185 |
|
186 |
# fire an event after 7.7 seconds |
187 |
my $w = AnyEvent->timer (after => 7.7, cb => sub { |
188 |
warn "timeout\n"; |
189 |
}); |
190 |
|
191 |
# to cancel the timer: |
192 |
undef $w; |
193 |
|
194 |
Example 2: |
195 |
|
196 |
# fire an event after 0.5 seconds, then roughly every second |
197 |
my $w; |
198 |
|
199 |
my $cb = sub { |
200 |
# cancel the old timer while creating a new one |
201 |
$w = AnyEvent->timer (after => 1, cb => $cb); |
202 |
}; |
203 |
|
204 |
# start the "loop" by creating the first watcher |
205 |
$w = AnyEvent->timer (after => 0.5, cb => $cb); |
206 |
|
207 |
=head3 TIMING ISSUES |
208 |
|
209 |
There are two ways to handle timers: based on real time (relative, "fire |
210 |
in 10 seconds") and based on wallclock time (absolute, "fire at 12 |
211 |
o'clock"). |
212 |
|
213 |
While most event loops expect timers to specified in a relative way, they |
214 |
use absolute time internally. This makes a difference when your clock |
215 |
"jumps", for example, when ntp decides to set your clock backwards from |
216 |
the wrong date of 2014-01-01 to 2008-01-01, a watcher that is supposed to |
217 |
fire "after" a second might actually take six years to finally fire. |
218 |
|
219 |
AnyEvent cannot compensate for this. The only event loop that is conscious |
220 |
about these issues is L<EV>, which offers both relative (ev_timer, based |
221 |
on true relative time) and absolute (ev_periodic, based on wallclock time) |
222 |
timers. |
223 |
|
224 |
AnyEvent always prefers relative timers, if available, matching the |
225 |
AnyEvent API. |
226 |
|
227 |
=head2 SIGNAL WATCHERS |
228 |
|
229 |
You can watch for signals using a signal watcher, C<signal> is the signal |
230 |
I<name> without any C<SIG> prefix, C<cb> is the Perl callback to |
231 |
be invoked whenever a signal occurs. |
232 |
|
233 |
Multiple signal occurances can be clumped together into one callback |
234 |
invocation, and callback invocation will be synchronous. synchronous means |
235 |
that it might take a while until the signal gets handled by the process, |
236 |
but it is guarenteed not to interrupt any other callbacks. |
237 |
|
238 |
The main advantage of using these watchers is that you can share a signal |
239 |
between multiple watchers. |
240 |
|
241 |
This watcher might use C<%SIG>, so programs overwriting those signals |
242 |
directly will likely not work correctly. |
243 |
|
244 |
Example: exit on SIGINT |
245 |
|
246 |
my $w = AnyEvent->signal (signal => "INT", cb => sub { exit 1 }); |
247 |
|
248 |
=head2 CHILD PROCESS WATCHERS |
249 |
|
250 |
You can also watch on a child process exit and catch its exit status. |
251 |
|
252 |
The child process is specified by the C<pid> argument (if set to C<0>, it |
253 |
watches for any child process exit). The watcher will trigger as often |
254 |
as status change for the child are received. This works by installing a |
255 |
signal handler for C<SIGCHLD>. The callback will be called with the pid |
256 |
and exit status (as returned by waitpid). |
257 |
|
258 |
Example: wait for pid 1333 |
259 |
|
260 |
my $w = AnyEvent->child ( |
261 |
pid => 1333, |
262 |
cb => sub { |
263 |
my ($pid, $status) = @_; |
264 |
warn "pid $pid exited with status $status"; |
265 |
}, |
266 |
); |
267 |
|
268 |
=head2 CONDITION VARIABLES |
269 |
|
270 |
Condition variables can be created by calling the C<< AnyEvent->condvar >> |
271 |
method without any arguments. |
272 |
|
273 |
A condition variable waits for a condition - precisely that the C<< |
274 |
->broadcast >> method has been called. |
275 |
|
276 |
They are very useful to signal that a condition has been fulfilled, for |
277 |
example, if you write a module that does asynchronous http requests, |
278 |
then a condition variable would be the ideal candidate to signal the |
279 |
availability of results. |
280 |
|
281 |
You can also use condition variables to block your main program until |
282 |
an event occurs - for example, you could C<< ->wait >> in your main |
283 |
program until the user clicks the Quit button in your app, which would C<< |
284 |
->broadcast >> the "quit" event. |
285 |
|
286 |
Note that condition variables recurse into the event loop - if you have |
287 |
two pirces of code that call C<< ->wait >> in a round-robbin fashion, you |
288 |
lose. Therefore, condition variables are good to export to your caller, but |
289 |
you should avoid making a blocking wait yourself, at least in callbacks, |
290 |
as this asks for trouble. |
291 |
|
292 |
This object has two methods: |
293 |
|
294 |
=over 4 |
295 |
|
296 |
=item $cv->wait |
297 |
|
298 |
Wait (blocking if necessary) until the C<< ->broadcast >> method has been |
299 |
called on c<$cv>, while servicing other watchers normally. |
300 |
|
301 |
You can only wait once on a condition - additional calls will return |
302 |
immediately. |
303 |
|
304 |
Not all event models support a blocking wait - some die in that case |
305 |
(programs might want to do that to stay interactive), so I<if you are |
306 |
using this from a module, never require a blocking wait>, but let the |
307 |
caller decide whether the call will block or not (for example, by coupling |
308 |
condition variables with some kind of request results and supporting |
309 |
callbacks so the caller knows that getting the result will not block, |
310 |
while still suppporting blocking waits if the caller so desires). |
311 |
|
312 |
Another reason I<never> to C<< ->wait >> in a module is that you cannot |
313 |
sensibly have two C<< ->wait >>'s in parallel, as that would require |
314 |
multiple interpreters or coroutines/threads, none of which C<AnyEvent> |
315 |
can supply (the coroutine-aware backends L<AnyEvent::Impl::CoroEV> and |
316 |
L<AnyEvent::Impl::CoroEvent> explicitly support concurrent C<< ->wait >>'s |
317 |
from different coroutines, however). |
318 |
|
319 |
=item $cv->broadcast |
320 |
|
321 |
Flag the condition as ready - a running C<< ->wait >> and all further |
322 |
calls to C<wait> will (eventually) return after this method has been |
323 |
called. If nobody is waiting the broadcast will be remembered.. |
324 |
|
325 |
=back |
326 |
|
327 |
Example: |
328 |
|
329 |
# wait till the result is ready |
330 |
my $result_ready = AnyEvent->condvar; |
331 |
|
332 |
# do something such as adding a timer |
333 |
# or socket watcher the calls $result_ready->broadcast |
334 |
# when the "result" is ready. |
335 |
# in this case, we simply use a timer: |
336 |
my $w = AnyEvent->timer ( |
337 |
after => 1, |
338 |
cb => sub { $result_ready->broadcast }, |
339 |
); |
340 |
|
341 |
# this "blocks" (while handling events) till the watcher |
342 |
# calls broadcast |
343 |
$result_ready->wait; |
344 |
|
345 |
=head1 GLOBAL VARIABLES AND FUNCTIONS |
346 |
|
347 |
=over 4 |
348 |
|
349 |
=item $AnyEvent::MODEL |
350 |
|
351 |
Contains C<undef> until the first watcher is being created. Then it |
352 |
contains the event model that is being used, which is the name of the |
353 |
Perl class implementing the model. This class is usually one of the |
354 |
C<AnyEvent::Impl:xxx> modules, but can be any other class in the case |
355 |
AnyEvent has been extended at runtime (e.g. in I<rxvt-unicode>). |
356 |
|
357 |
The known classes so far are: |
358 |
|
359 |
AnyEvent::Impl::CoroEV based on Coro::EV, best choice. |
360 |
AnyEvent::Impl::CoroEvent based on Coro::Event, second best choice. |
361 |
AnyEvent::Impl::EV based on EV (an interface to libev, best choice). |
362 |
AnyEvent::Impl::Event based on Event, second best choice. |
363 |
AnyEvent::Impl::Glib based on Glib, third-best choice. |
364 |
AnyEvent::Impl::Tk based on Tk, very bad choice. |
365 |
AnyEvent::Impl::Perl pure-perl implementation, inefficient but portable. |
366 |
AnyEvent::Impl::Qt based on Qt, cannot be autoprobed (see its docs). |
367 |
AnyEvent::Impl::EventLib based on Event::Lib, leaks memory and worse. |
368 |
AnyEvent::Impl::POE based on POE, not generic enough for full support. |
369 |
|
370 |
There is no support for WxWidgets, as WxWidgets has no support for |
371 |
watching file handles. However, you can use WxWidgets through the |
372 |
POE Adaptor, as POE has a Wx backend that simply polls 20 times per |
373 |
second, which was considered to be too horrible to even consider for |
374 |
AnyEvent. Likewise, other POE backends can be used by AnyEvent by using |
375 |
it's adaptor. |
376 |
|
377 |
AnyEvent knows about L<Prima> and L<Wx> and will try to use L<POE> when |
378 |
autodetecting them. |
379 |
|
380 |
=item AnyEvent::detect |
381 |
|
382 |
Returns C<$AnyEvent::MODEL>, forcing autodetection of the event model |
383 |
if necessary. You should only call this function right before you would |
384 |
have created an AnyEvent watcher anyway, that is, as late as possible at |
385 |
runtime. |
386 |
|
387 |
=back |
388 |
|
389 |
=head1 WHAT TO DO IN A MODULE |
390 |
|
391 |
As a module author, you should C<use AnyEvent> and call AnyEvent methods |
392 |
freely, but you should not load a specific event module or rely on it. |
393 |
|
394 |
Be careful when you create watchers in the module body - AnyEvent will |
395 |
decide which event module to use as soon as the first method is called, so |
396 |
by calling AnyEvent in your module body you force the user of your module |
397 |
to load the event module first. |
398 |
|
399 |
Never call C<< ->wait >> on a condition variable unless you I<know> that |
400 |
the C<< ->broadcast >> method has been called on it already. This is |
401 |
because it will stall the whole program, and the whole point of using |
402 |
events is to stay interactive. |
403 |
|
404 |
It is fine, however, to call C<< ->wait >> when the user of your module |
405 |
requests it (i.e. if you create a http request object ad have a method |
406 |
called C<results> that returns the results, it should call C<< ->wait >> |
407 |
freely, as the user of your module knows what she is doing. always). |
408 |
|
409 |
=head1 WHAT TO DO IN THE MAIN PROGRAM |
410 |
|
411 |
There will always be a single main program - the only place that should |
412 |
dictate which event model to use. |
413 |
|
414 |
If it doesn't care, it can just "use AnyEvent" and use it itself, or not |
415 |
do anything special (it does not need to be event-based) and let AnyEvent |
416 |
decide which implementation to chose if some module relies on it. |
417 |
|
418 |
If the main program relies on a specific event model. For example, in |
419 |
Gtk2 programs you have to rely on the Glib module. You should load the |
420 |
event module before loading AnyEvent or any module that uses it: generally |
421 |
speaking, you should load it as early as possible. The reason is that |
422 |
modules might create watchers when they are loaded, and AnyEvent will |
423 |
decide on the event model to use as soon as it creates watchers, and it |
424 |
might chose the wrong one unless you load the correct one yourself. |
425 |
|
426 |
You can chose to use a rather inefficient pure-perl implementation by |
427 |
loading the C<AnyEvent::Impl::Perl> module, which gives you similar |
428 |
behaviour everywhere, but letting AnyEvent chose is generally better. |
429 |
|
430 |
=cut |
431 |
|
432 |
package AnyEvent; |
433 |
|
434 |
no warnings; |
435 |
use strict; |
436 |
|
437 |
use Carp; |
438 |
|
439 |
our $VERSION = '3.3'; |
440 |
our $MODEL; |
441 |
|
442 |
our $AUTOLOAD; |
443 |
our @ISA; |
444 |
|
445 |
our $verbose = $ENV{PERL_ANYEVENT_VERBOSE}*1; |
446 |
|
447 |
our @REGISTRY; |
448 |
|
449 |
my @models = ( |
450 |
[Coro::EV:: => AnyEvent::Impl::CoroEV::], |
451 |
[Coro::Event:: => AnyEvent::Impl::CoroEvent::], |
452 |
[EV:: => AnyEvent::Impl::EV::], |
453 |
[Event:: => AnyEvent::Impl::Event::], |
454 |
[Glib:: => AnyEvent::Impl::Glib::], |
455 |
[Tk:: => AnyEvent::Impl::Tk::], |
456 |
[Wx:: => AnyEvent::Impl::POE::], |
457 |
[Prima:: => AnyEvent::Impl::POE::], |
458 |
[AnyEvent::Impl::Perl:: => AnyEvent::Impl::Perl::], |
459 |
# everything below here will not be autoprobed as the pureperl backend should work everywhere |
460 |
[Event::Lib:: => AnyEvent::Impl::EventLib::], # too buggy |
461 |
[Qt:: => AnyEvent::Impl::Qt::], # requires special main program |
462 |
[POE::Kernel:: => AnyEvent::Impl::POE::], # lasciate ogni speranza |
463 |
); |
464 |
|
465 |
our %method = map +($_ => 1), qw(io timer signal child condvar broadcast wait one_event DESTROY); |
466 |
|
467 |
sub detect() { |
468 |
unless ($MODEL) { |
469 |
no strict 'refs'; |
470 |
|
471 |
if ($ENV{PERL_ANYEVENT_MODEL} =~ /^([a-zA-Z]+)$/) { |
472 |
my $model = "AnyEvent::Impl::$1"; |
473 |
if (eval "require $model") { |
474 |
$MODEL = $model; |
475 |
warn "AnyEvent: loaded model '$model' (forced by \$PERL_ANYEVENT_MODEL), using it.\n" if $verbose > 1; |
476 |
} else { |
477 |
warn "AnyEvent: unable to load model '$model' (from \$PERL_ANYEVENT_MODEL):\n$@" if $verbose; |
478 |
} |
479 |
} |
480 |
|
481 |
# check for already loaded models |
482 |
unless ($MODEL) { |
483 |
for (@REGISTRY, @models) { |
484 |
my ($package, $model) = @$_; |
485 |
if (${"$package\::VERSION"} > 0) { |
486 |
if (eval "require $model") { |
487 |
$MODEL = $model; |
488 |
warn "AnyEvent: autodetected model '$model', using it.\n" if $verbose > 1; |
489 |
last; |
490 |
} |
491 |
} |
492 |
} |
493 |
|
494 |
unless ($MODEL) { |
495 |
# try to load a model |
496 |
|
497 |
for (@REGISTRY, @models) { |
498 |
my ($package, $model) = @$_; |
499 |
if (eval "require $package" |
500 |
and ${"$package\::VERSION"} > 0 |
501 |
and eval "require $model") { |
502 |
$MODEL = $model; |
503 |
warn "AnyEvent: autoprobed model '$model', using it.\n" if $verbose > 1; |
504 |
last; |
505 |
} |
506 |
} |
507 |
|
508 |
$MODEL |
509 |
or die "No event module selected for AnyEvent and autodetect failed. Install any one of these modules: EV (or Coro+EV), Event (or Coro+Event) or Glib."; |
510 |
} |
511 |
} |
512 |
|
513 |
unshift @ISA, $MODEL; |
514 |
push @{"$MODEL\::ISA"}, "AnyEvent::Base"; |
515 |
} |
516 |
|
517 |
$MODEL |
518 |
} |
519 |
|
520 |
sub AUTOLOAD { |
521 |
(my $func = $AUTOLOAD) =~ s/.*://; |
522 |
|
523 |
$method{$func} |
524 |
or croak "$func: not a valid method for AnyEvent objects"; |
525 |
|
526 |
detect unless $MODEL; |
527 |
|
528 |
my $class = shift; |
529 |
$class->$func (@_); |
530 |
} |
531 |
|
532 |
package AnyEvent::Base; |
533 |
|
534 |
# default implementation for ->condvar, ->wait, ->broadcast |
535 |
|
536 |
sub condvar { |
537 |
bless \my $flag, "AnyEvent::Base::CondVar" |
538 |
} |
539 |
|
540 |
sub AnyEvent::Base::CondVar::broadcast { |
541 |
${$_[0]}++; |
542 |
} |
543 |
|
544 |
sub AnyEvent::Base::CondVar::wait { |
545 |
AnyEvent->one_event while !${$_[0]}; |
546 |
} |
547 |
|
548 |
# default implementation for ->signal |
549 |
|
550 |
our %SIG_CB; |
551 |
|
552 |
sub signal { |
553 |
my (undef, %arg) = @_; |
554 |
|
555 |
my $signal = uc $arg{signal} |
556 |
or Carp::croak "required option 'signal' is missing"; |
557 |
|
558 |
$SIG_CB{$signal}{$arg{cb}} = $arg{cb}; |
559 |
$SIG{$signal} ||= sub { |
560 |
$_->() for values %{ $SIG_CB{$signal} || {} }; |
561 |
}; |
562 |
|
563 |
bless [$signal, $arg{cb}], "AnyEvent::Base::Signal" |
564 |
} |
565 |
|
566 |
sub AnyEvent::Base::Signal::DESTROY { |
567 |
my ($signal, $cb) = @{$_[0]}; |
568 |
|
569 |
delete $SIG_CB{$signal}{$cb}; |
570 |
|
571 |
$SIG{$signal} = 'DEFAULT' unless keys %{ $SIG_CB{$signal} }; |
572 |
} |
573 |
|
574 |
# default implementation for ->child |
575 |
|
576 |
our %PID_CB; |
577 |
our $CHLD_W; |
578 |
our $CHLD_DELAY_W; |
579 |
our $PID_IDLE; |
580 |
our $WNOHANG; |
581 |
|
582 |
sub _child_wait { |
583 |
while (0 < (my $pid = waitpid -1, $WNOHANG)) { |
584 |
$_->($pid, $?) for (values %{ $PID_CB{$pid} || {} }), |
585 |
(values %{ $PID_CB{0} || {} }); |
586 |
} |
587 |
|
588 |
undef $PID_IDLE; |
589 |
} |
590 |
|
591 |
sub _sigchld { |
592 |
# make sure we deliver these changes "synchronous" with the event loop. |
593 |
$CHLD_DELAY_W ||= AnyEvent->timer (after => 0, cb => sub { |
594 |
undef $CHLD_DELAY_W; |
595 |
&_child_wait; |
596 |
}); |
597 |
} |
598 |
|
599 |
sub child { |
600 |
my (undef, %arg) = @_; |
601 |
|
602 |
defined (my $pid = $arg{pid} + 0) |
603 |
or Carp::croak "required option 'pid' is missing"; |
604 |
|
605 |
$PID_CB{$pid}{$arg{cb}} = $arg{cb}; |
606 |
|
607 |
unless ($WNOHANG) { |
608 |
$WNOHANG = eval { require POSIX; &POSIX::WNOHANG } || 1; |
609 |
} |
610 |
|
611 |
unless ($CHLD_W) { |
612 |
$CHLD_W = AnyEvent->signal (signal => 'CHLD', cb => \&_sigchld); |
613 |
# child could be a zombie already, so make at least one round |
614 |
&_sigchld; |
615 |
} |
616 |
|
617 |
bless [$pid, $arg{cb}], "AnyEvent::Base::Child" |
618 |
} |
619 |
|
620 |
sub AnyEvent::Base::Child::DESTROY { |
621 |
my ($pid, $cb) = @{$_[0]}; |
622 |
|
623 |
delete $PID_CB{$pid}{$cb}; |
624 |
delete $PID_CB{$pid} unless keys %{ $PID_CB{$pid} }; |
625 |
|
626 |
undef $CHLD_W unless keys %PID_CB; |
627 |
} |
628 |
|
629 |
=head1 SUPPLYING YOUR OWN EVENT MODEL INTERFACE |
630 |
|
631 |
This is an advanced topic that you do not normally need to use AnyEvent in |
632 |
a module. This section is only of use to event loop authors who want to |
633 |
provide AnyEvent compatibility. |
634 |
|
635 |
If you need to support another event library which isn't directly |
636 |
supported by AnyEvent, you can supply your own interface to it by |
637 |
pushing, before the first watcher gets created, the package name of |
638 |
the event module and the package name of the interface to use onto |
639 |
C<@AnyEvent::REGISTRY>. You can do that before and even without loading |
640 |
AnyEvent, so it is reasonably cheap. |
641 |
|
642 |
Example: |
643 |
|
644 |
push @AnyEvent::REGISTRY, [urxvt => urxvt::anyevent::]; |
645 |
|
646 |
This tells AnyEvent to (literally) use the C<urxvt::anyevent::> |
647 |
package/class when it finds the C<urxvt> package/module is already loaded. |
648 |
|
649 |
When AnyEvent is loaded and asked to find a suitable event model, it |
650 |
will first check for the presence of urxvt by trying to C<use> the |
651 |
C<urxvt::anyevent> module. |
652 |
|
653 |
The class should provide implementations for all watcher types. See |
654 |
L<AnyEvent::Impl::EV> (source code), L<AnyEvent::Impl::Glib> (Source code) |
655 |
and so on for actual examples. Use C<perldoc -m AnyEvent::Impl::Glib> to |
656 |
see the sources. |
657 |
|
658 |
If you don't provide C<signal> and C<child> watchers than AnyEvent will |
659 |
provide suitable (hopefully) replacements. |
660 |
|
661 |
The above example isn't fictitious, the I<rxvt-unicode> (a.k.a. urxvt) |
662 |
terminal emulator uses the above line as-is. An interface isn't included |
663 |
in AnyEvent because it doesn't make sense outside the embedded interpreter |
664 |
inside I<rxvt-unicode>, and it is updated and maintained as part of the |
665 |
I<rxvt-unicode> distribution. |
666 |
|
667 |
I<rxvt-unicode> also cheats a bit by not providing blocking access to |
668 |
condition variables: code blocking while waiting for a condition will |
669 |
C<die>. This still works with most modules/usages, and blocking calls must |
670 |
not be done in an interactive application, so it makes sense. |
671 |
|
672 |
=head1 ENVIRONMENT VARIABLES |
673 |
|
674 |
The following environment variables are used by this module: |
675 |
|
676 |
=over 4 |
677 |
|
678 |
=item C<PERL_ANYEVENT_VERBOSE> |
679 |
|
680 |
By default, AnyEvent will be completely silent except in fatal |
681 |
conditions. You can set this environment variable to make AnyEvent more |
682 |
talkative. |
683 |
|
684 |
When set to C<1> or higher, causes AnyEvent to warn about unexpected |
685 |
conditions, such as not being able to load the event model specified by |
686 |
C<PERL_ANYEVENT_MODEL>. |
687 |
|
688 |
When set to C<2> or higher, cause AnyEvent to report to STDERR which event |
689 |
model it chooses. |
690 |
|
691 |
=item C<PERL_ANYEVENT_MODEL> |
692 |
|
693 |
This can be used to specify the event model to be used by AnyEvent, before |
694 |
autodetection and -probing kicks in. It must be a string consisting |
695 |
entirely of ASCII letters. The string C<AnyEvent::Impl::> gets prepended |
696 |
and the resulting module name is loaded and if the load was successful, |
697 |
used as event model. If it fails to load AnyEvent will proceed with |
698 |
autodetection and -probing. |
699 |
|
700 |
This functionality might change in future versions. |
701 |
|
702 |
For example, to force the pure perl model (L<AnyEvent::Impl::Perl>) you |
703 |
could start your program like this: |
704 |
|
705 |
PERL_ANYEVENT_MODEL=Perl perl ... |
706 |
|
707 |
=back |
708 |
|
709 |
=head1 EXAMPLE PROGRAM |
710 |
|
711 |
The following program uses an IO watcher to read data from STDIN, a timer |
712 |
to display a message once per second, and a condition variable to quit the |
713 |
program when the user enters quit: |
714 |
|
715 |
use AnyEvent; |
716 |
|
717 |
my $cv = AnyEvent->condvar; |
718 |
|
719 |
my $io_watcher = AnyEvent->io ( |
720 |
fh => \*STDIN, |
721 |
poll => 'r', |
722 |
cb => sub { |
723 |
warn "io event <$_[0]>\n"; # will always output <r> |
724 |
chomp (my $input = <STDIN>); # read a line |
725 |
warn "read: $input\n"; # output what has been read |
726 |
$cv->broadcast if $input =~ /^q/i; # quit program if /^q/i |
727 |
}, |
728 |
); |
729 |
|
730 |
my $time_watcher; # can only be used once |
731 |
|
732 |
sub new_timer { |
733 |
$timer = AnyEvent->timer (after => 1, cb => sub { |
734 |
warn "timeout\n"; # print 'timeout' about every second |
735 |
&new_timer; # and restart the time |
736 |
}); |
737 |
} |
738 |
|
739 |
new_timer; # create first timer |
740 |
|
741 |
$cv->wait; # wait until user enters /^q/i |
742 |
|
743 |
=head1 REAL-WORLD EXAMPLE |
744 |
|
745 |
Consider the L<Net::FCP> module. It features (among others) the following |
746 |
API calls, which are to freenet what HTTP GET requests are to http: |
747 |
|
748 |
my $data = $fcp->client_get ($url); # blocks |
749 |
|
750 |
my $transaction = $fcp->txn_client_get ($url); # does not block |
751 |
$transaction->cb ( sub { ... } ); # set optional result callback |
752 |
my $data = $transaction->result; # possibly blocks |
753 |
|
754 |
The C<client_get> method works like C<LWP::Simple::get>: it requests the |
755 |
given URL and waits till the data has arrived. It is defined to be: |
756 |
|
757 |
sub client_get { $_[0]->txn_client_get ($_[1])->result } |
758 |
|
759 |
And in fact is automatically generated. This is the blocking API of |
760 |
L<Net::FCP>, and it works as simple as in any other, similar, module. |
761 |
|
762 |
More complicated is C<txn_client_get>: It only creates a transaction |
763 |
(completion, result, ...) object and initiates the transaction. |
764 |
|
765 |
my $txn = bless { }, Net::FCP::Txn::; |
766 |
|
767 |
It also creates a condition variable that is used to signal the completion |
768 |
of the request: |
769 |
|
770 |
$txn->{finished} = AnyAvent->condvar; |
771 |
|
772 |
It then creates a socket in non-blocking mode. |
773 |
|
774 |
socket $txn->{fh}, ...; |
775 |
fcntl $txn->{fh}, F_SETFL, O_NONBLOCK; |
776 |
connect $txn->{fh}, ... |
777 |
and !$!{EWOULDBLOCK} |
778 |
and !$!{EINPROGRESS} |
779 |
and Carp::croak "unable to connect: $!\n"; |
780 |
|
781 |
Then it creates a write-watcher which gets called whenever an error occurs |
782 |
or the connection succeeds: |
783 |
|
784 |
$txn->{w} = AnyEvent->io (fh => $txn->{fh}, poll => 'w', cb => sub { $txn->fh_ready_w }); |
785 |
|
786 |
And returns this transaction object. The C<fh_ready_w> callback gets |
787 |
called as soon as the event loop detects that the socket is ready for |
788 |
writing. |
789 |
|
790 |
The C<fh_ready_w> method makes the socket blocking again, writes the |
791 |
request data and replaces the watcher by a read watcher (waiting for reply |
792 |
data). The actual code is more complicated, but that doesn't matter for |
793 |
this example: |
794 |
|
795 |
fcntl $txn->{fh}, F_SETFL, 0; |
796 |
syswrite $txn->{fh}, $txn->{request} |
797 |
or die "connection or write error"; |
798 |
$txn->{w} = AnyEvent->io (fh => $txn->{fh}, poll => 'r', cb => sub { $txn->fh_ready_r }); |
799 |
|
800 |
Again, C<fh_ready_r> waits till all data has arrived, and then stores the |
801 |
result and signals any possible waiters that the request ahs finished: |
802 |
|
803 |
sysread $txn->{fh}, $txn->{buf}, length $txn->{$buf}; |
804 |
|
805 |
if (end-of-file or data complete) { |
806 |
$txn->{result} = $txn->{buf}; |
807 |
$txn->{finished}->broadcast; |
808 |
$txb->{cb}->($txn) of $txn->{cb}; # also call callback |
809 |
} |
810 |
|
811 |
The C<result> method, finally, just waits for the finished signal (if the |
812 |
request was already finished, it doesn't wait, of course, and returns the |
813 |
data: |
814 |
|
815 |
$txn->{finished}->wait; |
816 |
return $txn->{result}; |
817 |
|
818 |
The actual code goes further and collects all errors (C<die>s, exceptions) |
819 |
that occured during request processing. The C<result> method detects |
820 |
whether an exception as thrown (it is stored inside the $txn object) |
821 |
and just throws the exception, which means connection errors and other |
822 |
problems get reported tot he code that tries to use the result, not in a |
823 |
random callback. |
824 |
|
825 |
All of this enables the following usage styles: |
826 |
|
827 |
1. Blocking: |
828 |
|
829 |
my $data = $fcp->client_get ($url); |
830 |
|
831 |
2. Blocking, but running in parallel: |
832 |
|
833 |
my @datas = map $_->result, |
834 |
map $fcp->txn_client_get ($_), |
835 |
@urls; |
836 |
|
837 |
Both blocking examples work without the module user having to know |
838 |
anything about events. |
839 |
|
840 |
3a. Event-based in a main program, using any supported event module: |
841 |
|
842 |
use EV; |
843 |
|
844 |
$fcp->txn_client_get ($url)->cb (sub { |
845 |
my $txn = shift; |
846 |
my $data = $txn->result; |
847 |
... |
848 |
}); |
849 |
|
850 |
EV::loop; |
851 |
|
852 |
3b. The module user could use AnyEvent, too: |
853 |
|
854 |
use AnyEvent; |
855 |
|
856 |
my $quit = AnyEvent->condvar; |
857 |
|
858 |
$fcp->txn_client_get ($url)->cb (sub { |
859 |
... |
860 |
$quit->broadcast; |
861 |
}); |
862 |
|
863 |
$quit->wait; |
864 |
|
865 |
|
866 |
=head1 BENCHMARK |
867 |
|
868 |
To give you an idea of the performance and overheads that AnyEvent adds |
869 |
over the event loops directly, here is a benchmark of various supported |
870 |
event models natively and with anyevent. The benchmark creates a lot of |
871 |
timers (with a zero timeout) and io watchers (watching STDOUT, a pty, to |
872 |
become writable, which it is), lets them fire exactly once and destroys |
873 |
them again. |
874 |
|
875 |
=head2 Explanation of the columns |
876 |
|
877 |
I<watcher> is the number of event watchers created/destroyed. Since |
878 |
different event models feature vastly different performances, each event |
879 |
loop was given a number of watchers so that overall runtime is acceptable |
880 |
and similar between tested event loop (and keep them from crashing): Glib |
881 |
would probably take thousands of years if asked to process the same number |
882 |
of watchers as EV in this benchmark. |
883 |
|
884 |
I<bytes> is the number of bytes (as measured by the resident set size, |
885 |
RSS) consumed by each watcher. This method of measuring captures both C |
886 |
and Perl-based overheads. |
887 |
|
888 |
I<create> is the time, in microseconds (millionths of seconds), that it |
889 |
takes to create a single watcher. The callback is a closure shared between |
890 |
all watchers, to avoid adding memory overhead. That means closure creation |
891 |
and memory usage is not included in the figures. |
892 |
|
893 |
I<invoke> is the time, in microseconds, used to invoke a simple |
894 |
callback. The callback simply counts down a Perl variable and after it was |
895 |
invoked "watcher" times, it would C<< ->broadcast >> a condvar once to |
896 |
signal the end of this phase. |
897 |
|
898 |
I<destroy> is the time, in microseconds, that it takes destroy a single |
899 |
watcher. |
900 |
|
901 |
=head2 Results |
902 |
|
903 |
name watcher bytes create invoke destroy comment |
904 |
EV/EV 400000 244 0.56 0.46 0.31 EV native interface |
905 |
EV/Any 100000 610 3.52 0.91 0.75 EV + AnyEvent watchers |
906 |
CoroEV/Any 100000 610 3.49 0.92 0.75 coroutines + Coro::Signal |
907 |
Perl/Any 16000 654 4.64 1.22 0.77 pure perl implementation |
908 |
Event/Event 16000 523 28.05 21.38 0.86 Event native interface |
909 |
Event/Any 16000 943 34.43 20.48 1.39 Event + AnyEvent watchers |
910 |
Glib/Any 16000 1357 96.99 12.55 55.51 quadratic behaviour |
911 |
Tk/Any 2000 1855 27.01 66.61 14.03 SEGV with >> 2000 watchers |
912 |
POE/Event 2000 6644 108.15 768.19 14.33 via POE::Loop::Event |
913 |
POE/Select 2000 6343 94.69 807.65 562.69 via POE::Loop::Select |
914 |
|
915 |
=head2 Discussion |
916 |
|
917 |
The benchmark does I<not> measure scalability of the event loop very |
918 |
well. For example, a select-based event loop (such as the pure perl one) |
919 |
can never compete with an event loop that uses epoll when the number of |
920 |
file descriptors grows high. In this benchmark, only a single filehandle |
921 |
is used (although some of the AnyEvent adaptors dup() its file descriptor |
922 |
to worka round bugs). |
923 |
|
924 |
C<EV> is the sole leader regarding speed and memory use, which are both |
925 |
maximal/minimal, respectively. Even when going through AnyEvent, there is |
926 |
only one event loop that uses less memory (the C<Event> module natively), and |
927 |
no faster event model, not event C<Event> natively. |
928 |
|
929 |
The pure perl implementation is hit in a few sweet spots (both the |
930 |
zero timeout and the use of a single fd hit optimisations in the perl |
931 |
interpreter and the backend itself). Nevertheless tis shows that it |
932 |
adds very little overhead in itself. Like any select-based backend its |
933 |
performance becomes really bad with lots of file descriptors, of course, |
934 |
but this was not subjetc of this benchmark. |
935 |
|
936 |
The C<Event> module has a relatively high setup and callback invocation cost, |
937 |
but overall scores on the third place. |
938 |
|
939 |
C<Glib>'s memory usage is quite a bit bit higher, features a faster |
940 |
callback invocation and overall lands in the same class as C<Event>. |
941 |
|
942 |
The C<Tk> adaptor works relatively well, the fact that it crashes with |
943 |
more than 2000 watchers is a big setback, however, as correctness takes |
944 |
precedence over speed. Nevertheless, its performance is surprising, as the |
945 |
file descriptor is dup()ed for each watcher. This shows that the dup() |
946 |
employed by some adaptors is not a big performance issue (it does incur a |
947 |
hidden memory cost inside the kernel, though). |
948 |
|
949 |
C<POE>, regardless of backend (wether using its pure perl select-based |
950 |
backend or the Event backend) shows abysmal performance and memory |
951 |
usage: Watchers use almost 30 times as much memory as EV watchers, and 10 |
952 |
times as much memory as both Event or EV via AnyEvent. Watcher invocation |
953 |
is almost 700 times slower as with AnyEvent's pure perl implementation. |
954 |
|
955 |
Summary: using EV through AnyEvent is faster than any other event |
956 |
loop. The overhead AnyEvent adds can be very small, and you should avoid |
957 |
POE like the plague if you want performance or reasonable memory usage. |
958 |
|
959 |
|
960 |
=head1 FORK |
961 |
|
962 |
Most event libraries are not fork-safe. The ones who are usually are |
963 |
because they are so inefficient. Only L<EV> is fully fork-aware. |
964 |
|
965 |
If you have to fork, you must either do so I<before> creating your first |
966 |
watcher OR you must not use AnyEvent at all in the child. |
967 |
|
968 |
|
969 |
=head1 SECURITY CONSIDERATIONS |
970 |
|
971 |
AnyEvent can be forced to load any event model via |
972 |
$ENV{PERL_ANYEVENT_MODEL}. While this cannot (to my knowledge) be used to |
973 |
execute arbitrary code or directly gain access, it can easily be used to |
974 |
make the program hang or malfunction in subtle ways, as AnyEvent watchers |
975 |
will not be active when the program uses a different event model than |
976 |
specified in the variable. |
977 |
|
978 |
You can make AnyEvent completely ignore this variable by deleting it |
979 |
before the first watcher gets created, e.g. with a C<BEGIN> block: |
980 |
|
981 |
BEGIN { delete $ENV{PERL_ANYEVENT_MODEL} } |
982 |
|
983 |
use AnyEvent; |
984 |
|
985 |
|
986 |
=head1 SEE ALSO |
987 |
|
988 |
Event modules: L<Coro::EV>, L<EV>, L<EV::Glib>, L<Glib::EV>, |
989 |
L<Coro::Event>, L<Event>, L<Glib::Event>, L<Glib>, L<Coro>, L<Tk>, |
990 |
L<Event::Lib>, L<Qt>, L<POE>. |
991 |
|
992 |
Implementations: L<AnyEvent::Impl::CoroEV>, L<AnyEvent::Impl::EV>, |
993 |
L<AnyEvent::Impl::CoroEvent>, L<AnyEvent::Impl::Event>, L<AnyEvent::Impl::Glib>, |
994 |
L<AnyEvent::Impl::Tk>, L<AnyEvent::Impl::Perl>, L<AnyEvent::Impl::EventLib>, |
995 |
L<AnyEvent::Impl::Qt>, L<AnyEvent::Impl::POE>. |
996 |
|
997 |
Nontrivial usage examples: L<Net::FCP>, L<Net::XMPP2>. |
998 |
|
999 |
|
1000 |
=head1 AUTHOR |
1001 |
|
1002 |
Marc Lehmann <schmorp@schmorp.de> |
1003 |
http://home.schmorp.de/ |
1004 |
|
1005 |
=cut |
1006 |
|
1007 |
1 |
1008 |
|