1 |
package AnyEvent::Handle; |
2 |
|
3 |
no warnings; |
4 |
use strict qw(subs vars); |
5 |
|
6 |
use AnyEvent (); |
7 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
8 |
use Scalar::Util (); |
9 |
use Carp (); |
10 |
use Fcntl (); |
11 |
use Errno qw(EAGAIN EINTR); |
12 |
|
13 |
=head1 NAME |
14 |
|
15 |
AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent |
16 |
|
17 |
=cut |
18 |
|
19 |
our $VERSION = 4.3; |
20 |
|
21 |
=head1 SYNOPSIS |
22 |
|
23 |
use AnyEvent; |
24 |
use AnyEvent::Handle; |
25 |
|
26 |
my $cv = AnyEvent->condvar; |
27 |
|
28 |
my $handle = |
29 |
AnyEvent::Handle->new ( |
30 |
fh => \*STDIN, |
31 |
on_eof => sub { |
32 |
$cv->broadcast; |
33 |
}, |
34 |
); |
35 |
|
36 |
# send some request line |
37 |
$handle->push_write ("getinfo\015\012"); |
38 |
|
39 |
# read the response line |
40 |
$handle->push_read (line => sub { |
41 |
my ($handle, $line) = @_; |
42 |
warn "read line <$line>\n"; |
43 |
$cv->send; |
44 |
}); |
45 |
|
46 |
$cv->recv; |
47 |
|
48 |
=head1 DESCRIPTION |
49 |
|
50 |
This module is a helper module to make it easier to do event-based I/O on |
51 |
filehandles. For utility functions for doing non-blocking connects and accepts |
52 |
on sockets see L<AnyEvent::Util>. |
53 |
|
54 |
The L<AnyEvent::Intro> tutorial contains some well-documented |
55 |
AnyEvent::Handle examples. |
56 |
|
57 |
In the following, when the documentation refers to of "bytes" then this |
58 |
means characters. As sysread and syswrite are used for all I/O, their |
59 |
treatment of characters applies to this module as well. |
60 |
|
61 |
All callbacks will be invoked with the handle object as their first |
62 |
argument. |
63 |
|
64 |
=head2 SIGPIPE is not handled by this module |
65 |
|
66 |
SIGPIPE is not handled by this module, so one of the practical |
67 |
requirements of using it is to ignore SIGPIPE (C<$SIG{PIPE} = |
68 |
'IGNORE'>). At least, this is highly recommend in a networked program: If |
69 |
you use AnyEvent::Handle in a filter program (like sort), exiting on |
70 |
SIGPIPE is probably the right thing to do. |
71 |
|
72 |
=head1 METHODS |
73 |
|
74 |
=over 4 |
75 |
|
76 |
=item B<new (%args)> |
77 |
|
78 |
The constructor supports these arguments (all as key => value pairs). |
79 |
|
80 |
=over 4 |
81 |
|
82 |
=item fh => $filehandle [MANDATORY] |
83 |
|
84 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
85 |
|
86 |
NOTE: The filehandle will be set to non-blocking mode (using |
87 |
C<AnyEvent::Util::fh_nonblocking>) by the constructor and needs to stay in |
88 |
that mode. |
89 |
|
90 |
=item on_eof => $cb->($handle) |
91 |
|
92 |
Set the callback to be called when an end-of-file condition is detected, |
93 |
i.e. in the case of a socket, when the other side has closed the |
94 |
connection cleanly. |
95 |
|
96 |
For sockets, this just means that the other side has stopped sending data, |
97 |
you can still try to write data, and, in fact, one can return from the eof |
98 |
callback and continue writing data, as only the read part has been shut |
99 |
down. |
100 |
|
101 |
While not mandatory, it is I<highly> recommended to set an eof callback, |
102 |
otherwise you might end up with a closed socket while you are still |
103 |
waiting for data. |
104 |
|
105 |
If an EOF condition has been detected but no C<on_eof> callback has been |
106 |
set, then a fatal error will be raised with C<$!> set to <0>. |
107 |
|
108 |
=item on_error => $cb->($handle, $fatal) |
109 |
|
110 |
This is the error callback, which is called when, well, some error |
111 |
occured, such as not being able to resolve the hostname, failure to |
112 |
connect or a read error. |
113 |
|
114 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
115 |
fatal errors the handle object will be shut down and will not be usable |
116 |
(but you are free to look at the current C<< ->rbuf >>). Examples of fatal |
117 |
errors are an EOF condition with active (but unsatisifable) read watchers |
118 |
(C<EPIPE>) or I/O errors. |
119 |
|
120 |
Non-fatal errors can be retried by simply returning, but it is recommended |
121 |
to simply ignore this parameter and instead abondon the handle object |
122 |
when this callback is invoked. Examples of non-fatal errors are timeouts |
123 |
C<ETIMEDOUT>) or badly-formatted data (C<EBADMSG>). |
124 |
|
125 |
On callback entrance, the value of C<$!> contains the operating system |
126 |
error (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT> or C<EBADMSG>). |
127 |
|
128 |
While not mandatory, it is I<highly> recommended to set this callback, as |
129 |
you will not be notified of errors otherwise. The default simply calls |
130 |
C<croak>. |
131 |
|
132 |
=item on_read => $cb->($handle) |
133 |
|
134 |
This sets the default read callback, which is called when data arrives |
135 |
and no read request is in the queue (unlike read queue callbacks, this |
136 |
callback will only be called when at least one octet of data is in the |
137 |
read buffer). |
138 |
|
139 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
140 |
method or access the C<$handle->{rbuf}> member directly. |
141 |
|
142 |
When an EOF condition is detected then AnyEvent::Handle will first try to |
143 |
feed all the remaining data to the queued callbacks and C<on_read> before |
144 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
145 |
error will be raised (with C<$!> set to C<EPIPE>). |
146 |
|
147 |
=item on_drain => $cb->($handle) |
148 |
|
149 |
This sets the callback that is called when the write buffer becomes empty |
150 |
(or when the callback is set and the buffer is empty already). |
151 |
|
152 |
To append to the write buffer, use the C<< ->push_write >> method. |
153 |
|
154 |
This callback is useful when you don't want to put all of your write data |
155 |
into the queue at once, for example, when you want to write the contents |
156 |
of some file to the socket you might not want to read the whole file into |
157 |
memory and push it into the queue, but instead only read more data from |
158 |
the file when the write queue becomes empty. |
159 |
|
160 |
=item timeout => $fractional_seconds |
161 |
|
162 |
If non-zero, then this enables an "inactivity" timeout: whenever this many |
163 |
seconds pass without a successful read or write on the underlying file |
164 |
handle, the C<on_timeout> callback will be invoked (and if that one is |
165 |
missing, a non-fatal C<ETIMEDOUT> error will be raised). |
166 |
|
167 |
Note that timeout processing is also active when you currently do not have |
168 |
any outstanding read or write requests: If you plan to keep the connection |
169 |
idle then you should disable the timout temporarily or ignore the timeout |
170 |
in the C<on_timeout> callback, in which case AnyEvent::Handle will simply |
171 |
restart the timeout. |
172 |
|
173 |
Zero (the default) disables this timeout. |
174 |
|
175 |
=item on_timeout => $cb->($handle) |
176 |
|
177 |
Called whenever the inactivity timeout passes. If you return from this |
178 |
callback, then the timeout will be reset as if some activity had happened, |
179 |
so this condition is not fatal in any way. |
180 |
|
181 |
=item rbuf_max => <bytes> |
182 |
|
183 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
184 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
185 |
avoid some forms of denial-of-service attacks. |
186 |
|
187 |
For example, a server accepting connections from untrusted sources should |
188 |
be configured to accept only so-and-so much data that it cannot act on |
189 |
(for example, when expecting a line, an attacker could send an unlimited |
190 |
amount of data without a callback ever being called as long as the line |
191 |
isn't finished). |
192 |
|
193 |
=item autocork => <boolean> |
194 |
|
195 |
When disabled (the default), then C<push_write> will try to immediately |
196 |
write the data to the handle, if possible. This avoids having to register |
197 |
a write watcher and wait for the next event loop iteration, but can |
198 |
be inefficient if you write multiple small chunks (on the wire, this |
199 |
disadvantage is usually avoided by your kernel's nagle algorithm, see |
200 |
C<no_delay>, but this option can save costly syscalls). |
201 |
|
202 |
When enabled, then writes will always be queued till the next event loop |
203 |
iteration. This is efficient when you do many small writes per iteration, |
204 |
but less efficient when you do a single write only per iteration (or when |
205 |
the write buffer often is full). It also increases write latency. |
206 |
|
207 |
=item no_delay => <boolean> |
208 |
|
209 |
When doing small writes on sockets, your operating system kernel might |
210 |
wait a bit for more data before actually sending it out. This is called |
211 |
the Nagle algorithm, and usually it is beneficial. |
212 |
|
213 |
In some situations you want as low a delay as possible, which can be |
214 |
accomplishd by setting this option to a true value. |
215 |
|
216 |
The default is your opertaing system's default behaviour (most likely |
217 |
enabled), this option explicitly enables or disables it, if possible. |
218 |
|
219 |
=item read_size => <bytes> |
220 |
|
221 |
The default read block size (the amount of bytes this module will |
222 |
try to read during each loop iteration, which affects memory |
223 |
requirements). Default: C<8192>. |
224 |
|
225 |
=item low_water_mark => <bytes> |
226 |
|
227 |
Sets the amount of bytes (default: C<0>) that make up an "empty" write |
228 |
buffer: If the write reaches this size or gets even samller it is |
229 |
considered empty. |
230 |
|
231 |
Sometimes it can be beneficial (for performance reasons) to add data to |
232 |
the write buffer before it is fully drained, but this is a rare case, as |
233 |
the operating system kernel usually buffers data as well, so the default |
234 |
is good in almost all cases. |
235 |
|
236 |
=item linger => <seconds> |
237 |
|
238 |
If non-zero (default: C<3600>), then the destructor of the |
239 |
AnyEvent::Handle object will check whether there is still outstanding |
240 |
write data and will install a watcher that will write this data to the |
241 |
socket. No errors will be reported (this mostly matches how the operating |
242 |
system treats outstanding data at socket close time). |
243 |
|
244 |
This will not work for partial TLS data that could not be encoded |
245 |
yet. This data will be lost. Calling the C<stoptls> method in time might |
246 |
help. |
247 |
|
248 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
249 |
|
250 |
When this parameter is given, it enables TLS (SSL) mode, that means |
251 |
AnyEvent will start a TLS handshake as soon as the conenction has been |
252 |
established and will transparently encrypt/decrypt data afterwards. |
253 |
|
254 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
255 |
automatically when you try to create a TLS handle): this module doesn't |
256 |
have a dependency on that module, so if your module requires it, you have |
257 |
to add the dependency yourself. |
258 |
|
259 |
Unlike TCP, TLS has a server and client side: for the TLS server side, use |
260 |
C<accept>, and for the TLS client side of a connection, use C<connect> |
261 |
mode. |
262 |
|
263 |
You can also provide your own TLS connection object, but you have |
264 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
265 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
266 |
AnyEvent::Handle. |
267 |
|
268 |
See the C<< ->starttls >> method for when need to start TLS negotiation later. |
269 |
|
270 |
=item tls_ctx => $ssl_ctx |
271 |
|
272 |
Use the given C<Net::SSLeay::CTX> object to create the new TLS connection |
273 |
(unless a connection object was specified directly). If this parameter is |
274 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
275 |
|
276 |
=item json => JSON or JSON::XS object |
277 |
|
278 |
This is the json coder object used by the C<json> read and write types. |
279 |
|
280 |
If you don't supply it, then AnyEvent::Handle will create and use a |
281 |
suitable one (on demand), which will write and expect UTF-8 encoded JSON |
282 |
texts. |
283 |
|
284 |
Note that you are responsible to depend on the JSON module if you want to |
285 |
use this functionality, as AnyEvent does not have a dependency itself. |
286 |
|
287 |
=back |
288 |
|
289 |
=cut |
290 |
|
291 |
sub new { |
292 |
my $class = shift; |
293 |
|
294 |
my $self = bless { @_ }, $class; |
295 |
|
296 |
$self->{fh} or Carp::croak "mandatory argument fh is missing"; |
297 |
|
298 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
299 |
|
300 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}) |
301 |
if $self->{tls}; |
302 |
|
303 |
$self->{_activity} = AnyEvent->now; |
304 |
$self->_timeout; |
305 |
|
306 |
$self->on_drain (delete $self->{on_drain}) if exists $self->{on_drain}; |
307 |
$self->no_delay (delete $self->{no_delay}) if exists $self->{no_delay}; |
308 |
|
309 |
$self->start_read |
310 |
if $self->{on_read}; |
311 |
|
312 |
$self |
313 |
} |
314 |
|
315 |
sub _shutdown { |
316 |
my ($self) = @_; |
317 |
|
318 |
delete $self->{_tw}; |
319 |
delete $self->{_rw}; |
320 |
delete $self->{_ww}; |
321 |
delete $self->{fh}; |
322 |
|
323 |
&_freetls; |
324 |
|
325 |
delete $self->{on_read}; |
326 |
delete $self->{_queue}; |
327 |
} |
328 |
|
329 |
sub _error { |
330 |
my ($self, $errno, $fatal) = @_; |
331 |
|
332 |
$self->_shutdown |
333 |
if $fatal; |
334 |
|
335 |
$! = $errno; |
336 |
|
337 |
if ($self->{on_error}) { |
338 |
$self->{on_error}($self, $fatal); |
339 |
} else { |
340 |
Carp::croak "AnyEvent::Handle uncaught error: $!"; |
341 |
} |
342 |
} |
343 |
|
344 |
=item $fh = $handle->fh |
345 |
|
346 |
This method returns the file handle used to create the L<AnyEvent::Handle> object. |
347 |
|
348 |
=cut |
349 |
|
350 |
sub fh { $_[0]{fh} } |
351 |
|
352 |
=item $handle->on_error ($cb) |
353 |
|
354 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
355 |
|
356 |
=cut |
357 |
|
358 |
sub on_error { |
359 |
$_[0]{on_error} = $_[1]; |
360 |
} |
361 |
|
362 |
=item $handle->on_eof ($cb) |
363 |
|
364 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
365 |
|
366 |
=cut |
367 |
|
368 |
sub on_eof { |
369 |
$_[0]{on_eof} = $_[1]; |
370 |
} |
371 |
|
372 |
=item $handle->on_timeout ($cb) |
373 |
|
374 |
Replace the current C<on_timeout> callback, or disables the callback (but |
375 |
not the timeout) if C<$cb> = C<undef>. See the C<timeout> constructor |
376 |
argument and method. |
377 |
|
378 |
=cut |
379 |
|
380 |
sub on_timeout { |
381 |
$_[0]{on_timeout} = $_[1]; |
382 |
} |
383 |
|
384 |
=item $handle->autocork ($boolean) |
385 |
|
386 |
Enables or disables the current autocork behaviour (see C<autocork> |
387 |
constructor argument). |
388 |
|
389 |
=cut |
390 |
|
391 |
=item $handle->no_delay ($boolean) |
392 |
|
393 |
Enables or disables the C<no_delay> setting (see constructor argument of |
394 |
the same name for details). |
395 |
|
396 |
=cut |
397 |
|
398 |
sub no_delay { |
399 |
$_[0]{no_delay} = $_[1]; |
400 |
|
401 |
eval { |
402 |
local $SIG{__DIE__}; |
403 |
setsockopt $_[0]{fh}, &Socket::IPPROTO_TCP, &Socket::TCP_NODELAY, int $_[1]; |
404 |
}; |
405 |
} |
406 |
|
407 |
############################################################################# |
408 |
|
409 |
=item $handle->timeout ($seconds) |
410 |
|
411 |
Configures (or disables) the inactivity timeout. |
412 |
|
413 |
=cut |
414 |
|
415 |
sub timeout { |
416 |
my ($self, $timeout) = @_; |
417 |
|
418 |
$self->{timeout} = $timeout; |
419 |
$self->_timeout; |
420 |
} |
421 |
|
422 |
# reset the timeout watcher, as neccessary |
423 |
# also check for time-outs |
424 |
sub _timeout { |
425 |
my ($self) = @_; |
426 |
|
427 |
if ($self->{timeout}) { |
428 |
my $NOW = AnyEvent->now; |
429 |
|
430 |
# when would the timeout trigger? |
431 |
my $after = $self->{_activity} + $self->{timeout} - $NOW; |
432 |
|
433 |
# now or in the past already? |
434 |
if ($after <= 0) { |
435 |
$self->{_activity} = $NOW; |
436 |
|
437 |
if ($self->{on_timeout}) { |
438 |
$self->{on_timeout}($self); |
439 |
} else { |
440 |
$self->_error (&Errno::ETIMEDOUT); |
441 |
} |
442 |
|
443 |
# callback could have changed timeout value, optimise |
444 |
return unless $self->{timeout}; |
445 |
|
446 |
# calculate new after |
447 |
$after = $self->{timeout}; |
448 |
} |
449 |
|
450 |
Scalar::Util::weaken $self; |
451 |
return unless $self; # ->error could have destroyed $self |
452 |
|
453 |
$self->{_tw} ||= AnyEvent->timer (after => $after, cb => sub { |
454 |
delete $self->{_tw}; |
455 |
$self->_timeout; |
456 |
}); |
457 |
} else { |
458 |
delete $self->{_tw}; |
459 |
} |
460 |
} |
461 |
|
462 |
############################################################################# |
463 |
|
464 |
=back |
465 |
|
466 |
=head2 WRITE QUEUE |
467 |
|
468 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
469 |
for reading. |
470 |
|
471 |
The write queue is very simple: you can add data to its end, and |
472 |
AnyEvent::Handle will automatically try to get rid of it for you. |
473 |
|
474 |
When data could be written and the write buffer is shorter then the low |
475 |
water mark, the C<on_drain> callback will be invoked. |
476 |
|
477 |
=over 4 |
478 |
|
479 |
=item $handle->on_drain ($cb) |
480 |
|
481 |
Sets the C<on_drain> callback or clears it (see the description of |
482 |
C<on_drain> in the constructor). |
483 |
|
484 |
=cut |
485 |
|
486 |
sub on_drain { |
487 |
my ($self, $cb) = @_; |
488 |
|
489 |
$self->{on_drain} = $cb; |
490 |
|
491 |
$cb->($self) |
492 |
if $cb && $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}); |
493 |
} |
494 |
|
495 |
=item $handle->push_write ($data) |
496 |
|
497 |
Queues the given scalar to be written. You can push as much data as you |
498 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
499 |
buffers it independently of the kernel. |
500 |
|
501 |
=cut |
502 |
|
503 |
sub _drain_wbuf { |
504 |
my ($self) = @_; |
505 |
|
506 |
if (!$self->{_ww} && length $self->{wbuf}) { |
507 |
|
508 |
Scalar::Util::weaken $self; |
509 |
|
510 |
my $cb = sub { |
511 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
512 |
|
513 |
if ($len >= 0) { |
514 |
substr $self->{wbuf}, 0, $len, ""; |
515 |
|
516 |
$self->{_activity} = AnyEvent->now; |
517 |
|
518 |
$self->{on_drain}($self) |
519 |
if $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}) |
520 |
&& $self->{on_drain}; |
521 |
|
522 |
delete $self->{_ww} unless length $self->{wbuf}; |
523 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
524 |
$self->_error ($!, 1); |
525 |
} |
526 |
}; |
527 |
|
528 |
# try to write data immediately |
529 |
$cb->() unless $self->{autocork}; |
530 |
|
531 |
# if still data left in wbuf, we need to poll |
532 |
$self->{_ww} = AnyEvent->io (fh => $self->{fh}, poll => "w", cb => $cb) |
533 |
if length $self->{wbuf}; |
534 |
}; |
535 |
} |
536 |
|
537 |
our %WH; |
538 |
|
539 |
sub register_write_type($$) { |
540 |
$WH{$_[0]} = $_[1]; |
541 |
} |
542 |
|
543 |
sub push_write { |
544 |
my $self = shift; |
545 |
|
546 |
if (@_ > 1) { |
547 |
my $type = shift; |
548 |
|
549 |
@_ = ($WH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_write") |
550 |
->($self, @_); |
551 |
} |
552 |
|
553 |
if ($self->{tls}) { |
554 |
$self->{_tls_wbuf} .= $_[0]; |
555 |
|
556 |
&_dotls ($self); |
557 |
} else { |
558 |
$self->{wbuf} .= $_[0]; |
559 |
$self->_drain_wbuf; |
560 |
} |
561 |
} |
562 |
|
563 |
=item $handle->push_write (type => @args) |
564 |
|
565 |
Instead of formatting your data yourself, you can also let this module do |
566 |
the job by specifying a type and type-specific arguments. |
567 |
|
568 |
Predefined types are (if you have ideas for additional types, feel free to |
569 |
drop by and tell us): |
570 |
|
571 |
=over 4 |
572 |
|
573 |
=item netstring => $string |
574 |
|
575 |
Formats the given value as netstring |
576 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
577 |
|
578 |
=cut |
579 |
|
580 |
register_write_type netstring => sub { |
581 |
my ($self, $string) = @_; |
582 |
|
583 |
(length $string) . ":$string," |
584 |
}; |
585 |
|
586 |
=item packstring => $format, $data |
587 |
|
588 |
An octet string prefixed with an encoded length. The encoding C<$format> |
589 |
uses the same format as a Perl C<pack> format, but must specify a single |
590 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
591 |
optional C<!>, C<< < >> or C<< > >> modifier). |
592 |
|
593 |
=cut |
594 |
|
595 |
register_write_type packstring => sub { |
596 |
my ($self, $format, $string) = @_; |
597 |
|
598 |
pack "$format/a*", $string |
599 |
}; |
600 |
|
601 |
=item json => $array_or_hashref |
602 |
|
603 |
Encodes the given hash or array reference into a JSON object. Unless you |
604 |
provide your own JSON object, this means it will be encoded to JSON text |
605 |
in UTF-8. |
606 |
|
607 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
608 |
one end of a handle and read them at the other end without using any |
609 |
additional framing. |
610 |
|
611 |
The generated JSON text is guaranteed not to contain any newlines: While |
612 |
this module doesn't need delimiters after or between JSON texts to be |
613 |
able to read them, many other languages depend on that. |
614 |
|
615 |
A simple RPC protocol that interoperates easily with others is to send |
616 |
JSON arrays (or objects, although arrays are usually the better choice as |
617 |
they mimic how function argument passing works) and a newline after each |
618 |
JSON text: |
619 |
|
620 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
621 |
$handle->push_write ("\012"); |
622 |
|
623 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
624 |
rely on the fact that the newline will be skipped as leading whitespace: |
625 |
|
626 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
627 |
|
628 |
Other languages could read single lines terminated by a newline and pass |
629 |
this line into their JSON decoder of choice. |
630 |
|
631 |
=cut |
632 |
|
633 |
register_write_type json => sub { |
634 |
my ($self, $ref) = @_; |
635 |
|
636 |
require JSON; |
637 |
|
638 |
$self->{json} ? $self->{json}->encode ($ref) |
639 |
: JSON::encode_json ($ref) |
640 |
}; |
641 |
|
642 |
=item storable => $reference |
643 |
|
644 |
Freezes the given reference using L<Storable> and writes it to the |
645 |
handle. Uses the C<nfreeze> format. |
646 |
|
647 |
=cut |
648 |
|
649 |
register_write_type storable => sub { |
650 |
my ($self, $ref) = @_; |
651 |
|
652 |
require Storable; |
653 |
|
654 |
pack "w/a*", Storable::nfreeze ($ref) |
655 |
}; |
656 |
|
657 |
=back |
658 |
|
659 |
=item AnyEvent::Handle::register_write_type type => $coderef->($handle, @args) |
660 |
|
661 |
This function (not method) lets you add your own types to C<push_write>. |
662 |
Whenever the given C<type> is used, C<push_write> will invoke the code |
663 |
reference with the handle object and the remaining arguments. |
664 |
|
665 |
The code reference is supposed to return a single octet string that will |
666 |
be appended to the write buffer. |
667 |
|
668 |
Note that this is a function, and all types registered this way will be |
669 |
global, so try to use unique names. |
670 |
|
671 |
=cut |
672 |
|
673 |
############################################################################# |
674 |
|
675 |
=back |
676 |
|
677 |
=head2 READ QUEUE |
678 |
|
679 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
680 |
for reading. |
681 |
|
682 |
The read queue is more complex than the write queue. It can be used in two |
683 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
684 |
a queue. |
685 |
|
686 |
In the simple case, you just install an C<on_read> callback and whenever |
687 |
new data arrives, it will be called. You can then remove some data (if |
688 |
enough is there) from the read buffer (C<< $handle->rbuf >>). Or you cna |
689 |
leave the data there if you want to accumulate more (e.g. when only a |
690 |
partial message has been received so far). |
691 |
|
692 |
In the more complex case, you want to queue multiple callbacks. In this |
693 |
case, AnyEvent::Handle will call the first queued callback each time new |
694 |
data arrives (also the first time it is queued) and removes it when it has |
695 |
done its job (see C<push_read>, below). |
696 |
|
697 |
This way you can, for example, push three line-reads, followed by reading |
698 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
699 |
|
700 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
701 |
the specified number of bytes which give an XML datagram. |
702 |
|
703 |
# in the default state, expect some header bytes |
704 |
$handle->on_read (sub { |
705 |
# some data is here, now queue the length-header-read (4 octets) |
706 |
shift->unshift_read (chunk => 4, sub { |
707 |
# header arrived, decode |
708 |
my $len = unpack "N", $_[1]; |
709 |
|
710 |
# now read the payload |
711 |
shift->unshift_read (chunk => $len, sub { |
712 |
my $xml = $_[1]; |
713 |
# handle xml |
714 |
}); |
715 |
}); |
716 |
}); |
717 |
|
718 |
Example 2: Implement a client for a protocol that replies either with "OK" |
719 |
and another line or "ERROR" for the first request that is sent, and 64 |
720 |
bytes for the second request. Due to the availability of a queue, we can |
721 |
just pipeline sending both requests and manipulate the queue as necessary |
722 |
in the callbacks. |
723 |
|
724 |
When the first callback is called and sees an "OK" response, it will |
725 |
C<unshift> another line-read. This line-read will be queued I<before> the |
726 |
64-byte chunk callback. |
727 |
|
728 |
# request one, returns either "OK + extra line" or "ERROR" |
729 |
$handle->push_write ("request 1\015\012"); |
730 |
|
731 |
# we expect "ERROR" or "OK" as response, so push a line read |
732 |
$handle->push_read (line => sub { |
733 |
# if we got an "OK", we have to _prepend_ another line, |
734 |
# so it will be read before the second request reads its 64 bytes |
735 |
# which are already in the queue when this callback is called |
736 |
# we don't do this in case we got an error |
737 |
if ($_[1] eq "OK") { |
738 |
$_[0]->unshift_read (line => sub { |
739 |
my $response = $_[1]; |
740 |
... |
741 |
}); |
742 |
} |
743 |
}); |
744 |
|
745 |
# request two, simply returns 64 octets |
746 |
$handle->push_write ("request 2\015\012"); |
747 |
|
748 |
# simply read 64 bytes, always |
749 |
$handle->push_read (chunk => 64, sub { |
750 |
my $response = $_[1]; |
751 |
... |
752 |
}); |
753 |
|
754 |
=over 4 |
755 |
|
756 |
=cut |
757 |
|
758 |
sub _drain_rbuf { |
759 |
my ($self) = @_; |
760 |
|
761 |
local $self->{_in_drain} = 1; |
762 |
|
763 |
if ( |
764 |
defined $self->{rbuf_max} |
765 |
&& $self->{rbuf_max} < length $self->{rbuf} |
766 |
) { |
767 |
$self->_error (&Errno::ENOSPC, 1), return; |
768 |
} |
769 |
|
770 |
while () { |
771 |
my $len = length $self->{rbuf}; |
772 |
|
773 |
if (my $cb = shift @{ $self->{_queue} }) { |
774 |
unless ($cb->($self)) { |
775 |
if ($self->{_eof}) { |
776 |
# no progress can be made (not enough data and no data forthcoming) |
777 |
$self->_error (&Errno::EPIPE, 1), return; |
778 |
} |
779 |
|
780 |
unshift @{ $self->{_queue} }, $cb; |
781 |
last; |
782 |
} |
783 |
} elsif ($self->{on_read}) { |
784 |
last unless $len; |
785 |
|
786 |
$self->{on_read}($self); |
787 |
|
788 |
if ( |
789 |
$len == length $self->{rbuf} # if no data has been consumed |
790 |
&& !@{ $self->{_queue} } # and the queue is still empty |
791 |
&& $self->{on_read} # but we still have on_read |
792 |
) { |
793 |
# no further data will arrive |
794 |
# so no progress can be made |
795 |
$self->_error (&Errno::EPIPE, 1), return |
796 |
if $self->{_eof}; |
797 |
|
798 |
last; # more data might arrive |
799 |
} |
800 |
} else { |
801 |
# read side becomes idle |
802 |
delete $self->{_rw} unless $self->{tls}; |
803 |
last; |
804 |
} |
805 |
} |
806 |
|
807 |
if ($self->{_eof}) { |
808 |
if ($self->{on_eof}) { |
809 |
$self->{on_eof}($self) |
810 |
} else { |
811 |
$self->_error (0, 1); |
812 |
} |
813 |
} |
814 |
|
815 |
# may need to restart read watcher |
816 |
unless ($self->{_rw}) { |
817 |
$self->start_read |
818 |
if $self->{on_read} || @{ $self->{_queue} }; |
819 |
} |
820 |
} |
821 |
|
822 |
=item $handle->on_read ($cb) |
823 |
|
824 |
This replaces the currently set C<on_read> callback, or clears it (when |
825 |
the new callback is C<undef>). See the description of C<on_read> in the |
826 |
constructor. |
827 |
|
828 |
=cut |
829 |
|
830 |
sub on_read { |
831 |
my ($self, $cb) = @_; |
832 |
|
833 |
$self->{on_read} = $cb; |
834 |
$self->_drain_rbuf if $cb && !$self->{_in_drain}; |
835 |
} |
836 |
|
837 |
=item $handle->rbuf |
838 |
|
839 |
Returns the read buffer (as a modifiable lvalue). |
840 |
|
841 |
You can access the read buffer directly as the C<< ->{rbuf} >> member, if |
842 |
you want. |
843 |
|
844 |
NOTE: The read buffer should only be used or modified if the C<on_read>, |
845 |
C<push_read> or C<unshift_read> methods are used. The other read methods |
846 |
automatically manage the read buffer. |
847 |
|
848 |
=cut |
849 |
|
850 |
sub rbuf : lvalue { |
851 |
$_[0]{rbuf} |
852 |
} |
853 |
|
854 |
=item $handle->push_read ($cb) |
855 |
|
856 |
=item $handle->unshift_read ($cb) |
857 |
|
858 |
Append the given callback to the end of the queue (C<push_read>) or |
859 |
prepend it (C<unshift_read>). |
860 |
|
861 |
The callback is called each time some additional read data arrives. |
862 |
|
863 |
It must check whether enough data is in the read buffer already. |
864 |
|
865 |
If not enough data is available, it must return the empty list or a false |
866 |
value, in which case it will be called repeatedly until enough data is |
867 |
available (or an error condition is detected). |
868 |
|
869 |
If enough data was available, then the callback must remove all data it is |
870 |
interested in (which can be none at all) and return a true value. After returning |
871 |
true, it will be removed from the queue. |
872 |
|
873 |
=cut |
874 |
|
875 |
our %RH; |
876 |
|
877 |
sub register_read_type($$) { |
878 |
$RH{$_[0]} = $_[1]; |
879 |
} |
880 |
|
881 |
sub push_read { |
882 |
my $self = shift; |
883 |
my $cb = pop; |
884 |
|
885 |
if (@_) { |
886 |
my $type = shift; |
887 |
|
888 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_read") |
889 |
->($self, $cb, @_); |
890 |
} |
891 |
|
892 |
push @{ $self->{_queue} }, $cb; |
893 |
$self->_drain_rbuf unless $self->{_in_drain}; |
894 |
} |
895 |
|
896 |
sub unshift_read { |
897 |
my $self = shift; |
898 |
my $cb = pop; |
899 |
|
900 |
if (@_) { |
901 |
my $type = shift; |
902 |
|
903 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::unshift_read") |
904 |
->($self, $cb, @_); |
905 |
} |
906 |
|
907 |
|
908 |
unshift @{ $self->{_queue} }, $cb; |
909 |
$self->_drain_rbuf unless $self->{_in_drain}; |
910 |
} |
911 |
|
912 |
=item $handle->push_read (type => @args, $cb) |
913 |
|
914 |
=item $handle->unshift_read (type => @args, $cb) |
915 |
|
916 |
Instead of providing a callback that parses the data itself you can chose |
917 |
between a number of predefined parsing formats, for chunks of data, lines |
918 |
etc. |
919 |
|
920 |
Predefined types are (if you have ideas for additional types, feel free to |
921 |
drop by and tell us): |
922 |
|
923 |
=over 4 |
924 |
|
925 |
=item chunk => $octets, $cb->($handle, $data) |
926 |
|
927 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
928 |
data read to the callback. The callback will never be called with less |
929 |
data. |
930 |
|
931 |
Example: read 2 bytes. |
932 |
|
933 |
$handle->push_read (chunk => 2, sub { |
934 |
warn "yay ", unpack "H*", $_[1]; |
935 |
}); |
936 |
|
937 |
=cut |
938 |
|
939 |
register_read_type chunk => sub { |
940 |
my ($self, $cb, $len) = @_; |
941 |
|
942 |
sub { |
943 |
$len <= length $_[0]{rbuf} or return; |
944 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
945 |
1 |
946 |
} |
947 |
}; |
948 |
|
949 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
950 |
|
951 |
The callback will be called only once a full line (including the end of |
952 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
953 |
marker) will be passed to the callback as second argument (C<$line>), and |
954 |
the end of line marker as the third argument (C<$eol>). |
955 |
|
956 |
The end of line marker, C<$eol>, can be either a string, in which case it |
957 |
will be interpreted as a fixed record end marker, or it can be a regex |
958 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
959 |
regular expression. |
960 |
|
961 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
962 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
963 |
protocols). |
964 |
|
965 |
Partial lines at the end of the stream will never be returned, as they are |
966 |
not marked by the end of line marker. |
967 |
|
968 |
=cut |
969 |
|
970 |
register_read_type line => sub { |
971 |
my ($self, $cb, $eol) = @_; |
972 |
|
973 |
if (@_ < 3) { |
974 |
# this is more than twice as fast as the generic code below |
975 |
sub { |
976 |
$_[0]{rbuf} =~ s/^([^\015\012]*)(\015?\012)// or return; |
977 |
|
978 |
$cb->($_[0], $1, $2); |
979 |
1 |
980 |
} |
981 |
} else { |
982 |
$eol = quotemeta $eol unless ref $eol; |
983 |
$eol = qr|^(.*?)($eol)|s; |
984 |
|
985 |
sub { |
986 |
$_[0]{rbuf} =~ s/$eol// or return; |
987 |
|
988 |
$cb->($_[0], $1, $2); |
989 |
1 |
990 |
} |
991 |
} |
992 |
}; |
993 |
|
994 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
995 |
|
996 |
Makes a regex match against the regex object C<$accept> and returns |
997 |
everything up to and including the match. |
998 |
|
999 |
Example: read a single line terminated by '\n'. |
1000 |
|
1001 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
1002 |
|
1003 |
If C<$reject> is given and not undef, then it determines when the data is |
1004 |
to be rejected: it is matched against the data when the C<$accept> regex |
1005 |
does not match and generates an C<EBADMSG> error when it matches. This is |
1006 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
1007 |
receive buffer overflow). |
1008 |
|
1009 |
Example: expect a single decimal number followed by whitespace, reject |
1010 |
anything else (not the use of an anchor). |
1011 |
|
1012 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
1013 |
|
1014 |
If C<$skip> is given and not C<undef>, then it will be matched against |
1015 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
1016 |
and everything preceding and including the match will be accepted |
1017 |
unconditionally. This is useful to skip large amounts of data that you |
1018 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
1019 |
have to start matching from the beginning. This is purely an optimisation |
1020 |
and is usually worth only when you expect more than a few kilobytes. |
1021 |
|
1022 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
1023 |
expect the header to be very large (it isn't in practise, but...), we use |
1024 |
a skip regex to skip initial portions. The skip regex is tricky in that |
1025 |
it only accepts something not ending in either \015 or \012, as these are |
1026 |
required for the accept regex. |
1027 |
|
1028 |
$handle->push_read (regex => |
1029 |
qr<\015\012\015\012>, |
1030 |
undef, # no reject |
1031 |
qr<^.*[^\015\012]>, |
1032 |
sub { ... }); |
1033 |
|
1034 |
=cut |
1035 |
|
1036 |
register_read_type regex => sub { |
1037 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
1038 |
|
1039 |
my $data; |
1040 |
my $rbuf = \$self->{rbuf}; |
1041 |
|
1042 |
sub { |
1043 |
# accept |
1044 |
if ($$rbuf =~ $accept) { |
1045 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1046 |
$cb->($self, $data); |
1047 |
return 1; |
1048 |
} |
1049 |
|
1050 |
# reject |
1051 |
if ($reject && $$rbuf =~ $reject) { |
1052 |
$self->_error (&Errno::EBADMSG); |
1053 |
} |
1054 |
|
1055 |
# skip |
1056 |
if ($skip && $$rbuf =~ $skip) { |
1057 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1058 |
} |
1059 |
|
1060 |
() |
1061 |
} |
1062 |
}; |
1063 |
|
1064 |
=item netstring => $cb->($handle, $string) |
1065 |
|
1066 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
1067 |
|
1068 |
Throws an error with C<$!> set to EBADMSG on format violations. |
1069 |
|
1070 |
=cut |
1071 |
|
1072 |
register_read_type netstring => sub { |
1073 |
my ($self, $cb) = @_; |
1074 |
|
1075 |
sub { |
1076 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
1077 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
1078 |
$self->_error (&Errno::EBADMSG); |
1079 |
} |
1080 |
return; |
1081 |
} |
1082 |
|
1083 |
my $len = $1; |
1084 |
|
1085 |
$self->unshift_read (chunk => $len, sub { |
1086 |
my $string = $_[1]; |
1087 |
$_[0]->unshift_read (chunk => 1, sub { |
1088 |
if ($_[1] eq ",") { |
1089 |
$cb->($_[0], $string); |
1090 |
} else { |
1091 |
$self->_error (&Errno::EBADMSG); |
1092 |
} |
1093 |
}); |
1094 |
}); |
1095 |
|
1096 |
1 |
1097 |
} |
1098 |
}; |
1099 |
|
1100 |
=item packstring => $format, $cb->($handle, $string) |
1101 |
|
1102 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1103 |
uses the same format as a Perl C<pack> format, but must specify a single |
1104 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1105 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1106 |
|
1107 |
For example, DNS over TCP uses a prefix of C<n> (2 octet network order), |
1108 |
EPP uses a prefix of C<N> (4 octtes). |
1109 |
|
1110 |
Example: read a block of data prefixed by its length in BER-encoded |
1111 |
format (very efficient). |
1112 |
|
1113 |
$handle->push_read (packstring => "w", sub { |
1114 |
my ($handle, $data) = @_; |
1115 |
}); |
1116 |
|
1117 |
=cut |
1118 |
|
1119 |
register_read_type packstring => sub { |
1120 |
my ($self, $cb, $format) = @_; |
1121 |
|
1122 |
sub { |
1123 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1124 |
defined (my $len = eval { unpack $format, $_[0]{rbuf} }) |
1125 |
or return; |
1126 |
|
1127 |
$format = length pack $format, $len; |
1128 |
|
1129 |
# bypass unshift if we already have the remaining chunk |
1130 |
if ($format + $len <= length $_[0]{rbuf}) { |
1131 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1132 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1133 |
$cb->($_[0], $data); |
1134 |
} else { |
1135 |
# remove prefix |
1136 |
substr $_[0]{rbuf}, 0, $format, ""; |
1137 |
|
1138 |
# read remaining chunk |
1139 |
$_[0]->unshift_read (chunk => $len, $cb); |
1140 |
} |
1141 |
|
1142 |
1 |
1143 |
} |
1144 |
}; |
1145 |
|
1146 |
=item json => $cb->($handle, $hash_or_arrayref) |
1147 |
|
1148 |
Reads a JSON object or array, decodes it and passes it to the callback. |
1149 |
|
1150 |
If a C<json> object was passed to the constructor, then that will be used |
1151 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1152 |
|
1153 |
This read type uses the incremental parser available with JSON version |
1154 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1155 |
dependency on your own: this module will load the JSON module, but |
1156 |
AnyEvent does not depend on it itself. |
1157 |
|
1158 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1159 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1160 |
the C<json> write type description, above, for an actual example. |
1161 |
|
1162 |
=cut |
1163 |
|
1164 |
register_read_type json => sub { |
1165 |
my ($self, $cb) = @_; |
1166 |
|
1167 |
require JSON; |
1168 |
|
1169 |
my $data; |
1170 |
my $rbuf = \$self->{rbuf}; |
1171 |
|
1172 |
my $json = $self->{json} ||= JSON->new->utf8; |
1173 |
|
1174 |
sub { |
1175 |
my $ref = $json->incr_parse ($self->{rbuf}); |
1176 |
|
1177 |
if ($ref) { |
1178 |
$self->{rbuf} = $json->incr_text; |
1179 |
$json->incr_text = ""; |
1180 |
$cb->($self, $ref); |
1181 |
|
1182 |
1 |
1183 |
} else { |
1184 |
$self->{rbuf} = ""; |
1185 |
() |
1186 |
} |
1187 |
} |
1188 |
}; |
1189 |
|
1190 |
=item storable => $cb->($handle, $ref) |
1191 |
|
1192 |
Deserialises a L<Storable> frozen representation as written by the |
1193 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1194 |
data). |
1195 |
|
1196 |
Raises C<EBADMSG> error if the data could not be decoded. |
1197 |
|
1198 |
=cut |
1199 |
|
1200 |
register_read_type storable => sub { |
1201 |
my ($self, $cb) = @_; |
1202 |
|
1203 |
require Storable; |
1204 |
|
1205 |
sub { |
1206 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1207 |
defined (my $len = eval { unpack "w", $_[0]{rbuf} }) |
1208 |
or return; |
1209 |
|
1210 |
my $format = length pack "w", $len; |
1211 |
|
1212 |
# bypass unshift if we already have the remaining chunk |
1213 |
if ($format + $len <= length $_[0]{rbuf}) { |
1214 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1215 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1216 |
$cb->($_[0], Storable::thaw ($data)); |
1217 |
} else { |
1218 |
# remove prefix |
1219 |
substr $_[0]{rbuf}, 0, $format, ""; |
1220 |
|
1221 |
# read remaining chunk |
1222 |
$_[0]->unshift_read (chunk => $len, sub { |
1223 |
if (my $ref = eval { Storable::thaw ($_[1]) }) { |
1224 |
$cb->($_[0], $ref); |
1225 |
} else { |
1226 |
$self->_error (&Errno::EBADMSG); |
1227 |
} |
1228 |
}); |
1229 |
} |
1230 |
|
1231 |
1 |
1232 |
} |
1233 |
}; |
1234 |
|
1235 |
=back |
1236 |
|
1237 |
=item AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args) |
1238 |
|
1239 |
This function (not method) lets you add your own types to C<push_read>. |
1240 |
|
1241 |
Whenever the given C<type> is used, C<push_read> will invoke the code |
1242 |
reference with the handle object, the callback and the remaining |
1243 |
arguments. |
1244 |
|
1245 |
The code reference is supposed to return a callback (usually a closure) |
1246 |
that works as a plain read callback (see C<< ->push_read ($cb) >>). |
1247 |
|
1248 |
It should invoke the passed callback when it is done reading (remember to |
1249 |
pass C<$handle> as first argument as all other callbacks do that). |
1250 |
|
1251 |
Note that this is a function, and all types registered this way will be |
1252 |
global, so try to use unique names. |
1253 |
|
1254 |
For examples, see the source of this module (F<perldoc -m AnyEvent::Handle>, |
1255 |
search for C<register_read_type>)). |
1256 |
|
1257 |
=item $handle->stop_read |
1258 |
|
1259 |
=item $handle->start_read |
1260 |
|
1261 |
In rare cases you actually do not want to read anything from the |
1262 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1263 |
any queued callbacks will be executed then. To start reading again, call |
1264 |
C<start_read>. |
1265 |
|
1266 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1267 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1268 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1269 |
there are any read requests in the queue. |
1270 |
|
1271 |
These methods will have no effect when in TLS mode (as TLS doesn't support |
1272 |
half-duplex connections). |
1273 |
|
1274 |
=cut |
1275 |
|
1276 |
sub stop_read { |
1277 |
my ($self) = @_; |
1278 |
|
1279 |
delete $self->{_rw} unless $self->{tls}; |
1280 |
} |
1281 |
|
1282 |
sub start_read { |
1283 |
my ($self) = @_; |
1284 |
|
1285 |
unless ($self->{_rw} || $self->{_eof}) { |
1286 |
Scalar::Util::weaken $self; |
1287 |
|
1288 |
$self->{_rw} = AnyEvent->io (fh => $self->{fh}, poll => "r", cb => sub { |
1289 |
my $rbuf = \($self->{tls} ? my $buf : $self->{rbuf}); |
1290 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size} || 8192, length $$rbuf; |
1291 |
|
1292 |
if ($len > 0) { |
1293 |
$self->{_activity} = AnyEvent->now; |
1294 |
|
1295 |
if ($self->{tls}) { |
1296 |
Net::SSLeay::BIO_write ($self->{_rbio}, $$rbuf); |
1297 |
|
1298 |
&_dotls ($self); |
1299 |
} else { |
1300 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1301 |
} |
1302 |
|
1303 |
} elsif (defined $len) { |
1304 |
delete $self->{_rw}; |
1305 |
$self->{_eof} = 1; |
1306 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1307 |
|
1308 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1309 |
return $self->_error ($!, 1); |
1310 |
} |
1311 |
}); |
1312 |
} |
1313 |
} |
1314 |
|
1315 |
# poll the write BIO and send the data if applicable |
1316 |
sub _dotls { |
1317 |
my ($self) = @_; |
1318 |
|
1319 |
my $tmp; |
1320 |
|
1321 |
if (length $self->{_tls_wbuf}) { |
1322 |
while (($tmp = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1323 |
substr $self->{_tls_wbuf}, 0, $tmp, ""; |
1324 |
} |
1325 |
} |
1326 |
|
1327 |
while (defined ($tmp = Net::SSLeay::read ($self->{tls}))) { |
1328 |
unless (length $tmp) { |
1329 |
# let's treat SSL-eof as we treat normal EOF |
1330 |
delete $self->{_rw}; |
1331 |
$self->{_eof} = 1; |
1332 |
&_freetls; |
1333 |
} |
1334 |
|
1335 |
$self->{rbuf} .= $tmp; |
1336 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1337 |
$self->{tls} or return; # tls session might have gone away in callback |
1338 |
} |
1339 |
|
1340 |
$tmp = Net::SSLeay::get_error ($self->{tls}, -1); |
1341 |
|
1342 |
if ($tmp != Net::SSLeay::ERROR_WANT_READ ()) { |
1343 |
if ($tmp == Net::SSLeay::ERROR_SYSCALL ()) { |
1344 |
return $self->_error ($!, 1); |
1345 |
} elsif ($tmp == Net::SSLeay::ERROR_SSL ()) { |
1346 |
return $self->_error (&Errno::EIO, 1); |
1347 |
} |
1348 |
|
1349 |
# all other errors are fine for our purposes |
1350 |
} |
1351 |
|
1352 |
while (length ($tmp = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1353 |
$self->{wbuf} .= $tmp; |
1354 |
$self->_drain_wbuf; |
1355 |
} |
1356 |
} |
1357 |
|
1358 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1359 |
|
1360 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1361 |
object is created, you can also do that at a later time by calling |
1362 |
C<starttls>. |
1363 |
|
1364 |
The first argument is the same as the C<tls> constructor argument (either |
1365 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1366 |
|
1367 |
The second argument is the optional C<Net::SSLeay::CTX> object that is |
1368 |
used when AnyEvent::Handle has to create its own TLS connection object. |
1369 |
|
1370 |
The TLS connection object will end up in C<< $handle->{tls} >> after this |
1371 |
call and can be used or changed to your liking. Note that the handshake |
1372 |
might have already started when this function returns. |
1373 |
|
1374 |
If it an error to start a TLS handshake more than once per |
1375 |
AnyEvent::Handle object (this is due to bugs in OpenSSL). |
1376 |
|
1377 |
=cut |
1378 |
|
1379 |
sub starttls { |
1380 |
my ($self, $ssl, $ctx) = @_; |
1381 |
|
1382 |
require Net::SSLeay; |
1383 |
|
1384 |
Carp::croak "it is an error to call starttls more than once on an Anyevent::Handle object" |
1385 |
if $self->{tls}; |
1386 |
|
1387 |
if ($ssl eq "accept") { |
1388 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1389 |
Net::SSLeay::set_accept_state ($ssl); |
1390 |
} elsif ($ssl eq "connect") { |
1391 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1392 |
Net::SSLeay::set_connect_state ($ssl); |
1393 |
} |
1394 |
|
1395 |
$self->{tls} = $ssl; |
1396 |
|
1397 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1398 |
# but the openssl maintainers basically said: "trust us, it just works". |
1399 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1400 |
# and mismaintained ssleay-module doesn't even offer them). |
1401 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1402 |
# |
1403 |
# in short: this is a mess. |
1404 |
# |
1405 |
# note that we do not try to keep the length constant between writes as we are required to do. |
1406 |
# we assume that most (but not all) of this insanity only applies to non-blocking cases, |
1407 |
# and we drive openssl fully in blocking mode here. Or maybe we don't - openssl seems to |
1408 |
# have identity issues in that area. |
1409 |
Net::SSLeay::CTX_set_mode ($self->{tls}, |
1410 |
(eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1411 |
| (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1412 |
|
1413 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1414 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1415 |
|
1416 |
Net::SSLeay::set_bio ($ssl, $self->{_rbio}, $self->{_wbio}); |
1417 |
|
1418 |
&_dotls; # need to trigger the initial handshake |
1419 |
$self->start_read; # make sure we actually do read |
1420 |
} |
1421 |
|
1422 |
=item $handle->stoptls |
1423 |
|
1424 |
Shuts down the SSL connection - this makes a proper EOF handshake by |
1425 |
sending a close notify to the other side, but since OpenSSL doesn't |
1426 |
support non-blocking shut downs, it is not possible to re-use the stream |
1427 |
afterwards. |
1428 |
|
1429 |
=cut |
1430 |
|
1431 |
sub stoptls { |
1432 |
my ($self) = @_; |
1433 |
|
1434 |
if ($self->{tls}) { |
1435 |
Net::SSLeay::shutdown ($self->{tls}); |
1436 |
|
1437 |
&_dotls; |
1438 |
|
1439 |
# we don't give a shit. no, we do, but we can't. no... |
1440 |
# we, we... have to use openssl :/ |
1441 |
&_freetls; |
1442 |
} |
1443 |
} |
1444 |
|
1445 |
sub _freetls { |
1446 |
my ($self) = @_; |
1447 |
|
1448 |
return unless $self->{tls}; |
1449 |
|
1450 |
Net::SSLeay::free (delete $self->{tls}); |
1451 |
|
1452 |
delete @$self{qw(_rbio _wbio _tls_wbuf)}; |
1453 |
} |
1454 |
|
1455 |
sub DESTROY { |
1456 |
my $self = shift; |
1457 |
|
1458 |
&_freetls; |
1459 |
|
1460 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
1461 |
|
1462 |
if ($linger && length $self->{wbuf}) { |
1463 |
my $fh = delete $self->{fh}; |
1464 |
my $wbuf = delete $self->{wbuf}; |
1465 |
|
1466 |
my @linger; |
1467 |
|
1468 |
push @linger, AnyEvent->io (fh => $fh, poll => "w", cb => sub { |
1469 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
1470 |
|
1471 |
if ($len > 0) { |
1472 |
substr $wbuf, 0, $len, ""; |
1473 |
} else { |
1474 |
@linger = (); # end |
1475 |
} |
1476 |
}); |
1477 |
push @linger, AnyEvent->timer (after => $linger, cb => sub { |
1478 |
@linger = (); |
1479 |
}); |
1480 |
} |
1481 |
} |
1482 |
|
1483 |
=item AnyEvent::Handle::TLS_CTX |
1484 |
|
1485 |
This function creates and returns the Net::SSLeay::CTX object used by |
1486 |
default for TLS mode. |
1487 |
|
1488 |
The context is created like this: |
1489 |
|
1490 |
Net::SSLeay::load_error_strings; |
1491 |
Net::SSLeay::SSLeay_add_ssl_algorithms; |
1492 |
Net::SSLeay::randomize; |
1493 |
|
1494 |
my $CTX = Net::SSLeay::CTX_new; |
1495 |
|
1496 |
Net::SSLeay::CTX_set_options $CTX, Net::SSLeay::OP_ALL |
1497 |
|
1498 |
=cut |
1499 |
|
1500 |
our $TLS_CTX; |
1501 |
|
1502 |
sub TLS_CTX() { |
1503 |
$TLS_CTX || do { |
1504 |
require Net::SSLeay; |
1505 |
|
1506 |
Net::SSLeay::load_error_strings (); |
1507 |
Net::SSLeay::SSLeay_add_ssl_algorithms (); |
1508 |
Net::SSLeay::randomize (); |
1509 |
|
1510 |
$TLS_CTX = Net::SSLeay::CTX_new (); |
1511 |
|
1512 |
Net::SSLeay::CTX_set_options ($TLS_CTX, Net::SSLeay::OP_ALL ()); |
1513 |
|
1514 |
$TLS_CTX |
1515 |
} |
1516 |
} |
1517 |
|
1518 |
=back |
1519 |
|
1520 |
|
1521 |
=head1 NONFREQUENTLY ASKED QUESTIONS |
1522 |
|
1523 |
=over 4 |
1524 |
|
1525 |
=item How do I read data until the other side closes the connection? |
1526 |
|
1527 |
If you just want to read your data into a perl scalar, the easiest way |
1528 |
to achieve this is by setting an C<on_read> callback that does nothing, |
1529 |
clearing the C<on_eof> callback and in the C<on_error> callback, the data |
1530 |
will be in C<$_[0]{rbuf}>: |
1531 |
|
1532 |
$handle->on_read (sub { }); |
1533 |
$handle->on_eof (undef); |
1534 |
$handle->on_error (sub { |
1535 |
my $data = delete $_[0]{rbuf}; |
1536 |
undef $handle; |
1537 |
}); |
1538 |
|
1539 |
The reason to use C<on_error> is that TCP connections, due to latencies |
1540 |
and packets loss, might get closed quite violently with an error, when in |
1541 |
fact, all data has been received. |
1542 |
|
1543 |
It is usually better to use acknowledgements when transfering data, |
1544 |
to make sure the other side hasn't just died and you got the data |
1545 |
intact. This is also one reason why so many internet protocols have an |
1546 |
explicit QUIT command. |
1547 |
|
1548 |
|
1549 |
=item I don't want to destroy the handle too early - how do I wait until |
1550 |
all data has been written? |
1551 |
|
1552 |
After writing your last bits of data, set the C<on_drain> callback |
1553 |
and destroy the handle in there - with the default setting of |
1554 |
C<low_water_mark> this will be called precisely when all data has been |
1555 |
written to the socket: |
1556 |
|
1557 |
$handle->push_write (...); |
1558 |
$handle->on_drain (sub { |
1559 |
warn "all data submitted to the kernel\n"; |
1560 |
undef $handle; |
1561 |
}); |
1562 |
|
1563 |
=back |
1564 |
|
1565 |
|
1566 |
=head1 SUBCLASSING AnyEvent::Handle |
1567 |
|
1568 |
In many cases, you might want to subclass AnyEvent::Handle. |
1569 |
|
1570 |
To make this easier, a given version of AnyEvent::Handle uses these |
1571 |
conventions: |
1572 |
|
1573 |
=over 4 |
1574 |
|
1575 |
=item * all constructor arguments become object members. |
1576 |
|
1577 |
At least initially, when you pass a C<tls>-argument to the constructor it |
1578 |
will end up in C<< $handle->{tls} >>. Those members might be changed or |
1579 |
mutated later on (for example C<tls> will hold the TLS connection object). |
1580 |
|
1581 |
=item * other object member names are prefixed with an C<_>. |
1582 |
|
1583 |
All object members not explicitly documented (internal use) are prefixed |
1584 |
with an underscore character, so the remaining non-C<_>-namespace is free |
1585 |
for use for subclasses. |
1586 |
|
1587 |
=item * all members not documented here and not prefixed with an underscore |
1588 |
are free to use in subclasses. |
1589 |
|
1590 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
1591 |
member variables, but thats just life, at least it is documented. |
1592 |
|
1593 |
=back |
1594 |
|
1595 |
=head1 AUTHOR |
1596 |
|
1597 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
1598 |
|
1599 |
=cut |
1600 |
|
1601 |
1; # End of AnyEvent::Handle |