1 |
package AnyEvent::Handle; |
2 |
|
3 |
no warnings; |
4 |
use strict qw(subs vars); |
5 |
|
6 |
use AnyEvent (); |
7 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
8 |
use Scalar::Util (); |
9 |
use Carp (); |
10 |
use Fcntl (); |
11 |
use Errno qw(EAGAIN EINTR); |
12 |
|
13 |
=head1 NAME |
14 |
|
15 |
AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent |
16 |
|
17 |
=cut |
18 |
|
19 |
our $VERSION = 4.45; |
20 |
|
21 |
=head1 SYNOPSIS |
22 |
|
23 |
use AnyEvent; |
24 |
use AnyEvent::Handle; |
25 |
|
26 |
my $cv = AnyEvent->condvar; |
27 |
|
28 |
my $handle = |
29 |
AnyEvent::Handle->new ( |
30 |
fh => \*STDIN, |
31 |
on_eof => sub { |
32 |
$cv->send; |
33 |
}, |
34 |
); |
35 |
|
36 |
# send some request line |
37 |
$handle->push_write ("getinfo\015\012"); |
38 |
|
39 |
# read the response line |
40 |
$handle->push_read (line => sub { |
41 |
my ($handle, $line) = @_; |
42 |
warn "read line <$line>\n"; |
43 |
$cv->send; |
44 |
}); |
45 |
|
46 |
$cv->recv; |
47 |
|
48 |
=head1 DESCRIPTION |
49 |
|
50 |
This module is a helper module to make it easier to do event-based I/O on |
51 |
filehandles. For utility functions for doing non-blocking connects and accepts |
52 |
on sockets see L<AnyEvent::Util>. |
53 |
|
54 |
The L<AnyEvent::Intro> tutorial contains some well-documented |
55 |
AnyEvent::Handle examples. |
56 |
|
57 |
In the following, when the documentation refers to of "bytes" then this |
58 |
means characters. As sysread and syswrite are used for all I/O, their |
59 |
treatment of characters applies to this module as well. |
60 |
|
61 |
All callbacks will be invoked with the handle object as their first |
62 |
argument. |
63 |
|
64 |
=head1 METHODS |
65 |
|
66 |
=over 4 |
67 |
|
68 |
=item $handle = B<new> AnyEvent::TLS fh => $filehandle, key => value... |
69 |
|
70 |
The constructor supports these arguments (all as C<< key => value >> pairs). |
71 |
|
72 |
=over 4 |
73 |
|
74 |
=item fh => $filehandle [MANDATORY] |
75 |
|
76 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
77 |
|
78 |
NOTE: The filehandle will be set to non-blocking mode (using |
79 |
C<AnyEvent::Util::fh_nonblocking>) by the constructor and needs to stay in |
80 |
that mode. |
81 |
|
82 |
=item on_eof => $cb->($handle) |
83 |
|
84 |
Set the callback to be called when an end-of-file condition is detected, |
85 |
i.e. in the case of a socket, when the other side has closed the |
86 |
connection cleanly. |
87 |
|
88 |
For sockets, this just means that the other side has stopped sending data, |
89 |
you can still try to write data, and, in fact, one can return from the EOF |
90 |
callback and continue writing data, as only the read part has been shut |
91 |
down. |
92 |
|
93 |
While not mandatory, it is I<highly> recommended to set an EOF callback, |
94 |
otherwise you might end up with a closed socket while you are still |
95 |
waiting for data. |
96 |
|
97 |
If an EOF condition has been detected but no C<on_eof> callback has been |
98 |
set, then a fatal error will be raised with C<$!> set to <0>. |
99 |
|
100 |
=item on_error => $cb->($handle, $fatal, $message) |
101 |
|
102 |
This is the error callback, which is called when, well, some error |
103 |
occured, such as not being able to resolve the hostname, failure to |
104 |
connect or a read error. |
105 |
|
106 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
107 |
fatal errors the handle object will be shut down and will not be usable |
108 |
(but you are free to look at the current C<< ->rbuf >>). Examples of fatal |
109 |
errors are an EOF condition with active (but unsatisifable) read watchers |
110 |
(C<EPIPE>) or I/O errors. |
111 |
|
112 |
AnyEvent::Handle tries to find an appropriate error code for you to check |
113 |
against, but in some cases (TLS errors), this does not work well. It is |
114 |
recommended to always output the C<$message> argument in human-readable |
115 |
error messages (it's usually the same as C<"$!">). |
116 |
|
117 |
Non-fatal errors can be retried by simply returning, but it is recommended |
118 |
to simply ignore this parameter and instead abondon the handle object |
119 |
when this callback is invoked. Examples of non-fatal errors are timeouts |
120 |
C<ETIMEDOUT>) or badly-formatted data (C<EBADMSG>). |
121 |
|
122 |
On callback entrance, the value of C<$!> contains the operating system |
123 |
error code (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT>, C<EBADMSG> or |
124 |
C<EPROTO>). |
125 |
|
126 |
While not mandatory, it is I<highly> recommended to set this callback, as |
127 |
you will not be notified of errors otherwise. The default simply calls |
128 |
C<croak>. |
129 |
|
130 |
=item on_read => $cb->($handle) |
131 |
|
132 |
This sets the default read callback, which is called when data arrives |
133 |
and no read request is in the queue (unlike read queue callbacks, this |
134 |
callback will only be called when at least one octet of data is in the |
135 |
read buffer). |
136 |
|
137 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
138 |
method or access the C<$handle->{rbuf}> member directly. Note that you |
139 |
must not enlarge or modify the read buffer, you can only remove data at |
140 |
the beginning from it. |
141 |
|
142 |
When an EOF condition is detected then AnyEvent::Handle will first try to |
143 |
feed all the remaining data to the queued callbacks and C<on_read> before |
144 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
145 |
error will be raised (with C<$!> set to C<EPIPE>). |
146 |
|
147 |
=item on_drain => $cb->($handle) |
148 |
|
149 |
This sets the callback that is called when the write buffer becomes empty |
150 |
(or when the callback is set and the buffer is empty already). |
151 |
|
152 |
To append to the write buffer, use the C<< ->push_write >> method. |
153 |
|
154 |
This callback is useful when you don't want to put all of your write data |
155 |
into the queue at once, for example, when you want to write the contents |
156 |
of some file to the socket you might not want to read the whole file into |
157 |
memory and push it into the queue, but instead only read more data from |
158 |
the file when the write queue becomes empty. |
159 |
|
160 |
=item timeout => $fractional_seconds |
161 |
|
162 |
If non-zero, then this enables an "inactivity" timeout: whenever this many |
163 |
seconds pass without a successful read or write on the underlying file |
164 |
handle, the C<on_timeout> callback will be invoked (and if that one is |
165 |
missing, a non-fatal C<ETIMEDOUT> error will be raised). |
166 |
|
167 |
Note that timeout processing is also active when you currently do not have |
168 |
any outstanding read or write requests: If you plan to keep the connection |
169 |
idle then you should disable the timout temporarily or ignore the timeout |
170 |
in the C<on_timeout> callback, in which case AnyEvent::Handle will simply |
171 |
restart the timeout. |
172 |
|
173 |
Zero (the default) disables this timeout. |
174 |
|
175 |
=item on_timeout => $cb->($handle) |
176 |
|
177 |
Called whenever the inactivity timeout passes. If you return from this |
178 |
callback, then the timeout will be reset as if some activity had happened, |
179 |
so this condition is not fatal in any way. |
180 |
|
181 |
=item rbuf_max => <bytes> |
182 |
|
183 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
184 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
185 |
avoid some forms of denial-of-service attacks. |
186 |
|
187 |
For example, a server accepting connections from untrusted sources should |
188 |
be configured to accept only so-and-so much data that it cannot act on |
189 |
(for example, when expecting a line, an attacker could send an unlimited |
190 |
amount of data without a callback ever being called as long as the line |
191 |
isn't finished). |
192 |
|
193 |
=item autocork => <boolean> |
194 |
|
195 |
When disabled (the default), then C<push_write> will try to immediately |
196 |
write the data to the handle, if possible. This avoids having to register |
197 |
a write watcher and wait for the next event loop iteration, but can |
198 |
be inefficient if you write multiple small chunks (on the wire, this |
199 |
disadvantage is usually avoided by your kernel's nagle algorithm, see |
200 |
C<no_delay>, but this option can save costly syscalls). |
201 |
|
202 |
When enabled, then writes will always be queued till the next event loop |
203 |
iteration. This is efficient when you do many small writes per iteration, |
204 |
but less efficient when you do a single write only per iteration (or when |
205 |
the write buffer often is full). It also increases write latency. |
206 |
|
207 |
=item no_delay => <boolean> |
208 |
|
209 |
When doing small writes on sockets, your operating system kernel might |
210 |
wait a bit for more data before actually sending it out. This is called |
211 |
the Nagle algorithm, and usually it is beneficial. |
212 |
|
213 |
In some situations you want as low a delay as possible, which can be |
214 |
accomplishd by setting this option to a true value. |
215 |
|
216 |
The default is your opertaing system's default behaviour (most likely |
217 |
enabled), this option explicitly enables or disables it, if possible. |
218 |
|
219 |
=item read_size => <bytes> |
220 |
|
221 |
The default read block size (the amount of bytes this module will |
222 |
try to read during each loop iteration, which affects memory |
223 |
requirements). Default: C<8192>. |
224 |
|
225 |
=item low_water_mark => <bytes> |
226 |
|
227 |
Sets the amount of bytes (default: C<0>) that make up an "empty" write |
228 |
buffer: If the write reaches this size or gets even samller it is |
229 |
considered empty. |
230 |
|
231 |
Sometimes it can be beneficial (for performance reasons) to add data to |
232 |
the write buffer before it is fully drained, but this is a rare case, as |
233 |
the operating system kernel usually buffers data as well, so the default |
234 |
is good in almost all cases. |
235 |
|
236 |
=item linger => <seconds> |
237 |
|
238 |
If non-zero (default: C<3600>), then the destructor of the |
239 |
AnyEvent::Handle object will check whether there is still outstanding |
240 |
write data and will install a watcher that will write this data to the |
241 |
socket. No errors will be reported (this mostly matches how the operating |
242 |
system treats outstanding data at socket close time). |
243 |
|
244 |
This will not work for partial TLS data that could not be encoded |
245 |
yet. This data will be lost. Calling the C<stoptls> method in time might |
246 |
help. |
247 |
|
248 |
=item peername => $string |
249 |
|
250 |
A string used to identify the remote site - usually the DNS hostname |
251 |
(I<not> IDN!) used to create the connection, rarely the IP address. |
252 |
|
253 |
Apart from being useful in error messages, this string is also used in TLS |
254 |
common name verification (see C<verify_cn> in L<AnyEvent::TLS>). |
255 |
|
256 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
257 |
|
258 |
When this parameter is given, it enables TLS (SSL) mode, that means |
259 |
AnyEvent will start a TLS handshake as soon as the conenction has been |
260 |
established and will transparently encrypt/decrypt data afterwards. |
261 |
|
262 |
All TLS protocol errors will be signalled as C<EPROTO>, with an |
263 |
appropriate error message. |
264 |
|
265 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
266 |
automatically when you try to create a TLS handle): this module doesn't |
267 |
have a dependency on that module, so if your module requires it, you have |
268 |
to add the dependency yourself. |
269 |
|
270 |
Unlike TCP, TLS has a server and client side: for the TLS server side, use |
271 |
C<accept>, and for the TLS client side of a connection, use C<connect> |
272 |
mode. |
273 |
|
274 |
You can also provide your own TLS connection object, but you have |
275 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
276 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
277 |
AnyEvent::Handle. Also, this module will take ownership of this connection |
278 |
object. |
279 |
|
280 |
At some future point, AnyEvent::Handle might switch to another TLS |
281 |
implementation, then the option to use your own session object will go |
282 |
away. |
283 |
|
284 |
B<IMPORTANT:> since Net::SSLeay "objects" are really only integers, |
285 |
passing in the wrong integer will lead to certain crash. This most often |
286 |
happens when one uses a stylish C<< tls => 1 >> and is surprised about the |
287 |
segmentation fault. |
288 |
|
289 |
See the C<< ->starttls >> method for when need to start TLS negotiation later. |
290 |
|
291 |
=item tls_ctx => $anyevent_tls |
292 |
|
293 |
Use the given C<AnyEvent::TLS> object to create the new TLS connection |
294 |
(unless a connection object was specified directly). If this parameter is |
295 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
296 |
|
297 |
Instead of an object, you can also specify a hash reference with C<< key |
298 |
=> value >> pairs. Those will be passed to L<AnyEvent::TLS> to create a |
299 |
new TLS context object. |
300 |
|
301 |
=item json => JSON or JSON::XS object |
302 |
|
303 |
This is the json coder object used by the C<json> read and write types. |
304 |
|
305 |
If you don't supply it, then AnyEvent::Handle will create and use a |
306 |
suitable one (on demand), which will write and expect UTF-8 encoded JSON |
307 |
texts. |
308 |
|
309 |
Note that you are responsible to depend on the JSON module if you want to |
310 |
use this functionality, as AnyEvent does not have a dependency itself. |
311 |
|
312 |
=back |
313 |
|
314 |
=cut |
315 |
|
316 |
sub new { |
317 |
my $class = shift; |
318 |
my $self = bless { @_ }, $class; |
319 |
|
320 |
$self->{fh} or Carp::croak "mandatory argument fh is missing"; |
321 |
|
322 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
323 |
|
324 |
$self->{_activity} = AnyEvent->now; |
325 |
$self->_timeout; |
326 |
|
327 |
$self->no_delay (delete $self->{no_delay}) if exists $self->{no_delay}; |
328 |
|
329 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}) |
330 |
if $self->{tls}; |
331 |
|
332 |
$self->on_drain (delete $self->{on_drain}) if exists $self->{on_drain}; |
333 |
|
334 |
$self->start_read |
335 |
if $self->{on_read}; |
336 |
|
337 |
$self->{fh} && $self |
338 |
} |
339 |
|
340 |
sub _shutdown { |
341 |
my ($self) = @_; |
342 |
|
343 |
delete @$self{qw(_tw _rw _ww fh wbuf on_read _queue)}; |
344 |
$self->{_eof} = 1; # tell starttls et. al to stop trying |
345 |
|
346 |
&_freetls; |
347 |
} |
348 |
|
349 |
sub _error { |
350 |
my ($self, $errno, $fatal, $message) = @_; |
351 |
|
352 |
$self->_shutdown |
353 |
if $fatal; |
354 |
|
355 |
$! = $errno; |
356 |
$message ||= "$!"; |
357 |
|
358 |
if ($self->{on_error}) { |
359 |
$self->{on_error}($self, $fatal, $message); |
360 |
} elsif ($self->{fh}) { |
361 |
Carp::croak "AnyEvent::Handle uncaught error: $message"; |
362 |
} |
363 |
} |
364 |
|
365 |
=item $fh = $handle->fh |
366 |
|
367 |
This method returns the file handle used to create the L<AnyEvent::Handle> object. |
368 |
|
369 |
=cut |
370 |
|
371 |
sub fh { $_[0]{fh} } |
372 |
|
373 |
=item $handle->on_error ($cb) |
374 |
|
375 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
376 |
|
377 |
=cut |
378 |
|
379 |
sub on_error { |
380 |
$_[0]{on_error} = $_[1]; |
381 |
} |
382 |
|
383 |
=item $handle->on_eof ($cb) |
384 |
|
385 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
386 |
|
387 |
=cut |
388 |
|
389 |
sub on_eof { |
390 |
$_[0]{on_eof} = $_[1]; |
391 |
} |
392 |
|
393 |
=item $handle->on_timeout ($cb) |
394 |
|
395 |
Replace the current C<on_timeout> callback, or disables the callback (but |
396 |
not the timeout) if C<$cb> = C<undef>. See the C<timeout> constructor |
397 |
argument and method. |
398 |
|
399 |
=cut |
400 |
|
401 |
sub on_timeout { |
402 |
$_[0]{on_timeout} = $_[1]; |
403 |
} |
404 |
|
405 |
=item $handle->autocork ($boolean) |
406 |
|
407 |
Enables or disables the current autocork behaviour (see C<autocork> |
408 |
constructor argument). Changes will only take effect on the next write. |
409 |
|
410 |
=cut |
411 |
|
412 |
sub autocork { |
413 |
$_[0]{autocork} = $_[1]; |
414 |
} |
415 |
|
416 |
=item $handle->no_delay ($boolean) |
417 |
|
418 |
Enables or disables the C<no_delay> setting (see constructor argument of |
419 |
the same name for details). |
420 |
|
421 |
=cut |
422 |
|
423 |
sub no_delay { |
424 |
$_[0]{no_delay} = $_[1]; |
425 |
|
426 |
eval { |
427 |
local $SIG{__DIE__}; |
428 |
setsockopt $_[0]{fh}, &Socket::IPPROTO_TCP, &Socket::TCP_NODELAY, int $_[1]; |
429 |
}; |
430 |
} |
431 |
|
432 |
############################################################################# |
433 |
|
434 |
=item $handle->timeout ($seconds) |
435 |
|
436 |
Configures (or disables) the inactivity timeout. |
437 |
|
438 |
=cut |
439 |
|
440 |
sub timeout { |
441 |
my ($self, $timeout) = @_; |
442 |
|
443 |
$self->{timeout} = $timeout; |
444 |
$self->_timeout; |
445 |
} |
446 |
|
447 |
# reset the timeout watcher, as neccessary |
448 |
# also check for time-outs |
449 |
sub _timeout { |
450 |
my ($self) = @_; |
451 |
|
452 |
if ($self->{timeout}) { |
453 |
my $NOW = AnyEvent->now; |
454 |
|
455 |
# when would the timeout trigger? |
456 |
my $after = $self->{_activity} + $self->{timeout} - $NOW; |
457 |
|
458 |
# now or in the past already? |
459 |
if ($after <= 0) { |
460 |
$self->{_activity} = $NOW; |
461 |
|
462 |
if ($self->{on_timeout}) { |
463 |
$self->{on_timeout}($self); |
464 |
} else { |
465 |
$self->_error (&Errno::ETIMEDOUT); |
466 |
} |
467 |
|
468 |
# callback could have changed timeout value, optimise |
469 |
return unless $self->{timeout}; |
470 |
|
471 |
# calculate new after |
472 |
$after = $self->{timeout}; |
473 |
} |
474 |
|
475 |
Scalar::Util::weaken $self; |
476 |
return unless $self; # ->error could have destroyed $self |
477 |
|
478 |
$self->{_tw} ||= AnyEvent->timer (after => $after, cb => sub { |
479 |
delete $self->{_tw}; |
480 |
$self->_timeout; |
481 |
}); |
482 |
} else { |
483 |
delete $self->{_tw}; |
484 |
} |
485 |
} |
486 |
|
487 |
############################################################################# |
488 |
|
489 |
=back |
490 |
|
491 |
=head2 WRITE QUEUE |
492 |
|
493 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
494 |
for reading. |
495 |
|
496 |
The write queue is very simple: you can add data to its end, and |
497 |
AnyEvent::Handle will automatically try to get rid of it for you. |
498 |
|
499 |
When data could be written and the write buffer is shorter then the low |
500 |
water mark, the C<on_drain> callback will be invoked. |
501 |
|
502 |
=over 4 |
503 |
|
504 |
=item $handle->on_drain ($cb) |
505 |
|
506 |
Sets the C<on_drain> callback or clears it (see the description of |
507 |
C<on_drain> in the constructor). |
508 |
|
509 |
=cut |
510 |
|
511 |
sub on_drain { |
512 |
my ($self, $cb) = @_; |
513 |
|
514 |
$self->{on_drain} = $cb; |
515 |
|
516 |
$cb->($self) |
517 |
if $cb && $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}); |
518 |
} |
519 |
|
520 |
=item $handle->push_write ($data) |
521 |
|
522 |
Queues the given scalar to be written. You can push as much data as you |
523 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
524 |
buffers it independently of the kernel. |
525 |
|
526 |
=cut |
527 |
|
528 |
sub _drain_wbuf { |
529 |
my ($self) = @_; |
530 |
|
531 |
if (!$self->{_ww} && length $self->{wbuf}) { |
532 |
|
533 |
Scalar::Util::weaken $self; |
534 |
|
535 |
my $cb = sub { |
536 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
537 |
|
538 |
if ($len >= 0) { |
539 |
substr $self->{wbuf}, 0, $len, ""; |
540 |
|
541 |
$self->{_activity} = AnyEvent->now; |
542 |
|
543 |
$self->{on_drain}($self) |
544 |
if $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}) |
545 |
&& $self->{on_drain}; |
546 |
|
547 |
delete $self->{_ww} unless length $self->{wbuf}; |
548 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
549 |
$self->_error ($!, 1); |
550 |
} |
551 |
}; |
552 |
|
553 |
# try to write data immediately |
554 |
$cb->() unless $self->{autocork}; |
555 |
|
556 |
# if still data left in wbuf, we need to poll |
557 |
$self->{_ww} = AnyEvent->io (fh => $self->{fh}, poll => "w", cb => $cb) |
558 |
if length $self->{wbuf}; |
559 |
}; |
560 |
} |
561 |
|
562 |
our %WH; |
563 |
|
564 |
sub register_write_type($$) { |
565 |
$WH{$_[0]} = $_[1]; |
566 |
} |
567 |
|
568 |
sub push_write { |
569 |
my $self = shift; |
570 |
|
571 |
if (@_ > 1) { |
572 |
my $type = shift; |
573 |
|
574 |
@_ = ($WH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_write") |
575 |
->($self, @_); |
576 |
} |
577 |
|
578 |
if ($self->{tls}) { |
579 |
$self->{_tls_wbuf} .= $_[0]; |
580 |
|
581 |
&_dotls ($self); |
582 |
} else { |
583 |
$self->{wbuf} .= $_[0]; |
584 |
$self->_drain_wbuf; |
585 |
} |
586 |
} |
587 |
|
588 |
=item $handle->push_write (type => @args) |
589 |
|
590 |
Instead of formatting your data yourself, you can also let this module do |
591 |
the job by specifying a type and type-specific arguments. |
592 |
|
593 |
Predefined types are (if you have ideas for additional types, feel free to |
594 |
drop by and tell us): |
595 |
|
596 |
=over 4 |
597 |
|
598 |
=item netstring => $string |
599 |
|
600 |
Formats the given value as netstring |
601 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
602 |
|
603 |
=cut |
604 |
|
605 |
register_write_type netstring => sub { |
606 |
my ($self, $string) = @_; |
607 |
|
608 |
(length $string) . ":$string," |
609 |
}; |
610 |
|
611 |
=item packstring => $format, $data |
612 |
|
613 |
An octet string prefixed with an encoded length. The encoding C<$format> |
614 |
uses the same format as a Perl C<pack> format, but must specify a single |
615 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
616 |
optional C<!>, C<< < >> or C<< > >> modifier). |
617 |
|
618 |
=cut |
619 |
|
620 |
register_write_type packstring => sub { |
621 |
my ($self, $format, $string) = @_; |
622 |
|
623 |
pack "$format/a*", $string |
624 |
}; |
625 |
|
626 |
=item json => $array_or_hashref |
627 |
|
628 |
Encodes the given hash or array reference into a JSON object. Unless you |
629 |
provide your own JSON object, this means it will be encoded to JSON text |
630 |
in UTF-8. |
631 |
|
632 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
633 |
one end of a handle and read them at the other end without using any |
634 |
additional framing. |
635 |
|
636 |
The generated JSON text is guaranteed not to contain any newlines: While |
637 |
this module doesn't need delimiters after or between JSON texts to be |
638 |
able to read them, many other languages depend on that. |
639 |
|
640 |
A simple RPC protocol that interoperates easily with others is to send |
641 |
JSON arrays (or objects, although arrays are usually the better choice as |
642 |
they mimic how function argument passing works) and a newline after each |
643 |
JSON text: |
644 |
|
645 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
646 |
$handle->push_write ("\012"); |
647 |
|
648 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
649 |
rely on the fact that the newline will be skipped as leading whitespace: |
650 |
|
651 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
652 |
|
653 |
Other languages could read single lines terminated by a newline and pass |
654 |
this line into their JSON decoder of choice. |
655 |
|
656 |
=cut |
657 |
|
658 |
register_write_type json => sub { |
659 |
my ($self, $ref) = @_; |
660 |
|
661 |
require JSON; |
662 |
|
663 |
$self->{json} ? $self->{json}->encode ($ref) |
664 |
: JSON::encode_json ($ref) |
665 |
}; |
666 |
|
667 |
=item storable => $reference |
668 |
|
669 |
Freezes the given reference using L<Storable> and writes it to the |
670 |
handle. Uses the C<nfreeze> format. |
671 |
|
672 |
=cut |
673 |
|
674 |
register_write_type storable => sub { |
675 |
my ($self, $ref) = @_; |
676 |
|
677 |
require Storable; |
678 |
|
679 |
pack "w/a*", Storable::nfreeze ($ref) |
680 |
}; |
681 |
|
682 |
=back |
683 |
|
684 |
=item $handle->push_shutdown |
685 |
|
686 |
Sometimes you know you want to close the socket after writing your data |
687 |
before it was actually written. One way to do that is to replace your |
688 |
C<on_drain> handler by a callback that shuts down the socket. This method |
689 |
is a shorthand for just that, and replaces the C<on_drain> callback with: |
690 |
|
691 |
sub { shutdown $_[0]{fh}, 1 } # for push_shutdown |
692 |
|
693 |
This simply shuts down the write side and signals an EOF condition to the |
694 |
the peer. |
695 |
|
696 |
You can rely on the normal read queue and C<on_eof> handling |
697 |
afterwards. This is the cleanest way to close a connection. |
698 |
|
699 |
=cut |
700 |
|
701 |
sub push_shutdown { |
702 |
$_[0]->{on_drain} = sub { shutdown $_[0]{fh}, 1 }; |
703 |
} |
704 |
|
705 |
=item AnyEvent::Handle::register_write_type type => $coderef->($handle, @args) |
706 |
|
707 |
This function (not method) lets you add your own types to C<push_write>. |
708 |
Whenever the given C<type> is used, C<push_write> will invoke the code |
709 |
reference with the handle object and the remaining arguments. |
710 |
|
711 |
The code reference is supposed to return a single octet string that will |
712 |
be appended to the write buffer. |
713 |
|
714 |
Note that this is a function, and all types registered this way will be |
715 |
global, so try to use unique names. |
716 |
|
717 |
=cut |
718 |
|
719 |
############################################################################# |
720 |
|
721 |
=back |
722 |
|
723 |
=head2 READ QUEUE |
724 |
|
725 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
726 |
for reading. |
727 |
|
728 |
The read queue is more complex than the write queue. It can be used in two |
729 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
730 |
a queue. |
731 |
|
732 |
In the simple case, you just install an C<on_read> callback and whenever |
733 |
new data arrives, it will be called. You can then remove some data (if |
734 |
enough is there) from the read buffer (C<< $handle->rbuf >>). Or you cna |
735 |
leave the data there if you want to accumulate more (e.g. when only a |
736 |
partial message has been received so far). |
737 |
|
738 |
In the more complex case, you want to queue multiple callbacks. In this |
739 |
case, AnyEvent::Handle will call the first queued callback each time new |
740 |
data arrives (also the first time it is queued) and removes it when it has |
741 |
done its job (see C<push_read>, below). |
742 |
|
743 |
This way you can, for example, push three line-reads, followed by reading |
744 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
745 |
|
746 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
747 |
the specified number of bytes which give an XML datagram. |
748 |
|
749 |
# in the default state, expect some header bytes |
750 |
$handle->on_read (sub { |
751 |
# some data is here, now queue the length-header-read (4 octets) |
752 |
shift->unshift_read (chunk => 4, sub { |
753 |
# header arrived, decode |
754 |
my $len = unpack "N", $_[1]; |
755 |
|
756 |
# now read the payload |
757 |
shift->unshift_read (chunk => $len, sub { |
758 |
my $xml = $_[1]; |
759 |
# handle xml |
760 |
}); |
761 |
}); |
762 |
}); |
763 |
|
764 |
Example 2: Implement a client for a protocol that replies either with "OK" |
765 |
and another line or "ERROR" for the first request that is sent, and 64 |
766 |
bytes for the second request. Due to the availability of a queue, we can |
767 |
just pipeline sending both requests and manipulate the queue as necessary |
768 |
in the callbacks. |
769 |
|
770 |
When the first callback is called and sees an "OK" response, it will |
771 |
C<unshift> another line-read. This line-read will be queued I<before> the |
772 |
64-byte chunk callback. |
773 |
|
774 |
# request one, returns either "OK + extra line" or "ERROR" |
775 |
$handle->push_write ("request 1\015\012"); |
776 |
|
777 |
# we expect "ERROR" or "OK" as response, so push a line read |
778 |
$handle->push_read (line => sub { |
779 |
# if we got an "OK", we have to _prepend_ another line, |
780 |
# so it will be read before the second request reads its 64 bytes |
781 |
# which are already in the queue when this callback is called |
782 |
# we don't do this in case we got an error |
783 |
if ($_[1] eq "OK") { |
784 |
$_[0]->unshift_read (line => sub { |
785 |
my $response = $_[1]; |
786 |
... |
787 |
}); |
788 |
} |
789 |
}); |
790 |
|
791 |
# request two, simply returns 64 octets |
792 |
$handle->push_write ("request 2\015\012"); |
793 |
|
794 |
# simply read 64 bytes, always |
795 |
$handle->push_read (chunk => 64, sub { |
796 |
my $response = $_[1]; |
797 |
... |
798 |
}); |
799 |
|
800 |
=over 4 |
801 |
|
802 |
=cut |
803 |
|
804 |
sub _drain_rbuf { |
805 |
my ($self) = @_; |
806 |
|
807 |
local $self->{_in_drain} = 1; |
808 |
|
809 |
if ( |
810 |
defined $self->{rbuf_max} |
811 |
&& $self->{rbuf_max} < length $self->{rbuf} |
812 |
) { |
813 |
$self->_error (&Errno::ENOSPC, 1), return; |
814 |
} |
815 |
|
816 |
while () { |
817 |
# we need to use a separate tls read buffer, as we must not receive data while |
818 |
# we are draining the buffer, and this can only happen with TLS. |
819 |
$self->{rbuf} .= delete $self->{_tls_rbuf} if exists $self->{_tls_rbuf}; |
820 |
|
821 |
my $len = length $self->{rbuf}; |
822 |
|
823 |
if (my $cb = shift @{ $self->{_queue} }) { |
824 |
unless ($cb->($self)) { |
825 |
if ($self->{_eof}) { |
826 |
# no progress can be made (not enough data and no data forthcoming) |
827 |
$self->_error (&Errno::EPIPE, 1), return; |
828 |
} |
829 |
|
830 |
unshift @{ $self->{_queue} }, $cb; |
831 |
last; |
832 |
} |
833 |
} elsif ($self->{on_read}) { |
834 |
last unless $len; |
835 |
|
836 |
$self->{on_read}($self); |
837 |
|
838 |
if ( |
839 |
$len == length $self->{rbuf} # if no data has been consumed |
840 |
&& !@{ $self->{_queue} } # and the queue is still empty |
841 |
&& $self->{on_read} # but we still have on_read |
842 |
) { |
843 |
# no further data will arrive |
844 |
# so no progress can be made |
845 |
$self->_error (&Errno::EPIPE, 1), return |
846 |
if $self->{_eof}; |
847 |
|
848 |
last; # more data might arrive |
849 |
} |
850 |
} else { |
851 |
# read side becomes idle |
852 |
delete $self->{_rw} unless $self->{tls}; |
853 |
last; |
854 |
} |
855 |
} |
856 |
|
857 |
if ($self->{_eof}) { |
858 |
if ($self->{on_eof}) { |
859 |
$self->{on_eof}($self) |
860 |
} else { |
861 |
$self->_error (0, 1); |
862 |
} |
863 |
} |
864 |
|
865 |
# may need to restart read watcher |
866 |
unless ($self->{_rw}) { |
867 |
$self->start_read |
868 |
if $self->{on_read} || @{ $self->{_queue} }; |
869 |
} |
870 |
} |
871 |
|
872 |
=item $handle->on_read ($cb) |
873 |
|
874 |
This replaces the currently set C<on_read> callback, or clears it (when |
875 |
the new callback is C<undef>). See the description of C<on_read> in the |
876 |
constructor. |
877 |
|
878 |
=cut |
879 |
|
880 |
sub on_read { |
881 |
my ($self, $cb) = @_; |
882 |
|
883 |
$self->{on_read} = $cb; |
884 |
$self->_drain_rbuf if $cb && !$self->{_in_drain}; |
885 |
} |
886 |
|
887 |
=item $handle->rbuf |
888 |
|
889 |
Returns the read buffer (as a modifiable lvalue). |
890 |
|
891 |
You can access the read buffer directly as the C<< ->{rbuf} >> |
892 |
member, if you want. However, the only operation allowed on the |
893 |
read buffer (apart from looking at it) is removing data from its |
894 |
beginning. Otherwise modifying or appending to it is not allowed and will |
895 |
lead to hard-to-track-down bugs. |
896 |
|
897 |
NOTE: The read buffer should only be used or modified if the C<on_read>, |
898 |
C<push_read> or C<unshift_read> methods are used. The other read methods |
899 |
automatically manage the read buffer. |
900 |
|
901 |
=cut |
902 |
|
903 |
sub rbuf : lvalue { |
904 |
$_[0]{rbuf} |
905 |
} |
906 |
|
907 |
=item $handle->push_read ($cb) |
908 |
|
909 |
=item $handle->unshift_read ($cb) |
910 |
|
911 |
Append the given callback to the end of the queue (C<push_read>) or |
912 |
prepend it (C<unshift_read>). |
913 |
|
914 |
The callback is called each time some additional read data arrives. |
915 |
|
916 |
It must check whether enough data is in the read buffer already. |
917 |
|
918 |
If not enough data is available, it must return the empty list or a false |
919 |
value, in which case it will be called repeatedly until enough data is |
920 |
available (or an error condition is detected). |
921 |
|
922 |
If enough data was available, then the callback must remove all data it is |
923 |
interested in (which can be none at all) and return a true value. After returning |
924 |
true, it will be removed from the queue. |
925 |
|
926 |
=cut |
927 |
|
928 |
our %RH; |
929 |
|
930 |
sub register_read_type($$) { |
931 |
$RH{$_[0]} = $_[1]; |
932 |
} |
933 |
|
934 |
sub push_read { |
935 |
my $self = shift; |
936 |
my $cb = pop; |
937 |
|
938 |
if (@_) { |
939 |
my $type = shift; |
940 |
|
941 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_read") |
942 |
->($self, $cb, @_); |
943 |
} |
944 |
|
945 |
push @{ $self->{_queue} }, $cb; |
946 |
$self->_drain_rbuf unless $self->{_in_drain}; |
947 |
} |
948 |
|
949 |
sub unshift_read { |
950 |
my $self = shift; |
951 |
my $cb = pop; |
952 |
|
953 |
if (@_) { |
954 |
my $type = shift; |
955 |
|
956 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::unshift_read") |
957 |
->($self, $cb, @_); |
958 |
} |
959 |
|
960 |
|
961 |
unshift @{ $self->{_queue} }, $cb; |
962 |
$self->_drain_rbuf unless $self->{_in_drain}; |
963 |
} |
964 |
|
965 |
=item $handle->push_read (type => @args, $cb) |
966 |
|
967 |
=item $handle->unshift_read (type => @args, $cb) |
968 |
|
969 |
Instead of providing a callback that parses the data itself you can chose |
970 |
between a number of predefined parsing formats, for chunks of data, lines |
971 |
etc. |
972 |
|
973 |
Predefined types are (if you have ideas for additional types, feel free to |
974 |
drop by and tell us): |
975 |
|
976 |
=over 4 |
977 |
|
978 |
=item chunk => $octets, $cb->($handle, $data) |
979 |
|
980 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
981 |
data read to the callback. The callback will never be called with less |
982 |
data. |
983 |
|
984 |
Example: read 2 bytes. |
985 |
|
986 |
$handle->push_read (chunk => 2, sub { |
987 |
warn "yay ", unpack "H*", $_[1]; |
988 |
}); |
989 |
|
990 |
=cut |
991 |
|
992 |
register_read_type chunk => sub { |
993 |
my ($self, $cb, $len) = @_; |
994 |
|
995 |
sub { |
996 |
$len <= length $_[0]{rbuf} or return; |
997 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
998 |
1 |
999 |
} |
1000 |
}; |
1001 |
|
1002 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
1003 |
|
1004 |
The callback will be called only once a full line (including the end of |
1005 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
1006 |
marker) will be passed to the callback as second argument (C<$line>), and |
1007 |
the end of line marker as the third argument (C<$eol>). |
1008 |
|
1009 |
The end of line marker, C<$eol>, can be either a string, in which case it |
1010 |
will be interpreted as a fixed record end marker, or it can be a regex |
1011 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
1012 |
regular expression. |
1013 |
|
1014 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
1015 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
1016 |
protocols). |
1017 |
|
1018 |
Partial lines at the end of the stream will never be returned, as they are |
1019 |
not marked by the end of line marker. |
1020 |
|
1021 |
=cut |
1022 |
|
1023 |
register_read_type line => sub { |
1024 |
my ($self, $cb, $eol) = @_; |
1025 |
|
1026 |
if (@_ < 3) { |
1027 |
# this is more than twice as fast as the generic code below |
1028 |
sub { |
1029 |
$_[0]{rbuf} =~ s/^([^\015\012]*)(\015?\012)// or return; |
1030 |
|
1031 |
$cb->($_[0], $1, $2); |
1032 |
1 |
1033 |
} |
1034 |
} else { |
1035 |
$eol = quotemeta $eol unless ref $eol; |
1036 |
$eol = qr|^(.*?)($eol)|s; |
1037 |
|
1038 |
sub { |
1039 |
$_[0]{rbuf} =~ s/$eol// or return; |
1040 |
|
1041 |
$cb->($_[0], $1, $2); |
1042 |
1 |
1043 |
} |
1044 |
} |
1045 |
}; |
1046 |
|
1047 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
1048 |
|
1049 |
Makes a regex match against the regex object C<$accept> and returns |
1050 |
everything up to and including the match. |
1051 |
|
1052 |
Example: read a single line terminated by '\n'. |
1053 |
|
1054 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
1055 |
|
1056 |
If C<$reject> is given and not undef, then it determines when the data is |
1057 |
to be rejected: it is matched against the data when the C<$accept> regex |
1058 |
does not match and generates an C<EBADMSG> error when it matches. This is |
1059 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
1060 |
receive buffer overflow). |
1061 |
|
1062 |
Example: expect a single decimal number followed by whitespace, reject |
1063 |
anything else (not the use of an anchor). |
1064 |
|
1065 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
1066 |
|
1067 |
If C<$skip> is given and not C<undef>, then it will be matched against |
1068 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
1069 |
and everything preceding and including the match will be accepted |
1070 |
unconditionally. This is useful to skip large amounts of data that you |
1071 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
1072 |
have to start matching from the beginning. This is purely an optimisation |
1073 |
and is usually worth only when you expect more than a few kilobytes. |
1074 |
|
1075 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
1076 |
expect the header to be very large (it isn't in practise, but...), we use |
1077 |
a skip regex to skip initial portions. The skip regex is tricky in that |
1078 |
it only accepts something not ending in either \015 or \012, as these are |
1079 |
required for the accept regex. |
1080 |
|
1081 |
$handle->push_read (regex => |
1082 |
qr<\015\012\015\012>, |
1083 |
undef, # no reject |
1084 |
qr<^.*[^\015\012]>, |
1085 |
sub { ... }); |
1086 |
|
1087 |
=cut |
1088 |
|
1089 |
register_read_type regex => sub { |
1090 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
1091 |
|
1092 |
my $data; |
1093 |
my $rbuf = \$self->{rbuf}; |
1094 |
|
1095 |
sub { |
1096 |
# accept |
1097 |
if ($$rbuf =~ $accept) { |
1098 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1099 |
$cb->($self, $data); |
1100 |
return 1; |
1101 |
} |
1102 |
|
1103 |
# reject |
1104 |
if ($reject && $$rbuf =~ $reject) { |
1105 |
$self->_error (&Errno::EBADMSG); |
1106 |
} |
1107 |
|
1108 |
# skip |
1109 |
if ($skip && $$rbuf =~ $skip) { |
1110 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1111 |
} |
1112 |
|
1113 |
() |
1114 |
} |
1115 |
}; |
1116 |
|
1117 |
=item netstring => $cb->($handle, $string) |
1118 |
|
1119 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
1120 |
|
1121 |
Throws an error with C<$!> set to EBADMSG on format violations. |
1122 |
|
1123 |
=cut |
1124 |
|
1125 |
register_read_type netstring => sub { |
1126 |
my ($self, $cb) = @_; |
1127 |
|
1128 |
sub { |
1129 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
1130 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
1131 |
$self->_error (&Errno::EBADMSG); |
1132 |
} |
1133 |
return; |
1134 |
} |
1135 |
|
1136 |
my $len = $1; |
1137 |
|
1138 |
$self->unshift_read (chunk => $len, sub { |
1139 |
my $string = $_[1]; |
1140 |
$_[0]->unshift_read (chunk => 1, sub { |
1141 |
if ($_[1] eq ",") { |
1142 |
$cb->($_[0], $string); |
1143 |
} else { |
1144 |
$self->_error (&Errno::EBADMSG); |
1145 |
} |
1146 |
}); |
1147 |
}); |
1148 |
|
1149 |
1 |
1150 |
} |
1151 |
}; |
1152 |
|
1153 |
=item packstring => $format, $cb->($handle, $string) |
1154 |
|
1155 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1156 |
uses the same format as a Perl C<pack> format, but must specify a single |
1157 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1158 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1159 |
|
1160 |
For example, DNS over TCP uses a prefix of C<n> (2 octet network order), |
1161 |
EPP uses a prefix of C<N> (4 octtes). |
1162 |
|
1163 |
Example: read a block of data prefixed by its length in BER-encoded |
1164 |
format (very efficient). |
1165 |
|
1166 |
$handle->push_read (packstring => "w", sub { |
1167 |
my ($handle, $data) = @_; |
1168 |
}); |
1169 |
|
1170 |
=cut |
1171 |
|
1172 |
register_read_type packstring => sub { |
1173 |
my ($self, $cb, $format) = @_; |
1174 |
|
1175 |
sub { |
1176 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1177 |
defined (my $len = eval { unpack $format, $_[0]{rbuf} }) |
1178 |
or return; |
1179 |
|
1180 |
$format = length pack $format, $len; |
1181 |
|
1182 |
# bypass unshift if we already have the remaining chunk |
1183 |
if ($format + $len <= length $_[0]{rbuf}) { |
1184 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1185 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1186 |
$cb->($_[0], $data); |
1187 |
} else { |
1188 |
# remove prefix |
1189 |
substr $_[0]{rbuf}, 0, $format, ""; |
1190 |
|
1191 |
# read remaining chunk |
1192 |
$_[0]->unshift_read (chunk => $len, $cb); |
1193 |
} |
1194 |
|
1195 |
1 |
1196 |
} |
1197 |
}; |
1198 |
|
1199 |
=item json => $cb->($handle, $hash_or_arrayref) |
1200 |
|
1201 |
Reads a JSON object or array, decodes it and passes it to the |
1202 |
callback. When a parse error occurs, an C<EBADMSG> error will be raised. |
1203 |
|
1204 |
If a C<json> object was passed to the constructor, then that will be used |
1205 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1206 |
|
1207 |
This read type uses the incremental parser available with JSON version |
1208 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1209 |
dependency on your own: this module will load the JSON module, but |
1210 |
AnyEvent does not depend on it itself. |
1211 |
|
1212 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1213 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1214 |
the C<json> write type description, above, for an actual example. |
1215 |
|
1216 |
=cut |
1217 |
|
1218 |
register_read_type json => sub { |
1219 |
my ($self, $cb) = @_; |
1220 |
|
1221 |
require JSON; |
1222 |
|
1223 |
my $data; |
1224 |
my $rbuf = \$self->{rbuf}; |
1225 |
|
1226 |
my $json = $self->{json} ||= JSON->new->utf8; |
1227 |
|
1228 |
sub { |
1229 |
my $ref = eval { $json->incr_parse ($self->{rbuf}) }; |
1230 |
|
1231 |
if ($ref) { |
1232 |
$self->{rbuf} = $json->incr_text; |
1233 |
$json->incr_text = ""; |
1234 |
$cb->($self, $ref); |
1235 |
|
1236 |
1 |
1237 |
} elsif ($@) { |
1238 |
# error case |
1239 |
$json->incr_skip; |
1240 |
|
1241 |
$self->{rbuf} = $json->incr_text; |
1242 |
$json->incr_text = ""; |
1243 |
|
1244 |
$self->_error (&Errno::EBADMSG); |
1245 |
|
1246 |
() |
1247 |
} else { |
1248 |
$self->{rbuf} = ""; |
1249 |
|
1250 |
() |
1251 |
} |
1252 |
} |
1253 |
}; |
1254 |
|
1255 |
=item storable => $cb->($handle, $ref) |
1256 |
|
1257 |
Deserialises a L<Storable> frozen representation as written by the |
1258 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1259 |
data). |
1260 |
|
1261 |
Raises C<EBADMSG> error if the data could not be decoded. |
1262 |
|
1263 |
=cut |
1264 |
|
1265 |
register_read_type storable => sub { |
1266 |
my ($self, $cb) = @_; |
1267 |
|
1268 |
require Storable; |
1269 |
|
1270 |
sub { |
1271 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1272 |
defined (my $len = eval { unpack "w", $_[0]{rbuf} }) |
1273 |
or return; |
1274 |
|
1275 |
my $format = length pack "w", $len; |
1276 |
|
1277 |
# bypass unshift if we already have the remaining chunk |
1278 |
if ($format + $len <= length $_[0]{rbuf}) { |
1279 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1280 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1281 |
$cb->($_[0], Storable::thaw ($data)); |
1282 |
} else { |
1283 |
# remove prefix |
1284 |
substr $_[0]{rbuf}, 0, $format, ""; |
1285 |
|
1286 |
# read remaining chunk |
1287 |
$_[0]->unshift_read (chunk => $len, sub { |
1288 |
if (my $ref = eval { Storable::thaw ($_[1]) }) { |
1289 |
$cb->($_[0], $ref); |
1290 |
} else { |
1291 |
$self->_error (&Errno::EBADMSG); |
1292 |
} |
1293 |
}); |
1294 |
} |
1295 |
|
1296 |
1 |
1297 |
} |
1298 |
}; |
1299 |
|
1300 |
=back |
1301 |
|
1302 |
=item AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args) |
1303 |
|
1304 |
This function (not method) lets you add your own types to C<push_read>. |
1305 |
|
1306 |
Whenever the given C<type> is used, C<push_read> will invoke the code |
1307 |
reference with the handle object, the callback and the remaining |
1308 |
arguments. |
1309 |
|
1310 |
The code reference is supposed to return a callback (usually a closure) |
1311 |
that works as a plain read callback (see C<< ->push_read ($cb) >>). |
1312 |
|
1313 |
It should invoke the passed callback when it is done reading (remember to |
1314 |
pass C<$handle> as first argument as all other callbacks do that). |
1315 |
|
1316 |
Note that this is a function, and all types registered this way will be |
1317 |
global, so try to use unique names. |
1318 |
|
1319 |
For examples, see the source of this module (F<perldoc -m AnyEvent::Handle>, |
1320 |
search for C<register_read_type>)). |
1321 |
|
1322 |
=item $handle->stop_read |
1323 |
|
1324 |
=item $handle->start_read |
1325 |
|
1326 |
In rare cases you actually do not want to read anything from the |
1327 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1328 |
any queued callbacks will be executed then. To start reading again, call |
1329 |
C<start_read>. |
1330 |
|
1331 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1332 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1333 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1334 |
there are any read requests in the queue. |
1335 |
|
1336 |
These methods will have no effect when in TLS mode (as TLS doesn't support |
1337 |
half-duplex connections). |
1338 |
|
1339 |
=cut |
1340 |
|
1341 |
sub stop_read { |
1342 |
my ($self) = @_; |
1343 |
|
1344 |
delete $self->{_rw} unless $self->{tls}; |
1345 |
} |
1346 |
|
1347 |
sub start_read { |
1348 |
my ($self) = @_; |
1349 |
|
1350 |
unless ($self->{_rw} || $self->{_eof}) { |
1351 |
Scalar::Util::weaken $self; |
1352 |
|
1353 |
$self->{_rw} = AnyEvent->io (fh => $self->{fh}, poll => "r", cb => sub { |
1354 |
my $rbuf = \($self->{tls} ? my $buf : $self->{rbuf}); |
1355 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size} || 8192, length $$rbuf; |
1356 |
|
1357 |
if ($len > 0) { |
1358 |
$self->{_activity} = AnyEvent->now; |
1359 |
|
1360 |
if ($self->{tls}) { |
1361 |
Net::SSLeay::BIO_write ($self->{_rbio}, $$rbuf); |
1362 |
|
1363 |
&_dotls ($self); |
1364 |
} else { |
1365 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1366 |
} |
1367 |
|
1368 |
} elsif (defined $len) { |
1369 |
delete $self->{_rw}; |
1370 |
$self->{_eof} = 1; |
1371 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1372 |
|
1373 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1374 |
return $self->_error ($!, 1); |
1375 |
} |
1376 |
}); |
1377 |
} |
1378 |
} |
1379 |
|
1380 |
our $ERROR_SYSCALL; |
1381 |
our $ERROR_WANT_READ; |
1382 |
our $ERROR_ZERO_RETURN; |
1383 |
|
1384 |
sub _tls_error { |
1385 |
my ($self, $err) = @_; |
1386 |
warn "$err,$!\n";#d# |
1387 |
|
1388 |
return $self->_error ($!, 1) |
1389 |
if $err == Net::SSLeay::ERROR_SYSCALL (); |
1390 |
|
1391 |
$self->_error (&Errno::EPROTO, 1, |
1392 |
Net::SSLeay::ERR_error_string (Net::SSLeay::ERR_get_error ())); |
1393 |
} |
1394 |
|
1395 |
# poll the write BIO and send the data if applicable |
1396 |
# also decode read data if possible |
1397 |
# this is basiclaly our TLS state machine |
1398 |
# more efficient implementations are possible with openssl, |
1399 |
# but not with the buggy and incomplete Net::SSLeay. |
1400 |
sub _dotls { |
1401 |
my ($self) = @_; |
1402 |
|
1403 |
my $tmp; |
1404 |
|
1405 |
if (length $self->{_tls_wbuf}) { |
1406 |
while (($tmp = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1407 |
substr $self->{_tls_wbuf}, 0, $tmp, ""; |
1408 |
} |
1409 |
|
1410 |
$tmp = Net::SSLeay::get_error ($self->{tls}, $tmp); |
1411 |
return $self->_tls_error ($tmp) |
1412 |
if $tmp != $ERROR_WANT_READ |
1413 |
&& ($tmp != $ERROR_SYSCALL || $!) |
1414 |
&& $tmp != $ERROR_ZERO_RETURN; |
1415 |
} |
1416 |
|
1417 |
while (defined ($tmp = Net::SSLeay::read ($self->{tls}))) { |
1418 |
unless (length $tmp) { |
1419 |
# let's treat SSL-eof as we treat normal EOF |
1420 |
delete $self->{_rw}; |
1421 |
$self->{_eof} = 1; |
1422 |
&_freetls; |
1423 |
} |
1424 |
|
1425 |
$self->{_tls_rbuf} .= $tmp; |
1426 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1427 |
$self->{tls} or return; # tls session might have gone away in callback |
1428 |
} |
1429 |
|
1430 |
$tmp = Net::SSLeay::get_error ($self->{tls}, -1); |
1431 |
return $self->_tls_error ($tmp) |
1432 |
if $tmp != $ERROR_WANT_READ |
1433 |
&& ($tmp != $ERROR_SYSCALL || $!) |
1434 |
&& $tmp != $ERROR_ZERO_RETURN; |
1435 |
|
1436 |
while (length ($tmp = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1437 |
$self->{wbuf} .= $tmp; |
1438 |
$self->_drain_wbuf; |
1439 |
} |
1440 |
} |
1441 |
|
1442 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1443 |
|
1444 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1445 |
object is created, you can also do that at a later time by calling |
1446 |
C<starttls>. |
1447 |
|
1448 |
The first argument is the same as the C<tls> constructor argument (either |
1449 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1450 |
|
1451 |
The second argument is the optional C<AnyEvent::TLS> object that is used |
1452 |
when AnyEvent::Handle has to create its own TLS connection object, or |
1453 |
a hash reference with C<< key => value >> pairs that will be used to |
1454 |
construct a new context. |
1455 |
|
1456 |
The TLS connection object will end up in C<< $handle->{tls} >>, the TLS |
1457 |
context in C<< $handle->{tls_ctx} >> after this call and can be used or |
1458 |
changed to your liking. Note that the handshake might have already started |
1459 |
when this function returns. |
1460 |
|
1461 |
If it an error to start a TLS handshake more than once per |
1462 |
AnyEvent::Handle object (this is due to bugs in OpenSSL). |
1463 |
|
1464 |
=cut |
1465 |
|
1466 |
sub starttls { |
1467 |
my ($self, $ssl, $ctx) = @_; |
1468 |
|
1469 |
require Net::SSLeay; |
1470 |
|
1471 |
Carp::croak "it is an error to call starttls more than once on an AnyEvent::Handle object" |
1472 |
if $self->{tls}; |
1473 |
|
1474 |
$ERROR_SYSCALL = Net::SSLeay::ERROR_SYSCALL (); |
1475 |
$ERROR_WANT_READ = Net::SSLeay::ERROR_WANT_READ (); |
1476 |
$ERROR_ZERO_RETURN = Net::SSLeay::ERROR_ZERO_RETURN (); |
1477 |
|
1478 |
$ctx ||= $self->{tls_ctx}; |
1479 |
|
1480 |
if ("HASH" eq ref $ctx) { |
1481 |
require AnyEvent::TLS; |
1482 |
|
1483 |
local $Carp::CarpLevel = 1; # skip ourselves when creating a new context |
1484 |
$ctx = new AnyEvent::TLS %$ctx; |
1485 |
} |
1486 |
|
1487 |
$self->{tls_ctx} = $ctx || TLS_CTX (); |
1488 |
$self->{tls} = $ssl = $self->{tls_ctx}->_get_session ($ssl, $self, $self->{peername}); |
1489 |
|
1490 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1491 |
# but the openssl maintainers basically said: "trust us, it just works". |
1492 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1493 |
# and mismaintained ssleay-module doesn't even offer them). |
1494 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1495 |
# |
1496 |
# in short: this is a mess. |
1497 |
# |
1498 |
# note that we do not try to keep the length constant between writes as we are required to do. |
1499 |
# we assume that most (but not all) of this insanity only applies to non-blocking cases, |
1500 |
# and we drive openssl fully in blocking mode here. Or maybe we don't - openssl seems to |
1501 |
# have identity issues in that area. |
1502 |
# Net::SSLeay::CTX_set_mode ($ssl, |
1503 |
# (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1504 |
# | (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1505 |
Net::SSLeay::CTX_set_mode ($ssl, 1|2); |
1506 |
|
1507 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1508 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1509 |
|
1510 |
Net::SSLeay::set_bio ($ssl, $self->{_rbio}, $self->{_wbio}); |
1511 |
|
1512 |
&_dotls; # need to trigger the initial handshake |
1513 |
$self->start_read; # make sure we actually do read |
1514 |
} |
1515 |
|
1516 |
=item $handle->stoptls |
1517 |
|
1518 |
Shuts down the SSL connection - this makes a proper EOF handshake by |
1519 |
sending a close notify to the other side, but since OpenSSL doesn't |
1520 |
support non-blocking shut downs, it is not possible to re-use the stream |
1521 |
afterwards. |
1522 |
|
1523 |
=cut |
1524 |
|
1525 |
sub stoptls { |
1526 |
my ($self) = @_; |
1527 |
|
1528 |
if ($self->{tls}) { |
1529 |
Net::SSLeay::shutdown ($self->{tls}); |
1530 |
|
1531 |
&_dotls; |
1532 |
|
1533 |
# we don't give a shit. no, we do, but we can't. no... |
1534 |
# we, we... have to use openssl :/ |
1535 |
&_freetls; |
1536 |
} |
1537 |
} |
1538 |
|
1539 |
sub _freetls { |
1540 |
my ($self) = @_; |
1541 |
|
1542 |
return unless $self->{tls}; |
1543 |
|
1544 |
$self->{tls_ctx}->_put_session (delete $self->{tls}); |
1545 |
|
1546 |
delete @$self{qw(_rbio _wbio _tls_wbuf)}; |
1547 |
} |
1548 |
|
1549 |
sub DESTROY { |
1550 |
my ($self) = @_; |
1551 |
|
1552 |
&_freetls; |
1553 |
|
1554 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
1555 |
|
1556 |
if ($linger && length $self->{wbuf}) { |
1557 |
my $fh = delete $self->{fh}; |
1558 |
my $wbuf = delete $self->{wbuf}; |
1559 |
|
1560 |
my @linger; |
1561 |
|
1562 |
push @linger, AnyEvent->io (fh => $fh, poll => "w", cb => sub { |
1563 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
1564 |
|
1565 |
if ($len > 0) { |
1566 |
substr $wbuf, 0, $len, ""; |
1567 |
} else { |
1568 |
@linger = (); # end |
1569 |
} |
1570 |
}); |
1571 |
push @linger, AnyEvent->timer (after => $linger, cb => sub { |
1572 |
@linger = (); |
1573 |
}); |
1574 |
} |
1575 |
} |
1576 |
|
1577 |
=item $handle->destroy |
1578 |
|
1579 |
Shuts down the handle object as much as possible - this call ensures that |
1580 |
no further callbacks will be invoked and resources will be freed as much |
1581 |
as possible. You must not call any methods on the object afterwards. |
1582 |
|
1583 |
Normally, you can just "forget" any references to an AnyEvent::Handle |
1584 |
object and it will simply shut down. This works in fatal error and EOF |
1585 |
callbacks, as well as code outside. It does I<NOT> work in a read or write |
1586 |
callback, so when you want to destroy the AnyEvent::Handle object from |
1587 |
within such an callback. You I<MUST> call C<< ->destroy >> explicitly in |
1588 |
that case. |
1589 |
|
1590 |
The handle might still linger in the background and write out remaining |
1591 |
data, as specified by the C<linger> option, however. |
1592 |
|
1593 |
=cut |
1594 |
|
1595 |
sub destroy { |
1596 |
my ($self) = @_; |
1597 |
|
1598 |
$self->DESTROY; |
1599 |
%$self = (); |
1600 |
} |
1601 |
|
1602 |
=item AnyEvent::Handle::TLS_CTX |
1603 |
|
1604 |
This function creates and returns the AnyEvent::TLS object used by default |
1605 |
for TLS mode. |
1606 |
|
1607 |
The context is created by calling L<AnyEvent::TLS> without any arguments. |
1608 |
|
1609 |
=cut |
1610 |
|
1611 |
our $TLS_CTX; |
1612 |
|
1613 |
sub TLS_CTX() { |
1614 |
$TLS_CTX ||= do { |
1615 |
require AnyEvent::TLS; |
1616 |
|
1617 |
new AnyEvent::TLS |
1618 |
} |
1619 |
} |
1620 |
|
1621 |
=back |
1622 |
|
1623 |
|
1624 |
=head1 NONFREQUENTLY ASKED QUESTIONS |
1625 |
|
1626 |
=over 4 |
1627 |
|
1628 |
=item I C<undef> the AnyEvent::Handle reference inside my callback and |
1629 |
still get further invocations! |
1630 |
|
1631 |
That's because AnyEvent::Handle keeps a reference to itself when handling |
1632 |
read or write callbacks. |
1633 |
|
1634 |
It is only safe to "forget" the reference inside EOF or error callbacks, |
1635 |
from within all other callbacks, you need to explicitly call the C<< |
1636 |
->destroy >> method. |
1637 |
|
1638 |
=item I get different callback invocations in TLS mode/Why can't I pause |
1639 |
reading? |
1640 |
|
1641 |
Unlike, say, TCP, TLS connections do not consist of two independent |
1642 |
communication channels, one for each direction. Or put differently. The |
1643 |
read and write directions are not independent of each other: you cannot |
1644 |
write data unless you are also prepared to read, and vice versa. |
1645 |
|
1646 |
This can mean than, in TLS mode, you might get C<on_error> or C<on_eof> |
1647 |
callback invocations when you are not expecting any read data - the reason |
1648 |
is that AnyEvent::Handle always reads in TLS mode. |
1649 |
|
1650 |
During the connection, you have to make sure that you always have a |
1651 |
non-empty read-queue, or an C<on_read> watcher. At the end of the |
1652 |
connection (or when you no longer want to use it) you can call the |
1653 |
C<destroy> method. |
1654 |
|
1655 |
=item How do I read data until the other side closes the connection? |
1656 |
|
1657 |
If you just want to read your data into a perl scalar, the easiest way |
1658 |
to achieve this is by setting an C<on_read> callback that does nothing, |
1659 |
clearing the C<on_eof> callback and in the C<on_error> callback, the data |
1660 |
will be in C<$_[0]{rbuf}>: |
1661 |
|
1662 |
$handle->on_read (sub { }); |
1663 |
$handle->on_eof (undef); |
1664 |
$handle->on_error (sub { |
1665 |
my $data = delete $_[0]{rbuf}; |
1666 |
undef $handle; |
1667 |
}); |
1668 |
|
1669 |
The reason to use C<on_error> is that TCP connections, due to latencies |
1670 |
and packets loss, might get closed quite violently with an error, when in |
1671 |
fact, all data has been received. |
1672 |
|
1673 |
It is usually better to use acknowledgements when transferring data, |
1674 |
to make sure the other side hasn't just died and you got the data |
1675 |
intact. This is also one reason why so many internet protocols have an |
1676 |
explicit QUIT command. |
1677 |
|
1678 |
=item I don't want to destroy the handle too early - how do I wait until |
1679 |
all data has been written? |
1680 |
|
1681 |
After writing your last bits of data, set the C<on_drain> callback |
1682 |
and destroy the handle in there - with the default setting of |
1683 |
C<low_water_mark> this will be called precisely when all data has been |
1684 |
written to the socket: |
1685 |
|
1686 |
$handle->push_write (...); |
1687 |
$handle->on_drain (sub { |
1688 |
warn "all data submitted to the kernel\n"; |
1689 |
undef $handle; |
1690 |
}); |
1691 |
|
1692 |
=back |
1693 |
|
1694 |
|
1695 |
=head1 SUBCLASSING AnyEvent::Handle |
1696 |
|
1697 |
In many cases, you might want to subclass AnyEvent::Handle. |
1698 |
|
1699 |
To make this easier, a given version of AnyEvent::Handle uses these |
1700 |
conventions: |
1701 |
|
1702 |
=over 4 |
1703 |
|
1704 |
=item * all constructor arguments become object members. |
1705 |
|
1706 |
At least initially, when you pass a C<tls>-argument to the constructor it |
1707 |
will end up in C<< $handle->{tls} >>. Those members might be changed or |
1708 |
mutated later on (for example C<tls> will hold the TLS connection object). |
1709 |
|
1710 |
=item * other object member names are prefixed with an C<_>. |
1711 |
|
1712 |
All object members not explicitly documented (internal use) are prefixed |
1713 |
with an underscore character, so the remaining non-C<_>-namespace is free |
1714 |
for use for subclasses. |
1715 |
|
1716 |
=item * all members not documented here and not prefixed with an underscore |
1717 |
are free to use in subclasses. |
1718 |
|
1719 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
1720 |
member variables, but thats just life, at least it is documented. |
1721 |
|
1722 |
=back |
1723 |
|
1724 |
=head1 AUTHOR |
1725 |
|
1726 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
1727 |
|
1728 |
=cut |
1729 |
|
1730 |
1; # End of AnyEvent::Handle |