1 |
package AnyEvent::Handle; |
2 |
|
3 |
no warnings; |
4 |
use strict; |
5 |
|
6 |
use AnyEvent (); |
7 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
8 |
use Scalar::Util (); |
9 |
use Carp (); |
10 |
use Fcntl (); |
11 |
use Errno qw(EAGAIN EINTR); |
12 |
|
13 |
=head1 NAME |
14 |
|
15 |
AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent |
16 |
|
17 |
=cut |
18 |
|
19 |
our $VERSION = 4.151; |
20 |
|
21 |
=head1 SYNOPSIS |
22 |
|
23 |
use AnyEvent; |
24 |
use AnyEvent::Handle; |
25 |
|
26 |
my $cv = AnyEvent->condvar; |
27 |
|
28 |
my $handle = |
29 |
AnyEvent::Handle->new ( |
30 |
fh => \*STDIN, |
31 |
on_eof => sub { |
32 |
$cv->broadcast; |
33 |
}, |
34 |
); |
35 |
|
36 |
# send some request line |
37 |
$handle->push_write ("getinfo\015\012"); |
38 |
|
39 |
# read the response line |
40 |
$handle->push_read (line => sub { |
41 |
my ($handle, $line) = @_; |
42 |
warn "read line <$line>\n"; |
43 |
$cv->send; |
44 |
}); |
45 |
|
46 |
$cv->recv; |
47 |
|
48 |
=head1 DESCRIPTION |
49 |
|
50 |
This module is a helper module to make it easier to do event-based I/O on |
51 |
filehandles. For utility functions for doing non-blocking connects and accepts |
52 |
on sockets see L<AnyEvent::Util>. |
53 |
|
54 |
In the following, when the documentation refers to of "bytes" then this |
55 |
means characters. As sysread and syswrite are used for all I/O, their |
56 |
treatment of characters applies to this module as well. |
57 |
|
58 |
All callbacks will be invoked with the handle object as their first |
59 |
argument. |
60 |
|
61 |
=head1 METHODS |
62 |
|
63 |
=over 4 |
64 |
|
65 |
=item B<new (%args)> |
66 |
|
67 |
The constructor supports these arguments (all as key => value pairs). |
68 |
|
69 |
=over 4 |
70 |
|
71 |
=item fh => $filehandle [MANDATORY] |
72 |
|
73 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
74 |
|
75 |
NOTE: The filehandle will be set to non-blocking (using |
76 |
AnyEvent::Util::fh_nonblocking). |
77 |
|
78 |
=item on_eof => $cb->($handle) |
79 |
|
80 |
Set the callback to be called when an end-of-file condition is detcted, |
81 |
i.e. in the case of a socket, when the other side has closed the |
82 |
connection cleanly. |
83 |
|
84 |
While not mandatory, it is highly recommended to set an eof callback, |
85 |
otherwise you might end up with a closed socket while you are still |
86 |
waiting for data. |
87 |
|
88 |
=item on_error => $cb->($handle, $fatal) |
89 |
|
90 |
This is the error callback, which is called when, well, some error |
91 |
occured, such as not being able to resolve the hostname, failure to |
92 |
connect or a read error. |
93 |
|
94 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
95 |
fatal errors the handle object will be shut down and will not be |
96 |
usable. Non-fatal errors can be retried by simply returning, but it is |
97 |
recommended to simply ignore this parameter and instead abondon the handle |
98 |
object when this callback is invoked. |
99 |
|
100 |
On callback entrance, the value of C<$!> contains the operating system |
101 |
error (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT> or C<EBADMSG>). |
102 |
|
103 |
While not mandatory, it is I<highly> recommended to set this callback, as |
104 |
you will not be notified of errors otherwise. The default simply calls |
105 |
C<croak>. |
106 |
|
107 |
=item on_read => $cb->($handle) |
108 |
|
109 |
This sets the default read callback, which is called when data arrives |
110 |
and no read request is in the queue (unlike read queue callbacks, this |
111 |
callback will only be called when at least one octet of data is in the |
112 |
read buffer). |
113 |
|
114 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
115 |
method or access the C<$handle->{rbuf}> member directly. |
116 |
|
117 |
When an EOF condition is detected then AnyEvent::Handle will first try to |
118 |
feed all the remaining data to the queued callbacks and C<on_read> before |
119 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
120 |
error will be raised (with C<$!> set to C<EPIPE>). |
121 |
|
122 |
=item on_drain => $cb->($handle) |
123 |
|
124 |
This sets the callback that is called when the write buffer becomes empty |
125 |
(or when the callback is set and the buffer is empty already). |
126 |
|
127 |
To append to the write buffer, use the C<< ->push_write >> method. |
128 |
|
129 |
This callback is useful when you don't want to put all of your write data |
130 |
into the queue at once, for example, when you want to write the contents |
131 |
of some file to the socket you might not want to read the whole file into |
132 |
memory and push it into the queue, but instead only read more data from |
133 |
the file when the write queue becomes empty. |
134 |
|
135 |
=item timeout => $fractional_seconds |
136 |
|
137 |
If non-zero, then this enables an "inactivity" timeout: whenever this many |
138 |
seconds pass without a successful read or write on the underlying file |
139 |
handle, the C<on_timeout> callback will be invoked (and if that one is |
140 |
missing, an C<ETIMEDOUT> error will be raised). |
141 |
|
142 |
Note that timeout processing is also active when you currently do not have |
143 |
any outstanding read or write requests: If you plan to keep the connection |
144 |
idle then you should disable the timout temporarily or ignore the timeout |
145 |
in the C<on_timeout> callback. |
146 |
|
147 |
Zero (the default) disables this timeout. |
148 |
|
149 |
=item on_timeout => $cb->($handle) |
150 |
|
151 |
Called whenever the inactivity timeout passes. If you return from this |
152 |
callback, then the timeout will be reset as if some activity had happened, |
153 |
so this condition is not fatal in any way. |
154 |
|
155 |
=item rbuf_max => <bytes> |
156 |
|
157 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
158 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
159 |
avoid denial-of-service attacks. |
160 |
|
161 |
For example, a server accepting connections from untrusted sources should |
162 |
be configured to accept only so-and-so much data that it cannot act on |
163 |
(for example, when expecting a line, an attacker could send an unlimited |
164 |
amount of data without a callback ever being called as long as the line |
165 |
isn't finished). |
166 |
|
167 |
=item read_size => <bytes> |
168 |
|
169 |
The default read block size (the amount of bytes this module will try to read |
170 |
during each (loop iteration). Default: C<8192>. |
171 |
|
172 |
=item low_water_mark => <bytes> |
173 |
|
174 |
Sets the amount of bytes (default: C<0>) that make up an "empty" write |
175 |
buffer: If the write reaches this size or gets even samller it is |
176 |
considered empty. |
177 |
|
178 |
=item linger => <seconds> |
179 |
|
180 |
If non-zero (default: C<3600>), then the destructor of the |
181 |
AnyEvent::Handle object will check wether there is still outstanding write |
182 |
data and will install a watcher that will write out this data. No errors |
183 |
will be reported (this mostly matches how the operating system treats |
184 |
outstanding data at socket close time). |
185 |
|
186 |
This will not work for partial TLS data that could not yet been |
187 |
encoded. This data will be lost. |
188 |
|
189 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
190 |
|
191 |
When this parameter is given, it enables TLS (SSL) mode, that means it |
192 |
will start making tls handshake and will transparently encrypt/decrypt |
193 |
data. |
194 |
|
195 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
196 |
automatically when you try to create a TLS handle). |
197 |
|
198 |
For the TLS server side, use C<accept>, and for the TLS client side of a |
199 |
connection, use C<connect> mode. |
200 |
|
201 |
You can also provide your own TLS connection object, but you have |
202 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
203 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
204 |
AnyEvent::Handle. |
205 |
|
206 |
See the C<starttls> method if you need to start TLs negotiation later. |
207 |
|
208 |
=item tls_ctx => $ssl_ctx |
209 |
|
210 |
Use the given Net::SSLeay::CTX object to create the new TLS connection |
211 |
(unless a connection object was specified directly). If this parameter is |
212 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
213 |
|
214 |
=item json => JSON or JSON::XS object |
215 |
|
216 |
This is the json coder object used by the C<json> read and write types. |
217 |
|
218 |
If you don't supply it, then AnyEvent::Handle will create and use a |
219 |
suitable one, which will write and expect UTF-8 encoded JSON texts. |
220 |
|
221 |
Note that you are responsible to depend on the JSON module if you want to |
222 |
use this functionality, as AnyEvent does not have a dependency itself. |
223 |
|
224 |
=item filter_r => $cb |
225 |
|
226 |
=item filter_w => $cb |
227 |
|
228 |
These exist, but are undocumented at this time. |
229 |
|
230 |
=back |
231 |
|
232 |
=cut |
233 |
|
234 |
sub new { |
235 |
my $class = shift; |
236 |
|
237 |
my $self = bless { @_ }, $class; |
238 |
|
239 |
$self->{fh} or Carp::croak "mandatory argument fh is missing"; |
240 |
|
241 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
242 |
|
243 |
if ($self->{tls}) { |
244 |
require Net::SSLeay; |
245 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}); |
246 |
} |
247 |
|
248 |
$self->{_activity} = AnyEvent->now; |
249 |
$self->_timeout; |
250 |
|
251 |
$self->on_drain (delete $self->{on_drain}) if $self->{on_drain}; |
252 |
|
253 |
$self->start_read |
254 |
if $self->{on_read}; |
255 |
|
256 |
$self |
257 |
} |
258 |
|
259 |
sub _shutdown { |
260 |
my ($self) = @_; |
261 |
|
262 |
delete $self->{_tw}; |
263 |
delete $self->{_rw}; |
264 |
delete $self->{_ww}; |
265 |
delete $self->{fh}; |
266 |
|
267 |
$self->stoptls; |
268 |
} |
269 |
|
270 |
sub _error { |
271 |
my ($self, $errno, $fatal) = @_; |
272 |
|
273 |
$self->_shutdown |
274 |
if $fatal; |
275 |
|
276 |
$! = $errno; |
277 |
|
278 |
if ($self->{on_error}) { |
279 |
$self->{on_error}($self, $fatal); |
280 |
} else { |
281 |
Carp::croak "AnyEvent::Handle uncaught error: $!"; |
282 |
} |
283 |
} |
284 |
|
285 |
=item $fh = $handle->fh |
286 |
|
287 |
This method returns the file handle of the L<AnyEvent::Handle> object. |
288 |
|
289 |
=cut |
290 |
|
291 |
sub fh { $_[0]{fh} } |
292 |
|
293 |
=item $handle->on_error ($cb) |
294 |
|
295 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
296 |
|
297 |
=cut |
298 |
|
299 |
sub on_error { |
300 |
$_[0]{on_error} = $_[1]; |
301 |
} |
302 |
|
303 |
=item $handle->on_eof ($cb) |
304 |
|
305 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
306 |
|
307 |
=cut |
308 |
|
309 |
sub on_eof { |
310 |
$_[0]{on_eof} = $_[1]; |
311 |
} |
312 |
|
313 |
=item $handle->on_timeout ($cb) |
314 |
|
315 |
Replace the current C<on_timeout> callback, or disables the callback |
316 |
(but not the timeout) if C<$cb> = C<undef>. See C<timeout> constructor |
317 |
argument. |
318 |
|
319 |
=cut |
320 |
|
321 |
sub on_timeout { |
322 |
$_[0]{on_timeout} = $_[1]; |
323 |
} |
324 |
|
325 |
############################################################################# |
326 |
|
327 |
=item $handle->timeout ($seconds) |
328 |
|
329 |
Configures (or disables) the inactivity timeout. |
330 |
|
331 |
=cut |
332 |
|
333 |
sub timeout { |
334 |
my ($self, $timeout) = @_; |
335 |
|
336 |
$self->{timeout} = $timeout; |
337 |
$self->_timeout; |
338 |
} |
339 |
|
340 |
# reset the timeout watcher, as neccessary |
341 |
# also check for time-outs |
342 |
sub _timeout { |
343 |
my ($self) = @_; |
344 |
|
345 |
if ($self->{timeout}) { |
346 |
my $NOW = AnyEvent->now; |
347 |
|
348 |
# when would the timeout trigger? |
349 |
my $after = $self->{_activity} + $self->{timeout} - $NOW; |
350 |
|
351 |
# now or in the past already? |
352 |
if ($after <= 0) { |
353 |
$self->{_activity} = $NOW; |
354 |
|
355 |
if ($self->{on_timeout}) { |
356 |
$self->{on_timeout}($self); |
357 |
} else { |
358 |
$self->_error (&Errno::ETIMEDOUT); |
359 |
} |
360 |
|
361 |
# callback could have changed timeout value, optimise |
362 |
return unless $self->{timeout}; |
363 |
|
364 |
# calculate new after |
365 |
$after = $self->{timeout}; |
366 |
} |
367 |
|
368 |
Scalar::Util::weaken $self; |
369 |
return unless $self; # ->error could have destroyed $self |
370 |
|
371 |
$self->{_tw} ||= AnyEvent->timer (after => $after, cb => sub { |
372 |
delete $self->{_tw}; |
373 |
$self->_timeout; |
374 |
}); |
375 |
} else { |
376 |
delete $self->{_tw}; |
377 |
} |
378 |
} |
379 |
|
380 |
############################################################################# |
381 |
|
382 |
=back |
383 |
|
384 |
=head2 WRITE QUEUE |
385 |
|
386 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
387 |
for reading. |
388 |
|
389 |
The write queue is very simple: you can add data to its end, and |
390 |
AnyEvent::Handle will automatically try to get rid of it for you. |
391 |
|
392 |
When data could be written and the write buffer is shorter then the low |
393 |
water mark, the C<on_drain> callback will be invoked. |
394 |
|
395 |
=over 4 |
396 |
|
397 |
=item $handle->on_drain ($cb) |
398 |
|
399 |
Sets the C<on_drain> callback or clears it (see the description of |
400 |
C<on_drain> in the constructor). |
401 |
|
402 |
=cut |
403 |
|
404 |
sub on_drain { |
405 |
my ($self, $cb) = @_; |
406 |
|
407 |
$self->{on_drain} = $cb; |
408 |
|
409 |
$cb->($self) |
410 |
if $cb && $self->{low_water_mark} >= length $self->{wbuf}; |
411 |
} |
412 |
|
413 |
=item $handle->push_write ($data) |
414 |
|
415 |
Queues the given scalar to be written. You can push as much data as you |
416 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
417 |
buffers it independently of the kernel. |
418 |
|
419 |
=cut |
420 |
|
421 |
sub _drain_wbuf { |
422 |
my ($self) = @_; |
423 |
|
424 |
if (!$self->{_ww} && length $self->{wbuf}) { |
425 |
|
426 |
Scalar::Util::weaken $self; |
427 |
|
428 |
my $cb = sub { |
429 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
430 |
|
431 |
if ($len >= 0) { |
432 |
substr $self->{wbuf}, 0, $len, ""; |
433 |
|
434 |
$self->{_activity} = AnyEvent->now; |
435 |
|
436 |
$self->{on_drain}($self) |
437 |
if $self->{low_water_mark} >= length $self->{wbuf} |
438 |
&& $self->{on_drain}; |
439 |
|
440 |
delete $self->{_ww} unless length $self->{wbuf}; |
441 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
442 |
$self->_error ($!, 1); |
443 |
} |
444 |
}; |
445 |
|
446 |
# try to write data immediately |
447 |
$cb->(); |
448 |
|
449 |
# if still data left in wbuf, we need to poll |
450 |
$self->{_ww} = AnyEvent->io (fh => $self->{fh}, poll => "w", cb => $cb) |
451 |
if length $self->{wbuf}; |
452 |
}; |
453 |
} |
454 |
|
455 |
our %WH; |
456 |
|
457 |
sub register_write_type($$) { |
458 |
$WH{$_[0]} = $_[1]; |
459 |
} |
460 |
|
461 |
sub push_write { |
462 |
my $self = shift; |
463 |
|
464 |
if (@_ > 1) { |
465 |
my $type = shift; |
466 |
|
467 |
@_ = ($WH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_write") |
468 |
->($self, @_); |
469 |
} |
470 |
|
471 |
if ($self->{filter_w}) { |
472 |
$self->{filter_w}($self, \$_[0]); |
473 |
} else { |
474 |
$self->{wbuf} .= $_[0]; |
475 |
$self->_drain_wbuf; |
476 |
} |
477 |
} |
478 |
|
479 |
=item $handle->push_write (type => @args) |
480 |
|
481 |
Instead of formatting your data yourself, you can also let this module do |
482 |
the job by specifying a type and type-specific arguments. |
483 |
|
484 |
Predefined types are (if you have ideas for additional types, feel free to |
485 |
drop by and tell us): |
486 |
|
487 |
=over 4 |
488 |
|
489 |
=item netstring => $string |
490 |
|
491 |
Formats the given value as netstring |
492 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
493 |
|
494 |
=cut |
495 |
|
496 |
register_write_type netstring => sub { |
497 |
my ($self, $string) = @_; |
498 |
|
499 |
sprintf "%d:%s,", (length $string), $string |
500 |
}; |
501 |
|
502 |
=item packstring => $format, $data |
503 |
|
504 |
An octet string prefixed with an encoded length. The encoding C<$format> |
505 |
uses the same format as a Perl C<pack> format, but must specify a single |
506 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
507 |
optional C<!>, C<< < >> or C<< > >> modifier). |
508 |
|
509 |
=cut |
510 |
|
511 |
register_write_type packstring => sub { |
512 |
my ($self, $format, $string) = @_; |
513 |
|
514 |
pack "$format/a*", $string |
515 |
}; |
516 |
|
517 |
=item json => $array_or_hashref |
518 |
|
519 |
Encodes the given hash or array reference into a JSON object. Unless you |
520 |
provide your own JSON object, this means it will be encoded to JSON text |
521 |
in UTF-8. |
522 |
|
523 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
524 |
one end of a handle and read them at the other end without using any |
525 |
additional framing. |
526 |
|
527 |
The generated JSON text is guaranteed not to contain any newlines: While |
528 |
this module doesn't need delimiters after or between JSON texts to be |
529 |
able to read them, many other languages depend on that. |
530 |
|
531 |
A simple RPC protocol that interoperates easily with others is to send |
532 |
JSON arrays (or objects, although arrays are usually the better choice as |
533 |
they mimic how function argument passing works) and a newline after each |
534 |
JSON text: |
535 |
|
536 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
537 |
$handle->push_write ("\012"); |
538 |
|
539 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
540 |
rely on the fact that the newline will be skipped as leading whitespace: |
541 |
|
542 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
543 |
|
544 |
Other languages could read single lines terminated by a newline and pass |
545 |
this line into their JSON decoder of choice. |
546 |
|
547 |
=cut |
548 |
|
549 |
register_write_type json => sub { |
550 |
my ($self, $ref) = @_; |
551 |
|
552 |
require JSON; |
553 |
|
554 |
$self->{json} ? $self->{json}->encode ($ref) |
555 |
: JSON::encode_json ($ref) |
556 |
}; |
557 |
|
558 |
=item storable => $reference |
559 |
|
560 |
Freezes the given reference using L<Storable> and writes it to the |
561 |
handle. Uses the C<nfreeze> format. |
562 |
|
563 |
=cut |
564 |
|
565 |
register_write_type storable => sub { |
566 |
my ($self, $ref) = @_; |
567 |
|
568 |
require Storable; |
569 |
|
570 |
pack "w/a*", Storable::nfreeze ($ref) |
571 |
}; |
572 |
|
573 |
=back |
574 |
|
575 |
=item AnyEvent::Handle::register_write_type type => $coderef->($handle, @args) |
576 |
|
577 |
This function (not method) lets you add your own types to C<push_write>. |
578 |
Whenever the given C<type> is used, C<push_write> will invoke the code |
579 |
reference with the handle object and the remaining arguments. |
580 |
|
581 |
The code reference is supposed to return a single octet string that will |
582 |
be appended to the write buffer. |
583 |
|
584 |
Note that this is a function, and all types registered this way will be |
585 |
global, so try to use unique names. |
586 |
|
587 |
=cut |
588 |
|
589 |
############################################################################# |
590 |
|
591 |
=back |
592 |
|
593 |
=head2 READ QUEUE |
594 |
|
595 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
596 |
for reading. |
597 |
|
598 |
The read queue is more complex than the write queue. It can be used in two |
599 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
600 |
a queue. |
601 |
|
602 |
In the simple case, you just install an C<on_read> callback and whenever |
603 |
new data arrives, it will be called. You can then remove some data (if |
604 |
enough is there) from the read buffer (C<< $handle->rbuf >>). Or you cna |
605 |
leave the data there if you want to accumulate more (e.g. when only a |
606 |
partial message has been received so far). |
607 |
|
608 |
In the more complex case, you want to queue multiple callbacks. In this |
609 |
case, AnyEvent::Handle will call the first queued callback each time new |
610 |
data arrives (also the first time it is queued) and removes it when it has |
611 |
done its job (see C<push_read>, below). |
612 |
|
613 |
This way you can, for example, push three line-reads, followed by reading |
614 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
615 |
|
616 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
617 |
the specified number of bytes which give an XML datagram. |
618 |
|
619 |
# in the default state, expect some header bytes |
620 |
$handle->on_read (sub { |
621 |
# some data is here, now queue the length-header-read (4 octets) |
622 |
shift->unshift_read (chunk => 4, sub { |
623 |
# header arrived, decode |
624 |
my $len = unpack "N", $_[1]; |
625 |
|
626 |
# now read the payload |
627 |
shift->unshift_read (chunk => $len, sub { |
628 |
my $xml = $_[1]; |
629 |
# handle xml |
630 |
}); |
631 |
}); |
632 |
}); |
633 |
|
634 |
Example 2: Implement a client for a protocol that replies either with "OK" |
635 |
and another line or "ERROR" for the first request that is sent, and 64 |
636 |
bytes for the second request. Due to the availability of a queue, we can |
637 |
just pipeline sending both requests and manipulate the queue as necessary |
638 |
in the callbacks. |
639 |
|
640 |
When the first callback is called and sees an "OK" response, it will |
641 |
C<unshift> another line-read. This line-read will be queued I<before> the |
642 |
64-byte chunk callback. |
643 |
|
644 |
# request one, returns either "OK + extra line" or "ERROR" |
645 |
$handle->push_write ("request 1\015\012"); |
646 |
|
647 |
# we expect "ERROR" or "OK" as response, so push a line read |
648 |
$handle->push_read (line => sub { |
649 |
# if we got an "OK", we have to _prepend_ another line, |
650 |
# so it will be read before the second request reads its 64 bytes |
651 |
# which are already in the queue when this callback is called |
652 |
# we don't do this in case we got an error |
653 |
if ($_[1] eq "OK") { |
654 |
$_[0]->unshift_read (line => sub { |
655 |
my $response = $_[1]; |
656 |
... |
657 |
}); |
658 |
} |
659 |
}); |
660 |
|
661 |
# request two, simply returns 64 octets |
662 |
$handle->push_write ("request 2\015\012"); |
663 |
|
664 |
# simply read 64 bytes, always |
665 |
$handle->push_read (chunk => 64, sub { |
666 |
my $response = $_[1]; |
667 |
... |
668 |
}); |
669 |
|
670 |
=over 4 |
671 |
|
672 |
=cut |
673 |
|
674 |
sub _drain_rbuf { |
675 |
my ($self) = @_; |
676 |
|
677 |
local $self->{_in_drain} = 1; |
678 |
|
679 |
if ( |
680 |
defined $self->{rbuf_max} |
681 |
&& $self->{rbuf_max} < length $self->{rbuf} |
682 |
) { |
683 |
return $self->_error (&Errno::ENOSPC, 1); |
684 |
} |
685 |
|
686 |
while () { |
687 |
no strict 'refs'; |
688 |
|
689 |
my $len = length $self->{rbuf}; |
690 |
|
691 |
if (my $cb = shift @{ $self->{_queue} }) { |
692 |
unless ($cb->($self)) { |
693 |
if ($self->{_eof}) { |
694 |
# no progress can be made (not enough data and no data forthcoming) |
695 |
$self->_error (&Errno::EPIPE, 1), last; |
696 |
} |
697 |
|
698 |
unshift @{ $self->{_queue} }, $cb; |
699 |
last; |
700 |
} |
701 |
} elsif ($self->{on_read}) { |
702 |
last unless $len; |
703 |
|
704 |
$self->{on_read}($self); |
705 |
|
706 |
if ( |
707 |
$len == length $self->{rbuf} # if no data has been consumed |
708 |
&& !@{ $self->{_queue} } # and the queue is still empty |
709 |
&& $self->{on_read} # but we still have on_read |
710 |
) { |
711 |
# no further data will arrive |
712 |
# so no progress can be made |
713 |
$self->_error (&Errno::EPIPE, 1), last |
714 |
if $self->{_eof}; |
715 |
|
716 |
last; # more data might arrive |
717 |
} |
718 |
} else { |
719 |
# read side becomes idle |
720 |
delete $self->{_rw}; |
721 |
last; |
722 |
} |
723 |
} |
724 |
|
725 |
$self->{on_eof}($self) |
726 |
if $self->{_eof} && $self->{on_eof}; |
727 |
|
728 |
# may need to restart read watcher |
729 |
unless ($self->{_rw}) { |
730 |
$self->start_read |
731 |
if $self->{on_read} || @{ $self->{_queue} }; |
732 |
} |
733 |
} |
734 |
|
735 |
=item $handle->on_read ($cb) |
736 |
|
737 |
This replaces the currently set C<on_read> callback, or clears it (when |
738 |
the new callback is C<undef>). See the description of C<on_read> in the |
739 |
constructor. |
740 |
|
741 |
=cut |
742 |
|
743 |
sub on_read { |
744 |
my ($self, $cb) = @_; |
745 |
|
746 |
$self->{on_read} = $cb; |
747 |
$self->_drain_rbuf if $cb && !$self->{_in_drain}; |
748 |
} |
749 |
|
750 |
=item $handle->rbuf |
751 |
|
752 |
Returns the read buffer (as a modifiable lvalue). |
753 |
|
754 |
You can access the read buffer directly as the C<< ->{rbuf} >> member, if |
755 |
you want. |
756 |
|
757 |
NOTE: The read buffer should only be used or modified if the C<on_read>, |
758 |
C<push_read> or C<unshift_read> methods are used. The other read methods |
759 |
automatically manage the read buffer. |
760 |
|
761 |
=cut |
762 |
|
763 |
sub rbuf : lvalue { |
764 |
$_[0]{rbuf} |
765 |
} |
766 |
|
767 |
=item $handle->push_read ($cb) |
768 |
|
769 |
=item $handle->unshift_read ($cb) |
770 |
|
771 |
Append the given callback to the end of the queue (C<push_read>) or |
772 |
prepend it (C<unshift_read>). |
773 |
|
774 |
The callback is called each time some additional read data arrives. |
775 |
|
776 |
It must check whether enough data is in the read buffer already. |
777 |
|
778 |
If not enough data is available, it must return the empty list or a false |
779 |
value, in which case it will be called repeatedly until enough data is |
780 |
available (or an error condition is detected). |
781 |
|
782 |
If enough data was available, then the callback must remove all data it is |
783 |
interested in (which can be none at all) and return a true value. After returning |
784 |
true, it will be removed from the queue. |
785 |
|
786 |
=cut |
787 |
|
788 |
our %RH; |
789 |
|
790 |
sub register_read_type($$) { |
791 |
$RH{$_[0]} = $_[1]; |
792 |
} |
793 |
|
794 |
sub push_read { |
795 |
my $self = shift; |
796 |
my $cb = pop; |
797 |
|
798 |
if (@_) { |
799 |
my $type = shift; |
800 |
|
801 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_read") |
802 |
->($self, $cb, @_); |
803 |
} |
804 |
|
805 |
push @{ $self->{_queue} }, $cb; |
806 |
$self->_drain_rbuf unless $self->{_in_drain}; |
807 |
} |
808 |
|
809 |
sub unshift_read { |
810 |
my $self = shift; |
811 |
my $cb = pop; |
812 |
|
813 |
if (@_) { |
814 |
my $type = shift; |
815 |
|
816 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::unshift_read") |
817 |
->($self, $cb, @_); |
818 |
} |
819 |
|
820 |
|
821 |
unshift @{ $self->{_queue} }, $cb; |
822 |
$self->_drain_rbuf unless $self->{_in_drain}; |
823 |
} |
824 |
|
825 |
=item $handle->push_read (type => @args, $cb) |
826 |
|
827 |
=item $handle->unshift_read (type => @args, $cb) |
828 |
|
829 |
Instead of providing a callback that parses the data itself you can chose |
830 |
between a number of predefined parsing formats, for chunks of data, lines |
831 |
etc. |
832 |
|
833 |
Predefined types are (if you have ideas for additional types, feel free to |
834 |
drop by and tell us): |
835 |
|
836 |
=over 4 |
837 |
|
838 |
=item chunk => $octets, $cb->($handle, $data) |
839 |
|
840 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
841 |
data read to the callback. The callback will never be called with less |
842 |
data. |
843 |
|
844 |
Example: read 2 bytes. |
845 |
|
846 |
$handle->push_read (chunk => 2, sub { |
847 |
warn "yay ", unpack "H*", $_[1]; |
848 |
}); |
849 |
|
850 |
=cut |
851 |
|
852 |
register_read_type chunk => sub { |
853 |
my ($self, $cb, $len) = @_; |
854 |
|
855 |
sub { |
856 |
$len <= length $_[0]{rbuf} or return; |
857 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
858 |
1 |
859 |
} |
860 |
}; |
861 |
|
862 |
# compatibility with older API |
863 |
sub push_read_chunk { |
864 |
$_[0]->push_read (chunk => $_[1], $_[2]); |
865 |
} |
866 |
|
867 |
sub unshift_read_chunk { |
868 |
$_[0]->unshift_read (chunk => $_[1], $_[2]); |
869 |
} |
870 |
|
871 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
872 |
|
873 |
The callback will be called only once a full line (including the end of |
874 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
875 |
marker) will be passed to the callback as second argument (C<$line>), and |
876 |
the end of line marker as the third argument (C<$eol>). |
877 |
|
878 |
The end of line marker, C<$eol>, can be either a string, in which case it |
879 |
will be interpreted as a fixed record end marker, or it can be a regex |
880 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
881 |
regular expression. |
882 |
|
883 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
884 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
885 |
protocols). |
886 |
|
887 |
Partial lines at the end of the stream will never be returned, as they are |
888 |
not marked by the end of line marker. |
889 |
|
890 |
=cut |
891 |
|
892 |
register_read_type line => sub { |
893 |
my ($self, $cb, $eol) = @_; |
894 |
|
895 |
$eol = qr|(\015?\012)| if @_ < 3; |
896 |
$eol = quotemeta $eol unless ref $eol; |
897 |
$eol = qr|^(.*?)($eol)|s; |
898 |
|
899 |
sub { |
900 |
$_[0]{rbuf} =~ s/$eol// or return; |
901 |
|
902 |
$cb->($_[0], $1, $2); |
903 |
1 |
904 |
} |
905 |
}; |
906 |
|
907 |
# compatibility with older API |
908 |
sub push_read_line { |
909 |
my $self = shift; |
910 |
$self->push_read (line => @_); |
911 |
} |
912 |
|
913 |
sub unshift_read_line { |
914 |
my $self = shift; |
915 |
$self->unshift_read (line => @_); |
916 |
} |
917 |
|
918 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
919 |
|
920 |
Makes a regex match against the regex object C<$accept> and returns |
921 |
everything up to and including the match. |
922 |
|
923 |
Example: read a single line terminated by '\n'. |
924 |
|
925 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
926 |
|
927 |
If C<$reject> is given and not undef, then it determines when the data is |
928 |
to be rejected: it is matched against the data when the C<$accept> regex |
929 |
does not match and generates an C<EBADMSG> error when it matches. This is |
930 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
931 |
receive buffer overflow). |
932 |
|
933 |
Example: expect a single decimal number followed by whitespace, reject |
934 |
anything else (not the use of an anchor). |
935 |
|
936 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
937 |
|
938 |
If C<$skip> is given and not C<undef>, then it will be matched against |
939 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
940 |
and everything preceding and including the match will be accepted |
941 |
unconditionally. This is useful to skip large amounts of data that you |
942 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
943 |
have to start matching from the beginning. This is purely an optimisation |
944 |
and is usually worth only when you expect more than a few kilobytes. |
945 |
|
946 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
947 |
expect the header to be very large (it isn't in practise, but...), we use |
948 |
a skip regex to skip initial portions. The skip regex is tricky in that |
949 |
it only accepts something not ending in either \015 or \012, as these are |
950 |
required for the accept regex. |
951 |
|
952 |
$handle->push_read (regex => |
953 |
qr<\015\012\015\012>, |
954 |
undef, # no reject |
955 |
qr<^.*[^\015\012]>, |
956 |
sub { ... }); |
957 |
|
958 |
=cut |
959 |
|
960 |
register_read_type regex => sub { |
961 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
962 |
|
963 |
my $data; |
964 |
my $rbuf = \$self->{rbuf}; |
965 |
|
966 |
sub { |
967 |
# accept |
968 |
if ($$rbuf =~ $accept) { |
969 |
$data .= substr $$rbuf, 0, $+[0], ""; |
970 |
$cb->($self, $data); |
971 |
return 1; |
972 |
} |
973 |
|
974 |
# reject |
975 |
if ($reject && $$rbuf =~ $reject) { |
976 |
$self->_error (&Errno::EBADMSG); |
977 |
} |
978 |
|
979 |
# skip |
980 |
if ($skip && $$rbuf =~ $skip) { |
981 |
$data .= substr $$rbuf, 0, $+[0], ""; |
982 |
} |
983 |
|
984 |
() |
985 |
} |
986 |
}; |
987 |
|
988 |
=item netstring => $cb->($handle, $string) |
989 |
|
990 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
991 |
|
992 |
Throws an error with C<$!> set to EBADMSG on format violations. |
993 |
|
994 |
=cut |
995 |
|
996 |
register_read_type netstring => sub { |
997 |
my ($self, $cb) = @_; |
998 |
|
999 |
sub { |
1000 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
1001 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
1002 |
$self->_error (&Errno::EBADMSG); |
1003 |
} |
1004 |
return; |
1005 |
} |
1006 |
|
1007 |
my $len = $1; |
1008 |
|
1009 |
$self->unshift_read (chunk => $len, sub { |
1010 |
my $string = $_[1]; |
1011 |
$_[0]->unshift_read (chunk => 1, sub { |
1012 |
if ($_[1] eq ",") { |
1013 |
$cb->($_[0], $string); |
1014 |
} else { |
1015 |
$self->_error (&Errno::EBADMSG); |
1016 |
} |
1017 |
}); |
1018 |
}); |
1019 |
|
1020 |
1 |
1021 |
} |
1022 |
}; |
1023 |
|
1024 |
=item packstring => $format, $cb->($handle, $string) |
1025 |
|
1026 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1027 |
uses the same format as a Perl C<pack> format, but must specify a single |
1028 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1029 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1030 |
|
1031 |
DNS over TCP uses a prefix of C<n>, EPP uses a prefix of C<N>. |
1032 |
|
1033 |
Example: read a block of data prefixed by its length in BER-encoded |
1034 |
format (very efficient). |
1035 |
|
1036 |
$handle->push_read (packstring => "w", sub { |
1037 |
my ($handle, $data) = @_; |
1038 |
}); |
1039 |
|
1040 |
=cut |
1041 |
|
1042 |
register_read_type packstring => sub { |
1043 |
my ($self, $cb, $format) = @_; |
1044 |
|
1045 |
sub { |
1046 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1047 |
defined (my $len = eval { unpack $format, $_[0]->{rbuf} }) |
1048 |
or return; |
1049 |
|
1050 |
# remove prefix |
1051 |
substr $_[0]->{rbuf}, 0, (length pack $format, $len), ""; |
1052 |
|
1053 |
# read rest |
1054 |
$_[0]->unshift_read (chunk => $len, $cb); |
1055 |
|
1056 |
1 |
1057 |
} |
1058 |
}; |
1059 |
|
1060 |
=item json => $cb->($handle, $hash_or_arrayref) |
1061 |
|
1062 |
Reads a JSON object or array, decodes it and passes it to the callback. |
1063 |
|
1064 |
If a C<json> object was passed to the constructor, then that will be used |
1065 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1066 |
|
1067 |
This read type uses the incremental parser available with JSON version |
1068 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1069 |
dependency on your own: this module will load the JSON module, but |
1070 |
AnyEvent does not depend on it itself. |
1071 |
|
1072 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1073 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1074 |
the C<json> write type description, above, for an actual example. |
1075 |
|
1076 |
=cut |
1077 |
|
1078 |
register_read_type json => sub { |
1079 |
my ($self, $cb) = @_; |
1080 |
|
1081 |
require JSON; |
1082 |
|
1083 |
my $data; |
1084 |
my $rbuf = \$self->{rbuf}; |
1085 |
|
1086 |
my $json = $self->{json} ||= JSON->new->utf8; |
1087 |
|
1088 |
sub { |
1089 |
my $ref = $json->incr_parse ($self->{rbuf}); |
1090 |
|
1091 |
if ($ref) { |
1092 |
$self->{rbuf} = $json->incr_text; |
1093 |
$json->incr_text = ""; |
1094 |
$cb->($self, $ref); |
1095 |
|
1096 |
1 |
1097 |
} else { |
1098 |
$self->{rbuf} = ""; |
1099 |
() |
1100 |
} |
1101 |
} |
1102 |
}; |
1103 |
|
1104 |
=item storable => $cb->($handle, $ref) |
1105 |
|
1106 |
Deserialises a L<Storable> frozen representation as written by the |
1107 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1108 |
data). |
1109 |
|
1110 |
Raises C<EBADMSG> error if the data could not be decoded. |
1111 |
|
1112 |
=cut |
1113 |
|
1114 |
register_read_type storable => sub { |
1115 |
my ($self, $cb) = @_; |
1116 |
|
1117 |
require Storable; |
1118 |
|
1119 |
sub { |
1120 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1121 |
defined (my $len = eval { unpack "w", $_[0]->{rbuf} }) |
1122 |
or return; |
1123 |
|
1124 |
# remove prefix |
1125 |
substr $_[0]->{rbuf}, 0, (length pack "w", $len), ""; |
1126 |
|
1127 |
# read rest |
1128 |
$_[0]->unshift_read (chunk => $len, sub { |
1129 |
if (my $ref = eval { Storable::thaw ($_[1]) }) { |
1130 |
$cb->($_[0], $ref); |
1131 |
} else { |
1132 |
$self->_error (&Errno::EBADMSG); |
1133 |
} |
1134 |
}); |
1135 |
} |
1136 |
}; |
1137 |
|
1138 |
=back |
1139 |
|
1140 |
=item AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args) |
1141 |
|
1142 |
This function (not method) lets you add your own types to C<push_read>. |
1143 |
|
1144 |
Whenever the given C<type> is used, C<push_read> will invoke the code |
1145 |
reference with the handle object, the callback and the remaining |
1146 |
arguments. |
1147 |
|
1148 |
The code reference is supposed to return a callback (usually a closure) |
1149 |
that works as a plain read callback (see C<< ->push_read ($cb) >>). |
1150 |
|
1151 |
It should invoke the passed callback when it is done reading (remember to |
1152 |
pass C<$handle> as first argument as all other callbacks do that). |
1153 |
|
1154 |
Note that this is a function, and all types registered this way will be |
1155 |
global, so try to use unique names. |
1156 |
|
1157 |
For examples, see the source of this module (F<perldoc -m AnyEvent::Handle>, |
1158 |
search for C<register_read_type>)). |
1159 |
|
1160 |
=item $handle->stop_read |
1161 |
|
1162 |
=item $handle->start_read |
1163 |
|
1164 |
In rare cases you actually do not want to read anything from the |
1165 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1166 |
any queued callbacks will be executed then. To start reading again, call |
1167 |
C<start_read>. |
1168 |
|
1169 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1170 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1171 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1172 |
there are any read requests in the queue. |
1173 |
|
1174 |
=cut |
1175 |
|
1176 |
sub stop_read { |
1177 |
my ($self) = @_; |
1178 |
|
1179 |
delete $self->{_rw}; |
1180 |
} |
1181 |
|
1182 |
sub start_read { |
1183 |
my ($self) = @_; |
1184 |
|
1185 |
unless ($self->{_rw} || $self->{_eof}) { |
1186 |
Scalar::Util::weaken $self; |
1187 |
|
1188 |
$self->{_rw} = AnyEvent->io (fh => $self->{fh}, poll => "r", cb => sub { |
1189 |
my $rbuf = $self->{filter_r} ? \my $buf : \$self->{rbuf}; |
1190 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size} || 8192, length $$rbuf; |
1191 |
|
1192 |
if ($len > 0) { |
1193 |
$self->{_activity} = AnyEvent->now; |
1194 |
|
1195 |
$self->{filter_r} |
1196 |
? $self->{filter_r}($self, $rbuf) |
1197 |
: $self->{_in_drain} || $self->_drain_rbuf; |
1198 |
|
1199 |
} elsif (defined $len) { |
1200 |
delete $self->{_rw}; |
1201 |
$self->{_eof} = 1; |
1202 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1203 |
|
1204 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1205 |
return $self->_error ($!, 1); |
1206 |
} |
1207 |
}); |
1208 |
} |
1209 |
} |
1210 |
|
1211 |
sub _dotls { |
1212 |
my ($self) = @_; |
1213 |
|
1214 |
my $buf; |
1215 |
|
1216 |
if (length $self->{_tls_wbuf}) { |
1217 |
while ((my $len = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1218 |
substr $self->{_tls_wbuf}, 0, $len, ""; |
1219 |
} |
1220 |
} |
1221 |
|
1222 |
if (length ($buf = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1223 |
$self->{wbuf} .= $buf; |
1224 |
$self->_drain_wbuf; |
1225 |
} |
1226 |
|
1227 |
while (defined ($buf = Net::SSLeay::read ($self->{tls}))) { |
1228 |
if (length $buf) { |
1229 |
$self->{rbuf} .= $buf; |
1230 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1231 |
} else { |
1232 |
# let's treat SSL-eof as we treat normal EOF |
1233 |
$self->{_eof} = 1; |
1234 |
$self->_shutdown; |
1235 |
return; |
1236 |
} |
1237 |
} |
1238 |
|
1239 |
my $err = Net::SSLeay::get_error ($self->{tls}, -1); |
1240 |
|
1241 |
if ($err!= Net::SSLeay::ERROR_WANT_READ ()) { |
1242 |
if ($err == Net::SSLeay::ERROR_SYSCALL ()) { |
1243 |
return $self->_error ($!, 1); |
1244 |
} elsif ($err == Net::SSLeay::ERROR_SSL ()) { |
1245 |
return $self->_error (&Errno::EIO, 1); |
1246 |
} |
1247 |
|
1248 |
# all others are fine for our purposes |
1249 |
} |
1250 |
} |
1251 |
|
1252 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1253 |
|
1254 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1255 |
object is created, you can also do that at a later time by calling |
1256 |
C<starttls>. |
1257 |
|
1258 |
The first argument is the same as the C<tls> constructor argument (either |
1259 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1260 |
|
1261 |
The second argument is the optional C<Net::SSLeay::CTX> object that is |
1262 |
used when AnyEvent::Handle has to create its own TLS connection object. |
1263 |
|
1264 |
The TLS connection object will end up in C<< $handle->{tls} >> after this |
1265 |
call and can be used or changed to your liking. Note that the handshake |
1266 |
might have already started when this function returns. |
1267 |
|
1268 |
=cut |
1269 |
|
1270 |
sub starttls { |
1271 |
my ($self, $ssl, $ctx) = @_; |
1272 |
|
1273 |
$self->stoptls; |
1274 |
|
1275 |
if ($ssl eq "accept") { |
1276 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1277 |
Net::SSLeay::set_accept_state ($ssl); |
1278 |
} elsif ($ssl eq "connect") { |
1279 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1280 |
Net::SSLeay::set_connect_state ($ssl); |
1281 |
} |
1282 |
|
1283 |
$self->{tls} = $ssl; |
1284 |
|
1285 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1286 |
# but the openssl maintainers basically said: "trust us, it just works". |
1287 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1288 |
# and mismaintained ssleay-module doesn't even offer them). |
1289 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1290 |
Net::SSLeay::CTX_set_mode ($self->{tls}, |
1291 |
(eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1292 |
| (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1293 |
|
1294 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1295 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1296 |
|
1297 |
Net::SSLeay::set_bio ($ssl, $self->{_rbio}, $self->{_wbio}); |
1298 |
|
1299 |
$self->{filter_w} = sub { |
1300 |
$_[0]{_tls_wbuf} .= ${$_[1]}; |
1301 |
&_dotls; |
1302 |
}; |
1303 |
$self->{filter_r} = sub { |
1304 |
Net::SSLeay::BIO_write ($_[0]{_rbio}, ${$_[1]}); |
1305 |
&_dotls; |
1306 |
}; |
1307 |
} |
1308 |
|
1309 |
=item $handle->stoptls |
1310 |
|
1311 |
Destroys the SSL connection, if any. Partial read or write data will be |
1312 |
lost. |
1313 |
|
1314 |
=cut |
1315 |
|
1316 |
sub stoptls { |
1317 |
my ($self) = @_; |
1318 |
|
1319 |
Net::SSLeay::free (delete $self->{tls}) if $self->{tls}; |
1320 |
|
1321 |
delete $self->{_rbio}; |
1322 |
delete $self->{_wbio}; |
1323 |
delete $self->{_tls_wbuf}; |
1324 |
delete $self->{filter_r}; |
1325 |
delete $self->{filter_w}; |
1326 |
} |
1327 |
|
1328 |
sub DESTROY { |
1329 |
my $self = shift; |
1330 |
|
1331 |
$self->stoptls; |
1332 |
|
1333 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
1334 |
|
1335 |
if ($linger && length $self->{wbuf}) { |
1336 |
my $fh = delete $self->{fh}; |
1337 |
my $wbuf = delete $self->{wbuf}; |
1338 |
|
1339 |
my @linger; |
1340 |
|
1341 |
push @linger, AnyEvent->io (fh => $fh, poll => "w", cb => sub { |
1342 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
1343 |
|
1344 |
if ($len > 0) { |
1345 |
substr $wbuf, 0, $len, ""; |
1346 |
} else { |
1347 |
@linger = (); # end |
1348 |
} |
1349 |
}); |
1350 |
push @linger, AnyEvent->timer (after => $linger, cb => sub { |
1351 |
@linger = (); |
1352 |
}); |
1353 |
} |
1354 |
} |
1355 |
|
1356 |
=item AnyEvent::Handle::TLS_CTX |
1357 |
|
1358 |
This function creates and returns the Net::SSLeay::CTX object used by |
1359 |
default for TLS mode. |
1360 |
|
1361 |
The context is created like this: |
1362 |
|
1363 |
Net::SSLeay::load_error_strings; |
1364 |
Net::SSLeay::SSLeay_add_ssl_algorithms; |
1365 |
Net::SSLeay::randomize; |
1366 |
|
1367 |
my $CTX = Net::SSLeay::CTX_new; |
1368 |
|
1369 |
Net::SSLeay::CTX_set_options $CTX, Net::SSLeay::OP_ALL |
1370 |
|
1371 |
=cut |
1372 |
|
1373 |
our $TLS_CTX; |
1374 |
|
1375 |
sub TLS_CTX() { |
1376 |
$TLS_CTX || do { |
1377 |
require Net::SSLeay; |
1378 |
|
1379 |
Net::SSLeay::load_error_strings (); |
1380 |
Net::SSLeay::SSLeay_add_ssl_algorithms (); |
1381 |
Net::SSLeay::randomize (); |
1382 |
|
1383 |
$TLS_CTX = Net::SSLeay::CTX_new (); |
1384 |
|
1385 |
Net::SSLeay::CTX_set_options ($TLS_CTX, Net::SSLeay::OP_ALL ()); |
1386 |
|
1387 |
$TLS_CTX |
1388 |
} |
1389 |
} |
1390 |
|
1391 |
=back |
1392 |
|
1393 |
=head1 SUBCLASSING AnyEvent::Handle |
1394 |
|
1395 |
In many cases, you might want to subclass AnyEvent::Handle. |
1396 |
|
1397 |
To make this easier, a given version of AnyEvent::Handle uses these |
1398 |
conventions: |
1399 |
|
1400 |
=over 4 |
1401 |
|
1402 |
=item * all constructor arguments become object members. |
1403 |
|
1404 |
At least initially, when you pass a C<tls>-argument to the constructor it |
1405 |
will end up in C<< $handle->{tls} >>. Those members might be changes or |
1406 |
mutated later on (for example C<tls> will hold the TLS connection object). |
1407 |
|
1408 |
=item * other object member names are prefixed with an C<_>. |
1409 |
|
1410 |
All object members not explicitly documented (internal use) are prefixed |
1411 |
with an underscore character, so the remaining non-C<_>-namespace is free |
1412 |
for use for subclasses. |
1413 |
|
1414 |
=item * all members not documented here and not prefixed with an underscore |
1415 |
are free to use in subclasses. |
1416 |
|
1417 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
1418 |
member variables, but thats just life, at least it is documented. |
1419 |
|
1420 |
=back |
1421 |
|
1422 |
=head1 AUTHOR |
1423 |
|
1424 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
1425 |
|
1426 |
=cut |
1427 |
|
1428 |
1; # End of AnyEvent::Handle |