1 |
package AnyEvent::Handle; |
2 |
|
3 |
use Scalar::Util (); |
4 |
use Carp (); |
5 |
use Errno qw(EAGAIN EINTR); |
6 |
|
7 |
use AnyEvent (); BEGIN { AnyEvent::common_sense } |
8 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
9 |
|
10 |
=head1 NAME |
11 |
|
12 |
AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent |
13 |
|
14 |
=cut |
15 |
|
16 |
our $VERSION = 4.88; |
17 |
|
18 |
=head1 SYNOPSIS |
19 |
|
20 |
use AnyEvent; |
21 |
use AnyEvent::Handle; |
22 |
|
23 |
my $cv = AnyEvent->condvar; |
24 |
|
25 |
my $hdl; $hdl = new AnyEvent::Handle |
26 |
fh => \*STDIN, |
27 |
on_error => sub { |
28 |
my ($hdl, $fatal, $msg) = @_; |
29 |
warn "got error $msg\n"; |
30 |
$hdl->destroy; |
31 |
$cv->send; |
32 |
); |
33 |
|
34 |
# send some request line |
35 |
$hdl->push_write ("getinfo\015\012"); |
36 |
|
37 |
# read the response line |
38 |
$hdl->push_read (line => sub { |
39 |
my ($hdl, $line) = @_; |
40 |
warn "got line <$line>\n"; |
41 |
$cv->send; |
42 |
}); |
43 |
|
44 |
$cv->recv; |
45 |
|
46 |
=head1 DESCRIPTION |
47 |
|
48 |
This module is a helper module to make it easier to do event-based I/O on |
49 |
filehandles. |
50 |
|
51 |
The L<AnyEvent::Intro> tutorial contains some well-documented |
52 |
AnyEvent::Handle examples. |
53 |
|
54 |
In the following, when the documentation refers to of "bytes" then this |
55 |
means characters. As sysread and syswrite are used for all I/O, their |
56 |
treatment of characters applies to this module as well. |
57 |
|
58 |
At the very minimum, you should specify C<fh> or C<connect>, and the |
59 |
C<on_error> callback. |
60 |
|
61 |
All callbacks will be invoked with the handle object as their first |
62 |
argument. |
63 |
|
64 |
=head1 METHODS |
65 |
|
66 |
=over 4 |
67 |
|
68 |
=item $handle = B<new> AnyEvent::TLS fh => $filehandle, key => value... |
69 |
|
70 |
The constructor supports these arguments (all as C<< key => value >> pairs). |
71 |
|
72 |
=over 4 |
73 |
|
74 |
=item fh => $filehandle [C<fh> or C<connect> MANDATORY] |
75 |
|
76 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
77 |
NOTE: The filehandle will be set to non-blocking mode (using |
78 |
C<AnyEvent::Util::fh_nonblocking>) by the constructor and needs to stay in |
79 |
that mode. |
80 |
|
81 |
=item connect => [$host, $service] [C<fh> or C<connect> MANDATORY] |
82 |
|
83 |
Try to connect to the specified host and service (port), using |
84 |
C<AnyEvent::Socket::tcp_connect>. The C<$host> additionally becomes the |
85 |
default C<peername>. |
86 |
|
87 |
You have to specify either this parameter, or C<fh>, above. |
88 |
|
89 |
It is possible to push requests on the read and write queues, and modify |
90 |
properties of the stream, even while AnyEvent::Handle is connecting. |
91 |
|
92 |
When this parameter is specified, then the C<on_prepare>, |
93 |
C<on_connect_error> and C<on_connect> callbacks will be called under the |
94 |
appropriate circumstances: |
95 |
|
96 |
=over 4 |
97 |
|
98 |
=item on_prepare => $cb->($handle) |
99 |
|
100 |
This (rarely used) callback is called before a new connection is |
101 |
attempted, but after the file handle has been created. It could be used to |
102 |
prepare the file handle with parameters required for the actual connect |
103 |
(as opposed to settings that can be changed when the connection is already |
104 |
established). |
105 |
|
106 |
The return value of this callback should be the connect timeout value in |
107 |
seconds (or C<0>, or C<undef>, or the empty list, to indicate the default |
108 |
timeout is to be used). |
109 |
|
110 |
=item on_connect => $cb->($handle, $host, $port, $retry->()) |
111 |
|
112 |
This callback is called when a connection has been successfully established. |
113 |
|
114 |
The actual numeric host and port (the socket peername) are passed as |
115 |
parameters, together with a retry callback. |
116 |
|
117 |
When, for some reason, the handle is not acceptable, then calling |
118 |
C<$retry> will continue with the next conenction target (in case of |
119 |
multi-homed hosts or SRV records there can be multiple connection |
120 |
endpoints). When it is called then the read and write queues, eof status, |
121 |
tls status and similar properties of the handle are being reset. |
122 |
|
123 |
In most cases, ignoring the C<$retry> parameter is the way to go. |
124 |
|
125 |
=item on_connect_error => $cb->($handle, $message) |
126 |
|
127 |
This callback is called when the conenction could not be |
128 |
established. C<$!> will contain the relevant error code, and C<$message> a |
129 |
message describing it (usually the same as C<"$!">). |
130 |
|
131 |
If this callback isn't specified, then C<on_error> will be called with a |
132 |
fatal error instead. |
133 |
|
134 |
=back |
135 |
|
136 |
=item on_error => $cb->($handle, $fatal, $message) |
137 |
|
138 |
This is the error callback, which is called when, well, some error |
139 |
occured, such as not being able to resolve the hostname, failure to |
140 |
connect or a read error. |
141 |
|
142 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
143 |
fatal errors the handle object will be destroyed (by a call to C<< -> |
144 |
destroy >>) after invoking the error callback (which means you are free to |
145 |
examine the handle object). Examples of fatal errors are an EOF condition |
146 |
with active (but unsatisifable) read watchers (C<EPIPE>) or I/O errors. In |
147 |
cases where the other side can close the connection at their will it is |
148 |
often easiest to not report C<EPIPE> errors in this callback. |
149 |
|
150 |
AnyEvent::Handle tries to find an appropriate error code for you to check |
151 |
against, but in some cases (TLS errors), this does not work well. It is |
152 |
recommended to always output the C<$message> argument in human-readable |
153 |
error messages (it's usually the same as C<"$!">). |
154 |
|
155 |
Non-fatal errors can be retried by simply returning, but it is recommended |
156 |
to simply ignore this parameter and instead abondon the handle object |
157 |
when this callback is invoked. Examples of non-fatal errors are timeouts |
158 |
C<ETIMEDOUT>) or badly-formatted data (C<EBADMSG>). |
159 |
|
160 |
On callback entrance, the value of C<$!> contains the operating system |
161 |
error code (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT>, C<EBADMSG> or |
162 |
C<EPROTO>). |
163 |
|
164 |
While not mandatory, it is I<highly> recommended to set this callback, as |
165 |
you will not be notified of errors otherwise. The default simply calls |
166 |
C<croak>. |
167 |
|
168 |
=item on_read => $cb->($handle) |
169 |
|
170 |
This sets the default read callback, which is called when data arrives |
171 |
and no read request is in the queue (unlike read queue callbacks, this |
172 |
callback will only be called when at least one octet of data is in the |
173 |
read buffer). |
174 |
|
175 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
176 |
method or access the C<< $handle->{rbuf} >> member directly. Note that you |
177 |
must not enlarge or modify the read buffer, you can only remove data at |
178 |
the beginning from it. |
179 |
|
180 |
When an EOF condition is detected then AnyEvent::Handle will first try to |
181 |
feed all the remaining data to the queued callbacks and C<on_read> before |
182 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
183 |
error will be raised (with C<$!> set to C<EPIPE>). |
184 |
|
185 |
Note that, unlike requests in the read queue, an C<on_read> callback |
186 |
doesn't mean you I<require> some data: if there is an EOF and there |
187 |
are outstanding read requests then an error will be flagged. With an |
188 |
C<on_read> callback, the C<on_eof> callback will be invoked. |
189 |
|
190 |
=item on_eof => $cb->($handle) |
191 |
|
192 |
Set the callback to be called when an end-of-file condition is detected, |
193 |
i.e. in the case of a socket, when the other side has closed the |
194 |
connection cleanly, and there are no outstanding read requests in the |
195 |
queue (if there are read requests, then an EOF counts as an unexpected |
196 |
connection close and will be flagged as an error). |
197 |
|
198 |
For sockets, this just means that the other side has stopped sending data, |
199 |
you can still try to write data, and, in fact, one can return from the EOF |
200 |
callback and continue writing data, as only the read part has been shut |
201 |
down. |
202 |
|
203 |
If an EOF condition has been detected but no C<on_eof> callback has been |
204 |
set, then a fatal error will be raised with C<$!> set to <0>. |
205 |
|
206 |
=item on_drain => $cb->($handle) |
207 |
|
208 |
This sets the callback that is called when the write buffer becomes empty |
209 |
(or when the callback is set and the buffer is empty already). |
210 |
|
211 |
To append to the write buffer, use the C<< ->push_write >> method. |
212 |
|
213 |
This callback is useful when you don't want to put all of your write data |
214 |
into the queue at once, for example, when you want to write the contents |
215 |
of some file to the socket you might not want to read the whole file into |
216 |
memory and push it into the queue, but instead only read more data from |
217 |
the file when the write queue becomes empty. |
218 |
|
219 |
=item timeout => $fractional_seconds |
220 |
|
221 |
If non-zero, then this enables an "inactivity" timeout: whenever this many |
222 |
seconds pass without a successful read or write on the underlying file |
223 |
handle, the C<on_timeout> callback will be invoked (and if that one is |
224 |
missing, a non-fatal C<ETIMEDOUT> error will be raised). |
225 |
|
226 |
Note that timeout processing is also active when you currently do not have |
227 |
any outstanding read or write requests: If you plan to keep the connection |
228 |
idle then you should disable the timout temporarily or ignore the timeout |
229 |
in the C<on_timeout> callback, in which case AnyEvent::Handle will simply |
230 |
restart the timeout. |
231 |
|
232 |
Zero (the default) disables this timeout. |
233 |
|
234 |
=item on_timeout => $cb->($handle) |
235 |
|
236 |
Called whenever the inactivity timeout passes. If you return from this |
237 |
callback, then the timeout will be reset as if some activity had happened, |
238 |
so this condition is not fatal in any way. |
239 |
|
240 |
=item rbuf_max => <bytes> |
241 |
|
242 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
243 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
244 |
avoid some forms of denial-of-service attacks. |
245 |
|
246 |
For example, a server accepting connections from untrusted sources should |
247 |
be configured to accept only so-and-so much data that it cannot act on |
248 |
(for example, when expecting a line, an attacker could send an unlimited |
249 |
amount of data without a callback ever being called as long as the line |
250 |
isn't finished). |
251 |
|
252 |
=item autocork => <boolean> |
253 |
|
254 |
When disabled (the default), then C<push_write> will try to immediately |
255 |
write the data to the handle, if possible. This avoids having to register |
256 |
a write watcher and wait for the next event loop iteration, but can |
257 |
be inefficient if you write multiple small chunks (on the wire, this |
258 |
disadvantage is usually avoided by your kernel's nagle algorithm, see |
259 |
C<no_delay>, but this option can save costly syscalls). |
260 |
|
261 |
When enabled, then writes will always be queued till the next event loop |
262 |
iteration. This is efficient when you do many small writes per iteration, |
263 |
but less efficient when you do a single write only per iteration (or when |
264 |
the write buffer often is full). It also increases write latency. |
265 |
|
266 |
=item no_delay => <boolean> |
267 |
|
268 |
When doing small writes on sockets, your operating system kernel might |
269 |
wait a bit for more data before actually sending it out. This is called |
270 |
the Nagle algorithm, and usually it is beneficial. |
271 |
|
272 |
In some situations you want as low a delay as possible, which can be |
273 |
accomplishd by setting this option to a true value. |
274 |
|
275 |
The default is your opertaing system's default behaviour (most likely |
276 |
enabled), this option explicitly enables or disables it, if possible. |
277 |
|
278 |
=item read_size => <bytes> |
279 |
|
280 |
The default read block size (the amount of bytes this module will |
281 |
try to read during each loop iteration, which affects memory |
282 |
requirements). Default: C<8192>. |
283 |
|
284 |
=item low_water_mark => <bytes> |
285 |
|
286 |
Sets the amount of bytes (default: C<0>) that make up an "empty" write |
287 |
buffer: If the write reaches this size or gets even samller it is |
288 |
considered empty. |
289 |
|
290 |
Sometimes it can be beneficial (for performance reasons) to add data to |
291 |
the write buffer before it is fully drained, but this is a rare case, as |
292 |
the operating system kernel usually buffers data as well, so the default |
293 |
is good in almost all cases. |
294 |
|
295 |
=item linger => <seconds> |
296 |
|
297 |
If non-zero (default: C<3600>), then the destructor of the |
298 |
AnyEvent::Handle object will check whether there is still outstanding |
299 |
write data and will install a watcher that will write this data to the |
300 |
socket. No errors will be reported (this mostly matches how the operating |
301 |
system treats outstanding data at socket close time). |
302 |
|
303 |
This will not work for partial TLS data that could not be encoded |
304 |
yet. This data will be lost. Calling the C<stoptls> method in time might |
305 |
help. |
306 |
|
307 |
=item peername => $string |
308 |
|
309 |
A string used to identify the remote site - usually the DNS hostname |
310 |
(I<not> IDN!) used to create the connection, rarely the IP address. |
311 |
|
312 |
Apart from being useful in error messages, this string is also used in TLS |
313 |
peername verification (see C<verify_peername> in L<AnyEvent::TLS>). This |
314 |
verification will be skipped when C<peername> is not specified or |
315 |
C<undef>. |
316 |
|
317 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
318 |
|
319 |
When this parameter is given, it enables TLS (SSL) mode, that means |
320 |
AnyEvent will start a TLS handshake as soon as the conenction has been |
321 |
established and will transparently encrypt/decrypt data afterwards. |
322 |
|
323 |
All TLS protocol errors will be signalled as C<EPROTO>, with an |
324 |
appropriate error message. |
325 |
|
326 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
327 |
automatically when you try to create a TLS handle): this module doesn't |
328 |
have a dependency on that module, so if your module requires it, you have |
329 |
to add the dependency yourself. |
330 |
|
331 |
Unlike TCP, TLS has a server and client side: for the TLS server side, use |
332 |
C<accept>, and for the TLS client side of a connection, use C<connect> |
333 |
mode. |
334 |
|
335 |
You can also provide your own TLS connection object, but you have |
336 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
337 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
338 |
AnyEvent::Handle. Also, this module will take ownership of this connection |
339 |
object. |
340 |
|
341 |
At some future point, AnyEvent::Handle might switch to another TLS |
342 |
implementation, then the option to use your own session object will go |
343 |
away. |
344 |
|
345 |
B<IMPORTANT:> since Net::SSLeay "objects" are really only integers, |
346 |
passing in the wrong integer will lead to certain crash. This most often |
347 |
happens when one uses a stylish C<< tls => 1 >> and is surprised about the |
348 |
segmentation fault. |
349 |
|
350 |
See the C<< ->starttls >> method for when need to start TLS negotiation later. |
351 |
|
352 |
=item tls_ctx => $anyevent_tls |
353 |
|
354 |
Use the given C<AnyEvent::TLS> object to create the new TLS connection |
355 |
(unless a connection object was specified directly). If this parameter is |
356 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
357 |
|
358 |
Instead of an object, you can also specify a hash reference with C<< key |
359 |
=> value >> pairs. Those will be passed to L<AnyEvent::TLS> to create a |
360 |
new TLS context object. |
361 |
|
362 |
=item on_starttls => $cb->($handle, $success[, $error_message]) |
363 |
|
364 |
This callback will be invoked when the TLS/SSL handshake has finished. If |
365 |
C<$success> is true, then the TLS handshake succeeded, otherwise it failed |
366 |
(C<on_stoptls> will not be called in this case). |
367 |
|
368 |
The session in C<< $handle->{tls} >> can still be examined in this |
369 |
callback, even when the handshake was not successful. |
370 |
|
371 |
TLS handshake failures will not cause C<on_error> to be invoked when this |
372 |
callback is in effect, instead, the error message will be passed to C<on_starttls>. |
373 |
|
374 |
Without this callback, handshake failures lead to C<on_error> being |
375 |
called, as normal. |
376 |
|
377 |
Note that you cannot call C<starttls> right again in this callback. If you |
378 |
need to do that, start an zero-second timer instead whose callback can |
379 |
then call C<< ->starttls >> again. |
380 |
|
381 |
=item on_stoptls => $cb->($handle) |
382 |
|
383 |
When a SSLv3/TLS shutdown/close notify/EOF is detected and this callback is |
384 |
set, then it will be invoked after freeing the TLS session. If it is not, |
385 |
then a TLS shutdown condition will be treated like a normal EOF condition |
386 |
on the handle. |
387 |
|
388 |
The session in C<< $handle->{tls} >> can still be examined in this |
389 |
callback. |
390 |
|
391 |
This callback will only be called on TLS shutdowns, not when the |
392 |
underlying handle signals EOF. |
393 |
|
394 |
=item json => JSON or JSON::XS object |
395 |
|
396 |
This is the json coder object used by the C<json> read and write types. |
397 |
|
398 |
If you don't supply it, then AnyEvent::Handle will create and use a |
399 |
suitable one (on demand), which will write and expect UTF-8 encoded JSON |
400 |
texts. |
401 |
|
402 |
Note that you are responsible to depend on the JSON module if you want to |
403 |
use this functionality, as AnyEvent does not have a dependency itself. |
404 |
|
405 |
=back |
406 |
|
407 |
=cut |
408 |
|
409 |
sub new { |
410 |
my $class = shift; |
411 |
my $self = bless { @_ }, $class; |
412 |
|
413 |
if ($self->{fh}) { |
414 |
$self->_start; |
415 |
return unless $self->{fh}; # could be gone by now |
416 |
|
417 |
} elsif ($self->{connect}) { |
418 |
require AnyEvent::Socket; |
419 |
|
420 |
$self->{peername} = $self->{connect}[0] |
421 |
unless exists $self->{peername}; |
422 |
|
423 |
$self->{_skip_drain_rbuf} = 1; |
424 |
|
425 |
{ |
426 |
Scalar::Util::weaken (my $self = $self); |
427 |
|
428 |
$self->{_connect} = |
429 |
AnyEvent::Socket::tcp_connect ( |
430 |
$self->{connect}[0], |
431 |
$self->{connect}[1], |
432 |
sub { |
433 |
my ($fh, $host, $port, $retry) = @_; |
434 |
|
435 |
if ($fh) { |
436 |
$self->{fh} = $fh; |
437 |
|
438 |
delete $self->{_skip_drain_rbuf}; |
439 |
$self->_start; |
440 |
|
441 |
$self->{on_connect} |
442 |
and $self->{on_connect}($self, $host, $port, sub { |
443 |
delete @$self{qw(fh _tw _ww _rw _eof _queue rbuf _wbuf tls _tls_rbuf _tls_wbuf)}; |
444 |
$self->{_skip_drain_rbuf} = 1; |
445 |
&$retry; |
446 |
}); |
447 |
|
448 |
} else { |
449 |
if ($self->{on_connect_error}) { |
450 |
$self->{on_connect_error}($self, "$!"); |
451 |
$self->destroy; |
452 |
} else { |
453 |
$self->_error ($!, 1); |
454 |
} |
455 |
} |
456 |
}, |
457 |
sub { |
458 |
local $self->{fh} = $_[0]; |
459 |
|
460 |
$self->{on_prepare} |
461 |
? $self->{on_prepare}->($self) |
462 |
: () |
463 |
} |
464 |
); |
465 |
} |
466 |
|
467 |
} else { |
468 |
Carp::croak "AnyEvent::Handle: either an existing fh or the connect parameter must be specified"; |
469 |
} |
470 |
|
471 |
$self |
472 |
} |
473 |
|
474 |
sub _start { |
475 |
my ($self) = @_; |
476 |
|
477 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
478 |
|
479 |
$self->{_activity} = AnyEvent->now; |
480 |
$self->_timeout; |
481 |
|
482 |
$self->no_delay (delete $self->{no_delay}) if exists $self->{no_delay}; |
483 |
|
484 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}) |
485 |
if $self->{tls}; |
486 |
|
487 |
$self->on_drain (delete $self->{on_drain}) if $self->{on_drain}; |
488 |
|
489 |
$self->start_read |
490 |
if $self->{on_read} || @{ $self->{_queue} }; |
491 |
|
492 |
$self->_drain_wbuf; |
493 |
} |
494 |
|
495 |
#sub _shutdown { |
496 |
# my ($self) = @_; |
497 |
# |
498 |
# delete @$self{qw(_tw _rw _ww fh wbuf on_read _queue)}; |
499 |
# $self->{_eof} = 1; # tell starttls et. al to stop trying |
500 |
# |
501 |
# &_freetls; |
502 |
#} |
503 |
|
504 |
sub _error { |
505 |
my ($self, $errno, $fatal, $message) = @_; |
506 |
|
507 |
$! = $errno; |
508 |
$message ||= "$!"; |
509 |
|
510 |
if ($self->{on_error}) { |
511 |
$self->{on_error}($self, $fatal, $message); |
512 |
$self->destroy if $fatal; |
513 |
} elsif ($self->{fh}) { |
514 |
$self->destroy; |
515 |
Carp::croak "AnyEvent::Handle uncaught error: $message"; |
516 |
} |
517 |
} |
518 |
|
519 |
=item $fh = $handle->fh |
520 |
|
521 |
This method returns the file handle used to create the L<AnyEvent::Handle> object. |
522 |
|
523 |
=cut |
524 |
|
525 |
sub fh { $_[0]{fh} } |
526 |
|
527 |
=item $handle->on_error ($cb) |
528 |
|
529 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
530 |
|
531 |
=cut |
532 |
|
533 |
sub on_error { |
534 |
$_[0]{on_error} = $_[1]; |
535 |
} |
536 |
|
537 |
=item $handle->on_eof ($cb) |
538 |
|
539 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
540 |
|
541 |
=cut |
542 |
|
543 |
sub on_eof { |
544 |
$_[0]{on_eof} = $_[1]; |
545 |
} |
546 |
|
547 |
=item $handle->on_timeout ($cb) |
548 |
|
549 |
Replace the current C<on_timeout> callback, or disables the callback (but |
550 |
not the timeout) if C<$cb> = C<undef>. See the C<timeout> constructor |
551 |
argument and method. |
552 |
|
553 |
=cut |
554 |
|
555 |
sub on_timeout { |
556 |
$_[0]{on_timeout} = $_[1]; |
557 |
} |
558 |
|
559 |
=item $handle->autocork ($boolean) |
560 |
|
561 |
Enables or disables the current autocork behaviour (see C<autocork> |
562 |
constructor argument). Changes will only take effect on the next write. |
563 |
|
564 |
=cut |
565 |
|
566 |
sub autocork { |
567 |
$_[0]{autocork} = $_[1]; |
568 |
} |
569 |
|
570 |
=item $handle->no_delay ($boolean) |
571 |
|
572 |
Enables or disables the C<no_delay> setting (see constructor argument of |
573 |
the same name for details). |
574 |
|
575 |
=cut |
576 |
|
577 |
sub no_delay { |
578 |
$_[0]{no_delay} = $_[1]; |
579 |
|
580 |
eval { |
581 |
local $SIG{__DIE__}; |
582 |
setsockopt $_[0]{fh}, &Socket::IPPROTO_TCP, &Socket::TCP_NODELAY, int $_[1] |
583 |
if $_[0]{fh}; |
584 |
}; |
585 |
} |
586 |
|
587 |
=item $handle->on_starttls ($cb) |
588 |
|
589 |
Replace the current C<on_starttls> callback (see the C<on_starttls> constructor argument). |
590 |
|
591 |
=cut |
592 |
|
593 |
sub on_starttls { |
594 |
$_[0]{on_starttls} = $_[1]; |
595 |
} |
596 |
|
597 |
=item $handle->on_stoptls ($cb) |
598 |
|
599 |
Replace the current C<on_stoptls> callback (see the C<on_stoptls> constructor argument). |
600 |
|
601 |
=cut |
602 |
|
603 |
sub on_starttls { |
604 |
$_[0]{on_stoptls} = $_[1]; |
605 |
} |
606 |
|
607 |
############################################################################# |
608 |
|
609 |
=item $handle->timeout ($seconds) |
610 |
|
611 |
Configures (or disables) the inactivity timeout. |
612 |
|
613 |
=cut |
614 |
|
615 |
sub timeout { |
616 |
my ($self, $timeout) = @_; |
617 |
|
618 |
$self->{timeout} = $timeout; |
619 |
$self->_timeout; |
620 |
} |
621 |
|
622 |
# reset the timeout watcher, as neccessary |
623 |
# also check for time-outs |
624 |
sub _timeout { |
625 |
my ($self) = @_; |
626 |
|
627 |
if ($self->{timeout} && $self->{fh}) { |
628 |
my $NOW = AnyEvent->now; |
629 |
|
630 |
# when would the timeout trigger? |
631 |
my $after = $self->{_activity} + $self->{timeout} - $NOW; |
632 |
|
633 |
# now or in the past already? |
634 |
if ($after <= 0) { |
635 |
$self->{_activity} = $NOW; |
636 |
|
637 |
if ($self->{on_timeout}) { |
638 |
$self->{on_timeout}($self); |
639 |
} else { |
640 |
$self->_error (Errno::ETIMEDOUT); |
641 |
} |
642 |
|
643 |
# callback could have changed timeout value, optimise |
644 |
return unless $self->{timeout}; |
645 |
|
646 |
# calculate new after |
647 |
$after = $self->{timeout}; |
648 |
} |
649 |
|
650 |
Scalar::Util::weaken $self; |
651 |
return unless $self; # ->error could have destroyed $self |
652 |
|
653 |
$self->{_tw} ||= AnyEvent->timer (after => $after, cb => sub { |
654 |
delete $self->{_tw}; |
655 |
$self->_timeout; |
656 |
}); |
657 |
} else { |
658 |
delete $self->{_tw}; |
659 |
} |
660 |
} |
661 |
|
662 |
############################################################################# |
663 |
|
664 |
=back |
665 |
|
666 |
=head2 WRITE QUEUE |
667 |
|
668 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
669 |
for reading. |
670 |
|
671 |
The write queue is very simple: you can add data to its end, and |
672 |
AnyEvent::Handle will automatically try to get rid of it for you. |
673 |
|
674 |
When data could be written and the write buffer is shorter then the low |
675 |
water mark, the C<on_drain> callback will be invoked. |
676 |
|
677 |
=over 4 |
678 |
|
679 |
=item $handle->on_drain ($cb) |
680 |
|
681 |
Sets the C<on_drain> callback or clears it (see the description of |
682 |
C<on_drain> in the constructor). |
683 |
|
684 |
=cut |
685 |
|
686 |
sub on_drain { |
687 |
my ($self, $cb) = @_; |
688 |
|
689 |
$self->{on_drain} = $cb; |
690 |
|
691 |
$cb->($self) |
692 |
if $cb && $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}); |
693 |
} |
694 |
|
695 |
=item $handle->push_write ($data) |
696 |
|
697 |
Queues the given scalar to be written. You can push as much data as you |
698 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
699 |
buffers it independently of the kernel. |
700 |
|
701 |
=cut |
702 |
|
703 |
sub _drain_wbuf { |
704 |
my ($self) = @_; |
705 |
|
706 |
if (!$self->{_ww} && length $self->{wbuf}) { |
707 |
|
708 |
Scalar::Util::weaken $self; |
709 |
|
710 |
my $cb = sub { |
711 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
712 |
|
713 |
if (defined $len) { |
714 |
substr $self->{wbuf}, 0, $len, ""; |
715 |
|
716 |
$self->{_activity} = AnyEvent->now; |
717 |
|
718 |
$self->{on_drain}($self) |
719 |
if $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}) |
720 |
&& $self->{on_drain}; |
721 |
|
722 |
delete $self->{_ww} unless length $self->{wbuf}; |
723 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
724 |
$self->_error ($!, 1); |
725 |
} |
726 |
}; |
727 |
|
728 |
# try to write data immediately |
729 |
$cb->() unless $self->{autocork}; |
730 |
|
731 |
# if still data left in wbuf, we need to poll |
732 |
$self->{_ww} = AnyEvent->io (fh => $self->{fh}, poll => "w", cb => $cb) |
733 |
if length $self->{wbuf}; |
734 |
}; |
735 |
} |
736 |
|
737 |
our %WH; |
738 |
|
739 |
sub register_write_type($$) { |
740 |
$WH{$_[0]} = $_[1]; |
741 |
} |
742 |
|
743 |
sub push_write { |
744 |
my $self = shift; |
745 |
|
746 |
if (@_ > 1) { |
747 |
my $type = shift; |
748 |
|
749 |
@_ = ($WH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_write") |
750 |
->($self, @_); |
751 |
} |
752 |
|
753 |
if ($self->{tls}) { |
754 |
$self->{_tls_wbuf} .= $_[0]; |
755 |
&_dotls ($self) if $self->{fh}; |
756 |
} else { |
757 |
$self->{wbuf} .= $_[0]; |
758 |
$self->_drain_wbuf if $self->{fh}; |
759 |
} |
760 |
} |
761 |
|
762 |
=item $handle->push_write (type => @args) |
763 |
|
764 |
Instead of formatting your data yourself, you can also let this module do |
765 |
the job by specifying a type and type-specific arguments. |
766 |
|
767 |
Predefined types are (if you have ideas for additional types, feel free to |
768 |
drop by and tell us): |
769 |
|
770 |
=over 4 |
771 |
|
772 |
=item netstring => $string |
773 |
|
774 |
Formats the given value as netstring |
775 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
776 |
|
777 |
=cut |
778 |
|
779 |
register_write_type netstring => sub { |
780 |
my ($self, $string) = @_; |
781 |
|
782 |
(length $string) . ":$string," |
783 |
}; |
784 |
|
785 |
=item packstring => $format, $data |
786 |
|
787 |
An octet string prefixed with an encoded length. The encoding C<$format> |
788 |
uses the same format as a Perl C<pack> format, but must specify a single |
789 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
790 |
optional C<!>, C<< < >> or C<< > >> modifier). |
791 |
|
792 |
=cut |
793 |
|
794 |
register_write_type packstring => sub { |
795 |
my ($self, $format, $string) = @_; |
796 |
|
797 |
pack "$format/a*", $string |
798 |
}; |
799 |
|
800 |
=item json => $array_or_hashref |
801 |
|
802 |
Encodes the given hash or array reference into a JSON object. Unless you |
803 |
provide your own JSON object, this means it will be encoded to JSON text |
804 |
in UTF-8. |
805 |
|
806 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
807 |
one end of a handle and read them at the other end without using any |
808 |
additional framing. |
809 |
|
810 |
The generated JSON text is guaranteed not to contain any newlines: While |
811 |
this module doesn't need delimiters after or between JSON texts to be |
812 |
able to read them, many other languages depend on that. |
813 |
|
814 |
A simple RPC protocol that interoperates easily with others is to send |
815 |
JSON arrays (or objects, although arrays are usually the better choice as |
816 |
they mimic how function argument passing works) and a newline after each |
817 |
JSON text: |
818 |
|
819 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
820 |
$handle->push_write ("\012"); |
821 |
|
822 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
823 |
rely on the fact that the newline will be skipped as leading whitespace: |
824 |
|
825 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
826 |
|
827 |
Other languages could read single lines terminated by a newline and pass |
828 |
this line into their JSON decoder of choice. |
829 |
|
830 |
=cut |
831 |
|
832 |
register_write_type json => sub { |
833 |
my ($self, $ref) = @_; |
834 |
|
835 |
require JSON; |
836 |
|
837 |
$self->{json} ? $self->{json}->encode ($ref) |
838 |
: JSON::encode_json ($ref) |
839 |
}; |
840 |
|
841 |
=item storable => $reference |
842 |
|
843 |
Freezes the given reference using L<Storable> and writes it to the |
844 |
handle. Uses the C<nfreeze> format. |
845 |
|
846 |
=cut |
847 |
|
848 |
register_write_type storable => sub { |
849 |
my ($self, $ref) = @_; |
850 |
|
851 |
require Storable; |
852 |
|
853 |
pack "w/a*", Storable::nfreeze ($ref) |
854 |
}; |
855 |
|
856 |
=back |
857 |
|
858 |
=item $handle->push_shutdown |
859 |
|
860 |
Sometimes you know you want to close the socket after writing your data |
861 |
before it was actually written. One way to do that is to replace your |
862 |
C<on_drain> handler by a callback that shuts down the socket (and set |
863 |
C<low_water_mark> to C<0>). This method is a shorthand for just that, and |
864 |
replaces the C<on_drain> callback with: |
865 |
|
866 |
sub { shutdown $_[0]{fh}, 1 } # for push_shutdown |
867 |
|
868 |
This simply shuts down the write side and signals an EOF condition to the |
869 |
the peer. |
870 |
|
871 |
You can rely on the normal read queue and C<on_eof> handling |
872 |
afterwards. This is the cleanest way to close a connection. |
873 |
|
874 |
=cut |
875 |
|
876 |
sub push_shutdown { |
877 |
my ($self) = @_; |
878 |
|
879 |
delete $self->{low_water_mark}; |
880 |
$self->on_drain (sub { shutdown $_[0]{fh}, 1 }); |
881 |
} |
882 |
|
883 |
=item AnyEvent::Handle::register_write_type type => $coderef->($handle, @args) |
884 |
|
885 |
This function (not method) lets you add your own types to C<push_write>. |
886 |
Whenever the given C<type> is used, C<push_write> will invoke the code |
887 |
reference with the handle object and the remaining arguments. |
888 |
|
889 |
The code reference is supposed to return a single octet string that will |
890 |
be appended to the write buffer. |
891 |
|
892 |
Note that this is a function, and all types registered this way will be |
893 |
global, so try to use unique names. |
894 |
|
895 |
=cut |
896 |
|
897 |
############################################################################# |
898 |
|
899 |
=back |
900 |
|
901 |
=head2 READ QUEUE |
902 |
|
903 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
904 |
for reading. |
905 |
|
906 |
The read queue is more complex than the write queue. It can be used in two |
907 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
908 |
a queue. |
909 |
|
910 |
In the simple case, you just install an C<on_read> callback and whenever |
911 |
new data arrives, it will be called. You can then remove some data (if |
912 |
enough is there) from the read buffer (C<< $handle->rbuf >>). Or you cna |
913 |
leave the data there if you want to accumulate more (e.g. when only a |
914 |
partial message has been received so far). |
915 |
|
916 |
In the more complex case, you want to queue multiple callbacks. In this |
917 |
case, AnyEvent::Handle will call the first queued callback each time new |
918 |
data arrives (also the first time it is queued) and removes it when it has |
919 |
done its job (see C<push_read>, below). |
920 |
|
921 |
This way you can, for example, push three line-reads, followed by reading |
922 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
923 |
|
924 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
925 |
the specified number of bytes which give an XML datagram. |
926 |
|
927 |
# in the default state, expect some header bytes |
928 |
$handle->on_read (sub { |
929 |
# some data is here, now queue the length-header-read (4 octets) |
930 |
shift->unshift_read (chunk => 4, sub { |
931 |
# header arrived, decode |
932 |
my $len = unpack "N", $_[1]; |
933 |
|
934 |
# now read the payload |
935 |
shift->unshift_read (chunk => $len, sub { |
936 |
my $xml = $_[1]; |
937 |
# handle xml |
938 |
}); |
939 |
}); |
940 |
}); |
941 |
|
942 |
Example 2: Implement a client for a protocol that replies either with "OK" |
943 |
and another line or "ERROR" for the first request that is sent, and 64 |
944 |
bytes for the second request. Due to the availability of a queue, we can |
945 |
just pipeline sending both requests and manipulate the queue as necessary |
946 |
in the callbacks. |
947 |
|
948 |
When the first callback is called and sees an "OK" response, it will |
949 |
C<unshift> another line-read. This line-read will be queued I<before> the |
950 |
64-byte chunk callback. |
951 |
|
952 |
# request one, returns either "OK + extra line" or "ERROR" |
953 |
$handle->push_write ("request 1\015\012"); |
954 |
|
955 |
# we expect "ERROR" or "OK" as response, so push a line read |
956 |
$handle->push_read (line => sub { |
957 |
# if we got an "OK", we have to _prepend_ another line, |
958 |
# so it will be read before the second request reads its 64 bytes |
959 |
# which are already in the queue when this callback is called |
960 |
# we don't do this in case we got an error |
961 |
if ($_[1] eq "OK") { |
962 |
$_[0]->unshift_read (line => sub { |
963 |
my $response = $_[1]; |
964 |
... |
965 |
}); |
966 |
} |
967 |
}); |
968 |
|
969 |
# request two, simply returns 64 octets |
970 |
$handle->push_write ("request 2\015\012"); |
971 |
|
972 |
# simply read 64 bytes, always |
973 |
$handle->push_read (chunk => 64, sub { |
974 |
my $response = $_[1]; |
975 |
... |
976 |
}); |
977 |
|
978 |
=over 4 |
979 |
|
980 |
=cut |
981 |
|
982 |
sub _drain_rbuf { |
983 |
my ($self) = @_; |
984 |
|
985 |
# avoid recursion |
986 |
return if exists $self->{_skip_drain_rbuf}; |
987 |
local $self->{_skip_drain_rbuf} = 1; |
988 |
|
989 |
if ( |
990 |
defined $self->{rbuf_max} |
991 |
&& $self->{rbuf_max} < length $self->{rbuf} |
992 |
) { |
993 |
$self->_error (Errno::ENOSPC, 1), return; |
994 |
} |
995 |
|
996 |
while () { |
997 |
# we need to use a separate tls read buffer, as we must not receive data while |
998 |
# we are draining the buffer, and this can only happen with TLS. |
999 |
$self->{rbuf} .= delete $self->{_tls_rbuf} |
1000 |
if exists $self->{_tls_rbuf}; |
1001 |
|
1002 |
my $len = length $self->{rbuf}; |
1003 |
|
1004 |
if (my $cb = shift @{ $self->{_queue} }) { |
1005 |
unless ($cb->($self)) { |
1006 |
# no progress can be made |
1007 |
# (not enough data and no data forthcoming) |
1008 |
$self->_error (Errno::EPIPE, 1), return |
1009 |
if $self->{_eof}; |
1010 |
|
1011 |
unshift @{ $self->{_queue} }, $cb; |
1012 |
last; |
1013 |
} |
1014 |
} elsif ($self->{on_read}) { |
1015 |
last unless $len; |
1016 |
|
1017 |
$self->{on_read}($self); |
1018 |
|
1019 |
if ( |
1020 |
$len == length $self->{rbuf} # if no data has been consumed |
1021 |
&& !@{ $self->{_queue} } # and the queue is still empty |
1022 |
&& $self->{on_read} # but we still have on_read |
1023 |
) { |
1024 |
# no further data will arrive |
1025 |
# so no progress can be made |
1026 |
$self->_error (Errno::EPIPE, 1), return |
1027 |
if $self->{_eof}; |
1028 |
|
1029 |
last; # more data might arrive |
1030 |
} |
1031 |
} else { |
1032 |
# read side becomes idle |
1033 |
delete $self->{_rw} unless $self->{tls}; |
1034 |
last; |
1035 |
} |
1036 |
} |
1037 |
|
1038 |
if ($self->{_eof}) { |
1039 |
$self->{on_eof} |
1040 |
? $self->{on_eof}($self) |
1041 |
: $self->_error (0, 1, "Unexpected end-of-file"); |
1042 |
|
1043 |
return; |
1044 |
} |
1045 |
|
1046 |
# may need to restart read watcher |
1047 |
unless ($self->{_rw}) { |
1048 |
$self->start_read |
1049 |
if $self->{on_read} || @{ $self->{_queue} }; |
1050 |
} |
1051 |
} |
1052 |
|
1053 |
=item $handle->on_read ($cb) |
1054 |
|
1055 |
This replaces the currently set C<on_read> callback, or clears it (when |
1056 |
the new callback is C<undef>). See the description of C<on_read> in the |
1057 |
constructor. |
1058 |
|
1059 |
=cut |
1060 |
|
1061 |
sub on_read { |
1062 |
my ($self, $cb) = @_; |
1063 |
|
1064 |
$self->{on_read} = $cb; |
1065 |
$self->_drain_rbuf if $cb; |
1066 |
} |
1067 |
|
1068 |
=item $handle->rbuf |
1069 |
|
1070 |
Returns the read buffer (as a modifiable lvalue). |
1071 |
|
1072 |
You can access the read buffer directly as the C<< ->{rbuf} >> |
1073 |
member, if you want. However, the only operation allowed on the |
1074 |
read buffer (apart from looking at it) is removing data from its |
1075 |
beginning. Otherwise modifying or appending to it is not allowed and will |
1076 |
lead to hard-to-track-down bugs. |
1077 |
|
1078 |
NOTE: The read buffer should only be used or modified if the C<on_read>, |
1079 |
C<push_read> or C<unshift_read> methods are used. The other read methods |
1080 |
automatically manage the read buffer. |
1081 |
|
1082 |
=cut |
1083 |
|
1084 |
sub rbuf : lvalue { |
1085 |
$_[0]{rbuf} |
1086 |
} |
1087 |
|
1088 |
=item $handle->push_read ($cb) |
1089 |
|
1090 |
=item $handle->unshift_read ($cb) |
1091 |
|
1092 |
Append the given callback to the end of the queue (C<push_read>) or |
1093 |
prepend it (C<unshift_read>). |
1094 |
|
1095 |
The callback is called each time some additional read data arrives. |
1096 |
|
1097 |
It must check whether enough data is in the read buffer already. |
1098 |
|
1099 |
If not enough data is available, it must return the empty list or a false |
1100 |
value, in which case it will be called repeatedly until enough data is |
1101 |
available (or an error condition is detected). |
1102 |
|
1103 |
If enough data was available, then the callback must remove all data it is |
1104 |
interested in (which can be none at all) and return a true value. After returning |
1105 |
true, it will be removed from the queue. |
1106 |
|
1107 |
=cut |
1108 |
|
1109 |
our %RH; |
1110 |
|
1111 |
sub register_read_type($$) { |
1112 |
$RH{$_[0]} = $_[1]; |
1113 |
} |
1114 |
|
1115 |
sub push_read { |
1116 |
my $self = shift; |
1117 |
my $cb = pop; |
1118 |
|
1119 |
if (@_) { |
1120 |
my $type = shift; |
1121 |
|
1122 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_read") |
1123 |
->($self, $cb, @_); |
1124 |
} |
1125 |
|
1126 |
push @{ $self->{_queue} }, $cb; |
1127 |
$self->_drain_rbuf; |
1128 |
} |
1129 |
|
1130 |
sub unshift_read { |
1131 |
my $self = shift; |
1132 |
my $cb = pop; |
1133 |
|
1134 |
if (@_) { |
1135 |
my $type = shift; |
1136 |
|
1137 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::unshift_read") |
1138 |
->($self, $cb, @_); |
1139 |
} |
1140 |
|
1141 |
|
1142 |
unshift @{ $self->{_queue} }, $cb; |
1143 |
$self->_drain_rbuf; |
1144 |
} |
1145 |
|
1146 |
=item $handle->push_read (type => @args, $cb) |
1147 |
|
1148 |
=item $handle->unshift_read (type => @args, $cb) |
1149 |
|
1150 |
Instead of providing a callback that parses the data itself you can chose |
1151 |
between a number of predefined parsing formats, for chunks of data, lines |
1152 |
etc. |
1153 |
|
1154 |
Predefined types are (if you have ideas for additional types, feel free to |
1155 |
drop by and tell us): |
1156 |
|
1157 |
=over 4 |
1158 |
|
1159 |
=item chunk => $octets, $cb->($handle, $data) |
1160 |
|
1161 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
1162 |
data read to the callback. The callback will never be called with less |
1163 |
data. |
1164 |
|
1165 |
Example: read 2 bytes. |
1166 |
|
1167 |
$handle->push_read (chunk => 2, sub { |
1168 |
warn "yay ", unpack "H*", $_[1]; |
1169 |
}); |
1170 |
|
1171 |
=cut |
1172 |
|
1173 |
register_read_type chunk => sub { |
1174 |
my ($self, $cb, $len) = @_; |
1175 |
|
1176 |
sub { |
1177 |
$len <= length $_[0]{rbuf} or return; |
1178 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
1179 |
1 |
1180 |
} |
1181 |
}; |
1182 |
|
1183 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
1184 |
|
1185 |
The callback will be called only once a full line (including the end of |
1186 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
1187 |
marker) will be passed to the callback as second argument (C<$line>), and |
1188 |
the end of line marker as the third argument (C<$eol>). |
1189 |
|
1190 |
The end of line marker, C<$eol>, can be either a string, in which case it |
1191 |
will be interpreted as a fixed record end marker, or it can be a regex |
1192 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
1193 |
regular expression. |
1194 |
|
1195 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
1196 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
1197 |
protocols). |
1198 |
|
1199 |
Partial lines at the end of the stream will never be returned, as they are |
1200 |
not marked by the end of line marker. |
1201 |
|
1202 |
=cut |
1203 |
|
1204 |
register_read_type line => sub { |
1205 |
my ($self, $cb, $eol) = @_; |
1206 |
|
1207 |
if (@_ < 3) { |
1208 |
# this is more than twice as fast as the generic code below |
1209 |
sub { |
1210 |
$_[0]{rbuf} =~ s/^([^\015\012]*)(\015?\012)// or return; |
1211 |
|
1212 |
$cb->($_[0], $1, $2); |
1213 |
1 |
1214 |
} |
1215 |
} else { |
1216 |
$eol = quotemeta $eol unless ref $eol; |
1217 |
$eol = qr|^(.*?)($eol)|s; |
1218 |
|
1219 |
sub { |
1220 |
$_[0]{rbuf} =~ s/$eol// or return; |
1221 |
|
1222 |
$cb->($_[0], $1, $2); |
1223 |
1 |
1224 |
} |
1225 |
} |
1226 |
}; |
1227 |
|
1228 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
1229 |
|
1230 |
Makes a regex match against the regex object C<$accept> and returns |
1231 |
everything up to and including the match. |
1232 |
|
1233 |
Example: read a single line terminated by '\n'. |
1234 |
|
1235 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
1236 |
|
1237 |
If C<$reject> is given and not undef, then it determines when the data is |
1238 |
to be rejected: it is matched against the data when the C<$accept> regex |
1239 |
does not match and generates an C<EBADMSG> error when it matches. This is |
1240 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
1241 |
receive buffer overflow). |
1242 |
|
1243 |
Example: expect a single decimal number followed by whitespace, reject |
1244 |
anything else (not the use of an anchor). |
1245 |
|
1246 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
1247 |
|
1248 |
If C<$skip> is given and not C<undef>, then it will be matched against |
1249 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
1250 |
and everything preceding and including the match will be accepted |
1251 |
unconditionally. This is useful to skip large amounts of data that you |
1252 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
1253 |
have to start matching from the beginning. This is purely an optimisation |
1254 |
and is usually worth only when you expect more than a few kilobytes. |
1255 |
|
1256 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
1257 |
expect the header to be very large (it isn't in practise, but...), we use |
1258 |
a skip regex to skip initial portions. The skip regex is tricky in that |
1259 |
it only accepts something not ending in either \015 or \012, as these are |
1260 |
required for the accept regex. |
1261 |
|
1262 |
$handle->push_read (regex => |
1263 |
qr<\015\012\015\012>, |
1264 |
undef, # no reject |
1265 |
qr<^.*[^\015\012]>, |
1266 |
sub { ... }); |
1267 |
|
1268 |
=cut |
1269 |
|
1270 |
register_read_type regex => sub { |
1271 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
1272 |
|
1273 |
my $data; |
1274 |
my $rbuf = \$self->{rbuf}; |
1275 |
|
1276 |
sub { |
1277 |
# accept |
1278 |
if ($$rbuf =~ $accept) { |
1279 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1280 |
$cb->($self, $data); |
1281 |
return 1; |
1282 |
} |
1283 |
|
1284 |
# reject |
1285 |
if ($reject && $$rbuf =~ $reject) { |
1286 |
$self->_error (Errno::EBADMSG); |
1287 |
} |
1288 |
|
1289 |
# skip |
1290 |
if ($skip && $$rbuf =~ $skip) { |
1291 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1292 |
} |
1293 |
|
1294 |
() |
1295 |
} |
1296 |
}; |
1297 |
|
1298 |
=item netstring => $cb->($handle, $string) |
1299 |
|
1300 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
1301 |
|
1302 |
Throws an error with C<$!> set to EBADMSG on format violations. |
1303 |
|
1304 |
=cut |
1305 |
|
1306 |
register_read_type netstring => sub { |
1307 |
my ($self, $cb) = @_; |
1308 |
|
1309 |
sub { |
1310 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
1311 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
1312 |
$self->_error (Errno::EBADMSG); |
1313 |
} |
1314 |
return; |
1315 |
} |
1316 |
|
1317 |
my $len = $1; |
1318 |
|
1319 |
$self->unshift_read (chunk => $len, sub { |
1320 |
my $string = $_[1]; |
1321 |
$_[0]->unshift_read (chunk => 1, sub { |
1322 |
if ($_[1] eq ",") { |
1323 |
$cb->($_[0], $string); |
1324 |
} else { |
1325 |
$self->_error (Errno::EBADMSG); |
1326 |
} |
1327 |
}); |
1328 |
}); |
1329 |
|
1330 |
1 |
1331 |
} |
1332 |
}; |
1333 |
|
1334 |
=item packstring => $format, $cb->($handle, $string) |
1335 |
|
1336 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1337 |
uses the same format as a Perl C<pack> format, but must specify a single |
1338 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1339 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1340 |
|
1341 |
For example, DNS over TCP uses a prefix of C<n> (2 octet network order), |
1342 |
EPP uses a prefix of C<N> (4 octtes). |
1343 |
|
1344 |
Example: read a block of data prefixed by its length in BER-encoded |
1345 |
format (very efficient). |
1346 |
|
1347 |
$handle->push_read (packstring => "w", sub { |
1348 |
my ($handle, $data) = @_; |
1349 |
}); |
1350 |
|
1351 |
=cut |
1352 |
|
1353 |
register_read_type packstring => sub { |
1354 |
my ($self, $cb, $format) = @_; |
1355 |
|
1356 |
sub { |
1357 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1358 |
defined (my $len = eval { unpack $format, $_[0]{rbuf} }) |
1359 |
or return; |
1360 |
|
1361 |
$format = length pack $format, $len; |
1362 |
|
1363 |
# bypass unshift if we already have the remaining chunk |
1364 |
if ($format + $len <= length $_[0]{rbuf}) { |
1365 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1366 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1367 |
$cb->($_[0], $data); |
1368 |
} else { |
1369 |
# remove prefix |
1370 |
substr $_[0]{rbuf}, 0, $format, ""; |
1371 |
|
1372 |
# read remaining chunk |
1373 |
$_[0]->unshift_read (chunk => $len, $cb); |
1374 |
} |
1375 |
|
1376 |
1 |
1377 |
} |
1378 |
}; |
1379 |
|
1380 |
=item json => $cb->($handle, $hash_or_arrayref) |
1381 |
|
1382 |
Reads a JSON object or array, decodes it and passes it to the |
1383 |
callback. When a parse error occurs, an C<EBADMSG> error will be raised. |
1384 |
|
1385 |
If a C<json> object was passed to the constructor, then that will be used |
1386 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1387 |
|
1388 |
This read type uses the incremental parser available with JSON version |
1389 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1390 |
dependency on your own: this module will load the JSON module, but |
1391 |
AnyEvent does not depend on it itself. |
1392 |
|
1393 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1394 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1395 |
the C<json> write type description, above, for an actual example. |
1396 |
|
1397 |
=cut |
1398 |
|
1399 |
register_read_type json => sub { |
1400 |
my ($self, $cb) = @_; |
1401 |
|
1402 |
my $json = $self->{json} ||= |
1403 |
eval { require JSON::XS; JSON::XS->new->utf8 } |
1404 |
|| do { require JSON; JSON->new->utf8 }; |
1405 |
|
1406 |
my $data; |
1407 |
my $rbuf = \$self->{rbuf}; |
1408 |
|
1409 |
sub { |
1410 |
my $ref = eval { $json->incr_parse ($self->{rbuf}) }; |
1411 |
|
1412 |
if ($ref) { |
1413 |
$self->{rbuf} = $json->incr_text; |
1414 |
$json->incr_text = ""; |
1415 |
$cb->($self, $ref); |
1416 |
|
1417 |
1 |
1418 |
} elsif ($@) { |
1419 |
# error case |
1420 |
$json->incr_skip; |
1421 |
|
1422 |
$self->{rbuf} = $json->incr_text; |
1423 |
$json->incr_text = ""; |
1424 |
|
1425 |
$self->_error (Errno::EBADMSG); |
1426 |
|
1427 |
() |
1428 |
} else { |
1429 |
$self->{rbuf} = ""; |
1430 |
|
1431 |
() |
1432 |
} |
1433 |
} |
1434 |
}; |
1435 |
|
1436 |
=item storable => $cb->($handle, $ref) |
1437 |
|
1438 |
Deserialises a L<Storable> frozen representation as written by the |
1439 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1440 |
data). |
1441 |
|
1442 |
Raises C<EBADMSG> error if the data could not be decoded. |
1443 |
|
1444 |
=cut |
1445 |
|
1446 |
register_read_type storable => sub { |
1447 |
my ($self, $cb) = @_; |
1448 |
|
1449 |
require Storable; |
1450 |
|
1451 |
sub { |
1452 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1453 |
defined (my $len = eval { unpack "w", $_[0]{rbuf} }) |
1454 |
or return; |
1455 |
|
1456 |
my $format = length pack "w", $len; |
1457 |
|
1458 |
# bypass unshift if we already have the remaining chunk |
1459 |
if ($format + $len <= length $_[0]{rbuf}) { |
1460 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1461 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1462 |
$cb->($_[0], Storable::thaw ($data)); |
1463 |
} else { |
1464 |
# remove prefix |
1465 |
substr $_[0]{rbuf}, 0, $format, ""; |
1466 |
|
1467 |
# read remaining chunk |
1468 |
$_[0]->unshift_read (chunk => $len, sub { |
1469 |
if (my $ref = eval { Storable::thaw ($_[1]) }) { |
1470 |
$cb->($_[0], $ref); |
1471 |
} else { |
1472 |
$self->_error (Errno::EBADMSG); |
1473 |
} |
1474 |
}); |
1475 |
} |
1476 |
|
1477 |
1 |
1478 |
} |
1479 |
}; |
1480 |
|
1481 |
=back |
1482 |
|
1483 |
=item AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args) |
1484 |
|
1485 |
This function (not method) lets you add your own types to C<push_read>. |
1486 |
|
1487 |
Whenever the given C<type> is used, C<push_read> will invoke the code |
1488 |
reference with the handle object, the callback and the remaining |
1489 |
arguments. |
1490 |
|
1491 |
The code reference is supposed to return a callback (usually a closure) |
1492 |
that works as a plain read callback (see C<< ->push_read ($cb) >>). |
1493 |
|
1494 |
It should invoke the passed callback when it is done reading (remember to |
1495 |
pass C<$handle> as first argument as all other callbacks do that). |
1496 |
|
1497 |
Note that this is a function, and all types registered this way will be |
1498 |
global, so try to use unique names. |
1499 |
|
1500 |
For examples, see the source of this module (F<perldoc -m AnyEvent::Handle>, |
1501 |
search for C<register_read_type>)). |
1502 |
|
1503 |
=item $handle->stop_read |
1504 |
|
1505 |
=item $handle->start_read |
1506 |
|
1507 |
In rare cases you actually do not want to read anything from the |
1508 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1509 |
any queued callbacks will be executed then. To start reading again, call |
1510 |
C<start_read>. |
1511 |
|
1512 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1513 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1514 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1515 |
there are any read requests in the queue. |
1516 |
|
1517 |
These methods will have no effect when in TLS mode (as TLS doesn't support |
1518 |
half-duplex connections). |
1519 |
|
1520 |
=cut |
1521 |
|
1522 |
sub stop_read { |
1523 |
my ($self) = @_; |
1524 |
|
1525 |
delete $self->{_rw} unless $self->{tls}; |
1526 |
} |
1527 |
|
1528 |
sub start_read { |
1529 |
my ($self) = @_; |
1530 |
|
1531 |
unless ($self->{_rw} || $self->{_eof}) { |
1532 |
Scalar::Util::weaken $self; |
1533 |
|
1534 |
$self->{_rw} = AnyEvent->io (fh => $self->{fh}, poll => "r", cb => sub { |
1535 |
my $rbuf = \($self->{tls} ? my $buf : $self->{rbuf}); |
1536 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size} || 8192, length $$rbuf; |
1537 |
|
1538 |
if ($len > 0) { |
1539 |
$self->{_activity} = AnyEvent->now; |
1540 |
|
1541 |
if ($self->{tls}) { |
1542 |
Net::SSLeay::BIO_write ($self->{_rbio}, $$rbuf); |
1543 |
|
1544 |
&_dotls ($self); |
1545 |
} else { |
1546 |
$self->_drain_rbuf; |
1547 |
} |
1548 |
|
1549 |
} elsif (defined $len) { |
1550 |
delete $self->{_rw}; |
1551 |
$self->{_eof} = 1; |
1552 |
$self->_drain_rbuf; |
1553 |
|
1554 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1555 |
return $self->_error ($!, 1); |
1556 |
} |
1557 |
}); |
1558 |
} |
1559 |
} |
1560 |
|
1561 |
our $ERROR_SYSCALL; |
1562 |
our $ERROR_WANT_READ; |
1563 |
|
1564 |
sub _tls_error { |
1565 |
my ($self, $err) = @_; |
1566 |
|
1567 |
return $self->_error ($!, 1) |
1568 |
if $err == Net::SSLeay::ERROR_SYSCALL (); |
1569 |
|
1570 |
my $err =Net::SSLeay::ERR_error_string (Net::SSLeay::ERR_get_error ()); |
1571 |
|
1572 |
# reduce error string to look less scary |
1573 |
$err =~ s/^error:[0-9a-fA-F]{8}:[^:]+:([^:]+):/\L$1: /; |
1574 |
|
1575 |
if ($self->{_on_starttls}) { |
1576 |
(delete $self->{_on_starttls})->($self, undef, $err); |
1577 |
&_freetls; |
1578 |
} else { |
1579 |
&_freetls; |
1580 |
$self->_error (Errno::EPROTO, 1, $err); |
1581 |
} |
1582 |
} |
1583 |
|
1584 |
# poll the write BIO and send the data if applicable |
1585 |
# also decode read data if possible |
1586 |
# this is basiclaly our TLS state machine |
1587 |
# more efficient implementations are possible with openssl, |
1588 |
# but not with the buggy and incomplete Net::SSLeay. |
1589 |
sub _dotls { |
1590 |
my ($self) = @_; |
1591 |
|
1592 |
my $tmp; |
1593 |
|
1594 |
if (length $self->{_tls_wbuf}) { |
1595 |
while (($tmp = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1596 |
substr $self->{_tls_wbuf}, 0, $tmp, ""; |
1597 |
} |
1598 |
|
1599 |
$tmp = Net::SSLeay::get_error ($self->{tls}, $tmp); |
1600 |
return $self->_tls_error ($tmp) |
1601 |
if $tmp != $ERROR_WANT_READ |
1602 |
&& ($tmp != $ERROR_SYSCALL || $!); |
1603 |
} |
1604 |
|
1605 |
while (defined ($tmp = Net::SSLeay::read ($self->{tls}))) { |
1606 |
unless (length $tmp) { |
1607 |
$self->{_on_starttls} |
1608 |
and (delete $self->{_on_starttls})->($self, undef, "EOF during handshake"); # ??? |
1609 |
&_freetls; |
1610 |
|
1611 |
if ($self->{on_stoptls}) { |
1612 |
$self->{on_stoptls}($self); |
1613 |
return; |
1614 |
} else { |
1615 |
# let's treat SSL-eof as we treat normal EOF |
1616 |
delete $self->{_rw}; |
1617 |
$self->{_eof} = 1; |
1618 |
} |
1619 |
} |
1620 |
|
1621 |
$self->{_tls_rbuf} .= $tmp; |
1622 |
$self->_drain_rbuf; |
1623 |
$self->{tls} or return; # tls session might have gone away in callback |
1624 |
} |
1625 |
|
1626 |
$tmp = Net::SSLeay::get_error ($self->{tls}, -1); |
1627 |
return $self->_tls_error ($tmp) |
1628 |
if $tmp != $ERROR_WANT_READ |
1629 |
&& ($tmp != $ERROR_SYSCALL || $!); |
1630 |
|
1631 |
while (length ($tmp = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1632 |
$self->{wbuf} .= $tmp; |
1633 |
$self->_drain_wbuf; |
1634 |
} |
1635 |
|
1636 |
$self->{_on_starttls} |
1637 |
and Net::SSLeay::state ($self->{tls}) == Net::SSLeay::ST_OK () |
1638 |
and (delete $self->{_on_starttls})->($self, 1, "TLS/SSL connection established"); |
1639 |
} |
1640 |
|
1641 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1642 |
|
1643 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1644 |
object is created, you can also do that at a later time by calling |
1645 |
C<starttls>. |
1646 |
|
1647 |
Starting TLS is currently an asynchronous operation - when you push some |
1648 |
write data and then call C<< ->starttls >> then TLS negotiation will start |
1649 |
immediately, after which the queued write data is then sent. |
1650 |
|
1651 |
The first argument is the same as the C<tls> constructor argument (either |
1652 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1653 |
|
1654 |
The second argument is the optional C<AnyEvent::TLS> object that is used |
1655 |
when AnyEvent::Handle has to create its own TLS connection object, or |
1656 |
a hash reference with C<< key => value >> pairs that will be used to |
1657 |
construct a new context. |
1658 |
|
1659 |
The TLS connection object will end up in C<< $handle->{tls} >>, the TLS |
1660 |
context in C<< $handle->{tls_ctx} >> after this call and can be used or |
1661 |
changed to your liking. Note that the handshake might have already started |
1662 |
when this function returns. |
1663 |
|
1664 |
Due to bugs in OpenSSL, it might or might not be possible to do multiple |
1665 |
handshakes on the same stream. Best do not attempt to use the stream after |
1666 |
stopping TLS. |
1667 |
|
1668 |
=cut |
1669 |
|
1670 |
our %TLS_CACHE; #TODO not yet documented, should we? |
1671 |
|
1672 |
sub starttls { |
1673 |
my ($self, $tls, $ctx) = @_; |
1674 |
|
1675 |
Carp::croak "It is an error to call starttls on an AnyEvent::Handle object while TLS is already active, caught" |
1676 |
if $self->{tls}; |
1677 |
|
1678 |
$self->{tls} = $tls; |
1679 |
$self->{tls_ctx} = $ctx if @_ > 2; |
1680 |
|
1681 |
return unless $self->{fh}; |
1682 |
|
1683 |
require Net::SSLeay; |
1684 |
|
1685 |
$ERROR_SYSCALL = Net::SSLeay::ERROR_SYSCALL (); |
1686 |
$ERROR_WANT_READ = Net::SSLeay::ERROR_WANT_READ (); |
1687 |
|
1688 |
$tls = $self->{tls}; |
1689 |
$ctx = $self->{tls_ctx}; |
1690 |
|
1691 |
local $Carp::CarpLevel = 1; # skip ourselves when creating a new context or session |
1692 |
|
1693 |
if ("HASH" eq ref $ctx) { |
1694 |
require AnyEvent::TLS; |
1695 |
|
1696 |
if ($ctx->{cache}) { |
1697 |
my $key = $ctx+0; |
1698 |
$ctx = $TLS_CACHE{$key} ||= new AnyEvent::TLS %$ctx; |
1699 |
} else { |
1700 |
$ctx = new AnyEvent::TLS %$ctx; |
1701 |
} |
1702 |
} |
1703 |
|
1704 |
$self->{tls_ctx} = $ctx || TLS_CTX (); |
1705 |
$self->{tls} = $tls = $self->{tls_ctx}->_get_session ($tls, $self, $self->{peername}); |
1706 |
|
1707 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1708 |
# but the openssl maintainers basically said: "trust us, it just works". |
1709 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1710 |
# and mismaintained ssleay-module doesn't even offer them). |
1711 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1712 |
# |
1713 |
# in short: this is a mess. |
1714 |
# |
1715 |
# note that we do not try to keep the length constant between writes as we are required to do. |
1716 |
# we assume that most (but not all) of this insanity only applies to non-blocking cases, |
1717 |
# and we drive openssl fully in blocking mode here. Or maybe we don't - openssl seems to |
1718 |
# have identity issues in that area. |
1719 |
# Net::SSLeay::CTX_set_mode ($ssl, |
1720 |
# (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1721 |
# | (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1722 |
Net::SSLeay::CTX_set_mode ($tls, 1|2); |
1723 |
|
1724 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1725 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1726 |
|
1727 |
Net::SSLeay::set_bio ($tls, $self->{_rbio}, $self->{_wbio}); |
1728 |
|
1729 |
$self->{_on_starttls} = sub { $_[0]{on_starttls}(@_) } |
1730 |
if $self->{on_starttls}; |
1731 |
|
1732 |
&_dotls; # need to trigger the initial handshake |
1733 |
$self->start_read; # make sure we actually do read |
1734 |
} |
1735 |
|
1736 |
=item $handle->stoptls |
1737 |
|
1738 |
Shuts down the SSL connection - this makes a proper EOF handshake by |
1739 |
sending a close notify to the other side, but since OpenSSL doesn't |
1740 |
support non-blocking shut downs, it is not guarenteed that you can re-use |
1741 |
the stream afterwards. |
1742 |
|
1743 |
=cut |
1744 |
|
1745 |
sub stoptls { |
1746 |
my ($self) = @_; |
1747 |
|
1748 |
if ($self->{tls}) { |
1749 |
Net::SSLeay::shutdown ($self->{tls}); |
1750 |
|
1751 |
&_dotls; |
1752 |
|
1753 |
# # we don't give a shit. no, we do, but we can't. no...#d# |
1754 |
# # we, we... have to use openssl :/#d# |
1755 |
# &_freetls;#d# |
1756 |
} |
1757 |
} |
1758 |
|
1759 |
sub _freetls { |
1760 |
my ($self) = @_; |
1761 |
|
1762 |
return unless $self->{tls}; |
1763 |
|
1764 |
$self->{tls_ctx}->_put_session (delete $self->{tls}) |
1765 |
if ref $self->{tls}; |
1766 |
|
1767 |
delete @$self{qw(_rbio _wbio _tls_wbuf _on_starttls)}; |
1768 |
} |
1769 |
|
1770 |
sub DESTROY { |
1771 |
my ($self) = @_; |
1772 |
|
1773 |
&_freetls; |
1774 |
|
1775 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
1776 |
|
1777 |
if ($linger && length $self->{wbuf} && $self->{fh}) { |
1778 |
my $fh = delete $self->{fh}; |
1779 |
my $wbuf = delete $self->{wbuf}; |
1780 |
|
1781 |
my @linger; |
1782 |
|
1783 |
push @linger, AnyEvent->io (fh => $fh, poll => "w", cb => sub { |
1784 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
1785 |
|
1786 |
if ($len > 0) { |
1787 |
substr $wbuf, 0, $len, ""; |
1788 |
} else { |
1789 |
@linger = (); # end |
1790 |
} |
1791 |
}); |
1792 |
push @linger, AnyEvent->timer (after => $linger, cb => sub { |
1793 |
@linger = (); |
1794 |
}); |
1795 |
} |
1796 |
} |
1797 |
|
1798 |
=item $handle->destroy |
1799 |
|
1800 |
Shuts down the handle object as much as possible - this call ensures that |
1801 |
no further callbacks will be invoked and as many resources as possible |
1802 |
will be freed. Any method you will call on the handle object after |
1803 |
destroying it in this way will be silently ignored (and it will return the |
1804 |
empty list). |
1805 |
|
1806 |
Normally, you can just "forget" any references to an AnyEvent::Handle |
1807 |
object and it will simply shut down. This works in fatal error and EOF |
1808 |
callbacks, as well as code outside. It does I<NOT> work in a read or write |
1809 |
callback, so when you want to destroy the AnyEvent::Handle object from |
1810 |
within such an callback. You I<MUST> call C<< ->destroy >> explicitly in |
1811 |
that case. |
1812 |
|
1813 |
Destroying the handle object in this way has the advantage that callbacks |
1814 |
will be removed as well, so if those are the only reference holders (as |
1815 |
is common), then one doesn't need to do anything special to break any |
1816 |
reference cycles. |
1817 |
|
1818 |
The handle might still linger in the background and write out remaining |
1819 |
data, as specified by the C<linger> option, however. |
1820 |
|
1821 |
=cut |
1822 |
|
1823 |
sub destroy { |
1824 |
my ($self) = @_; |
1825 |
|
1826 |
$self->DESTROY; |
1827 |
%$self = (); |
1828 |
bless $self, "AnyEvent::Handle::destroyed"; |
1829 |
} |
1830 |
|
1831 |
sub AnyEvent::Handle::destroyed::AUTOLOAD { |
1832 |
#nop |
1833 |
} |
1834 |
|
1835 |
=item AnyEvent::Handle::TLS_CTX |
1836 |
|
1837 |
This function creates and returns the AnyEvent::TLS object used by default |
1838 |
for TLS mode. |
1839 |
|
1840 |
The context is created by calling L<AnyEvent::TLS> without any arguments. |
1841 |
|
1842 |
=cut |
1843 |
|
1844 |
our $TLS_CTX; |
1845 |
|
1846 |
sub TLS_CTX() { |
1847 |
$TLS_CTX ||= do { |
1848 |
require AnyEvent::TLS; |
1849 |
|
1850 |
new AnyEvent::TLS |
1851 |
} |
1852 |
} |
1853 |
|
1854 |
=back |
1855 |
|
1856 |
|
1857 |
=head1 NONFREQUENTLY ASKED QUESTIONS |
1858 |
|
1859 |
=over 4 |
1860 |
|
1861 |
=item I C<undef> the AnyEvent::Handle reference inside my callback and |
1862 |
still get further invocations! |
1863 |
|
1864 |
That's because AnyEvent::Handle keeps a reference to itself when handling |
1865 |
read or write callbacks. |
1866 |
|
1867 |
It is only safe to "forget" the reference inside EOF or error callbacks, |
1868 |
from within all other callbacks, you need to explicitly call the C<< |
1869 |
->destroy >> method. |
1870 |
|
1871 |
=item I get different callback invocations in TLS mode/Why can't I pause |
1872 |
reading? |
1873 |
|
1874 |
Unlike, say, TCP, TLS connections do not consist of two independent |
1875 |
communication channels, one for each direction. Or put differently. The |
1876 |
read and write directions are not independent of each other: you cannot |
1877 |
write data unless you are also prepared to read, and vice versa. |
1878 |
|
1879 |
This can mean than, in TLS mode, you might get C<on_error> or C<on_eof> |
1880 |
callback invocations when you are not expecting any read data - the reason |
1881 |
is that AnyEvent::Handle always reads in TLS mode. |
1882 |
|
1883 |
During the connection, you have to make sure that you always have a |
1884 |
non-empty read-queue, or an C<on_read> watcher. At the end of the |
1885 |
connection (or when you no longer want to use it) you can call the |
1886 |
C<destroy> method. |
1887 |
|
1888 |
=item How do I read data until the other side closes the connection? |
1889 |
|
1890 |
If you just want to read your data into a perl scalar, the easiest way |
1891 |
to achieve this is by setting an C<on_read> callback that does nothing, |
1892 |
clearing the C<on_eof> callback and in the C<on_error> callback, the data |
1893 |
will be in C<$_[0]{rbuf}>: |
1894 |
|
1895 |
$handle->on_read (sub { }); |
1896 |
$handle->on_eof (undef); |
1897 |
$handle->on_error (sub { |
1898 |
my $data = delete $_[0]{rbuf}; |
1899 |
}); |
1900 |
|
1901 |
The reason to use C<on_error> is that TCP connections, due to latencies |
1902 |
and packets loss, might get closed quite violently with an error, when in |
1903 |
fact, all data has been received. |
1904 |
|
1905 |
It is usually better to use acknowledgements when transferring data, |
1906 |
to make sure the other side hasn't just died and you got the data |
1907 |
intact. This is also one reason why so many internet protocols have an |
1908 |
explicit QUIT command. |
1909 |
|
1910 |
=item I don't want to destroy the handle too early - how do I wait until |
1911 |
all data has been written? |
1912 |
|
1913 |
After writing your last bits of data, set the C<on_drain> callback |
1914 |
and destroy the handle in there - with the default setting of |
1915 |
C<low_water_mark> this will be called precisely when all data has been |
1916 |
written to the socket: |
1917 |
|
1918 |
$handle->push_write (...); |
1919 |
$handle->on_drain (sub { |
1920 |
warn "all data submitted to the kernel\n"; |
1921 |
undef $handle; |
1922 |
}); |
1923 |
|
1924 |
If you just want to queue some data and then signal EOF to the other side, |
1925 |
consider using C<< ->push_shutdown >> instead. |
1926 |
|
1927 |
=item I want to contact a TLS/SSL server, I don't care about security. |
1928 |
|
1929 |
If your TLS server is a pure TLS server (e.g. HTTPS) that only speaks TLS, |
1930 |
simply connect to it and then create the AnyEvent::Handle with the C<tls> |
1931 |
parameter: |
1932 |
|
1933 |
tcp_connect $host, $port, sub { |
1934 |
my ($fh) = @_; |
1935 |
|
1936 |
my $handle = new AnyEvent::Handle |
1937 |
fh => $fh, |
1938 |
tls => "connect", |
1939 |
on_error => sub { ... }; |
1940 |
|
1941 |
$handle->push_write (...); |
1942 |
}; |
1943 |
|
1944 |
=item I want to contact a TLS/SSL server, I do care about security. |
1945 |
|
1946 |
Then you should additionally enable certificate verification, including |
1947 |
peername verification, if the protocol you use supports it (see |
1948 |
L<AnyEvent::TLS>, C<verify_peername>). |
1949 |
|
1950 |
E.g. for HTTPS: |
1951 |
|
1952 |
tcp_connect $host, $port, sub { |
1953 |
my ($fh) = @_; |
1954 |
|
1955 |
my $handle = new AnyEvent::Handle |
1956 |
fh => $fh, |
1957 |
peername => $host, |
1958 |
tls => "connect", |
1959 |
tls_ctx => { verify => 1, verify_peername => "https" }, |
1960 |
... |
1961 |
|
1962 |
Note that you must specify the hostname you connected to (or whatever |
1963 |
"peername" the protocol needs) as the C<peername> argument, otherwise no |
1964 |
peername verification will be done. |
1965 |
|
1966 |
The above will use the system-dependent default set of trusted CA |
1967 |
certificates. If you want to check against a specific CA, add the |
1968 |
C<ca_file> (or C<ca_cert>) arguments to C<tls_ctx>: |
1969 |
|
1970 |
tls_ctx => { |
1971 |
verify => 1, |
1972 |
verify_peername => "https", |
1973 |
ca_file => "my-ca-cert.pem", |
1974 |
}, |
1975 |
|
1976 |
=item I want to create a TLS/SSL server, how do I do that? |
1977 |
|
1978 |
Well, you first need to get a server certificate and key. You have |
1979 |
three options: a) ask a CA (buy one, use cacert.org etc.) b) create a |
1980 |
self-signed certificate (cheap. check the search engine of your choice, |
1981 |
there are many tutorials on the net) or c) make your own CA (tinyca2 is a |
1982 |
nice program for that purpose). |
1983 |
|
1984 |
Then create a file with your private key (in PEM format, see |
1985 |
L<AnyEvent::TLS>), followed by the certificate (also in PEM format). The |
1986 |
file should then look like this: |
1987 |
|
1988 |
-----BEGIN RSA PRIVATE KEY----- |
1989 |
...header data |
1990 |
... lots of base64'y-stuff |
1991 |
-----END RSA PRIVATE KEY----- |
1992 |
|
1993 |
-----BEGIN CERTIFICATE----- |
1994 |
... lots of base64'y-stuff |
1995 |
-----END CERTIFICATE----- |
1996 |
|
1997 |
The important bits are the "PRIVATE KEY" and "CERTIFICATE" parts. Then |
1998 |
specify this file as C<cert_file>: |
1999 |
|
2000 |
tcp_server undef, $port, sub { |
2001 |
my ($fh) = @_; |
2002 |
|
2003 |
my $handle = new AnyEvent::Handle |
2004 |
fh => $fh, |
2005 |
tls => "accept", |
2006 |
tls_ctx => { cert_file => "my-server-keycert.pem" }, |
2007 |
... |
2008 |
|
2009 |
When you have intermediate CA certificates that your clients might not |
2010 |
know about, just append them to the C<cert_file>. |
2011 |
|
2012 |
=back |
2013 |
|
2014 |
|
2015 |
=head1 SUBCLASSING AnyEvent::Handle |
2016 |
|
2017 |
In many cases, you might want to subclass AnyEvent::Handle. |
2018 |
|
2019 |
To make this easier, a given version of AnyEvent::Handle uses these |
2020 |
conventions: |
2021 |
|
2022 |
=over 4 |
2023 |
|
2024 |
=item * all constructor arguments become object members. |
2025 |
|
2026 |
At least initially, when you pass a C<tls>-argument to the constructor it |
2027 |
will end up in C<< $handle->{tls} >>. Those members might be changed or |
2028 |
mutated later on (for example C<tls> will hold the TLS connection object). |
2029 |
|
2030 |
=item * other object member names are prefixed with an C<_>. |
2031 |
|
2032 |
All object members not explicitly documented (internal use) are prefixed |
2033 |
with an underscore character, so the remaining non-C<_>-namespace is free |
2034 |
for use for subclasses. |
2035 |
|
2036 |
=item * all members not documented here and not prefixed with an underscore |
2037 |
are free to use in subclasses. |
2038 |
|
2039 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
2040 |
member variables, but thats just life, at least it is documented. |
2041 |
|
2042 |
=back |
2043 |
|
2044 |
=head1 AUTHOR |
2045 |
|
2046 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
2047 |
|
2048 |
=cut |
2049 |
|
2050 |
1; # End of AnyEvent::Handle |