1 |
package AnyEvent::Handle; |
2 |
|
3 |
no warnings; |
4 |
use strict; |
5 |
|
6 |
use AnyEvent (); |
7 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
8 |
use Scalar::Util (); |
9 |
use Carp (); |
10 |
use Fcntl (); |
11 |
use Errno qw(EAGAIN EINTR); |
12 |
|
13 |
=head1 NAME |
14 |
|
15 |
AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent |
16 |
|
17 |
=cut |
18 |
|
19 |
our $VERSION = 4.22; |
20 |
|
21 |
=head1 SYNOPSIS |
22 |
|
23 |
use AnyEvent; |
24 |
use AnyEvent::Handle; |
25 |
|
26 |
my $cv = AnyEvent->condvar; |
27 |
|
28 |
my $handle = |
29 |
AnyEvent::Handle->new ( |
30 |
fh => \*STDIN, |
31 |
on_eof => sub { |
32 |
$cv->broadcast; |
33 |
}, |
34 |
); |
35 |
|
36 |
# send some request line |
37 |
$handle->push_write ("getinfo\015\012"); |
38 |
|
39 |
# read the response line |
40 |
$handle->push_read (line => sub { |
41 |
my ($handle, $line) = @_; |
42 |
warn "read line <$line>\n"; |
43 |
$cv->send; |
44 |
}); |
45 |
|
46 |
$cv->recv; |
47 |
|
48 |
=head1 DESCRIPTION |
49 |
|
50 |
This module is a helper module to make it easier to do event-based I/O on |
51 |
filehandles. For utility functions for doing non-blocking connects and accepts |
52 |
on sockets see L<AnyEvent::Util>. |
53 |
|
54 |
In the following, when the documentation refers to of "bytes" then this |
55 |
means characters. As sysread and syswrite are used for all I/O, their |
56 |
treatment of characters applies to this module as well. |
57 |
|
58 |
All callbacks will be invoked with the handle object as their first |
59 |
argument. |
60 |
|
61 |
=head1 METHODS |
62 |
|
63 |
=over 4 |
64 |
|
65 |
=item B<new (%args)> |
66 |
|
67 |
The constructor supports these arguments (all as key => value pairs). |
68 |
|
69 |
=over 4 |
70 |
|
71 |
=item fh => $filehandle [MANDATORY] |
72 |
|
73 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
74 |
|
75 |
NOTE: The filehandle will be set to non-blocking (using |
76 |
AnyEvent::Util::fh_nonblocking). |
77 |
|
78 |
=item on_eof => $cb->($handle) |
79 |
|
80 |
Set the callback to be called when an end-of-file condition is detected, |
81 |
i.e. in the case of a socket, when the other side has closed the |
82 |
connection cleanly. |
83 |
|
84 |
While not mandatory, it is highly recommended to set an eof callback, |
85 |
otherwise you might end up with a closed socket while you are still |
86 |
waiting for data. |
87 |
|
88 |
=item on_error => $cb->($handle, $fatal) |
89 |
|
90 |
This is the error callback, which is called when, well, some error |
91 |
occured, such as not being able to resolve the hostname, failure to |
92 |
connect or a read error. |
93 |
|
94 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
95 |
fatal errors the handle object will be shut down and will not be |
96 |
usable. Non-fatal errors can be retried by simply returning, but it is |
97 |
recommended to simply ignore this parameter and instead abondon the handle |
98 |
object when this callback is invoked. |
99 |
|
100 |
On callback entrance, the value of C<$!> contains the operating system |
101 |
error (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT> or C<EBADMSG>). |
102 |
|
103 |
While not mandatory, it is I<highly> recommended to set this callback, as |
104 |
you will not be notified of errors otherwise. The default simply calls |
105 |
C<croak>. |
106 |
|
107 |
=item on_read => $cb->($handle) |
108 |
|
109 |
This sets the default read callback, which is called when data arrives |
110 |
and no read request is in the queue (unlike read queue callbacks, this |
111 |
callback will only be called when at least one octet of data is in the |
112 |
read buffer). |
113 |
|
114 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
115 |
method or access the C<$handle->{rbuf}> member directly. |
116 |
|
117 |
When an EOF condition is detected then AnyEvent::Handle will first try to |
118 |
feed all the remaining data to the queued callbacks and C<on_read> before |
119 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
120 |
error will be raised (with C<$!> set to C<EPIPE>). |
121 |
|
122 |
=item on_drain => $cb->($handle) |
123 |
|
124 |
This sets the callback that is called when the write buffer becomes empty |
125 |
(or when the callback is set and the buffer is empty already). |
126 |
|
127 |
To append to the write buffer, use the C<< ->push_write >> method. |
128 |
|
129 |
This callback is useful when you don't want to put all of your write data |
130 |
into the queue at once, for example, when you want to write the contents |
131 |
of some file to the socket you might not want to read the whole file into |
132 |
memory and push it into the queue, but instead only read more data from |
133 |
the file when the write queue becomes empty. |
134 |
|
135 |
=item timeout => $fractional_seconds |
136 |
|
137 |
If non-zero, then this enables an "inactivity" timeout: whenever this many |
138 |
seconds pass without a successful read or write on the underlying file |
139 |
handle, the C<on_timeout> callback will be invoked (and if that one is |
140 |
missing, an C<ETIMEDOUT> error will be raised). |
141 |
|
142 |
Note that timeout processing is also active when you currently do not have |
143 |
any outstanding read or write requests: If you plan to keep the connection |
144 |
idle then you should disable the timout temporarily or ignore the timeout |
145 |
in the C<on_timeout> callback. |
146 |
|
147 |
Zero (the default) disables this timeout. |
148 |
|
149 |
=item on_timeout => $cb->($handle) |
150 |
|
151 |
Called whenever the inactivity timeout passes. If you return from this |
152 |
callback, then the timeout will be reset as if some activity had happened, |
153 |
so this condition is not fatal in any way. |
154 |
|
155 |
=item rbuf_max => <bytes> |
156 |
|
157 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
158 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
159 |
avoid denial-of-service attacks. |
160 |
|
161 |
For example, a server accepting connections from untrusted sources should |
162 |
be configured to accept only so-and-so much data that it cannot act on |
163 |
(for example, when expecting a line, an attacker could send an unlimited |
164 |
amount of data without a callback ever being called as long as the line |
165 |
isn't finished). |
166 |
|
167 |
=item autocork => <boolean> |
168 |
|
169 |
When disabled (the default), then C<push_write> will try to immediately |
170 |
write the data to the handle if possible. This avoids having to register |
171 |
a write watcher and wait for the next event loop iteration, but can be |
172 |
inefficient if you write multiple small chunks (this disadvantage is |
173 |
usually avoided by your kernel's nagle algorithm, see C<low_delay>). |
174 |
|
175 |
When enabled, then writes will always be queued till the next event loop |
176 |
iteration. This is efficient when you do many small writes per iteration, |
177 |
but less efficient when you do a single write only. |
178 |
|
179 |
=item no_delay => <boolean> |
180 |
|
181 |
When doing small writes on sockets, your operating system kernel might |
182 |
wait a bit for more data before actually sending it out. This is called |
183 |
the Nagle algorithm, and usually it is beneficial. |
184 |
|
185 |
In some situations you want as low a delay as possible, which cna be |
186 |
accomplishd by setting this option to true. |
187 |
|
188 |
The default is your opertaing system's default behaviour, this option |
189 |
explicitly enables or disables it, if possible. |
190 |
|
191 |
=item read_size => <bytes> |
192 |
|
193 |
The default read block size (the amount of bytes this module will try to read |
194 |
during each (loop iteration). Default: C<8192>. |
195 |
|
196 |
=item low_water_mark => <bytes> |
197 |
|
198 |
Sets the amount of bytes (default: C<0>) that make up an "empty" write |
199 |
buffer: If the write reaches this size or gets even samller it is |
200 |
considered empty. |
201 |
|
202 |
=item linger => <seconds> |
203 |
|
204 |
If non-zero (default: C<3600>), then the destructor of the |
205 |
AnyEvent::Handle object will check wether there is still outstanding write |
206 |
data and will install a watcher that will write out this data. No errors |
207 |
will be reported (this mostly matches how the operating system treats |
208 |
outstanding data at socket close time). |
209 |
|
210 |
This will not work for partial TLS data that could not yet been |
211 |
encoded. This data will be lost. |
212 |
|
213 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
214 |
|
215 |
When this parameter is given, it enables TLS (SSL) mode, that means it |
216 |
will start making tls handshake and will transparently encrypt/decrypt |
217 |
data. |
218 |
|
219 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
220 |
automatically when you try to create a TLS handle). |
221 |
|
222 |
For the TLS server side, use C<accept>, and for the TLS client side of a |
223 |
connection, use C<connect> mode. |
224 |
|
225 |
You can also provide your own TLS connection object, but you have |
226 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
227 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
228 |
AnyEvent::Handle. |
229 |
|
230 |
See the C<starttls> method if you need to start TLS negotiation later. |
231 |
|
232 |
=item tls_ctx => $ssl_ctx |
233 |
|
234 |
Use the given Net::SSLeay::CTX object to create the new TLS connection |
235 |
(unless a connection object was specified directly). If this parameter is |
236 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
237 |
|
238 |
=item json => JSON or JSON::XS object |
239 |
|
240 |
This is the json coder object used by the C<json> read and write types. |
241 |
|
242 |
If you don't supply it, then AnyEvent::Handle will create and use a |
243 |
suitable one, which will write and expect UTF-8 encoded JSON texts. |
244 |
|
245 |
Note that you are responsible to depend on the JSON module if you want to |
246 |
use this functionality, as AnyEvent does not have a dependency itself. |
247 |
|
248 |
=item filter_r => $cb |
249 |
|
250 |
=item filter_w => $cb |
251 |
|
252 |
These exist, but are undocumented at this time. |
253 |
|
254 |
=back |
255 |
|
256 |
=cut |
257 |
|
258 |
sub new { |
259 |
my $class = shift; |
260 |
|
261 |
my $self = bless { @_ }, $class; |
262 |
|
263 |
$self->{fh} or Carp::croak "mandatory argument fh is missing"; |
264 |
|
265 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
266 |
|
267 |
if ($self->{tls}) { |
268 |
require Net::SSLeay; |
269 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}); |
270 |
} |
271 |
|
272 |
$self->{_activity} = AnyEvent->now; |
273 |
$self->_timeout; |
274 |
|
275 |
$self->on_drain (delete $self->{on_drain}) if exists $self->{on_drain}; |
276 |
$self->no_delay (delete $self->{no_delay}) if exists $self->{no_delay}; |
277 |
|
278 |
$self->start_read |
279 |
if $self->{on_read}; |
280 |
|
281 |
$self |
282 |
} |
283 |
|
284 |
sub _shutdown { |
285 |
my ($self) = @_; |
286 |
|
287 |
delete $self->{_tw}; |
288 |
delete $self->{_rw}; |
289 |
delete $self->{_ww}; |
290 |
delete $self->{fh}; |
291 |
|
292 |
$self->stoptls; |
293 |
} |
294 |
|
295 |
sub _error { |
296 |
my ($self, $errno, $fatal) = @_; |
297 |
|
298 |
$self->_shutdown |
299 |
if $fatal; |
300 |
|
301 |
$! = $errno; |
302 |
|
303 |
if ($self->{on_error}) { |
304 |
$self->{on_error}($self, $fatal); |
305 |
} else { |
306 |
Carp::croak "AnyEvent::Handle uncaught error: $!"; |
307 |
} |
308 |
} |
309 |
|
310 |
=item $fh = $handle->fh |
311 |
|
312 |
This method returns the file handle of the L<AnyEvent::Handle> object. |
313 |
|
314 |
=cut |
315 |
|
316 |
sub fh { $_[0]{fh} } |
317 |
|
318 |
=item $handle->on_error ($cb) |
319 |
|
320 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
321 |
|
322 |
=cut |
323 |
|
324 |
sub on_error { |
325 |
$_[0]{on_error} = $_[1]; |
326 |
} |
327 |
|
328 |
=item $handle->on_eof ($cb) |
329 |
|
330 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
331 |
|
332 |
=cut |
333 |
|
334 |
sub on_eof { |
335 |
$_[0]{on_eof} = $_[1]; |
336 |
} |
337 |
|
338 |
=item $handle->on_timeout ($cb) |
339 |
|
340 |
Replace the current C<on_timeout> callback, or disables the callback |
341 |
(but not the timeout) if C<$cb> = C<undef>. See C<timeout> constructor |
342 |
argument. |
343 |
|
344 |
=cut |
345 |
|
346 |
sub on_timeout { |
347 |
$_[0]{on_timeout} = $_[1]; |
348 |
} |
349 |
|
350 |
=item $handle->autocork ($boolean) |
351 |
|
352 |
Enables or disables the current autocork behaviour (see C<autocork> |
353 |
constructor argument). |
354 |
|
355 |
=cut |
356 |
|
357 |
=item $handle->no_delay ($boolean) |
358 |
|
359 |
Enables or disables the C<no_delay> setting (see constructor argument of |
360 |
the same name for details). |
361 |
|
362 |
=cut |
363 |
|
364 |
sub no_delay { |
365 |
$_[0]{no_delay} = $_[1]; |
366 |
|
367 |
eval { |
368 |
local $SIG{__DIE__}; |
369 |
setsockopt $_[0]{fh}, &Socket::IPPROTO_TCP, &Socket::TCP_NODELAY, int $_[1]; |
370 |
}; |
371 |
} |
372 |
|
373 |
############################################################################# |
374 |
|
375 |
=item $handle->timeout ($seconds) |
376 |
|
377 |
Configures (or disables) the inactivity timeout. |
378 |
|
379 |
=cut |
380 |
|
381 |
sub timeout { |
382 |
my ($self, $timeout) = @_; |
383 |
|
384 |
$self->{timeout} = $timeout; |
385 |
$self->_timeout; |
386 |
} |
387 |
|
388 |
# reset the timeout watcher, as neccessary |
389 |
# also check for time-outs |
390 |
sub _timeout { |
391 |
my ($self) = @_; |
392 |
|
393 |
if ($self->{timeout}) { |
394 |
my $NOW = AnyEvent->now; |
395 |
|
396 |
# when would the timeout trigger? |
397 |
my $after = $self->{_activity} + $self->{timeout} - $NOW; |
398 |
|
399 |
# now or in the past already? |
400 |
if ($after <= 0) { |
401 |
$self->{_activity} = $NOW; |
402 |
|
403 |
if ($self->{on_timeout}) { |
404 |
$self->{on_timeout}($self); |
405 |
} else { |
406 |
$self->_error (&Errno::ETIMEDOUT); |
407 |
} |
408 |
|
409 |
# callback could have changed timeout value, optimise |
410 |
return unless $self->{timeout}; |
411 |
|
412 |
# calculate new after |
413 |
$after = $self->{timeout}; |
414 |
} |
415 |
|
416 |
Scalar::Util::weaken $self; |
417 |
return unless $self; # ->error could have destroyed $self |
418 |
|
419 |
$self->{_tw} ||= AnyEvent->timer (after => $after, cb => sub { |
420 |
delete $self->{_tw}; |
421 |
$self->_timeout; |
422 |
}); |
423 |
} else { |
424 |
delete $self->{_tw}; |
425 |
} |
426 |
} |
427 |
|
428 |
############################################################################# |
429 |
|
430 |
=back |
431 |
|
432 |
=head2 WRITE QUEUE |
433 |
|
434 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
435 |
for reading. |
436 |
|
437 |
The write queue is very simple: you can add data to its end, and |
438 |
AnyEvent::Handle will automatically try to get rid of it for you. |
439 |
|
440 |
When data could be written and the write buffer is shorter then the low |
441 |
water mark, the C<on_drain> callback will be invoked. |
442 |
|
443 |
=over 4 |
444 |
|
445 |
=item $handle->on_drain ($cb) |
446 |
|
447 |
Sets the C<on_drain> callback or clears it (see the description of |
448 |
C<on_drain> in the constructor). |
449 |
|
450 |
=cut |
451 |
|
452 |
sub on_drain { |
453 |
my ($self, $cb) = @_; |
454 |
|
455 |
$self->{on_drain} = $cb; |
456 |
|
457 |
$cb->($self) |
458 |
if $cb && $self->{low_water_mark} >= length $self->{wbuf}; |
459 |
} |
460 |
|
461 |
=item $handle->push_write ($data) |
462 |
|
463 |
Queues the given scalar to be written. You can push as much data as you |
464 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
465 |
buffers it independently of the kernel. |
466 |
|
467 |
=cut |
468 |
|
469 |
sub _drain_wbuf { |
470 |
my ($self) = @_; |
471 |
|
472 |
if (!$self->{_ww} && length $self->{wbuf}) { |
473 |
|
474 |
Scalar::Util::weaken $self; |
475 |
|
476 |
my $cb = sub { |
477 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
478 |
|
479 |
if ($len >= 0) { |
480 |
substr $self->{wbuf}, 0, $len, ""; |
481 |
|
482 |
$self->{_activity} = AnyEvent->now; |
483 |
|
484 |
$self->{on_drain}($self) |
485 |
if $self->{low_water_mark} >= length $self->{wbuf} |
486 |
&& $self->{on_drain}; |
487 |
|
488 |
delete $self->{_ww} unless length $self->{wbuf}; |
489 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
490 |
$self->_error ($!, 1); |
491 |
} |
492 |
}; |
493 |
|
494 |
# try to write data immediately |
495 |
$cb->() unless $self->{autocork}; |
496 |
|
497 |
# if still data left in wbuf, we need to poll |
498 |
$self->{_ww} = AnyEvent->io (fh => $self->{fh}, poll => "w", cb => $cb) |
499 |
if length $self->{wbuf}; |
500 |
}; |
501 |
} |
502 |
|
503 |
our %WH; |
504 |
|
505 |
sub register_write_type($$) { |
506 |
$WH{$_[0]} = $_[1]; |
507 |
} |
508 |
|
509 |
sub push_write { |
510 |
my $self = shift; |
511 |
|
512 |
if (@_ > 1) { |
513 |
my $type = shift; |
514 |
|
515 |
@_ = ($WH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_write") |
516 |
->($self, @_); |
517 |
} |
518 |
|
519 |
if ($self->{filter_w}) { |
520 |
$self->{filter_w}($self, \$_[0]); |
521 |
} else { |
522 |
$self->{wbuf} .= $_[0]; |
523 |
$self->_drain_wbuf; |
524 |
} |
525 |
} |
526 |
|
527 |
=item $handle->push_write (type => @args) |
528 |
|
529 |
Instead of formatting your data yourself, you can also let this module do |
530 |
the job by specifying a type and type-specific arguments. |
531 |
|
532 |
Predefined types are (if you have ideas for additional types, feel free to |
533 |
drop by and tell us): |
534 |
|
535 |
=over 4 |
536 |
|
537 |
=item netstring => $string |
538 |
|
539 |
Formats the given value as netstring |
540 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
541 |
|
542 |
=cut |
543 |
|
544 |
register_write_type netstring => sub { |
545 |
my ($self, $string) = @_; |
546 |
|
547 |
sprintf "%d:%s,", (length $string), $string |
548 |
}; |
549 |
|
550 |
=item packstring => $format, $data |
551 |
|
552 |
An octet string prefixed with an encoded length. The encoding C<$format> |
553 |
uses the same format as a Perl C<pack> format, but must specify a single |
554 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
555 |
optional C<!>, C<< < >> or C<< > >> modifier). |
556 |
|
557 |
=cut |
558 |
|
559 |
register_write_type packstring => sub { |
560 |
my ($self, $format, $string) = @_; |
561 |
|
562 |
pack "$format/a*", $string |
563 |
}; |
564 |
|
565 |
=item json => $array_or_hashref |
566 |
|
567 |
Encodes the given hash or array reference into a JSON object. Unless you |
568 |
provide your own JSON object, this means it will be encoded to JSON text |
569 |
in UTF-8. |
570 |
|
571 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
572 |
one end of a handle and read them at the other end without using any |
573 |
additional framing. |
574 |
|
575 |
The generated JSON text is guaranteed not to contain any newlines: While |
576 |
this module doesn't need delimiters after or between JSON texts to be |
577 |
able to read them, many other languages depend on that. |
578 |
|
579 |
A simple RPC protocol that interoperates easily with others is to send |
580 |
JSON arrays (or objects, although arrays are usually the better choice as |
581 |
they mimic how function argument passing works) and a newline after each |
582 |
JSON text: |
583 |
|
584 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
585 |
$handle->push_write ("\012"); |
586 |
|
587 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
588 |
rely on the fact that the newline will be skipped as leading whitespace: |
589 |
|
590 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
591 |
|
592 |
Other languages could read single lines terminated by a newline and pass |
593 |
this line into their JSON decoder of choice. |
594 |
|
595 |
=cut |
596 |
|
597 |
register_write_type json => sub { |
598 |
my ($self, $ref) = @_; |
599 |
|
600 |
require JSON; |
601 |
|
602 |
$self->{json} ? $self->{json}->encode ($ref) |
603 |
: JSON::encode_json ($ref) |
604 |
}; |
605 |
|
606 |
=item storable => $reference |
607 |
|
608 |
Freezes the given reference using L<Storable> and writes it to the |
609 |
handle. Uses the C<nfreeze> format. |
610 |
|
611 |
=cut |
612 |
|
613 |
register_write_type storable => sub { |
614 |
my ($self, $ref) = @_; |
615 |
|
616 |
require Storable; |
617 |
|
618 |
pack "w/a*", Storable::nfreeze ($ref) |
619 |
}; |
620 |
|
621 |
=back |
622 |
|
623 |
=item AnyEvent::Handle::register_write_type type => $coderef->($handle, @args) |
624 |
|
625 |
This function (not method) lets you add your own types to C<push_write>. |
626 |
Whenever the given C<type> is used, C<push_write> will invoke the code |
627 |
reference with the handle object and the remaining arguments. |
628 |
|
629 |
The code reference is supposed to return a single octet string that will |
630 |
be appended to the write buffer. |
631 |
|
632 |
Note that this is a function, and all types registered this way will be |
633 |
global, so try to use unique names. |
634 |
|
635 |
=cut |
636 |
|
637 |
############################################################################# |
638 |
|
639 |
=back |
640 |
|
641 |
=head2 READ QUEUE |
642 |
|
643 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
644 |
for reading. |
645 |
|
646 |
The read queue is more complex than the write queue. It can be used in two |
647 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
648 |
a queue. |
649 |
|
650 |
In the simple case, you just install an C<on_read> callback and whenever |
651 |
new data arrives, it will be called. You can then remove some data (if |
652 |
enough is there) from the read buffer (C<< $handle->rbuf >>). Or you cna |
653 |
leave the data there if you want to accumulate more (e.g. when only a |
654 |
partial message has been received so far). |
655 |
|
656 |
In the more complex case, you want to queue multiple callbacks. In this |
657 |
case, AnyEvent::Handle will call the first queued callback each time new |
658 |
data arrives (also the first time it is queued) and removes it when it has |
659 |
done its job (see C<push_read>, below). |
660 |
|
661 |
This way you can, for example, push three line-reads, followed by reading |
662 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
663 |
|
664 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
665 |
the specified number of bytes which give an XML datagram. |
666 |
|
667 |
# in the default state, expect some header bytes |
668 |
$handle->on_read (sub { |
669 |
# some data is here, now queue the length-header-read (4 octets) |
670 |
shift->unshift_read (chunk => 4, sub { |
671 |
# header arrived, decode |
672 |
my $len = unpack "N", $_[1]; |
673 |
|
674 |
# now read the payload |
675 |
shift->unshift_read (chunk => $len, sub { |
676 |
my $xml = $_[1]; |
677 |
# handle xml |
678 |
}); |
679 |
}); |
680 |
}); |
681 |
|
682 |
Example 2: Implement a client for a protocol that replies either with "OK" |
683 |
and another line or "ERROR" for the first request that is sent, and 64 |
684 |
bytes for the second request. Due to the availability of a queue, we can |
685 |
just pipeline sending both requests and manipulate the queue as necessary |
686 |
in the callbacks. |
687 |
|
688 |
When the first callback is called and sees an "OK" response, it will |
689 |
C<unshift> another line-read. This line-read will be queued I<before> the |
690 |
64-byte chunk callback. |
691 |
|
692 |
# request one, returns either "OK + extra line" or "ERROR" |
693 |
$handle->push_write ("request 1\015\012"); |
694 |
|
695 |
# we expect "ERROR" or "OK" as response, so push a line read |
696 |
$handle->push_read (line => sub { |
697 |
# if we got an "OK", we have to _prepend_ another line, |
698 |
# so it will be read before the second request reads its 64 bytes |
699 |
# which are already in the queue when this callback is called |
700 |
# we don't do this in case we got an error |
701 |
if ($_[1] eq "OK") { |
702 |
$_[0]->unshift_read (line => sub { |
703 |
my $response = $_[1]; |
704 |
... |
705 |
}); |
706 |
} |
707 |
}); |
708 |
|
709 |
# request two, simply returns 64 octets |
710 |
$handle->push_write ("request 2\015\012"); |
711 |
|
712 |
# simply read 64 bytes, always |
713 |
$handle->push_read (chunk => 64, sub { |
714 |
my $response = $_[1]; |
715 |
... |
716 |
}); |
717 |
|
718 |
=over 4 |
719 |
|
720 |
=cut |
721 |
|
722 |
sub _drain_rbuf { |
723 |
my ($self) = @_; |
724 |
|
725 |
local $self->{_in_drain} = 1; |
726 |
|
727 |
if ( |
728 |
defined $self->{rbuf_max} |
729 |
&& $self->{rbuf_max} < length $self->{rbuf} |
730 |
) { |
731 |
return $self->_error (&Errno::ENOSPC, 1); |
732 |
} |
733 |
|
734 |
while () { |
735 |
no strict 'refs'; |
736 |
|
737 |
my $len = length $self->{rbuf}; |
738 |
|
739 |
if (my $cb = shift @{ $self->{_queue} }) { |
740 |
unless ($cb->($self)) { |
741 |
if ($self->{_eof}) { |
742 |
# no progress can be made (not enough data and no data forthcoming) |
743 |
$self->_error (&Errno::EPIPE, 1), last; |
744 |
} |
745 |
|
746 |
unshift @{ $self->{_queue} }, $cb; |
747 |
last; |
748 |
} |
749 |
} elsif ($self->{on_read}) { |
750 |
last unless $len; |
751 |
|
752 |
$self->{on_read}($self); |
753 |
|
754 |
if ( |
755 |
$len == length $self->{rbuf} # if no data has been consumed |
756 |
&& !@{ $self->{_queue} } # and the queue is still empty |
757 |
&& $self->{on_read} # but we still have on_read |
758 |
) { |
759 |
# no further data will arrive |
760 |
# so no progress can be made |
761 |
$self->_error (&Errno::EPIPE, 1), last |
762 |
if $self->{_eof}; |
763 |
|
764 |
last; # more data might arrive |
765 |
} |
766 |
} else { |
767 |
# read side becomes idle |
768 |
delete $self->{_rw}; |
769 |
last; |
770 |
} |
771 |
} |
772 |
|
773 |
$self->{on_eof}($self) |
774 |
if $self->{_eof} && $self->{on_eof}; |
775 |
|
776 |
# may need to restart read watcher |
777 |
unless ($self->{_rw}) { |
778 |
$self->start_read |
779 |
if $self->{on_read} || @{ $self->{_queue} }; |
780 |
} |
781 |
} |
782 |
|
783 |
=item $handle->on_read ($cb) |
784 |
|
785 |
This replaces the currently set C<on_read> callback, or clears it (when |
786 |
the new callback is C<undef>). See the description of C<on_read> in the |
787 |
constructor. |
788 |
|
789 |
=cut |
790 |
|
791 |
sub on_read { |
792 |
my ($self, $cb) = @_; |
793 |
|
794 |
$self->{on_read} = $cb; |
795 |
$self->_drain_rbuf if $cb && !$self->{_in_drain}; |
796 |
} |
797 |
|
798 |
=item $handle->rbuf |
799 |
|
800 |
Returns the read buffer (as a modifiable lvalue). |
801 |
|
802 |
You can access the read buffer directly as the C<< ->{rbuf} >> member, if |
803 |
you want. |
804 |
|
805 |
NOTE: The read buffer should only be used or modified if the C<on_read>, |
806 |
C<push_read> or C<unshift_read> methods are used. The other read methods |
807 |
automatically manage the read buffer. |
808 |
|
809 |
=cut |
810 |
|
811 |
sub rbuf : lvalue { |
812 |
$_[0]{rbuf} |
813 |
} |
814 |
|
815 |
=item $handle->push_read ($cb) |
816 |
|
817 |
=item $handle->unshift_read ($cb) |
818 |
|
819 |
Append the given callback to the end of the queue (C<push_read>) or |
820 |
prepend it (C<unshift_read>). |
821 |
|
822 |
The callback is called each time some additional read data arrives. |
823 |
|
824 |
It must check whether enough data is in the read buffer already. |
825 |
|
826 |
If not enough data is available, it must return the empty list or a false |
827 |
value, in which case it will be called repeatedly until enough data is |
828 |
available (or an error condition is detected). |
829 |
|
830 |
If enough data was available, then the callback must remove all data it is |
831 |
interested in (which can be none at all) and return a true value. After returning |
832 |
true, it will be removed from the queue. |
833 |
|
834 |
=cut |
835 |
|
836 |
our %RH; |
837 |
|
838 |
sub register_read_type($$) { |
839 |
$RH{$_[0]} = $_[1]; |
840 |
} |
841 |
|
842 |
sub push_read { |
843 |
my $self = shift; |
844 |
my $cb = pop; |
845 |
|
846 |
if (@_) { |
847 |
my $type = shift; |
848 |
|
849 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_read") |
850 |
->($self, $cb, @_); |
851 |
} |
852 |
|
853 |
push @{ $self->{_queue} }, $cb; |
854 |
$self->_drain_rbuf unless $self->{_in_drain}; |
855 |
} |
856 |
|
857 |
sub unshift_read { |
858 |
my $self = shift; |
859 |
my $cb = pop; |
860 |
|
861 |
if (@_) { |
862 |
my $type = shift; |
863 |
|
864 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::unshift_read") |
865 |
->($self, $cb, @_); |
866 |
} |
867 |
|
868 |
|
869 |
unshift @{ $self->{_queue} }, $cb; |
870 |
$self->_drain_rbuf unless $self->{_in_drain}; |
871 |
} |
872 |
|
873 |
=item $handle->push_read (type => @args, $cb) |
874 |
|
875 |
=item $handle->unshift_read (type => @args, $cb) |
876 |
|
877 |
Instead of providing a callback that parses the data itself you can chose |
878 |
between a number of predefined parsing formats, for chunks of data, lines |
879 |
etc. |
880 |
|
881 |
Predefined types are (if you have ideas for additional types, feel free to |
882 |
drop by and tell us): |
883 |
|
884 |
=over 4 |
885 |
|
886 |
=item chunk => $octets, $cb->($handle, $data) |
887 |
|
888 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
889 |
data read to the callback. The callback will never be called with less |
890 |
data. |
891 |
|
892 |
Example: read 2 bytes. |
893 |
|
894 |
$handle->push_read (chunk => 2, sub { |
895 |
warn "yay ", unpack "H*", $_[1]; |
896 |
}); |
897 |
|
898 |
=cut |
899 |
|
900 |
register_read_type chunk => sub { |
901 |
my ($self, $cb, $len) = @_; |
902 |
|
903 |
sub { |
904 |
$len <= length $_[0]{rbuf} or return; |
905 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
906 |
1 |
907 |
} |
908 |
}; |
909 |
|
910 |
# compatibility with older API |
911 |
sub push_read_chunk { |
912 |
$_[0]->push_read (chunk => $_[1], $_[2]); |
913 |
} |
914 |
|
915 |
sub unshift_read_chunk { |
916 |
$_[0]->unshift_read (chunk => $_[1], $_[2]); |
917 |
} |
918 |
|
919 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
920 |
|
921 |
The callback will be called only once a full line (including the end of |
922 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
923 |
marker) will be passed to the callback as second argument (C<$line>), and |
924 |
the end of line marker as the third argument (C<$eol>). |
925 |
|
926 |
The end of line marker, C<$eol>, can be either a string, in which case it |
927 |
will be interpreted as a fixed record end marker, or it can be a regex |
928 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
929 |
regular expression. |
930 |
|
931 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
932 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
933 |
protocols). |
934 |
|
935 |
Partial lines at the end of the stream will never be returned, as they are |
936 |
not marked by the end of line marker. |
937 |
|
938 |
=cut |
939 |
|
940 |
register_read_type line => sub { |
941 |
my ($self, $cb, $eol) = @_; |
942 |
|
943 |
if (@_ < 3) { |
944 |
# this is more than twice as fast as the generic code below |
945 |
sub { |
946 |
$_[0]{rbuf} =~ s/^([^\015\012]*)(\015?\012)// or return; |
947 |
|
948 |
$cb->($_[0], $1, $2); |
949 |
1 |
950 |
} |
951 |
} else { |
952 |
$eol = quotemeta $eol unless ref $eol; |
953 |
$eol = qr|^(.*?)($eol)|s; |
954 |
|
955 |
sub { |
956 |
$_[0]{rbuf} =~ s/$eol// or return; |
957 |
|
958 |
$cb->($_[0], $1, $2); |
959 |
1 |
960 |
} |
961 |
} |
962 |
}; |
963 |
|
964 |
# compatibility with older API |
965 |
sub push_read_line { |
966 |
my $self = shift; |
967 |
$self->push_read (line => @_); |
968 |
} |
969 |
|
970 |
sub unshift_read_line { |
971 |
my $self = shift; |
972 |
$self->unshift_read (line => @_); |
973 |
} |
974 |
|
975 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
976 |
|
977 |
Makes a regex match against the regex object C<$accept> and returns |
978 |
everything up to and including the match. |
979 |
|
980 |
Example: read a single line terminated by '\n'. |
981 |
|
982 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
983 |
|
984 |
If C<$reject> is given and not undef, then it determines when the data is |
985 |
to be rejected: it is matched against the data when the C<$accept> regex |
986 |
does not match and generates an C<EBADMSG> error when it matches. This is |
987 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
988 |
receive buffer overflow). |
989 |
|
990 |
Example: expect a single decimal number followed by whitespace, reject |
991 |
anything else (not the use of an anchor). |
992 |
|
993 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
994 |
|
995 |
If C<$skip> is given and not C<undef>, then it will be matched against |
996 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
997 |
and everything preceding and including the match will be accepted |
998 |
unconditionally. This is useful to skip large amounts of data that you |
999 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
1000 |
have to start matching from the beginning. This is purely an optimisation |
1001 |
and is usually worth only when you expect more than a few kilobytes. |
1002 |
|
1003 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
1004 |
expect the header to be very large (it isn't in practise, but...), we use |
1005 |
a skip regex to skip initial portions. The skip regex is tricky in that |
1006 |
it only accepts something not ending in either \015 or \012, as these are |
1007 |
required for the accept regex. |
1008 |
|
1009 |
$handle->push_read (regex => |
1010 |
qr<\015\012\015\012>, |
1011 |
undef, # no reject |
1012 |
qr<^.*[^\015\012]>, |
1013 |
sub { ... }); |
1014 |
|
1015 |
=cut |
1016 |
|
1017 |
register_read_type regex => sub { |
1018 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
1019 |
|
1020 |
my $data; |
1021 |
my $rbuf = \$self->{rbuf}; |
1022 |
|
1023 |
sub { |
1024 |
# accept |
1025 |
if ($$rbuf =~ $accept) { |
1026 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1027 |
$cb->($self, $data); |
1028 |
return 1; |
1029 |
} |
1030 |
|
1031 |
# reject |
1032 |
if ($reject && $$rbuf =~ $reject) { |
1033 |
$self->_error (&Errno::EBADMSG); |
1034 |
} |
1035 |
|
1036 |
# skip |
1037 |
if ($skip && $$rbuf =~ $skip) { |
1038 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1039 |
} |
1040 |
|
1041 |
() |
1042 |
} |
1043 |
}; |
1044 |
|
1045 |
=item netstring => $cb->($handle, $string) |
1046 |
|
1047 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
1048 |
|
1049 |
Throws an error with C<$!> set to EBADMSG on format violations. |
1050 |
|
1051 |
=cut |
1052 |
|
1053 |
register_read_type netstring => sub { |
1054 |
my ($self, $cb) = @_; |
1055 |
|
1056 |
sub { |
1057 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
1058 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
1059 |
$self->_error (&Errno::EBADMSG); |
1060 |
} |
1061 |
return; |
1062 |
} |
1063 |
|
1064 |
my $len = $1; |
1065 |
|
1066 |
$self->unshift_read (chunk => $len, sub { |
1067 |
my $string = $_[1]; |
1068 |
$_[0]->unshift_read (chunk => 1, sub { |
1069 |
if ($_[1] eq ",") { |
1070 |
$cb->($_[0], $string); |
1071 |
} else { |
1072 |
$self->_error (&Errno::EBADMSG); |
1073 |
} |
1074 |
}); |
1075 |
}); |
1076 |
|
1077 |
1 |
1078 |
} |
1079 |
}; |
1080 |
|
1081 |
=item packstring => $format, $cb->($handle, $string) |
1082 |
|
1083 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1084 |
uses the same format as a Perl C<pack> format, but must specify a single |
1085 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1086 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1087 |
|
1088 |
DNS over TCP uses a prefix of C<n>, EPP uses a prefix of C<N>. |
1089 |
|
1090 |
Example: read a block of data prefixed by its length in BER-encoded |
1091 |
format (very efficient). |
1092 |
|
1093 |
$handle->push_read (packstring => "w", sub { |
1094 |
my ($handle, $data) = @_; |
1095 |
}); |
1096 |
|
1097 |
=cut |
1098 |
|
1099 |
register_read_type packstring => sub { |
1100 |
my ($self, $cb, $format) = @_; |
1101 |
|
1102 |
sub { |
1103 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1104 |
defined (my $len = eval { unpack $format, $_[0]{rbuf} }) |
1105 |
or return; |
1106 |
|
1107 |
$format = length pack $format, $len; |
1108 |
|
1109 |
# bypass unshift if we already have the remaining chunk |
1110 |
if ($format + $len <= length $_[0]{rbuf}) { |
1111 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1112 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1113 |
$cb->($_[0], $data); |
1114 |
} else { |
1115 |
# remove prefix |
1116 |
substr $_[0]{rbuf}, 0, $format, ""; |
1117 |
|
1118 |
# read remaining chunk |
1119 |
$_[0]->unshift_read (chunk => $len, $cb); |
1120 |
} |
1121 |
|
1122 |
1 |
1123 |
} |
1124 |
}; |
1125 |
|
1126 |
=item json => $cb->($handle, $hash_or_arrayref) |
1127 |
|
1128 |
Reads a JSON object or array, decodes it and passes it to the callback. |
1129 |
|
1130 |
If a C<json> object was passed to the constructor, then that will be used |
1131 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1132 |
|
1133 |
This read type uses the incremental parser available with JSON version |
1134 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1135 |
dependency on your own: this module will load the JSON module, but |
1136 |
AnyEvent does not depend on it itself. |
1137 |
|
1138 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1139 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1140 |
the C<json> write type description, above, for an actual example. |
1141 |
|
1142 |
=cut |
1143 |
|
1144 |
register_read_type json => sub { |
1145 |
my ($self, $cb) = @_; |
1146 |
|
1147 |
require JSON; |
1148 |
|
1149 |
my $data; |
1150 |
my $rbuf = \$self->{rbuf}; |
1151 |
|
1152 |
my $json = $self->{json} ||= JSON->new->utf8; |
1153 |
|
1154 |
sub { |
1155 |
my $ref = $json->incr_parse ($self->{rbuf}); |
1156 |
|
1157 |
if ($ref) { |
1158 |
$self->{rbuf} = $json->incr_text; |
1159 |
$json->incr_text = ""; |
1160 |
$cb->($self, $ref); |
1161 |
|
1162 |
1 |
1163 |
} else { |
1164 |
$self->{rbuf} = ""; |
1165 |
() |
1166 |
} |
1167 |
} |
1168 |
}; |
1169 |
|
1170 |
=item storable => $cb->($handle, $ref) |
1171 |
|
1172 |
Deserialises a L<Storable> frozen representation as written by the |
1173 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1174 |
data). |
1175 |
|
1176 |
Raises C<EBADMSG> error if the data could not be decoded. |
1177 |
|
1178 |
=cut |
1179 |
|
1180 |
register_read_type storable => sub { |
1181 |
my ($self, $cb) = @_; |
1182 |
|
1183 |
require Storable; |
1184 |
|
1185 |
sub { |
1186 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1187 |
defined (my $len = eval { unpack "w", $_[0]{rbuf} }) |
1188 |
or return; |
1189 |
|
1190 |
my $format = length pack "w", $len; |
1191 |
|
1192 |
# bypass unshift if we already have the remaining chunk |
1193 |
if ($format + $len <= length $_[0]{rbuf}) { |
1194 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1195 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1196 |
$cb->($_[0], Storable::thaw ($data)); |
1197 |
} else { |
1198 |
# remove prefix |
1199 |
substr $_[0]{rbuf}, 0, $format, ""; |
1200 |
|
1201 |
# read remaining chunk |
1202 |
$_[0]->unshift_read (chunk => $len, sub { |
1203 |
if (my $ref = eval { Storable::thaw ($_[1]) }) { |
1204 |
$cb->($_[0], $ref); |
1205 |
} else { |
1206 |
$self->_error (&Errno::EBADMSG); |
1207 |
} |
1208 |
}); |
1209 |
} |
1210 |
|
1211 |
1 |
1212 |
} |
1213 |
}; |
1214 |
|
1215 |
=back |
1216 |
|
1217 |
=item AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args) |
1218 |
|
1219 |
This function (not method) lets you add your own types to C<push_read>. |
1220 |
|
1221 |
Whenever the given C<type> is used, C<push_read> will invoke the code |
1222 |
reference with the handle object, the callback and the remaining |
1223 |
arguments. |
1224 |
|
1225 |
The code reference is supposed to return a callback (usually a closure) |
1226 |
that works as a plain read callback (see C<< ->push_read ($cb) >>). |
1227 |
|
1228 |
It should invoke the passed callback when it is done reading (remember to |
1229 |
pass C<$handle> as first argument as all other callbacks do that). |
1230 |
|
1231 |
Note that this is a function, and all types registered this way will be |
1232 |
global, so try to use unique names. |
1233 |
|
1234 |
For examples, see the source of this module (F<perldoc -m AnyEvent::Handle>, |
1235 |
search for C<register_read_type>)). |
1236 |
|
1237 |
=item $handle->stop_read |
1238 |
|
1239 |
=item $handle->start_read |
1240 |
|
1241 |
In rare cases you actually do not want to read anything from the |
1242 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1243 |
any queued callbacks will be executed then. To start reading again, call |
1244 |
C<start_read>. |
1245 |
|
1246 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1247 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1248 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1249 |
there are any read requests in the queue. |
1250 |
|
1251 |
=cut |
1252 |
|
1253 |
sub stop_read { |
1254 |
my ($self) = @_; |
1255 |
|
1256 |
delete $self->{_rw}; |
1257 |
} |
1258 |
|
1259 |
sub start_read { |
1260 |
my ($self) = @_; |
1261 |
|
1262 |
unless ($self->{_rw} || $self->{_eof}) { |
1263 |
Scalar::Util::weaken $self; |
1264 |
|
1265 |
$self->{_rw} = AnyEvent->io (fh => $self->{fh}, poll => "r", cb => sub { |
1266 |
my $rbuf = $self->{filter_r} ? \my $buf : \$self->{rbuf}; |
1267 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size} || 8192, length $$rbuf; |
1268 |
|
1269 |
if ($len > 0) { |
1270 |
$self->{_activity} = AnyEvent->now; |
1271 |
|
1272 |
$self->{filter_r} |
1273 |
? $self->{filter_r}($self, $rbuf) |
1274 |
: $self->{_in_drain} || $self->_drain_rbuf; |
1275 |
|
1276 |
} elsif (defined $len) { |
1277 |
delete $self->{_rw}; |
1278 |
$self->{_eof} = 1; |
1279 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1280 |
|
1281 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1282 |
return $self->_error ($!, 1); |
1283 |
} |
1284 |
}); |
1285 |
} |
1286 |
} |
1287 |
|
1288 |
sub _dotls { |
1289 |
my ($self) = @_; |
1290 |
|
1291 |
my $buf; |
1292 |
|
1293 |
if (length $self->{_tls_wbuf}) { |
1294 |
while ((my $len = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1295 |
substr $self->{_tls_wbuf}, 0, $len, ""; |
1296 |
} |
1297 |
} |
1298 |
|
1299 |
if (length ($buf = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1300 |
$self->{wbuf} .= $buf; |
1301 |
$self->_drain_wbuf; |
1302 |
} |
1303 |
|
1304 |
while (defined ($buf = Net::SSLeay::read ($self->{tls}))) { |
1305 |
if (length $buf) { |
1306 |
$self->{rbuf} .= $buf; |
1307 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1308 |
} else { |
1309 |
# let's treat SSL-eof as we treat normal EOF |
1310 |
$self->{_eof} = 1; |
1311 |
$self->_shutdown; |
1312 |
return; |
1313 |
} |
1314 |
} |
1315 |
|
1316 |
my $err = Net::SSLeay::get_error ($self->{tls}, -1); |
1317 |
|
1318 |
if ($err!= Net::SSLeay::ERROR_WANT_READ ()) { |
1319 |
if ($err == Net::SSLeay::ERROR_SYSCALL ()) { |
1320 |
return $self->_error ($!, 1); |
1321 |
} elsif ($err == Net::SSLeay::ERROR_SSL ()) { |
1322 |
return $self->_error (&Errno::EIO, 1); |
1323 |
} |
1324 |
|
1325 |
# all others are fine for our purposes |
1326 |
} |
1327 |
} |
1328 |
|
1329 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1330 |
|
1331 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1332 |
object is created, you can also do that at a later time by calling |
1333 |
C<starttls>. |
1334 |
|
1335 |
The first argument is the same as the C<tls> constructor argument (either |
1336 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1337 |
|
1338 |
The second argument is the optional C<Net::SSLeay::CTX> object that is |
1339 |
used when AnyEvent::Handle has to create its own TLS connection object. |
1340 |
|
1341 |
The TLS connection object will end up in C<< $handle->{tls} >> after this |
1342 |
call and can be used or changed to your liking. Note that the handshake |
1343 |
might have already started when this function returns. |
1344 |
|
1345 |
=cut |
1346 |
|
1347 |
sub starttls { |
1348 |
my ($self, $ssl, $ctx) = @_; |
1349 |
|
1350 |
$self->stoptls; |
1351 |
|
1352 |
if ($ssl eq "accept") { |
1353 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1354 |
Net::SSLeay::set_accept_state ($ssl); |
1355 |
} elsif ($ssl eq "connect") { |
1356 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1357 |
Net::SSLeay::set_connect_state ($ssl); |
1358 |
} |
1359 |
|
1360 |
$self->{tls} = $ssl; |
1361 |
|
1362 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1363 |
# but the openssl maintainers basically said: "trust us, it just works". |
1364 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1365 |
# and mismaintained ssleay-module doesn't even offer them). |
1366 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1367 |
Net::SSLeay::CTX_set_mode ($self->{tls}, |
1368 |
(eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1369 |
| (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1370 |
|
1371 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1372 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1373 |
|
1374 |
Net::SSLeay::set_bio ($ssl, $self->{_rbio}, $self->{_wbio}); |
1375 |
|
1376 |
$self->{filter_w} = sub { |
1377 |
$_[0]{_tls_wbuf} .= ${$_[1]}; |
1378 |
&_dotls; |
1379 |
}; |
1380 |
$self->{filter_r} = sub { |
1381 |
Net::SSLeay::BIO_write ($_[0]{_rbio}, ${$_[1]}); |
1382 |
&_dotls; |
1383 |
}; |
1384 |
} |
1385 |
|
1386 |
=item $handle->stoptls |
1387 |
|
1388 |
Destroys the SSL connection, if any. Partial read or write data will be |
1389 |
lost. |
1390 |
|
1391 |
=cut |
1392 |
|
1393 |
sub stoptls { |
1394 |
my ($self) = @_; |
1395 |
|
1396 |
Net::SSLeay::free (delete $self->{tls}) if $self->{tls}; |
1397 |
|
1398 |
delete $self->{_rbio}; |
1399 |
delete $self->{_wbio}; |
1400 |
delete $self->{_tls_wbuf}; |
1401 |
delete $self->{filter_r}; |
1402 |
delete $self->{filter_w}; |
1403 |
} |
1404 |
|
1405 |
sub DESTROY { |
1406 |
my $self = shift; |
1407 |
|
1408 |
$self->stoptls; |
1409 |
|
1410 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
1411 |
|
1412 |
if ($linger && length $self->{wbuf}) { |
1413 |
my $fh = delete $self->{fh}; |
1414 |
my $wbuf = delete $self->{wbuf}; |
1415 |
|
1416 |
my @linger; |
1417 |
|
1418 |
push @linger, AnyEvent->io (fh => $fh, poll => "w", cb => sub { |
1419 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
1420 |
|
1421 |
if ($len > 0) { |
1422 |
substr $wbuf, 0, $len, ""; |
1423 |
} else { |
1424 |
@linger = (); # end |
1425 |
} |
1426 |
}); |
1427 |
push @linger, AnyEvent->timer (after => $linger, cb => sub { |
1428 |
@linger = (); |
1429 |
}); |
1430 |
} |
1431 |
} |
1432 |
|
1433 |
=item AnyEvent::Handle::TLS_CTX |
1434 |
|
1435 |
This function creates and returns the Net::SSLeay::CTX object used by |
1436 |
default for TLS mode. |
1437 |
|
1438 |
The context is created like this: |
1439 |
|
1440 |
Net::SSLeay::load_error_strings; |
1441 |
Net::SSLeay::SSLeay_add_ssl_algorithms; |
1442 |
Net::SSLeay::randomize; |
1443 |
|
1444 |
my $CTX = Net::SSLeay::CTX_new; |
1445 |
|
1446 |
Net::SSLeay::CTX_set_options $CTX, Net::SSLeay::OP_ALL |
1447 |
|
1448 |
=cut |
1449 |
|
1450 |
our $TLS_CTX; |
1451 |
|
1452 |
sub TLS_CTX() { |
1453 |
$TLS_CTX || do { |
1454 |
require Net::SSLeay; |
1455 |
|
1456 |
Net::SSLeay::load_error_strings (); |
1457 |
Net::SSLeay::SSLeay_add_ssl_algorithms (); |
1458 |
Net::SSLeay::randomize (); |
1459 |
|
1460 |
$TLS_CTX = Net::SSLeay::CTX_new (); |
1461 |
|
1462 |
Net::SSLeay::CTX_set_options ($TLS_CTX, Net::SSLeay::OP_ALL ()); |
1463 |
|
1464 |
$TLS_CTX |
1465 |
} |
1466 |
} |
1467 |
|
1468 |
=back |
1469 |
|
1470 |
=head1 SUBCLASSING AnyEvent::Handle |
1471 |
|
1472 |
In many cases, you might want to subclass AnyEvent::Handle. |
1473 |
|
1474 |
To make this easier, a given version of AnyEvent::Handle uses these |
1475 |
conventions: |
1476 |
|
1477 |
=over 4 |
1478 |
|
1479 |
=item * all constructor arguments become object members. |
1480 |
|
1481 |
At least initially, when you pass a C<tls>-argument to the constructor it |
1482 |
will end up in C<< $handle->{tls} >>. Those members might be changed or |
1483 |
mutated later on (for example C<tls> will hold the TLS connection object). |
1484 |
|
1485 |
=item * other object member names are prefixed with an C<_>. |
1486 |
|
1487 |
All object members not explicitly documented (internal use) are prefixed |
1488 |
with an underscore character, so the remaining non-C<_>-namespace is free |
1489 |
for use for subclasses. |
1490 |
|
1491 |
=item * all members not documented here and not prefixed with an underscore |
1492 |
are free to use in subclasses. |
1493 |
|
1494 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
1495 |
member variables, but thats just life, at least it is documented. |
1496 |
|
1497 |
=back |
1498 |
|
1499 |
=head1 AUTHOR |
1500 |
|
1501 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
1502 |
|
1503 |
=cut |
1504 |
|
1505 |
1; # End of AnyEvent::Handle |