1 |
package AnyEvent::Handle; |
2 |
|
3 |
no warnings; |
4 |
use strict; |
5 |
|
6 |
use AnyEvent (); |
7 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
8 |
use Scalar::Util (); |
9 |
use Carp (); |
10 |
use Fcntl (); |
11 |
use Errno qw(EAGAIN EINTR); |
12 |
|
13 |
=head1 NAME |
14 |
|
15 |
AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent |
16 |
|
17 |
=cut |
18 |
|
19 |
our $VERSION = '0.04'; |
20 |
|
21 |
=head1 SYNOPSIS |
22 |
|
23 |
use AnyEvent; |
24 |
use AnyEvent::Handle; |
25 |
|
26 |
my $cv = AnyEvent->condvar; |
27 |
|
28 |
my $handle = |
29 |
AnyEvent::Handle->new ( |
30 |
fh => \*STDIN, |
31 |
on_eof => sub { |
32 |
$cv->broadcast; |
33 |
}, |
34 |
); |
35 |
|
36 |
# send some request line |
37 |
$handle->push_write ("getinfo\015\012"); |
38 |
|
39 |
# read the response line |
40 |
$handle->push_read (line => sub { |
41 |
my ($handle, $line) = @_; |
42 |
warn "read line <$line>\n"; |
43 |
$cv->send; |
44 |
}); |
45 |
|
46 |
$cv->recv; |
47 |
|
48 |
=head1 DESCRIPTION |
49 |
|
50 |
This module is a helper module to make it easier to do event-based I/O on |
51 |
filehandles. For utility functions for doing non-blocking connects and accepts |
52 |
on sockets see L<AnyEvent::Util>. |
53 |
|
54 |
In the following, when the documentation refers to of "bytes" then this |
55 |
means characters. As sysread and syswrite are used for all I/O, their |
56 |
treatment of characters applies to this module as well. |
57 |
|
58 |
All callbacks will be invoked with the handle object as their first |
59 |
argument. |
60 |
|
61 |
=head1 METHODS |
62 |
|
63 |
=over 4 |
64 |
|
65 |
=item B<new (%args)> |
66 |
|
67 |
The constructor supports these arguments (all as key => value pairs). |
68 |
|
69 |
=over 4 |
70 |
|
71 |
=item fh => $filehandle [MANDATORY] |
72 |
|
73 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
74 |
|
75 |
NOTE: The filehandle will be set to non-blocking (using |
76 |
AnyEvent::Util::fh_nonblocking). |
77 |
|
78 |
=item on_eof => $cb->($handle) |
79 |
|
80 |
Set the callback to be called on EOF. |
81 |
|
82 |
While not mandatory, it is highly recommended to set an eof callback, |
83 |
otherwise you might end up with a closed socket while you are still |
84 |
waiting for data. |
85 |
|
86 |
=item on_error => $cb->($handle) |
87 |
|
88 |
This is the fatal error callback, that is called when, well, a fatal error |
89 |
occurs, such as not being able to resolve the hostname, failure to connect |
90 |
or a read error. |
91 |
|
92 |
The object will not be in a usable state when this callback has been |
93 |
called. |
94 |
|
95 |
On callback entrance, the value of C<$!> contains the operating system |
96 |
error (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT> or C<EBADMSG>). |
97 |
|
98 |
The callback should throw an exception. If it returns, then |
99 |
AnyEvent::Handle will C<croak> for you. |
100 |
|
101 |
While not mandatory, it is I<highly> recommended to set this callback, as |
102 |
you will not be notified of errors otherwise. The default simply calls |
103 |
die. |
104 |
|
105 |
=item on_read => $cb->($handle) |
106 |
|
107 |
This sets the default read callback, which is called when data arrives |
108 |
and no read request is in the queue. |
109 |
|
110 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
111 |
method or access the C<$handle->{rbuf}> member directly. |
112 |
|
113 |
When an EOF condition is detected then AnyEvent::Handle will first try to |
114 |
feed all the remaining data to the queued callbacks and C<on_read> before |
115 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
116 |
error will be raised (with C<$!> set to C<EPIPE>). |
117 |
|
118 |
=item on_drain => $cb->($handle) |
119 |
|
120 |
This sets the callback that is called when the write buffer becomes empty |
121 |
(or when the callback is set and the buffer is empty already). |
122 |
|
123 |
To append to the write buffer, use the C<< ->push_write >> method. |
124 |
|
125 |
=item timeout => $fractional_seconds |
126 |
|
127 |
If non-zero, then this enables an "inactivity" timeout: whenever this many |
128 |
seconds pass without a successful read or write on the underlying file |
129 |
handle, the C<on_timeout> callback will be invoked (and if that one is |
130 |
missing, an C<ETIMEDOUT> error will be raised). |
131 |
|
132 |
Note that timeout processing is also active when you currently do not have |
133 |
any outstanding read or write requests: If you plan to keep the connection |
134 |
idle then you should disable the timout temporarily or ignore the timeout |
135 |
in the C<on_timeout> callback. |
136 |
|
137 |
Zero (the default) disables this timeout. |
138 |
|
139 |
=item on_timeout => $cb->($handle) |
140 |
|
141 |
Called whenever the inactivity timeout passes. If you return from this |
142 |
callback, then the timeout will be reset as if some activity had happened, |
143 |
so this condition is not fatal in any way. |
144 |
|
145 |
=item rbuf_max => <bytes> |
146 |
|
147 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
148 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
149 |
avoid denial-of-service attacks. |
150 |
|
151 |
For example, a server accepting connections from untrusted sources should |
152 |
be configured to accept only so-and-so much data that it cannot act on |
153 |
(for example, when expecting a line, an attacker could send an unlimited |
154 |
amount of data without a callback ever being called as long as the line |
155 |
isn't finished). |
156 |
|
157 |
=item read_size => <bytes> |
158 |
|
159 |
The default read block size (the amount of bytes this module will try to read |
160 |
during each (loop iteration). Default: C<8192>. |
161 |
|
162 |
=item low_water_mark => <bytes> |
163 |
|
164 |
Sets the amount of bytes (default: C<0>) that make up an "empty" write |
165 |
buffer: If the write reaches this size or gets even samller it is |
166 |
considered empty. |
167 |
|
168 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
169 |
|
170 |
When this parameter is given, it enables TLS (SSL) mode, that means it |
171 |
will start making tls handshake and will transparently encrypt/decrypt |
172 |
data. |
173 |
|
174 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
175 |
automatically when you try to create a TLS handle). |
176 |
|
177 |
For the TLS server side, use C<accept>, and for the TLS client side of a |
178 |
connection, use C<connect> mode. |
179 |
|
180 |
You can also provide your own TLS connection object, but you have |
181 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
182 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
183 |
AnyEvent::Handle. |
184 |
|
185 |
See the C<starttls> method if you need to start TLs negotiation later. |
186 |
|
187 |
=item tls_ctx => $ssl_ctx |
188 |
|
189 |
Use the given Net::SSLeay::CTX object to create the new TLS connection |
190 |
(unless a connection object was specified directly). If this parameter is |
191 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
192 |
|
193 |
=item json => JSON or JSON::XS object |
194 |
|
195 |
This is the json coder object used by the C<json> read and write types. |
196 |
|
197 |
If you don't supply it, then AnyEvent::Handle will create and use a |
198 |
suitable one, which will write and expect UTF-8 encoded JSON texts. |
199 |
|
200 |
Note that you are responsible to depend on the JSON module if you want to |
201 |
use this functionality, as AnyEvent does not have a dependency itself. |
202 |
|
203 |
=item filter_r => $cb |
204 |
|
205 |
=item filter_w => $cb |
206 |
|
207 |
These exist, but are undocumented at this time. |
208 |
|
209 |
=back |
210 |
|
211 |
=cut |
212 |
|
213 |
sub new { |
214 |
my $class = shift; |
215 |
|
216 |
my $self = bless { @_ }, $class; |
217 |
|
218 |
$self->{fh} or Carp::croak "mandatory argument fh is missing"; |
219 |
|
220 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
221 |
|
222 |
if ($self->{tls}) { |
223 |
require Net::SSLeay; |
224 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}); |
225 |
} |
226 |
|
227 |
# $self->on_eof (delete $self->{on_eof} ) if $self->{on_eof}; # nop |
228 |
# $self->on_error (delete $self->{on_error}) if $self->{on_error}; # nop |
229 |
# $self->on_read (delete $self->{on_read} ) if $self->{on_read}; # nop |
230 |
$self->on_drain (delete $self->{on_drain}) if $self->{on_drain}; |
231 |
|
232 |
$self->{_activity} = AnyEvent->now; |
233 |
$self->_timeout; |
234 |
|
235 |
$self->start_read; |
236 |
|
237 |
$self |
238 |
} |
239 |
|
240 |
sub _shutdown { |
241 |
my ($self) = @_; |
242 |
|
243 |
delete $self->{_tw}; |
244 |
delete $self->{_rw}; |
245 |
delete $self->{_ww}; |
246 |
delete $self->{fh}; |
247 |
} |
248 |
|
249 |
sub error { |
250 |
my ($self) = @_; |
251 |
|
252 |
{ |
253 |
local $!; |
254 |
$self->_shutdown; |
255 |
} |
256 |
|
257 |
$self->{on_error}($self) |
258 |
if $self->{on_error}; |
259 |
|
260 |
Carp::croak "AnyEvent::Handle uncaught fatal error: $!"; |
261 |
} |
262 |
|
263 |
=item $fh = $handle->fh |
264 |
|
265 |
This method returns the file handle of the L<AnyEvent::Handle> object. |
266 |
|
267 |
=cut |
268 |
|
269 |
sub fh { $_[0]{fh} } |
270 |
|
271 |
=item $handle->on_error ($cb) |
272 |
|
273 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
274 |
|
275 |
=cut |
276 |
|
277 |
sub on_error { |
278 |
$_[0]{on_error} = $_[1]; |
279 |
} |
280 |
|
281 |
=item $handle->on_eof ($cb) |
282 |
|
283 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
284 |
|
285 |
=cut |
286 |
|
287 |
sub on_eof { |
288 |
$_[0]{on_eof} = $_[1]; |
289 |
} |
290 |
|
291 |
=item $handle->on_timeout ($cb) |
292 |
|
293 |
Replace the current C<on_timeout> callback, or disables the callback |
294 |
(but not the timeout) if C<$cb> = C<undef>. See C<timeout> constructor |
295 |
argument. |
296 |
|
297 |
=cut |
298 |
|
299 |
sub on_timeout { |
300 |
$_[0]{on_timeout} = $_[1]; |
301 |
} |
302 |
|
303 |
############################################################################# |
304 |
|
305 |
=item $handle->timeout ($seconds) |
306 |
|
307 |
Configures (or disables) the inactivity timeout. |
308 |
|
309 |
=cut |
310 |
|
311 |
sub timeout { |
312 |
my ($self, $timeout) = @_; |
313 |
|
314 |
$self->{timeout} = $timeout; |
315 |
$self->_timeout; |
316 |
} |
317 |
|
318 |
# reset the timeout watcher, as neccessary |
319 |
# also check for time-outs |
320 |
sub _timeout { |
321 |
my ($self) = @_; |
322 |
|
323 |
if ($self->{timeout}) { |
324 |
my $NOW = AnyEvent->now; |
325 |
|
326 |
# when would the timeout trigger? |
327 |
my $after = $self->{_activity} + $self->{timeout} - $NOW; |
328 |
|
329 |
# now or in the past already? |
330 |
if ($after <= 0) { |
331 |
$self->{_activity} = $NOW; |
332 |
|
333 |
if ($self->{on_timeout}) { |
334 |
$self->{on_timeout}->($self); |
335 |
} else { |
336 |
$! = Errno::ETIMEDOUT; |
337 |
$self->error; |
338 |
} |
339 |
|
340 |
# callbakx could have changed timeout value, optimise |
341 |
return unless $self->{timeout}; |
342 |
|
343 |
# calculate new after |
344 |
$after = $self->{timeout}; |
345 |
} |
346 |
|
347 |
Scalar::Util::weaken $self; |
348 |
|
349 |
$self->{_tw} ||= AnyEvent->timer (after => $after, cb => sub { |
350 |
delete $self->{_tw}; |
351 |
$self->_timeout; |
352 |
}); |
353 |
} else { |
354 |
delete $self->{_tw}; |
355 |
} |
356 |
} |
357 |
|
358 |
############################################################################# |
359 |
|
360 |
=back |
361 |
|
362 |
=head2 WRITE QUEUE |
363 |
|
364 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
365 |
for reading. |
366 |
|
367 |
The write queue is very simple: you can add data to its end, and |
368 |
AnyEvent::Handle will automatically try to get rid of it for you. |
369 |
|
370 |
When data could be written and the write buffer is shorter then the low |
371 |
water mark, the C<on_drain> callback will be invoked. |
372 |
|
373 |
=over 4 |
374 |
|
375 |
=item $handle->on_drain ($cb) |
376 |
|
377 |
Sets the C<on_drain> callback or clears it (see the description of |
378 |
C<on_drain> in the constructor). |
379 |
|
380 |
=cut |
381 |
|
382 |
sub on_drain { |
383 |
my ($self, $cb) = @_; |
384 |
|
385 |
$self->{on_drain} = $cb; |
386 |
|
387 |
$cb->($self) |
388 |
if $cb && $self->{low_water_mark} >= length $self->{wbuf}; |
389 |
} |
390 |
|
391 |
=item $handle->push_write ($data) |
392 |
|
393 |
Queues the given scalar to be written. You can push as much data as you |
394 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
395 |
buffers it independently of the kernel. |
396 |
|
397 |
=cut |
398 |
|
399 |
sub _drain_wbuf { |
400 |
my ($self) = @_; |
401 |
|
402 |
if (!$self->{_ww} && length $self->{wbuf}) { |
403 |
|
404 |
Scalar::Util::weaken $self; |
405 |
|
406 |
my $cb = sub { |
407 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
408 |
|
409 |
if ($len >= 0) { |
410 |
substr $self->{wbuf}, 0, $len, ""; |
411 |
|
412 |
$self->{_activity} = AnyEvent->now; |
413 |
|
414 |
$self->{on_drain}($self) |
415 |
if $self->{low_water_mark} >= length $self->{wbuf} |
416 |
&& $self->{on_drain}; |
417 |
|
418 |
delete $self->{_ww} unless length $self->{wbuf}; |
419 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
420 |
$self->error; |
421 |
} |
422 |
}; |
423 |
|
424 |
# try to write data immediately |
425 |
$cb->(); |
426 |
|
427 |
# if still data left in wbuf, we need to poll |
428 |
$self->{_ww} = AnyEvent->io (fh => $self->{fh}, poll => "w", cb => $cb) |
429 |
if length $self->{wbuf}; |
430 |
}; |
431 |
} |
432 |
|
433 |
our %WH; |
434 |
|
435 |
sub register_write_type($$) { |
436 |
$WH{$_[0]} = $_[1]; |
437 |
} |
438 |
|
439 |
sub push_write { |
440 |
my $self = shift; |
441 |
|
442 |
if (@_ > 1) { |
443 |
my $type = shift; |
444 |
|
445 |
@_ = ($WH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_write") |
446 |
->($self, @_); |
447 |
} |
448 |
|
449 |
if ($self->{filter_w}) { |
450 |
$self->{filter_w}->($self, \$_[0]); |
451 |
} else { |
452 |
$self->{wbuf} .= $_[0]; |
453 |
$self->_drain_wbuf; |
454 |
} |
455 |
} |
456 |
|
457 |
=item $handle->push_write (type => @args) |
458 |
|
459 |
=item $handle->unshift_write (type => @args) |
460 |
|
461 |
Instead of formatting your data yourself, you can also let this module do |
462 |
the job by specifying a type and type-specific arguments. |
463 |
|
464 |
Predefined types are (if you have ideas for additional types, feel free to |
465 |
drop by and tell us): |
466 |
|
467 |
=over 4 |
468 |
|
469 |
=item netstring => $string |
470 |
|
471 |
Formats the given value as netstring |
472 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
473 |
|
474 |
=back |
475 |
|
476 |
=cut |
477 |
|
478 |
register_write_type netstring => sub { |
479 |
my ($self, $string) = @_; |
480 |
|
481 |
sprintf "%d:%s,", (length $string), $string |
482 |
}; |
483 |
|
484 |
=item json => $array_or_hashref |
485 |
|
486 |
Encodes the given hash or array reference into a JSON object. Unless you |
487 |
provide your own JSON object, this means it will be encoded to JSON text |
488 |
in UTF-8. |
489 |
|
490 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
491 |
one end of a handle and read them at the other end without using any |
492 |
additional framing. |
493 |
|
494 |
The generated JSON text is guaranteed not to contain any newlines: While |
495 |
this module doesn't need delimiters after or between JSON texts to be |
496 |
able to read them, many other languages depend on that. |
497 |
|
498 |
A simple RPC protocol that interoperates easily with others is to send |
499 |
JSON arrays (or objects, although arrays are usually the better choice as |
500 |
they mimic how function argument passing works) and a newline after each |
501 |
JSON text: |
502 |
|
503 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
504 |
$handle->push_write ("\012"); |
505 |
|
506 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
507 |
rely on the fact that the newline will be skipped as leading whitespace: |
508 |
|
509 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
510 |
|
511 |
Other languages could read single lines terminated by a newline and pass |
512 |
this line into their JSON decoder of choice. |
513 |
|
514 |
=cut |
515 |
|
516 |
register_write_type json => sub { |
517 |
my ($self, $ref) = @_; |
518 |
|
519 |
require JSON; |
520 |
|
521 |
$self->{json} ? $self->{json}->encode ($ref) |
522 |
: JSON::encode_json ($ref) |
523 |
}; |
524 |
|
525 |
=item AnyEvent::Handle::register_write_type type => $coderef->($handle, @args) |
526 |
|
527 |
This function (not method) lets you add your own types to C<push_write>. |
528 |
Whenever the given C<type> is used, C<push_write> will invoke the code |
529 |
reference with the handle object and the remaining arguments. |
530 |
|
531 |
The code reference is supposed to return a single octet string that will |
532 |
be appended to the write buffer. |
533 |
|
534 |
Note that this is a function, and all types registered this way will be |
535 |
global, so try to use unique names. |
536 |
|
537 |
=cut |
538 |
|
539 |
############################################################################# |
540 |
|
541 |
=back |
542 |
|
543 |
=head2 READ QUEUE |
544 |
|
545 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
546 |
for reading. |
547 |
|
548 |
The read queue is more complex than the write queue. It can be used in two |
549 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
550 |
a queue. |
551 |
|
552 |
In the simple case, you just install an C<on_read> callback and whenever |
553 |
new data arrives, it will be called. You can then remove some data (if |
554 |
enough is there) from the read buffer (C<< $handle->rbuf >>) if you want |
555 |
or not. |
556 |
|
557 |
In the more complex case, you want to queue multiple callbacks. In this |
558 |
case, AnyEvent::Handle will call the first queued callback each time new |
559 |
data arrives and removes it when it has done its job (see C<push_read>, |
560 |
below). |
561 |
|
562 |
This way you can, for example, push three line-reads, followed by reading |
563 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
564 |
|
565 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
566 |
the specified number of bytes which give an XML datagram. |
567 |
|
568 |
# in the default state, expect some header bytes |
569 |
$handle->on_read (sub { |
570 |
# some data is here, now queue the length-header-read (4 octets) |
571 |
shift->unshift_read_chunk (4, sub { |
572 |
# header arrived, decode |
573 |
my $len = unpack "N", $_[1]; |
574 |
|
575 |
# now read the payload |
576 |
shift->unshift_read_chunk ($len, sub { |
577 |
my $xml = $_[1]; |
578 |
# handle xml |
579 |
}); |
580 |
}); |
581 |
}); |
582 |
|
583 |
Example 2: Implement a client for a protocol that replies either with |
584 |
"OK" and another line or "ERROR" for one request, and 64 bytes for the |
585 |
second request. Due tot he availability of a full queue, we can just |
586 |
pipeline sending both requests and manipulate the queue as necessary in |
587 |
the callbacks: |
588 |
|
589 |
# request one |
590 |
$handle->push_write ("request 1\015\012"); |
591 |
|
592 |
# we expect "ERROR" or "OK" as response, so push a line read |
593 |
$handle->push_read_line (sub { |
594 |
# if we got an "OK", we have to _prepend_ another line, |
595 |
# so it will be read before the second request reads its 64 bytes |
596 |
# which are already in the queue when this callback is called |
597 |
# we don't do this in case we got an error |
598 |
if ($_[1] eq "OK") { |
599 |
$_[0]->unshift_read_line (sub { |
600 |
my $response = $_[1]; |
601 |
... |
602 |
}); |
603 |
} |
604 |
}); |
605 |
|
606 |
# request two |
607 |
$handle->push_write ("request 2\015\012"); |
608 |
|
609 |
# simply read 64 bytes, always |
610 |
$handle->push_read_chunk (64, sub { |
611 |
my $response = $_[1]; |
612 |
... |
613 |
}); |
614 |
|
615 |
=over 4 |
616 |
|
617 |
=cut |
618 |
|
619 |
sub _drain_rbuf { |
620 |
my ($self) = @_; |
621 |
|
622 |
if ( |
623 |
defined $self->{rbuf_max} |
624 |
&& $self->{rbuf_max} < length $self->{rbuf} |
625 |
) { |
626 |
$! = &Errno::ENOSPC; |
627 |
$self->error; |
628 |
} |
629 |
|
630 |
return if $self->{in_drain}; |
631 |
local $self->{in_drain} = 1; |
632 |
|
633 |
while (my $len = length $self->{rbuf}) { |
634 |
no strict 'refs'; |
635 |
if (my $cb = shift @{ $self->{_queue} }) { |
636 |
unless ($cb->($self)) { |
637 |
if ($self->{_eof}) { |
638 |
# no progress can be made (not enough data and no data forthcoming) |
639 |
$! = &Errno::EPIPE; |
640 |
$self->error; |
641 |
} |
642 |
|
643 |
unshift @{ $self->{_queue} }, $cb; |
644 |
return; |
645 |
} |
646 |
} elsif ($self->{on_read}) { |
647 |
$self->{on_read}($self); |
648 |
|
649 |
if ( |
650 |
$self->{_eof} # if no further data will arrive |
651 |
&& $len == length $self->{rbuf} # and no data has been consumed |
652 |
&& !@{ $self->{_queue} } # and the queue is still empty |
653 |
&& $self->{on_read} # and we still want to read data |
654 |
) { |
655 |
# then no progress can be made |
656 |
$! = &Errno::EPIPE; |
657 |
$self->error; |
658 |
} |
659 |
} else { |
660 |
# read side becomes idle |
661 |
delete $self->{_rw}; |
662 |
return; |
663 |
} |
664 |
} |
665 |
|
666 |
if ($self->{_eof}) { |
667 |
$self->_shutdown; |
668 |
$self->{on_eof}($self) |
669 |
if $self->{on_eof}; |
670 |
} |
671 |
} |
672 |
|
673 |
=item $handle->on_read ($cb) |
674 |
|
675 |
This replaces the currently set C<on_read> callback, or clears it (when |
676 |
the new callback is C<undef>). See the description of C<on_read> in the |
677 |
constructor. |
678 |
|
679 |
=cut |
680 |
|
681 |
sub on_read { |
682 |
my ($self, $cb) = @_; |
683 |
|
684 |
$self->{on_read} = $cb; |
685 |
} |
686 |
|
687 |
=item $handle->rbuf |
688 |
|
689 |
Returns the read buffer (as a modifiable lvalue). |
690 |
|
691 |
You can access the read buffer directly as the C<< ->{rbuf} >> member, if |
692 |
you want. |
693 |
|
694 |
NOTE: The read buffer should only be used or modified if the C<on_read>, |
695 |
C<push_read> or C<unshift_read> methods are used. The other read methods |
696 |
automatically manage the read buffer. |
697 |
|
698 |
=cut |
699 |
|
700 |
sub rbuf : lvalue { |
701 |
$_[0]{rbuf} |
702 |
} |
703 |
|
704 |
=item $handle->push_read ($cb) |
705 |
|
706 |
=item $handle->unshift_read ($cb) |
707 |
|
708 |
Append the given callback to the end of the queue (C<push_read>) or |
709 |
prepend it (C<unshift_read>). |
710 |
|
711 |
The callback is called each time some additional read data arrives. |
712 |
|
713 |
It must check whether enough data is in the read buffer already. |
714 |
|
715 |
If not enough data is available, it must return the empty list or a false |
716 |
value, in which case it will be called repeatedly until enough data is |
717 |
available (or an error condition is detected). |
718 |
|
719 |
If enough data was available, then the callback must remove all data it is |
720 |
interested in (which can be none at all) and return a true value. After returning |
721 |
true, it will be removed from the queue. |
722 |
|
723 |
=cut |
724 |
|
725 |
our %RH; |
726 |
|
727 |
sub register_read_type($$) { |
728 |
$RH{$_[0]} = $_[1]; |
729 |
} |
730 |
|
731 |
sub push_read { |
732 |
my $self = shift; |
733 |
my $cb = pop; |
734 |
|
735 |
if (@_) { |
736 |
my $type = shift; |
737 |
|
738 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_read") |
739 |
->($self, $cb, @_); |
740 |
} |
741 |
|
742 |
push @{ $self->{_queue} }, $cb; |
743 |
$self->_drain_rbuf; |
744 |
} |
745 |
|
746 |
sub unshift_read { |
747 |
my $self = shift; |
748 |
my $cb = pop; |
749 |
|
750 |
if (@_) { |
751 |
my $type = shift; |
752 |
|
753 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::unshift_read") |
754 |
->($self, $cb, @_); |
755 |
} |
756 |
|
757 |
|
758 |
unshift @{ $self->{_queue} }, $cb; |
759 |
$self->_drain_rbuf; |
760 |
} |
761 |
|
762 |
=item $handle->push_read (type => @args, $cb) |
763 |
|
764 |
=item $handle->unshift_read (type => @args, $cb) |
765 |
|
766 |
Instead of providing a callback that parses the data itself you can chose |
767 |
between a number of predefined parsing formats, for chunks of data, lines |
768 |
etc. |
769 |
|
770 |
Predefined types are (if you have ideas for additional types, feel free to |
771 |
drop by and tell us): |
772 |
|
773 |
=over 4 |
774 |
|
775 |
=item chunk => $octets, $cb->($handle, $data) |
776 |
|
777 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
778 |
data read to the callback. The callback will never be called with less |
779 |
data. |
780 |
|
781 |
Example: read 2 bytes. |
782 |
|
783 |
$handle->push_read (chunk => 2, sub { |
784 |
warn "yay ", unpack "H*", $_[1]; |
785 |
}); |
786 |
|
787 |
=cut |
788 |
|
789 |
register_read_type chunk => sub { |
790 |
my ($self, $cb, $len) = @_; |
791 |
|
792 |
sub { |
793 |
$len <= length $_[0]{rbuf} or return; |
794 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
795 |
1 |
796 |
} |
797 |
}; |
798 |
|
799 |
# compatibility with older API |
800 |
sub push_read_chunk { |
801 |
$_[0]->push_read (chunk => $_[1], $_[2]); |
802 |
} |
803 |
|
804 |
sub unshift_read_chunk { |
805 |
$_[0]->unshift_read (chunk => $_[1], $_[2]); |
806 |
} |
807 |
|
808 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
809 |
|
810 |
The callback will be called only once a full line (including the end of |
811 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
812 |
marker) will be passed to the callback as second argument (C<$line>), and |
813 |
the end of line marker as the third argument (C<$eol>). |
814 |
|
815 |
The end of line marker, C<$eol>, can be either a string, in which case it |
816 |
will be interpreted as a fixed record end marker, or it can be a regex |
817 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
818 |
regular expression. |
819 |
|
820 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
821 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
822 |
protocols). |
823 |
|
824 |
Partial lines at the end of the stream will never be returned, as they are |
825 |
not marked by the end of line marker. |
826 |
|
827 |
=cut |
828 |
|
829 |
register_read_type line => sub { |
830 |
my ($self, $cb, $eol) = @_; |
831 |
|
832 |
$eol = qr|(\015?\012)| if @_ < 3; |
833 |
$eol = quotemeta $eol unless ref $eol; |
834 |
$eol = qr|^(.*?)($eol)|s; |
835 |
|
836 |
sub { |
837 |
$_[0]{rbuf} =~ s/$eol// or return; |
838 |
|
839 |
$cb->($_[0], $1, $2); |
840 |
1 |
841 |
} |
842 |
}; |
843 |
|
844 |
# compatibility with older API |
845 |
sub push_read_line { |
846 |
my $self = shift; |
847 |
$self->push_read (line => @_); |
848 |
} |
849 |
|
850 |
sub unshift_read_line { |
851 |
my $self = shift; |
852 |
$self->unshift_read (line => @_); |
853 |
} |
854 |
|
855 |
=item netstring => $cb->($handle, $string) |
856 |
|
857 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
858 |
|
859 |
Throws an error with C<$!> set to EBADMSG on format violations. |
860 |
|
861 |
=cut |
862 |
|
863 |
register_read_type netstring => sub { |
864 |
my ($self, $cb) = @_; |
865 |
|
866 |
sub { |
867 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
868 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
869 |
$! = &Errno::EBADMSG; |
870 |
$self->error; |
871 |
} |
872 |
return; |
873 |
} |
874 |
|
875 |
my $len = $1; |
876 |
|
877 |
$self->unshift_read (chunk => $len, sub { |
878 |
my $string = $_[1]; |
879 |
$_[0]->unshift_read (chunk => 1, sub { |
880 |
if ($_[1] eq ",") { |
881 |
$cb->($_[0], $string); |
882 |
} else { |
883 |
$! = &Errno::EBADMSG; |
884 |
$self->error; |
885 |
} |
886 |
}); |
887 |
}); |
888 |
|
889 |
1 |
890 |
} |
891 |
}; |
892 |
|
893 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
894 |
|
895 |
Makes a regex match against the regex object C<$accept> and returns |
896 |
everything up to and including the match. |
897 |
|
898 |
Example: read a single line terminated by '\n'. |
899 |
|
900 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
901 |
|
902 |
If C<$reject> is given and not undef, then it determines when the data is |
903 |
to be rejected: it is matched against the data when the C<$accept> regex |
904 |
does not match and generates an C<EBADMSG> error when it matches. This is |
905 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
906 |
receive buffer overflow). |
907 |
|
908 |
Example: expect a single decimal number followed by whitespace, reject |
909 |
anything else (not the use of an anchor). |
910 |
|
911 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
912 |
|
913 |
If C<$skip> is given and not C<undef>, then it will be matched against |
914 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
915 |
and everything preceding and including the match will be accepted |
916 |
unconditionally. This is useful to skip large amounts of data that you |
917 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
918 |
have to start matching from the beginning. This is purely an optimisation |
919 |
and is usually worth only when you expect more than a few kilobytes. |
920 |
|
921 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
922 |
expect the header to be very large (it isn't in practise, but...), we use |
923 |
a skip regex to skip initial portions. The skip regex is tricky in that |
924 |
it only accepts something not ending in either \015 or \012, as these are |
925 |
required for the accept regex. |
926 |
|
927 |
$handle->push_read (regex => |
928 |
qr<\015\012\015\012>, |
929 |
undef, # no reject |
930 |
qr<^.*[^\015\012]>, |
931 |
sub { ... }); |
932 |
|
933 |
=cut |
934 |
|
935 |
register_read_type regex => sub { |
936 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
937 |
|
938 |
my $data; |
939 |
my $rbuf = \$self->{rbuf}; |
940 |
|
941 |
sub { |
942 |
# accept |
943 |
if ($$rbuf =~ $accept) { |
944 |
$data .= substr $$rbuf, 0, $+[0], ""; |
945 |
$cb->($self, $data); |
946 |
return 1; |
947 |
} |
948 |
|
949 |
# reject |
950 |
if ($reject && $$rbuf =~ $reject) { |
951 |
$! = &Errno::EBADMSG; |
952 |
$self->error; |
953 |
} |
954 |
|
955 |
# skip |
956 |
if ($skip && $$rbuf =~ $skip) { |
957 |
$data .= substr $$rbuf, 0, $+[0], ""; |
958 |
} |
959 |
|
960 |
() |
961 |
} |
962 |
}; |
963 |
|
964 |
=item json => $cb->($handle, $hash_or_arrayref) |
965 |
|
966 |
Reads a JSON object or array, decodes it and passes it to the callback. |
967 |
|
968 |
If a C<json> object was passed to the constructor, then that will be used |
969 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
970 |
|
971 |
This read type uses the incremental parser available with JSON version |
972 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
973 |
dependency on your own: this module will load the JSON module, but |
974 |
AnyEvent does not depend on it itself. |
975 |
|
976 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
977 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
978 |
the C<json> write type description, above, for an actual example. |
979 |
|
980 |
=cut |
981 |
|
982 |
register_read_type json => sub { |
983 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
984 |
|
985 |
require JSON; |
986 |
|
987 |
my $data; |
988 |
my $rbuf = \$self->{rbuf}; |
989 |
|
990 |
my $json = $self->{json} ||= JSON->new->utf8; |
991 |
|
992 |
sub { |
993 |
my $ref = $json->incr_parse ($self->{rbuf}); |
994 |
|
995 |
if ($ref) { |
996 |
$self->{rbuf} = $json->incr_text; |
997 |
$json->incr_text = ""; |
998 |
$cb->($self, $ref); |
999 |
|
1000 |
1 |
1001 |
} else { |
1002 |
$self->{rbuf} = ""; |
1003 |
() |
1004 |
} |
1005 |
} |
1006 |
}; |
1007 |
|
1008 |
=back |
1009 |
|
1010 |
=item AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args) |
1011 |
|
1012 |
This function (not method) lets you add your own types to C<push_read>. |
1013 |
|
1014 |
Whenever the given C<type> is used, C<push_read> will invoke the code |
1015 |
reference with the handle object, the callback and the remaining |
1016 |
arguments. |
1017 |
|
1018 |
The code reference is supposed to return a callback (usually a closure) |
1019 |
that works as a plain read callback (see C<< ->push_read ($cb) >>). |
1020 |
|
1021 |
It should invoke the passed callback when it is done reading (remember to |
1022 |
pass C<$handle> as first argument as all other callbacks do that). |
1023 |
|
1024 |
Note that this is a function, and all types registered this way will be |
1025 |
global, so try to use unique names. |
1026 |
|
1027 |
For examples, see the source of this module (F<perldoc -m AnyEvent::Handle>, |
1028 |
search for C<register_read_type>)). |
1029 |
|
1030 |
=item $handle->stop_read |
1031 |
|
1032 |
=item $handle->start_read |
1033 |
|
1034 |
In rare cases you actually do not want to read anything from the |
1035 |
socket. In this case you can call C<stop_read>. Neither C<on_read> no |
1036 |
any queued callbacks will be executed then. To start reading again, call |
1037 |
C<start_read>. |
1038 |
|
1039 |
=cut |
1040 |
|
1041 |
sub stop_read { |
1042 |
my ($self) = @_; |
1043 |
|
1044 |
delete $self->{_rw}; |
1045 |
} |
1046 |
|
1047 |
sub start_read { |
1048 |
my ($self) = @_; |
1049 |
|
1050 |
unless ($self->{_rw} || $self->{_eof}) { |
1051 |
Scalar::Util::weaken $self; |
1052 |
|
1053 |
$self->{_rw} = AnyEvent->io (fh => $self->{fh}, poll => "r", cb => sub { |
1054 |
my $rbuf = $self->{filter_r} ? \my $buf : \$self->{rbuf}; |
1055 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size} || 8192, length $$rbuf; |
1056 |
|
1057 |
if ($len > 0) { |
1058 |
$self->{_activity} = AnyEvent->now; |
1059 |
|
1060 |
$self->{filter_r} |
1061 |
? $self->{filter_r}->($self, $rbuf) |
1062 |
: $self->_drain_rbuf; |
1063 |
|
1064 |
} elsif (defined $len) { |
1065 |
delete $self->{_rw}; |
1066 |
$self->{_eof} = 1; |
1067 |
$self->_drain_rbuf; |
1068 |
|
1069 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1070 |
return $self->error; |
1071 |
} |
1072 |
}); |
1073 |
} |
1074 |
} |
1075 |
|
1076 |
sub _dotls { |
1077 |
my ($self) = @_; |
1078 |
|
1079 |
if (length $self->{_tls_wbuf}) { |
1080 |
while ((my $len = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1081 |
substr $self->{_tls_wbuf}, 0, $len, ""; |
1082 |
} |
1083 |
} |
1084 |
|
1085 |
if (defined (my $buf = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1086 |
$self->{wbuf} .= $buf; |
1087 |
$self->_drain_wbuf; |
1088 |
} |
1089 |
|
1090 |
while (defined (my $buf = Net::SSLeay::read ($self->{tls}))) { |
1091 |
$self->{rbuf} .= $buf; |
1092 |
$self->_drain_rbuf; |
1093 |
} |
1094 |
|
1095 |
my $err = Net::SSLeay::get_error ($self->{tls}, -1); |
1096 |
|
1097 |
if ($err!= Net::SSLeay::ERROR_WANT_READ ()) { |
1098 |
if ($err == Net::SSLeay::ERROR_SYSCALL ()) { |
1099 |
$self->error; |
1100 |
} elsif ($err == Net::SSLeay::ERROR_SSL ()) { |
1101 |
$! = &Errno::EIO; |
1102 |
$self->error; |
1103 |
} |
1104 |
|
1105 |
# all others are fine for our purposes |
1106 |
} |
1107 |
} |
1108 |
|
1109 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1110 |
|
1111 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1112 |
object is created, you can also do that at a later time by calling |
1113 |
C<starttls>. |
1114 |
|
1115 |
The first argument is the same as the C<tls> constructor argument (either |
1116 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1117 |
|
1118 |
The second argument is the optional C<Net::SSLeay::CTX> object that is |
1119 |
used when AnyEvent::Handle has to create its own TLS connection object. |
1120 |
|
1121 |
The TLS connection object will end up in C<< $handle->{tls} >> after this |
1122 |
call and can be used or changed to your liking. Note that the handshake |
1123 |
might have already started when this function returns. |
1124 |
|
1125 |
=cut |
1126 |
|
1127 |
# TODO: maybe document... |
1128 |
sub starttls { |
1129 |
my ($self, $ssl, $ctx) = @_; |
1130 |
|
1131 |
$self->stoptls; |
1132 |
|
1133 |
if ($ssl eq "accept") { |
1134 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1135 |
Net::SSLeay::set_accept_state ($ssl); |
1136 |
} elsif ($ssl eq "connect") { |
1137 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1138 |
Net::SSLeay::set_connect_state ($ssl); |
1139 |
} |
1140 |
|
1141 |
$self->{tls} = $ssl; |
1142 |
|
1143 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1144 |
# but the openssl maintainers basically said: "trust us, it just works". |
1145 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1146 |
# and mismaintained ssleay-module doesn't even offer them). |
1147 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1148 |
Net::SSLeay::CTX_set_mode ($self->{tls}, |
1149 |
(eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1150 |
| (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1151 |
|
1152 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1153 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1154 |
|
1155 |
Net::SSLeay::set_bio ($ssl, $self->{_rbio}, $self->{_wbio}); |
1156 |
|
1157 |
$self->{filter_w} = sub { |
1158 |
$_[0]{_tls_wbuf} .= ${$_[1]}; |
1159 |
&_dotls; |
1160 |
}; |
1161 |
$self->{filter_r} = sub { |
1162 |
Net::SSLeay::BIO_write ($_[0]{_rbio}, ${$_[1]}); |
1163 |
&_dotls; |
1164 |
}; |
1165 |
} |
1166 |
|
1167 |
=item $handle->stoptls |
1168 |
|
1169 |
Destroys the SSL connection, if any. Partial read or write data will be |
1170 |
lost. |
1171 |
|
1172 |
=cut |
1173 |
|
1174 |
sub stoptls { |
1175 |
my ($self) = @_; |
1176 |
|
1177 |
Net::SSLeay::free (delete $self->{tls}) if $self->{tls}; |
1178 |
|
1179 |
delete $self->{_rbio}; |
1180 |
delete $self->{_wbio}; |
1181 |
delete $self->{_tls_wbuf}; |
1182 |
delete $self->{filter_r}; |
1183 |
delete $self->{filter_w}; |
1184 |
} |
1185 |
|
1186 |
sub DESTROY { |
1187 |
my $self = shift; |
1188 |
|
1189 |
$self->stoptls; |
1190 |
} |
1191 |
|
1192 |
=item AnyEvent::Handle::TLS_CTX |
1193 |
|
1194 |
This function creates and returns the Net::SSLeay::CTX object used by |
1195 |
default for TLS mode. |
1196 |
|
1197 |
The context is created like this: |
1198 |
|
1199 |
Net::SSLeay::load_error_strings; |
1200 |
Net::SSLeay::SSLeay_add_ssl_algorithms; |
1201 |
Net::SSLeay::randomize; |
1202 |
|
1203 |
my $CTX = Net::SSLeay::CTX_new; |
1204 |
|
1205 |
Net::SSLeay::CTX_set_options $CTX, Net::SSLeay::OP_ALL |
1206 |
|
1207 |
=cut |
1208 |
|
1209 |
our $TLS_CTX; |
1210 |
|
1211 |
sub TLS_CTX() { |
1212 |
$TLS_CTX || do { |
1213 |
require Net::SSLeay; |
1214 |
|
1215 |
Net::SSLeay::load_error_strings (); |
1216 |
Net::SSLeay::SSLeay_add_ssl_algorithms (); |
1217 |
Net::SSLeay::randomize (); |
1218 |
|
1219 |
$TLS_CTX = Net::SSLeay::CTX_new (); |
1220 |
|
1221 |
Net::SSLeay::CTX_set_options ($TLS_CTX, Net::SSLeay::OP_ALL ()); |
1222 |
|
1223 |
$TLS_CTX |
1224 |
} |
1225 |
} |
1226 |
|
1227 |
=back |
1228 |
|
1229 |
=head1 SUBCLASSING AnyEvent::Handle |
1230 |
|
1231 |
In many cases, you might want to subclass AnyEvent::Handle. |
1232 |
|
1233 |
To make this easier, a given version of AnyEvent::Handle uses these |
1234 |
conventions: |
1235 |
|
1236 |
=over 4 |
1237 |
|
1238 |
=item * all constructor arguments become object members. |
1239 |
|
1240 |
At least initially, when you pass a C<tls>-argument to the constructor it |
1241 |
will end up in C<< $handle->{tls} >>. Those members might be changes or |
1242 |
mutated later on (for example C<tls> will hold the TLS connection object). |
1243 |
|
1244 |
=item * other object member names are prefixed with an C<_>. |
1245 |
|
1246 |
All object members not explicitly documented (internal use) are prefixed |
1247 |
with an underscore character, so the remaining non-C<_>-namespace is free |
1248 |
for use for subclasses. |
1249 |
|
1250 |
=item * all members not documented here and not prefixed with an underscore |
1251 |
are free to use in subclasses. |
1252 |
|
1253 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
1254 |
member variables, but thats just life, at least it is documented. |
1255 |
|
1256 |
=back |
1257 |
|
1258 |
=head1 AUTHOR |
1259 |
|
1260 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
1261 |
|
1262 |
=cut |
1263 |
|
1264 |
1; # End of AnyEvent::Handle |