1 |
package AnyEvent::Handle; |
2 |
|
3 |
no warnings; |
4 |
use strict qw(subs vars); |
5 |
|
6 |
use AnyEvent (); |
7 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
8 |
use Scalar::Util (); |
9 |
use Carp (); |
10 |
use Fcntl (); |
11 |
use Errno qw(EAGAIN EINTR); |
12 |
|
13 |
=head1 NAME |
14 |
|
15 |
AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent |
16 |
|
17 |
=cut |
18 |
|
19 |
our $VERSION = 4.232; |
20 |
|
21 |
=head1 SYNOPSIS |
22 |
|
23 |
use AnyEvent; |
24 |
use AnyEvent::Handle; |
25 |
|
26 |
my $cv = AnyEvent->condvar; |
27 |
|
28 |
my $handle = |
29 |
AnyEvent::Handle->new ( |
30 |
fh => \*STDIN, |
31 |
on_eof => sub { |
32 |
$cv->broadcast; |
33 |
}, |
34 |
); |
35 |
|
36 |
# send some request line |
37 |
$handle->push_write ("getinfo\015\012"); |
38 |
|
39 |
# read the response line |
40 |
$handle->push_read (line => sub { |
41 |
my ($handle, $line) = @_; |
42 |
warn "read line <$line>\n"; |
43 |
$cv->send; |
44 |
}); |
45 |
|
46 |
$cv->recv; |
47 |
|
48 |
=head1 DESCRIPTION |
49 |
|
50 |
This module is a helper module to make it easier to do event-based I/O on |
51 |
filehandles. For utility functions for doing non-blocking connects and accepts |
52 |
on sockets see L<AnyEvent::Util>. |
53 |
|
54 |
The L<AnyEvent::Intro> tutorial contains some well-documented |
55 |
AnyEvent::Handle examples. |
56 |
|
57 |
In the following, when the documentation refers to of "bytes" then this |
58 |
means characters. As sysread and syswrite are used for all I/O, their |
59 |
treatment of characters applies to this module as well. |
60 |
|
61 |
All callbacks will be invoked with the handle object as their first |
62 |
argument. |
63 |
|
64 |
=head1 METHODS |
65 |
|
66 |
=over 4 |
67 |
|
68 |
=item B<new (%args)> |
69 |
|
70 |
The constructor supports these arguments (all as key => value pairs). |
71 |
|
72 |
=over 4 |
73 |
|
74 |
=item fh => $filehandle [MANDATORY] |
75 |
|
76 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
77 |
|
78 |
NOTE: The filehandle will be set to non-blocking mode (using |
79 |
C<AnyEvent::Util::fh_nonblocking>) by the constructor and needs to stay in |
80 |
that mode. |
81 |
|
82 |
=item on_eof => $cb->($handle) |
83 |
|
84 |
Set the callback to be called when an end-of-file condition is detected, |
85 |
i.e. in the case of a socket, when the other side has closed the |
86 |
connection cleanly. |
87 |
|
88 |
For sockets, this just means that the other side has stopped sending data, |
89 |
you can still try to write data, and, in fact, one can return from the eof |
90 |
callback and continue writing data, as only the read part has been shut |
91 |
down. |
92 |
|
93 |
While not mandatory, it is I<highly> recommended to set an eof callback, |
94 |
otherwise you might end up with a closed socket while you are still |
95 |
waiting for data. |
96 |
|
97 |
If an EOF condition has been detected but no C<on_eof> callback has been |
98 |
set, then a fatal error will be raised with C<$!> set to <0>. |
99 |
|
100 |
=item on_error => $cb->($handle, $fatal) |
101 |
|
102 |
This is the error callback, which is called when, well, some error |
103 |
occured, such as not being able to resolve the hostname, failure to |
104 |
connect or a read error. |
105 |
|
106 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
107 |
fatal errors the handle object will be shut down and will not be usable |
108 |
(but you are free to look at the current C< ->rbuf >). Examples of fatal |
109 |
errors are an EOF condition with active (but unsatisifable) read watchers |
110 |
(C<EPIPE>) or I/O errors. |
111 |
|
112 |
Non-fatal errors can be retried by simply returning, but it is recommended |
113 |
to simply ignore this parameter and instead abondon the handle object |
114 |
when this callback is invoked. Examples of non-fatal errors are timeouts |
115 |
C<ETIMEDOUT>) or badly-formatted data (C<EBADMSG>). |
116 |
|
117 |
On callback entrance, the value of C<$!> contains the operating system |
118 |
error (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT> or C<EBADMSG>). |
119 |
|
120 |
While not mandatory, it is I<highly> recommended to set this callback, as |
121 |
you will not be notified of errors otherwise. The default simply calls |
122 |
C<croak>. |
123 |
|
124 |
=item on_read => $cb->($handle) |
125 |
|
126 |
This sets the default read callback, which is called when data arrives |
127 |
and no read request is in the queue (unlike read queue callbacks, this |
128 |
callback will only be called when at least one octet of data is in the |
129 |
read buffer). |
130 |
|
131 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
132 |
method or access the C<$handle->{rbuf}> member directly. |
133 |
|
134 |
When an EOF condition is detected then AnyEvent::Handle will first try to |
135 |
feed all the remaining data to the queued callbacks and C<on_read> before |
136 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
137 |
error will be raised (with C<$!> set to C<EPIPE>). |
138 |
|
139 |
=item on_drain => $cb->($handle) |
140 |
|
141 |
This sets the callback that is called when the write buffer becomes empty |
142 |
(or when the callback is set and the buffer is empty already). |
143 |
|
144 |
To append to the write buffer, use the C<< ->push_write >> method. |
145 |
|
146 |
This callback is useful when you don't want to put all of your write data |
147 |
into the queue at once, for example, when you want to write the contents |
148 |
of some file to the socket you might not want to read the whole file into |
149 |
memory and push it into the queue, but instead only read more data from |
150 |
the file when the write queue becomes empty. |
151 |
|
152 |
=item timeout => $fractional_seconds |
153 |
|
154 |
If non-zero, then this enables an "inactivity" timeout: whenever this many |
155 |
seconds pass without a successful read or write on the underlying file |
156 |
handle, the C<on_timeout> callback will be invoked (and if that one is |
157 |
missing, an C<ETIMEDOUT> error will be raised). |
158 |
|
159 |
Note that timeout processing is also active when you currently do not have |
160 |
any outstanding read or write requests: If you plan to keep the connection |
161 |
idle then you should disable the timout temporarily or ignore the timeout |
162 |
in the C<on_timeout> callback. |
163 |
|
164 |
Zero (the default) disables this timeout. |
165 |
|
166 |
=item on_timeout => $cb->($handle) |
167 |
|
168 |
Called whenever the inactivity timeout passes. If you return from this |
169 |
callback, then the timeout will be reset as if some activity had happened, |
170 |
so this condition is not fatal in any way. |
171 |
|
172 |
=item rbuf_max => <bytes> |
173 |
|
174 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
175 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
176 |
avoid denial-of-service attacks. |
177 |
|
178 |
For example, a server accepting connections from untrusted sources should |
179 |
be configured to accept only so-and-so much data that it cannot act on |
180 |
(for example, when expecting a line, an attacker could send an unlimited |
181 |
amount of data without a callback ever being called as long as the line |
182 |
isn't finished). |
183 |
|
184 |
=item autocork => <boolean> |
185 |
|
186 |
When disabled (the default), then C<push_write> will try to immediately |
187 |
write the data to the handle if possible. This avoids having to register |
188 |
a write watcher and wait for the next event loop iteration, but can be |
189 |
inefficient if you write multiple small chunks (this disadvantage is |
190 |
usually avoided by your kernel's nagle algorithm, see C<low_delay>). |
191 |
|
192 |
When enabled, then writes will always be queued till the next event loop |
193 |
iteration. This is efficient when you do many small writes per iteration, |
194 |
but less efficient when you do a single write only. |
195 |
|
196 |
=item no_delay => <boolean> |
197 |
|
198 |
When doing small writes on sockets, your operating system kernel might |
199 |
wait a bit for more data before actually sending it out. This is called |
200 |
the Nagle algorithm, and usually it is beneficial. |
201 |
|
202 |
In some situations you want as low a delay as possible, which cna be |
203 |
accomplishd by setting this option to true. |
204 |
|
205 |
The default is your opertaing system's default behaviour, this option |
206 |
explicitly enables or disables it, if possible. |
207 |
|
208 |
=item read_size => <bytes> |
209 |
|
210 |
The default read block size (the amount of bytes this module will try to read |
211 |
during each (loop iteration). Default: C<8192>. |
212 |
|
213 |
=item low_water_mark => <bytes> |
214 |
|
215 |
Sets the amount of bytes (default: C<0>) that make up an "empty" write |
216 |
buffer: If the write reaches this size or gets even samller it is |
217 |
considered empty. |
218 |
|
219 |
=item linger => <seconds> |
220 |
|
221 |
If non-zero (default: C<3600>), then the destructor of the |
222 |
AnyEvent::Handle object will check wether there is still outstanding write |
223 |
data and will install a watcher that will write out this data. No errors |
224 |
will be reported (this mostly matches how the operating system treats |
225 |
outstanding data at socket close time). |
226 |
|
227 |
This will not work for partial TLS data that could not yet been |
228 |
encoded. This data will be lost. |
229 |
|
230 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
231 |
|
232 |
When this parameter is given, it enables TLS (SSL) mode, that means |
233 |
AnyEvent will start a TLS handshake and will transparently encrypt/decrypt |
234 |
data. |
235 |
|
236 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
237 |
automatically when you try to create a TLS handle). |
238 |
|
239 |
Unlike TCP, TLS has a server and client side: for the TLS server side, use |
240 |
C<accept>, and for the TLS client side of a connection, use C<connect> |
241 |
mode. |
242 |
|
243 |
You can also provide your own TLS connection object, but you have |
244 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
245 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
246 |
AnyEvent::Handle. |
247 |
|
248 |
See the C<starttls> method for when need to start TLS negotiation later. |
249 |
|
250 |
=item tls_ctx => $ssl_ctx |
251 |
|
252 |
Use the given Net::SSLeay::CTX object to create the new TLS connection |
253 |
(unless a connection object was specified directly). If this parameter is |
254 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
255 |
|
256 |
=item json => JSON or JSON::XS object |
257 |
|
258 |
This is the json coder object used by the C<json> read and write types. |
259 |
|
260 |
If you don't supply it, then AnyEvent::Handle will create and use a |
261 |
suitable one, which will write and expect UTF-8 encoded JSON texts. |
262 |
|
263 |
Note that you are responsible to depend on the JSON module if you want to |
264 |
use this functionality, as AnyEvent does not have a dependency itself. |
265 |
|
266 |
=item filter_r => $cb |
267 |
|
268 |
=item filter_w => $cb |
269 |
|
270 |
These exist, but are undocumented at this time. |
271 |
|
272 |
=back |
273 |
|
274 |
=cut |
275 |
|
276 |
sub new { |
277 |
my $class = shift; |
278 |
|
279 |
my $self = bless { @_ }, $class; |
280 |
|
281 |
$self->{fh} or Carp::croak "mandatory argument fh is missing"; |
282 |
|
283 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
284 |
|
285 |
if ($self->{tls}) { |
286 |
require Net::SSLeay; |
287 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}); |
288 |
} |
289 |
|
290 |
$self->{_activity} = AnyEvent->now; |
291 |
$self->_timeout; |
292 |
|
293 |
$self->on_drain (delete $self->{on_drain}) if exists $self->{on_drain}; |
294 |
$self->no_delay (delete $self->{no_delay}) if exists $self->{no_delay}; |
295 |
|
296 |
$self->start_read |
297 |
if $self->{on_read}; |
298 |
|
299 |
$self |
300 |
} |
301 |
|
302 |
sub _shutdown { |
303 |
my ($self) = @_; |
304 |
|
305 |
delete $self->{_tw}; |
306 |
delete $self->{_rw}; |
307 |
delete $self->{_ww}; |
308 |
delete $self->{fh}; |
309 |
|
310 |
$self->stoptls; |
311 |
|
312 |
delete $self->{on_read}; |
313 |
delete $self->{_queue}; |
314 |
} |
315 |
|
316 |
sub _error { |
317 |
my ($self, $errno, $fatal) = @_; |
318 |
|
319 |
$self->_shutdown |
320 |
if $fatal; |
321 |
|
322 |
$! = $errno; |
323 |
|
324 |
if ($self->{on_error}) { |
325 |
$self->{on_error}($self, $fatal); |
326 |
} else { |
327 |
Carp::croak "AnyEvent::Handle uncaught error: $!"; |
328 |
} |
329 |
} |
330 |
|
331 |
=item $fh = $handle->fh |
332 |
|
333 |
This method returns the file handle of the L<AnyEvent::Handle> object. |
334 |
|
335 |
=cut |
336 |
|
337 |
sub fh { $_[0]{fh} } |
338 |
|
339 |
=item $handle->on_error ($cb) |
340 |
|
341 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
342 |
|
343 |
=cut |
344 |
|
345 |
sub on_error { |
346 |
$_[0]{on_error} = $_[1]; |
347 |
} |
348 |
|
349 |
=item $handle->on_eof ($cb) |
350 |
|
351 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
352 |
|
353 |
=cut |
354 |
|
355 |
sub on_eof { |
356 |
$_[0]{on_eof} = $_[1]; |
357 |
} |
358 |
|
359 |
=item $handle->on_timeout ($cb) |
360 |
|
361 |
Replace the current C<on_timeout> callback, or disables the callback |
362 |
(but not the timeout) if C<$cb> = C<undef>. See C<timeout> constructor |
363 |
argument. |
364 |
|
365 |
=cut |
366 |
|
367 |
sub on_timeout { |
368 |
$_[0]{on_timeout} = $_[1]; |
369 |
} |
370 |
|
371 |
=item $handle->autocork ($boolean) |
372 |
|
373 |
Enables or disables the current autocork behaviour (see C<autocork> |
374 |
constructor argument). |
375 |
|
376 |
=cut |
377 |
|
378 |
=item $handle->no_delay ($boolean) |
379 |
|
380 |
Enables or disables the C<no_delay> setting (see constructor argument of |
381 |
the same name for details). |
382 |
|
383 |
=cut |
384 |
|
385 |
sub no_delay { |
386 |
$_[0]{no_delay} = $_[1]; |
387 |
|
388 |
eval { |
389 |
local $SIG{__DIE__}; |
390 |
setsockopt $_[0]{fh}, &Socket::IPPROTO_TCP, &Socket::TCP_NODELAY, int $_[1]; |
391 |
}; |
392 |
} |
393 |
|
394 |
############################################################################# |
395 |
|
396 |
=item $handle->timeout ($seconds) |
397 |
|
398 |
Configures (or disables) the inactivity timeout. |
399 |
|
400 |
=cut |
401 |
|
402 |
sub timeout { |
403 |
my ($self, $timeout) = @_; |
404 |
|
405 |
$self->{timeout} = $timeout; |
406 |
$self->_timeout; |
407 |
} |
408 |
|
409 |
# reset the timeout watcher, as neccessary |
410 |
# also check for time-outs |
411 |
sub _timeout { |
412 |
my ($self) = @_; |
413 |
|
414 |
if ($self->{timeout}) { |
415 |
my $NOW = AnyEvent->now; |
416 |
|
417 |
# when would the timeout trigger? |
418 |
my $after = $self->{_activity} + $self->{timeout} - $NOW; |
419 |
|
420 |
# now or in the past already? |
421 |
if ($after <= 0) { |
422 |
$self->{_activity} = $NOW; |
423 |
|
424 |
if ($self->{on_timeout}) { |
425 |
$self->{on_timeout}($self); |
426 |
} else { |
427 |
$self->_error (&Errno::ETIMEDOUT); |
428 |
} |
429 |
|
430 |
# callback could have changed timeout value, optimise |
431 |
return unless $self->{timeout}; |
432 |
|
433 |
# calculate new after |
434 |
$after = $self->{timeout}; |
435 |
} |
436 |
|
437 |
Scalar::Util::weaken $self; |
438 |
return unless $self; # ->error could have destroyed $self |
439 |
|
440 |
$self->{_tw} ||= AnyEvent->timer (after => $after, cb => sub { |
441 |
delete $self->{_tw}; |
442 |
$self->_timeout; |
443 |
}); |
444 |
} else { |
445 |
delete $self->{_tw}; |
446 |
} |
447 |
} |
448 |
|
449 |
############################################################################# |
450 |
|
451 |
=back |
452 |
|
453 |
=head2 WRITE QUEUE |
454 |
|
455 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
456 |
for reading. |
457 |
|
458 |
The write queue is very simple: you can add data to its end, and |
459 |
AnyEvent::Handle will automatically try to get rid of it for you. |
460 |
|
461 |
When data could be written and the write buffer is shorter then the low |
462 |
water mark, the C<on_drain> callback will be invoked. |
463 |
|
464 |
=over 4 |
465 |
|
466 |
=item $handle->on_drain ($cb) |
467 |
|
468 |
Sets the C<on_drain> callback or clears it (see the description of |
469 |
C<on_drain> in the constructor). |
470 |
|
471 |
=cut |
472 |
|
473 |
sub on_drain { |
474 |
my ($self, $cb) = @_; |
475 |
|
476 |
$self->{on_drain} = $cb; |
477 |
|
478 |
$cb->($self) |
479 |
if $cb && $self->{low_water_mark} >= length $self->{wbuf}; |
480 |
} |
481 |
|
482 |
=item $handle->push_write ($data) |
483 |
|
484 |
Queues the given scalar to be written. You can push as much data as you |
485 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
486 |
buffers it independently of the kernel. |
487 |
|
488 |
=cut |
489 |
|
490 |
sub _drain_wbuf { |
491 |
my ($self) = @_; |
492 |
|
493 |
if (!$self->{_ww} && length $self->{wbuf}) { |
494 |
|
495 |
Scalar::Util::weaken $self; |
496 |
|
497 |
my $cb = sub { |
498 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
499 |
|
500 |
if ($len >= 0) { |
501 |
substr $self->{wbuf}, 0, $len, ""; |
502 |
|
503 |
$self->{_activity} = AnyEvent->now; |
504 |
|
505 |
$self->{on_drain}($self) |
506 |
if $self->{low_water_mark} >= length $self->{wbuf} |
507 |
&& $self->{on_drain}; |
508 |
|
509 |
delete $self->{_ww} unless length $self->{wbuf}; |
510 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
511 |
$self->_error ($!, 1); |
512 |
} |
513 |
}; |
514 |
|
515 |
# try to write data immediately |
516 |
$cb->() unless $self->{autocork}; |
517 |
|
518 |
# if still data left in wbuf, we need to poll |
519 |
$self->{_ww} = AnyEvent->io (fh => $self->{fh}, poll => "w", cb => $cb) |
520 |
if length $self->{wbuf}; |
521 |
}; |
522 |
} |
523 |
|
524 |
our %WH; |
525 |
|
526 |
sub register_write_type($$) { |
527 |
$WH{$_[0]} = $_[1]; |
528 |
} |
529 |
|
530 |
sub push_write { |
531 |
my $self = shift; |
532 |
|
533 |
if (@_ > 1) { |
534 |
my $type = shift; |
535 |
|
536 |
@_ = ($WH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_write") |
537 |
->($self, @_); |
538 |
} |
539 |
|
540 |
if ($self->{filter_w}) { |
541 |
$self->{filter_w}($self, \$_[0]); |
542 |
} else { |
543 |
$self->{wbuf} .= $_[0]; |
544 |
$self->_drain_wbuf; |
545 |
} |
546 |
} |
547 |
|
548 |
=item $handle->push_write (type => @args) |
549 |
|
550 |
Instead of formatting your data yourself, you can also let this module do |
551 |
the job by specifying a type and type-specific arguments. |
552 |
|
553 |
Predefined types are (if you have ideas for additional types, feel free to |
554 |
drop by and tell us): |
555 |
|
556 |
=over 4 |
557 |
|
558 |
=item netstring => $string |
559 |
|
560 |
Formats the given value as netstring |
561 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
562 |
|
563 |
=cut |
564 |
|
565 |
register_write_type netstring => sub { |
566 |
my ($self, $string) = @_; |
567 |
|
568 |
sprintf "%d:%s,", (length $string), $string |
569 |
}; |
570 |
|
571 |
=item packstring => $format, $data |
572 |
|
573 |
An octet string prefixed with an encoded length. The encoding C<$format> |
574 |
uses the same format as a Perl C<pack> format, but must specify a single |
575 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
576 |
optional C<!>, C<< < >> or C<< > >> modifier). |
577 |
|
578 |
=cut |
579 |
|
580 |
register_write_type packstring => sub { |
581 |
my ($self, $format, $string) = @_; |
582 |
|
583 |
pack "$format/a*", $string |
584 |
}; |
585 |
|
586 |
=item json => $array_or_hashref |
587 |
|
588 |
Encodes the given hash or array reference into a JSON object. Unless you |
589 |
provide your own JSON object, this means it will be encoded to JSON text |
590 |
in UTF-8. |
591 |
|
592 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
593 |
one end of a handle and read them at the other end without using any |
594 |
additional framing. |
595 |
|
596 |
The generated JSON text is guaranteed not to contain any newlines: While |
597 |
this module doesn't need delimiters after or between JSON texts to be |
598 |
able to read them, many other languages depend on that. |
599 |
|
600 |
A simple RPC protocol that interoperates easily with others is to send |
601 |
JSON arrays (or objects, although arrays are usually the better choice as |
602 |
they mimic how function argument passing works) and a newline after each |
603 |
JSON text: |
604 |
|
605 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
606 |
$handle->push_write ("\012"); |
607 |
|
608 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
609 |
rely on the fact that the newline will be skipped as leading whitespace: |
610 |
|
611 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
612 |
|
613 |
Other languages could read single lines terminated by a newline and pass |
614 |
this line into their JSON decoder of choice. |
615 |
|
616 |
=cut |
617 |
|
618 |
register_write_type json => sub { |
619 |
my ($self, $ref) = @_; |
620 |
|
621 |
require JSON; |
622 |
|
623 |
$self->{json} ? $self->{json}->encode ($ref) |
624 |
: JSON::encode_json ($ref) |
625 |
}; |
626 |
|
627 |
=item storable => $reference |
628 |
|
629 |
Freezes the given reference using L<Storable> and writes it to the |
630 |
handle. Uses the C<nfreeze> format. |
631 |
|
632 |
=cut |
633 |
|
634 |
register_write_type storable => sub { |
635 |
my ($self, $ref) = @_; |
636 |
|
637 |
require Storable; |
638 |
|
639 |
pack "w/a*", Storable::nfreeze ($ref) |
640 |
}; |
641 |
|
642 |
=back |
643 |
|
644 |
=item AnyEvent::Handle::register_write_type type => $coderef->($handle, @args) |
645 |
|
646 |
This function (not method) lets you add your own types to C<push_write>. |
647 |
Whenever the given C<type> is used, C<push_write> will invoke the code |
648 |
reference with the handle object and the remaining arguments. |
649 |
|
650 |
The code reference is supposed to return a single octet string that will |
651 |
be appended to the write buffer. |
652 |
|
653 |
Note that this is a function, and all types registered this way will be |
654 |
global, so try to use unique names. |
655 |
|
656 |
=cut |
657 |
|
658 |
############################################################################# |
659 |
|
660 |
=back |
661 |
|
662 |
=head2 READ QUEUE |
663 |
|
664 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
665 |
for reading. |
666 |
|
667 |
The read queue is more complex than the write queue. It can be used in two |
668 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
669 |
a queue. |
670 |
|
671 |
In the simple case, you just install an C<on_read> callback and whenever |
672 |
new data arrives, it will be called. You can then remove some data (if |
673 |
enough is there) from the read buffer (C<< $handle->rbuf >>). Or you cna |
674 |
leave the data there if you want to accumulate more (e.g. when only a |
675 |
partial message has been received so far). |
676 |
|
677 |
In the more complex case, you want to queue multiple callbacks. In this |
678 |
case, AnyEvent::Handle will call the first queued callback each time new |
679 |
data arrives (also the first time it is queued) and removes it when it has |
680 |
done its job (see C<push_read>, below). |
681 |
|
682 |
This way you can, for example, push three line-reads, followed by reading |
683 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
684 |
|
685 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
686 |
the specified number of bytes which give an XML datagram. |
687 |
|
688 |
# in the default state, expect some header bytes |
689 |
$handle->on_read (sub { |
690 |
# some data is here, now queue the length-header-read (4 octets) |
691 |
shift->unshift_read (chunk => 4, sub { |
692 |
# header arrived, decode |
693 |
my $len = unpack "N", $_[1]; |
694 |
|
695 |
# now read the payload |
696 |
shift->unshift_read (chunk => $len, sub { |
697 |
my $xml = $_[1]; |
698 |
# handle xml |
699 |
}); |
700 |
}); |
701 |
}); |
702 |
|
703 |
Example 2: Implement a client for a protocol that replies either with "OK" |
704 |
and another line or "ERROR" for the first request that is sent, and 64 |
705 |
bytes for the second request. Due to the availability of a queue, we can |
706 |
just pipeline sending both requests and manipulate the queue as necessary |
707 |
in the callbacks. |
708 |
|
709 |
When the first callback is called and sees an "OK" response, it will |
710 |
C<unshift> another line-read. This line-read will be queued I<before> the |
711 |
64-byte chunk callback. |
712 |
|
713 |
# request one, returns either "OK + extra line" or "ERROR" |
714 |
$handle->push_write ("request 1\015\012"); |
715 |
|
716 |
# we expect "ERROR" or "OK" as response, so push a line read |
717 |
$handle->push_read (line => sub { |
718 |
# if we got an "OK", we have to _prepend_ another line, |
719 |
# so it will be read before the second request reads its 64 bytes |
720 |
# which are already in the queue when this callback is called |
721 |
# we don't do this in case we got an error |
722 |
if ($_[1] eq "OK") { |
723 |
$_[0]->unshift_read (line => sub { |
724 |
my $response = $_[1]; |
725 |
... |
726 |
}); |
727 |
} |
728 |
}); |
729 |
|
730 |
# request two, simply returns 64 octets |
731 |
$handle->push_write ("request 2\015\012"); |
732 |
|
733 |
# simply read 64 bytes, always |
734 |
$handle->push_read (chunk => 64, sub { |
735 |
my $response = $_[1]; |
736 |
... |
737 |
}); |
738 |
|
739 |
=over 4 |
740 |
|
741 |
=cut |
742 |
|
743 |
sub _drain_rbuf { |
744 |
my ($self) = @_; |
745 |
|
746 |
local $self->{_in_drain} = 1; |
747 |
|
748 |
if ( |
749 |
defined $self->{rbuf_max} |
750 |
&& $self->{rbuf_max} < length $self->{rbuf} |
751 |
) { |
752 |
$self->_error (&Errno::ENOSPC, 1), return; |
753 |
} |
754 |
|
755 |
while () { |
756 |
my $len = length $self->{rbuf}; |
757 |
|
758 |
if (my $cb = shift @{ $self->{_queue} }) { |
759 |
unless ($cb->($self)) { |
760 |
if ($self->{_eof}) { |
761 |
# no progress can be made (not enough data and no data forthcoming) |
762 |
$self->_error (&Errno::EPIPE, 1), return; |
763 |
} |
764 |
|
765 |
unshift @{ $self->{_queue} }, $cb; |
766 |
last; |
767 |
} |
768 |
} elsif ($self->{on_read}) { |
769 |
last unless $len; |
770 |
|
771 |
$self->{on_read}($self); |
772 |
|
773 |
if ( |
774 |
$len == length $self->{rbuf} # if no data has been consumed |
775 |
&& !@{ $self->{_queue} } # and the queue is still empty |
776 |
&& $self->{on_read} # but we still have on_read |
777 |
) { |
778 |
# no further data will arrive |
779 |
# so no progress can be made |
780 |
$self->_error (&Errno::EPIPE, 1), return |
781 |
if $self->{_eof}; |
782 |
|
783 |
last; # more data might arrive |
784 |
} |
785 |
} else { |
786 |
# read side becomes idle |
787 |
delete $self->{_rw}; |
788 |
last; |
789 |
} |
790 |
} |
791 |
|
792 |
if ($self->{_eof}) { |
793 |
if ($self->{on_eof}) { |
794 |
$self->{on_eof}($self) |
795 |
} else { |
796 |
$self->_error (0, 1); |
797 |
} |
798 |
} |
799 |
|
800 |
# may need to restart read watcher |
801 |
unless ($self->{_rw}) { |
802 |
$self->start_read |
803 |
if $self->{on_read} || @{ $self->{_queue} }; |
804 |
} |
805 |
} |
806 |
|
807 |
=item $handle->on_read ($cb) |
808 |
|
809 |
This replaces the currently set C<on_read> callback, or clears it (when |
810 |
the new callback is C<undef>). See the description of C<on_read> in the |
811 |
constructor. |
812 |
|
813 |
=cut |
814 |
|
815 |
sub on_read { |
816 |
my ($self, $cb) = @_; |
817 |
|
818 |
$self->{on_read} = $cb; |
819 |
$self->_drain_rbuf if $cb && !$self->{_in_drain}; |
820 |
} |
821 |
|
822 |
=item $handle->rbuf |
823 |
|
824 |
Returns the read buffer (as a modifiable lvalue). |
825 |
|
826 |
You can access the read buffer directly as the C<< ->{rbuf} >> member, if |
827 |
you want. |
828 |
|
829 |
NOTE: The read buffer should only be used or modified if the C<on_read>, |
830 |
C<push_read> or C<unshift_read> methods are used. The other read methods |
831 |
automatically manage the read buffer. |
832 |
|
833 |
=cut |
834 |
|
835 |
sub rbuf : lvalue { |
836 |
$_[0]{rbuf} |
837 |
} |
838 |
|
839 |
=item $handle->push_read ($cb) |
840 |
|
841 |
=item $handle->unshift_read ($cb) |
842 |
|
843 |
Append the given callback to the end of the queue (C<push_read>) or |
844 |
prepend it (C<unshift_read>). |
845 |
|
846 |
The callback is called each time some additional read data arrives. |
847 |
|
848 |
It must check whether enough data is in the read buffer already. |
849 |
|
850 |
If not enough data is available, it must return the empty list or a false |
851 |
value, in which case it will be called repeatedly until enough data is |
852 |
available (or an error condition is detected). |
853 |
|
854 |
If enough data was available, then the callback must remove all data it is |
855 |
interested in (which can be none at all) and return a true value. After returning |
856 |
true, it will be removed from the queue. |
857 |
|
858 |
=cut |
859 |
|
860 |
our %RH; |
861 |
|
862 |
sub register_read_type($$) { |
863 |
$RH{$_[0]} = $_[1]; |
864 |
} |
865 |
|
866 |
sub push_read { |
867 |
my $self = shift; |
868 |
my $cb = pop; |
869 |
|
870 |
if (@_) { |
871 |
my $type = shift; |
872 |
|
873 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_read") |
874 |
->($self, $cb, @_); |
875 |
} |
876 |
|
877 |
push @{ $self->{_queue} }, $cb; |
878 |
$self->_drain_rbuf unless $self->{_in_drain}; |
879 |
} |
880 |
|
881 |
sub unshift_read { |
882 |
my $self = shift; |
883 |
my $cb = pop; |
884 |
|
885 |
if (@_) { |
886 |
my $type = shift; |
887 |
|
888 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::unshift_read") |
889 |
->($self, $cb, @_); |
890 |
} |
891 |
|
892 |
|
893 |
unshift @{ $self->{_queue} }, $cb; |
894 |
$self->_drain_rbuf unless $self->{_in_drain}; |
895 |
} |
896 |
|
897 |
=item $handle->push_read (type => @args, $cb) |
898 |
|
899 |
=item $handle->unshift_read (type => @args, $cb) |
900 |
|
901 |
Instead of providing a callback that parses the data itself you can chose |
902 |
between a number of predefined parsing formats, for chunks of data, lines |
903 |
etc. |
904 |
|
905 |
Predefined types are (if you have ideas for additional types, feel free to |
906 |
drop by and tell us): |
907 |
|
908 |
=over 4 |
909 |
|
910 |
=item chunk => $octets, $cb->($handle, $data) |
911 |
|
912 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
913 |
data read to the callback. The callback will never be called with less |
914 |
data. |
915 |
|
916 |
Example: read 2 bytes. |
917 |
|
918 |
$handle->push_read (chunk => 2, sub { |
919 |
warn "yay ", unpack "H*", $_[1]; |
920 |
}); |
921 |
|
922 |
=cut |
923 |
|
924 |
register_read_type chunk => sub { |
925 |
my ($self, $cb, $len) = @_; |
926 |
|
927 |
sub { |
928 |
$len <= length $_[0]{rbuf} or return; |
929 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
930 |
1 |
931 |
} |
932 |
}; |
933 |
|
934 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
935 |
|
936 |
The callback will be called only once a full line (including the end of |
937 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
938 |
marker) will be passed to the callback as second argument (C<$line>), and |
939 |
the end of line marker as the third argument (C<$eol>). |
940 |
|
941 |
The end of line marker, C<$eol>, can be either a string, in which case it |
942 |
will be interpreted as a fixed record end marker, or it can be a regex |
943 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
944 |
regular expression. |
945 |
|
946 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
947 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
948 |
protocols). |
949 |
|
950 |
Partial lines at the end of the stream will never be returned, as they are |
951 |
not marked by the end of line marker. |
952 |
|
953 |
=cut |
954 |
|
955 |
register_read_type line => sub { |
956 |
my ($self, $cb, $eol) = @_; |
957 |
|
958 |
if (@_ < 3) { |
959 |
# this is more than twice as fast as the generic code below |
960 |
sub { |
961 |
$_[0]{rbuf} =~ s/^([^\015\012]*)(\015?\012)// or return; |
962 |
|
963 |
$cb->($_[0], $1, $2); |
964 |
1 |
965 |
} |
966 |
} else { |
967 |
$eol = quotemeta $eol unless ref $eol; |
968 |
$eol = qr|^(.*?)($eol)|s; |
969 |
|
970 |
sub { |
971 |
$_[0]{rbuf} =~ s/$eol// or return; |
972 |
|
973 |
$cb->($_[0], $1, $2); |
974 |
1 |
975 |
} |
976 |
} |
977 |
}; |
978 |
|
979 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
980 |
|
981 |
Makes a regex match against the regex object C<$accept> and returns |
982 |
everything up to and including the match. |
983 |
|
984 |
Example: read a single line terminated by '\n'. |
985 |
|
986 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
987 |
|
988 |
If C<$reject> is given and not undef, then it determines when the data is |
989 |
to be rejected: it is matched against the data when the C<$accept> regex |
990 |
does not match and generates an C<EBADMSG> error when it matches. This is |
991 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
992 |
receive buffer overflow). |
993 |
|
994 |
Example: expect a single decimal number followed by whitespace, reject |
995 |
anything else (not the use of an anchor). |
996 |
|
997 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
998 |
|
999 |
If C<$skip> is given and not C<undef>, then it will be matched against |
1000 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
1001 |
and everything preceding and including the match will be accepted |
1002 |
unconditionally. This is useful to skip large amounts of data that you |
1003 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
1004 |
have to start matching from the beginning. This is purely an optimisation |
1005 |
and is usually worth only when you expect more than a few kilobytes. |
1006 |
|
1007 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
1008 |
expect the header to be very large (it isn't in practise, but...), we use |
1009 |
a skip regex to skip initial portions. The skip regex is tricky in that |
1010 |
it only accepts something not ending in either \015 or \012, as these are |
1011 |
required for the accept regex. |
1012 |
|
1013 |
$handle->push_read (regex => |
1014 |
qr<\015\012\015\012>, |
1015 |
undef, # no reject |
1016 |
qr<^.*[^\015\012]>, |
1017 |
sub { ... }); |
1018 |
|
1019 |
=cut |
1020 |
|
1021 |
register_read_type regex => sub { |
1022 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
1023 |
|
1024 |
my $data; |
1025 |
my $rbuf = \$self->{rbuf}; |
1026 |
|
1027 |
sub { |
1028 |
# accept |
1029 |
if ($$rbuf =~ $accept) { |
1030 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1031 |
$cb->($self, $data); |
1032 |
return 1; |
1033 |
} |
1034 |
|
1035 |
# reject |
1036 |
if ($reject && $$rbuf =~ $reject) { |
1037 |
$self->_error (&Errno::EBADMSG); |
1038 |
} |
1039 |
|
1040 |
# skip |
1041 |
if ($skip && $$rbuf =~ $skip) { |
1042 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1043 |
} |
1044 |
|
1045 |
() |
1046 |
} |
1047 |
}; |
1048 |
|
1049 |
=item netstring => $cb->($handle, $string) |
1050 |
|
1051 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
1052 |
|
1053 |
Throws an error with C<$!> set to EBADMSG on format violations. |
1054 |
|
1055 |
=cut |
1056 |
|
1057 |
register_read_type netstring => sub { |
1058 |
my ($self, $cb) = @_; |
1059 |
|
1060 |
sub { |
1061 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
1062 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
1063 |
$self->_error (&Errno::EBADMSG); |
1064 |
} |
1065 |
return; |
1066 |
} |
1067 |
|
1068 |
my $len = $1; |
1069 |
|
1070 |
$self->unshift_read (chunk => $len, sub { |
1071 |
my $string = $_[1]; |
1072 |
$_[0]->unshift_read (chunk => 1, sub { |
1073 |
if ($_[1] eq ",") { |
1074 |
$cb->($_[0], $string); |
1075 |
} else { |
1076 |
$self->_error (&Errno::EBADMSG); |
1077 |
} |
1078 |
}); |
1079 |
}); |
1080 |
|
1081 |
1 |
1082 |
} |
1083 |
}; |
1084 |
|
1085 |
=item packstring => $format, $cb->($handle, $string) |
1086 |
|
1087 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1088 |
uses the same format as a Perl C<pack> format, but must specify a single |
1089 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1090 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1091 |
|
1092 |
DNS over TCP uses a prefix of C<n>, EPP uses a prefix of C<N>. |
1093 |
|
1094 |
Example: read a block of data prefixed by its length in BER-encoded |
1095 |
format (very efficient). |
1096 |
|
1097 |
$handle->push_read (packstring => "w", sub { |
1098 |
my ($handle, $data) = @_; |
1099 |
}); |
1100 |
|
1101 |
=cut |
1102 |
|
1103 |
register_read_type packstring => sub { |
1104 |
my ($self, $cb, $format) = @_; |
1105 |
|
1106 |
sub { |
1107 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1108 |
defined (my $len = eval { unpack $format, $_[0]{rbuf} }) |
1109 |
or return; |
1110 |
|
1111 |
$format = length pack $format, $len; |
1112 |
|
1113 |
# bypass unshift if we already have the remaining chunk |
1114 |
if ($format + $len <= length $_[0]{rbuf}) { |
1115 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1116 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1117 |
$cb->($_[0], $data); |
1118 |
} else { |
1119 |
# remove prefix |
1120 |
substr $_[0]{rbuf}, 0, $format, ""; |
1121 |
|
1122 |
# read remaining chunk |
1123 |
$_[0]->unshift_read (chunk => $len, $cb); |
1124 |
} |
1125 |
|
1126 |
1 |
1127 |
} |
1128 |
}; |
1129 |
|
1130 |
=item json => $cb->($handle, $hash_or_arrayref) |
1131 |
|
1132 |
Reads a JSON object or array, decodes it and passes it to the callback. |
1133 |
|
1134 |
If a C<json> object was passed to the constructor, then that will be used |
1135 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1136 |
|
1137 |
This read type uses the incremental parser available with JSON version |
1138 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1139 |
dependency on your own: this module will load the JSON module, but |
1140 |
AnyEvent does not depend on it itself. |
1141 |
|
1142 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1143 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1144 |
the C<json> write type description, above, for an actual example. |
1145 |
|
1146 |
=cut |
1147 |
|
1148 |
register_read_type json => sub { |
1149 |
my ($self, $cb) = @_; |
1150 |
|
1151 |
require JSON; |
1152 |
|
1153 |
my $data; |
1154 |
my $rbuf = \$self->{rbuf}; |
1155 |
|
1156 |
my $json = $self->{json} ||= JSON->new->utf8; |
1157 |
|
1158 |
sub { |
1159 |
my $ref = $json->incr_parse ($self->{rbuf}); |
1160 |
|
1161 |
if ($ref) { |
1162 |
$self->{rbuf} = $json->incr_text; |
1163 |
$json->incr_text = ""; |
1164 |
$cb->($self, $ref); |
1165 |
|
1166 |
1 |
1167 |
} else { |
1168 |
$self->{rbuf} = ""; |
1169 |
() |
1170 |
} |
1171 |
} |
1172 |
}; |
1173 |
|
1174 |
=item storable => $cb->($handle, $ref) |
1175 |
|
1176 |
Deserialises a L<Storable> frozen representation as written by the |
1177 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1178 |
data). |
1179 |
|
1180 |
Raises C<EBADMSG> error if the data could not be decoded. |
1181 |
|
1182 |
=cut |
1183 |
|
1184 |
register_read_type storable => sub { |
1185 |
my ($self, $cb) = @_; |
1186 |
|
1187 |
require Storable; |
1188 |
|
1189 |
sub { |
1190 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1191 |
defined (my $len = eval { unpack "w", $_[0]{rbuf} }) |
1192 |
or return; |
1193 |
|
1194 |
my $format = length pack "w", $len; |
1195 |
|
1196 |
# bypass unshift if we already have the remaining chunk |
1197 |
if ($format + $len <= length $_[0]{rbuf}) { |
1198 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1199 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1200 |
$cb->($_[0], Storable::thaw ($data)); |
1201 |
} else { |
1202 |
# remove prefix |
1203 |
substr $_[0]{rbuf}, 0, $format, ""; |
1204 |
|
1205 |
# read remaining chunk |
1206 |
$_[0]->unshift_read (chunk => $len, sub { |
1207 |
if (my $ref = eval { Storable::thaw ($_[1]) }) { |
1208 |
$cb->($_[0], $ref); |
1209 |
} else { |
1210 |
$self->_error (&Errno::EBADMSG); |
1211 |
} |
1212 |
}); |
1213 |
} |
1214 |
|
1215 |
1 |
1216 |
} |
1217 |
}; |
1218 |
|
1219 |
=back |
1220 |
|
1221 |
=item AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args) |
1222 |
|
1223 |
This function (not method) lets you add your own types to C<push_read>. |
1224 |
|
1225 |
Whenever the given C<type> is used, C<push_read> will invoke the code |
1226 |
reference with the handle object, the callback and the remaining |
1227 |
arguments. |
1228 |
|
1229 |
The code reference is supposed to return a callback (usually a closure) |
1230 |
that works as a plain read callback (see C<< ->push_read ($cb) >>). |
1231 |
|
1232 |
It should invoke the passed callback when it is done reading (remember to |
1233 |
pass C<$handle> as first argument as all other callbacks do that). |
1234 |
|
1235 |
Note that this is a function, and all types registered this way will be |
1236 |
global, so try to use unique names. |
1237 |
|
1238 |
For examples, see the source of this module (F<perldoc -m AnyEvent::Handle>, |
1239 |
search for C<register_read_type>)). |
1240 |
|
1241 |
=item $handle->stop_read |
1242 |
|
1243 |
=item $handle->start_read |
1244 |
|
1245 |
In rare cases you actually do not want to read anything from the |
1246 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1247 |
any queued callbacks will be executed then. To start reading again, call |
1248 |
C<start_read>. |
1249 |
|
1250 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1251 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1252 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1253 |
there are any read requests in the queue. |
1254 |
|
1255 |
=cut |
1256 |
|
1257 |
sub stop_read { |
1258 |
my ($self) = @_; |
1259 |
|
1260 |
delete $self->{_rw}; |
1261 |
} |
1262 |
|
1263 |
sub start_read { |
1264 |
my ($self) = @_; |
1265 |
|
1266 |
unless ($self->{_rw} || $self->{_eof}) { |
1267 |
Scalar::Util::weaken $self; |
1268 |
|
1269 |
$self->{_rw} = AnyEvent->io (fh => $self->{fh}, poll => "r", cb => sub { |
1270 |
my $rbuf = $self->{filter_r} ? \my $buf : \$self->{rbuf}; |
1271 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size} || 8192, length $$rbuf; |
1272 |
|
1273 |
if ($len > 0) { |
1274 |
$self->{_activity} = AnyEvent->now; |
1275 |
|
1276 |
$self->{filter_r} |
1277 |
? $self->{filter_r}($self, $rbuf) |
1278 |
: $self->{_in_drain} || $self->_drain_rbuf; |
1279 |
|
1280 |
} elsif (defined $len) { |
1281 |
delete $self->{_rw}; |
1282 |
$self->{_eof} = 1; |
1283 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1284 |
|
1285 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1286 |
return $self->_error ($!, 1); |
1287 |
} |
1288 |
}); |
1289 |
} |
1290 |
} |
1291 |
|
1292 |
sub _dotls { |
1293 |
my ($self) = @_; |
1294 |
|
1295 |
my $buf; |
1296 |
|
1297 |
if (length $self->{_tls_wbuf}) { |
1298 |
while ((my $len = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1299 |
substr $self->{_tls_wbuf}, 0, $len, ""; |
1300 |
} |
1301 |
} |
1302 |
|
1303 |
if (length ($buf = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1304 |
$self->{wbuf} .= $buf; |
1305 |
$self->_drain_wbuf; |
1306 |
} |
1307 |
|
1308 |
while (defined ($buf = Net::SSLeay::read ($self->{tls}))) { |
1309 |
if (length $buf) { |
1310 |
$self->{rbuf} .= $buf; |
1311 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1312 |
} else { |
1313 |
# let's treat SSL-eof as we treat normal EOF |
1314 |
$self->{_eof} = 1; |
1315 |
$self->_shutdown; |
1316 |
return; |
1317 |
} |
1318 |
} |
1319 |
|
1320 |
my $err = Net::SSLeay::get_error ($self->{tls}, -1); |
1321 |
|
1322 |
if ($err!= Net::SSLeay::ERROR_WANT_READ ()) { |
1323 |
if ($err == Net::SSLeay::ERROR_SYSCALL ()) { |
1324 |
return $self->_error ($!, 1); |
1325 |
} elsif ($err == Net::SSLeay::ERROR_SSL ()) { |
1326 |
return $self->_error (&Errno::EIO, 1); |
1327 |
} |
1328 |
|
1329 |
# all others are fine for our purposes |
1330 |
} |
1331 |
} |
1332 |
|
1333 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1334 |
|
1335 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1336 |
object is created, you can also do that at a later time by calling |
1337 |
C<starttls>. |
1338 |
|
1339 |
The first argument is the same as the C<tls> constructor argument (either |
1340 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1341 |
|
1342 |
The second argument is the optional C<Net::SSLeay::CTX> object that is |
1343 |
used when AnyEvent::Handle has to create its own TLS connection object. |
1344 |
|
1345 |
The TLS connection object will end up in C<< $handle->{tls} >> after this |
1346 |
call and can be used or changed to your liking. Note that the handshake |
1347 |
might have already started when this function returns. |
1348 |
|
1349 |
=cut |
1350 |
|
1351 |
sub starttls { |
1352 |
my ($self, $ssl, $ctx) = @_; |
1353 |
|
1354 |
$self->stoptls; |
1355 |
|
1356 |
if ($ssl eq "accept") { |
1357 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1358 |
Net::SSLeay::set_accept_state ($ssl); |
1359 |
} elsif ($ssl eq "connect") { |
1360 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1361 |
Net::SSLeay::set_connect_state ($ssl); |
1362 |
} |
1363 |
|
1364 |
$self->{tls} = $ssl; |
1365 |
|
1366 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1367 |
# but the openssl maintainers basically said: "trust us, it just works". |
1368 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1369 |
# and mismaintained ssleay-module doesn't even offer them). |
1370 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1371 |
Net::SSLeay::CTX_set_mode ($self->{tls}, |
1372 |
(eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1373 |
| (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1374 |
|
1375 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1376 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1377 |
|
1378 |
Net::SSLeay::set_bio ($ssl, $self->{_rbio}, $self->{_wbio}); |
1379 |
|
1380 |
$self->{filter_w} = sub { |
1381 |
$_[0]{_tls_wbuf} .= ${$_[1]}; |
1382 |
&_dotls; |
1383 |
}; |
1384 |
$self->{filter_r} = sub { |
1385 |
Net::SSLeay::BIO_write ($_[0]{_rbio}, ${$_[1]}); |
1386 |
&_dotls; |
1387 |
}; |
1388 |
} |
1389 |
|
1390 |
=item $handle->stoptls |
1391 |
|
1392 |
Destroys the SSL connection, if any. Partial read or write data will be |
1393 |
lost. |
1394 |
|
1395 |
=cut |
1396 |
|
1397 |
sub stoptls { |
1398 |
my ($self) = @_; |
1399 |
|
1400 |
Net::SSLeay::free (delete $self->{tls}) if $self->{tls}; |
1401 |
|
1402 |
delete $self->{_rbio}; |
1403 |
delete $self->{_wbio}; |
1404 |
delete $self->{_tls_wbuf}; |
1405 |
delete $self->{filter_r}; |
1406 |
delete $self->{filter_w}; |
1407 |
} |
1408 |
|
1409 |
sub DESTROY { |
1410 |
my $self = shift; |
1411 |
|
1412 |
$self->stoptls; |
1413 |
|
1414 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
1415 |
|
1416 |
if ($linger && length $self->{wbuf}) { |
1417 |
my $fh = delete $self->{fh}; |
1418 |
my $wbuf = delete $self->{wbuf}; |
1419 |
|
1420 |
my @linger; |
1421 |
|
1422 |
push @linger, AnyEvent->io (fh => $fh, poll => "w", cb => sub { |
1423 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
1424 |
|
1425 |
if ($len > 0) { |
1426 |
substr $wbuf, 0, $len, ""; |
1427 |
} else { |
1428 |
@linger = (); # end |
1429 |
} |
1430 |
}); |
1431 |
push @linger, AnyEvent->timer (after => $linger, cb => sub { |
1432 |
@linger = (); |
1433 |
}); |
1434 |
} |
1435 |
} |
1436 |
|
1437 |
=item AnyEvent::Handle::TLS_CTX |
1438 |
|
1439 |
This function creates and returns the Net::SSLeay::CTX object used by |
1440 |
default for TLS mode. |
1441 |
|
1442 |
The context is created like this: |
1443 |
|
1444 |
Net::SSLeay::load_error_strings; |
1445 |
Net::SSLeay::SSLeay_add_ssl_algorithms; |
1446 |
Net::SSLeay::randomize; |
1447 |
|
1448 |
my $CTX = Net::SSLeay::CTX_new; |
1449 |
|
1450 |
Net::SSLeay::CTX_set_options $CTX, Net::SSLeay::OP_ALL |
1451 |
|
1452 |
=cut |
1453 |
|
1454 |
our $TLS_CTX; |
1455 |
|
1456 |
sub TLS_CTX() { |
1457 |
$TLS_CTX || do { |
1458 |
require Net::SSLeay; |
1459 |
|
1460 |
Net::SSLeay::load_error_strings (); |
1461 |
Net::SSLeay::SSLeay_add_ssl_algorithms (); |
1462 |
Net::SSLeay::randomize (); |
1463 |
|
1464 |
$TLS_CTX = Net::SSLeay::CTX_new (); |
1465 |
|
1466 |
Net::SSLeay::CTX_set_options ($TLS_CTX, Net::SSLeay::OP_ALL ()); |
1467 |
|
1468 |
$TLS_CTX |
1469 |
} |
1470 |
} |
1471 |
|
1472 |
=back |
1473 |
|
1474 |
=head1 SUBCLASSING AnyEvent::Handle |
1475 |
|
1476 |
In many cases, you might want to subclass AnyEvent::Handle. |
1477 |
|
1478 |
To make this easier, a given version of AnyEvent::Handle uses these |
1479 |
conventions: |
1480 |
|
1481 |
=over 4 |
1482 |
|
1483 |
=item * all constructor arguments become object members. |
1484 |
|
1485 |
At least initially, when you pass a C<tls>-argument to the constructor it |
1486 |
will end up in C<< $handle->{tls} >>. Those members might be changed or |
1487 |
mutated later on (for example C<tls> will hold the TLS connection object). |
1488 |
|
1489 |
=item * other object member names are prefixed with an C<_>. |
1490 |
|
1491 |
All object members not explicitly documented (internal use) are prefixed |
1492 |
with an underscore character, so the remaining non-C<_>-namespace is free |
1493 |
for use for subclasses. |
1494 |
|
1495 |
=item * all members not documented here and not prefixed with an underscore |
1496 |
are free to use in subclasses. |
1497 |
|
1498 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
1499 |
member variables, but thats just life, at least it is documented. |
1500 |
|
1501 |
=back |
1502 |
|
1503 |
=head1 AUTHOR |
1504 |
|
1505 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
1506 |
|
1507 |
=cut |
1508 |
|
1509 |
1; # End of AnyEvent::Handle |