1 |
package AnyEvent::Handle; |
2 |
|
3 |
no warnings; |
4 |
use strict qw(subs vars); |
5 |
|
6 |
use AnyEvent (); |
7 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
8 |
use Scalar::Util (); |
9 |
use Carp (); |
10 |
use Fcntl (); |
11 |
use Errno qw(EAGAIN EINTR); |
12 |
|
13 |
=head1 NAME |
14 |
|
15 |
AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent |
16 |
|
17 |
=cut |
18 |
|
19 |
our $VERSION = 4.3; |
20 |
|
21 |
=head1 SYNOPSIS |
22 |
|
23 |
use AnyEvent; |
24 |
use AnyEvent::Handle; |
25 |
|
26 |
my $cv = AnyEvent->condvar; |
27 |
|
28 |
my $handle = |
29 |
AnyEvent::Handle->new ( |
30 |
fh => \*STDIN, |
31 |
on_eof => sub { |
32 |
$cv->broadcast; |
33 |
}, |
34 |
); |
35 |
|
36 |
# send some request line |
37 |
$handle->push_write ("getinfo\015\012"); |
38 |
|
39 |
# read the response line |
40 |
$handle->push_read (line => sub { |
41 |
my ($handle, $line) = @_; |
42 |
warn "read line <$line>\n"; |
43 |
$cv->send; |
44 |
}); |
45 |
|
46 |
$cv->recv; |
47 |
|
48 |
=head1 DESCRIPTION |
49 |
|
50 |
This module is a helper module to make it easier to do event-based I/O on |
51 |
filehandles. For utility functions for doing non-blocking connects and accepts |
52 |
on sockets see L<AnyEvent::Util>. |
53 |
|
54 |
The L<AnyEvent::Intro> tutorial contains some well-documented |
55 |
AnyEvent::Handle examples. |
56 |
|
57 |
In the following, when the documentation refers to of "bytes" then this |
58 |
means characters. As sysread and syswrite are used for all I/O, their |
59 |
treatment of characters applies to this module as well. |
60 |
|
61 |
All callbacks will be invoked with the handle object as their first |
62 |
argument. |
63 |
|
64 |
=head2 SIGPIPE is not handled by this module |
65 |
|
66 |
SIGPIPE is not handled by this module, so one of the practical |
67 |
requirements of using it is to ignore SIGPIPE (C<$SIG{PIPE} = |
68 |
'IGNORE'>). At least, this is highly recommend in a networked program: If |
69 |
you use AnyEvent::Handle in a filter program (like sort), exiting on |
70 |
SIGPIPE is probably the right thing to do. |
71 |
|
72 |
=head1 METHODS |
73 |
|
74 |
=over 4 |
75 |
|
76 |
=item B<new (%args)> |
77 |
|
78 |
The constructor supports these arguments (all as key => value pairs). |
79 |
|
80 |
=over 4 |
81 |
|
82 |
=item fh => $filehandle [MANDATORY] |
83 |
|
84 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
85 |
|
86 |
NOTE: The filehandle will be set to non-blocking mode (using |
87 |
C<AnyEvent::Util::fh_nonblocking>) by the constructor and needs to stay in |
88 |
that mode. |
89 |
|
90 |
=item on_eof => $cb->($handle) |
91 |
|
92 |
Set the callback to be called when an end-of-file condition is detected, |
93 |
i.e. in the case of a socket, when the other side has closed the |
94 |
connection cleanly. |
95 |
|
96 |
For sockets, this just means that the other side has stopped sending data, |
97 |
you can still try to write data, and, in fact, one can return from the eof |
98 |
callback and continue writing data, as only the read part has been shut |
99 |
down. |
100 |
|
101 |
While not mandatory, it is I<highly> recommended to set an eof callback, |
102 |
otherwise you might end up with a closed socket while you are still |
103 |
waiting for data. |
104 |
|
105 |
If an EOF condition has been detected but no C<on_eof> callback has been |
106 |
set, then a fatal error will be raised with C<$!> set to <0>. |
107 |
|
108 |
=item on_error => $cb->($handle, $fatal) |
109 |
|
110 |
This is the error callback, which is called when, well, some error |
111 |
occured, such as not being able to resolve the hostname, failure to |
112 |
connect or a read error. |
113 |
|
114 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
115 |
fatal errors the handle object will be shut down and will not be usable |
116 |
(but you are free to look at the current C<< ->rbuf >>). Examples of fatal |
117 |
errors are an EOF condition with active (but unsatisifable) read watchers |
118 |
(C<EPIPE>) or I/O errors. |
119 |
|
120 |
Non-fatal errors can be retried by simply returning, but it is recommended |
121 |
to simply ignore this parameter and instead abondon the handle object |
122 |
when this callback is invoked. Examples of non-fatal errors are timeouts |
123 |
C<ETIMEDOUT>) or badly-formatted data (C<EBADMSG>). |
124 |
|
125 |
On callback entrance, the value of C<$!> contains the operating system |
126 |
error (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT> or C<EBADMSG>). |
127 |
|
128 |
While not mandatory, it is I<highly> recommended to set this callback, as |
129 |
you will not be notified of errors otherwise. The default simply calls |
130 |
C<croak>. |
131 |
|
132 |
=item on_read => $cb->($handle) |
133 |
|
134 |
This sets the default read callback, which is called when data arrives |
135 |
and no read request is in the queue (unlike read queue callbacks, this |
136 |
callback will only be called when at least one octet of data is in the |
137 |
read buffer). |
138 |
|
139 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
140 |
method or access the C<$handle->{rbuf}> member directly. |
141 |
|
142 |
When an EOF condition is detected then AnyEvent::Handle will first try to |
143 |
feed all the remaining data to the queued callbacks and C<on_read> before |
144 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
145 |
error will be raised (with C<$!> set to C<EPIPE>). |
146 |
|
147 |
=item on_drain => $cb->($handle) |
148 |
|
149 |
This sets the callback that is called when the write buffer becomes empty |
150 |
(or when the callback is set and the buffer is empty already). |
151 |
|
152 |
To append to the write buffer, use the C<< ->push_write >> method. |
153 |
|
154 |
This callback is useful when you don't want to put all of your write data |
155 |
into the queue at once, for example, when you want to write the contents |
156 |
of some file to the socket you might not want to read the whole file into |
157 |
memory and push it into the queue, but instead only read more data from |
158 |
the file when the write queue becomes empty. |
159 |
|
160 |
=item timeout => $fractional_seconds |
161 |
|
162 |
If non-zero, then this enables an "inactivity" timeout: whenever this many |
163 |
seconds pass without a successful read or write on the underlying file |
164 |
handle, the C<on_timeout> callback will be invoked (and if that one is |
165 |
missing, a non-fatal C<ETIMEDOUT> error will be raised). |
166 |
|
167 |
Note that timeout processing is also active when you currently do not have |
168 |
any outstanding read or write requests: If you plan to keep the connection |
169 |
idle then you should disable the timout temporarily or ignore the timeout |
170 |
in the C<on_timeout> callback, in which case AnyEvent::Handle will simply |
171 |
restart the timeout. |
172 |
|
173 |
Zero (the default) disables this timeout. |
174 |
|
175 |
=item on_timeout => $cb->($handle) |
176 |
|
177 |
Called whenever the inactivity timeout passes. If you return from this |
178 |
callback, then the timeout will be reset as if some activity had happened, |
179 |
so this condition is not fatal in any way. |
180 |
|
181 |
=item rbuf_max => <bytes> |
182 |
|
183 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
184 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
185 |
avoid some forms of denial-of-service attacks. |
186 |
|
187 |
For example, a server accepting connections from untrusted sources should |
188 |
be configured to accept only so-and-so much data that it cannot act on |
189 |
(for example, when expecting a line, an attacker could send an unlimited |
190 |
amount of data without a callback ever being called as long as the line |
191 |
isn't finished). |
192 |
|
193 |
=item autocork => <boolean> |
194 |
|
195 |
When disabled (the default), then C<push_write> will try to immediately |
196 |
write the data to the handle, if possible. This avoids having to register |
197 |
a write watcher and wait for the next event loop iteration, but can |
198 |
be inefficient if you write multiple small chunks (on the wire, this |
199 |
disadvantage is usually avoided by your kernel's nagle algorithm, see |
200 |
C<no_delay>, but this option can save costly syscalls). |
201 |
|
202 |
When enabled, then writes will always be queued till the next event loop |
203 |
iteration. This is efficient when you do many small writes per iteration, |
204 |
but less efficient when you do a single write only per iteration (or when |
205 |
the write buffer often is full). It also increases write latency. |
206 |
|
207 |
=item no_delay => <boolean> |
208 |
|
209 |
When doing small writes on sockets, your operating system kernel might |
210 |
wait a bit for more data before actually sending it out. This is called |
211 |
the Nagle algorithm, and usually it is beneficial. |
212 |
|
213 |
In some situations you want as low a delay as possible, which can be |
214 |
accomplishd by setting this option to a true value. |
215 |
|
216 |
The default is your opertaing system's default behaviour (most likely |
217 |
enabled), this option explicitly enables or disables it, if possible. |
218 |
|
219 |
=item read_size => <bytes> |
220 |
|
221 |
The default read block size (the amount of bytes this module will |
222 |
try to read during each loop iteration, which affects memory |
223 |
requirements). Default: C<8192>. |
224 |
|
225 |
=item low_water_mark => <bytes> |
226 |
|
227 |
Sets the amount of bytes (default: C<0>) that make up an "empty" write |
228 |
buffer: If the write reaches this size or gets even samller it is |
229 |
considered empty. |
230 |
|
231 |
Sometimes it can be beneficial (for performance reasons) to add data to |
232 |
the write buffer before it is fully drained, but this is a rare case, as |
233 |
the operating system kernel usually buffers data as well, so the default |
234 |
is good in almost all cases. |
235 |
|
236 |
=item linger => <seconds> |
237 |
|
238 |
If non-zero (default: C<3600>), then the destructor of the |
239 |
AnyEvent::Handle object will check whether there is still outstanding |
240 |
write data and will install a watcher that will write this data to the |
241 |
socket. No errors will be reported (this mostly matches how the operating |
242 |
system treats outstanding data at socket close time). |
243 |
|
244 |
This will not work for partial TLS data that could not be encoded |
245 |
yet. This data will be lost. Calling the C<stoptls> method in time might |
246 |
help. |
247 |
|
248 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
249 |
|
250 |
When this parameter is given, it enables TLS (SSL) mode, that means |
251 |
AnyEvent will start a TLS handshake as soon as the conenction has been |
252 |
established and will transparently encrypt/decrypt data afterwards. |
253 |
|
254 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
255 |
automatically when you try to create a TLS handle): this module doesn't |
256 |
have a dependency on that module, so if your module requires it, you have |
257 |
to add the dependency yourself. |
258 |
|
259 |
Unlike TCP, TLS has a server and client side: for the TLS server side, use |
260 |
C<accept>, and for the TLS client side of a connection, use C<connect> |
261 |
mode. |
262 |
|
263 |
You can also provide your own TLS connection object, but you have |
264 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
265 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
266 |
AnyEvent::Handle. |
267 |
|
268 |
See the C<< ->starttls >> method for when need to start TLS negotiation later. |
269 |
|
270 |
=item tls_ctx => $ssl_ctx |
271 |
|
272 |
Use the given C<Net::SSLeay::CTX> object to create the new TLS connection |
273 |
(unless a connection object was specified directly). If this parameter is |
274 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
275 |
|
276 |
=item json => JSON or JSON::XS object |
277 |
|
278 |
This is the json coder object used by the C<json> read and write types. |
279 |
|
280 |
If you don't supply it, then AnyEvent::Handle will create and use a |
281 |
suitable one (on demand), which will write and expect UTF-8 encoded JSON |
282 |
texts. |
283 |
|
284 |
Note that you are responsible to depend on the JSON module if you want to |
285 |
use this functionality, as AnyEvent does not have a dependency itself. |
286 |
|
287 |
=back |
288 |
|
289 |
=cut |
290 |
|
291 |
sub new { |
292 |
my $class = shift; |
293 |
|
294 |
my $self = bless { @_ }, $class; |
295 |
|
296 |
$self->{fh} or Carp::croak "mandatory argument fh is missing"; |
297 |
|
298 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
299 |
|
300 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}) |
301 |
if $self->{tls}; |
302 |
|
303 |
$self->{_activity} = AnyEvent->now; |
304 |
$self->_timeout; |
305 |
|
306 |
$self->on_drain (delete $self->{on_drain}) if exists $self->{on_drain}; |
307 |
$self->no_delay (delete $self->{no_delay}) if exists $self->{no_delay}; |
308 |
|
309 |
$self->start_read |
310 |
if $self->{on_read}; |
311 |
|
312 |
$self |
313 |
} |
314 |
|
315 |
sub _shutdown { |
316 |
my ($self) = @_; |
317 |
|
318 |
delete $self->{_tw}; |
319 |
delete $self->{_rw}; |
320 |
delete $self->{_ww}; |
321 |
delete $self->{fh}; |
322 |
|
323 |
&_freetls; |
324 |
|
325 |
delete $self->{on_read}; |
326 |
delete $self->{_queue}; |
327 |
} |
328 |
|
329 |
sub _error { |
330 |
my ($self, $errno, $fatal) = @_; |
331 |
|
332 |
$self->_shutdown |
333 |
if $fatal; |
334 |
|
335 |
$! = $errno; |
336 |
|
337 |
if ($self->{on_error}) { |
338 |
$self->{on_error}($self, $fatal); |
339 |
} else { |
340 |
Carp::croak "AnyEvent::Handle uncaught error: $!"; |
341 |
} |
342 |
} |
343 |
|
344 |
=item $fh = $handle->fh |
345 |
|
346 |
This method returns the file handle used to create the L<AnyEvent::Handle> object. |
347 |
|
348 |
=cut |
349 |
|
350 |
sub fh { $_[0]{fh} } |
351 |
|
352 |
=item $handle->on_error ($cb) |
353 |
|
354 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
355 |
|
356 |
=cut |
357 |
|
358 |
sub on_error { |
359 |
$_[0]{on_error} = $_[1]; |
360 |
} |
361 |
|
362 |
=item $handle->on_eof ($cb) |
363 |
|
364 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
365 |
|
366 |
=cut |
367 |
|
368 |
sub on_eof { |
369 |
$_[0]{on_eof} = $_[1]; |
370 |
} |
371 |
|
372 |
=item $handle->on_timeout ($cb) |
373 |
|
374 |
Replace the current C<on_timeout> callback, or disables the callback (but |
375 |
not the timeout) if C<$cb> = C<undef>. See the C<timeout> constructor |
376 |
argument and method. |
377 |
|
378 |
=cut |
379 |
|
380 |
sub on_timeout { |
381 |
$_[0]{on_timeout} = $_[1]; |
382 |
} |
383 |
|
384 |
=item $handle->autocork ($boolean) |
385 |
|
386 |
Enables or disables the current autocork behaviour (see C<autocork> |
387 |
constructor argument). |
388 |
|
389 |
=cut |
390 |
|
391 |
=item $handle->no_delay ($boolean) |
392 |
|
393 |
Enables or disables the C<no_delay> setting (see constructor argument of |
394 |
the same name for details). |
395 |
|
396 |
=cut |
397 |
|
398 |
sub no_delay { |
399 |
$_[0]{no_delay} = $_[1]; |
400 |
|
401 |
eval { |
402 |
local $SIG{__DIE__}; |
403 |
setsockopt $_[0]{fh}, &Socket::IPPROTO_TCP, &Socket::TCP_NODELAY, int $_[1]; |
404 |
}; |
405 |
} |
406 |
|
407 |
############################################################################# |
408 |
|
409 |
=item $handle->timeout ($seconds) |
410 |
|
411 |
Configures (or disables) the inactivity timeout. |
412 |
|
413 |
=cut |
414 |
|
415 |
sub timeout { |
416 |
my ($self, $timeout) = @_; |
417 |
|
418 |
$self->{timeout} = $timeout; |
419 |
$self->_timeout; |
420 |
} |
421 |
|
422 |
# reset the timeout watcher, as neccessary |
423 |
# also check for time-outs |
424 |
sub _timeout { |
425 |
my ($self) = @_; |
426 |
|
427 |
if ($self->{timeout}) { |
428 |
my $NOW = AnyEvent->now; |
429 |
|
430 |
# when would the timeout trigger? |
431 |
my $after = $self->{_activity} + $self->{timeout} - $NOW; |
432 |
|
433 |
# now or in the past already? |
434 |
if ($after <= 0) { |
435 |
$self->{_activity} = $NOW; |
436 |
|
437 |
if ($self->{on_timeout}) { |
438 |
$self->{on_timeout}($self); |
439 |
} else { |
440 |
$self->_error (&Errno::ETIMEDOUT); |
441 |
} |
442 |
|
443 |
# callback could have changed timeout value, optimise |
444 |
return unless $self->{timeout}; |
445 |
|
446 |
# calculate new after |
447 |
$after = $self->{timeout}; |
448 |
} |
449 |
|
450 |
Scalar::Util::weaken $self; |
451 |
return unless $self; # ->error could have destroyed $self |
452 |
|
453 |
$self->{_tw} ||= AnyEvent->timer (after => $after, cb => sub { |
454 |
delete $self->{_tw}; |
455 |
$self->_timeout; |
456 |
}); |
457 |
} else { |
458 |
delete $self->{_tw}; |
459 |
} |
460 |
} |
461 |
|
462 |
############################################################################# |
463 |
|
464 |
=back |
465 |
|
466 |
=head2 WRITE QUEUE |
467 |
|
468 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
469 |
for reading. |
470 |
|
471 |
The write queue is very simple: you can add data to its end, and |
472 |
AnyEvent::Handle will automatically try to get rid of it for you. |
473 |
|
474 |
When data could be written and the write buffer is shorter then the low |
475 |
water mark, the C<on_drain> callback will be invoked. |
476 |
|
477 |
=over 4 |
478 |
|
479 |
=item $handle->on_drain ($cb) |
480 |
|
481 |
Sets the C<on_drain> callback or clears it (see the description of |
482 |
C<on_drain> in the constructor). |
483 |
|
484 |
=cut |
485 |
|
486 |
sub on_drain { |
487 |
my ($self, $cb) = @_; |
488 |
|
489 |
$self->{on_drain} = $cb; |
490 |
|
491 |
$cb->($self) |
492 |
if $cb && $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}); |
493 |
} |
494 |
|
495 |
=item $handle->push_write ($data) |
496 |
|
497 |
Queues the given scalar to be written. You can push as much data as you |
498 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
499 |
buffers it independently of the kernel. |
500 |
|
501 |
=cut |
502 |
|
503 |
sub _drain_wbuf { |
504 |
my ($self) = @_; |
505 |
|
506 |
if (!$self->{_ww} && length $self->{wbuf}) { |
507 |
|
508 |
Scalar::Util::weaken $self; |
509 |
|
510 |
my $cb = sub { |
511 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
512 |
|
513 |
if ($len >= 0) { |
514 |
substr $self->{wbuf}, 0, $len, ""; |
515 |
|
516 |
$self->{_activity} = AnyEvent->now; |
517 |
|
518 |
$self->{on_drain}($self) |
519 |
if $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}) |
520 |
&& $self->{on_drain}; |
521 |
|
522 |
delete $self->{_ww} unless length $self->{wbuf}; |
523 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
524 |
$self->_error ($!, 1); |
525 |
} |
526 |
}; |
527 |
|
528 |
# try to write data immediately |
529 |
$cb->() unless $self->{autocork}; |
530 |
|
531 |
# if still data left in wbuf, we need to poll |
532 |
$self->{_ww} = AnyEvent->io (fh => $self->{fh}, poll => "w", cb => $cb) |
533 |
if length $self->{wbuf}; |
534 |
}; |
535 |
} |
536 |
|
537 |
our %WH; |
538 |
|
539 |
sub register_write_type($$) { |
540 |
$WH{$_[0]} = $_[1]; |
541 |
} |
542 |
|
543 |
sub push_write { |
544 |
my $self = shift; |
545 |
|
546 |
if (@_ > 1) { |
547 |
my $type = shift; |
548 |
|
549 |
@_ = ($WH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_write") |
550 |
->($self, @_); |
551 |
} |
552 |
|
553 |
if ($self->{tls}) { |
554 |
$self->{_tls_wbuf} .= $_[0]; |
555 |
&_dotls ($self); |
556 |
} else { |
557 |
$self->{wbuf} .= $_[0]; |
558 |
$self->_drain_wbuf; |
559 |
} |
560 |
} |
561 |
|
562 |
=item $handle->push_write (type => @args) |
563 |
|
564 |
Instead of formatting your data yourself, you can also let this module do |
565 |
the job by specifying a type and type-specific arguments. |
566 |
|
567 |
Predefined types are (if you have ideas for additional types, feel free to |
568 |
drop by and tell us): |
569 |
|
570 |
=over 4 |
571 |
|
572 |
=item netstring => $string |
573 |
|
574 |
Formats the given value as netstring |
575 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
576 |
|
577 |
=cut |
578 |
|
579 |
register_write_type netstring => sub { |
580 |
my ($self, $string) = @_; |
581 |
|
582 |
(length $string) . ":$string," |
583 |
}; |
584 |
|
585 |
=item packstring => $format, $data |
586 |
|
587 |
An octet string prefixed with an encoded length. The encoding C<$format> |
588 |
uses the same format as a Perl C<pack> format, but must specify a single |
589 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
590 |
optional C<!>, C<< < >> or C<< > >> modifier). |
591 |
|
592 |
=cut |
593 |
|
594 |
register_write_type packstring => sub { |
595 |
my ($self, $format, $string) = @_; |
596 |
|
597 |
pack "$format/a*", $string |
598 |
}; |
599 |
|
600 |
=item json => $array_or_hashref |
601 |
|
602 |
Encodes the given hash or array reference into a JSON object. Unless you |
603 |
provide your own JSON object, this means it will be encoded to JSON text |
604 |
in UTF-8. |
605 |
|
606 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
607 |
one end of a handle and read them at the other end without using any |
608 |
additional framing. |
609 |
|
610 |
The generated JSON text is guaranteed not to contain any newlines: While |
611 |
this module doesn't need delimiters after or between JSON texts to be |
612 |
able to read them, many other languages depend on that. |
613 |
|
614 |
A simple RPC protocol that interoperates easily with others is to send |
615 |
JSON arrays (or objects, although arrays are usually the better choice as |
616 |
they mimic how function argument passing works) and a newline after each |
617 |
JSON text: |
618 |
|
619 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
620 |
$handle->push_write ("\012"); |
621 |
|
622 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
623 |
rely on the fact that the newline will be skipped as leading whitespace: |
624 |
|
625 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
626 |
|
627 |
Other languages could read single lines terminated by a newline and pass |
628 |
this line into their JSON decoder of choice. |
629 |
|
630 |
=cut |
631 |
|
632 |
register_write_type json => sub { |
633 |
my ($self, $ref) = @_; |
634 |
|
635 |
require JSON; |
636 |
|
637 |
$self->{json} ? $self->{json}->encode ($ref) |
638 |
: JSON::encode_json ($ref) |
639 |
}; |
640 |
|
641 |
=item storable => $reference |
642 |
|
643 |
Freezes the given reference using L<Storable> and writes it to the |
644 |
handle. Uses the C<nfreeze> format. |
645 |
|
646 |
=cut |
647 |
|
648 |
register_write_type storable => sub { |
649 |
my ($self, $ref) = @_; |
650 |
|
651 |
require Storable; |
652 |
|
653 |
pack "w/a*", Storable::nfreeze ($ref) |
654 |
}; |
655 |
|
656 |
=back |
657 |
|
658 |
=item AnyEvent::Handle::register_write_type type => $coderef->($handle, @args) |
659 |
|
660 |
This function (not method) lets you add your own types to C<push_write>. |
661 |
Whenever the given C<type> is used, C<push_write> will invoke the code |
662 |
reference with the handle object and the remaining arguments. |
663 |
|
664 |
The code reference is supposed to return a single octet string that will |
665 |
be appended to the write buffer. |
666 |
|
667 |
Note that this is a function, and all types registered this way will be |
668 |
global, so try to use unique names. |
669 |
|
670 |
=cut |
671 |
|
672 |
############################################################################# |
673 |
|
674 |
=back |
675 |
|
676 |
=head2 READ QUEUE |
677 |
|
678 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
679 |
for reading. |
680 |
|
681 |
The read queue is more complex than the write queue. It can be used in two |
682 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
683 |
a queue. |
684 |
|
685 |
In the simple case, you just install an C<on_read> callback and whenever |
686 |
new data arrives, it will be called. You can then remove some data (if |
687 |
enough is there) from the read buffer (C<< $handle->rbuf >>). Or you cna |
688 |
leave the data there if you want to accumulate more (e.g. when only a |
689 |
partial message has been received so far). |
690 |
|
691 |
In the more complex case, you want to queue multiple callbacks. In this |
692 |
case, AnyEvent::Handle will call the first queued callback each time new |
693 |
data arrives (also the first time it is queued) and removes it when it has |
694 |
done its job (see C<push_read>, below). |
695 |
|
696 |
This way you can, for example, push three line-reads, followed by reading |
697 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
698 |
|
699 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
700 |
the specified number of bytes which give an XML datagram. |
701 |
|
702 |
# in the default state, expect some header bytes |
703 |
$handle->on_read (sub { |
704 |
# some data is here, now queue the length-header-read (4 octets) |
705 |
shift->unshift_read (chunk => 4, sub { |
706 |
# header arrived, decode |
707 |
my $len = unpack "N", $_[1]; |
708 |
|
709 |
# now read the payload |
710 |
shift->unshift_read (chunk => $len, sub { |
711 |
my $xml = $_[1]; |
712 |
# handle xml |
713 |
}); |
714 |
}); |
715 |
}); |
716 |
|
717 |
Example 2: Implement a client for a protocol that replies either with "OK" |
718 |
and another line or "ERROR" for the first request that is sent, and 64 |
719 |
bytes for the second request. Due to the availability of a queue, we can |
720 |
just pipeline sending both requests and manipulate the queue as necessary |
721 |
in the callbacks. |
722 |
|
723 |
When the first callback is called and sees an "OK" response, it will |
724 |
C<unshift> another line-read. This line-read will be queued I<before> the |
725 |
64-byte chunk callback. |
726 |
|
727 |
# request one, returns either "OK + extra line" or "ERROR" |
728 |
$handle->push_write ("request 1\015\012"); |
729 |
|
730 |
# we expect "ERROR" or "OK" as response, so push a line read |
731 |
$handle->push_read (line => sub { |
732 |
# if we got an "OK", we have to _prepend_ another line, |
733 |
# so it will be read before the second request reads its 64 bytes |
734 |
# which are already in the queue when this callback is called |
735 |
# we don't do this in case we got an error |
736 |
if ($_[1] eq "OK") { |
737 |
$_[0]->unshift_read (line => sub { |
738 |
my $response = $_[1]; |
739 |
... |
740 |
}); |
741 |
} |
742 |
}); |
743 |
|
744 |
# request two, simply returns 64 octets |
745 |
$handle->push_write ("request 2\015\012"); |
746 |
|
747 |
# simply read 64 bytes, always |
748 |
$handle->push_read (chunk => 64, sub { |
749 |
my $response = $_[1]; |
750 |
... |
751 |
}); |
752 |
|
753 |
=over 4 |
754 |
|
755 |
=cut |
756 |
|
757 |
sub _drain_rbuf { |
758 |
my ($self) = @_; |
759 |
|
760 |
local $self->{_in_drain} = 1; |
761 |
|
762 |
if ( |
763 |
defined $self->{rbuf_max} |
764 |
&& $self->{rbuf_max} < length $self->{rbuf} |
765 |
) { |
766 |
$self->_error (&Errno::ENOSPC, 1), return; |
767 |
} |
768 |
|
769 |
while () { |
770 |
my $len = length $self->{rbuf}; |
771 |
|
772 |
if (my $cb = shift @{ $self->{_queue} }) { |
773 |
unless ($cb->($self)) { |
774 |
if ($self->{_eof}) { |
775 |
# no progress can be made (not enough data and no data forthcoming) |
776 |
$self->_error (&Errno::EPIPE, 1), return; |
777 |
} |
778 |
|
779 |
unshift @{ $self->{_queue} }, $cb; |
780 |
last; |
781 |
} |
782 |
} elsif ($self->{on_read}) { |
783 |
last unless $len; |
784 |
|
785 |
$self->{on_read}($self); |
786 |
|
787 |
if ( |
788 |
$len == length $self->{rbuf} # if no data has been consumed |
789 |
&& !@{ $self->{_queue} } # and the queue is still empty |
790 |
&& $self->{on_read} # but we still have on_read |
791 |
) { |
792 |
# no further data will arrive |
793 |
# so no progress can be made |
794 |
$self->_error (&Errno::EPIPE, 1), return |
795 |
if $self->{_eof}; |
796 |
|
797 |
last; # more data might arrive |
798 |
} |
799 |
} else { |
800 |
# read side becomes idle |
801 |
delete $self->{_rw} unless $self->{tls}; |
802 |
last; |
803 |
} |
804 |
} |
805 |
|
806 |
if ($self->{_eof}) { |
807 |
if ($self->{on_eof}) { |
808 |
$self->{on_eof}($self) |
809 |
} else { |
810 |
$self->_error (0, 1); |
811 |
} |
812 |
} |
813 |
|
814 |
# may need to restart read watcher |
815 |
unless ($self->{_rw}) { |
816 |
$self->start_read |
817 |
if $self->{on_read} || @{ $self->{_queue} }; |
818 |
} |
819 |
} |
820 |
|
821 |
=item $handle->on_read ($cb) |
822 |
|
823 |
This replaces the currently set C<on_read> callback, or clears it (when |
824 |
the new callback is C<undef>). See the description of C<on_read> in the |
825 |
constructor. |
826 |
|
827 |
=cut |
828 |
|
829 |
sub on_read { |
830 |
my ($self, $cb) = @_; |
831 |
|
832 |
$self->{on_read} = $cb; |
833 |
$self->_drain_rbuf if $cb && !$self->{_in_drain}; |
834 |
} |
835 |
|
836 |
=item $handle->rbuf |
837 |
|
838 |
Returns the read buffer (as a modifiable lvalue). |
839 |
|
840 |
You can access the read buffer directly as the C<< ->{rbuf} >> member, if |
841 |
you want. |
842 |
|
843 |
NOTE: The read buffer should only be used or modified if the C<on_read>, |
844 |
C<push_read> or C<unshift_read> methods are used. The other read methods |
845 |
automatically manage the read buffer. |
846 |
|
847 |
=cut |
848 |
|
849 |
sub rbuf : lvalue { |
850 |
$_[0]{rbuf} |
851 |
} |
852 |
|
853 |
=item $handle->push_read ($cb) |
854 |
|
855 |
=item $handle->unshift_read ($cb) |
856 |
|
857 |
Append the given callback to the end of the queue (C<push_read>) or |
858 |
prepend it (C<unshift_read>). |
859 |
|
860 |
The callback is called each time some additional read data arrives. |
861 |
|
862 |
It must check whether enough data is in the read buffer already. |
863 |
|
864 |
If not enough data is available, it must return the empty list or a false |
865 |
value, in which case it will be called repeatedly until enough data is |
866 |
available (or an error condition is detected). |
867 |
|
868 |
If enough data was available, then the callback must remove all data it is |
869 |
interested in (which can be none at all) and return a true value. After returning |
870 |
true, it will be removed from the queue. |
871 |
|
872 |
=cut |
873 |
|
874 |
our %RH; |
875 |
|
876 |
sub register_read_type($$) { |
877 |
$RH{$_[0]} = $_[1]; |
878 |
} |
879 |
|
880 |
sub push_read { |
881 |
my $self = shift; |
882 |
my $cb = pop; |
883 |
|
884 |
if (@_) { |
885 |
my $type = shift; |
886 |
|
887 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_read") |
888 |
->($self, $cb, @_); |
889 |
} |
890 |
|
891 |
push @{ $self->{_queue} }, $cb; |
892 |
$self->_drain_rbuf unless $self->{_in_drain}; |
893 |
} |
894 |
|
895 |
sub unshift_read { |
896 |
my $self = shift; |
897 |
my $cb = pop; |
898 |
|
899 |
if (@_) { |
900 |
my $type = shift; |
901 |
|
902 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::unshift_read") |
903 |
->($self, $cb, @_); |
904 |
} |
905 |
|
906 |
|
907 |
unshift @{ $self->{_queue} }, $cb; |
908 |
$self->_drain_rbuf unless $self->{_in_drain}; |
909 |
} |
910 |
|
911 |
=item $handle->push_read (type => @args, $cb) |
912 |
|
913 |
=item $handle->unshift_read (type => @args, $cb) |
914 |
|
915 |
Instead of providing a callback that parses the data itself you can chose |
916 |
between a number of predefined parsing formats, for chunks of data, lines |
917 |
etc. |
918 |
|
919 |
Predefined types are (if you have ideas for additional types, feel free to |
920 |
drop by and tell us): |
921 |
|
922 |
=over 4 |
923 |
|
924 |
=item chunk => $octets, $cb->($handle, $data) |
925 |
|
926 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
927 |
data read to the callback. The callback will never be called with less |
928 |
data. |
929 |
|
930 |
Example: read 2 bytes. |
931 |
|
932 |
$handle->push_read (chunk => 2, sub { |
933 |
warn "yay ", unpack "H*", $_[1]; |
934 |
}); |
935 |
|
936 |
=cut |
937 |
|
938 |
register_read_type chunk => sub { |
939 |
my ($self, $cb, $len) = @_; |
940 |
|
941 |
sub { |
942 |
$len <= length $_[0]{rbuf} or return; |
943 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
944 |
1 |
945 |
} |
946 |
}; |
947 |
|
948 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
949 |
|
950 |
The callback will be called only once a full line (including the end of |
951 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
952 |
marker) will be passed to the callback as second argument (C<$line>), and |
953 |
the end of line marker as the third argument (C<$eol>). |
954 |
|
955 |
The end of line marker, C<$eol>, can be either a string, in which case it |
956 |
will be interpreted as a fixed record end marker, or it can be a regex |
957 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
958 |
regular expression. |
959 |
|
960 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
961 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
962 |
protocols). |
963 |
|
964 |
Partial lines at the end of the stream will never be returned, as they are |
965 |
not marked by the end of line marker. |
966 |
|
967 |
=cut |
968 |
|
969 |
register_read_type line => sub { |
970 |
my ($self, $cb, $eol) = @_; |
971 |
|
972 |
if (@_ < 3) { |
973 |
# this is more than twice as fast as the generic code below |
974 |
sub { |
975 |
$_[0]{rbuf} =~ s/^([^\015\012]*)(\015?\012)// or return; |
976 |
|
977 |
$cb->($_[0], $1, $2); |
978 |
1 |
979 |
} |
980 |
} else { |
981 |
$eol = quotemeta $eol unless ref $eol; |
982 |
$eol = qr|^(.*?)($eol)|s; |
983 |
|
984 |
sub { |
985 |
$_[0]{rbuf} =~ s/$eol// or return; |
986 |
|
987 |
$cb->($_[0], $1, $2); |
988 |
1 |
989 |
} |
990 |
} |
991 |
}; |
992 |
|
993 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
994 |
|
995 |
Makes a regex match against the regex object C<$accept> and returns |
996 |
everything up to and including the match. |
997 |
|
998 |
Example: read a single line terminated by '\n'. |
999 |
|
1000 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
1001 |
|
1002 |
If C<$reject> is given and not undef, then it determines when the data is |
1003 |
to be rejected: it is matched against the data when the C<$accept> regex |
1004 |
does not match and generates an C<EBADMSG> error when it matches. This is |
1005 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
1006 |
receive buffer overflow). |
1007 |
|
1008 |
Example: expect a single decimal number followed by whitespace, reject |
1009 |
anything else (not the use of an anchor). |
1010 |
|
1011 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
1012 |
|
1013 |
If C<$skip> is given and not C<undef>, then it will be matched against |
1014 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
1015 |
and everything preceding and including the match will be accepted |
1016 |
unconditionally. This is useful to skip large amounts of data that you |
1017 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
1018 |
have to start matching from the beginning. This is purely an optimisation |
1019 |
and is usually worth only when you expect more than a few kilobytes. |
1020 |
|
1021 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
1022 |
expect the header to be very large (it isn't in practise, but...), we use |
1023 |
a skip regex to skip initial portions. The skip regex is tricky in that |
1024 |
it only accepts something not ending in either \015 or \012, as these are |
1025 |
required for the accept regex. |
1026 |
|
1027 |
$handle->push_read (regex => |
1028 |
qr<\015\012\015\012>, |
1029 |
undef, # no reject |
1030 |
qr<^.*[^\015\012]>, |
1031 |
sub { ... }); |
1032 |
|
1033 |
=cut |
1034 |
|
1035 |
register_read_type regex => sub { |
1036 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
1037 |
|
1038 |
my $data; |
1039 |
my $rbuf = \$self->{rbuf}; |
1040 |
|
1041 |
sub { |
1042 |
# accept |
1043 |
if ($$rbuf =~ $accept) { |
1044 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1045 |
$cb->($self, $data); |
1046 |
return 1; |
1047 |
} |
1048 |
|
1049 |
# reject |
1050 |
if ($reject && $$rbuf =~ $reject) { |
1051 |
$self->_error (&Errno::EBADMSG); |
1052 |
} |
1053 |
|
1054 |
# skip |
1055 |
if ($skip && $$rbuf =~ $skip) { |
1056 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1057 |
} |
1058 |
|
1059 |
() |
1060 |
} |
1061 |
}; |
1062 |
|
1063 |
=item netstring => $cb->($handle, $string) |
1064 |
|
1065 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
1066 |
|
1067 |
Throws an error with C<$!> set to EBADMSG on format violations. |
1068 |
|
1069 |
=cut |
1070 |
|
1071 |
register_read_type netstring => sub { |
1072 |
my ($self, $cb) = @_; |
1073 |
|
1074 |
sub { |
1075 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
1076 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
1077 |
$self->_error (&Errno::EBADMSG); |
1078 |
} |
1079 |
return; |
1080 |
} |
1081 |
|
1082 |
my $len = $1; |
1083 |
|
1084 |
$self->unshift_read (chunk => $len, sub { |
1085 |
my $string = $_[1]; |
1086 |
$_[0]->unshift_read (chunk => 1, sub { |
1087 |
if ($_[1] eq ",") { |
1088 |
$cb->($_[0], $string); |
1089 |
} else { |
1090 |
$self->_error (&Errno::EBADMSG); |
1091 |
} |
1092 |
}); |
1093 |
}); |
1094 |
|
1095 |
1 |
1096 |
} |
1097 |
}; |
1098 |
|
1099 |
=item packstring => $format, $cb->($handle, $string) |
1100 |
|
1101 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1102 |
uses the same format as a Perl C<pack> format, but must specify a single |
1103 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1104 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1105 |
|
1106 |
For example, DNS over TCP uses a prefix of C<n> (2 octet network order), |
1107 |
EPP uses a prefix of C<N> (4 octtes). |
1108 |
|
1109 |
Example: read a block of data prefixed by its length in BER-encoded |
1110 |
format (very efficient). |
1111 |
|
1112 |
$handle->push_read (packstring => "w", sub { |
1113 |
my ($handle, $data) = @_; |
1114 |
}); |
1115 |
|
1116 |
=cut |
1117 |
|
1118 |
register_read_type packstring => sub { |
1119 |
my ($self, $cb, $format) = @_; |
1120 |
|
1121 |
sub { |
1122 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1123 |
defined (my $len = eval { unpack $format, $_[0]{rbuf} }) |
1124 |
or return; |
1125 |
|
1126 |
$format = length pack $format, $len; |
1127 |
|
1128 |
# bypass unshift if we already have the remaining chunk |
1129 |
if ($format + $len <= length $_[0]{rbuf}) { |
1130 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1131 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1132 |
$cb->($_[0], $data); |
1133 |
} else { |
1134 |
# remove prefix |
1135 |
substr $_[0]{rbuf}, 0, $format, ""; |
1136 |
|
1137 |
# read remaining chunk |
1138 |
$_[0]->unshift_read (chunk => $len, $cb); |
1139 |
} |
1140 |
|
1141 |
1 |
1142 |
} |
1143 |
}; |
1144 |
|
1145 |
=item json => $cb->($handle, $hash_or_arrayref) |
1146 |
|
1147 |
Reads a JSON object or array, decodes it and passes it to the callback. |
1148 |
|
1149 |
If a C<json> object was passed to the constructor, then that will be used |
1150 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1151 |
|
1152 |
This read type uses the incremental parser available with JSON version |
1153 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1154 |
dependency on your own: this module will load the JSON module, but |
1155 |
AnyEvent does not depend on it itself. |
1156 |
|
1157 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1158 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1159 |
the C<json> write type description, above, for an actual example. |
1160 |
|
1161 |
=cut |
1162 |
|
1163 |
register_read_type json => sub { |
1164 |
my ($self, $cb) = @_; |
1165 |
|
1166 |
require JSON; |
1167 |
|
1168 |
my $data; |
1169 |
my $rbuf = \$self->{rbuf}; |
1170 |
|
1171 |
my $json = $self->{json} ||= JSON->new->utf8; |
1172 |
|
1173 |
sub { |
1174 |
my $ref = $json->incr_parse ($self->{rbuf}); |
1175 |
|
1176 |
if ($ref) { |
1177 |
$self->{rbuf} = $json->incr_text; |
1178 |
$json->incr_text = ""; |
1179 |
$cb->($self, $ref); |
1180 |
|
1181 |
1 |
1182 |
} else { |
1183 |
$self->{rbuf} = ""; |
1184 |
() |
1185 |
} |
1186 |
} |
1187 |
}; |
1188 |
|
1189 |
=item storable => $cb->($handle, $ref) |
1190 |
|
1191 |
Deserialises a L<Storable> frozen representation as written by the |
1192 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1193 |
data). |
1194 |
|
1195 |
Raises C<EBADMSG> error if the data could not be decoded. |
1196 |
|
1197 |
=cut |
1198 |
|
1199 |
register_read_type storable => sub { |
1200 |
my ($self, $cb) = @_; |
1201 |
|
1202 |
require Storable; |
1203 |
|
1204 |
sub { |
1205 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1206 |
defined (my $len = eval { unpack "w", $_[0]{rbuf} }) |
1207 |
or return; |
1208 |
|
1209 |
my $format = length pack "w", $len; |
1210 |
|
1211 |
# bypass unshift if we already have the remaining chunk |
1212 |
if ($format + $len <= length $_[0]{rbuf}) { |
1213 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1214 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1215 |
$cb->($_[0], Storable::thaw ($data)); |
1216 |
} else { |
1217 |
# remove prefix |
1218 |
substr $_[0]{rbuf}, 0, $format, ""; |
1219 |
|
1220 |
# read remaining chunk |
1221 |
$_[0]->unshift_read (chunk => $len, sub { |
1222 |
if (my $ref = eval { Storable::thaw ($_[1]) }) { |
1223 |
$cb->($_[0], $ref); |
1224 |
} else { |
1225 |
$self->_error (&Errno::EBADMSG); |
1226 |
} |
1227 |
}); |
1228 |
} |
1229 |
|
1230 |
1 |
1231 |
} |
1232 |
}; |
1233 |
|
1234 |
=back |
1235 |
|
1236 |
=item AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args) |
1237 |
|
1238 |
This function (not method) lets you add your own types to C<push_read>. |
1239 |
|
1240 |
Whenever the given C<type> is used, C<push_read> will invoke the code |
1241 |
reference with the handle object, the callback and the remaining |
1242 |
arguments. |
1243 |
|
1244 |
The code reference is supposed to return a callback (usually a closure) |
1245 |
that works as a plain read callback (see C<< ->push_read ($cb) >>). |
1246 |
|
1247 |
It should invoke the passed callback when it is done reading (remember to |
1248 |
pass C<$handle> as first argument as all other callbacks do that). |
1249 |
|
1250 |
Note that this is a function, and all types registered this way will be |
1251 |
global, so try to use unique names. |
1252 |
|
1253 |
For examples, see the source of this module (F<perldoc -m AnyEvent::Handle>, |
1254 |
search for C<register_read_type>)). |
1255 |
|
1256 |
=item $handle->stop_read |
1257 |
|
1258 |
=item $handle->start_read |
1259 |
|
1260 |
In rare cases you actually do not want to read anything from the |
1261 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1262 |
any queued callbacks will be executed then. To start reading again, call |
1263 |
C<start_read>. |
1264 |
|
1265 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1266 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1267 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1268 |
there are any read requests in the queue. |
1269 |
|
1270 |
These methods will have no effect when in TLS mode (as TLS doesn't support |
1271 |
half-duplex connections). |
1272 |
|
1273 |
=cut |
1274 |
|
1275 |
sub stop_read { |
1276 |
my ($self) = @_; |
1277 |
|
1278 |
delete $self->{_rw} unless $self->{tls}; |
1279 |
} |
1280 |
|
1281 |
sub start_read { |
1282 |
my ($self) = @_; |
1283 |
|
1284 |
unless ($self->{_rw} || $self->{_eof}) { |
1285 |
Scalar::Util::weaken $self; |
1286 |
|
1287 |
$self->{_rw} = AnyEvent->io (fh => $self->{fh}, poll => "r", cb => sub { |
1288 |
my $rbuf = \($self->{tls} ? my $buf : $self->{rbuf}); |
1289 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size} || 8192, length $$rbuf; |
1290 |
|
1291 |
if ($len > 0) { |
1292 |
$self->{_activity} = AnyEvent->now; |
1293 |
|
1294 |
if ($self->{tls}) { |
1295 |
Net::SSLeay::BIO_write ($self->{_rbio}, $$rbuf); |
1296 |
&_dotls ($self); |
1297 |
} else { |
1298 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1299 |
} |
1300 |
|
1301 |
} elsif (defined $len) { |
1302 |
delete $self->{_rw}; |
1303 |
$self->{_eof} = 1; |
1304 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1305 |
|
1306 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1307 |
return $self->_error ($!, 1); |
1308 |
} |
1309 |
}); |
1310 |
} |
1311 |
} |
1312 |
|
1313 |
sub _dotls { |
1314 |
my ($self) = @_; |
1315 |
|
1316 |
my $buf; |
1317 |
|
1318 |
if (length $self->{_tls_wbuf}) { |
1319 |
while ((my $len = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1320 |
substr $self->{_tls_wbuf}, 0, $len, ""; |
1321 |
} |
1322 |
} |
1323 |
|
1324 |
while (defined ($buf = Net::SSLeay::read ($self->{tls}))) { |
1325 |
unless (length $buf) { |
1326 |
# let's treat SSL-eof as we treat normal EOF |
1327 |
delete $self->{_rw}; |
1328 |
$self->{_eof} = 1; |
1329 |
&_freetls; |
1330 |
} |
1331 |
|
1332 |
$self->{rbuf} .= $buf; |
1333 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1334 |
$self->{tls} or return; # tls session might have gone away in callback |
1335 |
} |
1336 |
|
1337 |
my $err = Net::SSLeay::get_error ($self->{tls}, -1); |
1338 |
|
1339 |
if ($err!= Net::SSLeay::ERROR_WANT_READ ()) { |
1340 |
if ($err == Net::SSLeay::ERROR_SYSCALL ()) { |
1341 |
return $self->_error ($!, 1); |
1342 |
} elsif ($err == Net::SSLeay::ERROR_SSL ()) { |
1343 |
return $self->_error (&Errno::EIO, 1); |
1344 |
} |
1345 |
|
1346 |
# all others are fine for our purposes |
1347 |
} |
1348 |
|
1349 |
while (length ($buf = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1350 |
$self->{wbuf} .= $buf; |
1351 |
$self->_drain_wbuf; |
1352 |
} |
1353 |
} |
1354 |
|
1355 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1356 |
|
1357 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1358 |
object is created, you can also do that at a later time by calling |
1359 |
C<starttls>. |
1360 |
|
1361 |
The first argument is the same as the C<tls> constructor argument (either |
1362 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1363 |
|
1364 |
The second argument is the optional C<Net::SSLeay::CTX> object that is |
1365 |
used when AnyEvent::Handle has to create its own TLS connection object. |
1366 |
|
1367 |
The TLS connection object will end up in C<< $handle->{tls} >> after this |
1368 |
call and can be used or changed to your liking. Note that the handshake |
1369 |
might have already started when this function returns. |
1370 |
|
1371 |
If it an error to start a TLS handshake more than once per |
1372 |
AnyEvent::Handle object (this is due to bugs in OpenSSL). |
1373 |
|
1374 |
=cut |
1375 |
|
1376 |
sub starttls { |
1377 |
my ($self, $ssl, $ctx) = @_; |
1378 |
|
1379 |
require Net::SSLeay; |
1380 |
|
1381 |
Carp::croak "it is an error to call starttls more than once on an Anyevent::Handle object" |
1382 |
if $self->{tls}; |
1383 |
|
1384 |
if ($ssl eq "accept") { |
1385 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1386 |
Net::SSLeay::set_accept_state ($ssl); |
1387 |
} elsif ($ssl eq "connect") { |
1388 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1389 |
Net::SSLeay::set_connect_state ($ssl); |
1390 |
} |
1391 |
|
1392 |
$self->{tls} = $ssl; |
1393 |
|
1394 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1395 |
# but the openssl maintainers basically said: "trust us, it just works". |
1396 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1397 |
# and mismaintained ssleay-module doesn't even offer them). |
1398 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1399 |
# |
1400 |
# in short: this is a mess. |
1401 |
# |
1402 |
# note that we do not try to keep the length constant between writes as we are required to do. |
1403 |
# we assume that most (but not all) of this insanity only applies to non-blocking cases, |
1404 |
# and we drive openssl fully in blocking mode here. Or maybe we don't - openssl seems to |
1405 |
# have identity issues in that area. |
1406 |
Net::SSLeay::CTX_set_mode ($self->{tls}, |
1407 |
(eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1408 |
| (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1409 |
|
1410 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1411 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1412 |
|
1413 |
Net::SSLeay::set_bio ($ssl, $self->{_rbio}, $self->{_wbio}); |
1414 |
|
1415 |
&_dotls; # need to trigger the initial handshake |
1416 |
$self->start_read; # make sure we actually do read |
1417 |
} |
1418 |
|
1419 |
=item $handle->stoptls |
1420 |
|
1421 |
Shuts down the SSL connection - this makes a proper EOF handshake by |
1422 |
sending a close notify to the other side, but since OpenSSL doesn't |
1423 |
support non-blocking shut downs, it is not possible to re-use the stream |
1424 |
afterwards. |
1425 |
|
1426 |
=cut |
1427 |
|
1428 |
sub stoptls { |
1429 |
my ($self) = @_; |
1430 |
|
1431 |
if ($self->{tls}) { |
1432 |
Net::SSLeay::shutdown ($self->{tls}); |
1433 |
|
1434 |
&_dotls; |
1435 |
|
1436 |
# we don't give a shit. no, we do, but we can't. no... |
1437 |
# we, we... have to use openssl :/ |
1438 |
&_freetls; |
1439 |
} |
1440 |
} |
1441 |
|
1442 |
sub _freetls { |
1443 |
my ($self) = @_; |
1444 |
|
1445 |
return unless $self->{tls}; |
1446 |
|
1447 |
Net::SSLeay::free (delete $self->{tls}); |
1448 |
|
1449 |
delete @$self{qw(_rbio _wbio _tls_wbuf)}; |
1450 |
} |
1451 |
|
1452 |
sub DESTROY { |
1453 |
my $self = shift; |
1454 |
|
1455 |
&_freetls; |
1456 |
|
1457 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
1458 |
|
1459 |
if ($linger && length $self->{wbuf}) { |
1460 |
my $fh = delete $self->{fh}; |
1461 |
my $wbuf = delete $self->{wbuf}; |
1462 |
|
1463 |
my @linger; |
1464 |
|
1465 |
push @linger, AnyEvent->io (fh => $fh, poll => "w", cb => sub { |
1466 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
1467 |
|
1468 |
if ($len > 0) { |
1469 |
substr $wbuf, 0, $len, ""; |
1470 |
} else { |
1471 |
@linger = (); # end |
1472 |
} |
1473 |
}); |
1474 |
push @linger, AnyEvent->timer (after => $linger, cb => sub { |
1475 |
@linger = (); |
1476 |
}); |
1477 |
} |
1478 |
} |
1479 |
|
1480 |
=item AnyEvent::Handle::TLS_CTX |
1481 |
|
1482 |
This function creates and returns the Net::SSLeay::CTX object used by |
1483 |
default for TLS mode. |
1484 |
|
1485 |
The context is created like this: |
1486 |
|
1487 |
Net::SSLeay::load_error_strings; |
1488 |
Net::SSLeay::SSLeay_add_ssl_algorithms; |
1489 |
Net::SSLeay::randomize; |
1490 |
|
1491 |
my $CTX = Net::SSLeay::CTX_new; |
1492 |
|
1493 |
Net::SSLeay::CTX_set_options $CTX, Net::SSLeay::OP_ALL |
1494 |
|
1495 |
=cut |
1496 |
|
1497 |
our $TLS_CTX; |
1498 |
|
1499 |
sub TLS_CTX() { |
1500 |
$TLS_CTX || do { |
1501 |
require Net::SSLeay; |
1502 |
|
1503 |
Net::SSLeay::load_error_strings (); |
1504 |
Net::SSLeay::SSLeay_add_ssl_algorithms (); |
1505 |
Net::SSLeay::randomize (); |
1506 |
|
1507 |
$TLS_CTX = Net::SSLeay::CTX_new (); |
1508 |
|
1509 |
Net::SSLeay::CTX_set_options ($TLS_CTX, Net::SSLeay::OP_ALL ()); |
1510 |
|
1511 |
$TLS_CTX |
1512 |
} |
1513 |
} |
1514 |
|
1515 |
=back |
1516 |
|
1517 |
|
1518 |
=head1 NONFREQUENTLY ASKED QUESTIONS |
1519 |
|
1520 |
=over 4 |
1521 |
|
1522 |
=item How do I read data until the other side closes the connection? |
1523 |
|
1524 |
If you just want to read your data into a perl scalar, the easiest way |
1525 |
to achieve this is by setting an C<on_read> callback that does nothing, |
1526 |
clearing the C<on_eof> callback and in the C<on_error> callback, the data |
1527 |
will be in C<$_[0]{rbuf}>: |
1528 |
|
1529 |
$handle->on_read (sub { }); |
1530 |
$handle->on_eof (undef); |
1531 |
$handle->on_error (sub { |
1532 |
my $data = delete $_[0]{rbuf}; |
1533 |
undef $handle; |
1534 |
}); |
1535 |
|
1536 |
The reason to use C<on_error> is that TCP connections, due to latencies |
1537 |
and packets loss, might get closed quite violently with an error, when in |
1538 |
fact, all data has been received. |
1539 |
|
1540 |
It is usually better to use acknowledgements when transfering data, |
1541 |
to make sure the other side hasn't just died and you got the data |
1542 |
intact. This is also one reason why so many internet protocols have an |
1543 |
explicit QUIT command. |
1544 |
|
1545 |
|
1546 |
=item I don't want to destroy the handle too early - how do I wait until |
1547 |
all data has been written? |
1548 |
|
1549 |
After writing your last bits of data, set the C<on_drain> callback |
1550 |
and destroy the handle in there - with the default setting of |
1551 |
C<low_water_mark> this will be called precisely when all data has been |
1552 |
written to the socket: |
1553 |
|
1554 |
$handle->push_write (...); |
1555 |
$handle->on_drain (sub { |
1556 |
warn "all data submitted to the kernel\n"; |
1557 |
undef $handle; |
1558 |
}); |
1559 |
|
1560 |
=back |
1561 |
|
1562 |
|
1563 |
=head1 SUBCLASSING AnyEvent::Handle |
1564 |
|
1565 |
In many cases, you might want to subclass AnyEvent::Handle. |
1566 |
|
1567 |
To make this easier, a given version of AnyEvent::Handle uses these |
1568 |
conventions: |
1569 |
|
1570 |
=over 4 |
1571 |
|
1572 |
=item * all constructor arguments become object members. |
1573 |
|
1574 |
At least initially, when you pass a C<tls>-argument to the constructor it |
1575 |
will end up in C<< $handle->{tls} >>. Those members might be changed or |
1576 |
mutated later on (for example C<tls> will hold the TLS connection object). |
1577 |
|
1578 |
=item * other object member names are prefixed with an C<_>. |
1579 |
|
1580 |
All object members not explicitly documented (internal use) are prefixed |
1581 |
with an underscore character, so the remaining non-C<_>-namespace is free |
1582 |
for use for subclasses. |
1583 |
|
1584 |
=item * all members not documented here and not prefixed with an underscore |
1585 |
are free to use in subclasses. |
1586 |
|
1587 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
1588 |
member variables, but thats just life, at least it is documented. |
1589 |
|
1590 |
=back |
1591 |
|
1592 |
=head1 AUTHOR |
1593 |
|
1594 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
1595 |
|
1596 |
=cut |
1597 |
|
1598 |
1; # End of AnyEvent::Handle |