1 |
package AnyEvent::Handle; |
2 |
|
3 |
no warnings; |
4 |
use strict qw(subs vars); |
5 |
|
6 |
use AnyEvent (); |
7 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
8 |
use Scalar::Util (); |
9 |
use Carp (); |
10 |
use Fcntl (); |
11 |
use Errno qw(EAGAIN EINTR); |
12 |
|
13 |
=head1 NAME |
14 |
|
15 |
AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent |
16 |
|
17 |
=cut |
18 |
|
19 |
our $VERSION = 4.45; |
20 |
|
21 |
=head1 SYNOPSIS |
22 |
|
23 |
use AnyEvent; |
24 |
use AnyEvent::Handle; |
25 |
|
26 |
my $cv = AnyEvent->condvar; |
27 |
|
28 |
my $handle = |
29 |
AnyEvent::Handle->new ( |
30 |
fh => \*STDIN, |
31 |
on_eof => sub { |
32 |
$cv->send; |
33 |
}, |
34 |
); |
35 |
|
36 |
# send some request line |
37 |
$handle->push_write ("getinfo\015\012"); |
38 |
|
39 |
# read the response line |
40 |
$handle->push_read (line => sub { |
41 |
my ($handle, $line) = @_; |
42 |
warn "read line <$line>\n"; |
43 |
$cv->send; |
44 |
}); |
45 |
|
46 |
$cv->recv; |
47 |
|
48 |
=head1 DESCRIPTION |
49 |
|
50 |
This module is a helper module to make it easier to do event-based I/O on |
51 |
filehandles. For utility functions for doing non-blocking connects and accepts |
52 |
on sockets see L<AnyEvent::Util>. |
53 |
|
54 |
The L<AnyEvent::Intro> tutorial contains some well-documented |
55 |
AnyEvent::Handle examples. |
56 |
|
57 |
In the following, when the documentation refers to of "bytes" then this |
58 |
means characters. As sysread and syswrite are used for all I/O, their |
59 |
treatment of characters applies to this module as well. |
60 |
|
61 |
All callbacks will be invoked with the handle object as their first |
62 |
argument. |
63 |
|
64 |
=head1 METHODS |
65 |
|
66 |
=over 4 |
67 |
|
68 |
=item $handle = B<new> AnyEvent::TLS fh => $filehandle, key => value... |
69 |
|
70 |
The constructor supports these arguments (all as C<< key => value >> pairs). |
71 |
|
72 |
=over 4 |
73 |
|
74 |
=item fh => $filehandle [MANDATORY] |
75 |
|
76 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
77 |
|
78 |
NOTE: The filehandle will be set to non-blocking mode (using |
79 |
C<AnyEvent::Util::fh_nonblocking>) by the constructor and needs to stay in |
80 |
that mode. |
81 |
|
82 |
=item on_eof => $cb->($handle) |
83 |
|
84 |
Set the callback to be called when an end-of-file condition is detected, |
85 |
i.e. in the case of a socket, when the other side has closed the |
86 |
connection cleanly. |
87 |
|
88 |
For sockets, this just means that the other side has stopped sending data, |
89 |
you can still try to write data, and, in fact, one can return from the EOF |
90 |
callback and continue writing data, as only the read part has been shut |
91 |
down. |
92 |
|
93 |
While not mandatory, it is I<highly> recommended to set an EOF callback, |
94 |
otherwise you might end up with a closed socket while you are still |
95 |
waiting for data. |
96 |
|
97 |
If an EOF condition has been detected but no C<on_eof> callback has been |
98 |
set, then a fatal error will be raised with C<$!> set to <0>. |
99 |
|
100 |
=item on_error => $cb->($handle, $fatal) |
101 |
|
102 |
This is the error callback, which is called when, well, some error |
103 |
occured, such as not being able to resolve the hostname, failure to |
104 |
connect or a read error. |
105 |
|
106 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
107 |
fatal errors the handle object will be shut down and will not be usable |
108 |
(but you are free to look at the current C<< ->rbuf >>). Examples of fatal |
109 |
errors are an EOF condition with active (but unsatisifable) read watchers |
110 |
(C<EPIPE>) or I/O errors. |
111 |
|
112 |
Non-fatal errors can be retried by simply returning, but it is recommended |
113 |
to simply ignore this parameter and instead abondon the handle object |
114 |
when this callback is invoked. Examples of non-fatal errors are timeouts |
115 |
C<ETIMEDOUT>) or badly-formatted data (C<EBADMSG>). |
116 |
|
117 |
On callback entrance, the value of C<$!> contains the operating system |
118 |
error (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT> or C<EBADMSG>). |
119 |
|
120 |
While not mandatory, it is I<highly> recommended to set this callback, as |
121 |
you will not be notified of errors otherwise. The default simply calls |
122 |
C<croak>. |
123 |
|
124 |
=item on_read => $cb->($handle) |
125 |
|
126 |
This sets the default read callback, which is called when data arrives |
127 |
and no read request is in the queue (unlike read queue callbacks, this |
128 |
callback will only be called when at least one octet of data is in the |
129 |
read buffer). |
130 |
|
131 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
132 |
method or access the C<$handle->{rbuf}> member directly. Note that you |
133 |
must not enlarge or modify the read buffer, you can only remove data at |
134 |
the beginning from it. |
135 |
|
136 |
When an EOF condition is detected then AnyEvent::Handle will first try to |
137 |
feed all the remaining data to the queued callbacks and C<on_read> before |
138 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
139 |
error will be raised (with C<$!> set to C<EPIPE>). |
140 |
|
141 |
=item on_drain => $cb->($handle) |
142 |
|
143 |
This sets the callback that is called when the write buffer becomes empty |
144 |
(or when the callback is set and the buffer is empty already). |
145 |
|
146 |
To append to the write buffer, use the C<< ->push_write >> method. |
147 |
|
148 |
This callback is useful when you don't want to put all of your write data |
149 |
into the queue at once, for example, when you want to write the contents |
150 |
of some file to the socket you might not want to read the whole file into |
151 |
memory and push it into the queue, but instead only read more data from |
152 |
the file when the write queue becomes empty. |
153 |
|
154 |
=item timeout => $fractional_seconds |
155 |
|
156 |
If non-zero, then this enables an "inactivity" timeout: whenever this many |
157 |
seconds pass without a successful read or write on the underlying file |
158 |
handle, the C<on_timeout> callback will be invoked (and if that one is |
159 |
missing, a non-fatal C<ETIMEDOUT> error will be raised). |
160 |
|
161 |
Note that timeout processing is also active when you currently do not have |
162 |
any outstanding read or write requests: If you plan to keep the connection |
163 |
idle then you should disable the timout temporarily or ignore the timeout |
164 |
in the C<on_timeout> callback, in which case AnyEvent::Handle will simply |
165 |
restart the timeout. |
166 |
|
167 |
Zero (the default) disables this timeout. |
168 |
|
169 |
=item on_timeout => $cb->($handle) |
170 |
|
171 |
Called whenever the inactivity timeout passes. If you return from this |
172 |
callback, then the timeout will be reset as if some activity had happened, |
173 |
so this condition is not fatal in any way. |
174 |
|
175 |
=item rbuf_max => <bytes> |
176 |
|
177 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
178 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
179 |
avoid some forms of denial-of-service attacks. |
180 |
|
181 |
For example, a server accepting connections from untrusted sources should |
182 |
be configured to accept only so-and-so much data that it cannot act on |
183 |
(for example, when expecting a line, an attacker could send an unlimited |
184 |
amount of data without a callback ever being called as long as the line |
185 |
isn't finished). |
186 |
|
187 |
=item autocork => <boolean> |
188 |
|
189 |
When disabled (the default), then C<push_write> will try to immediately |
190 |
write the data to the handle, if possible. This avoids having to register |
191 |
a write watcher and wait for the next event loop iteration, but can |
192 |
be inefficient if you write multiple small chunks (on the wire, this |
193 |
disadvantage is usually avoided by your kernel's nagle algorithm, see |
194 |
C<no_delay>, but this option can save costly syscalls). |
195 |
|
196 |
When enabled, then writes will always be queued till the next event loop |
197 |
iteration. This is efficient when you do many small writes per iteration, |
198 |
but less efficient when you do a single write only per iteration (or when |
199 |
the write buffer often is full). It also increases write latency. |
200 |
|
201 |
=item no_delay => <boolean> |
202 |
|
203 |
When doing small writes on sockets, your operating system kernel might |
204 |
wait a bit for more data before actually sending it out. This is called |
205 |
the Nagle algorithm, and usually it is beneficial. |
206 |
|
207 |
In some situations you want as low a delay as possible, which can be |
208 |
accomplishd by setting this option to a true value. |
209 |
|
210 |
The default is your opertaing system's default behaviour (most likely |
211 |
enabled), this option explicitly enables or disables it, if possible. |
212 |
|
213 |
=item read_size => <bytes> |
214 |
|
215 |
The default read block size (the amount of bytes this module will |
216 |
try to read during each loop iteration, which affects memory |
217 |
requirements). Default: C<8192>. |
218 |
|
219 |
=item low_water_mark => <bytes> |
220 |
|
221 |
Sets the amount of bytes (default: C<0>) that make up an "empty" write |
222 |
buffer: If the write reaches this size or gets even samller it is |
223 |
considered empty. |
224 |
|
225 |
Sometimes it can be beneficial (for performance reasons) to add data to |
226 |
the write buffer before it is fully drained, but this is a rare case, as |
227 |
the operating system kernel usually buffers data as well, so the default |
228 |
is good in almost all cases. |
229 |
|
230 |
=item linger => <seconds> |
231 |
|
232 |
If non-zero (default: C<3600>), then the destructor of the |
233 |
AnyEvent::Handle object will check whether there is still outstanding |
234 |
write data and will install a watcher that will write this data to the |
235 |
socket. No errors will be reported (this mostly matches how the operating |
236 |
system treats outstanding data at socket close time). |
237 |
|
238 |
This will not work for partial TLS data that could not be encoded |
239 |
yet. This data will be lost. Calling the C<stoptls> method in time might |
240 |
help. |
241 |
|
242 |
=item common_name => $string |
243 |
|
244 |
The common name used by some verification methods (most notably SSL/TLS) |
245 |
associated with this connection. Usually this is the remote hostname used |
246 |
to connect, but can be almost anything. |
247 |
|
248 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
249 |
|
250 |
When this parameter is given, it enables TLS (SSL) mode, that means |
251 |
AnyEvent will start a TLS handshake as soon as the conenction has been |
252 |
established and will transparently encrypt/decrypt data afterwards. |
253 |
|
254 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
255 |
automatically when you try to create a TLS handle): this module doesn't |
256 |
have a dependency on that module, so if your module requires it, you have |
257 |
to add the dependency yourself. |
258 |
|
259 |
Unlike TCP, TLS has a server and client side: for the TLS server side, use |
260 |
C<accept>, and for the TLS client side of a connection, use C<connect> |
261 |
mode. |
262 |
|
263 |
You can also provide your own TLS connection object, but you have |
264 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
265 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
266 |
AnyEvent::Handle. Also, this module will take ownership of this connection |
267 |
object. |
268 |
|
269 |
At some future point, AnyEvent::Handle might switch to another TLS |
270 |
implementation, then the option to use your own session object will go |
271 |
away. |
272 |
|
273 |
B<IMPORTANT:> since Net::SSLeay "objects" are really only integers, |
274 |
passing in the wrong integer will lead to certain crash. This most often |
275 |
happens when one uses a stylish C<< tls => 1 >> and is surprised about the |
276 |
segmentation fault. |
277 |
|
278 |
See the C<< ->starttls >> method for when need to start TLS negotiation later. |
279 |
|
280 |
=item tls_ctx => $anyevent_tls |
281 |
|
282 |
Use the given C<AnyEvent::TLS> object to create the new TLS connection |
283 |
(unless a connection object was specified directly). If this parameter is |
284 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
285 |
|
286 |
Instead of an object, you can also specify a hash reference with C<< key |
287 |
=> value >> pairs. Those will be passed to L<AnyEvent::TLS> to create a |
288 |
new TLS context object. |
289 |
|
290 |
=item json => JSON or JSON::XS object |
291 |
|
292 |
This is the json coder object used by the C<json> read and write types. |
293 |
|
294 |
If you don't supply it, then AnyEvent::Handle will create and use a |
295 |
suitable one (on demand), which will write and expect UTF-8 encoded JSON |
296 |
texts. |
297 |
|
298 |
Note that you are responsible to depend on the JSON module if you want to |
299 |
use this functionality, as AnyEvent does not have a dependency itself. |
300 |
|
301 |
=back |
302 |
|
303 |
=cut |
304 |
|
305 |
sub new { |
306 |
my $class = shift; |
307 |
my $self = bless { @_ }, $class; |
308 |
|
309 |
$self->{fh} or Carp::croak "mandatory argument fh is missing"; |
310 |
|
311 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
312 |
|
313 |
$self->{_activity} = AnyEvent->now; |
314 |
$self->_timeout; |
315 |
|
316 |
$self->no_delay (delete $self->{no_delay}) if exists $self->{no_delay}; |
317 |
|
318 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}) |
319 |
if $self->{tls}; |
320 |
|
321 |
$self->on_drain (delete $self->{on_drain}) if exists $self->{on_drain}; |
322 |
|
323 |
$self->start_read |
324 |
if $self->{on_read}; |
325 |
|
326 |
$self->{fh} && $self |
327 |
} |
328 |
|
329 |
sub _shutdown { |
330 |
my ($self) = @_; |
331 |
|
332 |
delete @$self{qw(_tw _rw _ww fh rbuf wbuf on_read _queue)}; |
333 |
$self->{_eof} = 1; # tell starttls et. al to stop trying |
334 |
|
335 |
&_freetls; |
336 |
} |
337 |
|
338 |
sub _error { |
339 |
my ($self, $errno, $fatal) = @_; |
340 |
|
341 |
$self->_shutdown |
342 |
if $fatal; |
343 |
|
344 |
$! = $errno; |
345 |
|
346 |
if ($self->{on_error}) { |
347 |
$self->{on_error}($self, $fatal); |
348 |
} elsif ($self->{fh}) { |
349 |
Carp::croak "AnyEvent::Handle uncaught error: $!"; |
350 |
} |
351 |
} |
352 |
|
353 |
=item $fh = $handle->fh |
354 |
|
355 |
This method returns the file handle used to create the L<AnyEvent::Handle> object. |
356 |
|
357 |
=cut |
358 |
|
359 |
sub fh { $_[0]{fh} } |
360 |
|
361 |
=item $handle->on_error ($cb) |
362 |
|
363 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
364 |
|
365 |
=cut |
366 |
|
367 |
sub on_error { |
368 |
$_[0]{on_error} = $_[1]; |
369 |
} |
370 |
|
371 |
=item $handle->on_eof ($cb) |
372 |
|
373 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
374 |
|
375 |
=cut |
376 |
|
377 |
sub on_eof { |
378 |
$_[0]{on_eof} = $_[1]; |
379 |
} |
380 |
|
381 |
=item $handle->on_timeout ($cb) |
382 |
|
383 |
Replace the current C<on_timeout> callback, or disables the callback (but |
384 |
not the timeout) if C<$cb> = C<undef>. See the C<timeout> constructor |
385 |
argument and method. |
386 |
|
387 |
=cut |
388 |
|
389 |
sub on_timeout { |
390 |
$_[0]{on_timeout} = $_[1]; |
391 |
} |
392 |
|
393 |
=item $handle->autocork ($boolean) |
394 |
|
395 |
Enables or disables the current autocork behaviour (see C<autocork> |
396 |
constructor argument). Changes will only take effect on the next write. |
397 |
|
398 |
=cut |
399 |
|
400 |
sub autocork { |
401 |
$_[0]{autocork} = $_[1]; |
402 |
} |
403 |
|
404 |
=item $handle->no_delay ($boolean) |
405 |
|
406 |
Enables or disables the C<no_delay> setting (see constructor argument of |
407 |
the same name for details). |
408 |
|
409 |
=cut |
410 |
|
411 |
sub no_delay { |
412 |
$_[0]{no_delay} = $_[1]; |
413 |
|
414 |
eval { |
415 |
local $SIG{__DIE__}; |
416 |
setsockopt $_[0]{fh}, &Socket::IPPROTO_TCP, &Socket::TCP_NODELAY, int $_[1]; |
417 |
}; |
418 |
} |
419 |
|
420 |
############################################################################# |
421 |
|
422 |
=item $handle->timeout ($seconds) |
423 |
|
424 |
Configures (or disables) the inactivity timeout. |
425 |
|
426 |
=cut |
427 |
|
428 |
sub timeout { |
429 |
my ($self, $timeout) = @_; |
430 |
|
431 |
$self->{timeout} = $timeout; |
432 |
$self->_timeout; |
433 |
} |
434 |
|
435 |
# reset the timeout watcher, as neccessary |
436 |
# also check for time-outs |
437 |
sub _timeout { |
438 |
my ($self) = @_; |
439 |
|
440 |
if ($self->{timeout}) { |
441 |
my $NOW = AnyEvent->now; |
442 |
|
443 |
# when would the timeout trigger? |
444 |
my $after = $self->{_activity} + $self->{timeout} - $NOW; |
445 |
|
446 |
# now or in the past already? |
447 |
if ($after <= 0) { |
448 |
$self->{_activity} = $NOW; |
449 |
|
450 |
if ($self->{on_timeout}) { |
451 |
$self->{on_timeout}($self); |
452 |
} else { |
453 |
$self->_error (&Errno::ETIMEDOUT); |
454 |
} |
455 |
|
456 |
# callback could have changed timeout value, optimise |
457 |
return unless $self->{timeout}; |
458 |
|
459 |
# calculate new after |
460 |
$after = $self->{timeout}; |
461 |
} |
462 |
|
463 |
Scalar::Util::weaken $self; |
464 |
return unless $self; # ->error could have destroyed $self |
465 |
|
466 |
$self->{_tw} ||= AnyEvent->timer (after => $after, cb => sub { |
467 |
delete $self->{_tw}; |
468 |
$self->_timeout; |
469 |
}); |
470 |
} else { |
471 |
delete $self->{_tw}; |
472 |
} |
473 |
} |
474 |
|
475 |
############################################################################# |
476 |
|
477 |
=back |
478 |
|
479 |
=head2 WRITE QUEUE |
480 |
|
481 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
482 |
for reading. |
483 |
|
484 |
The write queue is very simple: you can add data to its end, and |
485 |
AnyEvent::Handle will automatically try to get rid of it for you. |
486 |
|
487 |
When data could be written and the write buffer is shorter then the low |
488 |
water mark, the C<on_drain> callback will be invoked. |
489 |
|
490 |
=over 4 |
491 |
|
492 |
=item $handle->on_drain ($cb) |
493 |
|
494 |
Sets the C<on_drain> callback or clears it (see the description of |
495 |
C<on_drain> in the constructor). |
496 |
|
497 |
=cut |
498 |
|
499 |
sub on_drain { |
500 |
my ($self, $cb) = @_; |
501 |
|
502 |
$self->{on_drain} = $cb; |
503 |
|
504 |
$cb->($self) |
505 |
if $cb && $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}); |
506 |
} |
507 |
|
508 |
=item $handle->push_write ($data) |
509 |
|
510 |
Queues the given scalar to be written. You can push as much data as you |
511 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
512 |
buffers it independently of the kernel. |
513 |
|
514 |
=cut |
515 |
|
516 |
sub _drain_wbuf { |
517 |
my ($self) = @_; |
518 |
|
519 |
if (!$self->{_ww} && length $self->{wbuf}) { |
520 |
|
521 |
Scalar::Util::weaken $self; |
522 |
|
523 |
my $cb = sub { |
524 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
525 |
|
526 |
if ($len >= 0) { |
527 |
substr $self->{wbuf}, 0, $len, ""; |
528 |
|
529 |
$self->{_activity} = AnyEvent->now; |
530 |
|
531 |
$self->{on_drain}($self) |
532 |
if $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}) |
533 |
&& $self->{on_drain}; |
534 |
|
535 |
delete $self->{_ww} unless length $self->{wbuf}; |
536 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
537 |
$self->_error ($!, 1); |
538 |
} |
539 |
}; |
540 |
|
541 |
# try to write data immediately |
542 |
$cb->() unless $self->{autocork}; |
543 |
|
544 |
# if still data left in wbuf, we need to poll |
545 |
$self->{_ww} = AnyEvent->io (fh => $self->{fh}, poll => "w", cb => $cb) |
546 |
if length $self->{wbuf}; |
547 |
}; |
548 |
} |
549 |
|
550 |
our %WH; |
551 |
|
552 |
sub register_write_type($$) { |
553 |
$WH{$_[0]} = $_[1]; |
554 |
} |
555 |
|
556 |
sub push_write { |
557 |
my $self = shift; |
558 |
|
559 |
if (@_ > 1) { |
560 |
my $type = shift; |
561 |
|
562 |
@_ = ($WH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_write") |
563 |
->($self, @_); |
564 |
} |
565 |
|
566 |
if ($self->{tls}) { |
567 |
$self->{_tls_wbuf} .= $_[0]; |
568 |
|
569 |
&_dotls ($self); |
570 |
} else { |
571 |
$self->{wbuf} .= $_[0]; |
572 |
$self->_drain_wbuf; |
573 |
} |
574 |
} |
575 |
|
576 |
=item $handle->push_write (type => @args) |
577 |
|
578 |
Instead of formatting your data yourself, you can also let this module do |
579 |
the job by specifying a type and type-specific arguments. |
580 |
|
581 |
Predefined types are (if you have ideas for additional types, feel free to |
582 |
drop by and tell us): |
583 |
|
584 |
=over 4 |
585 |
|
586 |
=item netstring => $string |
587 |
|
588 |
Formats the given value as netstring |
589 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
590 |
|
591 |
=cut |
592 |
|
593 |
register_write_type netstring => sub { |
594 |
my ($self, $string) = @_; |
595 |
|
596 |
(length $string) . ":$string," |
597 |
}; |
598 |
|
599 |
=item packstring => $format, $data |
600 |
|
601 |
An octet string prefixed with an encoded length. The encoding C<$format> |
602 |
uses the same format as a Perl C<pack> format, but must specify a single |
603 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
604 |
optional C<!>, C<< < >> or C<< > >> modifier). |
605 |
|
606 |
=cut |
607 |
|
608 |
register_write_type packstring => sub { |
609 |
my ($self, $format, $string) = @_; |
610 |
|
611 |
pack "$format/a*", $string |
612 |
}; |
613 |
|
614 |
=item json => $array_or_hashref |
615 |
|
616 |
Encodes the given hash or array reference into a JSON object. Unless you |
617 |
provide your own JSON object, this means it will be encoded to JSON text |
618 |
in UTF-8. |
619 |
|
620 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
621 |
one end of a handle and read them at the other end without using any |
622 |
additional framing. |
623 |
|
624 |
The generated JSON text is guaranteed not to contain any newlines: While |
625 |
this module doesn't need delimiters after or between JSON texts to be |
626 |
able to read them, many other languages depend on that. |
627 |
|
628 |
A simple RPC protocol that interoperates easily with others is to send |
629 |
JSON arrays (or objects, although arrays are usually the better choice as |
630 |
they mimic how function argument passing works) and a newline after each |
631 |
JSON text: |
632 |
|
633 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
634 |
$handle->push_write ("\012"); |
635 |
|
636 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
637 |
rely on the fact that the newline will be skipped as leading whitespace: |
638 |
|
639 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
640 |
|
641 |
Other languages could read single lines terminated by a newline and pass |
642 |
this line into their JSON decoder of choice. |
643 |
|
644 |
=cut |
645 |
|
646 |
register_write_type json => sub { |
647 |
my ($self, $ref) = @_; |
648 |
|
649 |
require JSON; |
650 |
|
651 |
$self->{json} ? $self->{json}->encode ($ref) |
652 |
: JSON::encode_json ($ref) |
653 |
}; |
654 |
|
655 |
=item storable => $reference |
656 |
|
657 |
Freezes the given reference using L<Storable> and writes it to the |
658 |
handle. Uses the C<nfreeze> format. |
659 |
|
660 |
=cut |
661 |
|
662 |
register_write_type storable => sub { |
663 |
my ($self, $ref) = @_; |
664 |
|
665 |
require Storable; |
666 |
|
667 |
pack "w/a*", Storable::nfreeze ($ref) |
668 |
}; |
669 |
|
670 |
=back |
671 |
|
672 |
=item AnyEvent::Handle::register_write_type type => $coderef->($handle, @args) |
673 |
|
674 |
This function (not method) lets you add your own types to C<push_write>. |
675 |
Whenever the given C<type> is used, C<push_write> will invoke the code |
676 |
reference with the handle object and the remaining arguments. |
677 |
|
678 |
The code reference is supposed to return a single octet string that will |
679 |
be appended to the write buffer. |
680 |
|
681 |
Note that this is a function, and all types registered this way will be |
682 |
global, so try to use unique names. |
683 |
|
684 |
=cut |
685 |
|
686 |
############################################################################# |
687 |
|
688 |
=back |
689 |
|
690 |
=head2 READ QUEUE |
691 |
|
692 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
693 |
for reading. |
694 |
|
695 |
The read queue is more complex than the write queue. It can be used in two |
696 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
697 |
a queue. |
698 |
|
699 |
In the simple case, you just install an C<on_read> callback and whenever |
700 |
new data arrives, it will be called. You can then remove some data (if |
701 |
enough is there) from the read buffer (C<< $handle->rbuf >>). Or you cna |
702 |
leave the data there if you want to accumulate more (e.g. when only a |
703 |
partial message has been received so far). |
704 |
|
705 |
In the more complex case, you want to queue multiple callbacks. In this |
706 |
case, AnyEvent::Handle will call the first queued callback each time new |
707 |
data arrives (also the first time it is queued) and removes it when it has |
708 |
done its job (see C<push_read>, below). |
709 |
|
710 |
This way you can, for example, push three line-reads, followed by reading |
711 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
712 |
|
713 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
714 |
the specified number of bytes which give an XML datagram. |
715 |
|
716 |
# in the default state, expect some header bytes |
717 |
$handle->on_read (sub { |
718 |
# some data is here, now queue the length-header-read (4 octets) |
719 |
shift->unshift_read (chunk => 4, sub { |
720 |
# header arrived, decode |
721 |
my $len = unpack "N", $_[1]; |
722 |
|
723 |
# now read the payload |
724 |
shift->unshift_read (chunk => $len, sub { |
725 |
my $xml = $_[1]; |
726 |
# handle xml |
727 |
}); |
728 |
}); |
729 |
}); |
730 |
|
731 |
Example 2: Implement a client for a protocol that replies either with "OK" |
732 |
and another line or "ERROR" for the first request that is sent, and 64 |
733 |
bytes for the second request. Due to the availability of a queue, we can |
734 |
just pipeline sending both requests and manipulate the queue as necessary |
735 |
in the callbacks. |
736 |
|
737 |
When the first callback is called and sees an "OK" response, it will |
738 |
C<unshift> another line-read. This line-read will be queued I<before> the |
739 |
64-byte chunk callback. |
740 |
|
741 |
# request one, returns either "OK + extra line" or "ERROR" |
742 |
$handle->push_write ("request 1\015\012"); |
743 |
|
744 |
# we expect "ERROR" or "OK" as response, so push a line read |
745 |
$handle->push_read (line => sub { |
746 |
# if we got an "OK", we have to _prepend_ another line, |
747 |
# so it will be read before the second request reads its 64 bytes |
748 |
# which are already in the queue when this callback is called |
749 |
# we don't do this in case we got an error |
750 |
if ($_[1] eq "OK") { |
751 |
$_[0]->unshift_read (line => sub { |
752 |
my $response = $_[1]; |
753 |
... |
754 |
}); |
755 |
} |
756 |
}); |
757 |
|
758 |
# request two, simply returns 64 octets |
759 |
$handle->push_write ("request 2\015\012"); |
760 |
|
761 |
# simply read 64 bytes, always |
762 |
$handle->push_read (chunk => 64, sub { |
763 |
my $response = $_[1]; |
764 |
... |
765 |
}); |
766 |
|
767 |
=over 4 |
768 |
|
769 |
=cut |
770 |
|
771 |
sub _drain_rbuf { |
772 |
my ($self) = @_; |
773 |
|
774 |
local $self->{_in_drain} = 1; |
775 |
|
776 |
if ( |
777 |
defined $self->{rbuf_max} |
778 |
&& $self->{rbuf_max} < length $self->{rbuf} |
779 |
) { |
780 |
$self->_error (&Errno::ENOSPC, 1), return; |
781 |
} |
782 |
|
783 |
while () { |
784 |
# we need to use a separate tls read buffer, as we must not receive data while |
785 |
# we are draining the buffer, and this can only happen with TLS. |
786 |
$self->{rbuf} .= delete $self->{_tls_rbuf} if exists $self->{_tls_rbuf}; |
787 |
|
788 |
my $len = length $self->{rbuf}; |
789 |
|
790 |
if (my $cb = shift @{ $self->{_queue} }) { |
791 |
unless ($cb->($self)) { |
792 |
if ($self->{_eof}) { |
793 |
# no progress can be made (not enough data and no data forthcoming) |
794 |
$self->_error (&Errno::EPIPE, 1), return; |
795 |
} |
796 |
|
797 |
unshift @{ $self->{_queue} }, $cb; |
798 |
last; |
799 |
} |
800 |
} elsif ($self->{on_read}) { |
801 |
last unless $len; |
802 |
|
803 |
$self->{on_read}($self); |
804 |
|
805 |
if ( |
806 |
$len == length $self->{rbuf} # if no data has been consumed |
807 |
&& !@{ $self->{_queue} } # and the queue is still empty |
808 |
&& $self->{on_read} # but we still have on_read |
809 |
) { |
810 |
# no further data will arrive |
811 |
# so no progress can be made |
812 |
$self->_error (&Errno::EPIPE, 1), return |
813 |
if $self->{_eof}; |
814 |
|
815 |
last; # more data might arrive |
816 |
} |
817 |
} else { |
818 |
# read side becomes idle |
819 |
delete $self->{_rw} unless $self->{tls}; |
820 |
last; |
821 |
} |
822 |
} |
823 |
|
824 |
if ($self->{_eof}) { |
825 |
if ($self->{on_eof}) { |
826 |
$self->{on_eof}($self) |
827 |
} else { |
828 |
$self->_error (0, 1); |
829 |
} |
830 |
} |
831 |
|
832 |
# may need to restart read watcher |
833 |
unless ($self->{_rw}) { |
834 |
$self->start_read |
835 |
if $self->{on_read} || @{ $self->{_queue} }; |
836 |
} |
837 |
} |
838 |
|
839 |
=item $handle->on_read ($cb) |
840 |
|
841 |
This replaces the currently set C<on_read> callback, or clears it (when |
842 |
the new callback is C<undef>). See the description of C<on_read> in the |
843 |
constructor. |
844 |
|
845 |
=cut |
846 |
|
847 |
sub on_read { |
848 |
my ($self, $cb) = @_; |
849 |
|
850 |
$self->{on_read} = $cb; |
851 |
$self->_drain_rbuf if $cb && !$self->{_in_drain}; |
852 |
} |
853 |
|
854 |
=item $handle->rbuf |
855 |
|
856 |
Returns the read buffer (as a modifiable lvalue). |
857 |
|
858 |
You can access the read buffer directly as the C<< ->{rbuf} >> |
859 |
member, if you want. However, the only operation allowed on the |
860 |
read buffer (apart from looking at it) is removing data from its |
861 |
beginning. Otherwise modifying or appending to it is not allowed and will |
862 |
lead to hard-to-track-down bugs. |
863 |
|
864 |
NOTE: The read buffer should only be used or modified if the C<on_read>, |
865 |
C<push_read> or C<unshift_read> methods are used. The other read methods |
866 |
automatically manage the read buffer. |
867 |
|
868 |
=cut |
869 |
|
870 |
sub rbuf : lvalue { |
871 |
$_[0]{rbuf} |
872 |
} |
873 |
|
874 |
=item $handle->push_read ($cb) |
875 |
|
876 |
=item $handle->unshift_read ($cb) |
877 |
|
878 |
Append the given callback to the end of the queue (C<push_read>) or |
879 |
prepend it (C<unshift_read>). |
880 |
|
881 |
The callback is called each time some additional read data arrives. |
882 |
|
883 |
It must check whether enough data is in the read buffer already. |
884 |
|
885 |
If not enough data is available, it must return the empty list or a false |
886 |
value, in which case it will be called repeatedly until enough data is |
887 |
available (or an error condition is detected). |
888 |
|
889 |
If enough data was available, then the callback must remove all data it is |
890 |
interested in (which can be none at all) and return a true value. After returning |
891 |
true, it will be removed from the queue. |
892 |
|
893 |
=cut |
894 |
|
895 |
our %RH; |
896 |
|
897 |
sub register_read_type($$) { |
898 |
$RH{$_[0]} = $_[1]; |
899 |
} |
900 |
|
901 |
sub push_read { |
902 |
my $self = shift; |
903 |
my $cb = pop; |
904 |
|
905 |
if (@_) { |
906 |
my $type = shift; |
907 |
|
908 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_read") |
909 |
->($self, $cb, @_); |
910 |
} |
911 |
|
912 |
push @{ $self->{_queue} }, $cb; |
913 |
$self->_drain_rbuf unless $self->{_in_drain}; |
914 |
} |
915 |
|
916 |
sub unshift_read { |
917 |
my $self = shift; |
918 |
my $cb = pop; |
919 |
|
920 |
if (@_) { |
921 |
my $type = shift; |
922 |
|
923 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::unshift_read") |
924 |
->($self, $cb, @_); |
925 |
} |
926 |
|
927 |
|
928 |
unshift @{ $self->{_queue} }, $cb; |
929 |
$self->_drain_rbuf unless $self->{_in_drain}; |
930 |
} |
931 |
|
932 |
=item $handle->push_read (type => @args, $cb) |
933 |
|
934 |
=item $handle->unshift_read (type => @args, $cb) |
935 |
|
936 |
Instead of providing a callback that parses the data itself you can chose |
937 |
between a number of predefined parsing formats, for chunks of data, lines |
938 |
etc. |
939 |
|
940 |
Predefined types are (if you have ideas for additional types, feel free to |
941 |
drop by and tell us): |
942 |
|
943 |
=over 4 |
944 |
|
945 |
=item chunk => $octets, $cb->($handle, $data) |
946 |
|
947 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
948 |
data read to the callback. The callback will never be called with less |
949 |
data. |
950 |
|
951 |
Example: read 2 bytes. |
952 |
|
953 |
$handle->push_read (chunk => 2, sub { |
954 |
warn "yay ", unpack "H*", $_[1]; |
955 |
}); |
956 |
|
957 |
=cut |
958 |
|
959 |
register_read_type chunk => sub { |
960 |
my ($self, $cb, $len) = @_; |
961 |
|
962 |
sub { |
963 |
$len <= length $_[0]{rbuf} or return; |
964 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
965 |
1 |
966 |
} |
967 |
}; |
968 |
|
969 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
970 |
|
971 |
The callback will be called only once a full line (including the end of |
972 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
973 |
marker) will be passed to the callback as second argument (C<$line>), and |
974 |
the end of line marker as the third argument (C<$eol>). |
975 |
|
976 |
The end of line marker, C<$eol>, can be either a string, in which case it |
977 |
will be interpreted as a fixed record end marker, or it can be a regex |
978 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
979 |
regular expression. |
980 |
|
981 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
982 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
983 |
protocols). |
984 |
|
985 |
Partial lines at the end of the stream will never be returned, as they are |
986 |
not marked by the end of line marker. |
987 |
|
988 |
=cut |
989 |
|
990 |
register_read_type line => sub { |
991 |
my ($self, $cb, $eol) = @_; |
992 |
|
993 |
if (@_ < 3) { |
994 |
# this is more than twice as fast as the generic code below |
995 |
sub { |
996 |
$_[0]{rbuf} =~ s/^([^\015\012]*)(\015?\012)// or return; |
997 |
|
998 |
$cb->($_[0], $1, $2); |
999 |
1 |
1000 |
} |
1001 |
} else { |
1002 |
$eol = quotemeta $eol unless ref $eol; |
1003 |
$eol = qr|^(.*?)($eol)|s; |
1004 |
|
1005 |
sub { |
1006 |
$_[0]{rbuf} =~ s/$eol// or return; |
1007 |
|
1008 |
$cb->($_[0], $1, $2); |
1009 |
1 |
1010 |
} |
1011 |
} |
1012 |
}; |
1013 |
|
1014 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
1015 |
|
1016 |
Makes a regex match against the regex object C<$accept> and returns |
1017 |
everything up to and including the match. |
1018 |
|
1019 |
Example: read a single line terminated by '\n'. |
1020 |
|
1021 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
1022 |
|
1023 |
If C<$reject> is given and not undef, then it determines when the data is |
1024 |
to be rejected: it is matched against the data when the C<$accept> regex |
1025 |
does not match and generates an C<EBADMSG> error when it matches. This is |
1026 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
1027 |
receive buffer overflow). |
1028 |
|
1029 |
Example: expect a single decimal number followed by whitespace, reject |
1030 |
anything else (not the use of an anchor). |
1031 |
|
1032 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
1033 |
|
1034 |
If C<$skip> is given and not C<undef>, then it will be matched against |
1035 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
1036 |
and everything preceding and including the match will be accepted |
1037 |
unconditionally. This is useful to skip large amounts of data that you |
1038 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
1039 |
have to start matching from the beginning. This is purely an optimisation |
1040 |
and is usually worth only when you expect more than a few kilobytes. |
1041 |
|
1042 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
1043 |
expect the header to be very large (it isn't in practise, but...), we use |
1044 |
a skip regex to skip initial portions. The skip regex is tricky in that |
1045 |
it only accepts something not ending in either \015 or \012, as these are |
1046 |
required for the accept regex. |
1047 |
|
1048 |
$handle->push_read (regex => |
1049 |
qr<\015\012\015\012>, |
1050 |
undef, # no reject |
1051 |
qr<^.*[^\015\012]>, |
1052 |
sub { ... }); |
1053 |
|
1054 |
=cut |
1055 |
|
1056 |
register_read_type regex => sub { |
1057 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
1058 |
|
1059 |
my $data; |
1060 |
my $rbuf = \$self->{rbuf}; |
1061 |
|
1062 |
sub { |
1063 |
# accept |
1064 |
if ($$rbuf =~ $accept) { |
1065 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1066 |
$cb->($self, $data); |
1067 |
return 1; |
1068 |
} |
1069 |
|
1070 |
# reject |
1071 |
if ($reject && $$rbuf =~ $reject) { |
1072 |
$self->_error (&Errno::EBADMSG); |
1073 |
} |
1074 |
|
1075 |
# skip |
1076 |
if ($skip && $$rbuf =~ $skip) { |
1077 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1078 |
} |
1079 |
|
1080 |
() |
1081 |
} |
1082 |
}; |
1083 |
|
1084 |
=item netstring => $cb->($handle, $string) |
1085 |
|
1086 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
1087 |
|
1088 |
Throws an error with C<$!> set to EBADMSG on format violations. |
1089 |
|
1090 |
=cut |
1091 |
|
1092 |
register_read_type netstring => sub { |
1093 |
my ($self, $cb) = @_; |
1094 |
|
1095 |
sub { |
1096 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
1097 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
1098 |
$self->_error (&Errno::EBADMSG); |
1099 |
} |
1100 |
return; |
1101 |
} |
1102 |
|
1103 |
my $len = $1; |
1104 |
|
1105 |
$self->unshift_read (chunk => $len, sub { |
1106 |
my $string = $_[1]; |
1107 |
$_[0]->unshift_read (chunk => 1, sub { |
1108 |
if ($_[1] eq ",") { |
1109 |
$cb->($_[0], $string); |
1110 |
} else { |
1111 |
$self->_error (&Errno::EBADMSG); |
1112 |
} |
1113 |
}); |
1114 |
}); |
1115 |
|
1116 |
1 |
1117 |
} |
1118 |
}; |
1119 |
|
1120 |
=item packstring => $format, $cb->($handle, $string) |
1121 |
|
1122 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1123 |
uses the same format as a Perl C<pack> format, but must specify a single |
1124 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1125 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1126 |
|
1127 |
For example, DNS over TCP uses a prefix of C<n> (2 octet network order), |
1128 |
EPP uses a prefix of C<N> (4 octtes). |
1129 |
|
1130 |
Example: read a block of data prefixed by its length in BER-encoded |
1131 |
format (very efficient). |
1132 |
|
1133 |
$handle->push_read (packstring => "w", sub { |
1134 |
my ($handle, $data) = @_; |
1135 |
}); |
1136 |
|
1137 |
=cut |
1138 |
|
1139 |
register_read_type packstring => sub { |
1140 |
my ($self, $cb, $format) = @_; |
1141 |
|
1142 |
sub { |
1143 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1144 |
defined (my $len = eval { unpack $format, $_[0]{rbuf} }) |
1145 |
or return; |
1146 |
|
1147 |
$format = length pack $format, $len; |
1148 |
|
1149 |
# bypass unshift if we already have the remaining chunk |
1150 |
if ($format + $len <= length $_[0]{rbuf}) { |
1151 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1152 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1153 |
$cb->($_[0], $data); |
1154 |
} else { |
1155 |
# remove prefix |
1156 |
substr $_[0]{rbuf}, 0, $format, ""; |
1157 |
|
1158 |
# read remaining chunk |
1159 |
$_[0]->unshift_read (chunk => $len, $cb); |
1160 |
} |
1161 |
|
1162 |
1 |
1163 |
} |
1164 |
}; |
1165 |
|
1166 |
=item json => $cb->($handle, $hash_or_arrayref) |
1167 |
|
1168 |
Reads a JSON object or array, decodes it and passes it to the |
1169 |
callback. When a parse error occurs, an C<EBADMSG> error will be raised. |
1170 |
|
1171 |
If a C<json> object was passed to the constructor, then that will be used |
1172 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1173 |
|
1174 |
This read type uses the incremental parser available with JSON version |
1175 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1176 |
dependency on your own: this module will load the JSON module, but |
1177 |
AnyEvent does not depend on it itself. |
1178 |
|
1179 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1180 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1181 |
the C<json> write type description, above, for an actual example. |
1182 |
|
1183 |
=cut |
1184 |
|
1185 |
register_read_type json => sub { |
1186 |
my ($self, $cb) = @_; |
1187 |
|
1188 |
require JSON; |
1189 |
|
1190 |
my $data; |
1191 |
my $rbuf = \$self->{rbuf}; |
1192 |
|
1193 |
my $json = $self->{json} ||= JSON->new->utf8; |
1194 |
|
1195 |
sub { |
1196 |
my $ref = eval { $json->incr_parse ($self->{rbuf}) }; |
1197 |
|
1198 |
if ($ref) { |
1199 |
$self->{rbuf} = $json->incr_text; |
1200 |
$json->incr_text = ""; |
1201 |
$cb->($self, $ref); |
1202 |
|
1203 |
1 |
1204 |
} elsif ($@) { |
1205 |
# error case |
1206 |
$json->incr_skip; |
1207 |
|
1208 |
$self->{rbuf} = $json->incr_text; |
1209 |
$json->incr_text = ""; |
1210 |
|
1211 |
$self->_error (&Errno::EBADMSG); |
1212 |
|
1213 |
() |
1214 |
} else { |
1215 |
$self->{rbuf} = ""; |
1216 |
|
1217 |
() |
1218 |
} |
1219 |
} |
1220 |
}; |
1221 |
|
1222 |
=item storable => $cb->($handle, $ref) |
1223 |
|
1224 |
Deserialises a L<Storable> frozen representation as written by the |
1225 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1226 |
data). |
1227 |
|
1228 |
Raises C<EBADMSG> error if the data could not be decoded. |
1229 |
|
1230 |
=cut |
1231 |
|
1232 |
register_read_type storable => sub { |
1233 |
my ($self, $cb) = @_; |
1234 |
|
1235 |
require Storable; |
1236 |
|
1237 |
sub { |
1238 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1239 |
defined (my $len = eval { unpack "w", $_[0]{rbuf} }) |
1240 |
or return; |
1241 |
|
1242 |
my $format = length pack "w", $len; |
1243 |
|
1244 |
# bypass unshift if we already have the remaining chunk |
1245 |
if ($format + $len <= length $_[0]{rbuf}) { |
1246 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1247 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1248 |
$cb->($_[0], Storable::thaw ($data)); |
1249 |
} else { |
1250 |
# remove prefix |
1251 |
substr $_[0]{rbuf}, 0, $format, ""; |
1252 |
|
1253 |
# read remaining chunk |
1254 |
$_[0]->unshift_read (chunk => $len, sub { |
1255 |
if (my $ref = eval { Storable::thaw ($_[1]) }) { |
1256 |
$cb->($_[0], $ref); |
1257 |
} else { |
1258 |
$self->_error (&Errno::EBADMSG); |
1259 |
} |
1260 |
}); |
1261 |
} |
1262 |
|
1263 |
1 |
1264 |
} |
1265 |
}; |
1266 |
|
1267 |
=back |
1268 |
|
1269 |
=item AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args) |
1270 |
|
1271 |
This function (not method) lets you add your own types to C<push_read>. |
1272 |
|
1273 |
Whenever the given C<type> is used, C<push_read> will invoke the code |
1274 |
reference with the handle object, the callback and the remaining |
1275 |
arguments. |
1276 |
|
1277 |
The code reference is supposed to return a callback (usually a closure) |
1278 |
that works as a plain read callback (see C<< ->push_read ($cb) >>). |
1279 |
|
1280 |
It should invoke the passed callback when it is done reading (remember to |
1281 |
pass C<$handle> as first argument as all other callbacks do that). |
1282 |
|
1283 |
Note that this is a function, and all types registered this way will be |
1284 |
global, so try to use unique names. |
1285 |
|
1286 |
For examples, see the source of this module (F<perldoc -m AnyEvent::Handle>, |
1287 |
search for C<register_read_type>)). |
1288 |
|
1289 |
=item $handle->stop_read |
1290 |
|
1291 |
=item $handle->start_read |
1292 |
|
1293 |
In rare cases you actually do not want to read anything from the |
1294 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1295 |
any queued callbacks will be executed then. To start reading again, call |
1296 |
C<start_read>. |
1297 |
|
1298 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1299 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1300 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1301 |
there are any read requests in the queue. |
1302 |
|
1303 |
These methods will have no effect when in TLS mode (as TLS doesn't support |
1304 |
half-duplex connections). |
1305 |
|
1306 |
=cut |
1307 |
|
1308 |
sub stop_read { |
1309 |
my ($self) = @_; |
1310 |
|
1311 |
delete $self->{_rw} unless $self->{tls}; |
1312 |
} |
1313 |
|
1314 |
sub start_read { |
1315 |
my ($self) = @_; |
1316 |
|
1317 |
unless ($self->{_rw} || $self->{_eof}) { |
1318 |
Scalar::Util::weaken $self; |
1319 |
|
1320 |
$self->{_rw} = AnyEvent->io (fh => $self->{fh}, poll => "r", cb => sub { |
1321 |
my $rbuf = \($self->{tls} ? my $buf : $self->{rbuf}); |
1322 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size} || 8192, length $$rbuf; |
1323 |
|
1324 |
if ($len > 0) { |
1325 |
$self->{_activity} = AnyEvent->now; |
1326 |
|
1327 |
if ($self->{tls}) { |
1328 |
Net::SSLeay::BIO_write ($self->{_rbio}, $$rbuf); |
1329 |
|
1330 |
&_dotls ($self); |
1331 |
} else { |
1332 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1333 |
} |
1334 |
|
1335 |
} elsif (defined $len) { |
1336 |
delete $self->{_rw}; |
1337 |
$self->{_eof} = 1; |
1338 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1339 |
|
1340 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1341 |
return $self->_error ($!, 1); |
1342 |
} |
1343 |
}); |
1344 |
} |
1345 |
} |
1346 |
|
1347 |
# poll the write BIO and send the data if applicable |
1348 |
sub _dotls { |
1349 |
my ($self) = @_; |
1350 |
|
1351 |
my $tmp; |
1352 |
|
1353 |
if (length $self->{_tls_wbuf}) { |
1354 |
while (($tmp = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1355 |
substr $self->{_tls_wbuf}, 0, $tmp, ""; |
1356 |
} |
1357 |
} |
1358 |
|
1359 |
while (defined ($tmp = Net::SSLeay::read ($self->{tls}))) { |
1360 |
unless (length $tmp) { |
1361 |
# let's treat SSL-eof as we treat normal EOF |
1362 |
delete $self->{_rw}; |
1363 |
$self->{_eof} = 1; |
1364 |
&_freetls; |
1365 |
} |
1366 |
|
1367 |
$self->{_tls_rbuf} .= $tmp; |
1368 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1369 |
$self->{tls} or return; # tls session might have gone away in callback |
1370 |
} |
1371 |
|
1372 |
$tmp = Net::SSLeay::get_error ($self->{tls}, -1); |
1373 |
|
1374 |
if ($tmp != Net::SSLeay::ERROR_WANT_READ ()) { |
1375 |
if ($tmp == Net::SSLeay::ERROR_SYSCALL ()) { |
1376 |
return $self->_error ($!, 1); |
1377 |
} elsif ($tmp == Net::SSLeay::ERROR_SSL ()) { |
1378 |
return $self->_error (&Errno::EIO, 1); |
1379 |
} |
1380 |
|
1381 |
# all other errors are fine for our purposes |
1382 |
} |
1383 |
|
1384 |
while (length ($tmp = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1385 |
$self->{wbuf} .= $tmp; |
1386 |
$self->_drain_wbuf; |
1387 |
} |
1388 |
} |
1389 |
|
1390 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1391 |
|
1392 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1393 |
object is created, you can also do that at a later time by calling |
1394 |
C<starttls>. |
1395 |
|
1396 |
The first argument is the same as the C<tls> constructor argument (either |
1397 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1398 |
|
1399 |
The second argument is the optional C<AnyEvent::TLS> object that is used |
1400 |
when AnyEvent::Handle has to create its own TLS connection object, or |
1401 |
a hash reference with C<< key => value >> pairs that will be used to |
1402 |
construct a new context. |
1403 |
|
1404 |
The TLS connection object will end up in C<< $handle->{tls} >>, the TLS |
1405 |
context in C<< $handle->{tls_ctx} >> after this call and can be used or |
1406 |
changed to your liking. Note that the handshake might have already started |
1407 |
when this function returns. |
1408 |
|
1409 |
If it an error to start a TLS handshake more than once per |
1410 |
AnyEvent::Handle object (this is due to bugs in OpenSSL). |
1411 |
|
1412 |
=cut |
1413 |
|
1414 |
sub starttls { |
1415 |
my ($self, $ssl, $ctx) = @_; |
1416 |
|
1417 |
require Net::SSLeay; |
1418 |
|
1419 |
Carp::croak "it is an error to call starttls more than once on an AnyEvent::Handle object" |
1420 |
if $self->{tls}; |
1421 |
|
1422 |
$ctx ||= $self->{tls_ctx}; |
1423 |
|
1424 |
if ("HASH" eq ref $ctx) { |
1425 |
require AnyEvent::TLS; |
1426 |
|
1427 |
local $Carp::CarpLevel = 1; # skip ourselves when creating a new context |
1428 |
$ctx = new AnyEvent::TLS %$ctx; |
1429 |
} |
1430 |
|
1431 |
$self->{tls_ctx} = $ctx || TLS_CTX (); |
1432 |
$self->{tls} = $ssl = $self->{tls_ctx}->_get_session ($ssl, $self); |
1433 |
|
1434 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1435 |
# but the openssl maintainers basically said: "trust us, it just works". |
1436 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1437 |
# and mismaintained ssleay-module doesn't even offer them). |
1438 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1439 |
# |
1440 |
# in short: this is a mess. |
1441 |
# |
1442 |
# note that we do not try to keep the length constant between writes as we are required to do. |
1443 |
# we assume that most (but not all) of this insanity only applies to non-blocking cases, |
1444 |
# and we drive openssl fully in blocking mode here. Or maybe we don't - openssl seems to |
1445 |
# have identity issues in that area. |
1446 |
# Net::SSLeay::CTX_set_mode ($ssl, |
1447 |
# (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1448 |
# | (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1449 |
Net::SSLeay::CTX_set_mode ($ssl, 1|2); |
1450 |
|
1451 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1452 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1453 |
|
1454 |
Net::SSLeay::set_bio ($ssl, $self->{_rbio}, $self->{_wbio}); |
1455 |
|
1456 |
&_dotls; # need to trigger the initial handshake |
1457 |
$self->start_read; # make sure we actually do read |
1458 |
} |
1459 |
|
1460 |
=item $handle->stoptls |
1461 |
|
1462 |
Shuts down the SSL connection - this makes a proper EOF handshake by |
1463 |
sending a close notify to the other side, but since OpenSSL doesn't |
1464 |
support non-blocking shut downs, it is not possible to re-use the stream |
1465 |
afterwards. |
1466 |
|
1467 |
=cut |
1468 |
|
1469 |
sub stoptls { |
1470 |
my ($self) = @_; |
1471 |
|
1472 |
if ($self->{tls}) { |
1473 |
Net::SSLeay::shutdown ($self->{tls}); |
1474 |
|
1475 |
&_dotls; |
1476 |
|
1477 |
# we don't give a shit. no, we do, but we can't. no... |
1478 |
# we, we... have to use openssl :/ |
1479 |
&_freetls; |
1480 |
} |
1481 |
} |
1482 |
|
1483 |
sub _freetls { |
1484 |
my ($self) = @_; |
1485 |
|
1486 |
return unless $self->{tls}; |
1487 |
|
1488 |
$self->{tls_ctx}->_put_session (delete $self->{tls}); |
1489 |
|
1490 |
delete @$self{qw(_rbio _wbio _tls_wbuf)}; |
1491 |
} |
1492 |
|
1493 |
sub DESTROY { |
1494 |
my ($self) = @_; |
1495 |
|
1496 |
&_freetls; |
1497 |
|
1498 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
1499 |
|
1500 |
if ($linger && length $self->{wbuf}) { |
1501 |
my $fh = delete $self->{fh}; |
1502 |
my $wbuf = delete $self->{wbuf}; |
1503 |
|
1504 |
my @linger; |
1505 |
|
1506 |
push @linger, AnyEvent->io (fh => $fh, poll => "w", cb => sub { |
1507 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
1508 |
|
1509 |
if ($len > 0) { |
1510 |
substr $wbuf, 0, $len, ""; |
1511 |
} else { |
1512 |
@linger = (); # end |
1513 |
} |
1514 |
}); |
1515 |
push @linger, AnyEvent->timer (after => $linger, cb => sub { |
1516 |
@linger = (); |
1517 |
}); |
1518 |
} |
1519 |
} |
1520 |
|
1521 |
=item $handle->destroy |
1522 |
|
1523 |
Shuts down the handle object as much as possible - this call ensures that |
1524 |
no further callbacks will be invoked and resources will be freed as much |
1525 |
as possible. You must not call any methods on the object afterwards. |
1526 |
|
1527 |
Normally, you can just "forget" any references to an AnyEvent::Handle |
1528 |
object and it will simply shut down. This works in fatal error and EOF |
1529 |
callbacks, as well as code outside. It does I<NOT> work in a read or write |
1530 |
callback, so when you want to destroy the AnyEvent::Handle object from |
1531 |
within such an callback. You I<MUST> call C<< ->destroy >> explicitly in |
1532 |
that case. |
1533 |
|
1534 |
The handle might still linger in the background and write out remaining |
1535 |
data, as specified by the C<linger> option, however. |
1536 |
|
1537 |
=cut |
1538 |
|
1539 |
sub destroy { |
1540 |
my ($self) = @_; |
1541 |
|
1542 |
$self->DESTROY; |
1543 |
%$self = (); |
1544 |
} |
1545 |
|
1546 |
=item AnyEvent::Handle::TLS_CTX |
1547 |
|
1548 |
This function creates and returns the AnyEvent::TLS object used by default |
1549 |
for TLS mode. |
1550 |
|
1551 |
The context is created by calling L<AnyEvent::TLS> without any arguments. |
1552 |
|
1553 |
=cut |
1554 |
|
1555 |
our $TLS_CTX; |
1556 |
|
1557 |
sub TLS_CTX() { |
1558 |
$TLS_CTX ||= do { |
1559 |
require AnyEvent::TLS; |
1560 |
|
1561 |
new AnyEvent::TLS |
1562 |
} |
1563 |
} |
1564 |
|
1565 |
=back |
1566 |
|
1567 |
|
1568 |
=head1 NONFREQUENTLY ASKED QUESTIONS |
1569 |
|
1570 |
=over 4 |
1571 |
|
1572 |
=item I C<undef> the AnyEvent::Handle reference inside my callback and |
1573 |
still get further invocations! |
1574 |
|
1575 |
That's because AnyEvent::Handle keeps a reference to itself when handling |
1576 |
read or write callbacks. |
1577 |
|
1578 |
It is only safe to "forget" the reference inside EOF or error callbacks, |
1579 |
from within all other callbacks, you need to explicitly call the C<< |
1580 |
->destroy >> method. |
1581 |
|
1582 |
=item I get different callback invocations in TLS mode/Why can't I pause |
1583 |
reading? |
1584 |
|
1585 |
Unlike, say, TCP, TLS connections do not consist of two independent |
1586 |
communication channels, one for each direction. Or put differently. The |
1587 |
read and write directions are not independent of each other: you cannot |
1588 |
write data unless you are also prepared to read, and vice versa. |
1589 |
|
1590 |
This can mean than, in TLS mode, you might get C<on_error> or C<on_eof> |
1591 |
callback invocations when you are not expecting any read data - the reason |
1592 |
is that AnyEvent::Handle always reads in TLS mode. |
1593 |
|
1594 |
During the connection, you have to make sure that you always have a |
1595 |
non-empty read-queue, or an C<on_read> watcher. At the end of the |
1596 |
connection (or when you no longer want to use it) you can call the |
1597 |
C<destroy> method. |
1598 |
|
1599 |
=item How do I read data until the other side closes the connection? |
1600 |
|
1601 |
If you just want to read your data into a perl scalar, the easiest way |
1602 |
to achieve this is by setting an C<on_read> callback that does nothing, |
1603 |
clearing the C<on_eof> callback and in the C<on_error> callback, the data |
1604 |
will be in C<$_[0]{rbuf}>: |
1605 |
|
1606 |
$handle->on_read (sub { }); |
1607 |
$handle->on_eof (undef); |
1608 |
$handle->on_error (sub { |
1609 |
my $data = delete $_[0]{rbuf}; |
1610 |
undef $handle; |
1611 |
}); |
1612 |
|
1613 |
The reason to use C<on_error> is that TCP connections, due to latencies |
1614 |
and packets loss, might get closed quite violently with an error, when in |
1615 |
fact, all data has been received. |
1616 |
|
1617 |
It is usually better to use acknowledgements when transferring data, |
1618 |
to make sure the other side hasn't just died and you got the data |
1619 |
intact. This is also one reason why so many internet protocols have an |
1620 |
explicit QUIT command. |
1621 |
|
1622 |
=item I don't want to destroy the handle too early - how do I wait until |
1623 |
all data has been written? |
1624 |
|
1625 |
After writing your last bits of data, set the C<on_drain> callback |
1626 |
and destroy the handle in there - with the default setting of |
1627 |
C<low_water_mark> this will be called precisely when all data has been |
1628 |
written to the socket: |
1629 |
|
1630 |
$handle->push_write (...); |
1631 |
$handle->on_drain (sub { |
1632 |
warn "all data submitted to the kernel\n"; |
1633 |
undef $handle; |
1634 |
}); |
1635 |
|
1636 |
=back |
1637 |
|
1638 |
|
1639 |
=head1 SUBCLASSING AnyEvent::Handle |
1640 |
|
1641 |
In many cases, you might want to subclass AnyEvent::Handle. |
1642 |
|
1643 |
To make this easier, a given version of AnyEvent::Handle uses these |
1644 |
conventions: |
1645 |
|
1646 |
=over 4 |
1647 |
|
1648 |
=item * all constructor arguments become object members. |
1649 |
|
1650 |
At least initially, when you pass a C<tls>-argument to the constructor it |
1651 |
will end up in C<< $handle->{tls} >>. Those members might be changed or |
1652 |
mutated later on (for example C<tls> will hold the TLS connection object). |
1653 |
|
1654 |
=item * other object member names are prefixed with an C<_>. |
1655 |
|
1656 |
All object members not explicitly documented (internal use) are prefixed |
1657 |
with an underscore character, so the remaining non-C<_>-namespace is free |
1658 |
for use for subclasses. |
1659 |
|
1660 |
=item * all members not documented here and not prefixed with an underscore |
1661 |
are free to use in subclasses. |
1662 |
|
1663 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
1664 |
member variables, but thats just life, at least it is documented. |
1665 |
|
1666 |
=back |
1667 |
|
1668 |
=head1 AUTHOR |
1669 |
|
1670 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
1671 |
|
1672 |
=cut |
1673 |
|
1674 |
1; # End of AnyEvent::Handle |