1 |
package AnyEvent::Handle; |
2 |
|
3 |
no warnings; |
4 |
use strict; |
5 |
|
6 |
use AnyEvent (); |
7 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
8 |
use Scalar::Util (); |
9 |
use Carp (); |
10 |
use Fcntl (); |
11 |
use Errno qw(EAGAIN EINTR); |
12 |
|
13 |
=head1 NAME |
14 |
|
15 |
AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent |
16 |
|
17 |
=cut |
18 |
|
19 |
our $VERSION = 4.15; |
20 |
|
21 |
=head1 SYNOPSIS |
22 |
|
23 |
use AnyEvent; |
24 |
use AnyEvent::Handle; |
25 |
|
26 |
my $cv = AnyEvent->condvar; |
27 |
|
28 |
my $handle = |
29 |
AnyEvent::Handle->new ( |
30 |
fh => \*STDIN, |
31 |
on_eof => sub { |
32 |
$cv->broadcast; |
33 |
}, |
34 |
); |
35 |
|
36 |
# send some request line |
37 |
$handle->push_write ("getinfo\015\012"); |
38 |
|
39 |
# read the response line |
40 |
$handle->push_read (line => sub { |
41 |
my ($handle, $line) = @_; |
42 |
warn "read line <$line>\n"; |
43 |
$cv->send; |
44 |
}); |
45 |
|
46 |
$cv->recv; |
47 |
|
48 |
=head1 DESCRIPTION |
49 |
|
50 |
This module is a helper module to make it easier to do event-based I/O on |
51 |
filehandles. For utility functions for doing non-blocking connects and accepts |
52 |
on sockets see L<AnyEvent::Util>. |
53 |
|
54 |
In the following, when the documentation refers to of "bytes" then this |
55 |
means characters. As sysread and syswrite are used for all I/O, their |
56 |
treatment of characters applies to this module as well. |
57 |
|
58 |
All callbacks will be invoked with the handle object as their first |
59 |
argument. |
60 |
|
61 |
=head1 METHODS |
62 |
|
63 |
=over 4 |
64 |
|
65 |
=item B<new (%args)> |
66 |
|
67 |
The constructor supports these arguments (all as key => value pairs). |
68 |
|
69 |
=over 4 |
70 |
|
71 |
=item fh => $filehandle [MANDATORY] |
72 |
|
73 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
74 |
|
75 |
NOTE: The filehandle will be set to non-blocking (using |
76 |
AnyEvent::Util::fh_nonblocking). |
77 |
|
78 |
=item on_eof => $cb->($handle) |
79 |
|
80 |
Set the callback to be called when an end-of-file condition is detcted, |
81 |
i.e. in the case of a socket, when the other side has closed the |
82 |
connection cleanly. |
83 |
|
84 |
While not mandatory, it is highly recommended to set an eof callback, |
85 |
otherwise you might end up with a closed socket while you are still |
86 |
waiting for data. |
87 |
|
88 |
=item on_error => $cb->($handle, $fatal) |
89 |
|
90 |
This is the error callback, which is called when, well, some error |
91 |
occured, such as not being able to resolve the hostname, failure to |
92 |
connect or a read error. |
93 |
|
94 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
95 |
fatal errors the handle object will be shut down and will not be |
96 |
usable. Non-fatal errors can be retried by simply returning, but it is |
97 |
recommended to simply ignore this parameter and instead abondon the handle |
98 |
object when this callback is invoked. |
99 |
|
100 |
On callback entrance, the value of C<$!> contains the operating system |
101 |
error (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT> or C<EBADMSG>). |
102 |
|
103 |
While not mandatory, it is I<highly> recommended to set this callback, as |
104 |
you will not be notified of errors otherwise. The default simply calls |
105 |
C<croak>. |
106 |
|
107 |
=item on_read => $cb->($handle) |
108 |
|
109 |
This sets the default read callback, which is called when data arrives |
110 |
and no read request is in the queue (unlike read queue callbacks, this |
111 |
callback will only be called when at least one octet of data is in the |
112 |
read buffer). |
113 |
|
114 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
115 |
method or access the C<$handle->{rbuf}> member directly. |
116 |
|
117 |
When an EOF condition is detected then AnyEvent::Handle will first try to |
118 |
feed all the remaining data to the queued callbacks and C<on_read> before |
119 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
120 |
error will be raised (with C<$!> set to C<EPIPE>). |
121 |
|
122 |
=item on_drain => $cb->($handle) |
123 |
|
124 |
This sets the callback that is called when the write buffer becomes empty |
125 |
(or when the callback is set and the buffer is empty already). |
126 |
|
127 |
To append to the write buffer, use the C<< ->push_write >> method. |
128 |
|
129 |
=item timeout => $fractional_seconds |
130 |
|
131 |
If non-zero, then this enables an "inactivity" timeout: whenever this many |
132 |
seconds pass without a successful read or write on the underlying file |
133 |
handle, the C<on_timeout> callback will be invoked (and if that one is |
134 |
missing, an C<ETIMEDOUT> error will be raised). |
135 |
|
136 |
Note that timeout processing is also active when you currently do not have |
137 |
any outstanding read or write requests: If you plan to keep the connection |
138 |
idle then you should disable the timout temporarily or ignore the timeout |
139 |
in the C<on_timeout> callback. |
140 |
|
141 |
Zero (the default) disables this timeout. |
142 |
|
143 |
=item on_timeout => $cb->($handle) |
144 |
|
145 |
Called whenever the inactivity timeout passes. If you return from this |
146 |
callback, then the timeout will be reset as if some activity had happened, |
147 |
so this condition is not fatal in any way. |
148 |
|
149 |
=item rbuf_max => <bytes> |
150 |
|
151 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
152 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
153 |
avoid denial-of-service attacks. |
154 |
|
155 |
For example, a server accepting connections from untrusted sources should |
156 |
be configured to accept only so-and-so much data that it cannot act on |
157 |
(for example, when expecting a line, an attacker could send an unlimited |
158 |
amount of data without a callback ever being called as long as the line |
159 |
isn't finished). |
160 |
|
161 |
=item read_size => <bytes> |
162 |
|
163 |
The default read block size (the amount of bytes this module will try to read |
164 |
during each (loop iteration). Default: C<8192>. |
165 |
|
166 |
=item low_water_mark => <bytes> |
167 |
|
168 |
Sets the amount of bytes (default: C<0>) that make up an "empty" write |
169 |
buffer: If the write reaches this size or gets even samller it is |
170 |
considered empty. |
171 |
|
172 |
=item linger => <seconds> |
173 |
|
174 |
If non-zero (default: C<3600>), then the destructor of the |
175 |
AnyEvent::Handle object will check wether there is still outstanding write |
176 |
data and will install a watcher that will write out this data. No errors |
177 |
will be reported (this mostly matches how the operating system treats |
178 |
outstanding data at socket close time). |
179 |
|
180 |
This will not work for partial TLS data that could not yet been |
181 |
encoded. This data will be lost. |
182 |
|
183 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
184 |
|
185 |
When this parameter is given, it enables TLS (SSL) mode, that means it |
186 |
will start making tls handshake and will transparently encrypt/decrypt |
187 |
data. |
188 |
|
189 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
190 |
automatically when you try to create a TLS handle). |
191 |
|
192 |
For the TLS server side, use C<accept>, and for the TLS client side of a |
193 |
connection, use C<connect> mode. |
194 |
|
195 |
You can also provide your own TLS connection object, but you have |
196 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
197 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
198 |
AnyEvent::Handle. |
199 |
|
200 |
See the C<starttls> method if you need to start TLs negotiation later. |
201 |
|
202 |
=item tls_ctx => $ssl_ctx |
203 |
|
204 |
Use the given Net::SSLeay::CTX object to create the new TLS connection |
205 |
(unless a connection object was specified directly). If this parameter is |
206 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
207 |
|
208 |
=item json => JSON or JSON::XS object |
209 |
|
210 |
This is the json coder object used by the C<json> read and write types. |
211 |
|
212 |
If you don't supply it, then AnyEvent::Handle will create and use a |
213 |
suitable one, which will write and expect UTF-8 encoded JSON texts. |
214 |
|
215 |
Note that you are responsible to depend on the JSON module if you want to |
216 |
use this functionality, as AnyEvent does not have a dependency itself. |
217 |
|
218 |
=item filter_r => $cb |
219 |
|
220 |
=item filter_w => $cb |
221 |
|
222 |
These exist, but are undocumented at this time. |
223 |
|
224 |
=back |
225 |
|
226 |
=cut |
227 |
|
228 |
sub new { |
229 |
my $class = shift; |
230 |
|
231 |
my $self = bless { @_ }, $class; |
232 |
|
233 |
$self->{fh} or Carp::croak "mandatory argument fh is missing"; |
234 |
|
235 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
236 |
|
237 |
if ($self->{tls}) { |
238 |
require Net::SSLeay; |
239 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}); |
240 |
} |
241 |
|
242 |
$self->{_activity} = AnyEvent->now; |
243 |
$self->_timeout; |
244 |
|
245 |
$self->on_drain (delete $self->{on_drain}) if $self->{on_drain}; |
246 |
|
247 |
$self |
248 |
} |
249 |
|
250 |
sub _shutdown { |
251 |
my ($self) = @_; |
252 |
|
253 |
delete $self->{_tw}; |
254 |
delete $self->{_rw}; |
255 |
delete $self->{_ww}; |
256 |
delete $self->{fh}; |
257 |
|
258 |
$self->stoptls; |
259 |
} |
260 |
|
261 |
sub _error { |
262 |
my ($self, $errno, $fatal) = @_; |
263 |
|
264 |
$self->_shutdown |
265 |
if $fatal; |
266 |
|
267 |
$! = $errno; |
268 |
|
269 |
if ($self->{on_error}) { |
270 |
$self->{on_error}($self, $fatal); |
271 |
} else { |
272 |
Carp::croak "AnyEvent::Handle uncaught error: $!"; |
273 |
} |
274 |
} |
275 |
|
276 |
=item $fh = $handle->fh |
277 |
|
278 |
This method returns the file handle of the L<AnyEvent::Handle> object. |
279 |
|
280 |
=cut |
281 |
|
282 |
sub fh { $_[0]{fh} } |
283 |
|
284 |
=item $handle->on_error ($cb) |
285 |
|
286 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
287 |
|
288 |
=cut |
289 |
|
290 |
sub on_error { |
291 |
$_[0]{on_error} = $_[1]; |
292 |
} |
293 |
|
294 |
=item $handle->on_eof ($cb) |
295 |
|
296 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
297 |
|
298 |
=cut |
299 |
|
300 |
sub on_eof { |
301 |
$_[0]{on_eof} = $_[1]; |
302 |
} |
303 |
|
304 |
=item $handle->on_timeout ($cb) |
305 |
|
306 |
Replace the current C<on_timeout> callback, or disables the callback |
307 |
(but not the timeout) if C<$cb> = C<undef>. See C<timeout> constructor |
308 |
argument. |
309 |
|
310 |
=cut |
311 |
|
312 |
sub on_timeout { |
313 |
$_[0]{on_timeout} = $_[1]; |
314 |
} |
315 |
|
316 |
############################################################################# |
317 |
|
318 |
=item $handle->timeout ($seconds) |
319 |
|
320 |
Configures (or disables) the inactivity timeout. |
321 |
|
322 |
=cut |
323 |
|
324 |
sub timeout { |
325 |
my ($self, $timeout) = @_; |
326 |
|
327 |
$self->{timeout} = $timeout; |
328 |
$self->_timeout; |
329 |
} |
330 |
|
331 |
# reset the timeout watcher, as neccessary |
332 |
# also check for time-outs |
333 |
sub _timeout { |
334 |
my ($self) = @_; |
335 |
|
336 |
if ($self->{timeout}) { |
337 |
my $NOW = AnyEvent->now; |
338 |
|
339 |
# when would the timeout trigger? |
340 |
my $after = $self->{_activity} + $self->{timeout} - $NOW; |
341 |
|
342 |
# now or in the past already? |
343 |
if ($after <= 0) { |
344 |
$self->{_activity} = $NOW; |
345 |
|
346 |
if ($self->{on_timeout}) { |
347 |
$self->{on_timeout}($self); |
348 |
} else { |
349 |
$self->_error (&Errno::ETIMEDOUT); |
350 |
} |
351 |
|
352 |
# callback could have changed timeout value, optimise |
353 |
return unless $self->{timeout}; |
354 |
|
355 |
# calculate new after |
356 |
$after = $self->{timeout}; |
357 |
} |
358 |
|
359 |
Scalar::Util::weaken $self; |
360 |
return unless $self; # ->error could have destroyed $self |
361 |
|
362 |
$self->{_tw} ||= AnyEvent->timer (after => $after, cb => sub { |
363 |
delete $self->{_tw}; |
364 |
$self->_timeout; |
365 |
}); |
366 |
} else { |
367 |
delete $self->{_tw}; |
368 |
} |
369 |
} |
370 |
|
371 |
############################################################################# |
372 |
|
373 |
=back |
374 |
|
375 |
=head2 WRITE QUEUE |
376 |
|
377 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
378 |
for reading. |
379 |
|
380 |
The write queue is very simple: you can add data to its end, and |
381 |
AnyEvent::Handle will automatically try to get rid of it for you. |
382 |
|
383 |
When data could be written and the write buffer is shorter then the low |
384 |
water mark, the C<on_drain> callback will be invoked. |
385 |
|
386 |
=over 4 |
387 |
|
388 |
=item $handle->on_drain ($cb) |
389 |
|
390 |
Sets the C<on_drain> callback or clears it (see the description of |
391 |
C<on_drain> in the constructor). |
392 |
|
393 |
=cut |
394 |
|
395 |
sub on_drain { |
396 |
my ($self, $cb) = @_; |
397 |
|
398 |
$self->{on_drain} = $cb; |
399 |
|
400 |
$cb->($self) |
401 |
if $cb && $self->{low_water_mark} >= length $self->{wbuf}; |
402 |
} |
403 |
|
404 |
=item $handle->push_write ($data) |
405 |
|
406 |
Queues the given scalar to be written. You can push as much data as you |
407 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
408 |
buffers it independently of the kernel. |
409 |
|
410 |
=cut |
411 |
|
412 |
sub _drain_wbuf { |
413 |
my ($self) = @_; |
414 |
|
415 |
if (!$self->{_ww} && length $self->{wbuf}) { |
416 |
|
417 |
Scalar::Util::weaken $self; |
418 |
|
419 |
my $cb = sub { |
420 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
421 |
|
422 |
if ($len >= 0) { |
423 |
substr $self->{wbuf}, 0, $len, ""; |
424 |
|
425 |
$self->{_activity} = AnyEvent->now; |
426 |
|
427 |
$self->{on_drain}($self) |
428 |
if $self->{low_water_mark} >= length $self->{wbuf} |
429 |
&& $self->{on_drain}; |
430 |
|
431 |
delete $self->{_ww} unless length $self->{wbuf}; |
432 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
433 |
$self->_error ($!, 1); |
434 |
} |
435 |
}; |
436 |
|
437 |
# try to write data immediately |
438 |
$cb->(); |
439 |
|
440 |
# if still data left in wbuf, we need to poll |
441 |
$self->{_ww} = AnyEvent->io (fh => $self->{fh}, poll => "w", cb => $cb) |
442 |
if length $self->{wbuf}; |
443 |
}; |
444 |
} |
445 |
|
446 |
our %WH; |
447 |
|
448 |
sub register_write_type($$) { |
449 |
$WH{$_[0]} = $_[1]; |
450 |
} |
451 |
|
452 |
sub push_write { |
453 |
my $self = shift; |
454 |
|
455 |
if (@_ > 1) { |
456 |
my $type = shift; |
457 |
|
458 |
@_ = ($WH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_write") |
459 |
->($self, @_); |
460 |
} |
461 |
|
462 |
if ($self->{filter_w}) { |
463 |
$self->{filter_w}($self, \$_[0]); |
464 |
} else { |
465 |
$self->{wbuf} .= $_[0]; |
466 |
$self->_drain_wbuf; |
467 |
} |
468 |
} |
469 |
|
470 |
=item $handle->push_write (type => @args) |
471 |
|
472 |
Instead of formatting your data yourself, you can also let this module do |
473 |
the job by specifying a type and type-specific arguments. |
474 |
|
475 |
Predefined types are (if you have ideas for additional types, feel free to |
476 |
drop by and tell us): |
477 |
|
478 |
=over 4 |
479 |
|
480 |
=item netstring => $string |
481 |
|
482 |
Formats the given value as netstring |
483 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
484 |
|
485 |
=cut |
486 |
|
487 |
register_write_type netstring => sub { |
488 |
my ($self, $string) = @_; |
489 |
|
490 |
sprintf "%d:%s,", (length $string), $string |
491 |
}; |
492 |
|
493 |
=item packstring => $format, $data |
494 |
|
495 |
An octet string prefixed with an encoded length. The encoding C<$format> |
496 |
uses the same format as a Perl C<pack> format, but must specify a single |
497 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
498 |
optional C<!>, C<< < >> or C<< > >> modifier). |
499 |
|
500 |
=cut |
501 |
|
502 |
register_write_type packstring => sub { |
503 |
my ($self, $format, $string) = @_; |
504 |
|
505 |
pack "$format/a*", $string |
506 |
}; |
507 |
|
508 |
=item json => $array_or_hashref |
509 |
|
510 |
Encodes the given hash or array reference into a JSON object. Unless you |
511 |
provide your own JSON object, this means it will be encoded to JSON text |
512 |
in UTF-8. |
513 |
|
514 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
515 |
one end of a handle and read them at the other end without using any |
516 |
additional framing. |
517 |
|
518 |
The generated JSON text is guaranteed not to contain any newlines: While |
519 |
this module doesn't need delimiters after or between JSON texts to be |
520 |
able to read them, many other languages depend on that. |
521 |
|
522 |
A simple RPC protocol that interoperates easily with others is to send |
523 |
JSON arrays (or objects, although arrays are usually the better choice as |
524 |
they mimic how function argument passing works) and a newline after each |
525 |
JSON text: |
526 |
|
527 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
528 |
$handle->push_write ("\012"); |
529 |
|
530 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
531 |
rely on the fact that the newline will be skipped as leading whitespace: |
532 |
|
533 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
534 |
|
535 |
Other languages could read single lines terminated by a newline and pass |
536 |
this line into their JSON decoder of choice. |
537 |
|
538 |
=cut |
539 |
|
540 |
register_write_type json => sub { |
541 |
my ($self, $ref) = @_; |
542 |
|
543 |
require JSON; |
544 |
|
545 |
$self->{json} ? $self->{json}->encode ($ref) |
546 |
: JSON::encode_json ($ref) |
547 |
}; |
548 |
|
549 |
=item storable => $reference |
550 |
|
551 |
Freezes the given reference using L<Storable> and writes it to the |
552 |
handle. Uses the C<nfreeze> format. |
553 |
|
554 |
=cut |
555 |
|
556 |
register_write_type storable => sub { |
557 |
my ($self, $ref) = @_; |
558 |
|
559 |
require Storable; |
560 |
|
561 |
pack "w/a*", Storable::nfreeze ($ref) |
562 |
}; |
563 |
|
564 |
=back |
565 |
|
566 |
=item AnyEvent::Handle::register_write_type type => $coderef->($handle, @args) |
567 |
|
568 |
This function (not method) lets you add your own types to C<push_write>. |
569 |
Whenever the given C<type> is used, C<push_write> will invoke the code |
570 |
reference with the handle object and the remaining arguments. |
571 |
|
572 |
The code reference is supposed to return a single octet string that will |
573 |
be appended to the write buffer. |
574 |
|
575 |
Note that this is a function, and all types registered this way will be |
576 |
global, so try to use unique names. |
577 |
|
578 |
=cut |
579 |
|
580 |
############################################################################# |
581 |
|
582 |
=back |
583 |
|
584 |
=head2 READ QUEUE |
585 |
|
586 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
587 |
for reading. |
588 |
|
589 |
The read queue is more complex than the write queue. It can be used in two |
590 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
591 |
a queue. |
592 |
|
593 |
In the simple case, you just install an C<on_read> callback and whenever |
594 |
new data arrives, it will be called. You can then remove some data (if |
595 |
enough is there) from the read buffer (C<< $handle->rbuf >>) if you want |
596 |
or not. |
597 |
|
598 |
In the more complex case, you want to queue multiple callbacks. In this |
599 |
case, AnyEvent::Handle will call the first queued callback each time new |
600 |
data arrives (also the first time it is queued) and removes it when it has |
601 |
done its job (see C<push_read>, below). |
602 |
|
603 |
This way you can, for example, push three line-reads, followed by reading |
604 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
605 |
|
606 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
607 |
the specified number of bytes which give an XML datagram. |
608 |
|
609 |
# in the default state, expect some header bytes |
610 |
$handle->on_read (sub { |
611 |
# some data is here, now queue the length-header-read (4 octets) |
612 |
shift->unshift_read (chunk => 4, sub { |
613 |
# header arrived, decode |
614 |
my $len = unpack "N", $_[1]; |
615 |
|
616 |
# now read the payload |
617 |
shift->unshift_read (chunk => $len, sub { |
618 |
my $xml = $_[1]; |
619 |
# handle xml |
620 |
}); |
621 |
}); |
622 |
}); |
623 |
|
624 |
Example 2: Implement a client for a protocol that replies either with |
625 |
"OK" and another line or "ERROR" for one request, and 64 bytes for the |
626 |
second request. Due tot he availability of a full queue, we can just |
627 |
pipeline sending both requests and manipulate the queue as necessary in |
628 |
the callbacks: |
629 |
|
630 |
# request one |
631 |
$handle->push_write ("request 1\015\012"); |
632 |
|
633 |
# we expect "ERROR" or "OK" as response, so push a line read |
634 |
$handle->push_read (line => sub { |
635 |
# if we got an "OK", we have to _prepend_ another line, |
636 |
# so it will be read before the second request reads its 64 bytes |
637 |
# which are already in the queue when this callback is called |
638 |
# we don't do this in case we got an error |
639 |
if ($_[1] eq "OK") { |
640 |
$_[0]->unshift_read (line => sub { |
641 |
my $response = $_[1]; |
642 |
... |
643 |
}); |
644 |
} |
645 |
}); |
646 |
|
647 |
# request two |
648 |
$handle->push_write ("request 2\015\012"); |
649 |
|
650 |
# simply read 64 bytes, always |
651 |
$handle->push_read (chunk => 64, sub { |
652 |
my $response = $_[1]; |
653 |
... |
654 |
}); |
655 |
|
656 |
=over 4 |
657 |
|
658 |
=cut |
659 |
|
660 |
sub _drain_rbuf { |
661 |
my ($self) = @_; |
662 |
|
663 |
local $self->{_in_drain} = 1; |
664 |
|
665 |
if ( |
666 |
defined $self->{rbuf_max} |
667 |
&& $self->{rbuf_max} < length $self->{rbuf} |
668 |
) { |
669 |
return $self->_error (&Errno::ENOSPC, 1); |
670 |
} |
671 |
|
672 |
while () { |
673 |
no strict 'refs'; |
674 |
|
675 |
my $len = length $self->{rbuf}; |
676 |
|
677 |
if (my $cb = shift @{ $self->{_queue} }) { |
678 |
unless ($cb->($self)) { |
679 |
if ($self->{_eof}) { |
680 |
# no progress can be made (not enough data and no data forthcoming) |
681 |
$self->_error (&Errno::EPIPE, 1), last; |
682 |
} |
683 |
|
684 |
unshift @{ $self->{_queue} }, $cb; |
685 |
last; |
686 |
} |
687 |
} elsif ($self->{on_read}) { |
688 |
last unless $len; |
689 |
|
690 |
$self->{on_read}($self); |
691 |
|
692 |
if ( |
693 |
$len == length $self->{rbuf} # if no data has been consumed |
694 |
&& !@{ $self->{_queue} } # and the queue is still empty |
695 |
&& $self->{on_read} # but we still have on_read |
696 |
) { |
697 |
# no further data will arrive |
698 |
# so no progress can be made |
699 |
$self->_error (&Errno::EPIPE, 1), last |
700 |
if $self->{_eof}; |
701 |
|
702 |
last; # more data might arrive |
703 |
} |
704 |
} else { |
705 |
# read side becomes idle |
706 |
delete $self->{_rw}; |
707 |
last; |
708 |
} |
709 |
} |
710 |
|
711 |
$self->{on_eof}($self) |
712 |
if $self->{_eof} && $self->{on_eof}; |
713 |
|
714 |
# may need to restart read watcher |
715 |
unless ($self->{_rw}) { |
716 |
$self->start_read |
717 |
if $self->{on_read} || @{ $self->{_queue} }; |
718 |
} |
719 |
} |
720 |
|
721 |
=item $handle->on_read ($cb) |
722 |
|
723 |
This replaces the currently set C<on_read> callback, or clears it (when |
724 |
the new callback is C<undef>). See the description of C<on_read> in the |
725 |
constructor. |
726 |
|
727 |
=cut |
728 |
|
729 |
sub on_read { |
730 |
my ($self, $cb) = @_; |
731 |
|
732 |
$self->{on_read} = $cb; |
733 |
$self->_drain_rbuf if $cb && !$self->{_in_drain}; |
734 |
} |
735 |
|
736 |
=item $handle->rbuf |
737 |
|
738 |
Returns the read buffer (as a modifiable lvalue). |
739 |
|
740 |
You can access the read buffer directly as the C<< ->{rbuf} >> member, if |
741 |
you want. |
742 |
|
743 |
NOTE: The read buffer should only be used or modified if the C<on_read>, |
744 |
C<push_read> or C<unshift_read> methods are used. The other read methods |
745 |
automatically manage the read buffer. |
746 |
|
747 |
=cut |
748 |
|
749 |
sub rbuf : lvalue { |
750 |
$_[0]{rbuf} |
751 |
} |
752 |
|
753 |
=item $handle->push_read ($cb) |
754 |
|
755 |
=item $handle->unshift_read ($cb) |
756 |
|
757 |
Append the given callback to the end of the queue (C<push_read>) or |
758 |
prepend it (C<unshift_read>). |
759 |
|
760 |
The callback is called each time some additional read data arrives. |
761 |
|
762 |
It must check whether enough data is in the read buffer already. |
763 |
|
764 |
If not enough data is available, it must return the empty list or a false |
765 |
value, in which case it will be called repeatedly until enough data is |
766 |
available (or an error condition is detected). |
767 |
|
768 |
If enough data was available, then the callback must remove all data it is |
769 |
interested in (which can be none at all) and return a true value. After returning |
770 |
true, it will be removed from the queue. |
771 |
|
772 |
=cut |
773 |
|
774 |
our %RH; |
775 |
|
776 |
sub register_read_type($$) { |
777 |
$RH{$_[0]} = $_[1]; |
778 |
} |
779 |
|
780 |
sub push_read { |
781 |
my $self = shift; |
782 |
my $cb = pop; |
783 |
|
784 |
if (@_) { |
785 |
my $type = shift; |
786 |
|
787 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_read") |
788 |
->($self, $cb, @_); |
789 |
} |
790 |
|
791 |
push @{ $self->{_queue} }, $cb; |
792 |
$self->_drain_rbuf unless $self->{_in_drain}; |
793 |
} |
794 |
|
795 |
sub unshift_read { |
796 |
my $self = shift; |
797 |
my $cb = pop; |
798 |
|
799 |
if (@_) { |
800 |
my $type = shift; |
801 |
|
802 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::unshift_read") |
803 |
->($self, $cb, @_); |
804 |
} |
805 |
|
806 |
|
807 |
unshift @{ $self->{_queue} }, $cb; |
808 |
$self->_drain_rbuf unless $self->{_in_drain}; |
809 |
} |
810 |
|
811 |
=item $handle->push_read (type => @args, $cb) |
812 |
|
813 |
=item $handle->unshift_read (type => @args, $cb) |
814 |
|
815 |
Instead of providing a callback that parses the data itself you can chose |
816 |
between a number of predefined parsing formats, for chunks of data, lines |
817 |
etc. |
818 |
|
819 |
Predefined types are (if you have ideas for additional types, feel free to |
820 |
drop by and tell us): |
821 |
|
822 |
=over 4 |
823 |
|
824 |
=item chunk => $octets, $cb->($handle, $data) |
825 |
|
826 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
827 |
data read to the callback. The callback will never be called with less |
828 |
data. |
829 |
|
830 |
Example: read 2 bytes. |
831 |
|
832 |
$handle->push_read (chunk => 2, sub { |
833 |
warn "yay ", unpack "H*", $_[1]; |
834 |
}); |
835 |
|
836 |
=cut |
837 |
|
838 |
register_read_type chunk => sub { |
839 |
my ($self, $cb, $len) = @_; |
840 |
|
841 |
sub { |
842 |
$len <= length $_[0]{rbuf} or return; |
843 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
844 |
1 |
845 |
} |
846 |
}; |
847 |
|
848 |
# compatibility with older API |
849 |
sub push_read_chunk { |
850 |
$_[0]->push_read (chunk => $_[1], $_[2]); |
851 |
} |
852 |
|
853 |
sub unshift_read_chunk { |
854 |
$_[0]->unshift_read (chunk => $_[1], $_[2]); |
855 |
} |
856 |
|
857 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
858 |
|
859 |
The callback will be called only once a full line (including the end of |
860 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
861 |
marker) will be passed to the callback as second argument (C<$line>), and |
862 |
the end of line marker as the third argument (C<$eol>). |
863 |
|
864 |
The end of line marker, C<$eol>, can be either a string, in which case it |
865 |
will be interpreted as a fixed record end marker, or it can be a regex |
866 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
867 |
regular expression. |
868 |
|
869 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
870 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
871 |
protocols). |
872 |
|
873 |
Partial lines at the end of the stream will never be returned, as they are |
874 |
not marked by the end of line marker. |
875 |
|
876 |
=cut |
877 |
|
878 |
register_read_type line => sub { |
879 |
my ($self, $cb, $eol) = @_; |
880 |
|
881 |
$eol = qr|(\015?\012)| if @_ < 3; |
882 |
$eol = quotemeta $eol unless ref $eol; |
883 |
$eol = qr|^(.*?)($eol)|s; |
884 |
|
885 |
sub { |
886 |
$_[0]{rbuf} =~ s/$eol// or return; |
887 |
|
888 |
$cb->($_[0], $1, $2); |
889 |
1 |
890 |
} |
891 |
}; |
892 |
|
893 |
# compatibility with older API |
894 |
sub push_read_line { |
895 |
my $self = shift; |
896 |
$self->push_read (line => @_); |
897 |
} |
898 |
|
899 |
sub unshift_read_line { |
900 |
my $self = shift; |
901 |
$self->unshift_read (line => @_); |
902 |
} |
903 |
|
904 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
905 |
|
906 |
Makes a regex match against the regex object C<$accept> and returns |
907 |
everything up to and including the match. |
908 |
|
909 |
Example: read a single line terminated by '\n'. |
910 |
|
911 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
912 |
|
913 |
If C<$reject> is given and not undef, then it determines when the data is |
914 |
to be rejected: it is matched against the data when the C<$accept> regex |
915 |
does not match and generates an C<EBADMSG> error when it matches. This is |
916 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
917 |
receive buffer overflow). |
918 |
|
919 |
Example: expect a single decimal number followed by whitespace, reject |
920 |
anything else (not the use of an anchor). |
921 |
|
922 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
923 |
|
924 |
If C<$skip> is given and not C<undef>, then it will be matched against |
925 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
926 |
and everything preceding and including the match will be accepted |
927 |
unconditionally. This is useful to skip large amounts of data that you |
928 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
929 |
have to start matching from the beginning. This is purely an optimisation |
930 |
and is usually worth only when you expect more than a few kilobytes. |
931 |
|
932 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
933 |
expect the header to be very large (it isn't in practise, but...), we use |
934 |
a skip regex to skip initial portions. The skip regex is tricky in that |
935 |
it only accepts something not ending in either \015 or \012, as these are |
936 |
required for the accept regex. |
937 |
|
938 |
$handle->push_read (regex => |
939 |
qr<\015\012\015\012>, |
940 |
undef, # no reject |
941 |
qr<^.*[^\015\012]>, |
942 |
sub { ... }); |
943 |
|
944 |
=cut |
945 |
|
946 |
register_read_type regex => sub { |
947 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
948 |
|
949 |
my $data; |
950 |
my $rbuf = \$self->{rbuf}; |
951 |
|
952 |
sub { |
953 |
# accept |
954 |
if ($$rbuf =~ $accept) { |
955 |
$data .= substr $$rbuf, 0, $+[0], ""; |
956 |
$cb->($self, $data); |
957 |
return 1; |
958 |
} |
959 |
|
960 |
# reject |
961 |
if ($reject && $$rbuf =~ $reject) { |
962 |
$self->_error (&Errno::EBADMSG); |
963 |
} |
964 |
|
965 |
# skip |
966 |
if ($skip && $$rbuf =~ $skip) { |
967 |
$data .= substr $$rbuf, 0, $+[0], ""; |
968 |
} |
969 |
|
970 |
() |
971 |
} |
972 |
}; |
973 |
|
974 |
=item netstring => $cb->($handle, $string) |
975 |
|
976 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
977 |
|
978 |
Throws an error with C<$!> set to EBADMSG on format violations. |
979 |
|
980 |
=cut |
981 |
|
982 |
register_read_type netstring => sub { |
983 |
my ($self, $cb) = @_; |
984 |
|
985 |
sub { |
986 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
987 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
988 |
$self->_error (&Errno::EBADMSG); |
989 |
} |
990 |
return; |
991 |
} |
992 |
|
993 |
my $len = $1; |
994 |
|
995 |
$self->unshift_read (chunk => $len, sub { |
996 |
my $string = $_[1]; |
997 |
$_[0]->unshift_read (chunk => 1, sub { |
998 |
if ($_[1] eq ",") { |
999 |
$cb->($_[0], $string); |
1000 |
} else { |
1001 |
$self->_error (&Errno::EBADMSG); |
1002 |
} |
1003 |
}); |
1004 |
}); |
1005 |
|
1006 |
1 |
1007 |
} |
1008 |
}; |
1009 |
|
1010 |
=item packstring => $format, $cb->($handle, $string) |
1011 |
|
1012 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1013 |
uses the same format as a Perl C<pack> format, but must specify a single |
1014 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1015 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1016 |
|
1017 |
DNS over TCP uses a prefix of C<n>, EPP uses a prefix of C<N>. |
1018 |
|
1019 |
Example: read a block of data prefixed by its length in BER-encoded |
1020 |
format (very efficient). |
1021 |
|
1022 |
$handle->push_read (packstring => "w", sub { |
1023 |
my ($handle, $data) = @_; |
1024 |
}); |
1025 |
|
1026 |
=cut |
1027 |
|
1028 |
register_read_type packstring => sub { |
1029 |
my ($self, $cb, $format) = @_; |
1030 |
|
1031 |
sub { |
1032 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1033 |
defined (my $len = eval { unpack $format, $_[0]->{rbuf} }) |
1034 |
or return; |
1035 |
|
1036 |
# remove prefix |
1037 |
substr $_[0]->{rbuf}, 0, (length pack $format, $len), ""; |
1038 |
|
1039 |
# read rest |
1040 |
$_[0]->unshift_read (chunk => $len, $cb); |
1041 |
|
1042 |
1 |
1043 |
} |
1044 |
}; |
1045 |
|
1046 |
=item json => $cb->($handle, $hash_or_arrayref) |
1047 |
|
1048 |
Reads a JSON object or array, decodes it and passes it to the callback. |
1049 |
|
1050 |
If a C<json> object was passed to the constructor, then that will be used |
1051 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1052 |
|
1053 |
This read type uses the incremental parser available with JSON version |
1054 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1055 |
dependency on your own: this module will load the JSON module, but |
1056 |
AnyEvent does not depend on it itself. |
1057 |
|
1058 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1059 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1060 |
the C<json> write type description, above, for an actual example. |
1061 |
|
1062 |
=cut |
1063 |
|
1064 |
register_read_type json => sub { |
1065 |
my ($self, $cb) = @_; |
1066 |
|
1067 |
require JSON; |
1068 |
|
1069 |
my $data; |
1070 |
my $rbuf = \$self->{rbuf}; |
1071 |
|
1072 |
my $json = $self->{json} ||= JSON->new->utf8; |
1073 |
|
1074 |
sub { |
1075 |
my $ref = $json->incr_parse ($self->{rbuf}); |
1076 |
|
1077 |
if ($ref) { |
1078 |
$self->{rbuf} = $json->incr_text; |
1079 |
$json->incr_text = ""; |
1080 |
$cb->($self, $ref); |
1081 |
|
1082 |
1 |
1083 |
} else { |
1084 |
$self->{rbuf} = ""; |
1085 |
() |
1086 |
} |
1087 |
} |
1088 |
}; |
1089 |
|
1090 |
=item storable => $cb->($handle, $ref) |
1091 |
|
1092 |
Deserialises a L<Storable> frozen representation as written by the |
1093 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1094 |
data). |
1095 |
|
1096 |
Raises C<EBADMSG> error if the data could not be decoded. |
1097 |
|
1098 |
=cut |
1099 |
|
1100 |
register_read_type storable => sub { |
1101 |
my ($self, $cb) = @_; |
1102 |
|
1103 |
require Storable; |
1104 |
|
1105 |
sub { |
1106 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1107 |
defined (my $len = eval { unpack "w", $_[0]->{rbuf} }) |
1108 |
or return; |
1109 |
|
1110 |
# remove prefix |
1111 |
substr $_[0]->{rbuf}, 0, (length pack "w", $len), ""; |
1112 |
|
1113 |
# read rest |
1114 |
$_[0]->unshift_read (chunk => $len, sub { |
1115 |
if (my $ref = eval { Storable::thaw ($_[1]) }) { |
1116 |
$cb->($_[0], $ref); |
1117 |
} else { |
1118 |
$self->_error (&Errno::EBADMSG); |
1119 |
} |
1120 |
}); |
1121 |
} |
1122 |
}; |
1123 |
|
1124 |
=back |
1125 |
|
1126 |
=item AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args) |
1127 |
|
1128 |
This function (not method) lets you add your own types to C<push_read>. |
1129 |
|
1130 |
Whenever the given C<type> is used, C<push_read> will invoke the code |
1131 |
reference with the handle object, the callback and the remaining |
1132 |
arguments. |
1133 |
|
1134 |
The code reference is supposed to return a callback (usually a closure) |
1135 |
that works as a plain read callback (see C<< ->push_read ($cb) >>). |
1136 |
|
1137 |
It should invoke the passed callback when it is done reading (remember to |
1138 |
pass C<$handle> as first argument as all other callbacks do that). |
1139 |
|
1140 |
Note that this is a function, and all types registered this way will be |
1141 |
global, so try to use unique names. |
1142 |
|
1143 |
For examples, see the source of this module (F<perldoc -m AnyEvent::Handle>, |
1144 |
search for C<register_read_type>)). |
1145 |
|
1146 |
=item $handle->stop_read |
1147 |
|
1148 |
=item $handle->start_read |
1149 |
|
1150 |
In rare cases you actually do not want to read anything from the |
1151 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1152 |
any queued callbacks will be executed then. To start reading again, call |
1153 |
C<start_read>. |
1154 |
|
1155 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1156 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1157 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1158 |
there are any read requests in the queue. |
1159 |
|
1160 |
=cut |
1161 |
|
1162 |
sub stop_read { |
1163 |
my ($self) = @_; |
1164 |
|
1165 |
delete $self->{_rw}; |
1166 |
} |
1167 |
|
1168 |
sub start_read { |
1169 |
my ($self) = @_; |
1170 |
|
1171 |
unless ($self->{_rw} || $self->{_eof}) { |
1172 |
Scalar::Util::weaken $self; |
1173 |
|
1174 |
$self->{_rw} = AnyEvent->io (fh => $self->{fh}, poll => "r", cb => sub { |
1175 |
my $rbuf = $self->{filter_r} ? \my $buf : \$self->{rbuf}; |
1176 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size} || 8192, length $$rbuf; |
1177 |
|
1178 |
if ($len > 0) { |
1179 |
$self->{_activity} = AnyEvent->now; |
1180 |
|
1181 |
$self->{filter_r} |
1182 |
? $self->{filter_r}($self, $rbuf) |
1183 |
: $self->{_in_drain} || $self->_drain_rbuf; |
1184 |
|
1185 |
} elsif (defined $len) { |
1186 |
delete $self->{_rw}; |
1187 |
$self->{_eof} = 1; |
1188 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1189 |
|
1190 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1191 |
return $self->_error ($!, 1); |
1192 |
} |
1193 |
}); |
1194 |
} |
1195 |
} |
1196 |
|
1197 |
sub _dotls { |
1198 |
my ($self) = @_; |
1199 |
|
1200 |
my $buf; |
1201 |
|
1202 |
if (length $self->{_tls_wbuf}) { |
1203 |
while ((my $len = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1204 |
substr $self->{_tls_wbuf}, 0, $len, ""; |
1205 |
} |
1206 |
} |
1207 |
|
1208 |
if (length ($buf = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1209 |
$self->{wbuf} .= $buf; |
1210 |
$self->_drain_wbuf; |
1211 |
} |
1212 |
|
1213 |
while (defined ($buf = Net::SSLeay::read ($self->{tls}))) { |
1214 |
if (length $buf) { |
1215 |
$self->{rbuf} .= $buf; |
1216 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1217 |
} else { |
1218 |
# let's treat SSL-eof as we treat normal EOF |
1219 |
$self->{_eof} = 1; |
1220 |
$self->_shutdown; |
1221 |
return; |
1222 |
} |
1223 |
} |
1224 |
|
1225 |
my $err = Net::SSLeay::get_error ($self->{tls}, -1); |
1226 |
|
1227 |
if ($err!= Net::SSLeay::ERROR_WANT_READ ()) { |
1228 |
if ($err == Net::SSLeay::ERROR_SYSCALL ()) { |
1229 |
return $self->_error ($!, 1); |
1230 |
} elsif ($err == Net::SSLeay::ERROR_SSL ()) { |
1231 |
return $self->_error (&Errno::EIO, 1); |
1232 |
} |
1233 |
|
1234 |
# all others are fine for our purposes |
1235 |
} |
1236 |
} |
1237 |
|
1238 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1239 |
|
1240 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1241 |
object is created, you can also do that at a later time by calling |
1242 |
C<starttls>. |
1243 |
|
1244 |
The first argument is the same as the C<tls> constructor argument (either |
1245 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1246 |
|
1247 |
The second argument is the optional C<Net::SSLeay::CTX> object that is |
1248 |
used when AnyEvent::Handle has to create its own TLS connection object. |
1249 |
|
1250 |
The TLS connection object will end up in C<< $handle->{tls} >> after this |
1251 |
call and can be used or changed to your liking. Note that the handshake |
1252 |
might have already started when this function returns. |
1253 |
|
1254 |
=cut |
1255 |
|
1256 |
sub starttls { |
1257 |
my ($self, $ssl, $ctx) = @_; |
1258 |
|
1259 |
$self->stoptls; |
1260 |
|
1261 |
if ($ssl eq "accept") { |
1262 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1263 |
Net::SSLeay::set_accept_state ($ssl); |
1264 |
} elsif ($ssl eq "connect") { |
1265 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1266 |
Net::SSLeay::set_connect_state ($ssl); |
1267 |
} |
1268 |
|
1269 |
$self->{tls} = $ssl; |
1270 |
|
1271 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1272 |
# but the openssl maintainers basically said: "trust us, it just works". |
1273 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1274 |
# and mismaintained ssleay-module doesn't even offer them). |
1275 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1276 |
Net::SSLeay::CTX_set_mode ($self->{tls}, |
1277 |
(eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1278 |
| (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1279 |
|
1280 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1281 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1282 |
|
1283 |
Net::SSLeay::set_bio ($ssl, $self->{_rbio}, $self->{_wbio}); |
1284 |
|
1285 |
$self->{filter_w} = sub { |
1286 |
$_[0]{_tls_wbuf} .= ${$_[1]}; |
1287 |
&_dotls; |
1288 |
}; |
1289 |
$self->{filter_r} = sub { |
1290 |
Net::SSLeay::BIO_write ($_[0]{_rbio}, ${$_[1]}); |
1291 |
&_dotls; |
1292 |
}; |
1293 |
} |
1294 |
|
1295 |
=item $handle->stoptls |
1296 |
|
1297 |
Destroys the SSL connection, if any. Partial read or write data will be |
1298 |
lost. |
1299 |
|
1300 |
=cut |
1301 |
|
1302 |
sub stoptls { |
1303 |
my ($self) = @_; |
1304 |
|
1305 |
Net::SSLeay::free (delete $self->{tls}) if $self->{tls}; |
1306 |
|
1307 |
delete $self->{_rbio}; |
1308 |
delete $self->{_wbio}; |
1309 |
delete $self->{_tls_wbuf}; |
1310 |
delete $self->{filter_r}; |
1311 |
delete $self->{filter_w}; |
1312 |
} |
1313 |
|
1314 |
sub DESTROY { |
1315 |
my $self = shift; |
1316 |
|
1317 |
$self->stoptls; |
1318 |
|
1319 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
1320 |
|
1321 |
if ($linger && length $self->{wbuf}) { |
1322 |
my $fh = delete $self->{fh}; |
1323 |
my $wbuf = delete $self->{wbuf}; |
1324 |
|
1325 |
my @linger; |
1326 |
|
1327 |
push @linger, AnyEvent->io (fh => $fh, poll => "w", cb => sub { |
1328 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
1329 |
|
1330 |
if ($len > 0) { |
1331 |
substr $wbuf, 0, $len, ""; |
1332 |
} else { |
1333 |
@linger = (); # end |
1334 |
} |
1335 |
}); |
1336 |
push @linger, AnyEvent->timer (after => $linger, cb => sub { |
1337 |
@linger = (); |
1338 |
}); |
1339 |
} |
1340 |
} |
1341 |
|
1342 |
=item AnyEvent::Handle::TLS_CTX |
1343 |
|
1344 |
This function creates and returns the Net::SSLeay::CTX object used by |
1345 |
default for TLS mode. |
1346 |
|
1347 |
The context is created like this: |
1348 |
|
1349 |
Net::SSLeay::load_error_strings; |
1350 |
Net::SSLeay::SSLeay_add_ssl_algorithms; |
1351 |
Net::SSLeay::randomize; |
1352 |
|
1353 |
my $CTX = Net::SSLeay::CTX_new; |
1354 |
|
1355 |
Net::SSLeay::CTX_set_options $CTX, Net::SSLeay::OP_ALL |
1356 |
|
1357 |
=cut |
1358 |
|
1359 |
our $TLS_CTX; |
1360 |
|
1361 |
sub TLS_CTX() { |
1362 |
$TLS_CTX || do { |
1363 |
require Net::SSLeay; |
1364 |
|
1365 |
Net::SSLeay::load_error_strings (); |
1366 |
Net::SSLeay::SSLeay_add_ssl_algorithms (); |
1367 |
Net::SSLeay::randomize (); |
1368 |
|
1369 |
$TLS_CTX = Net::SSLeay::CTX_new (); |
1370 |
|
1371 |
Net::SSLeay::CTX_set_options ($TLS_CTX, Net::SSLeay::OP_ALL ()); |
1372 |
|
1373 |
$TLS_CTX |
1374 |
} |
1375 |
} |
1376 |
|
1377 |
=back |
1378 |
|
1379 |
=head1 SUBCLASSING AnyEvent::Handle |
1380 |
|
1381 |
In many cases, you might want to subclass AnyEvent::Handle. |
1382 |
|
1383 |
To make this easier, a given version of AnyEvent::Handle uses these |
1384 |
conventions: |
1385 |
|
1386 |
=over 4 |
1387 |
|
1388 |
=item * all constructor arguments become object members. |
1389 |
|
1390 |
At least initially, when you pass a C<tls>-argument to the constructor it |
1391 |
will end up in C<< $handle->{tls} >>. Those members might be changes or |
1392 |
mutated later on (for example C<tls> will hold the TLS connection object). |
1393 |
|
1394 |
=item * other object member names are prefixed with an C<_>. |
1395 |
|
1396 |
All object members not explicitly documented (internal use) are prefixed |
1397 |
with an underscore character, so the remaining non-C<_>-namespace is free |
1398 |
for use for subclasses. |
1399 |
|
1400 |
=item * all members not documented here and not prefixed with an underscore |
1401 |
are free to use in subclasses. |
1402 |
|
1403 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
1404 |
member variables, but thats just life, at least it is documented. |
1405 |
|
1406 |
=back |
1407 |
|
1408 |
=head1 AUTHOR |
1409 |
|
1410 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
1411 |
|
1412 |
=cut |
1413 |
|
1414 |
1; # End of AnyEvent::Handle |