1 |
package AnyEvent::Handle; |
2 |
|
3 |
no warnings; |
4 |
use strict qw(subs vars); |
5 |
|
6 |
use AnyEvent (); |
7 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
8 |
use Scalar::Util (); |
9 |
use Carp (); |
10 |
use Fcntl (); |
11 |
use Errno qw(EAGAIN EINTR); |
12 |
|
13 |
=head1 NAME |
14 |
|
15 |
AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent |
16 |
|
17 |
=cut |
18 |
|
19 |
our $VERSION = 4.33; |
20 |
|
21 |
=head1 SYNOPSIS |
22 |
|
23 |
use AnyEvent; |
24 |
use AnyEvent::Handle; |
25 |
|
26 |
my $cv = AnyEvent->condvar; |
27 |
|
28 |
my $handle = |
29 |
AnyEvent::Handle->new ( |
30 |
fh => \*STDIN, |
31 |
on_eof => sub { |
32 |
$cv->broadcast; |
33 |
}, |
34 |
); |
35 |
|
36 |
# send some request line |
37 |
$handle->push_write ("getinfo\015\012"); |
38 |
|
39 |
# read the response line |
40 |
$handle->push_read (line => sub { |
41 |
my ($handle, $line) = @_; |
42 |
warn "read line <$line>\n"; |
43 |
$cv->send; |
44 |
}); |
45 |
|
46 |
$cv->recv; |
47 |
|
48 |
=head1 DESCRIPTION |
49 |
|
50 |
This module is a helper module to make it easier to do event-based I/O on |
51 |
filehandles. For utility functions for doing non-blocking connects and accepts |
52 |
on sockets see L<AnyEvent::Util>. |
53 |
|
54 |
The L<AnyEvent::Intro> tutorial contains some well-documented |
55 |
AnyEvent::Handle examples. |
56 |
|
57 |
In the following, when the documentation refers to of "bytes" then this |
58 |
means characters. As sysread and syswrite are used for all I/O, their |
59 |
treatment of characters applies to this module as well. |
60 |
|
61 |
All callbacks will be invoked with the handle object as their first |
62 |
argument. |
63 |
|
64 |
=head1 METHODS |
65 |
|
66 |
=over 4 |
67 |
|
68 |
=item B<new (%args)> |
69 |
|
70 |
The constructor supports these arguments (all as key => value pairs). |
71 |
|
72 |
=over 4 |
73 |
|
74 |
=item fh => $filehandle [MANDATORY] |
75 |
|
76 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
77 |
|
78 |
NOTE: The filehandle will be set to non-blocking mode (using |
79 |
C<AnyEvent::Util::fh_nonblocking>) by the constructor and needs to stay in |
80 |
that mode. |
81 |
|
82 |
=item on_eof => $cb->($handle) |
83 |
|
84 |
Set the callback to be called when an end-of-file condition is detected, |
85 |
i.e. in the case of a socket, when the other side has closed the |
86 |
connection cleanly. |
87 |
|
88 |
For sockets, this just means that the other side has stopped sending data, |
89 |
you can still try to write data, and, in fact, one can return from the EOF |
90 |
callback and continue writing data, as only the read part has been shut |
91 |
down. |
92 |
|
93 |
While not mandatory, it is I<highly> recommended to set an EOF callback, |
94 |
otherwise you might end up with a closed socket while you are still |
95 |
waiting for data. |
96 |
|
97 |
If an EOF condition has been detected but no C<on_eof> callback has been |
98 |
set, then a fatal error will be raised with C<$!> set to <0>. |
99 |
|
100 |
=item on_error => $cb->($handle, $fatal) |
101 |
|
102 |
This is the error callback, which is called when, well, some error |
103 |
occured, such as not being able to resolve the hostname, failure to |
104 |
connect or a read error. |
105 |
|
106 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
107 |
fatal errors the handle object will be shut down and will not be usable |
108 |
(but you are free to look at the current C<< ->rbuf >>). Examples of fatal |
109 |
errors are an EOF condition with active (but unsatisifable) read watchers |
110 |
(C<EPIPE>) or I/O errors. |
111 |
|
112 |
Non-fatal errors can be retried by simply returning, but it is recommended |
113 |
to simply ignore this parameter and instead abondon the handle object |
114 |
when this callback is invoked. Examples of non-fatal errors are timeouts |
115 |
C<ETIMEDOUT>) or badly-formatted data (C<EBADMSG>). |
116 |
|
117 |
On callback entrance, the value of C<$!> contains the operating system |
118 |
error (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT> or C<EBADMSG>). |
119 |
|
120 |
While not mandatory, it is I<highly> recommended to set this callback, as |
121 |
you will not be notified of errors otherwise. The default simply calls |
122 |
C<croak>. |
123 |
|
124 |
=item on_read => $cb->($handle) |
125 |
|
126 |
This sets the default read callback, which is called when data arrives |
127 |
and no read request is in the queue (unlike read queue callbacks, this |
128 |
callback will only be called when at least one octet of data is in the |
129 |
read buffer). |
130 |
|
131 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
132 |
method or access the C<$handle->{rbuf}> member directly. |
133 |
|
134 |
When an EOF condition is detected then AnyEvent::Handle will first try to |
135 |
feed all the remaining data to the queued callbacks and C<on_read> before |
136 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
137 |
error will be raised (with C<$!> set to C<EPIPE>). |
138 |
|
139 |
=item on_drain => $cb->($handle) |
140 |
|
141 |
This sets the callback that is called when the write buffer becomes empty |
142 |
(or when the callback is set and the buffer is empty already). |
143 |
|
144 |
To append to the write buffer, use the C<< ->push_write >> method. |
145 |
|
146 |
This callback is useful when you don't want to put all of your write data |
147 |
into the queue at once, for example, when you want to write the contents |
148 |
of some file to the socket you might not want to read the whole file into |
149 |
memory and push it into the queue, but instead only read more data from |
150 |
the file when the write queue becomes empty. |
151 |
|
152 |
=item timeout => $fractional_seconds |
153 |
|
154 |
If non-zero, then this enables an "inactivity" timeout: whenever this many |
155 |
seconds pass without a successful read or write on the underlying file |
156 |
handle, the C<on_timeout> callback will be invoked (and if that one is |
157 |
missing, a non-fatal C<ETIMEDOUT> error will be raised). |
158 |
|
159 |
Note that timeout processing is also active when you currently do not have |
160 |
any outstanding read or write requests: If you plan to keep the connection |
161 |
idle then you should disable the timout temporarily or ignore the timeout |
162 |
in the C<on_timeout> callback, in which case AnyEvent::Handle will simply |
163 |
restart the timeout. |
164 |
|
165 |
Zero (the default) disables this timeout. |
166 |
|
167 |
=item on_timeout => $cb->($handle) |
168 |
|
169 |
Called whenever the inactivity timeout passes. If you return from this |
170 |
callback, then the timeout will be reset as if some activity had happened, |
171 |
so this condition is not fatal in any way. |
172 |
|
173 |
=item rbuf_max => <bytes> |
174 |
|
175 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
176 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
177 |
avoid some forms of denial-of-service attacks. |
178 |
|
179 |
For example, a server accepting connections from untrusted sources should |
180 |
be configured to accept only so-and-so much data that it cannot act on |
181 |
(for example, when expecting a line, an attacker could send an unlimited |
182 |
amount of data without a callback ever being called as long as the line |
183 |
isn't finished). |
184 |
|
185 |
=item autocork => <boolean> |
186 |
|
187 |
When disabled (the default), then C<push_write> will try to immediately |
188 |
write the data to the handle, if possible. This avoids having to register |
189 |
a write watcher and wait for the next event loop iteration, but can |
190 |
be inefficient if you write multiple small chunks (on the wire, this |
191 |
disadvantage is usually avoided by your kernel's nagle algorithm, see |
192 |
C<no_delay>, but this option can save costly syscalls). |
193 |
|
194 |
When enabled, then writes will always be queued till the next event loop |
195 |
iteration. This is efficient when you do many small writes per iteration, |
196 |
but less efficient when you do a single write only per iteration (or when |
197 |
the write buffer often is full). It also increases write latency. |
198 |
|
199 |
=item no_delay => <boolean> |
200 |
|
201 |
When doing small writes on sockets, your operating system kernel might |
202 |
wait a bit for more data before actually sending it out. This is called |
203 |
the Nagle algorithm, and usually it is beneficial. |
204 |
|
205 |
In some situations you want as low a delay as possible, which can be |
206 |
accomplishd by setting this option to a true value. |
207 |
|
208 |
The default is your opertaing system's default behaviour (most likely |
209 |
enabled), this option explicitly enables or disables it, if possible. |
210 |
|
211 |
=item read_size => <bytes> |
212 |
|
213 |
The default read block size (the amount of bytes this module will |
214 |
try to read during each loop iteration, which affects memory |
215 |
requirements). Default: C<8192>. |
216 |
|
217 |
=item low_water_mark => <bytes> |
218 |
|
219 |
Sets the amount of bytes (default: C<0>) that make up an "empty" write |
220 |
buffer: If the write reaches this size or gets even samller it is |
221 |
considered empty. |
222 |
|
223 |
Sometimes it can be beneficial (for performance reasons) to add data to |
224 |
the write buffer before it is fully drained, but this is a rare case, as |
225 |
the operating system kernel usually buffers data as well, so the default |
226 |
is good in almost all cases. |
227 |
|
228 |
=item linger => <seconds> |
229 |
|
230 |
If non-zero (default: C<3600>), then the destructor of the |
231 |
AnyEvent::Handle object will check whether there is still outstanding |
232 |
write data and will install a watcher that will write this data to the |
233 |
socket. No errors will be reported (this mostly matches how the operating |
234 |
system treats outstanding data at socket close time). |
235 |
|
236 |
This will not work for partial TLS data that could not be encoded |
237 |
yet. This data will be lost. Calling the C<stoptls> method in time might |
238 |
help. |
239 |
|
240 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
241 |
|
242 |
When this parameter is given, it enables TLS (SSL) mode, that means |
243 |
AnyEvent will start a TLS handshake as soon as the conenction has been |
244 |
established and will transparently encrypt/decrypt data afterwards. |
245 |
|
246 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
247 |
automatically when you try to create a TLS handle): this module doesn't |
248 |
have a dependency on that module, so if your module requires it, you have |
249 |
to add the dependency yourself. |
250 |
|
251 |
Unlike TCP, TLS has a server and client side: for the TLS server side, use |
252 |
C<accept>, and for the TLS client side of a connection, use C<connect> |
253 |
mode. |
254 |
|
255 |
You can also provide your own TLS connection object, but you have |
256 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
257 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
258 |
AnyEvent::Handle. |
259 |
|
260 |
See the C<< ->starttls >> method for when need to start TLS negotiation later. |
261 |
|
262 |
=item tls_ctx => $ssl_ctx |
263 |
|
264 |
Use the given C<Net::SSLeay::CTX> object to create the new TLS connection |
265 |
(unless a connection object was specified directly). If this parameter is |
266 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
267 |
|
268 |
=item json => JSON or JSON::XS object |
269 |
|
270 |
This is the json coder object used by the C<json> read and write types. |
271 |
|
272 |
If you don't supply it, then AnyEvent::Handle will create and use a |
273 |
suitable one (on demand), which will write and expect UTF-8 encoded JSON |
274 |
texts. |
275 |
|
276 |
Note that you are responsible to depend on the JSON module if you want to |
277 |
use this functionality, as AnyEvent does not have a dependency itself. |
278 |
|
279 |
=back |
280 |
|
281 |
=cut |
282 |
|
283 |
sub new { |
284 |
my $class = shift; |
285 |
|
286 |
my $self = bless { @_ }, $class; |
287 |
|
288 |
$self->{fh} or Carp::croak "mandatory argument fh is missing"; |
289 |
|
290 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
291 |
|
292 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}) |
293 |
if $self->{tls}; |
294 |
|
295 |
$self->{_activity} = AnyEvent->now; |
296 |
$self->_timeout; |
297 |
|
298 |
$self->on_drain (delete $self->{on_drain}) if exists $self->{on_drain}; |
299 |
$self->no_delay (delete $self->{no_delay}) if exists $self->{no_delay}; |
300 |
|
301 |
$self->start_read |
302 |
if $self->{on_read}; |
303 |
|
304 |
$self |
305 |
} |
306 |
|
307 |
sub _shutdown { |
308 |
my ($self) = @_; |
309 |
|
310 |
delete $self->{_tw}; |
311 |
delete $self->{_rw}; |
312 |
delete $self->{_ww}; |
313 |
delete $self->{fh}; |
314 |
|
315 |
&_freetls; |
316 |
|
317 |
delete $self->{on_read}; |
318 |
delete $self->{_queue}; |
319 |
} |
320 |
|
321 |
sub _error { |
322 |
my ($self, $errno, $fatal) = @_; |
323 |
|
324 |
$self->_shutdown |
325 |
if $fatal; |
326 |
|
327 |
$! = $errno; |
328 |
|
329 |
if ($self->{on_error}) { |
330 |
$self->{on_error}($self, $fatal); |
331 |
} elsif ($self->{fh}) { |
332 |
Carp::croak "AnyEvent::Handle uncaught error: $!"; |
333 |
} |
334 |
} |
335 |
|
336 |
=item $fh = $handle->fh |
337 |
|
338 |
This method returns the file handle used to create the L<AnyEvent::Handle> object. |
339 |
|
340 |
=cut |
341 |
|
342 |
sub fh { $_[0]{fh} } |
343 |
|
344 |
=item $handle->on_error ($cb) |
345 |
|
346 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
347 |
|
348 |
=cut |
349 |
|
350 |
sub on_error { |
351 |
$_[0]{on_error} = $_[1]; |
352 |
} |
353 |
|
354 |
=item $handle->on_eof ($cb) |
355 |
|
356 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
357 |
|
358 |
=cut |
359 |
|
360 |
sub on_eof { |
361 |
$_[0]{on_eof} = $_[1]; |
362 |
} |
363 |
|
364 |
=item $handle->on_timeout ($cb) |
365 |
|
366 |
Replace the current C<on_timeout> callback, or disables the callback (but |
367 |
not the timeout) if C<$cb> = C<undef>. See the C<timeout> constructor |
368 |
argument and method. |
369 |
|
370 |
=cut |
371 |
|
372 |
sub on_timeout { |
373 |
$_[0]{on_timeout} = $_[1]; |
374 |
} |
375 |
|
376 |
=item $handle->autocork ($boolean) |
377 |
|
378 |
Enables or disables the current autocork behaviour (see C<autocork> |
379 |
constructor argument). Changes will only take effect on the next write. |
380 |
|
381 |
=cut |
382 |
|
383 |
sub autocork { |
384 |
$_[0]{autocork} = $_[1]; |
385 |
} |
386 |
|
387 |
=item $handle->no_delay ($boolean) |
388 |
|
389 |
Enables or disables the C<no_delay> setting (see constructor argument of |
390 |
the same name for details). |
391 |
|
392 |
=cut |
393 |
|
394 |
sub no_delay { |
395 |
$_[0]{no_delay} = $_[1]; |
396 |
|
397 |
eval { |
398 |
local $SIG{__DIE__}; |
399 |
setsockopt $_[0]{fh}, &Socket::IPPROTO_TCP, &Socket::TCP_NODELAY, int $_[1]; |
400 |
}; |
401 |
} |
402 |
|
403 |
############################################################################# |
404 |
|
405 |
=item $handle->timeout ($seconds) |
406 |
|
407 |
Configures (or disables) the inactivity timeout. |
408 |
|
409 |
=cut |
410 |
|
411 |
sub timeout { |
412 |
my ($self, $timeout) = @_; |
413 |
|
414 |
$self->{timeout} = $timeout; |
415 |
$self->_timeout; |
416 |
} |
417 |
|
418 |
# reset the timeout watcher, as neccessary |
419 |
# also check for time-outs |
420 |
sub _timeout { |
421 |
my ($self) = @_; |
422 |
|
423 |
if ($self->{timeout}) { |
424 |
my $NOW = AnyEvent->now; |
425 |
|
426 |
# when would the timeout trigger? |
427 |
my $after = $self->{_activity} + $self->{timeout} - $NOW; |
428 |
|
429 |
# now or in the past already? |
430 |
if ($after <= 0) { |
431 |
$self->{_activity} = $NOW; |
432 |
|
433 |
if ($self->{on_timeout}) { |
434 |
$self->{on_timeout}($self); |
435 |
} else { |
436 |
$self->_error (&Errno::ETIMEDOUT); |
437 |
} |
438 |
|
439 |
# callback could have changed timeout value, optimise |
440 |
return unless $self->{timeout}; |
441 |
|
442 |
# calculate new after |
443 |
$after = $self->{timeout}; |
444 |
} |
445 |
|
446 |
Scalar::Util::weaken $self; |
447 |
return unless $self; # ->error could have destroyed $self |
448 |
|
449 |
$self->{_tw} ||= AnyEvent->timer (after => $after, cb => sub { |
450 |
delete $self->{_tw}; |
451 |
$self->_timeout; |
452 |
}); |
453 |
} else { |
454 |
delete $self->{_tw}; |
455 |
} |
456 |
} |
457 |
|
458 |
############################################################################# |
459 |
|
460 |
=back |
461 |
|
462 |
=head2 WRITE QUEUE |
463 |
|
464 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
465 |
for reading. |
466 |
|
467 |
The write queue is very simple: you can add data to its end, and |
468 |
AnyEvent::Handle will automatically try to get rid of it for you. |
469 |
|
470 |
When data could be written and the write buffer is shorter then the low |
471 |
water mark, the C<on_drain> callback will be invoked. |
472 |
|
473 |
=over 4 |
474 |
|
475 |
=item $handle->on_drain ($cb) |
476 |
|
477 |
Sets the C<on_drain> callback or clears it (see the description of |
478 |
C<on_drain> in the constructor). |
479 |
|
480 |
=cut |
481 |
|
482 |
sub on_drain { |
483 |
my ($self, $cb) = @_; |
484 |
|
485 |
$self->{on_drain} = $cb; |
486 |
|
487 |
$cb->($self) |
488 |
if $cb && $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}); |
489 |
} |
490 |
|
491 |
=item $handle->push_write ($data) |
492 |
|
493 |
Queues the given scalar to be written. You can push as much data as you |
494 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
495 |
buffers it independently of the kernel. |
496 |
|
497 |
=cut |
498 |
|
499 |
sub _drain_wbuf { |
500 |
my ($self) = @_; |
501 |
|
502 |
if (!$self->{_ww} && length $self->{wbuf}) { |
503 |
|
504 |
Scalar::Util::weaken $self; |
505 |
|
506 |
my $cb = sub { |
507 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
508 |
|
509 |
if ($len >= 0) { |
510 |
substr $self->{wbuf}, 0, $len, ""; |
511 |
|
512 |
$self->{_activity} = AnyEvent->now; |
513 |
|
514 |
$self->{on_drain}($self) |
515 |
if $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}) |
516 |
&& $self->{on_drain}; |
517 |
|
518 |
delete $self->{_ww} unless length $self->{wbuf}; |
519 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
520 |
$self->_error ($!, 1); |
521 |
} |
522 |
}; |
523 |
|
524 |
# try to write data immediately |
525 |
$cb->() unless $self->{autocork}; |
526 |
|
527 |
# if still data left in wbuf, we need to poll |
528 |
$self->{_ww} = AnyEvent->io (fh => $self->{fh}, poll => "w", cb => $cb) |
529 |
if length $self->{wbuf}; |
530 |
}; |
531 |
} |
532 |
|
533 |
our %WH; |
534 |
|
535 |
sub register_write_type($$) { |
536 |
$WH{$_[0]} = $_[1]; |
537 |
} |
538 |
|
539 |
sub push_write { |
540 |
my $self = shift; |
541 |
|
542 |
if (@_ > 1) { |
543 |
my $type = shift; |
544 |
|
545 |
@_ = ($WH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_write") |
546 |
->($self, @_); |
547 |
} |
548 |
|
549 |
if ($self->{tls}) { |
550 |
$self->{_tls_wbuf} .= $_[0]; |
551 |
|
552 |
&_dotls ($self); |
553 |
} else { |
554 |
$self->{wbuf} .= $_[0]; |
555 |
$self->_drain_wbuf; |
556 |
} |
557 |
} |
558 |
|
559 |
=item $handle->push_write (type => @args) |
560 |
|
561 |
Instead of formatting your data yourself, you can also let this module do |
562 |
the job by specifying a type and type-specific arguments. |
563 |
|
564 |
Predefined types are (if you have ideas for additional types, feel free to |
565 |
drop by and tell us): |
566 |
|
567 |
=over 4 |
568 |
|
569 |
=item netstring => $string |
570 |
|
571 |
Formats the given value as netstring |
572 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
573 |
|
574 |
=cut |
575 |
|
576 |
register_write_type netstring => sub { |
577 |
my ($self, $string) = @_; |
578 |
|
579 |
(length $string) . ":$string," |
580 |
}; |
581 |
|
582 |
=item packstring => $format, $data |
583 |
|
584 |
An octet string prefixed with an encoded length. The encoding C<$format> |
585 |
uses the same format as a Perl C<pack> format, but must specify a single |
586 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
587 |
optional C<!>, C<< < >> or C<< > >> modifier). |
588 |
|
589 |
=cut |
590 |
|
591 |
register_write_type packstring => sub { |
592 |
my ($self, $format, $string) = @_; |
593 |
|
594 |
pack "$format/a*", $string |
595 |
}; |
596 |
|
597 |
=item json => $array_or_hashref |
598 |
|
599 |
Encodes the given hash or array reference into a JSON object. Unless you |
600 |
provide your own JSON object, this means it will be encoded to JSON text |
601 |
in UTF-8. |
602 |
|
603 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
604 |
one end of a handle and read them at the other end without using any |
605 |
additional framing. |
606 |
|
607 |
The generated JSON text is guaranteed not to contain any newlines: While |
608 |
this module doesn't need delimiters after or between JSON texts to be |
609 |
able to read them, many other languages depend on that. |
610 |
|
611 |
A simple RPC protocol that interoperates easily with others is to send |
612 |
JSON arrays (or objects, although arrays are usually the better choice as |
613 |
they mimic how function argument passing works) and a newline after each |
614 |
JSON text: |
615 |
|
616 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
617 |
$handle->push_write ("\012"); |
618 |
|
619 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
620 |
rely on the fact that the newline will be skipped as leading whitespace: |
621 |
|
622 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
623 |
|
624 |
Other languages could read single lines terminated by a newline and pass |
625 |
this line into their JSON decoder of choice. |
626 |
|
627 |
=cut |
628 |
|
629 |
register_write_type json => sub { |
630 |
my ($self, $ref) = @_; |
631 |
|
632 |
require JSON; |
633 |
|
634 |
$self->{json} ? $self->{json}->encode ($ref) |
635 |
: JSON::encode_json ($ref) |
636 |
}; |
637 |
|
638 |
=item storable => $reference |
639 |
|
640 |
Freezes the given reference using L<Storable> and writes it to the |
641 |
handle. Uses the C<nfreeze> format. |
642 |
|
643 |
=cut |
644 |
|
645 |
register_write_type storable => sub { |
646 |
my ($self, $ref) = @_; |
647 |
|
648 |
require Storable; |
649 |
|
650 |
pack "w/a*", Storable::nfreeze ($ref) |
651 |
}; |
652 |
|
653 |
=back |
654 |
|
655 |
=item AnyEvent::Handle::register_write_type type => $coderef->($handle, @args) |
656 |
|
657 |
This function (not method) lets you add your own types to C<push_write>. |
658 |
Whenever the given C<type> is used, C<push_write> will invoke the code |
659 |
reference with the handle object and the remaining arguments. |
660 |
|
661 |
The code reference is supposed to return a single octet string that will |
662 |
be appended to the write buffer. |
663 |
|
664 |
Note that this is a function, and all types registered this way will be |
665 |
global, so try to use unique names. |
666 |
|
667 |
=cut |
668 |
|
669 |
############################################################################# |
670 |
|
671 |
=back |
672 |
|
673 |
=head2 READ QUEUE |
674 |
|
675 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
676 |
for reading. |
677 |
|
678 |
The read queue is more complex than the write queue. It can be used in two |
679 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
680 |
a queue. |
681 |
|
682 |
In the simple case, you just install an C<on_read> callback and whenever |
683 |
new data arrives, it will be called. You can then remove some data (if |
684 |
enough is there) from the read buffer (C<< $handle->rbuf >>). Or you cna |
685 |
leave the data there if you want to accumulate more (e.g. when only a |
686 |
partial message has been received so far). |
687 |
|
688 |
In the more complex case, you want to queue multiple callbacks. In this |
689 |
case, AnyEvent::Handle will call the first queued callback each time new |
690 |
data arrives (also the first time it is queued) and removes it when it has |
691 |
done its job (see C<push_read>, below). |
692 |
|
693 |
This way you can, for example, push three line-reads, followed by reading |
694 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
695 |
|
696 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
697 |
the specified number of bytes which give an XML datagram. |
698 |
|
699 |
# in the default state, expect some header bytes |
700 |
$handle->on_read (sub { |
701 |
# some data is here, now queue the length-header-read (4 octets) |
702 |
shift->unshift_read (chunk => 4, sub { |
703 |
# header arrived, decode |
704 |
my $len = unpack "N", $_[1]; |
705 |
|
706 |
# now read the payload |
707 |
shift->unshift_read (chunk => $len, sub { |
708 |
my $xml = $_[1]; |
709 |
# handle xml |
710 |
}); |
711 |
}); |
712 |
}); |
713 |
|
714 |
Example 2: Implement a client for a protocol that replies either with "OK" |
715 |
and another line or "ERROR" for the first request that is sent, and 64 |
716 |
bytes for the second request. Due to the availability of a queue, we can |
717 |
just pipeline sending both requests and manipulate the queue as necessary |
718 |
in the callbacks. |
719 |
|
720 |
When the first callback is called and sees an "OK" response, it will |
721 |
C<unshift> another line-read. This line-read will be queued I<before> the |
722 |
64-byte chunk callback. |
723 |
|
724 |
# request one, returns either "OK + extra line" or "ERROR" |
725 |
$handle->push_write ("request 1\015\012"); |
726 |
|
727 |
# we expect "ERROR" or "OK" as response, so push a line read |
728 |
$handle->push_read (line => sub { |
729 |
# if we got an "OK", we have to _prepend_ another line, |
730 |
# so it will be read before the second request reads its 64 bytes |
731 |
# which are already in the queue when this callback is called |
732 |
# we don't do this in case we got an error |
733 |
if ($_[1] eq "OK") { |
734 |
$_[0]->unshift_read (line => sub { |
735 |
my $response = $_[1]; |
736 |
... |
737 |
}); |
738 |
} |
739 |
}); |
740 |
|
741 |
# request two, simply returns 64 octets |
742 |
$handle->push_write ("request 2\015\012"); |
743 |
|
744 |
# simply read 64 bytes, always |
745 |
$handle->push_read (chunk => 64, sub { |
746 |
my $response = $_[1]; |
747 |
... |
748 |
}); |
749 |
|
750 |
=over 4 |
751 |
|
752 |
=cut |
753 |
|
754 |
sub _drain_rbuf { |
755 |
my ($self) = @_; |
756 |
|
757 |
local $self->{_in_drain} = 1; |
758 |
|
759 |
if ( |
760 |
defined $self->{rbuf_max} |
761 |
&& $self->{rbuf_max} < length $self->{rbuf} |
762 |
) { |
763 |
$self->_error (&Errno::ENOSPC, 1), return; |
764 |
} |
765 |
|
766 |
while () { |
767 |
my $len = length $self->{rbuf}; |
768 |
|
769 |
if (my $cb = shift @{ $self->{_queue} }) { |
770 |
unless ($cb->($self)) { |
771 |
if ($self->{_eof}) { |
772 |
# no progress can be made (not enough data and no data forthcoming) |
773 |
$self->_error (&Errno::EPIPE, 1), return; |
774 |
} |
775 |
|
776 |
unshift @{ $self->{_queue} }, $cb; |
777 |
last; |
778 |
} |
779 |
} elsif ($self->{on_read}) { |
780 |
last unless $len; |
781 |
|
782 |
$self->{on_read}($self); |
783 |
|
784 |
if ( |
785 |
$len == length $self->{rbuf} # if no data has been consumed |
786 |
&& !@{ $self->{_queue} } # and the queue is still empty |
787 |
&& $self->{on_read} # but we still have on_read |
788 |
) { |
789 |
# no further data will arrive |
790 |
# so no progress can be made |
791 |
$self->_error (&Errno::EPIPE, 1), return |
792 |
if $self->{_eof}; |
793 |
|
794 |
last; # more data might arrive |
795 |
} |
796 |
} else { |
797 |
# read side becomes idle |
798 |
delete $self->{_rw} unless $self->{tls}; |
799 |
last; |
800 |
} |
801 |
} |
802 |
|
803 |
if ($self->{_eof}) { |
804 |
if ($self->{on_eof}) { |
805 |
$self->{on_eof}($self) |
806 |
} else { |
807 |
$self->_error (0, 1); |
808 |
} |
809 |
} |
810 |
|
811 |
# may need to restart read watcher |
812 |
unless ($self->{_rw}) { |
813 |
$self->start_read |
814 |
if $self->{on_read} || @{ $self->{_queue} }; |
815 |
} |
816 |
} |
817 |
|
818 |
=item $handle->on_read ($cb) |
819 |
|
820 |
This replaces the currently set C<on_read> callback, or clears it (when |
821 |
the new callback is C<undef>). See the description of C<on_read> in the |
822 |
constructor. |
823 |
|
824 |
=cut |
825 |
|
826 |
sub on_read { |
827 |
my ($self, $cb) = @_; |
828 |
|
829 |
$self->{on_read} = $cb; |
830 |
$self->_drain_rbuf if $cb && !$self->{_in_drain}; |
831 |
} |
832 |
|
833 |
=item $handle->rbuf |
834 |
|
835 |
Returns the read buffer (as a modifiable lvalue). |
836 |
|
837 |
You can access the read buffer directly as the C<< ->{rbuf} >> member, if |
838 |
you want. |
839 |
|
840 |
NOTE: The read buffer should only be used or modified if the C<on_read>, |
841 |
C<push_read> or C<unshift_read> methods are used. The other read methods |
842 |
automatically manage the read buffer. |
843 |
|
844 |
=cut |
845 |
|
846 |
sub rbuf : lvalue { |
847 |
$_[0]{rbuf} |
848 |
} |
849 |
|
850 |
=item $handle->push_read ($cb) |
851 |
|
852 |
=item $handle->unshift_read ($cb) |
853 |
|
854 |
Append the given callback to the end of the queue (C<push_read>) or |
855 |
prepend it (C<unshift_read>). |
856 |
|
857 |
The callback is called each time some additional read data arrives. |
858 |
|
859 |
It must check whether enough data is in the read buffer already. |
860 |
|
861 |
If not enough data is available, it must return the empty list or a false |
862 |
value, in which case it will be called repeatedly until enough data is |
863 |
available (or an error condition is detected). |
864 |
|
865 |
If enough data was available, then the callback must remove all data it is |
866 |
interested in (which can be none at all) and return a true value. After returning |
867 |
true, it will be removed from the queue. |
868 |
|
869 |
=cut |
870 |
|
871 |
our %RH; |
872 |
|
873 |
sub register_read_type($$) { |
874 |
$RH{$_[0]} = $_[1]; |
875 |
} |
876 |
|
877 |
sub push_read { |
878 |
my $self = shift; |
879 |
my $cb = pop; |
880 |
|
881 |
if (@_) { |
882 |
my $type = shift; |
883 |
|
884 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_read") |
885 |
->($self, $cb, @_); |
886 |
} |
887 |
|
888 |
push @{ $self->{_queue} }, $cb; |
889 |
$self->_drain_rbuf unless $self->{_in_drain}; |
890 |
} |
891 |
|
892 |
sub unshift_read { |
893 |
my $self = shift; |
894 |
my $cb = pop; |
895 |
|
896 |
if (@_) { |
897 |
my $type = shift; |
898 |
|
899 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::unshift_read") |
900 |
->($self, $cb, @_); |
901 |
} |
902 |
|
903 |
|
904 |
unshift @{ $self->{_queue} }, $cb; |
905 |
$self->_drain_rbuf unless $self->{_in_drain}; |
906 |
} |
907 |
|
908 |
=item $handle->push_read (type => @args, $cb) |
909 |
|
910 |
=item $handle->unshift_read (type => @args, $cb) |
911 |
|
912 |
Instead of providing a callback that parses the data itself you can chose |
913 |
between a number of predefined parsing formats, for chunks of data, lines |
914 |
etc. |
915 |
|
916 |
Predefined types are (if you have ideas for additional types, feel free to |
917 |
drop by and tell us): |
918 |
|
919 |
=over 4 |
920 |
|
921 |
=item chunk => $octets, $cb->($handle, $data) |
922 |
|
923 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
924 |
data read to the callback. The callback will never be called with less |
925 |
data. |
926 |
|
927 |
Example: read 2 bytes. |
928 |
|
929 |
$handle->push_read (chunk => 2, sub { |
930 |
warn "yay ", unpack "H*", $_[1]; |
931 |
}); |
932 |
|
933 |
=cut |
934 |
|
935 |
register_read_type chunk => sub { |
936 |
my ($self, $cb, $len) = @_; |
937 |
|
938 |
sub { |
939 |
$len <= length $_[0]{rbuf} or return; |
940 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
941 |
1 |
942 |
} |
943 |
}; |
944 |
|
945 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
946 |
|
947 |
The callback will be called only once a full line (including the end of |
948 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
949 |
marker) will be passed to the callback as second argument (C<$line>), and |
950 |
the end of line marker as the third argument (C<$eol>). |
951 |
|
952 |
The end of line marker, C<$eol>, can be either a string, in which case it |
953 |
will be interpreted as a fixed record end marker, or it can be a regex |
954 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
955 |
regular expression. |
956 |
|
957 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
958 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
959 |
protocols). |
960 |
|
961 |
Partial lines at the end of the stream will never be returned, as they are |
962 |
not marked by the end of line marker. |
963 |
|
964 |
=cut |
965 |
|
966 |
register_read_type line => sub { |
967 |
my ($self, $cb, $eol) = @_; |
968 |
|
969 |
if (@_ < 3) { |
970 |
# this is more than twice as fast as the generic code below |
971 |
sub { |
972 |
$_[0]{rbuf} =~ s/^([^\015\012]*)(\015?\012)// or return; |
973 |
|
974 |
$cb->($_[0], $1, $2); |
975 |
1 |
976 |
} |
977 |
} else { |
978 |
$eol = quotemeta $eol unless ref $eol; |
979 |
$eol = qr|^(.*?)($eol)|s; |
980 |
|
981 |
sub { |
982 |
$_[0]{rbuf} =~ s/$eol// or return; |
983 |
|
984 |
$cb->($_[0], $1, $2); |
985 |
1 |
986 |
} |
987 |
} |
988 |
}; |
989 |
|
990 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
991 |
|
992 |
Makes a regex match against the regex object C<$accept> and returns |
993 |
everything up to and including the match. |
994 |
|
995 |
Example: read a single line terminated by '\n'. |
996 |
|
997 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
998 |
|
999 |
If C<$reject> is given and not undef, then it determines when the data is |
1000 |
to be rejected: it is matched against the data when the C<$accept> regex |
1001 |
does not match and generates an C<EBADMSG> error when it matches. This is |
1002 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
1003 |
receive buffer overflow). |
1004 |
|
1005 |
Example: expect a single decimal number followed by whitespace, reject |
1006 |
anything else (not the use of an anchor). |
1007 |
|
1008 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
1009 |
|
1010 |
If C<$skip> is given and not C<undef>, then it will be matched against |
1011 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
1012 |
and everything preceding and including the match will be accepted |
1013 |
unconditionally. This is useful to skip large amounts of data that you |
1014 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
1015 |
have to start matching from the beginning. This is purely an optimisation |
1016 |
and is usually worth only when you expect more than a few kilobytes. |
1017 |
|
1018 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
1019 |
expect the header to be very large (it isn't in practise, but...), we use |
1020 |
a skip regex to skip initial portions. The skip regex is tricky in that |
1021 |
it only accepts something not ending in either \015 or \012, as these are |
1022 |
required for the accept regex. |
1023 |
|
1024 |
$handle->push_read (regex => |
1025 |
qr<\015\012\015\012>, |
1026 |
undef, # no reject |
1027 |
qr<^.*[^\015\012]>, |
1028 |
sub { ... }); |
1029 |
|
1030 |
=cut |
1031 |
|
1032 |
register_read_type regex => sub { |
1033 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
1034 |
|
1035 |
my $data; |
1036 |
my $rbuf = \$self->{rbuf}; |
1037 |
|
1038 |
sub { |
1039 |
# accept |
1040 |
if ($$rbuf =~ $accept) { |
1041 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1042 |
$cb->($self, $data); |
1043 |
return 1; |
1044 |
} |
1045 |
|
1046 |
# reject |
1047 |
if ($reject && $$rbuf =~ $reject) { |
1048 |
$self->_error (&Errno::EBADMSG); |
1049 |
} |
1050 |
|
1051 |
# skip |
1052 |
if ($skip && $$rbuf =~ $skip) { |
1053 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1054 |
} |
1055 |
|
1056 |
() |
1057 |
} |
1058 |
}; |
1059 |
|
1060 |
=item netstring => $cb->($handle, $string) |
1061 |
|
1062 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
1063 |
|
1064 |
Throws an error with C<$!> set to EBADMSG on format violations. |
1065 |
|
1066 |
=cut |
1067 |
|
1068 |
register_read_type netstring => sub { |
1069 |
my ($self, $cb) = @_; |
1070 |
|
1071 |
sub { |
1072 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
1073 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
1074 |
$self->_error (&Errno::EBADMSG); |
1075 |
} |
1076 |
return; |
1077 |
} |
1078 |
|
1079 |
my $len = $1; |
1080 |
|
1081 |
$self->unshift_read (chunk => $len, sub { |
1082 |
my $string = $_[1]; |
1083 |
$_[0]->unshift_read (chunk => 1, sub { |
1084 |
if ($_[1] eq ",") { |
1085 |
$cb->($_[0], $string); |
1086 |
} else { |
1087 |
$self->_error (&Errno::EBADMSG); |
1088 |
} |
1089 |
}); |
1090 |
}); |
1091 |
|
1092 |
1 |
1093 |
} |
1094 |
}; |
1095 |
|
1096 |
=item packstring => $format, $cb->($handle, $string) |
1097 |
|
1098 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1099 |
uses the same format as a Perl C<pack> format, but must specify a single |
1100 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1101 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1102 |
|
1103 |
For example, DNS over TCP uses a prefix of C<n> (2 octet network order), |
1104 |
EPP uses a prefix of C<N> (4 octtes). |
1105 |
|
1106 |
Example: read a block of data prefixed by its length in BER-encoded |
1107 |
format (very efficient). |
1108 |
|
1109 |
$handle->push_read (packstring => "w", sub { |
1110 |
my ($handle, $data) = @_; |
1111 |
}); |
1112 |
|
1113 |
=cut |
1114 |
|
1115 |
register_read_type packstring => sub { |
1116 |
my ($self, $cb, $format) = @_; |
1117 |
|
1118 |
sub { |
1119 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1120 |
defined (my $len = eval { unpack $format, $_[0]{rbuf} }) |
1121 |
or return; |
1122 |
|
1123 |
$format = length pack $format, $len; |
1124 |
|
1125 |
# bypass unshift if we already have the remaining chunk |
1126 |
if ($format + $len <= length $_[0]{rbuf}) { |
1127 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1128 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1129 |
$cb->($_[0], $data); |
1130 |
} else { |
1131 |
# remove prefix |
1132 |
substr $_[0]{rbuf}, 0, $format, ""; |
1133 |
|
1134 |
# read remaining chunk |
1135 |
$_[0]->unshift_read (chunk => $len, $cb); |
1136 |
} |
1137 |
|
1138 |
1 |
1139 |
} |
1140 |
}; |
1141 |
|
1142 |
=item json => $cb->($handle, $hash_or_arrayref) |
1143 |
|
1144 |
Reads a JSON object or array, decodes it and passes it to the callback. |
1145 |
|
1146 |
If a C<json> object was passed to the constructor, then that will be used |
1147 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1148 |
|
1149 |
This read type uses the incremental parser available with JSON version |
1150 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1151 |
dependency on your own: this module will load the JSON module, but |
1152 |
AnyEvent does not depend on it itself. |
1153 |
|
1154 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1155 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1156 |
the C<json> write type description, above, for an actual example. |
1157 |
|
1158 |
=cut |
1159 |
|
1160 |
register_read_type json => sub { |
1161 |
my ($self, $cb) = @_; |
1162 |
|
1163 |
require JSON; |
1164 |
|
1165 |
my $data; |
1166 |
my $rbuf = \$self->{rbuf}; |
1167 |
|
1168 |
my $json = $self->{json} ||= JSON->new->utf8; |
1169 |
|
1170 |
sub { |
1171 |
my $ref = $json->incr_parse ($self->{rbuf}); |
1172 |
|
1173 |
if ($ref) { |
1174 |
$self->{rbuf} = $json->incr_text; |
1175 |
$json->incr_text = ""; |
1176 |
$cb->($self, $ref); |
1177 |
|
1178 |
1 |
1179 |
} else { |
1180 |
$self->{rbuf} = ""; |
1181 |
() |
1182 |
} |
1183 |
} |
1184 |
}; |
1185 |
|
1186 |
=item storable => $cb->($handle, $ref) |
1187 |
|
1188 |
Deserialises a L<Storable> frozen representation as written by the |
1189 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1190 |
data). |
1191 |
|
1192 |
Raises C<EBADMSG> error if the data could not be decoded. |
1193 |
|
1194 |
=cut |
1195 |
|
1196 |
register_read_type storable => sub { |
1197 |
my ($self, $cb) = @_; |
1198 |
|
1199 |
require Storable; |
1200 |
|
1201 |
sub { |
1202 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1203 |
defined (my $len = eval { unpack "w", $_[0]{rbuf} }) |
1204 |
or return; |
1205 |
|
1206 |
my $format = length pack "w", $len; |
1207 |
|
1208 |
# bypass unshift if we already have the remaining chunk |
1209 |
if ($format + $len <= length $_[0]{rbuf}) { |
1210 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1211 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1212 |
$cb->($_[0], Storable::thaw ($data)); |
1213 |
} else { |
1214 |
# remove prefix |
1215 |
substr $_[0]{rbuf}, 0, $format, ""; |
1216 |
|
1217 |
# read remaining chunk |
1218 |
$_[0]->unshift_read (chunk => $len, sub { |
1219 |
if (my $ref = eval { Storable::thaw ($_[1]) }) { |
1220 |
$cb->($_[0], $ref); |
1221 |
} else { |
1222 |
$self->_error (&Errno::EBADMSG); |
1223 |
} |
1224 |
}); |
1225 |
} |
1226 |
|
1227 |
1 |
1228 |
} |
1229 |
}; |
1230 |
|
1231 |
=back |
1232 |
|
1233 |
=item AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args) |
1234 |
|
1235 |
This function (not method) lets you add your own types to C<push_read>. |
1236 |
|
1237 |
Whenever the given C<type> is used, C<push_read> will invoke the code |
1238 |
reference with the handle object, the callback and the remaining |
1239 |
arguments. |
1240 |
|
1241 |
The code reference is supposed to return a callback (usually a closure) |
1242 |
that works as a plain read callback (see C<< ->push_read ($cb) >>). |
1243 |
|
1244 |
It should invoke the passed callback when it is done reading (remember to |
1245 |
pass C<$handle> as first argument as all other callbacks do that). |
1246 |
|
1247 |
Note that this is a function, and all types registered this way will be |
1248 |
global, so try to use unique names. |
1249 |
|
1250 |
For examples, see the source of this module (F<perldoc -m AnyEvent::Handle>, |
1251 |
search for C<register_read_type>)). |
1252 |
|
1253 |
=item $handle->stop_read |
1254 |
|
1255 |
=item $handle->start_read |
1256 |
|
1257 |
In rare cases you actually do not want to read anything from the |
1258 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1259 |
any queued callbacks will be executed then. To start reading again, call |
1260 |
C<start_read>. |
1261 |
|
1262 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1263 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1264 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1265 |
there are any read requests in the queue. |
1266 |
|
1267 |
These methods will have no effect when in TLS mode (as TLS doesn't support |
1268 |
half-duplex connections). |
1269 |
|
1270 |
=cut |
1271 |
|
1272 |
sub stop_read { |
1273 |
my ($self) = @_; |
1274 |
|
1275 |
delete $self->{_rw} unless $self->{tls}; |
1276 |
} |
1277 |
|
1278 |
sub start_read { |
1279 |
my ($self) = @_; |
1280 |
|
1281 |
unless ($self->{_rw} || $self->{_eof}) { |
1282 |
Scalar::Util::weaken $self; |
1283 |
|
1284 |
$self->{_rw} = AnyEvent->io (fh => $self->{fh}, poll => "r", cb => sub { |
1285 |
my $rbuf = \($self->{tls} ? my $buf : $self->{rbuf}); |
1286 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size} || 8192, length $$rbuf; |
1287 |
|
1288 |
if ($len > 0) { |
1289 |
$self->{_activity} = AnyEvent->now; |
1290 |
|
1291 |
if ($self->{tls}) { |
1292 |
Net::SSLeay::BIO_write ($self->{_rbio}, $$rbuf); |
1293 |
|
1294 |
&_dotls ($self); |
1295 |
} else { |
1296 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1297 |
} |
1298 |
|
1299 |
} elsif (defined $len) { |
1300 |
delete $self->{_rw}; |
1301 |
$self->{_eof} = 1; |
1302 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1303 |
|
1304 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1305 |
return $self->_error ($!, 1); |
1306 |
} |
1307 |
}); |
1308 |
} |
1309 |
} |
1310 |
|
1311 |
# poll the write BIO and send the data if applicable |
1312 |
sub _dotls { |
1313 |
my ($self) = @_; |
1314 |
|
1315 |
my $tmp; |
1316 |
|
1317 |
if (length $self->{_tls_wbuf}) { |
1318 |
while (($tmp = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1319 |
substr $self->{_tls_wbuf}, 0, $tmp, ""; |
1320 |
} |
1321 |
} |
1322 |
|
1323 |
while (defined ($tmp = Net::SSLeay::read ($self->{tls}))) { |
1324 |
unless (length $tmp) { |
1325 |
# let's treat SSL-eof as we treat normal EOF |
1326 |
delete $self->{_rw}; |
1327 |
$self->{_eof} = 1; |
1328 |
&_freetls; |
1329 |
} |
1330 |
|
1331 |
$self->{rbuf} .= $tmp; |
1332 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1333 |
$self->{tls} or return; # tls session might have gone away in callback |
1334 |
} |
1335 |
|
1336 |
$tmp = Net::SSLeay::get_error ($self->{tls}, -1); |
1337 |
|
1338 |
if ($tmp != Net::SSLeay::ERROR_WANT_READ ()) { |
1339 |
if ($tmp == Net::SSLeay::ERROR_SYSCALL ()) { |
1340 |
return $self->_error ($!, 1); |
1341 |
} elsif ($tmp == Net::SSLeay::ERROR_SSL ()) { |
1342 |
return $self->_error (&Errno::EIO, 1); |
1343 |
} |
1344 |
|
1345 |
# all other errors are fine for our purposes |
1346 |
} |
1347 |
|
1348 |
while (length ($tmp = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1349 |
$self->{wbuf} .= $tmp; |
1350 |
$self->_drain_wbuf; |
1351 |
} |
1352 |
} |
1353 |
|
1354 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1355 |
|
1356 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1357 |
object is created, you can also do that at a later time by calling |
1358 |
C<starttls>. |
1359 |
|
1360 |
The first argument is the same as the C<tls> constructor argument (either |
1361 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1362 |
|
1363 |
The second argument is the optional C<Net::SSLeay::CTX> object that is |
1364 |
used when AnyEvent::Handle has to create its own TLS connection object. |
1365 |
|
1366 |
The TLS connection object will end up in C<< $handle->{tls} >> after this |
1367 |
call and can be used or changed to your liking. Note that the handshake |
1368 |
might have already started when this function returns. |
1369 |
|
1370 |
If it an error to start a TLS handshake more than once per |
1371 |
AnyEvent::Handle object (this is due to bugs in OpenSSL). |
1372 |
|
1373 |
=cut |
1374 |
|
1375 |
sub starttls { |
1376 |
my ($self, $ssl, $ctx) = @_; |
1377 |
|
1378 |
require Net::SSLeay; |
1379 |
|
1380 |
Carp::croak "it is an error to call starttls more than once on an AnyEvent::Handle object" |
1381 |
if $self->{tls}; |
1382 |
|
1383 |
if ($ssl eq "accept") { |
1384 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1385 |
Net::SSLeay::set_accept_state ($ssl); |
1386 |
} elsif ($ssl eq "connect") { |
1387 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1388 |
Net::SSLeay::set_connect_state ($ssl); |
1389 |
} |
1390 |
|
1391 |
$self->{tls} = $ssl; |
1392 |
|
1393 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1394 |
# but the openssl maintainers basically said: "trust us, it just works". |
1395 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1396 |
# and mismaintained ssleay-module doesn't even offer them). |
1397 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1398 |
# |
1399 |
# in short: this is a mess. |
1400 |
# |
1401 |
# note that we do not try to keep the length constant between writes as we are required to do. |
1402 |
# we assume that most (but not all) of this insanity only applies to non-blocking cases, |
1403 |
# and we drive openssl fully in blocking mode here. Or maybe we don't - openssl seems to |
1404 |
# have identity issues in that area. |
1405 |
Net::SSLeay::CTX_set_mode ($self->{tls}, |
1406 |
(eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1407 |
| (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1408 |
|
1409 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1410 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1411 |
|
1412 |
Net::SSLeay::set_bio ($ssl, $self->{_rbio}, $self->{_wbio}); |
1413 |
|
1414 |
&_dotls; # need to trigger the initial handshake |
1415 |
$self->start_read; # make sure we actually do read |
1416 |
} |
1417 |
|
1418 |
=item $handle->stoptls |
1419 |
|
1420 |
Shuts down the SSL connection - this makes a proper EOF handshake by |
1421 |
sending a close notify to the other side, but since OpenSSL doesn't |
1422 |
support non-blocking shut downs, it is not possible to re-use the stream |
1423 |
afterwards. |
1424 |
|
1425 |
=cut |
1426 |
|
1427 |
sub stoptls { |
1428 |
my ($self) = @_; |
1429 |
|
1430 |
if ($self->{tls}) { |
1431 |
Net::SSLeay::shutdown ($self->{tls}); |
1432 |
|
1433 |
&_dotls; |
1434 |
|
1435 |
# we don't give a shit. no, we do, but we can't. no... |
1436 |
# we, we... have to use openssl :/ |
1437 |
&_freetls; |
1438 |
} |
1439 |
} |
1440 |
|
1441 |
sub _freetls { |
1442 |
my ($self) = @_; |
1443 |
|
1444 |
return unless $self->{tls}; |
1445 |
|
1446 |
Net::SSLeay::free (delete $self->{tls}); |
1447 |
|
1448 |
delete @$self{qw(_rbio _wbio _tls_wbuf)}; |
1449 |
} |
1450 |
|
1451 |
sub DESTROY { |
1452 |
my $self = shift; |
1453 |
|
1454 |
&_freetls; |
1455 |
|
1456 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
1457 |
|
1458 |
if ($linger && length $self->{wbuf}) { |
1459 |
my $fh = delete $self->{fh}; |
1460 |
my $wbuf = delete $self->{wbuf}; |
1461 |
|
1462 |
my @linger; |
1463 |
|
1464 |
push @linger, AnyEvent->io (fh => $fh, poll => "w", cb => sub { |
1465 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
1466 |
|
1467 |
if ($len > 0) { |
1468 |
substr $wbuf, 0, $len, ""; |
1469 |
} else { |
1470 |
@linger = (); # end |
1471 |
} |
1472 |
}); |
1473 |
push @linger, AnyEvent->timer (after => $linger, cb => sub { |
1474 |
@linger = (); |
1475 |
}); |
1476 |
} |
1477 |
} |
1478 |
|
1479 |
=item $handle->destroy |
1480 |
|
1481 |
Shuts down the handle object as much as possible - this call ensures that |
1482 |
no further callbacks will be invoked and resources will be freed as much |
1483 |
as possible. You must not call any methods on the object afterwards. |
1484 |
|
1485 |
Normally, you can just "forget" any references to an AnyEvent::Handle |
1486 |
object and it will simply shut down. This works in fatal error and EOF |
1487 |
callbacks, as well as code outside. It does I<NOT> work in a read or write |
1488 |
callback, so when you want to destroy the AnyEvent::Handle object from |
1489 |
within such an callback. You I<MUST> call C<< ->destroy >> explicitly in |
1490 |
that case. |
1491 |
|
1492 |
The handle might still linger in the background and write out remaining |
1493 |
data, as specified by the C<linger> option, however. |
1494 |
|
1495 |
=cut |
1496 |
|
1497 |
sub destroy { |
1498 |
my ($self) = @_; |
1499 |
|
1500 |
$self->DESTROY; |
1501 |
%$self = (); |
1502 |
} |
1503 |
|
1504 |
=item AnyEvent::Handle::TLS_CTX |
1505 |
|
1506 |
This function creates and returns the Net::SSLeay::CTX object used by |
1507 |
default for TLS mode. |
1508 |
|
1509 |
The context is created like this: |
1510 |
|
1511 |
Net::SSLeay::load_error_strings; |
1512 |
Net::SSLeay::SSLeay_add_ssl_algorithms; |
1513 |
Net::SSLeay::randomize; |
1514 |
|
1515 |
my $CTX = Net::SSLeay::CTX_new; |
1516 |
|
1517 |
Net::SSLeay::CTX_set_options $CTX, Net::SSLeay::OP_ALL |
1518 |
|
1519 |
=cut |
1520 |
|
1521 |
our $TLS_CTX; |
1522 |
|
1523 |
sub TLS_CTX() { |
1524 |
$TLS_CTX || do { |
1525 |
require Net::SSLeay; |
1526 |
|
1527 |
Net::SSLeay::load_error_strings (); |
1528 |
Net::SSLeay::SSLeay_add_ssl_algorithms (); |
1529 |
Net::SSLeay::randomize (); |
1530 |
|
1531 |
$TLS_CTX = Net::SSLeay::CTX_new (); |
1532 |
|
1533 |
Net::SSLeay::CTX_set_options ($TLS_CTX, Net::SSLeay::OP_ALL ()); |
1534 |
|
1535 |
$TLS_CTX |
1536 |
} |
1537 |
} |
1538 |
|
1539 |
=back |
1540 |
|
1541 |
|
1542 |
=head1 NONFREQUENTLY ASKED QUESTIONS |
1543 |
|
1544 |
=over 4 |
1545 |
|
1546 |
=item I C<undef> the AnyEvent::Handle reference inside my callback and |
1547 |
still get further invocations! |
1548 |
|
1549 |
That's because AnyEvent::Handle keeps a reference to itself when handling |
1550 |
read or write callbacks. |
1551 |
|
1552 |
It is only safe to "forget" the reference inside EOF or error callbacks, |
1553 |
from within all other callbacks, you need to explicitly call the C<< |
1554 |
->destroy >> method. |
1555 |
|
1556 |
=item I get different callback invocations in TLS mode/Why can't I pause |
1557 |
reading? |
1558 |
|
1559 |
Unlike, say, TCP, TLS connections do not consist of two independent |
1560 |
communication channels, one for each direction. Or put differently. The |
1561 |
read and write directions are not independent of each other: you cannot |
1562 |
write data unless you are also prepared to read, and vice versa. |
1563 |
|
1564 |
This can mean than, in TLS mode, you might get C<on_error> or C<on_eof> |
1565 |
callback invocations when you are not expecting any read data - the reason |
1566 |
is that AnyEvent::Handle always reads in TLS mode. |
1567 |
|
1568 |
During the connection, you have to make sure that you always have a |
1569 |
non-empty read-queue, or an C<on_read> watcher. At the end of the |
1570 |
connection (or when you no longer want to use it) you can call the |
1571 |
C<destroy> method. |
1572 |
|
1573 |
=item How do I read data until the other side closes the connection? |
1574 |
|
1575 |
If you just want to read your data into a perl scalar, the easiest way |
1576 |
to achieve this is by setting an C<on_read> callback that does nothing, |
1577 |
clearing the C<on_eof> callback and in the C<on_error> callback, the data |
1578 |
will be in C<$_[0]{rbuf}>: |
1579 |
|
1580 |
$handle->on_read (sub { }); |
1581 |
$handle->on_eof (undef); |
1582 |
$handle->on_error (sub { |
1583 |
my $data = delete $_[0]{rbuf}; |
1584 |
undef $handle; |
1585 |
}); |
1586 |
|
1587 |
The reason to use C<on_error> is that TCP connections, due to latencies |
1588 |
and packets loss, might get closed quite violently with an error, when in |
1589 |
fact, all data has been received. |
1590 |
|
1591 |
It is usually better to use acknowledgements when transferring data, |
1592 |
to make sure the other side hasn't just died and you got the data |
1593 |
intact. This is also one reason why so many internet protocols have an |
1594 |
explicit QUIT command. |
1595 |
|
1596 |
=item I don't want to destroy the handle too early - how do I wait until |
1597 |
all data has been written? |
1598 |
|
1599 |
After writing your last bits of data, set the C<on_drain> callback |
1600 |
and destroy the handle in there - with the default setting of |
1601 |
C<low_water_mark> this will be called precisely when all data has been |
1602 |
written to the socket: |
1603 |
|
1604 |
$handle->push_write (...); |
1605 |
$handle->on_drain (sub { |
1606 |
warn "all data submitted to the kernel\n"; |
1607 |
undef $handle; |
1608 |
}); |
1609 |
|
1610 |
=back |
1611 |
|
1612 |
|
1613 |
=head1 SUBCLASSING AnyEvent::Handle |
1614 |
|
1615 |
In many cases, you might want to subclass AnyEvent::Handle. |
1616 |
|
1617 |
To make this easier, a given version of AnyEvent::Handle uses these |
1618 |
conventions: |
1619 |
|
1620 |
=over 4 |
1621 |
|
1622 |
=item * all constructor arguments become object members. |
1623 |
|
1624 |
At least initially, when you pass a C<tls>-argument to the constructor it |
1625 |
will end up in C<< $handle->{tls} >>. Those members might be changed or |
1626 |
mutated later on (for example C<tls> will hold the TLS connection object). |
1627 |
|
1628 |
=item * other object member names are prefixed with an C<_>. |
1629 |
|
1630 |
All object members not explicitly documented (internal use) are prefixed |
1631 |
with an underscore character, so the remaining non-C<_>-namespace is free |
1632 |
for use for subclasses. |
1633 |
|
1634 |
=item * all members not documented here and not prefixed with an underscore |
1635 |
are free to use in subclasses. |
1636 |
|
1637 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
1638 |
member variables, but thats just life, at least it is documented. |
1639 |
|
1640 |
=back |
1641 |
|
1642 |
=head1 AUTHOR |
1643 |
|
1644 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
1645 |
|
1646 |
=cut |
1647 |
|
1648 |
1; # End of AnyEvent::Handle |