1 |
package AnyEvent::Handle; |
2 |
|
3 |
no warnings; |
4 |
use strict qw(subs vars); |
5 |
|
6 |
use AnyEvent (); |
7 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
8 |
use Scalar::Util (); |
9 |
use Carp (); |
10 |
use Fcntl (); |
11 |
use Errno qw(EAGAIN EINTR); |
12 |
|
13 |
=head1 NAME |
14 |
|
15 |
AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent |
16 |
|
17 |
=cut |
18 |
|
19 |
our $VERSION = 4.82; |
20 |
|
21 |
=head1 SYNOPSIS |
22 |
|
23 |
use AnyEvent; |
24 |
use AnyEvent::Handle; |
25 |
|
26 |
my $cv = AnyEvent->condvar; |
27 |
|
28 |
my $hdl; $hdl = new AnyEvent::Handle |
29 |
fh => \*STDIN, |
30 |
on_error => sub { |
31 |
warn "got error $_[2]\n"; |
32 |
$cv->send; |
33 |
); |
34 |
|
35 |
# send some request line |
36 |
$hdl->push_write ("getinfo\015\012"); |
37 |
|
38 |
# read the response line |
39 |
$hdl->push_read (line => sub { |
40 |
my ($hdl, $line) = @_; |
41 |
warn "got line <$line>\n"; |
42 |
$cv->send; |
43 |
}); |
44 |
|
45 |
$cv->recv; |
46 |
|
47 |
=head1 DESCRIPTION |
48 |
|
49 |
This module is a helper module to make it easier to do event-based I/O on |
50 |
filehandles. For utility functions for doing non-blocking connects and accepts |
51 |
on sockets see L<AnyEvent::Util>. |
52 |
|
53 |
The L<AnyEvent::Intro> tutorial contains some well-documented |
54 |
AnyEvent::Handle examples. |
55 |
|
56 |
In the following, when the documentation refers to of "bytes" then this |
57 |
means characters. As sysread and syswrite are used for all I/O, their |
58 |
treatment of characters applies to this module as well. |
59 |
|
60 |
All callbacks will be invoked with the handle object as their first |
61 |
argument. |
62 |
|
63 |
=head1 METHODS |
64 |
|
65 |
=over 4 |
66 |
|
67 |
=item $handle = B<new> AnyEvent::TLS fh => $filehandle, key => value... |
68 |
|
69 |
The constructor supports these arguments (all as C<< key => value >> pairs). |
70 |
|
71 |
=over 4 |
72 |
|
73 |
=item fh => $filehandle [MANDATORY] |
74 |
|
75 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
76 |
|
77 |
NOTE: The filehandle will be set to non-blocking mode (using |
78 |
C<AnyEvent::Util::fh_nonblocking>) by the constructor and needs to stay in |
79 |
that mode. |
80 |
|
81 |
=item on_eof => $cb->($handle) |
82 |
|
83 |
Set the callback to be called when an end-of-file condition is detected, |
84 |
i.e. in the case of a socket, when the other side has closed the |
85 |
connection cleanly. |
86 |
|
87 |
For sockets, this just means that the other side has stopped sending data, |
88 |
you can still try to write data, and, in fact, one can return from the EOF |
89 |
callback and continue writing data, as only the read part has been shut |
90 |
down. |
91 |
|
92 |
While not mandatory, it is I<highly> recommended to set an EOF callback, |
93 |
otherwise you might end up with a closed socket while you are still |
94 |
waiting for data. |
95 |
|
96 |
If an EOF condition has been detected but no C<on_eof> callback has been |
97 |
set, then a fatal error will be raised with C<$!> set to <0>. |
98 |
|
99 |
=item on_error => $cb->($handle, $fatal, $message) |
100 |
|
101 |
This is the error callback, which is called when, well, some error |
102 |
occured, such as not being able to resolve the hostname, failure to |
103 |
connect or a read error. |
104 |
|
105 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
106 |
fatal errors the handle object will be destroyed (by a call to C<< -> |
107 |
destroy >>) after invoking the error callback (which means you are free to |
108 |
examine the handle object). Examples of fatal errors are an EOF condition |
109 |
with active (but unsatisifable) read watchers (C<EPIPE>) or I/O errors. |
110 |
|
111 |
AnyEvent::Handle tries to find an appropriate error code for you to check |
112 |
against, but in some cases (TLS errors), this does not work well. It is |
113 |
recommended to always output the C<$message> argument in human-readable |
114 |
error messages (it's usually the same as C<"$!">). |
115 |
|
116 |
Non-fatal errors can be retried by simply returning, but it is recommended |
117 |
to simply ignore this parameter and instead abondon the handle object |
118 |
when this callback is invoked. Examples of non-fatal errors are timeouts |
119 |
C<ETIMEDOUT>) or badly-formatted data (C<EBADMSG>). |
120 |
|
121 |
On callback entrance, the value of C<$!> contains the operating system |
122 |
error code (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT>, C<EBADMSG> or |
123 |
C<EPROTO>). |
124 |
|
125 |
While not mandatory, it is I<highly> recommended to set this callback, as |
126 |
you will not be notified of errors otherwise. The default simply calls |
127 |
C<croak>. |
128 |
|
129 |
=item on_read => $cb->($handle) |
130 |
|
131 |
This sets the default read callback, which is called when data arrives |
132 |
and no read request is in the queue (unlike read queue callbacks, this |
133 |
callback will only be called when at least one octet of data is in the |
134 |
read buffer). |
135 |
|
136 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
137 |
method or access the C<< $handle->{rbuf} >> member directly. Note that you |
138 |
must not enlarge or modify the read buffer, you can only remove data at |
139 |
the beginning from it. |
140 |
|
141 |
When an EOF condition is detected then AnyEvent::Handle will first try to |
142 |
feed all the remaining data to the queued callbacks and C<on_read> before |
143 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
144 |
error will be raised (with C<$!> set to C<EPIPE>). |
145 |
|
146 |
=item on_drain => $cb->($handle) |
147 |
|
148 |
This sets the callback that is called when the write buffer becomes empty |
149 |
(or when the callback is set and the buffer is empty already). |
150 |
|
151 |
To append to the write buffer, use the C<< ->push_write >> method. |
152 |
|
153 |
This callback is useful when you don't want to put all of your write data |
154 |
into the queue at once, for example, when you want to write the contents |
155 |
of some file to the socket you might not want to read the whole file into |
156 |
memory and push it into the queue, but instead only read more data from |
157 |
the file when the write queue becomes empty. |
158 |
|
159 |
=item timeout => $fractional_seconds |
160 |
|
161 |
If non-zero, then this enables an "inactivity" timeout: whenever this many |
162 |
seconds pass without a successful read or write on the underlying file |
163 |
handle, the C<on_timeout> callback will be invoked (and if that one is |
164 |
missing, a non-fatal C<ETIMEDOUT> error will be raised). |
165 |
|
166 |
Note that timeout processing is also active when you currently do not have |
167 |
any outstanding read or write requests: If you plan to keep the connection |
168 |
idle then you should disable the timout temporarily or ignore the timeout |
169 |
in the C<on_timeout> callback, in which case AnyEvent::Handle will simply |
170 |
restart the timeout. |
171 |
|
172 |
Zero (the default) disables this timeout. |
173 |
|
174 |
=item on_timeout => $cb->($handle) |
175 |
|
176 |
Called whenever the inactivity timeout passes. If you return from this |
177 |
callback, then the timeout will be reset as if some activity had happened, |
178 |
so this condition is not fatal in any way. |
179 |
|
180 |
=item rbuf_max => <bytes> |
181 |
|
182 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
183 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
184 |
avoid some forms of denial-of-service attacks. |
185 |
|
186 |
For example, a server accepting connections from untrusted sources should |
187 |
be configured to accept only so-and-so much data that it cannot act on |
188 |
(for example, when expecting a line, an attacker could send an unlimited |
189 |
amount of data without a callback ever being called as long as the line |
190 |
isn't finished). |
191 |
|
192 |
=item autocork => <boolean> |
193 |
|
194 |
When disabled (the default), then C<push_write> will try to immediately |
195 |
write the data to the handle, if possible. This avoids having to register |
196 |
a write watcher and wait for the next event loop iteration, but can |
197 |
be inefficient if you write multiple small chunks (on the wire, this |
198 |
disadvantage is usually avoided by your kernel's nagle algorithm, see |
199 |
C<no_delay>, but this option can save costly syscalls). |
200 |
|
201 |
When enabled, then writes will always be queued till the next event loop |
202 |
iteration. This is efficient when you do many small writes per iteration, |
203 |
but less efficient when you do a single write only per iteration (or when |
204 |
the write buffer often is full). It also increases write latency. |
205 |
|
206 |
=item no_delay => <boolean> |
207 |
|
208 |
When doing small writes on sockets, your operating system kernel might |
209 |
wait a bit for more data before actually sending it out. This is called |
210 |
the Nagle algorithm, and usually it is beneficial. |
211 |
|
212 |
In some situations you want as low a delay as possible, which can be |
213 |
accomplishd by setting this option to a true value. |
214 |
|
215 |
The default is your opertaing system's default behaviour (most likely |
216 |
enabled), this option explicitly enables or disables it, if possible. |
217 |
|
218 |
=item read_size => <bytes> |
219 |
|
220 |
The default read block size (the amount of bytes this module will |
221 |
try to read during each loop iteration, which affects memory |
222 |
requirements). Default: C<8192>. |
223 |
|
224 |
=item low_water_mark => <bytes> |
225 |
|
226 |
Sets the amount of bytes (default: C<0>) that make up an "empty" write |
227 |
buffer: If the write reaches this size or gets even samller it is |
228 |
considered empty. |
229 |
|
230 |
Sometimes it can be beneficial (for performance reasons) to add data to |
231 |
the write buffer before it is fully drained, but this is a rare case, as |
232 |
the operating system kernel usually buffers data as well, so the default |
233 |
is good in almost all cases. |
234 |
|
235 |
=item linger => <seconds> |
236 |
|
237 |
If non-zero (default: C<3600>), then the destructor of the |
238 |
AnyEvent::Handle object will check whether there is still outstanding |
239 |
write data and will install a watcher that will write this data to the |
240 |
socket. No errors will be reported (this mostly matches how the operating |
241 |
system treats outstanding data at socket close time). |
242 |
|
243 |
This will not work for partial TLS data that could not be encoded |
244 |
yet. This data will be lost. Calling the C<stoptls> method in time might |
245 |
help. |
246 |
|
247 |
=item peername => $string |
248 |
|
249 |
A string used to identify the remote site - usually the DNS hostname |
250 |
(I<not> IDN!) used to create the connection, rarely the IP address. |
251 |
|
252 |
Apart from being useful in error messages, this string is also used in TLS |
253 |
peername verification (see C<verify_peername> in L<AnyEvent::TLS>). This |
254 |
verification will be skipped when C<peername> is not specified or |
255 |
C<undef>. |
256 |
|
257 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
258 |
|
259 |
When this parameter is given, it enables TLS (SSL) mode, that means |
260 |
AnyEvent will start a TLS handshake as soon as the conenction has been |
261 |
established and will transparently encrypt/decrypt data afterwards. |
262 |
|
263 |
All TLS protocol errors will be signalled as C<EPROTO>, with an |
264 |
appropriate error message. |
265 |
|
266 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
267 |
automatically when you try to create a TLS handle): this module doesn't |
268 |
have a dependency on that module, so if your module requires it, you have |
269 |
to add the dependency yourself. |
270 |
|
271 |
Unlike TCP, TLS has a server and client side: for the TLS server side, use |
272 |
C<accept>, and for the TLS client side of a connection, use C<connect> |
273 |
mode. |
274 |
|
275 |
You can also provide your own TLS connection object, but you have |
276 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
277 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
278 |
AnyEvent::Handle. Also, this module will take ownership of this connection |
279 |
object. |
280 |
|
281 |
At some future point, AnyEvent::Handle might switch to another TLS |
282 |
implementation, then the option to use your own session object will go |
283 |
away. |
284 |
|
285 |
B<IMPORTANT:> since Net::SSLeay "objects" are really only integers, |
286 |
passing in the wrong integer will lead to certain crash. This most often |
287 |
happens when one uses a stylish C<< tls => 1 >> and is surprised about the |
288 |
segmentation fault. |
289 |
|
290 |
See the C<< ->starttls >> method for when need to start TLS negotiation later. |
291 |
|
292 |
=item tls_ctx => $anyevent_tls |
293 |
|
294 |
Use the given C<AnyEvent::TLS> object to create the new TLS connection |
295 |
(unless a connection object was specified directly). If this parameter is |
296 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
297 |
|
298 |
Instead of an object, you can also specify a hash reference with C<< key |
299 |
=> value >> pairs. Those will be passed to L<AnyEvent::TLS> to create a |
300 |
new TLS context object. |
301 |
|
302 |
=item on_starttls => $cb->($handle, $success[, $error_message]) |
303 |
|
304 |
This callback will be invoked when the TLS/SSL handshake has finished. If |
305 |
C<$success> is true, then the TLS handshake succeeded, otherwise it failed |
306 |
(C<on_stoptls> will not be called in this case). |
307 |
|
308 |
The session in C<< $handle->{tls} >> can still be examined in this |
309 |
callback, even when the handshake was not successful. |
310 |
|
311 |
TLS handshake failures will not cause C<on_error> to be invoked when this |
312 |
callback is in effect, instead, the error message will be passed to C<on_starttls>. |
313 |
|
314 |
Without this callback, handshake failures lead to C<on_error> being |
315 |
called, as normal. |
316 |
|
317 |
Note that you cannot call C<starttls> right again in this callback. If you |
318 |
need to do that, start an zero-second timer instead whose callback can |
319 |
then call C<< ->starttls >> again. |
320 |
|
321 |
=item on_stoptls => $cb->($handle) |
322 |
|
323 |
When a SSLv3/TLS shutdown/close notify/EOF is detected and this callback is |
324 |
set, then it will be invoked after freeing the TLS session. If it is not, |
325 |
then a TLS shutdown condition will be treated like a normal EOF condition |
326 |
on the handle. |
327 |
|
328 |
The session in C<< $handle->{tls} >> can still be examined in this |
329 |
callback. |
330 |
|
331 |
This callback will only be called on TLS shutdowns, not when the |
332 |
underlying handle signals EOF. |
333 |
|
334 |
=item json => JSON or JSON::XS object |
335 |
|
336 |
This is the json coder object used by the C<json> read and write types. |
337 |
|
338 |
If you don't supply it, then AnyEvent::Handle will create and use a |
339 |
suitable one (on demand), which will write and expect UTF-8 encoded JSON |
340 |
texts. |
341 |
|
342 |
Note that you are responsible to depend on the JSON module if you want to |
343 |
use this functionality, as AnyEvent does not have a dependency itself. |
344 |
|
345 |
=back |
346 |
|
347 |
=cut |
348 |
|
349 |
sub new { |
350 |
my $class = shift; |
351 |
my $self = bless { @_ }, $class; |
352 |
|
353 |
$self->{fh} or Carp::croak "mandatory argument fh is missing"; |
354 |
|
355 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
356 |
|
357 |
$self->{_activity} = AnyEvent->now; |
358 |
$self->_timeout; |
359 |
|
360 |
$self->no_delay (delete $self->{no_delay}) if exists $self->{no_delay}; |
361 |
|
362 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}) |
363 |
if $self->{tls}; |
364 |
|
365 |
$self->on_drain (delete $self->{on_drain}) if $self->{on_drain}; |
366 |
|
367 |
$self->start_read |
368 |
if $self->{on_read}; |
369 |
|
370 |
$self->{fh} && $self |
371 |
} |
372 |
|
373 |
#sub _shutdown { |
374 |
# my ($self) = @_; |
375 |
# |
376 |
# delete @$self{qw(_tw _rw _ww fh wbuf on_read _queue)}; |
377 |
# $self->{_eof} = 1; # tell starttls et. al to stop trying |
378 |
# |
379 |
# &_freetls; |
380 |
#} |
381 |
|
382 |
sub _error { |
383 |
my ($self, $errno, $fatal, $message) = @_; |
384 |
|
385 |
$! = $errno; |
386 |
$message ||= "$!"; |
387 |
|
388 |
if ($self->{on_error}) { |
389 |
$self->{on_error}($self, $fatal, $message); |
390 |
$self->destroy; |
391 |
} elsif ($self->{fh}) { |
392 |
$self->destroy; |
393 |
Carp::croak "AnyEvent::Handle uncaught error: $message"; |
394 |
} |
395 |
} |
396 |
|
397 |
=item $fh = $handle->fh |
398 |
|
399 |
This method returns the file handle used to create the L<AnyEvent::Handle> object. |
400 |
|
401 |
=cut |
402 |
|
403 |
sub fh { $_[0]{fh} } |
404 |
|
405 |
=item $handle->on_error ($cb) |
406 |
|
407 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
408 |
|
409 |
=cut |
410 |
|
411 |
sub on_error { |
412 |
$_[0]{on_error} = $_[1]; |
413 |
} |
414 |
|
415 |
=item $handle->on_eof ($cb) |
416 |
|
417 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
418 |
|
419 |
=cut |
420 |
|
421 |
sub on_eof { |
422 |
$_[0]{on_eof} = $_[1]; |
423 |
} |
424 |
|
425 |
=item $handle->on_timeout ($cb) |
426 |
|
427 |
Replace the current C<on_timeout> callback, or disables the callback (but |
428 |
not the timeout) if C<$cb> = C<undef>. See the C<timeout> constructor |
429 |
argument and method. |
430 |
|
431 |
=cut |
432 |
|
433 |
sub on_timeout { |
434 |
$_[0]{on_timeout} = $_[1]; |
435 |
} |
436 |
|
437 |
=item $handle->autocork ($boolean) |
438 |
|
439 |
Enables or disables the current autocork behaviour (see C<autocork> |
440 |
constructor argument). Changes will only take effect on the next write. |
441 |
|
442 |
=cut |
443 |
|
444 |
sub autocork { |
445 |
$_[0]{autocork} = $_[1]; |
446 |
} |
447 |
|
448 |
=item $handle->no_delay ($boolean) |
449 |
|
450 |
Enables or disables the C<no_delay> setting (see constructor argument of |
451 |
the same name for details). |
452 |
|
453 |
=cut |
454 |
|
455 |
sub no_delay { |
456 |
$_[0]{no_delay} = $_[1]; |
457 |
|
458 |
eval { |
459 |
local $SIG{__DIE__}; |
460 |
setsockopt $_[0]{fh}, &Socket::IPPROTO_TCP, &Socket::TCP_NODELAY, int $_[1]; |
461 |
}; |
462 |
} |
463 |
|
464 |
=item $handle->on_starttls ($cb) |
465 |
|
466 |
Replace the current C<on_starttls> callback (see the C<on_starttls> constructor argument). |
467 |
|
468 |
=cut |
469 |
|
470 |
sub on_starttls { |
471 |
$_[0]{on_starttls} = $_[1]; |
472 |
} |
473 |
|
474 |
=item $handle->on_stoptls ($cb) |
475 |
|
476 |
Replace the current C<on_stoptls> callback (see the C<on_stoptls> constructor argument). |
477 |
|
478 |
=cut |
479 |
|
480 |
sub on_starttls { |
481 |
$_[0]{on_stoptls} = $_[1]; |
482 |
} |
483 |
|
484 |
############################################################################# |
485 |
|
486 |
=item $handle->timeout ($seconds) |
487 |
|
488 |
Configures (or disables) the inactivity timeout. |
489 |
|
490 |
=cut |
491 |
|
492 |
sub timeout { |
493 |
my ($self, $timeout) = @_; |
494 |
|
495 |
$self->{timeout} = $timeout; |
496 |
$self->_timeout; |
497 |
} |
498 |
|
499 |
# reset the timeout watcher, as neccessary |
500 |
# also check for time-outs |
501 |
sub _timeout { |
502 |
my ($self) = @_; |
503 |
|
504 |
if ($self->{timeout}) { |
505 |
my $NOW = AnyEvent->now; |
506 |
|
507 |
# when would the timeout trigger? |
508 |
my $after = $self->{_activity} + $self->{timeout} - $NOW; |
509 |
|
510 |
# now or in the past already? |
511 |
if ($after <= 0) { |
512 |
$self->{_activity} = $NOW; |
513 |
|
514 |
if ($self->{on_timeout}) { |
515 |
$self->{on_timeout}($self); |
516 |
} else { |
517 |
$self->_error (&Errno::ETIMEDOUT); |
518 |
} |
519 |
|
520 |
# callback could have changed timeout value, optimise |
521 |
return unless $self->{timeout}; |
522 |
|
523 |
# calculate new after |
524 |
$after = $self->{timeout}; |
525 |
} |
526 |
|
527 |
Scalar::Util::weaken $self; |
528 |
return unless $self; # ->error could have destroyed $self |
529 |
|
530 |
$self->{_tw} ||= AnyEvent->timer (after => $after, cb => sub { |
531 |
delete $self->{_tw}; |
532 |
$self->_timeout; |
533 |
}); |
534 |
} else { |
535 |
delete $self->{_tw}; |
536 |
} |
537 |
} |
538 |
|
539 |
############################################################################# |
540 |
|
541 |
=back |
542 |
|
543 |
=head2 WRITE QUEUE |
544 |
|
545 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
546 |
for reading. |
547 |
|
548 |
The write queue is very simple: you can add data to its end, and |
549 |
AnyEvent::Handle will automatically try to get rid of it for you. |
550 |
|
551 |
When data could be written and the write buffer is shorter then the low |
552 |
water mark, the C<on_drain> callback will be invoked. |
553 |
|
554 |
=over 4 |
555 |
|
556 |
=item $handle->on_drain ($cb) |
557 |
|
558 |
Sets the C<on_drain> callback or clears it (see the description of |
559 |
C<on_drain> in the constructor). |
560 |
|
561 |
=cut |
562 |
|
563 |
sub on_drain { |
564 |
my ($self, $cb) = @_; |
565 |
|
566 |
$self->{on_drain} = $cb; |
567 |
|
568 |
$cb->($self) |
569 |
if $cb && $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}); |
570 |
} |
571 |
|
572 |
=item $handle->push_write ($data) |
573 |
|
574 |
Queues the given scalar to be written. You can push as much data as you |
575 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
576 |
buffers it independently of the kernel. |
577 |
|
578 |
=cut |
579 |
|
580 |
sub _drain_wbuf { |
581 |
my ($self) = @_; |
582 |
|
583 |
if (!$self->{_ww} && length $self->{wbuf}) { |
584 |
|
585 |
Scalar::Util::weaken $self; |
586 |
|
587 |
my $cb = sub { |
588 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
589 |
|
590 |
if (defined $len) { |
591 |
substr $self->{wbuf}, 0, $len, ""; |
592 |
|
593 |
$self->{_activity} = AnyEvent->now; |
594 |
|
595 |
$self->{on_drain}($self) |
596 |
if $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}) |
597 |
&& $self->{on_drain}; |
598 |
|
599 |
delete $self->{_ww} unless length $self->{wbuf}; |
600 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
601 |
$self->_error ($!, 1); |
602 |
} |
603 |
}; |
604 |
|
605 |
# try to write data immediately |
606 |
$cb->() unless $self->{autocork}; |
607 |
|
608 |
# if still data left in wbuf, we need to poll |
609 |
$self->{_ww} = AnyEvent->io (fh => $self->{fh}, poll => "w", cb => $cb) |
610 |
if length $self->{wbuf}; |
611 |
}; |
612 |
} |
613 |
|
614 |
our %WH; |
615 |
|
616 |
sub register_write_type($$) { |
617 |
$WH{$_[0]} = $_[1]; |
618 |
} |
619 |
|
620 |
sub push_write { |
621 |
my $self = shift; |
622 |
|
623 |
if (@_ > 1) { |
624 |
my $type = shift; |
625 |
|
626 |
@_ = ($WH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_write") |
627 |
->($self, @_); |
628 |
} |
629 |
|
630 |
if ($self->{tls}) { |
631 |
$self->{_tls_wbuf} .= $_[0]; |
632 |
|
633 |
&_dotls ($self); |
634 |
} else { |
635 |
$self->{wbuf} .= $_[0]; |
636 |
$self->_drain_wbuf; |
637 |
} |
638 |
} |
639 |
|
640 |
=item $handle->push_write (type => @args) |
641 |
|
642 |
Instead of formatting your data yourself, you can also let this module do |
643 |
the job by specifying a type and type-specific arguments. |
644 |
|
645 |
Predefined types are (if you have ideas for additional types, feel free to |
646 |
drop by and tell us): |
647 |
|
648 |
=over 4 |
649 |
|
650 |
=item netstring => $string |
651 |
|
652 |
Formats the given value as netstring |
653 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
654 |
|
655 |
=cut |
656 |
|
657 |
register_write_type netstring => sub { |
658 |
my ($self, $string) = @_; |
659 |
|
660 |
(length $string) . ":$string," |
661 |
}; |
662 |
|
663 |
=item packstring => $format, $data |
664 |
|
665 |
An octet string prefixed with an encoded length. The encoding C<$format> |
666 |
uses the same format as a Perl C<pack> format, but must specify a single |
667 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
668 |
optional C<!>, C<< < >> or C<< > >> modifier). |
669 |
|
670 |
=cut |
671 |
|
672 |
register_write_type packstring => sub { |
673 |
my ($self, $format, $string) = @_; |
674 |
|
675 |
pack "$format/a*", $string |
676 |
}; |
677 |
|
678 |
=item json => $array_or_hashref |
679 |
|
680 |
Encodes the given hash or array reference into a JSON object. Unless you |
681 |
provide your own JSON object, this means it will be encoded to JSON text |
682 |
in UTF-8. |
683 |
|
684 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
685 |
one end of a handle and read them at the other end without using any |
686 |
additional framing. |
687 |
|
688 |
The generated JSON text is guaranteed not to contain any newlines: While |
689 |
this module doesn't need delimiters after or between JSON texts to be |
690 |
able to read them, many other languages depend on that. |
691 |
|
692 |
A simple RPC protocol that interoperates easily with others is to send |
693 |
JSON arrays (or objects, although arrays are usually the better choice as |
694 |
they mimic how function argument passing works) and a newline after each |
695 |
JSON text: |
696 |
|
697 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
698 |
$handle->push_write ("\012"); |
699 |
|
700 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
701 |
rely on the fact that the newline will be skipped as leading whitespace: |
702 |
|
703 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
704 |
|
705 |
Other languages could read single lines terminated by a newline and pass |
706 |
this line into their JSON decoder of choice. |
707 |
|
708 |
=cut |
709 |
|
710 |
register_write_type json => sub { |
711 |
my ($self, $ref) = @_; |
712 |
|
713 |
require JSON; |
714 |
|
715 |
$self->{json} ? $self->{json}->encode ($ref) |
716 |
: JSON::encode_json ($ref) |
717 |
}; |
718 |
|
719 |
=item storable => $reference |
720 |
|
721 |
Freezes the given reference using L<Storable> and writes it to the |
722 |
handle. Uses the C<nfreeze> format. |
723 |
|
724 |
=cut |
725 |
|
726 |
register_write_type storable => sub { |
727 |
my ($self, $ref) = @_; |
728 |
|
729 |
require Storable; |
730 |
|
731 |
pack "w/a*", Storable::nfreeze ($ref) |
732 |
}; |
733 |
|
734 |
=back |
735 |
|
736 |
=item $handle->push_shutdown |
737 |
|
738 |
Sometimes you know you want to close the socket after writing your data |
739 |
before it was actually written. One way to do that is to replace your |
740 |
C<on_drain> handler by a callback that shuts down the socket (and set |
741 |
C<low_water_mark> to C<0>). This method is a shorthand for just that, and |
742 |
replaces the C<on_drain> callback with: |
743 |
|
744 |
sub { shutdown $_[0]{fh}, 1 } # for push_shutdown |
745 |
|
746 |
This simply shuts down the write side and signals an EOF condition to the |
747 |
the peer. |
748 |
|
749 |
You can rely on the normal read queue and C<on_eof> handling |
750 |
afterwards. This is the cleanest way to close a connection. |
751 |
|
752 |
=cut |
753 |
|
754 |
sub push_shutdown { |
755 |
my ($self) = @_; |
756 |
|
757 |
delete $self->{low_water_mark}; |
758 |
$self->on_drain (sub { shutdown $_[0]{fh}, 1 }); |
759 |
} |
760 |
|
761 |
=item AnyEvent::Handle::register_write_type type => $coderef->($handle, @args) |
762 |
|
763 |
This function (not method) lets you add your own types to C<push_write>. |
764 |
Whenever the given C<type> is used, C<push_write> will invoke the code |
765 |
reference with the handle object and the remaining arguments. |
766 |
|
767 |
The code reference is supposed to return a single octet string that will |
768 |
be appended to the write buffer. |
769 |
|
770 |
Note that this is a function, and all types registered this way will be |
771 |
global, so try to use unique names. |
772 |
|
773 |
=cut |
774 |
|
775 |
############################################################################# |
776 |
|
777 |
=back |
778 |
|
779 |
=head2 READ QUEUE |
780 |
|
781 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
782 |
for reading. |
783 |
|
784 |
The read queue is more complex than the write queue. It can be used in two |
785 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
786 |
a queue. |
787 |
|
788 |
In the simple case, you just install an C<on_read> callback and whenever |
789 |
new data arrives, it will be called. You can then remove some data (if |
790 |
enough is there) from the read buffer (C<< $handle->rbuf >>). Or you cna |
791 |
leave the data there if you want to accumulate more (e.g. when only a |
792 |
partial message has been received so far). |
793 |
|
794 |
In the more complex case, you want to queue multiple callbacks. In this |
795 |
case, AnyEvent::Handle will call the first queued callback each time new |
796 |
data arrives (also the first time it is queued) and removes it when it has |
797 |
done its job (see C<push_read>, below). |
798 |
|
799 |
This way you can, for example, push three line-reads, followed by reading |
800 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
801 |
|
802 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
803 |
the specified number of bytes which give an XML datagram. |
804 |
|
805 |
# in the default state, expect some header bytes |
806 |
$handle->on_read (sub { |
807 |
# some data is here, now queue the length-header-read (4 octets) |
808 |
shift->unshift_read (chunk => 4, sub { |
809 |
# header arrived, decode |
810 |
my $len = unpack "N", $_[1]; |
811 |
|
812 |
# now read the payload |
813 |
shift->unshift_read (chunk => $len, sub { |
814 |
my $xml = $_[1]; |
815 |
# handle xml |
816 |
}); |
817 |
}); |
818 |
}); |
819 |
|
820 |
Example 2: Implement a client for a protocol that replies either with "OK" |
821 |
and another line or "ERROR" for the first request that is sent, and 64 |
822 |
bytes for the second request. Due to the availability of a queue, we can |
823 |
just pipeline sending both requests and manipulate the queue as necessary |
824 |
in the callbacks. |
825 |
|
826 |
When the first callback is called and sees an "OK" response, it will |
827 |
C<unshift> another line-read. This line-read will be queued I<before> the |
828 |
64-byte chunk callback. |
829 |
|
830 |
# request one, returns either "OK + extra line" or "ERROR" |
831 |
$handle->push_write ("request 1\015\012"); |
832 |
|
833 |
# we expect "ERROR" or "OK" as response, so push a line read |
834 |
$handle->push_read (line => sub { |
835 |
# if we got an "OK", we have to _prepend_ another line, |
836 |
# so it will be read before the second request reads its 64 bytes |
837 |
# which are already in the queue when this callback is called |
838 |
# we don't do this in case we got an error |
839 |
if ($_[1] eq "OK") { |
840 |
$_[0]->unshift_read (line => sub { |
841 |
my $response = $_[1]; |
842 |
... |
843 |
}); |
844 |
} |
845 |
}); |
846 |
|
847 |
# request two, simply returns 64 octets |
848 |
$handle->push_write ("request 2\015\012"); |
849 |
|
850 |
# simply read 64 bytes, always |
851 |
$handle->push_read (chunk => 64, sub { |
852 |
my $response = $_[1]; |
853 |
... |
854 |
}); |
855 |
|
856 |
=over 4 |
857 |
|
858 |
=cut |
859 |
|
860 |
sub _drain_rbuf { |
861 |
my ($self) = @_; |
862 |
|
863 |
local $self->{_in_drain} = 1; |
864 |
|
865 |
if ( |
866 |
defined $self->{rbuf_max} |
867 |
&& $self->{rbuf_max} < length $self->{rbuf} |
868 |
) { |
869 |
$self->_error (&Errno::ENOSPC, 1), return; |
870 |
} |
871 |
|
872 |
while () { |
873 |
# we need to use a separate tls read buffer, as we must not receive data while |
874 |
# we are draining the buffer, and this can only happen with TLS. |
875 |
$self->{rbuf} .= delete $self->{_tls_rbuf} if exists $self->{_tls_rbuf}; |
876 |
|
877 |
my $len = length $self->{rbuf}; |
878 |
|
879 |
if (my $cb = shift @{ $self->{_queue} }) { |
880 |
unless ($cb->($self)) { |
881 |
if ($self->{_eof}) { |
882 |
# no progress can be made (not enough data and no data forthcoming) |
883 |
$self->_error (&Errno::EPIPE, 1), return; |
884 |
} |
885 |
|
886 |
unshift @{ $self->{_queue} }, $cb; |
887 |
last; |
888 |
} |
889 |
} elsif ($self->{on_read}) { |
890 |
last unless $len; |
891 |
|
892 |
$self->{on_read}($self); |
893 |
|
894 |
if ( |
895 |
$len == length $self->{rbuf} # if no data has been consumed |
896 |
&& !@{ $self->{_queue} } # and the queue is still empty |
897 |
&& $self->{on_read} # but we still have on_read |
898 |
) { |
899 |
# no further data will arrive |
900 |
# so no progress can be made |
901 |
$self->_error (&Errno::EPIPE, 1), return |
902 |
if $self->{_eof}; |
903 |
|
904 |
last; # more data might arrive |
905 |
} |
906 |
} else { |
907 |
# read side becomes idle |
908 |
delete $self->{_rw} unless $self->{tls}; |
909 |
last; |
910 |
} |
911 |
} |
912 |
|
913 |
if ($self->{_eof}) { |
914 |
if ($self->{on_eof}) { |
915 |
$self->{on_eof}($self) |
916 |
} else { |
917 |
$self->_error (0, 1, "Unexpected end-of-file"); |
918 |
} |
919 |
} |
920 |
|
921 |
# may need to restart read watcher |
922 |
unless ($self->{_rw}) { |
923 |
$self->start_read |
924 |
if $self->{on_read} || @{ $self->{_queue} }; |
925 |
} |
926 |
} |
927 |
|
928 |
=item $handle->on_read ($cb) |
929 |
|
930 |
This replaces the currently set C<on_read> callback, or clears it (when |
931 |
the new callback is C<undef>). See the description of C<on_read> in the |
932 |
constructor. |
933 |
|
934 |
=cut |
935 |
|
936 |
sub on_read { |
937 |
my ($self, $cb) = @_; |
938 |
|
939 |
$self->{on_read} = $cb; |
940 |
$self->_drain_rbuf if $cb && !$self->{_in_drain}; |
941 |
} |
942 |
|
943 |
=item $handle->rbuf |
944 |
|
945 |
Returns the read buffer (as a modifiable lvalue). |
946 |
|
947 |
You can access the read buffer directly as the C<< ->{rbuf} >> |
948 |
member, if you want. However, the only operation allowed on the |
949 |
read buffer (apart from looking at it) is removing data from its |
950 |
beginning. Otherwise modifying or appending to it is not allowed and will |
951 |
lead to hard-to-track-down bugs. |
952 |
|
953 |
NOTE: The read buffer should only be used or modified if the C<on_read>, |
954 |
C<push_read> or C<unshift_read> methods are used. The other read methods |
955 |
automatically manage the read buffer. |
956 |
|
957 |
=cut |
958 |
|
959 |
sub rbuf : lvalue { |
960 |
$_[0]{rbuf} |
961 |
} |
962 |
|
963 |
=item $handle->push_read ($cb) |
964 |
|
965 |
=item $handle->unshift_read ($cb) |
966 |
|
967 |
Append the given callback to the end of the queue (C<push_read>) or |
968 |
prepend it (C<unshift_read>). |
969 |
|
970 |
The callback is called each time some additional read data arrives. |
971 |
|
972 |
It must check whether enough data is in the read buffer already. |
973 |
|
974 |
If not enough data is available, it must return the empty list or a false |
975 |
value, in which case it will be called repeatedly until enough data is |
976 |
available (or an error condition is detected). |
977 |
|
978 |
If enough data was available, then the callback must remove all data it is |
979 |
interested in (which can be none at all) and return a true value. After returning |
980 |
true, it will be removed from the queue. |
981 |
|
982 |
=cut |
983 |
|
984 |
our %RH; |
985 |
|
986 |
sub register_read_type($$) { |
987 |
$RH{$_[0]} = $_[1]; |
988 |
} |
989 |
|
990 |
sub push_read { |
991 |
my $self = shift; |
992 |
my $cb = pop; |
993 |
|
994 |
if (@_) { |
995 |
my $type = shift; |
996 |
|
997 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_read") |
998 |
->($self, $cb, @_); |
999 |
} |
1000 |
|
1001 |
push @{ $self->{_queue} }, $cb; |
1002 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1003 |
} |
1004 |
|
1005 |
sub unshift_read { |
1006 |
my $self = shift; |
1007 |
my $cb = pop; |
1008 |
|
1009 |
if (@_) { |
1010 |
my $type = shift; |
1011 |
|
1012 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::unshift_read") |
1013 |
->($self, $cb, @_); |
1014 |
} |
1015 |
|
1016 |
|
1017 |
unshift @{ $self->{_queue} }, $cb; |
1018 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1019 |
} |
1020 |
|
1021 |
=item $handle->push_read (type => @args, $cb) |
1022 |
|
1023 |
=item $handle->unshift_read (type => @args, $cb) |
1024 |
|
1025 |
Instead of providing a callback that parses the data itself you can chose |
1026 |
between a number of predefined parsing formats, for chunks of data, lines |
1027 |
etc. |
1028 |
|
1029 |
Predefined types are (if you have ideas for additional types, feel free to |
1030 |
drop by and tell us): |
1031 |
|
1032 |
=over 4 |
1033 |
|
1034 |
=item chunk => $octets, $cb->($handle, $data) |
1035 |
|
1036 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
1037 |
data read to the callback. The callback will never be called with less |
1038 |
data. |
1039 |
|
1040 |
Example: read 2 bytes. |
1041 |
|
1042 |
$handle->push_read (chunk => 2, sub { |
1043 |
warn "yay ", unpack "H*", $_[1]; |
1044 |
}); |
1045 |
|
1046 |
=cut |
1047 |
|
1048 |
register_read_type chunk => sub { |
1049 |
my ($self, $cb, $len) = @_; |
1050 |
|
1051 |
sub { |
1052 |
$len <= length $_[0]{rbuf} or return; |
1053 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
1054 |
1 |
1055 |
} |
1056 |
}; |
1057 |
|
1058 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
1059 |
|
1060 |
The callback will be called only once a full line (including the end of |
1061 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
1062 |
marker) will be passed to the callback as second argument (C<$line>), and |
1063 |
the end of line marker as the third argument (C<$eol>). |
1064 |
|
1065 |
The end of line marker, C<$eol>, can be either a string, in which case it |
1066 |
will be interpreted as a fixed record end marker, or it can be a regex |
1067 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
1068 |
regular expression. |
1069 |
|
1070 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
1071 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
1072 |
protocols). |
1073 |
|
1074 |
Partial lines at the end of the stream will never be returned, as they are |
1075 |
not marked by the end of line marker. |
1076 |
|
1077 |
=cut |
1078 |
|
1079 |
register_read_type line => sub { |
1080 |
my ($self, $cb, $eol) = @_; |
1081 |
|
1082 |
if (@_ < 3) { |
1083 |
# this is more than twice as fast as the generic code below |
1084 |
sub { |
1085 |
$_[0]{rbuf} =~ s/^([^\015\012]*)(\015?\012)// or return; |
1086 |
|
1087 |
$cb->($_[0], $1, $2); |
1088 |
1 |
1089 |
} |
1090 |
} else { |
1091 |
$eol = quotemeta $eol unless ref $eol; |
1092 |
$eol = qr|^(.*?)($eol)|s; |
1093 |
|
1094 |
sub { |
1095 |
$_[0]{rbuf} =~ s/$eol// or return; |
1096 |
|
1097 |
$cb->($_[0], $1, $2); |
1098 |
1 |
1099 |
} |
1100 |
} |
1101 |
}; |
1102 |
|
1103 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
1104 |
|
1105 |
Makes a regex match against the regex object C<$accept> and returns |
1106 |
everything up to and including the match. |
1107 |
|
1108 |
Example: read a single line terminated by '\n'. |
1109 |
|
1110 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
1111 |
|
1112 |
If C<$reject> is given and not undef, then it determines when the data is |
1113 |
to be rejected: it is matched against the data when the C<$accept> regex |
1114 |
does not match and generates an C<EBADMSG> error when it matches. This is |
1115 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
1116 |
receive buffer overflow). |
1117 |
|
1118 |
Example: expect a single decimal number followed by whitespace, reject |
1119 |
anything else (not the use of an anchor). |
1120 |
|
1121 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
1122 |
|
1123 |
If C<$skip> is given and not C<undef>, then it will be matched against |
1124 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
1125 |
and everything preceding and including the match will be accepted |
1126 |
unconditionally. This is useful to skip large amounts of data that you |
1127 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
1128 |
have to start matching from the beginning. This is purely an optimisation |
1129 |
and is usually worth only when you expect more than a few kilobytes. |
1130 |
|
1131 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
1132 |
expect the header to be very large (it isn't in practise, but...), we use |
1133 |
a skip regex to skip initial portions. The skip regex is tricky in that |
1134 |
it only accepts something not ending in either \015 or \012, as these are |
1135 |
required for the accept regex. |
1136 |
|
1137 |
$handle->push_read (regex => |
1138 |
qr<\015\012\015\012>, |
1139 |
undef, # no reject |
1140 |
qr<^.*[^\015\012]>, |
1141 |
sub { ... }); |
1142 |
|
1143 |
=cut |
1144 |
|
1145 |
register_read_type regex => sub { |
1146 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
1147 |
|
1148 |
my $data; |
1149 |
my $rbuf = \$self->{rbuf}; |
1150 |
|
1151 |
sub { |
1152 |
# accept |
1153 |
if ($$rbuf =~ $accept) { |
1154 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1155 |
$cb->($self, $data); |
1156 |
return 1; |
1157 |
} |
1158 |
|
1159 |
# reject |
1160 |
if ($reject && $$rbuf =~ $reject) { |
1161 |
$self->_error (&Errno::EBADMSG); |
1162 |
} |
1163 |
|
1164 |
# skip |
1165 |
if ($skip && $$rbuf =~ $skip) { |
1166 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1167 |
} |
1168 |
|
1169 |
() |
1170 |
} |
1171 |
}; |
1172 |
|
1173 |
=item netstring => $cb->($handle, $string) |
1174 |
|
1175 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
1176 |
|
1177 |
Throws an error with C<$!> set to EBADMSG on format violations. |
1178 |
|
1179 |
=cut |
1180 |
|
1181 |
register_read_type netstring => sub { |
1182 |
my ($self, $cb) = @_; |
1183 |
|
1184 |
sub { |
1185 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
1186 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
1187 |
$self->_error (&Errno::EBADMSG); |
1188 |
} |
1189 |
return; |
1190 |
} |
1191 |
|
1192 |
my $len = $1; |
1193 |
|
1194 |
$self->unshift_read (chunk => $len, sub { |
1195 |
my $string = $_[1]; |
1196 |
$_[0]->unshift_read (chunk => 1, sub { |
1197 |
if ($_[1] eq ",") { |
1198 |
$cb->($_[0], $string); |
1199 |
} else { |
1200 |
$self->_error (&Errno::EBADMSG); |
1201 |
} |
1202 |
}); |
1203 |
}); |
1204 |
|
1205 |
1 |
1206 |
} |
1207 |
}; |
1208 |
|
1209 |
=item packstring => $format, $cb->($handle, $string) |
1210 |
|
1211 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1212 |
uses the same format as a Perl C<pack> format, but must specify a single |
1213 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1214 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1215 |
|
1216 |
For example, DNS over TCP uses a prefix of C<n> (2 octet network order), |
1217 |
EPP uses a prefix of C<N> (4 octtes). |
1218 |
|
1219 |
Example: read a block of data prefixed by its length in BER-encoded |
1220 |
format (very efficient). |
1221 |
|
1222 |
$handle->push_read (packstring => "w", sub { |
1223 |
my ($handle, $data) = @_; |
1224 |
}); |
1225 |
|
1226 |
=cut |
1227 |
|
1228 |
register_read_type packstring => sub { |
1229 |
my ($self, $cb, $format) = @_; |
1230 |
|
1231 |
sub { |
1232 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1233 |
defined (my $len = eval { unpack $format, $_[0]{rbuf} }) |
1234 |
or return; |
1235 |
|
1236 |
$format = length pack $format, $len; |
1237 |
|
1238 |
# bypass unshift if we already have the remaining chunk |
1239 |
if ($format + $len <= length $_[0]{rbuf}) { |
1240 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1241 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1242 |
$cb->($_[0], $data); |
1243 |
} else { |
1244 |
# remove prefix |
1245 |
substr $_[0]{rbuf}, 0, $format, ""; |
1246 |
|
1247 |
# read remaining chunk |
1248 |
$_[0]->unshift_read (chunk => $len, $cb); |
1249 |
} |
1250 |
|
1251 |
1 |
1252 |
} |
1253 |
}; |
1254 |
|
1255 |
=item json => $cb->($handle, $hash_or_arrayref) |
1256 |
|
1257 |
Reads a JSON object or array, decodes it and passes it to the |
1258 |
callback. When a parse error occurs, an C<EBADMSG> error will be raised. |
1259 |
|
1260 |
If a C<json> object was passed to the constructor, then that will be used |
1261 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1262 |
|
1263 |
This read type uses the incremental parser available with JSON version |
1264 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1265 |
dependency on your own: this module will load the JSON module, but |
1266 |
AnyEvent does not depend on it itself. |
1267 |
|
1268 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1269 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1270 |
the C<json> write type description, above, for an actual example. |
1271 |
|
1272 |
=cut |
1273 |
|
1274 |
register_read_type json => sub { |
1275 |
my ($self, $cb) = @_; |
1276 |
|
1277 |
my $json = $self->{json} ||= |
1278 |
eval { require JSON::XS; JSON::XS->new->utf8 } |
1279 |
|| do { require JSON; JSON->new->utf8 }; |
1280 |
|
1281 |
my $data; |
1282 |
my $rbuf = \$self->{rbuf}; |
1283 |
|
1284 |
sub { |
1285 |
my $ref = eval { $json->incr_parse ($self->{rbuf}) }; |
1286 |
|
1287 |
if ($ref) { |
1288 |
$self->{rbuf} = $json->incr_text; |
1289 |
$json->incr_text = ""; |
1290 |
$cb->($self, $ref); |
1291 |
|
1292 |
1 |
1293 |
} elsif ($@) { |
1294 |
# error case |
1295 |
$json->incr_skip; |
1296 |
|
1297 |
$self->{rbuf} = $json->incr_text; |
1298 |
$json->incr_text = ""; |
1299 |
|
1300 |
$self->_error (&Errno::EBADMSG); |
1301 |
|
1302 |
() |
1303 |
} else { |
1304 |
$self->{rbuf} = ""; |
1305 |
|
1306 |
() |
1307 |
} |
1308 |
} |
1309 |
}; |
1310 |
|
1311 |
=item storable => $cb->($handle, $ref) |
1312 |
|
1313 |
Deserialises a L<Storable> frozen representation as written by the |
1314 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1315 |
data). |
1316 |
|
1317 |
Raises C<EBADMSG> error if the data could not be decoded. |
1318 |
|
1319 |
=cut |
1320 |
|
1321 |
register_read_type storable => sub { |
1322 |
my ($self, $cb) = @_; |
1323 |
|
1324 |
require Storable; |
1325 |
|
1326 |
sub { |
1327 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1328 |
defined (my $len = eval { unpack "w", $_[0]{rbuf} }) |
1329 |
or return; |
1330 |
|
1331 |
my $format = length pack "w", $len; |
1332 |
|
1333 |
# bypass unshift if we already have the remaining chunk |
1334 |
if ($format + $len <= length $_[0]{rbuf}) { |
1335 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1336 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1337 |
$cb->($_[0], Storable::thaw ($data)); |
1338 |
} else { |
1339 |
# remove prefix |
1340 |
substr $_[0]{rbuf}, 0, $format, ""; |
1341 |
|
1342 |
# read remaining chunk |
1343 |
$_[0]->unshift_read (chunk => $len, sub { |
1344 |
if (my $ref = eval { Storable::thaw ($_[1]) }) { |
1345 |
$cb->($_[0], $ref); |
1346 |
} else { |
1347 |
$self->_error (&Errno::EBADMSG); |
1348 |
} |
1349 |
}); |
1350 |
} |
1351 |
|
1352 |
1 |
1353 |
} |
1354 |
}; |
1355 |
|
1356 |
=back |
1357 |
|
1358 |
=item AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args) |
1359 |
|
1360 |
This function (not method) lets you add your own types to C<push_read>. |
1361 |
|
1362 |
Whenever the given C<type> is used, C<push_read> will invoke the code |
1363 |
reference with the handle object, the callback and the remaining |
1364 |
arguments. |
1365 |
|
1366 |
The code reference is supposed to return a callback (usually a closure) |
1367 |
that works as a plain read callback (see C<< ->push_read ($cb) >>). |
1368 |
|
1369 |
It should invoke the passed callback when it is done reading (remember to |
1370 |
pass C<$handle> as first argument as all other callbacks do that). |
1371 |
|
1372 |
Note that this is a function, and all types registered this way will be |
1373 |
global, so try to use unique names. |
1374 |
|
1375 |
For examples, see the source of this module (F<perldoc -m AnyEvent::Handle>, |
1376 |
search for C<register_read_type>)). |
1377 |
|
1378 |
=item $handle->stop_read |
1379 |
|
1380 |
=item $handle->start_read |
1381 |
|
1382 |
In rare cases you actually do not want to read anything from the |
1383 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1384 |
any queued callbacks will be executed then. To start reading again, call |
1385 |
C<start_read>. |
1386 |
|
1387 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1388 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1389 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1390 |
there are any read requests in the queue. |
1391 |
|
1392 |
These methods will have no effect when in TLS mode (as TLS doesn't support |
1393 |
half-duplex connections). |
1394 |
|
1395 |
=cut |
1396 |
|
1397 |
sub stop_read { |
1398 |
my ($self) = @_; |
1399 |
|
1400 |
delete $self->{_rw} unless $self->{tls}; |
1401 |
} |
1402 |
|
1403 |
sub start_read { |
1404 |
my ($self) = @_; |
1405 |
|
1406 |
unless ($self->{_rw} || $self->{_eof}) { |
1407 |
Scalar::Util::weaken $self; |
1408 |
|
1409 |
$self->{_rw} = AnyEvent->io (fh => $self->{fh}, poll => "r", cb => sub { |
1410 |
my $rbuf = \($self->{tls} ? my $buf : $self->{rbuf}); |
1411 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size} || 8192, length $$rbuf; |
1412 |
|
1413 |
if ($len > 0) { |
1414 |
$self->{_activity} = AnyEvent->now; |
1415 |
|
1416 |
if ($self->{tls}) { |
1417 |
Net::SSLeay::BIO_write ($self->{_rbio}, $$rbuf); |
1418 |
|
1419 |
&_dotls ($self); |
1420 |
} else { |
1421 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1422 |
} |
1423 |
|
1424 |
} elsif (defined $len) { |
1425 |
delete $self->{_rw}; |
1426 |
$self->{_eof} = 1; |
1427 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1428 |
|
1429 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1430 |
return $self->_error ($!, 1); |
1431 |
} |
1432 |
}); |
1433 |
} |
1434 |
} |
1435 |
|
1436 |
our $ERROR_SYSCALL; |
1437 |
our $ERROR_WANT_READ; |
1438 |
|
1439 |
sub _tls_error { |
1440 |
my ($self, $err) = @_; |
1441 |
|
1442 |
return $self->_error ($!, 1) |
1443 |
if $err == Net::SSLeay::ERROR_SYSCALL (); |
1444 |
|
1445 |
my $err =Net::SSLeay::ERR_error_string (Net::SSLeay::ERR_get_error ()); |
1446 |
|
1447 |
# reduce error string to look less scary |
1448 |
$err =~ s/^error:[0-9a-fA-F]{8}:[^:]+:([^:]+):/\L$1: /; |
1449 |
|
1450 |
if ($self->{_on_starttls}) { |
1451 |
(delete $self->{_on_starttls})->($self, undef, $err); |
1452 |
&_freetls; |
1453 |
} else { |
1454 |
&_freetls; |
1455 |
$self->_error (&Errno::EPROTO, 1, $err); |
1456 |
} |
1457 |
} |
1458 |
|
1459 |
# poll the write BIO and send the data if applicable |
1460 |
# also decode read data if possible |
1461 |
# this is basiclaly our TLS state machine |
1462 |
# more efficient implementations are possible with openssl, |
1463 |
# but not with the buggy and incomplete Net::SSLeay. |
1464 |
sub _dotls { |
1465 |
my ($self) = @_; |
1466 |
|
1467 |
my $tmp; |
1468 |
|
1469 |
if (length $self->{_tls_wbuf}) { |
1470 |
while (($tmp = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1471 |
substr $self->{_tls_wbuf}, 0, $tmp, ""; |
1472 |
} |
1473 |
|
1474 |
$tmp = Net::SSLeay::get_error ($self->{tls}, $tmp); |
1475 |
return $self->_tls_error ($tmp) |
1476 |
if $tmp != $ERROR_WANT_READ |
1477 |
&& ($tmp != $ERROR_SYSCALL || $!); |
1478 |
} |
1479 |
|
1480 |
while (defined ($tmp = Net::SSLeay::read ($self->{tls}))) { |
1481 |
unless (length $tmp) { |
1482 |
$self->{_on_starttls} |
1483 |
and (delete $self->{_on_starttls})->($self, undef, "EOF during handshake"); # ??? |
1484 |
&_freetls; |
1485 |
|
1486 |
if ($self->{on_stoptls}) { |
1487 |
$self->{on_stoptls}($self); |
1488 |
return; |
1489 |
} else { |
1490 |
# let's treat SSL-eof as we treat normal EOF |
1491 |
delete $self->{_rw}; |
1492 |
$self->{_eof} = 1; |
1493 |
} |
1494 |
} |
1495 |
|
1496 |
$self->{_tls_rbuf} .= $tmp; |
1497 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1498 |
$self->{tls} or return; # tls session might have gone away in callback |
1499 |
} |
1500 |
|
1501 |
$tmp = Net::SSLeay::get_error ($self->{tls}, -1); |
1502 |
return $self->_tls_error ($tmp) |
1503 |
if $tmp != $ERROR_WANT_READ |
1504 |
&& ($tmp != $ERROR_SYSCALL || $!); |
1505 |
|
1506 |
while (length ($tmp = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1507 |
$self->{wbuf} .= $tmp; |
1508 |
$self->_drain_wbuf; |
1509 |
} |
1510 |
|
1511 |
$self->{_on_starttls} |
1512 |
and Net::SSLeay::state ($self->{tls}) == Net::SSLeay::ST_OK () |
1513 |
and (delete $self->{_on_starttls})->($self, 1, "TLS/SSL connection established"); |
1514 |
} |
1515 |
|
1516 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1517 |
|
1518 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1519 |
object is created, you can also do that at a later time by calling |
1520 |
C<starttls>. |
1521 |
|
1522 |
The first argument is the same as the C<tls> constructor argument (either |
1523 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1524 |
|
1525 |
The second argument is the optional C<AnyEvent::TLS> object that is used |
1526 |
when AnyEvent::Handle has to create its own TLS connection object, or |
1527 |
a hash reference with C<< key => value >> pairs that will be used to |
1528 |
construct a new context. |
1529 |
|
1530 |
The TLS connection object will end up in C<< $handle->{tls} >>, the TLS |
1531 |
context in C<< $handle->{tls_ctx} >> after this call and can be used or |
1532 |
changed to your liking. Note that the handshake might have already started |
1533 |
when this function returns. |
1534 |
|
1535 |
If it an error to start a TLS handshake more than once per |
1536 |
AnyEvent::Handle object (this is due to bugs in OpenSSL). |
1537 |
|
1538 |
=cut |
1539 |
|
1540 |
our %TLS_CACHE; #TODO not yet documented, should we? |
1541 |
|
1542 |
sub starttls { |
1543 |
my ($self, $ssl, $ctx) = @_; |
1544 |
|
1545 |
require Net::SSLeay; |
1546 |
|
1547 |
Carp::croak "it is an error to call starttls more than once on an AnyEvent::Handle object" |
1548 |
if $self->{tls}; |
1549 |
|
1550 |
$ERROR_SYSCALL = Net::SSLeay::ERROR_SYSCALL (); |
1551 |
$ERROR_WANT_READ = Net::SSLeay::ERROR_WANT_READ (); |
1552 |
|
1553 |
$ctx ||= $self->{tls_ctx}; |
1554 |
|
1555 |
if ("HASH" eq ref $ctx) { |
1556 |
require AnyEvent::TLS; |
1557 |
|
1558 |
local $Carp::CarpLevel = 1; # skip ourselves when creating a new context |
1559 |
|
1560 |
if ($ctx->{cache}) { |
1561 |
my $key = $ctx+0; |
1562 |
$ctx = $TLS_CACHE{$key} ||= new AnyEvent::TLS %$ctx; |
1563 |
} else { |
1564 |
$ctx = new AnyEvent::TLS %$ctx; |
1565 |
} |
1566 |
} |
1567 |
|
1568 |
$self->{tls_ctx} = $ctx || TLS_CTX (); |
1569 |
$self->{tls} = $ssl = $self->{tls_ctx}->_get_session ($ssl, $self, $self->{peername}); |
1570 |
|
1571 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1572 |
# but the openssl maintainers basically said: "trust us, it just works". |
1573 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1574 |
# and mismaintained ssleay-module doesn't even offer them). |
1575 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1576 |
# |
1577 |
# in short: this is a mess. |
1578 |
# |
1579 |
# note that we do not try to keep the length constant between writes as we are required to do. |
1580 |
# we assume that most (but not all) of this insanity only applies to non-blocking cases, |
1581 |
# and we drive openssl fully in blocking mode here. Or maybe we don't - openssl seems to |
1582 |
# have identity issues in that area. |
1583 |
# Net::SSLeay::CTX_set_mode ($ssl, |
1584 |
# (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1585 |
# | (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1586 |
Net::SSLeay::CTX_set_mode ($ssl, 1|2); |
1587 |
|
1588 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1589 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1590 |
|
1591 |
Net::SSLeay::set_bio ($ssl, $self->{_rbio}, $self->{_wbio}); |
1592 |
|
1593 |
$self->{_on_starttls} = sub { $_[0]{on_starttls}(@_) } |
1594 |
if $self->{on_starttls}; |
1595 |
|
1596 |
&_dotls; # need to trigger the initial handshake |
1597 |
$self->start_read; # make sure we actually do read |
1598 |
} |
1599 |
|
1600 |
=item $handle->stoptls |
1601 |
|
1602 |
Shuts down the SSL connection - this makes a proper EOF handshake by |
1603 |
sending a close notify to the other side, but since OpenSSL doesn't |
1604 |
support non-blocking shut downs, it is not possible to re-use the stream |
1605 |
afterwards. |
1606 |
|
1607 |
=cut |
1608 |
|
1609 |
sub stoptls { |
1610 |
my ($self) = @_; |
1611 |
|
1612 |
if ($self->{tls}) { |
1613 |
Net::SSLeay::shutdown ($self->{tls}); |
1614 |
|
1615 |
&_dotls; |
1616 |
|
1617 |
# # we don't give a shit. no, we do, but we can't. no...#d# |
1618 |
# # we, we... have to use openssl :/#d# |
1619 |
# &_freetls;#d# |
1620 |
} |
1621 |
} |
1622 |
|
1623 |
sub _freetls { |
1624 |
my ($self) = @_; |
1625 |
|
1626 |
return unless $self->{tls}; |
1627 |
|
1628 |
$self->{tls_ctx}->_put_session (delete $self->{tls}); |
1629 |
|
1630 |
delete @$self{qw(_rbio _wbio _tls_wbuf _on_starttls)}; |
1631 |
} |
1632 |
|
1633 |
sub DESTROY { |
1634 |
my ($self) = @_; |
1635 |
|
1636 |
&_freetls; |
1637 |
|
1638 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
1639 |
|
1640 |
if ($linger && length $self->{wbuf}) { |
1641 |
my $fh = delete $self->{fh}; |
1642 |
my $wbuf = delete $self->{wbuf}; |
1643 |
|
1644 |
my @linger; |
1645 |
|
1646 |
push @linger, AnyEvent->io (fh => $fh, poll => "w", cb => sub { |
1647 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
1648 |
|
1649 |
if ($len > 0) { |
1650 |
substr $wbuf, 0, $len, ""; |
1651 |
} else { |
1652 |
@linger = (); # end |
1653 |
} |
1654 |
}); |
1655 |
push @linger, AnyEvent->timer (after => $linger, cb => sub { |
1656 |
@linger = (); |
1657 |
}); |
1658 |
} |
1659 |
} |
1660 |
|
1661 |
=item $handle->destroy |
1662 |
|
1663 |
Shuts down the handle object as much as possible - this call ensures that |
1664 |
no further callbacks will be invoked and as many resources as possible |
1665 |
will be freed. You must not call any methods on the object afterwards. |
1666 |
|
1667 |
Normally, you can just "forget" any references to an AnyEvent::Handle |
1668 |
object and it will simply shut down. This works in fatal error and EOF |
1669 |
callbacks, as well as code outside. It does I<NOT> work in a read or write |
1670 |
callback, so when you want to destroy the AnyEvent::Handle object from |
1671 |
within such an callback. You I<MUST> call C<< ->destroy >> explicitly in |
1672 |
that case. |
1673 |
|
1674 |
Destroying the handle object in this way has the advantage that callbacks |
1675 |
will be removed as well, so if those are the only reference holders (as |
1676 |
is common), then one doesn't need to do anything special to break any |
1677 |
reference cycles. |
1678 |
|
1679 |
The handle might still linger in the background and write out remaining |
1680 |
data, as specified by the C<linger> option, however. |
1681 |
|
1682 |
=cut |
1683 |
|
1684 |
sub destroy { |
1685 |
my ($self) = @_; |
1686 |
|
1687 |
$self->DESTROY; |
1688 |
%$self = (); |
1689 |
} |
1690 |
|
1691 |
=item AnyEvent::Handle::TLS_CTX |
1692 |
|
1693 |
This function creates and returns the AnyEvent::TLS object used by default |
1694 |
for TLS mode. |
1695 |
|
1696 |
The context is created by calling L<AnyEvent::TLS> without any arguments. |
1697 |
|
1698 |
=cut |
1699 |
|
1700 |
our $TLS_CTX; |
1701 |
|
1702 |
sub TLS_CTX() { |
1703 |
$TLS_CTX ||= do { |
1704 |
require AnyEvent::TLS; |
1705 |
|
1706 |
new AnyEvent::TLS |
1707 |
} |
1708 |
} |
1709 |
|
1710 |
=back |
1711 |
|
1712 |
|
1713 |
=head1 NONFREQUENTLY ASKED QUESTIONS |
1714 |
|
1715 |
=over 4 |
1716 |
|
1717 |
=item I C<undef> the AnyEvent::Handle reference inside my callback and |
1718 |
still get further invocations! |
1719 |
|
1720 |
That's because AnyEvent::Handle keeps a reference to itself when handling |
1721 |
read or write callbacks. |
1722 |
|
1723 |
It is only safe to "forget" the reference inside EOF or error callbacks, |
1724 |
from within all other callbacks, you need to explicitly call the C<< |
1725 |
->destroy >> method. |
1726 |
|
1727 |
=item I get different callback invocations in TLS mode/Why can't I pause |
1728 |
reading? |
1729 |
|
1730 |
Unlike, say, TCP, TLS connections do not consist of two independent |
1731 |
communication channels, one for each direction. Or put differently. The |
1732 |
read and write directions are not independent of each other: you cannot |
1733 |
write data unless you are also prepared to read, and vice versa. |
1734 |
|
1735 |
This can mean than, in TLS mode, you might get C<on_error> or C<on_eof> |
1736 |
callback invocations when you are not expecting any read data - the reason |
1737 |
is that AnyEvent::Handle always reads in TLS mode. |
1738 |
|
1739 |
During the connection, you have to make sure that you always have a |
1740 |
non-empty read-queue, or an C<on_read> watcher. At the end of the |
1741 |
connection (or when you no longer want to use it) you can call the |
1742 |
C<destroy> method. |
1743 |
|
1744 |
=item How do I read data until the other side closes the connection? |
1745 |
|
1746 |
If you just want to read your data into a perl scalar, the easiest way |
1747 |
to achieve this is by setting an C<on_read> callback that does nothing, |
1748 |
clearing the C<on_eof> callback and in the C<on_error> callback, the data |
1749 |
will be in C<$_[0]{rbuf}>: |
1750 |
|
1751 |
$handle->on_read (sub { }); |
1752 |
$handle->on_eof (undef); |
1753 |
$handle->on_error (sub { |
1754 |
my $data = delete $_[0]{rbuf}; |
1755 |
}); |
1756 |
|
1757 |
The reason to use C<on_error> is that TCP connections, due to latencies |
1758 |
and packets loss, might get closed quite violently with an error, when in |
1759 |
fact, all data has been received. |
1760 |
|
1761 |
It is usually better to use acknowledgements when transferring data, |
1762 |
to make sure the other side hasn't just died and you got the data |
1763 |
intact. This is also one reason why so many internet protocols have an |
1764 |
explicit QUIT command. |
1765 |
|
1766 |
=item I don't want to destroy the handle too early - how do I wait until |
1767 |
all data has been written? |
1768 |
|
1769 |
After writing your last bits of data, set the C<on_drain> callback |
1770 |
and destroy the handle in there - with the default setting of |
1771 |
C<low_water_mark> this will be called precisely when all data has been |
1772 |
written to the socket: |
1773 |
|
1774 |
$handle->push_write (...); |
1775 |
$handle->on_drain (sub { |
1776 |
warn "all data submitted to the kernel\n"; |
1777 |
undef $handle; |
1778 |
}); |
1779 |
|
1780 |
If you just want to queue some data and then signal EOF to the other side, |
1781 |
consider using C<< ->push_shutdown >> instead. |
1782 |
|
1783 |
=item I want to contact a TLS/SSL server, I don't care about security. |
1784 |
|
1785 |
If your TLS server is a pure TLS server (e.g. HTTPS) that only speaks TLS, |
1786 |
simply connect to it and then create the AnyEvent::Handle with the C<tls> |
1787 |
parameter: |
1788 |
|
1789 |
tcp_connect $host, $port, sub { |
1790 |
my ($fh) = @_; |
1791 |
|
1792 |
my $handle = new AnyEvent::Handle |
1793 |
fh => $fh, |
1794 |
tls => "connect", |
1795 |
on_error => sub { ... }; |
1796 |
|
1797 |
$handle->push_write (...); |
1798 |
}; |
1799 |
|
1800 |
=item I want to contact a TLS/SSL server, I do care about security. |
1801 |
|
1802 |
Then you should additionally enable certificate verification, including |
1803 |
peername verification, if the protocol you use supports it (see |
1804 |
L<AnyEvent::TLS>, C<verify_peername>). |
1805 |
|
1806 |
E.g. for HTTPS: |
1807 |
|
1808 |
tcp_connect $host, $port, sub { |
1809 |
my ($fh) = @_; |
1810 |
|
1811 |
my $handle = new AnyEvent::Handle |
1812 |
fh => $fh, |
1813 |
peername => $host, |
1814 |
tls => "connect", |
1815 |
tls_ctx => { verify => 1, verify_peername => "https" }, |
1816 |
... |
1817 |
|
1818 |
Note that you must specify the hostname you connected to (or whatever |
1819 |
"peername" the protocol needs) as the C<peername> argument, otherwise no |
1820 |
peername verification will be done. |
1821 |
|
1822 |
The above will use the system-dependent default set of trusted CA |
1823 |
certificates. If you want to check against a specific CA, add the |
1824 |
C<ca_file> (or C<ca_cert>) arguments to C<tls_ctx>: |
1825 |
|
1826 |
tls_ctx => { |
1827 |
verify => 1, |
1828 |
verify_peername => "https", |
1829 |
ca_file => "my-ca-cert.pem", |
1830 |
}, |
1831 |
|
1832 |
=item I want to create a TLS/SSL server, how do I do that? |
1833 |
|
1834 |
Well, you first need to get a server certificate and key. You have |
1835 |
three options: a) ask a CA (buy one, use cacert.org etc.) b) create a |
1836 |
self-signed certificate (cheap. check the search engine of your choice, |
1837 |
there are many tutorials on the net) or c) make your own CA (tinyca2 is a |
1838 |
nice program for that purpose). |
1839 |
|
1840 |
Then create a file with your private key (in PEM format, see |
1841 |
L<AnyEvent::TLS>), followed by the certificate (also in PEM format). The |
1842 |
file should then look like this: |
1843 |
|
1844 |
-----BEGIN RSA PRIVATE KEY----- |
1845 |
...header data |
1846 |
... lots of base64'y-stuff |
1847 |
-----END RSA PRIVATE KEY----- |
1848 |
|
1849 |
-----BEGIN CERTIFICATE----- |
1850 |
... lots of base64'y-stuff |
1851 |
-----END CERTIFICATE----- |
1852 |
|
1853 |
The important bits are the "PRIVATE KEY" and "CERTIFICATE" parts. Then |
1854 |
specify this file as C<cert_file>: |
1855 |
|
1856 |
tcp_server undef, $port, sub { |
1857 |
my ($fh) = @_; |
1858 |
|
1859 |
my $handle = new AnyEvent::Handle |
1860 |
fh => $fh, |
1861 |
tls => "accept", |
1862 |
tls_ctx => { cert_file => "my-server-keycert.pem" }, |
1863 |
... |
1864 |
|
1865 |
When you have intermediate CA certificates that your clients might not |
1866 |
know about, just append them to the C<cert_file>. |
1867 |
|
1868 |
=back |
1869 |
|
1870 |
|
1871 |
=head1 SUBCLASSING AnyEvent::Handle |
1872 |
|
1873 |
In many cases, you might want to subclass AnyEvent::Handle. |
1874 |
|
1875 |
To make this easier, a given version of AnyEvent::Handle uses these |
1876 |
conventions: |
1877 |
|
1878 |
=over 4 |
1879 |
|
1880 |
=item * all constructor arguments become object members. |
1881 |
|
1882 |
At least initially, when you pass a C<tls>-argument to the constructor it |
1883 |
will end up in C<< $handle->{tls} >>. Those members might be changed or |
1884 |
mutated later on (for example C<tls> will hold the TLS connection object). |
1885 |
|
1886 |
=item * other object member names are prefixed with an C<_>. |
1887 |
|
1888 |
All object members not explicitly documented (internal use) are prefixed |
1889 |
with an underscore character, so the remaining non-C<_>-namespace is free |
1890 |
for use for subclasses. |
1891 |
|
1892 |
=item * all members not documented here and not prefixed with an underscore |
1893 |
are free to use in subclasses. |
1894 |
|
1895 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
1896 |
member variables, but thats just life, at least it is documented. |
1897 |
|
1898 |
=back |
1899 |
|
1900 |
=head1 AUTHOR |
1901 |
|
1902 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
1903 |
|
1904 |
=cut |
1905 |
|
1906 |
1; # End of AnyEvent::Handle |