1 |
=head1 NAME |
2 |
|
3 |
AnyEvent::Handle - non-blocking I/O on streaming handles via AnyEvent |
4 |
|
5 |
=head1 SYNOPSIS |
6 |
|
7 |
use AnyEvent; |
8 |
use AnyEvent::Handle; |
9 |
|
10 |
my $cv = AnyEvent->condvar; |
11 |
|
12 |
my $hdl; $hdl = new AnyEvent::Handle |
13 |
fh => \*STDIN, |
14 |
on_error => sub { |
15 |
my ($hdl, $fatal, $msg) = @_; |
16 |
warn "got error $msg\n"; |
17 |
$hdl->destroy; |
18 |
$cv->send; |
19 |
}; |
20 |
|
21 |
# send some request line |
22 |
$hdl->push_write ("getinfo\015\012"); |
23 |
|
24 |
# read the response line |
25 |
$hdl->push_read (line => sub { |
26 |
my ($hdl, $line) = @_; |
27 |
warn "got line <$line>\n"; |
28 |
$cv->send; |
29 |
}); |
30 |
|
31 |
$cv->recv; |
32 |
|
33 |
=head1 DESCRIPTION |
34 |
|
35 |
This is a helper module to make it easier to do event-based I/O on |
36 |
stream-based filehandles (sockets, pipes, and other stream things). |
37 |
|
38 |
The L<AnyEvent::Intro> tutorial contains some well-documented |
39 |
AnyEvent::Handle examples. |
40 |
|
41 |
In the following, where the documentation refers to "bytes", it means |
42 |
characters. As sysread and syswrite are used for all I/O, their |
43 |
treatment of characters applies to this module as well. |
44 |
|
45 |
At the very minimum, you should specify C<fh> or C<connect>, and the |
46 |
C<on_error> callback. |
47 |
|
48 |
All callbacks will be invoked with the handle object as their first |
49 |
argument. |
50 |
|
51 |
=cut |
52 |
|
53 |
package AnyEvent::Handle; |
54 |
|
55 |
use Scalar::Util (); |
56 |
use List::Util (); |
57 |
use Carp (); |
58 |
use Errno qw(EAGAIN EINTR); |
59 |
|
60 |
use AnyEvent (); BEGIN { AnyEvent::common_sense } |
61 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
62 |
|
63 |
our $VERSION = $AnyEvent::VERSION; |
64 |
|
65 |
sub _load_func($) { |
66 |
my $func = $_[0]; |
67 |
|
68 |
unless (defined &$func) { |
69 |
my $pkg = $func; |
70 |
do { |
71 |
$pkg =~ s/::[^:]+$// |
72 |
or return; |
73 |
eval "require $pkg"; |
74 |
} until defined &$func; |
75 |
} |
76 |
|
77 |
\&$func |
78 |
} |
79 |
|
80 |
sub MAX_READ_SIZE() { 131072 } |
81 |
|
82 |
=head1 METHODS |
83 |
|
84 |
=over 4 |
85 |
|
86 |
=item $handle = B<new> AnyEvent::Handle fh => $filehandle, key => value... |
87 |
|
88 |
The constructor supports these arguments (all as C<< key => value >> pairs). |
89 |
|
90 |
=over 4 |
91 |
|
92 |
=item fh => $filehandle [C<fh> or C<connect> MANDATORY] |
93 |
|
94 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
95 |
NOTE: The filehandle will be set to non-blocking mode (using |
96 |
C<AnyEvent::Util::fh_nonblocking>) by the constructor and needs to stay in |
97 |
that mode. |
98 |
|
99 |
=item connect => [$host, $service] [C<fh> or C<connect> MANDATORY] |
100 |
|
101 |
Try to connect to the specified host and service (port), using |
102 |
C<AnyEvent::Socket::tcp_connect>. The C<$host> additionally becomes the |
103 |
default C<peername>. |
104 |
|
105 |
You have to specify either this parameter, or C<fh>, above. |
106 |
|
107 |
It is possible to push requests on the read and write queues, and modify |
108 |
properties of the stream, even while AnyEvent::Handle is connecting. |
109 |
|
110 |
When this parameter is specified, then the C<on_prepare>, |
111 |
C<on_connect_error> and C<on_connect> callbacks will be called under the |
112 |
appropriate circumstances: |
113 |
|
114 |
=over 4 |
115 |
|
116 |
=item on_prepare => $cb->($handle) |
117 |
|
118 |
This (rarely used) callback is called before a new connection is |
119 |
attempted, but after the file handle has been created. It could be used to |
120 |
prepare the file handle with parameters required for the actual connect |
121 |
(as opposed to settings that can be changed when the connection is already |
122 |
established). |
123 |
|
124 |
The return value of this callback should be the connect timeout value in |
125 |
seconds (or C<0>, or C<undef>, or the empty list, to indicate that the |
126 |
default timeout is to be used). |
127 |
|
128 |
=item on_connect => $cb->($handle, $host, $port, $retry->()) |
129 |
|
130 |
This callback is called when a connection has been successfully established. |
131 |
|
132 |
The peer's numeric host and port (the socket peername) are passed as |
133 |
parameters, together with a retry callback. |
134 |
|
135 |
If, for some reason, the handle is not acceptable, calling C<$retry> |
136 |
will continue with the next connection target (in case of multi-homed |
137 |
hosts or SRV records there can be multiple connection endpoints). At the |
138 |
time it is called the read and write queues, eof status, tls status and |
139 |
similar properties of the handle will have been reset. |
140 |
|
141 |
In most cases, you should ignore the C<$retry> parameter. |
142 |
|
143 |
=item on_connect_error => $cb->($handle, $message) |
144 |
|
145 |
This callback is called when the connection could not be |
146 |
established. C<$!> will contain the relevant error code, and C<$message> a |
147 |
message describing it (usually the same as C<"$!">). |
148 |
|
149 |
If this callback isn't specified, then C<on_error> will be called with a |
150 |
fatal error instead. |
151 |
|
152 |
=back |
153 |
|
154 |
=item on_error => $cb->($handle, $fatal, $message) |
155 |
|
156 |
This is the error callback, which is called when, well, some error |
157 |
occured, such as not being able to resolve the hostname, failure to |
158 |
connect, or a read error. |
159 |
|
160 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
161 |
fatal errors the handle object will be destroyed (by a call to C<< -> |
162 |
destroy >>) after invoking the error callback (which means you are free to |
163 |
examine the handle object). Examples of fatal errors are an EOF condition |
164 |
with active (but unsatisfiable) read watchers (C<EPIPE>) or I/O errors. In |
165 |
cases where the other side can close the connection at will, it is |
166 |
often easiest to not report C<EPIPE> errors in this callback. |
167 |
|
168 |
AnyEvent::Handle tries to find an appropriate error code for you to check |
169 |
against, but in some cases (TLS errors), this does not work well. It is |
170 |
recommended to always output the C<$message> argument in human-readable |
171 |
error messages (it's usually the same as C<"$!">). |
172 |
|
173 |
Non-fatal errors can be retried by returning, but it is recommended |
174 |
to simply ignore this parameter and instead abondon the handle object |
175 |
when this callback is invoked. Examples of non-fatal errors are timeouts |
176 |
C<ETIMEDOUT>) or badly-formatted data (C<EBADMSG>). |
177 |
|
178 |
On entry to the callback, the value of C<$!> contains the operating |
179 |
system error code (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT>, C<EBADMSG> or |
180 |
C<EPROTO>). |
181 |
|
182 |
While not mandatory, it is I<highly> recommended to set this callback, as |
183 |
you will not be notified of errors otherwise. The default just calls |
184 |
C<croak>. |
185 |
|
186 |
=item on_read => $cb->($handle) |
187 |
|
188 |
This sets the default read callback, which is called when data arrives |
189 |
and no read request is in the queue (unlike read queue callbacks, this |
190 |
callback will only be called when at least one octet of data is in the |
191 |
read buffer). |
192 |
|
193 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
194 |
method or access the C<< $handle->{rbuf} >> member directly. Note that you |
195 |
must not enlarge or modify the read buffer, you can only remove data at |
196 |
the beginning from it. |
197 |
|
198 |
You can also call C<< ->push_read (...) >> or any other function that |
199 |
modifies the read queue. Or do both. Or ... |
200 |
|
201 |
When an EOF condition is detected, AnyEvent::Handle will first try to |
202 |
feed all the remaining data to the queued callbacks and C<on_read> before |
203 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
204 |
error will be raised (with C<$!> set to C<EPIPE>). |
205 |
|
206 |
Note that, unlike requests in the read queue, an C<on_read> callback |
207 |
doesn't mean you I<require> some data: if there is an EOF and there |
208 |
are outstanding read requests then an error will be flagged. With an |
209 |
C<on_read> callback, the C<on_eof> callback will be invoked. |
210 |
|
211 |
=item on_eof => $cb->($handle) |
212 |
|
213 |
Set the callback to be called when an end-of-file condition is detected, |
214 |
i.e. in the case of a socket, when the other side has closed the |
215 |
connection cleanly, and there are no outstanding read requests in the |
216 |
queue (if there are read requests, then an EOF counts as an unexpected |
217 |
connection close and will be flagged as an error). |
218 |
|
219 |
For sockets, this just means that the other side has stopped sending data, |
220 |
you can still try to write data, and, in fact, one can return from the EOF |
221 |
callback and continue writing data, as only the read part has been shut |
222 |
down. |
223 |
|
224 |
If an EOF condition has been detected but no C<on_eof> callback has been |
225 |
set, then a fatal error will be raised with C<$!> set to <0>. |
226 |
|
227 |
=item on_drain => $cb->($handle) |
228 |
|
229 |
This sets the callback that is called when the write buffer becomes empty |
230 |
(or immediately if the buffer is empty already). |
231 |
|
232 |
To append to the write buffer, use the C<< ->push_write >> method. |
233 |
|
234 |
This callback is useful when you don't want to put all of your write data |
235 |
into the queue at once, for example, when you want to write the contents |
236 |
of some file to the socket you might not want to read the whole file into |
237 |
memory and push it into the queue, but instead only read more data from |
238 |
the file when the write queue becomes empty. |
239 |
|
240 |
=item timeout => $fractional_seconds |
241 |
|
242 |
=item rtimeout => $fractional_seconds |
243 |
|
244 |
=item wtimeout => $fractional_seconds |
245 |
|
246 |
If non-zero, then these enables an "inactivity" timeout: whenever this |
247 |
many seconds pass without a successful read or write on the underlying |
248 |
file handle (or a call to C<timeout_reset>), the C<on_timeout> callback |
249 |
will be invoked (and if that one is missing, a non-fatal C<ETIMEDOUT> |
250 |
error will be raised). |
251 |
|
252 |
There are three variants of the timeouts that work independently |
253 |
of each other, for both read and write, just read, and just write: |
254 |
C<timeout>, C<rtimeout> and C<wtimeout>, with corresponding callbacks |
255 |
C<on_timeout>, C<on_rtimeout> and C<on_wtimeout>, and reset functions |
256 |
C<timeout_reset>, C<rtimeout_reset>, and C<wtimeout_reset>. |
257 |
|
258 |
Note that timeout processing is active even when you do not have |
259 |
any outstanding read or write requests: If you plan to keep the connection |
260 |
idle then you should disable the timeout temporarily or ignore the timeout |
261 |
in the C<on_timeout> callback, in which case AnyEvent::Handle will simply |
262 |
restart the timeout. |
263 |
|
264 |
Zero (the default) disables this timeout. |
265 |
|
266 |
=item on_timeout => $cb->($handle) |
267 |
|
268 |
Called whenever the inactivity timeout passes. If you return from this |
269 |
callback, then the timeout will be reset as if some activity had happened, |
270 |
so this condition is not fatal in any way. |
271 |
|
272 |
=item rbuf_max => <bytes> |
273 |
|
274 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
275 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
276 |
avoid some forms of denial-of-service attacks. |
277 |
|
278 |
For example, a server accepting connections from untrusted sources should |
279 |
be configured to accept only so-and-so much data that it cannot act on |
280 |
(for example, when expecting a line, an attacker could send an unlimited |
281 |
amount of data without a callback ever being called as long as the line |
282 |
isn't finished). |
283 |
|
284 |
=item autocork => <boolean> |
285 |
|
286 |
When disabled (the default), C<push_write> will try to immediately |
287 |
write the data to the handle if possible. This avoids having to register |
288 |
a write watcher and wait for the next event loop iteration, but can |
289 |
be inefficient if you write multiple small chunks (on the wire, this |
290 |
disadvantage is usually avoided by your kernel's nagle algorithm, see |
291 |
C<no_delay>, but this option can save costly syscalls). |
292 |
|
293 |
When enabled, writes will always be queued till the next event loop |
294 |
iteration. This is efficient when you do many small writes per iteration, |
295 |
but less efficient when you do a single write only per iteration (or when |
296 |
the write buffer often is full). It also increases write latency. |
297 |
|
298 |
=item no_delay => <boolean> |
299 |
|
300 |
When doing small writes on sockets, your operating system kernel might |
301 |
wait a bit for more data before actually sending it out. This is called |
302 |
the Nagle algorithm, and usually it is beneficial. |
303 |
|
304 |
In some situations you want as low a delay as possible, which can be |
305 |
accomplishd by setting this option to a true value. |
306 |
|
307 |
The default is your operating system's default behaviour (most likely |
308 |
enabled). This option explicitly enables or disables it, if possible. |
309 |
|
310 |
=item keepalive => <boolean> |
311 |
|
312 |
Enables (default disable) the SO_KEEPALIVE option on the stream socket: |
313 |
normally, TCP connections have no time-out once established, so TCP |
314 |
connections, once established, can stay alive forever even when the other |
315 |
side has long gone. TCP keepalives are a cheap way to take down long-lived |
316 |
TCP connections when the other side becomes unreachable. While the default |
317 |
is OS-dependent, TCP keepalives usually kick in after around two hours, |
318 |
and, if the other side doesn't reply, take down the TCP connection some 10 |
319 |
to 15 minutes later. |
320 |
|
321 |
It is harmless to specify this option for file handles that do not support |
322 |
keepalives, and enabling it on connections that are potentially long-lived |
323 |
is usually a good idea. |
324 |
|
325 |
=item oobinline => <boolean> |
326 |
|
327 |
BSD majorly fucked up the implementation of TCP urgent data. The result |
328 |
is that almost no OS implements TCP according to the specs, and every OS |
329 |
implements it slightly differently. |
330 |
|
331 |
If you want to handle TCP urgent data, then setting this flag (the default |
332 |
is enabled) gives you the most portable way of getting urgent data, by |
333 |
putting it into the stream. |
334 |
|
335 |
Since BSD emulation of OOB data on top of TCP's urgent data can have |
336 |
security implications, AnyEvent::Handle sets this flag automatically |
337 |
unless explicitly specified. Note that setting this flag after |
338 |
establishing a connection I<may> be a bit too late (data loss could |
339 |
already have occured on BSD systems), but at least it will protect you |
340 |
from most attacks. |
341 |
|
342 |
=item read_size => <bytes> |
343 |
|
344 |
The initial read block size, the number of bytes this module will try to |
345 |
read during each loop iteration. Each handle object will consume at least |
346 |
this amount of memory for the read buffer as well, so when handling many |
347 |
connections requirements). See also C<max_read_size>. Default: C<2048>. |
348 |
|
349 |
=item max_read_size => <bytes> |
350 |
|
351 |
The maximum read buffer size used by the dynamic adjustment |
352 |
algorithm: Each time AnyEvent::Handle can read C<read_size> bytes in |
353 |
one go it will double C<read_size> up to the maximum given by this |
354 |
option. Default: C<131072> or C<read_size>, whichever is higher. |
355 |
|
356 |
=item low_water_mark => <bytes> |
357 |
|
358 |
Sets the number of bytes (default: C<0>) that make up an "empty" write |
359 |
buffer: If the buffer reaches this size or gets even samller it is |
360 |
considered empty. |
361 |
|
362 |
Sometimes it can be beneficial (for performance reasons) to add data to |
363 |
the write buffer before it is fully drained, but this is a rare case, as |
364 |
the operating system kernel usually buffers data as well, so the default |
365 |
is good in almost all cases. |
366 |
|
367 |
=item linger => <seconds> |
368 |
|
369 |
If this is non-zero (default: C<3600>), the destructor of the |
370 |
AnyEvent::Handle object will check whether there is still outstanding |
371 |
write data and will install a watcher that will write this data to the |
372 |
socket. No errors will be reported (this mostly matches how the operating |
373 |
system treats outstanding data at socket close time). |
374 |
|
375 |
This will not work for partial TLS data that could not be encoded |
376 |
yet. This data will be lost. Calling the C<stoptls> method in time might |
377 |
help. |
378 |
|
379 |
=item peername => $string |
380 |
|
381 |
A string used to identify the remote site - usually the DNS hostname |
382 |
(I<not> IDN!) used to create the connection, rarely the IP address. |
383 |
|
384 |
Apart from being useful in error messages, this string is also used in TLS |
385 |
peername verification (see C<verify_peername> in L<AnyEvent::TLS>). This |
386 |
verification will be skipped when C<peername> is not specified or is |
387 |
C<undef>. |
388 |
|
389 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
390 |
|
391 |
When this parameter is given, it enables TLS (SSL) mode, that means |
392 |
AnyEvent will start a TLS handshake as soon as the connection has been |
393 |
established and will transparently encrypt/decrypt data afterwards. |
394 |
|
395 |
All TLS protocol errors will be signalled as C<EPROTO>, with an |
396 |
appropriate error message. |
397 |
|
398 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
399 |
automatically when you try to create a TLS handle): this module doesn't |
400 |
have a dependency on that module, so if your module requires it, you have |
401 |
to add the dependency yourself. |
402 |
|
403 |
Unlike TCP, TLS has a server and client side: for the TLS server side, use |
404 |
C<accept>, and for the TLS client side of a connection, use C<connect> |
405 |
mode. |
406 |
|
407 |
You can also provide your own TLS connection object, but you have |
408 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
409 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
410 |
AnyEvent::Handle. Also, this module will take ownership of this connection |
411 |
object. |
412 |
|
413 |
At some future point, AnyEvent::Handle might switch to another TLS |
414 |
implementation, then the option to use your own session object will go |
415 |
away. |
416 |
|
417 |
B<IMPORTANT:> since Net::SSLeay "objects" are really only integers, |
418 |
passing in the wrong integer will lead to certain crash. This most often |
419 |
happens when one uses a stylish C<< tls => 1 >> and is surprised about the |
420 |
segmentation fault. |
421 |
|
422 |
Use the C<< ->starttls >> method if you need to start TLS negotiation later. |
423 |
|
424 |
=item tls_ctx => $anyevent_tls |
425 |
|
426 |
Use the given C<AnyEvent::TLS> object to create the new TLS connection |
427 |
(unless a connection object was specified directly). If this parameter is |
428 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
429 |
|
430 |
Instead of an object, you can also specify a hash reference with C<< key |
431 |
=> value >> pairs. Those will be passed to L<AnyEvent::TLS> to create a |
432 |
new TLS context object. |
433 |
|
434 |
=item on_starttls => $cb->($handle, $success[, $error_message]) |
435 |
|
436 |
This callback will be invoked when the TLS/SSL handshake has finished. If |
437 |
C<$success> is true, then the TLS handshake succeeded, otherwise it failed |
438 |
(C<on_stoptls> will not be called in this case). |
439 |
|
440 |
The session in C<< $handle->{tls} >> can still be examined in this |
441 |
callback, even when the handshake was not successful. |
442 |
|
443 |
TLS handshake failures will not cause C<on_error> to be invoked when this |
444 |
callback is in effect, instead, the error message will be passed to C<on_starttls>. |
445 |
|
446 |
Without this callback, handshake failures lead to C<on_error> being |
447 |
called as usual. |
448 |
|
449 |
Note that you cannot just call C<starttls> again in this callback. If you |
450 |
need to do that, start an zero-second timer instead whose callback can |
451 |
then call C<< ->starttls >> again. |
452 |
|
453 |
=item on_stoptls => $cb->($handle) |
454 |
|
455 |
When a SSLv3/TLS shutdown/close notify/EOF is detected and this callback is |
456 |
set, then it will be invoked after freeing the TLS session. If it is not, |
457 |
then a TLS shutdown condition will be treated like a normal EOF condition |
458 |
on the handle. |
459 |
|
460 |
The session in C<< $handle->{tls} >> can still be examined in this |
461 |
callback. |
462 |
|
463 |
This callback will only be called on TLS shutdowns, not when the |
464 |
underlying handle signals EOF. |
465 |
|
466 |
=item json => JSON or JSON::XS object |
467 |
|
468 |
This is the json coder object used by the C<json> read and write types. |
469 |
|
470 |
If you don't supply it, then AnyEvent::Handle will create and use a |
471 |
suitable one (on demand), which will write and expect UTF-8 encoded JSON |
472 |
texts. |
473 |
|
474 |
Note that you are responsible to depend on the JSON module if you want to |
475 |
use this functionality, as AnyEvent does not have a dependency itself. |
476 |
|
477 |
=back |
478 |
|
479 |
=cut |
480 |
|
481 |
sub new { |
482 |
my $class = shift; |
483 |
my $self = bless { @_ }, $class; |
484 |
|
485 |
if ($self->{fh}) { |
486 |
$self->_start; |
487 |
return unless $self->{fh}; # could be gone by now |
488 |
|
489 |
} elsif ($self->{connect}) { |
490 |
require AnyEvent::Socket; |
491 |
|
492 |
$self->{peername} = $self->{connect}[0] |
493 |
unless exists $self->{peername}; |
494 |
|
495 |
$self->{_skip_drain_rbuf} = 1; |
496 |
|
497 |
{ |
498 |
Scalar::Util::weaken (my $self = $self); |
499 |
|
500 |
$self->{_connect} = |
501 |
AnyEvent::Socket::tcp_connect ( |
502 |
$self->{connect}[0], |
503 |
$self->{connect}[1], |
504 |
sub { |
505 |
my ($fh, $host, $port, $retry) = @_; |
506 |
|
507 |
if ($fh) { |
508 |
$self->{fh} = $fh; |
509 |
|
510 |
delete $self->{_skip_drain_rbuf}; |
511 |
$self->_start; |
512 |
|
513 |
$self->{on_connect} |
514 |
and $self->{on_connect}($self, $host, $port, sub { |
515 |
delete @$self{qw(fh _tw _rtw _wtw _ww _rw _eof _queue rbuf _wbuf tls _tls_rbuf _tls_wbuf)}; |
516 |
$self->{_skip_drain_rbuf} = 1; |
517 |
&$retry; |
518 |
}); |
519 |
|
520 |
} else { |
521 |
if ($self->{on_connect_error}) { |
522 |
$self->{on_connect_error}($self, "$!"); |
523 |
$self->destroy; |
524 |
} else { |
525 |
$self->_error ($!, 1); |
526 |
} |
527 |
} |
528 |
}, |
529 |
sub { |
530 |
local $self->{fh} = $_[0]; |
531 |
|
532 |
$self->{on_prepare} |
533 |
? $self->{on_prepare}->($self) |
534 |
: () |
535 |
} |
536 |
); |
537 |
} |
538 |
|
539 |
} else { |
540 |
Carp::croak "AnyEvent::Handle: either an existing fh or the connect parameter must be specified"; |
541 |
} |
542 |
|
543 |
$self |
544 |
} |
545 |
|
546 |
sub _start { |
547 |
my ($self) = @_; |
548 |
|
549 |
# too many clueless people try to use udp and similar sockets |
550 |
# with AnyEvent::Handle, do them a favour. |
551 |
my $type = getsockopt $self->{fh}, Socket::SOL_SOCKET (), Socket::SO_TYPE (); |
552 |
Carp::croak "AnyEvent::Handle: only stream sockets supported, anything else will NOT work!" |
553 |
if Socket::SOCK_STREAM () != (unpack "I", $type) && defined $type; |
554 |
|
555 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
556 |
|
557 |
$self->{_activity} = |
558 |
$self->{_ractivity} = |
559 |
$self->{_wactivity} = AE::now; |
560 |
|
561 |
$self->{read_size} ||= 2048; |
562 |
$self->{max_read_size} = $self->{read_size} |
563 |
if $self->{read_size} > ($self->{max_read_size} || MAX_READ_SIZE); |
564 |
|
565 |
$self->timeout (delete $self->{timeout} ) if $self->{timeout}; |
566 |
$self->rtimeout (delete $self->{rtimeout} ) if $self->{rtimeout}; |
567 |
$self->wtimeout (delete $self->{wtimeout} ) if $self->{wtimeout}; |
568 |
|
569 |
$self->no_delay (delete $self->{no_delay} ) if exists $self->{no_delay} && $self->{no_delay}; |
570 |
$self->keepalive (delete $self->{keepalive}) if exists $self->{keepalive} && $self->{keepalive}; |
571 |
|
572 |
$self->oobinline (exists $self->{oobinline} ? delete $self->{oobinline} : 1); |
573 |
|
574 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}) |
575 |
if $self->{tls}; |
576 |
|
577 |
$self->on_drain (delete $self->{on_drain} ) if $self->{on_drain}; |
578 |
|
579 |
$self->start_read |
580 |
if $self->{on_read} || @{ $self->{_queue} }; |
581 |
|
582 |
$self->_drain_wbuf; |
583 |
} |
584 |
|
585 |
sub _error { |
586 |
my ($self, $errno, $fatal, $message) = @_; |
587 |
|
588 |
$! = $errno; |
589 |
$message ||= "$!"; |
590 |
|
591 |
if ($self->{on_error}) { |
592 |
$self->{on_error}($self, $fatal, $message); |
593 |
$self->destroy if $fatal; |
594 |
} elsif ($self->{fh} || $self->{connect}) { |
595 |
$self->destroy; |
596 |
Carp::croak "AnyEvent::Handle uncaught error: $message"; |
597 |
} |
598 |
} |
599 |
|
600 |
=item $fh = $handle->fh |
601 |
|
602 |
This method returns the file handle used to create the L<AnyEvent::Handle> object. |
603 |
|
604 |
=cut |
605 |
|
606 |
sub fh { $_[0]{fh} } |
607 |
|
608 |
=item $handle->on_error ($cb) |
609 |
|
610 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
611 |
|
612 |
=cut |
613 |
|
614 |
sub on_error { |
615 |
$_[0]{on_error} = $_[1]; |
616 |
} |
617 |
|
618 |
=item $handle->on_eof ($cb) |
619 |
|
620 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
621 |
|
622 |
=cut |
623 |
|
624 |
sub on_eof { |
625 |
$_[0]{on_eof} = $_[1]; |
626 |
} |
627 |
|
628 |
=item $handle->on_timeout ($cb) |
629 |
|
630 |
=item $handle->on_rtimeout ($cb) |
631 |
|
632 |
=item $handle->on_wtimeout ($cb) |
633 |
|
634 |
Replace the current C<on_timeout>, C<on_rtimeout> or C<on_wtimeout> |
635 |
callback, or disables the callback (but not the timeout) if C<$cb> = |
636 |
C<undef>. See the C<timeout> constructor argument and method. |
637 |
|
638 |
=cut |
639 |
|
640 |
# see below |
641 |
|
642 |
=item $handle->autocork ($boolean) |
643 |
|
644 |
Enables or disables the current autocork behaviour (see C<autocork> |
645 |
constructor argument). Changes will only take effect on the next write. |
646 |
|
647 |
=cut |
648 |
|
649 |
sub autocork { |
650 |
$_[0]{autocork} = $_[1]; |
651 |
} |
652 |
|
653 |
=item $handle->no_delay ($boolean) |
654 |
|
655 |
Enables or disables the C<no_delay> setting (see constructor argument of |
656 |
the same name for details). |
657 |
|
658 |
=cut |
659 |
|
660 |
sub no_delay { |
661 |
$_[0]{no_delay} = $_[1]; |
662 |
|
663 |
setsockopt $_[0]{fh}, Socket::IPPROTO_TCP (), Socket::TCP_NODELAY (), int $_[1] |
664 |
if $_[0]{fh}; |
665 |
} |
666 |
|
667 |
=item $handle->keepalive ($boolean) |
668 |
|
669 |
Enables or disables the C<keepalive> setting (see constructor argument of |
670 |
the same name for details). |
671 |
|
672 |
=cut |
673 |
|
674 |
sub keepalive { |
675 |
$_[0]{keepalive} = $_[1]; |
676 |
|
677 |
eval { |
678 |
local $SIG{__DIE__}; |
679 |
setsockopt $_[0]{fh}, Socket::SOL_SOCKET (), Socket::SO_KEEPALIVE (), int $_[1] |
680 |
if $_[0]{fh}; |
681 |
}; |
682 |
} |
683 |
|
684 |
=item $handle->oobinline ($boolean) |
685 |
|
686 |
Enables or disables the C<oobinline> setting (see constructor argument of |
687 |
the same name for details). |
688 |
|
689 |
=cut |
690 |
|
691 |
sub oobinline { |
692 |
$_[0]{oobinline} = $_[1]; |
693 |
|
694 |
eval { |
695 |
local $SIG{__DIE__}; |
696 |
setsockopt $_[0]{fh}, Socket::SOL_SOCKET (), Socket::SO_OOBINLINE (), int $_[1] |
697 |
if $_[0]{fh}; |
698 |
}; |
699 |
} |
700 |
|
701 |
=item $handle->keepalive ($boolean) |
702 |
|
703 |
Enables or disables the C<keepalive> setting (see constructor argument of |
704 |
the same name for details). |
705 |
|
706 |
=cut |
707 |
|
708 |
sub keepalive { |
709 |
$_[0]{keepalive} = $_[1]; |
710 |
|
711 |
eval { |
712 |
local $SIG{__DIE__}; |
713 |
setsockopt $_[0]{fh}, Socket::SOL_SOCKET (), Socket::SO_KEEPALIVE (), int $_[1] |
714 |
if $_[0]{fh}; |
715 |
}; |
716 |
} |
717 |
|
718 |
=item $handle->on_starttls ($cb) |
719 |
|
720 |
Replace the current C<on_starttls> callback (see the C<on_starttls> constructor argument). |
721 |
|
722 |
=cut |
723 |
|
724 |
sub on_starttls { |
725 |
$_[0]{on_starttls} = $_[1]; |
726 |
} |
727 |
|
728 |
=item $handle->on_stoptls ($cb) |
729 |
|
730 |
Replace the current C<on_stoptls> callback (see the C<on_stoptls> constructor argument). |
731 |
|
732 |
=cut |
733 |
|
734 |
sub on_stoptls { |
735 |
$_[0]{on_stoptls} = $_[1]; |
736 |
} |
737 |
|
738 |
=item $handle->rbuf_max ($max_octets) |
739 |
|
740 |
Configures the C<rbuf_max> setting (C<undef> disables it). |
741 |
|
742 |
=cut |
743 |
|
744 |
sub rbuf_max { |
745 |
$_[0]{rbuf_max} = $_[1]; |
746 |
} |
747 |
|
748 |
############################################################################# |
749 |
|
750 |
=item $handle->timeout ($seconds) |
751 |
|
752 |
=item $handle->rtimeout ($seconds) |
753 |
|
754 |
=item $handle->wtimeout ($seconds) |
755 |
|
756 |
Configures (or disables) the inactivity timeout. |
757 |
|
758 |
=item $handle->timeout_reset |
759 |
|
760 |
=item $handle->rtimeout_reset |
761 |
|
762 |
=item $handle->wtimeout_reset |
763 |
|
764 |
Reset the activity timeout, as if data was received or sent. |
765 |
|
766 |
These methods are cheap to call. |
767 |
|
768 |
=cut |
769 |
|
770 |
for my $dir ("", "r", "w") { |
771 |
my $timeout = "${dir}timeout"; |
772 |
my $tw = "_${dir}tw"; |
773 |
my $on_timeout = "on_${dir}timeout"; |
774 |
my $activity = "_${dir}activity"; |
775 |
my $cb; |
776 |
|
777 |
*$on_timeout = sub { |
778 |
$_[0]{$on_timeout} = $_[1]; |
779 |
}; |
780 |
|
781 |
*$timeout = sub { |
782 |
my ($self, $new_value) = @_; |
783 |
|
784 |
$new_value >= 0 |
785 |
or Carp::croak "AnyEvent::Handle->$timeout called with negative timeout ($new_value), caught"; |
786 |
|
787 |
$self->{$timeout} = $new_value; |
788 |
delete $self->{$tw}; &$cb; |
789 |
}; |
790 |
|
791 |
*{"${dir}timeout_reset"} = sub { |
792 |
$_[0]{$activity} = AE::now; |
793 |
}; |
794 |
|
795 |
# main workhorse: |
796 |
# reset the timeout watcher, as neccessary |
797 |
# also check for time-outs |
798 |
$cb = sub { |
799 |
my ($self) = @_; |
800 |
|
801 |
if ($self->{$timeout} && $self->{fh}) { |
802 |
my $NOW = AE::now; |
803 |
|
804 |
# when would the timeout trigger? |
805 |
my $after = $self->{$activity} + $self->{$timeout} - $NOW; |
806 |
|
807 |
# now or in the past already? |
808 |
if ($after <= 0) { |
809 |
$self->{$activity} = $NOW; |
810 |
|
811 |
if ($self->{$on_timeout}) { |
812 |
$self->{$on_timeout}($self); |
813 |
} else { |
814 |
$self->_error (Errno::ETIMEDOUT); |
815 |
} |
816 |
|
817 |
# callback could have changed timeout value, optimise |
818 |
return unless $self->{$timeout}; |
819 |
|
820 |
# calculate new after |
821 |
$after = $self->{$timeout}; |
822 |
} |
823 |
|
824 |
Scalar::Util::weaken $self; |
825 |
return unless $self; # ->error could have destroyed $self |
826 |
|
827 |
$self->{$tw} ||= AE::timer $after, 0, sub { |
828 |
delete $self->{$tw}; |
829 |
$cb->($self); |
830 |
}; |
831 |
} else { |
832 |
delete $self->{$tw}; |
833 |
} |
834 |
} |
835 |
} |
836 |
|
837 |
############################################################################# |
838 |
|
839 |
=back |
840 |
|
841 |
=head2 WRITE QUEUE |
842 |
|
843 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
844 |
for reading. |
845 |
|
846 |
The write queue is very simple: you can add data to its end, and |
847 |
AnyEvent::Handle will automatically try to get rid of it for you. |
848 |
|
849 |
When data could be written and the write buffer is shorter then the low |
850 |
water mark, the C<on_drain> callback will be invoked. |
851 |
|
852 |
=over 4 |
853 |
|
854 |
=item $handle->on_drain ($cb) |
855 |
|
856 |
Sets the C<on_drain> callback or clears it (see the description of |
857 |
C<on_drain> in the constructor). |
858 |
|
859 |
This method may invoke callbacks (and therefore the handle might be |
860 |
destroyed after it returns). |
861 |
|
862 |
=cut |
863 |
|
864 |
sub on_drain { |
865 |
my ($self, $cb) = @_; |
866 |
|
867 |
$self->{on_drain} = $cb; |
868 |
|
869 |
$cb->($self) |
870 |
if $cb && $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}); |
871 |
} |
872 |
|
873 |
=item $handle->push_write ($data) |
874 |
|
875 |
Queues the given scalar to be written. You can push as much data as you |
876 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
877 |
buffers it independently of the kernel. |
878 |
|
879 |
This method may invoke callbacks (and therefore the handle might be |
880 |
destroyed after it returns). |
881 |
|
882 |
=cut |
883 |
|
884 |
sub _drain_wbuf { |
885 |
my ($self) = @_; |
886 |
|
887 |
if (!$self->{_ww} && length $self->{wbuf}) { |
888 |
|
889 |
Scalar::Util::weaken $self; |
890 |
|
891 |
my $cb = sub { |
892 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
893 |
|
894 |
if (defined $len) { |
895 |
substr $self->{wbuf}, 0, $len, ""; |
896 |
|
897 |
$self->{_activity} = $self->{_wactivity} = AE::now; |
898 |
|
899 |
$self->{on_drain}($self) |
900 |
if $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}) |
901 |
&& $self->{on_drain}; |
902 |
|
903 |
delete $self->{_ww} unless length $self->{wbuf}; |
904 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
905 |
$self->_error ($!, 1); |
906 |
} |
907 |
}; |
908 |
|
909 |
# try to write data immediately |
910 |
$cb->() unless $self->{autocork}; |
911 |
|
912 |
# if still data left in wbuf, we need to poll |
913 |
$self->{_ww} = AE::io $self->{fh}, 1, $cb |
914 |
if length $self->{wbuf}; |
915 |
}; |
916 |
} |
917 |
|
918 |
our %WH; |
919 |
|
920 |
# deprecated |
921 |
sub register_write_type($$) { |
922 |
$WH{$_[0]} = $_[1]; |
923 |
} |
924 |
|
925 |
sub push_write { |
926 |
my $self = shift; |
927 |
|
928 |
if (@_ > 1) { |
929 |
my $type = shift; |
930 |
|
931 |
@_ = ($WH{$type} ||= _load_func "$type\::anyevent_write_type" |
932 |
or Carp::croak "unsupported/unloadable type '$type' passed to AnyEvent::Handle::push_write") |
933 |
->($self, @_); |
934 |
} |
935 |
|
936 |
# we downgrade here to avoid hard-to-track-down bugs, |
937 |
# and diagnose the problem earlier and better. |
938 |
|
939 |
if ($self->{tls}) { |
940 |
utf8::downgrade $self->{_tls_wbuf} .= $_[0]; |
941 |
&_dotls ($self) if $self->{fh}; |
942 |
} else { |
943 |
utf8::downgrade $self->{wbuf} .= $_[0]; |
944 |
$self->_drain_wbuf if $self->{fh}; |
945 |
} |
946 |
} |
947 |
|
948 |
=item $handle->push_write (type => @args) |
949 |
|
950 |
Instead of formatting your data yourself, you can also let this module |
951 |
do the job by specifying a type and type-specific arguments. You |
952 |
can also specify the (fully qualified) name of a package, in which |
953 |
case AnyEvent tries to load the package and then expects to find the |
954 |
C<anyevent_write_type> function inside (see "custom write types", below). |
955 |
|
956 |
Predefined types are (if you have ideas for additional types, feel free to |
957 |
drop by and tell us): |
958 |
|
959 |
=over 4 |
960 |
|
961 |
=item netstring => $string |
962 |
|
963 |
Formats the given value as netstring |
964 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
965 |
|
966 |
=cut |
967 |
|
968 |
register_write_type netstring => sub { |
969 |
my ($self, $string) = @_; |
970 |
|
971 |
(length $string) . ":$string," |
972 |
}; |
973 |
|
974 |
=item packstring => $format, $data |
975 |
|
976 |
An octet string prefixed with an encoded length. The encoding C<$format> |
977 |
uses the same format as a Perl C<pack> format, but must specify a single |
978 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
979 |
optional C<!>, C<< < >> or C<< > >> modifier). |
980 |
|
981 |
=cut |
982 |
|
983 |
register_write_type packstring => sub { |
984 |
my ($self, $format, $string) = @_; |
985 |
|
986 |
pack "$format/a*", $string |
987 |
}; |
988 |
|
989 |
=item json => $array_or_hashref |
990 |
|
991 |
Encodes the given hash or array reference into a JSON object. Unless you |
992 |
provide your own JSON object, this means it will be encoded to JSON text |
993 |
in UTF-8. |
994 |
|
995 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
996 |
one end of a handle and read them at the other end without using any |
997 |
additional framing. |
998 |
|
999 |
The generated JSON text is guaranteed not to contain any newlines: While |
1000 |
this module doesn't need delimiters after or between JSON texts to be |
1001 |
able to read them, many other languages depend on that. |
1002 |
|
1003 |
A simple RPC protocol that interoperates easily with others is to send |
1004 |
JSON arrays (or objects, although arrays are usually the better choice as |
1005 |
they mimic how function argument passing works) and a newline after each |
1006 |
JSON text: |
1007 |
|
1008 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
1009 |
$handle->push_write ("\012"); |
1010 |
|
1011 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
1012 |
rely on the fact that the newline will be skipped as leading whitespace: |
1013 |
|
1014 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
1015 |
|
1016 |
Other languages could read single lines terminated by a newline and pass |
1017 |
this line into their JSON decoder of choice. |
1018 |
|
1019 |
=cut |
1020 |
|
1021 |
sub json_coder() { |
1022 |
eval { require JSON::XS; JSON::XS->new->utf8 } |
1023 |
|| do { require JSON; JSON->new->utf8 } |
1024 |
} |
1025 |
|
1026 |
register_write_type json => sub { |
1027 |
my ($self, $ref) = @_; |
1028 |
|
1029 |
my $json = $self->{json} ||= json_coder; |
1030 |
|
1031 |
$json->encode ($ref) |
1032 |
}; |
1033 |
|
1034 |
=item storable => $reference |
1035 |
|
1036 |
Freezes the given reference using L<Storable> and writes it to the |
1037 |
handle. Uses the C<nfreeze> format. |
1038 |
|
1039 |
=cut |
1040 |
|
1041 |
register_write_type storable => sub { |
1042 |
my ($self, $ref) = @_; |
1043 |
|
1044 |
require Storable; |
1045 |
|
1046 |
pack "w/a*", Storable::nfreeze ($ref) |
1047 |
}; |
1048 |
|
1049 |
=back |
1050 |
|
1051 |
=item $handle->push_shutdown |
1052 |
|
1053 |
Sometimes you know you want to close the socket after writing your data |
1054 |
before it was actually written. One way to do that is to replace your |
1055 |
C<on_drain> handler by a callback that shuts down the socket (and set |
1056 |
C<low_water_mark> to C<0>). This method is a shorthand for just that, and |
1057 |
replaces the C<on_drain> callback with: |
1058 |
|
1059 |
sub { shutdown $_[0]{fh}, 1 } # for push_shutdown |
1060 |
|
1061 |
This simply shuts down the write side and signals an EOF condition to the |
1062 |
the peer. |
1063 |
|
1064 |
You can rely on the normal read queue and C<on_eof> handling |
1065 |
afterwards. This is the cleanest way to close a connection. |
1066 |
|
1067 |
This method may invoke callbacks (and therefore the handle might be |
1068 |
destroyed after it returns). |
1069 |
|
1070 |
=cut |
1071 |
|
1072 |
sub push_shutdown { |
1073 |
my ($self) = @_; |
1074 |
|
1075 |
delete $self->{low_water_mark}; |
1076 |
$self->on_drain (sub { shutdown $_[0]{fh}, 1 }); |
1077 |
} |
1078 |
|
1079 |
=item custom write types - Package::anyevent_write_type $handle, @args |
1080 |
|
1081 |
Instead of one of the predefined types, you can also specify the name of |
1082 |
a package. AnyEvent will try to load the package and then expects to find |
1083 |
a function named C<anyevent_write_type> inside. If it isn't found, it |
1084 |
progressively tries to load the parent package until it either finds the |
1085 |
function (good) or runs out of packages (bad). |
1086 |
|
1087 |
Whenever the given C<type> is used, C<push_write> will the function with |
1088 |
the handle object and the remaining arguments. |
1089 |
|
1090 |
The function is supposed to return a single octet string that will be |
1091 |
appended to the write buffer, so you cna mentally treat this function as a |
1092 |
"arguments to on-the-wire-format" converter. |
1093 |
|
1094 |
Example: implement a custom write type C<join> that joins the remaining |
1095 |
arguments using the first one. |
1096 |
|
1097 |
$handle->push_write (My::Type => " ", 1,2,3); |
1098 |
|
1099 |
# uses the following package, which can be defined in the "My::Type" or in |
1100 |
# the "My" modules to be auto-loaded, or just about anywhere when the |
1101 |
# My::Type::anyevent_write_type is defined before invoking it. |
1102 |
|
1103 |
package My::Type; |
1104 |
|
1105 |
sub anyevent_write_type { |
1106 |
my ($handle, $delim, @args) = @_; |
1107 |
|
1108 |
join $delim, @args |
1109 |
} |
1110 |
|
1111 |
=cut |
1112 |
|
1113 |
############################################################################# |
1114 |
|
1115 |
=back |
1116 |
|
1117 |
=head2 READ QUEUE |
1118 |
|
1119 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
1120 |
for reading. |
1121 |
|
1122 |
The read queue is more complex than the write queue. It can be used in two |
1123 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
1124 |
a queue. |
1125 |
|
1126 |
In the simple case, you just install an C<on_read> callback and whenever |
1127 |
new data arrives, it will be called. You can then remove some data (if |
1128 |
enough is there) from the read buffer (C<< $handle->rbuf >>). Or you can |
1129 |
leave the data there if you want to accumulate more (e.g. when only a |
1130 |
partial message has been received so far), or change the read queue with |
1131 |
e.g. C<push_read>. |
1132 |
|
1133 |
In the more complex case, you want to queue multiple callbacks. In this |
1134 |
case, AnyEvent::Handle will call the first queued callback each time new |
1135 |
data arrives (also the first time it is queued) and remove it when it has |
1136 |
done its job (see C<push_read>, below). |
1137 |
|
1138 |
This way you can, for example, push three line-reads, followed by reading |
1139 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
1140 |
|
1141 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
1142 |
the specified number of bytes which give an XML datagram. |
1143 |
|
1144 |
# in the default state, expect some header bytes |
1145 |
$handle->on_read (sub { |
1146 |
# some data is here, now queue the length-header-read (4 octets) |
1147 |
shift->unshift_read (chunk => 4, sub { |
1148 |
# header arrived, decode |
1149 |
my $len = unpack "N", $_[1]; |
1150 |
|
1151 |
# now read the payload |
1152 |
shift->unshift_read (chunk => $len, sub { |
1153 |
my $xml = $_[1]; |
1154 |
# handle xml |
1155 |
}); |
1156 |
}); |
1157 |
}); |
1158 |
|
1159 |
Example 2: Implement a client for a protocol that replies either with "OK" |
1160 |
and another line or "ERROR" for the first request that is sent, and 64 |
1161 |
bytes for the second request. Due to the availability of a queue, we can |
1162 |
just pipeline sending both requests and manipulate the queue as necessary |
1163 |
in the callbacks. |
1164 |
|
1165 |
When the first callback is called and sees an "OK" response, it will |
1166 |
C<unshift> another line-read. This line-read will be queued I<before> the |
1167 |
64-byte chunk callback. |
1168 |
|
1169 |
# request one, returns either "OK + extra line" or "ERROR" |
1170 |
$handle->push_write ("request 1\015\012"); |
1171 |
|
1172 |
# we expect "ERROR" or "OK" as response, so push a line read |
1173 |
$handle->push_read (line => sub { |
1174 |
# if we got an "OK", we have to _prepend_ another line, |
1175 |
# so it will be read before the second request reads its 64 bytes |
1176 |
# which are already in the queue when this callback is called |
1177 |
# we don't do this in case we got an error |
1178 |
if ($_[1] eq "OK") { |
1179 |
$_[0]->unshift_read (line => sub { |
1180 |
my $response = $_[1]; |
1181 |
... |
1182 |
}); |
1183 |
} |
1184 |
}); |
1185 |
|
1186 |
# request two, simply returns 64 octets |
1187 |
$handle->push_write ("request 2\015\012"); |
1188 |
|
1189 |
# simply read 64 bytes, always |
1190 |
$handle->push_read (chunk => 64, sub { |
1191 |
my $response = $_[1]; |
1192 |
... |
1193 |
}); |
1194 |
|
1195 |
=over 4 |
1196 |
|
1197 |
=cut |
1198 |
|
1199 |
sub _drain_rbuf { |
1200 |
my ($self) = @_; |
1201 |
|
1202 |
# avoid recursion |
1203 |
return if $self->{_skip_drain_rbuf}; |
1204 |
local $self->{_skip_drain_rbuf} = 1; |
1205 |
|
1206 |
while () { |
1207 |
# we need to use a separate tls read buffer, as we must not receive data while |
1208 |
# we are draining the buffer, and this can only happen with TLS. |
1209 |
$self->{rbuf} .= delete $self->{_tls_rbuf} |
1210 |
if exists $self->{_tls_rbuf}; |
1211 |
|
1212 |
my $len = length $self->{rbuf}; |
1213 |
|
1214 |
if (my $cb = shift @{ $self->{_queue} }) { |
1215 |
unless ($cb->($self)) { |
1216 |
# no progress can be made |
1217 |
# (not enough data and no data forthcoming) |
1218 |
$self->_error (Errno::EPIPE, 1), return |
1219 |
if $self->{_eof}; |
1220 |
|
1221 |
unshift @{ $self->{_queue} }, $cb; |
1222 |
last; |
1223 |
} |
1224 |
} elsif ($self->{on_read}) { |
1225 |
last unless $len; |
1226 |
|
1227 |
$self->{on_read}($self); |
1228 |
|
1229 |
if ( |
1230 |
$len == length $self->{rbuf} # if no data has been consumed |
1231 |
&& !@{ $self->{_queue} } # and the queue is still empty |
1232 |
&& $self->{on_read} # but we still have on_read |
1233 |
) { |
1234 |
# no further data will arrive |
1235 |
# so no progress can be made |
1236 |
$self->_error (Errno::EPIPE, 1), return |
1237 |
if $self->{_eof}; |
1238 |
|
1239 |
last; # more data might arrive |
1240 |
} |
1241 |
} else { |
1242 |
# read side becomes idle |
1243 |
delete $self->{_rw} unless $self->{tls}; |
1244 |
last; |
1245 |
} |
1246 |
} |
1247 |
|
1248 |
if ($self->{_eof}) { |
1249 |
$self->{on_eof} |
1250 |
? $self->{on_eof}($self) |
1251 |
: $self->_error (0, 1, "Unexpected end-of-file"); |
1252 |
|
1253 |
return; |
1254 |
} |
1255 |
|
1256 |
if ( |
1257 |
defined $self->{rbuf_max} |
1258 |
&& $self->{rbuf_max} < length $self->{rbuf} |
1259 |
) { |
1260 |
$self->_error (Errno::ENOSPC, 1), return; |
1261 |
} |
1262 |
|
1263 |
# may need to restart read watcher |
1264 |
unless ($self->{_rw}) { |
1265 |
$self->start_read |
1266 |
if $self->{on_read} || @{ $self->{_queue} }; |
1267 |
} |
1268 |
} |
1269 |
|
1270 |
=item $handle->on_read ($cb) |
1271 |
|
1272 |
This replaces the currently set C<on_read> callback, or clears it (when |
1273 |
the new callback is C<undef>). See the description of C<on_read> in the |
1274 |
constructor. |
1275 |
|
1276 |
This method may invoke callbacks (and therefore the handle might be |
1277 |
destroyed after it returns). |
1278 |
|
1279 |
=cut |
1280 |
|
1281 |
sub on_read { |
1282 |
my ($self, $cb) = @_; |
1283 |
|
1284 |
$self->{on_read} = $cb; |
1285 |
$self->_drain_rbuf if $cb; |
1286 |
} |
1287 |
|
1288 |
=item $handle->rbuf |
1289 |
|
1290 |
Returns the read buffer (as a modifiable lvalue). You can also access the |
1291 |
read buffer directly as the C<< ->{rbuf} >> member, if you want (this is |
1292 |
much faster, and no less clean). |
1293 |
|
1294 |
The only operation allowed on the read buffer (apart from looking at it) |
1295 |
is removing data from its beginning. Otherwise modifying or appending to |
1296 |
it is not allowed and will lead to hard-to-track-down bugs. |
1297 |
|
1298 |
NOTE: The read buffer should only be used or modified in the C<on_read> |
1299 |
callback or when C<push_read> or C<unshift_read> are used with a single |
1300 |
callback (i.e. untyped). Typed C<push_read> and C<unshift_read> methods |
1301 |
will manage the read buffer on their own. |
1302 |
|
1303 |
=cut |
1304 |
|
1305 |
sub rbuf : lvalue { |
1306 |
$_[0]{rbuf} |
1307 |
} |
1308 |
|
1309 |
=item $handle->push_read ($cb) |
1310 |
|
1311 |
=item $handle->unshift_read ($cb) |
1312 |
|
1313 |
Append the given callback to the end of the queue (C<push_read>) or |
1314 |
prepend it (C<unshift_read>). |
1315 |
|
1316 |
The callback is called each time some additional read data arrives. |
1317 |
|
1318 |
It must check whether enough data is in the read buffer already. |
1319 |
|
1320 |
If not enough data is available, it must return the empty list or a false |
1321 |
value, in which case it will be called repeatedly until enough data is |
1322 |
available (or an error condition is detected). |
1323 |
|
1324 |
If enough data was available, then the callback must remove all data it is |
1325 |
interested in (which can be none at all) and return a true value. After returning |
1326 |
true, it will be removed from the queue. |
1327 |
|
1328 |
These methods may invoke callbacks (and therefore the handle might be |
1329 |
destroyed after it returns). |
1330 |
|
1331 |
=cut |
1332 |
|
1333 |
our %RH; |
1334 |
|
1335 |
sub register_read_type($$) { |
1336 |
$RH{$_[0]} = $_[1]; |
1337 |
} |
1338 |
|
1339 |
sub push_read { |
1340 |
my $self = shift; |
1341 |
my $cb = pop; |
1342 |
|
1343 |
if (@_) { |
1344 |
my $type = shift; |
1345 |
|
1346 |
$cb = ($RH{$type} ||= _load_func "$type\::anyevent_read_type" |
1347 |
or Carp::croak "unsupported/unloadable type '$type' passed to AnyEvent::Handle::push_read") |
1348 |
->($self, $cb, @_); |
1349 |
} |
1350 |
|
1351 |
push @{ $self->{_queue} }, $cb; |
1352 |
$self->_drain_rbuf; |
1353 |
} |
1354 |
|
1355 |
sub unshift_read { |
1356 |
my $self = shift; |
1357 |
my $cb = pop; |
1358 |
|
1359 |
if (@_) { |
1360 |
my $type = shift; |
1361 |
|
1362 |
$cb = ($RH{$type} ||= _load_func "$type\::anyevent_read_type" |
1363 |
or Carp::croak "unsupported/unloadable type '$type' passed to AnyEvent::Handle::unshift_read") |
1364 |
->($self, $cb, @_); |
1365 |
} |
1366 |
|
1367 |
unshift @{ $self->{_queue} }, $cb; |
1368 |
$self->_drain_rbuf; |
1369 |
} |
1370 |
|
1371 |
=item $handle->push_read (type => @args, $cb) |
1372 |
|
1373 |
=item $handle->unshift_read (type => @args, $cb) |
1374 |
|
1375 |
Instead of providing a callback that parses the data itself you can chose |
1376 |
between a number of predefined parsing formats, for chunks of data, lines |
1377 |
etc. You can also specify the (fully qualified) name of a package, in |
1378 |
which case AnyEvent tries to load the package and then expects to find the |
1379 |
C<anyevent_read_type> function inside (see "custom read types", below). |
1380 |
|
1381 |
Predefined types are (if you have ideas for additional types, feel free to |
1382 |
drop by and tell us): |
1383 |
|
1384 |
=over 4 |
1385 |
|
1386 |
=item chunk => $octets, $cb->($handle, $data) |
1387 |
|
1388 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
1389 |
data read to the callback. The callback will never be called with less |
1390 |
data. |
1391 |
|
1392 |
Example: read 2 bytes. |
1393 |
|
1394 |
$handle->push_read (chunk => 2, sub { |
1395 |
warn "yay ", unpack "H*", $_[1]; |
1396 |
}); |
1397 |
|
1398 |
=cut |
1399 |
|
1400 |
register_read_type chunk => sub { |
1401 |
my ($self, $cb, $len) = @_; |
1402 |
|
1403 |
sub { |
1404 |
$len <= length $_[0]{rbuf} or return; |
1405 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
1406 |
1 |
1407 |
} |
1408 |
}; |
1409 |
|
1410 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
1411 |
|
1412 |
The callback will be called only once a full line (including the end of |
1413 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
1414 |
marker) will be passed to the callback as second argument (C<$line>), and |
1415 |
the end of line marker as the third argument (C<$eol>). |
1416 |
|
1417 |
The end of line marker, C<$eol>, can be either a string, in which case it |
1418 |
will be interpreted as a fixed record end marker, or it can be a regex |
1419 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
1420 |
regular expression. |
1421 |
|
1422 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
1423 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
1424 |
protocols). |
1425 |
|
1426 |
Partial lines at the end of the stream will never be returned, as they are |
1427 |
not marked by the end of line marker. |
1428 |
|
1429 |
=cut |
1430 |
|
1431 |
register_read_type line => sub { |
1432 |
my ($self, $cb, $eol) = @_; |
1433 |
|
1434 |
if (@_ < 3) { |
1435 |
# this is more than twice as fast as the generic code below |
1436 |
sub { |
1437 |
$_[0]{rbuf} =~ s/^([^\015\012]*)(\015?\012)// or return; |
1438 |
|
1439 |
$cb->($_[0], $1, $2); |
1440 |
1 |
1441 |
} |
1442 |
} else { |
1443 |
$eol = quotemeta $eol unless ref $eol; |
1444 |
$eol = qr|^(.*?)($eol)|s; |
1445 |
|
1446 |
sub { |
1447 |
$_[0]{rbuf} =~ s/$eol// or return; |
1448 |
|
1449 |
$cb->($_[0], $1, $2); |
1450 |
1 |
1451 |
} |
1452 |
} |
1453 |
}; |
1454 |
|
1455 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
1456 |
|
1457 |
Makes a regex match against the regex object C<$accept> and returns |
1458 |
everything up to and including the match. |
1459 |
|
1460 |
Example: read a single line terminated by '\n'. |
1461 |
|
1462 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
1463 |
|
1464 |
If C<$reject> is given and not undef, then it determines when the data is |
1465 |
to be rejected: it is matched against the data when the C<$accept> regex |
1466 |
does not match and generates an C<EBADMSG> error when it matches. This is |
1467 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
1468 |
receive buffer overflow). |
1469 |
|
1470 |
Example: expect a single decimal number followed by whitespace, reject |
1471 |
anything else (not the use of an anchor). |
1472 |
|
1473 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
1474 |
|
1475 |
If C<$skip> is given and not C<undef>, then it will be matched against |
1476 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
1477 |
and everything preceding and including the match will be accepted |
1478 |
unconditionally. This is useful to skip large amounts of data that you |
1479 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
1480 |
have to start matching from the beginning. This is purely an optimisation |
1481 |
and is usually worth it only when you expect more than a few kilobytes. |
1482 |
|
1483 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
1484 |
expect the header to be very large (it isn't in practice, but...), we use |
1485 |
a skip regex to skip initial portions. The skip regex is tricky in that |
1486 |
it only accepts something not ending in either \015 or \012, as these are |
1487 |
required for the accept regex. |
1488 |
|
1489 |
$handle->push_read (regex => |
1490 |
qr<\015\012\015\012>, |
1491 |
undef, # no reject |
1492 |
qr<^.*[^\015\012]>, |
1493 |
sub { ... }); |
1494 |
|
1495 |
=cut |
1496 |
|
1497 |
register_read_type regex => sub { |
1498 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
1499 |
|
1500 |
my $data; |
1501 |
my $rbuf = \$self->{rbuf}; |
1502 |
|
1503 |
sub { |
1504 |
# accept |
1505 |
if ($$rbuf =~ $accept) { |
1506 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1507 |
$cb->($self, $data); |
1508 |
return 1; |
1509 |
} |
1510 |
|
1511 |
# reject |
1512 |
if ($reject && $$rbuf =~ $reject) { |
1513 |
$self->_error (Errno::EBADMSG); |
1514 |
} |
1515 |
|
1516 |
# skip |
1517 |
if ($skip && $$rbuf =~ $skip) { |
1518 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1519 |
} |
1520 |
|
1521 |
() |
1522 |
} |
1523 |
}; |
1524 |
|
1525 |
=item netstring => $cb->($handle, $string) |
1526 |
|
1527 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
1528 |
|
1529 |
Throws an error with C<$!> set to EBADMSG on format violations. |
1530 |
|
1531 |
=cut |
1532 |
|
1533 |
register_read_type netstring => sub { |
1534 |
my ($self, $cb) = @_; |
1535 |
|
1536 |
sub { |
1537 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
1538 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
1539 |
$self->_error (Errno::EBADMSG); |
1540 |
} |
1541 |
return; |
1542 |
} |
1543 |
|
1544 |
my $len = $1; |
1545 |
|
1546 |
$self->unshift_read (chunk => $len, sub { |
1547 |
my $string = $_[1]; |
1548 |
$_[0]->unshift_read (chunk => 1, sub { |
1549 |
if ($_[1] eq ",") { |
1550 |
$cb->($_[0], $string); |
1551 |
} else { |
1552 |
$self->_error (Errno::EBADMSG); |
1553 |
} |
1554 |
}); |
1555 |
}); |
1556 |
|
1557 |
1 |
1558 |
} |
1559 |
}; |
1560 |
|
1561 |
=item packstring => $format, $cb->($handle, $string) |
1562 |
|
1563 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1564 |
uses the same format as a Perl C<pack> format, but must specify a single |
1565 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1566 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1567 |
|
1568 |
For example, DNS over TCP uses a prefix of C<n> (2 octet network order), |
1569 |
EPP uses a prefix of C<N> (4 octtes). |
1570 |
|
1571 |
Example: read a block of data prefixed by its length in BER-encoded |
1572 |
format (very efficient). |
1573 |
|
1574 |
$handle->push_read (packstring => "w", sub { |
1575 |
my ($handle, $data) = @_; |
1576 |
}); |
1577 |
|
1578 |
=cut |
1579 |
|
1580 |
register_read_type packstring => sub { |
1581 |
my ($self, $cb, $format) = @_; |
1582 |
|
1583 |
sub { |
1584 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1585 |
defined (my $len = eval { unpack $format, $_[0]{rbuf} }) |
1586 |
or return; |
1587 |
|
1588 |
$format = length pack $format, $len; |
1589 |
|
1590 |
# bypass unshift if we already have the remaining chunk |
1591 |
if ($format + $len <= length $_[0]{rbuf}) { |
1592 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1593 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1594 |
$cb->($_[0], $data); |
1595 |
} else { |
1596 |
# remove prefix |
1597 |
substr $_[0]{rbuf}, 0, $format, ""; |
1598 |
|
1599 |
# read remaining chunk |
1600 |
$_[0]->unshift_read (chunk => $len, $cb); |
1601 |
} |
1602 |
|
1603 |
1 |
1604 |
} |
1605 |
}; |
1606 |
|
1607 |
=item json => $cb->($handle, $hash_or_arrayref) |
1608 |
|
1609 |
Reads a JSON object or array, decodes it and passes it to the |
1610 |
callback. When a parse error occurs, an C<EBADMSG> error will be raised. |
1611 |
|
1612 |
If a C<json> object was passed to the constructor, then that will be used |
1613 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1614 |
|
1615 |
This read type uses the incremental parser available with JSON version |
1616 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1617 |
dependency on your own: this module will load the JSON module, but |
1618 |
AnyEvent does not depend on it itself. |
1619 |
|
1620 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1621 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1622 |
the C<json> write type description, above, for an actual example. |
1623 |
|
1624 |
=cut |
1625 |
|
1626 |
register_read_type json => sub { |
1627 |
my ($self, $cb) = @_; |
1628 |
|
1629 |
my $json = $self->{json} ||= json_coder; |
1630 |
|
1631 |
my $data; |
1632 |
my $rbuf = \$self->{rbuf}; |
1633 |
|
1634 |
sub { |
1635 |
my $ref = eval { $json->incr_parse ($self->{rbuf}) }; |
1636 |
|
1637 |
if ($ref) { |
1638 |
$self->{rbuf} = $json->incr_text; |
1639 |
$json->incr_text = ""; |
1640 |
$cb->($self, $ref); |
1641 |
|
1642 |
1 |
1643 |
} elsif ($@) { |
1644 |
# error case |
1645 |
$json->incr_skip; |
1646 |
|
1647 |
$self->{rbuf} = $json->incr_text; |
1648 |
$json->incr_text = ""; |
1649 |
|
1650 |
$self->_error (Errno::EBADMSG); |
1651 |
|
1652 |
() |
1653 |
} else { |
1654 |
$self->{rbuf} = ""; |
1655 |
|
1656 |
() |
1657 |
} |
1658 |
} |
1659 |
}; |
1660 |
|
1661 |
=item storable => $cb->($handle, $ref) |
1662 |
|
1663 |
Deserialises a L<Storable> frozen representation as written by the |
1664 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1665 |
data). |
1666 |
|
1667 |
Raises C<EBADMSG> error if the data could not be decoded. |
1668 |
|
1669 |
=cut |
1670 |
|
1671 |
register_read_type storable => sub { |
1672 |
my ($self, $cb) = @_; |
1673 |
|
1674 |
require Storable; |
1675 |
|
1676 |
sub { |
1677 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1678 |
defined (my $len = eval { unpack "w", $_[0]{rbuf} }) |
1679 |
or return; |
1680 |
|
1681 |
my $format = length pack "w", $len; |
1682 |
|
1683 |
# bypass unshift if we already have the remaining chunk |
1684 |
if ($format + $len <= length $_[0]{rbuf}) { |
1685 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1686 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1687 |
$cb->($_[0], Storable::thaw ($data)); |
1688 |
} else { |
1689 |
# remove prefix |
1690 |
substr $_[0]{rbuf}, 0, $format, ""; |
1691 |
|
1692 |
# read remaining chunk |
1693 |
$_[0]->unshift_read (chunk => $len, sub { |
1694 |
if (my $ref = eval { Storable::thaw ($_[1]) }) { |
1695 |
$cb->($_[0], $ref); |
1696 |
} else { |
1697 |
$self->_error (Errno::EBADMSG); |
1698 |
} |
1699 |
}); |
1700 |
} |
1701 |
|
1702 |
1 |
1703 |
} |
1704 |
}; |
1705 |
|
1706 |
=back |
1707 |
|
1708 |
=item custom read types - Package::anyevent_read_type $handle, $cb, @args |
1709 |
|
1710 |
Instead of one of the predefined types, you can also specify the name |
1711 |
of a package. AnyEvent will try to load the package and then expects to |
1712 |
find a function named C<anyevent_read_type> inside. If it isn't found, it |
1713 |
progressively tries to load the parent package until it either finds the |
1714 |
function (good) or runs out of packages (bad). |
1715 |
|
1716 |
Whenever this type is used, C<push_read> will invoke the function with the |
1717 |
handle object, the original callback and the remaining arguments. |
1718 |
|
1719 |
The function is supposed to return a callback (usually a closure) that |
1720 |
works as a plain read callback (see C<< ->push_read ($cb) >>), so you can |
1721 |
mentally treat the function as a "configurable read type to read callback" |
1722 |
converter. |
1723 |
|
1724 |
It should invoke the original callback when it is done reading (remember |
1725 |
to pass C<$handle> as first argument as all other callbacks do that, |
1726 |
although there is no strict requirement on this). |
1727 |
|
1728 |
For examples, see the source of this module (F<perldoc -m |
1729 |
AnyEvent::Handle>, search for C<register_read_type>)). |
1730 |
|
1731 |
=item $handle->stop_read |
1732 |
|
1733 |
=item $handle->start_read |
1734 |
|
1735 |
In rare cases you actually do not want to read anything from the |
1736 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1737 |
any queued callbacks will be executed then. To start reading again, call |
1738 |
C<start_read>. |
1739 |
|
1740 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1741 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1742 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1743 |
there are any read requests in the queue. |
1744 |
|
1745 |
These methods will have no effect when in TLS mode (as TLS doesn't support |
1746 |
half-duplex connections). |
1747 |
|
1748 |
=cut |
1749 |
|
1750 |
sub stop_read { |
1751 |
my ($self) = @_; |
1752 |
|
1753 |
delete $self->{_rw} unless $self->{tls}; |
1754 |
} |
1755 |
|
1756 |
sub start_read { |
1757 |
my ($self) = @_; |
1758 |
|
1759 |
unless ($self->{_rw} || $self->{_eof} || !$self->{fh}) { |
1760 |
Scalar::Util::weaken $self; |
1761 |
|
1762 |
$self->{_rw} = AE::io $self->{fh}, 0, sub { |
1763 |
my $rbuf = \($self->{tls} ? my $buf : $self->{rbuf}); |
1764 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size}, length $$rbuf; |
1765 |
|
1766 |
if ($len > 0) { |
1767 |
$self->{_activity} = $self->{_ractivity} = AE::now; |
1768 |
|
1769 |
if ($self->{tls}) { |
1770 |
Net::SSLeay::BIO_write ($self->{_rbio}, $$rbuf); |
1771 |
|
1772 |
&_dotls ($self); |
1773 |
} else { |
1774 |
$self->_drain_rbuf; |
1775 |
} |
1776 |
|
1777 |
if ($len == $self->{read_size}) { |
1778 |
$self->{read_size} *= 2; |
1779 |
$self->{read_size} = $self->{max_read_size} || MAX_READ_SIZE |
1780 |
if $self->{read_size} > ($self->{max_read_size} || MAX_READ_SIZE); |
1781 |
} |
1782 |
|
1783 |
} elsif (defined $len) { |
1784 |
delete $self->{_rw}; |
1785 |
$self->{_eof} = 1; |
1786 |
$self->_drain_rbuf; |
1787 |
|
1788 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1789 |
return $self->_error ($!, 1); |
1790 |
} |
1791 |
}; |
1792 |
} |
1793 |
} |
1794 |
|
1795 |
our $ERROR_SYSCALL; |
1796 |
our $ERROR_WANT_READ; |
1797 |
|
1798 |
sub _tls_error { |
1799 |
my ($self, $err) = @_; |
1800 |
|
1801 |
return $self->_error ($!, 1) |
1802 |
if $err == Net::SSLeay::ERROR_SYSCALL (); |
1803 |
|
1804 |
my $err =Net::SSLeay::ERR_error_string (Net::SSLeay::ERR_get_error ()); |
1805 |
|
1806 |
# reduce error string to look less scary |
1807 |
$err =~ s/^error:[0-9a-fA-F]{8}:[^:]+:([^:]+):/\L$1: /; |
1808 |
|
1809 |
if ($self->{_on_starttls}) { |
1810 |
(delete $self->{_on_starttls})->($self, undef, $err); |
1811 |
&_freetls; |
1812 |
} else { |
1813 |
&_freetls; |
1814 |
$self->_error (Errno::EPROTO, 1, $err); |
1815 |
} |
1816 |
} |
1817 |
|
1818 |
# poll the write BIO and send the data if applicable |
1819 |
# also decode read data if possible |
1820 |
# this is basiclaly our TLS state machine |
1821 |
# more efficient implementations are possible with openssl, |
1822 |
# but not with the buggy and incomplete Net::SSLeay. |
1823 |
sub _dotls { |
1824 |
my ($self) = @_; |
1825 |
|
1826 |
my $tmp; |
1827 |
|
1828 |
if (length $self->{_tls_wbuf}) { |
1829 |
while (($tmp = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1830 |
substr $self->{_tls_wbuf}, 0, $tmp, ""; |
1831 |
} |
1832 |
|
1833 |
$tmp = Net::SSLeay::get_error ($self->{tls}, $tmp); |
1834 |
return $self->_tls_error ($tmp) |
1835 |
if $tmp != $ERROR_WANT_READ |
1836 |
&& ($tmp != $ERROR_SYSCALL || $!); |
1837 |
} |
1838 |
|
1839 |
while (defined ($tmp = Net::SSLeay::read ($self->{tls}))) { |
1840 |
unless (length $tmp) { |
1841 |
$self->{_on_starttls} |
1842 |
and (delete $self->{_on_starttls})->($self, undef, "EOF during handshake"); # ??? |
1843 |
&_freetls; |
1844 |
|
1845 |
if ($self->{on_stoptls}) { |
1846 |
$self->{on_stoptls}($self); |
1847 |
return; |
1848 |
} else { |
1849 |
# let's treat SSL-eof as we treat normal EOF |
1850 |
delete $self->{_rw}; |
1851 |
$self->{_eof} = 1; |
1852 |
} |
1853 |
} |
1854 |
|
1855 |
$self->{_tls_rbuf} .= $tmp; |
1856 |
$self->_drain_rbuf; |
1857 |
$self->{tls} or return; # tls session might have gone away in callback |
1858 |
} |
1859 |
|
1860 |
$tmp = Net::SSLeay::get_error ($self->{tls}, -1); |
1861 |
return $self->_tls_error ($tmp) |
1862 |
if $tmp != $ERROR_WANT_READ |
1863 |
&& ($tmp != $ERROR_SYSCALL || $!); |
1864 |
|
1865 |
while (length ($tmp = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1866 |
$self->{wbuf} .= $tmp; |
1867 |
$self->_drain_wbuf; |
1868 |
$self->{tls} or return; # tls session might have gone away in callback |
1869 |
} |
1870 |
|
1871 |
$self->{_on_starttls} |
1872 |
and Net::SSLeay::state ($self->{tls}) == Net::SSLeay::ST_OK () |
1873 |
and (delete $self->{_on_starttls})->($self, 1, "TLS/SSL connection established"); |
1874 |
} |
1875 |
|
1876 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1877 |
|
1878 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1879 |
object is created, you can also do that at a later time by calling |
1880 |
C<starttls>. |
1881 |
|
1882 |
Starting TLS is currently an asynchronous operation - when you push some |
1883 |
write data and then call C<< ->starttls >> then TLS negotiation will start |
1884 |
immediately, after which the queued write data is then sent. |
1885 |
|
1886 |
The first argument is the same as the C<tls> constructor argument (either |
1887 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1888 |
|
1889 |
The second argument is the optional C<AnyEvent::TLS> object that is used |
1890 |
when AnyEvent::Handle has to create its own TLS connection object, or |
1891 |
a hash reference with C<< key => value >> pairs that will be used to |
1892 |
construct a new context. |
1893 |
|
1894 |
The TLS connection object will end up in C<< $handle->{tls} >>, the TLS |
1895 |
context in C<< $handle->{tls_ctx} >> after this call and can be used or |
1896 |
changed to your liking. Note that the handshake might have already started |
1897 |
when this function returns. |
1898 |
|
1899 |
Due to bugs in OpenSSL, it might or might not be possible to do multiple |
1900 |
handshakes on the same stream. It is best to not attempt to use the |
1901 |
stream after stopping TLS. |
1902 |
|
1903 |
This method may invoke callbacks (and therefore the handle might be |
1904 |
destroyed after it returns). |
1905 |
|
1906 |
=cut |
1907 |
|
1908 |
our %TLS_CACHE; #TODO not yet documented, should we? |
1909 |
|
1910 |
sub starttls { |
1911 |
my ($self, $tls, $ctx) = @_; |
1912 |
|
1913 |
Carp::croak "It is an error to call starttls on an AnyEvent::Handle object while TLS is already active, caught" |
1914 |
if $self->{tls}; |
1915 |
|
1916 |
$self->{tls} = $tls; |
1917 |
$self->{tls_ctx} = $ctx if @_ > 2; |
1918 |
|
1919 |
return unless $self->{fh}; |
1920 |
|
1921 |
require Net::SSLeay; |
1922 |
|
1923 |
$ERROR_SYSCALL = Net::SSLeay::ERROR_SYSCALL (); |
1924 |
$ERROR_WANT_READ = Net::SSLeay::ERROR_WANT_READ (); |
1925 |
|
1926 |
$tls = delete $self->{tls}; |
1927 |
$ctx = $self->{tls_ctx}; |
1928 |
|
1929 |
local $Carp::CarpLevel = 1; # skip ourselves when creating a new context or session |
1930 |
|
1931 |
if ("HASH" eq ref $ctx) { |
1932 |
require AnyEvent::TLS; |
1933 |
|
1934 |
if ($ctx->{cache}) { |
1935 |
my $key = $ctx+0; |
1936 |
$ctx = $TLS_CACHE{$key} ||= new AnyEvent::TLS %$ctx; |
1937 |
} else { |
1938 |
$ctx = new AnyEvent::TLS %$ctx; |
1939 |
} |
1940 |
} |
1941 |
|
1942 |
$self->{tls_ctx} = $ctx || TLS_CTX (); |
1943 |
$self->{tls} = $tls = $self->{tls_ctx}->_get_session ($tls, $self, $self->{peername}); |
1944 |
|
1945 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1946 |
# but the openssl maintainers basically said: "trust us, it just works". |
1947 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1948 |
# and mismaintained ssleay-module doesn't even offer them). |
1949 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1950 |
# |
1951 |
# in short: this is a mess. |
1952 |
# |
1953 |
# note that we do not try to keep the length constant between writes as we are required to do. |
1954 |
# we assume that most (but not all) of this insanity only applies to non-blocking cases, |
1955 |
# and we drive openssl fully in blocking mode here. Or maybe we don't - openssl seems to |
1956 |
# have identity issues in that area. |
1957 |
# Net::SSLeay::CTX_set_mode ($ssl, |
1958 |
# (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1959 |
# | (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1960 |
Net::SSLeay::CTX_set_mode ($tls, 1|2); |
1961 |
|
1962 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1963 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1964 |
|
1965 |
Net::SSLeay::BIO_write ($self->{_rbio}, delete $self->{rbuf}); |
1966 |
|
1967 |
Net::SSLeay::set_bio ($tls, $self->{_rbio}, $self->{_wbio}); |
1968 |
|
1969 |
$self->{_on_starttls} = sub { $_[0]{on_starttls}(@_) } |
1970 |
if $self->{on_starttls}; |
1971 |
|
1972 |
&_dotls; # need to trigger the initial handshake |
1973 |
$self->start_read; # make sure we actually do read |
1974 |
} |
1975 |
|
1976 |
=item $handle->stoptls |
1977 |
|
1978 |
Shuts down the SSL connection - this makes a proper EOF handshake by |
1979 |
sending a close notify to the other side, but since OpenSSL doesn't |
1980 |
support non-blocking shut downs, it is not guaranteed that you can re-use |
1981 |
the stream afterwards. |
1982 |
|
1983 |
This method may invoke callbacks (and therefore the handle might be |
1984 |
destroyed after it returns). |
1985 |
|
1986 |
=cut |
1987 |
|
1988 |
sub stoptls { |
1989 |
my ($self) = @_; |
1990 |
|
1991 |
if ($self->{tls} && $self->{fh}) { |
1992 |
Net::SSLeay::shutdown ($self->{tls}); |
1993 |
|
1994 |
&_dotls; |
1995 |
|
1996 |
# # we don't give a shit. no, we do, but we can't. no...#d# |
1997 |
# # we, we... have to use openssl :/#d# |
1998 |
# &_freetls;#d# |
1999 |
} |
2000 |
} |
2001 |
|
2002 |
sub _freetls { |
2003 |
my ($self) = @_; |
2004 |
|
2005 |
return unless $self->{tls}; |
2006 |
|
2007 |
$self->{tls_ctx}->_put_session (delete $self->{tls}) |
2008 |
if $self->{tls} > 0; |
2009 |
|
2010 |
delete @$self{qw(_rbio _wbio _tls_wbuf _on_starttls)}; |
2011 |
} |
2012 |
|
2013 |
sub DESTROY { |
2014 |
my ($self) = @_; |
2015 |
|
2016 |
&_freetls; |
2017 |
|
2018 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
2019 |
|
2020 |
if ($linger && length $self->{wbuf} && $self->{fh}) { |
2021 |
my $fh = delete $self->{fh}; |
2022 |
my $wbuf = delete $self->{wbuf}; |
2023 |
|
2024 |
my @linger; |
2025 |
|
2026 |
push @linger, AE::io $fh, 1, sub { |
2027 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
2028 |
|
2029 |
if ($len > 0) { |
2030 |
substr $wbuf, 0, $len, ""; |
2031 |
} elsif (defined $len || ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK)) { |
2032 |
@linger = (); # end |
2033 |
} |
2034 |
}; |
2035 |
push @linger, AE::timer $linger, 0, sub { |
2036 |
@linger = (); |
2037 |
}; |
2038 |
} |
2039 |
} |
2040 |
|
2041 |
=item $handle->destroy |
2042 |
|
2043 |
Shuts down the handle object as much as possible - this call ensures that |
2044 |
no further callbacks will be invoked and as many resources as possible |
2045 |
will be freed. Any method you will call on the handle object after |
2046 |
destroying it in this way will be silently ignored (and it will return the |
2047 |
empty list). |
2048 |
|
2049 |
Normally, you can just "forget" any references to an AnyEvent::Handle |
2050 |
object and it will simply shut down. This works in fatal error and EOF |
2051 |
callbacks, as well as code outside. It does I<NOT> work in a read or write |
2052 |
callback, so when you want to destroy the AnyEvent::Handle object from |
2053 |
within such an callback. You I<MUST> call C<< ->destroy >> explicitly in |
2054 |
that case. |
2055 |
|
2056 |
Destroying the handle object in this way has the advantage that callbacks |
2057 |
will be removed as well, so if those are the only reference holders (as |
2058 |
is common), then one doesn't need to do anything special to break any |
2059 |
reference cycles. |
2060 |
|
2061 |
The handle might still linger in the background and write out remaining |
2062 |
data, as specified by the C<linger> option, however. |
2063 |
|
2064 |
=cut |
2065 |
|
2066 |
sub destroy { |
2067 |
my ($self) = @_; |
2068 |
|
2069 |
$self->DESTROY; |
2070 |
%$self = (); |
2071 |
bless $self, "AnyEvent::Handle::destroyed"; |
2072 |
} |
2073 |
|
2074 |
sub AnyEvent::Handle::destroyed::AUTOLOAD { |
2075 |
#nop |
2076 |
} |
2077 |
|
2078 |
=item $handle->destroyed |
2079 |
|
2080 |
Returns false as long as the handle hasn't been destroyed by a call to C<< |
2081 |
->destroy >>, true otherwise. |
2082 |
|
2083 |
Can be useful to decide whether the handle is still valid after some |
2084 |
callback possibly destroyed the handle. For example, C<< ->push_write >>, |
2085 |
C<< ->starttls >> and other methods can call user callbacks, which in turn |
2086 |
can destroy the handle, so work can be avoided by checking sometimes: |
2087 |
|
2088 |
$hdl->starttls ("accept"); |
2089 |
return if $hdl->destroyed; |
2090 |
$hdl->push_write (... |
2091 |
|
2092 |
Note that the call to C<push_write> will silently be ignored if the handle |
2093 |
has been destroyed, so often you can just ignore the possibility of the |
2094 |
handle being destroyed. |
2095 |
|
2096 |
=cut |
2097 |
|
2098 |
sub destroyed { 0 } |
2099 |
sub AnyEvent::Handle::destroyed::destroyed { 1 } |
2100 |
|
2101 |
=item AnyEvent::Handle::TLS_CTX |
2102 |
|
2103 |
This function creates and returns the AnyEvent::TLS object used by default |
2104 |
for TLS mode. |
2105 |
|
2106 |
The context is created by calling L<AnyEvent::TLS> without any arguments. |
2107 |
|
2108 |
=cut |
2109 |
|
2110 |
our $TLS_CTX; |
2111 |
|
2112 |
sub TLS_CTX() { |
2113 |
$TLS_CTX ||= do { |
2114 |
require AnyEvent::TLS; |
2115 |
|
2116 |
new AnyEvent::TLS |
2117 |
} |
2118 |
} |
2119 |
|
2120 |
=back |
2121 |
|
2122 |
|
2123 |
=head1 NONFREQUENTLY ASKED QUESTIONS |
2124 |
|
2125 |
=over 4 |
2126 |
|
2127 |
=item I C<undef> the AnyEvent::Handle reference inside my callback and |
2128 |
still get further invocations! |
2129 |
|
2130 |
That's because AnyEvent::Handle keeps a reference to itself when handling |
2131 |
read or write callbacks. |
2132 |
|
2133 |
It is only safe to "forget" the reference inside EOF or error callbacks, |
2134 |
from within all other callbacks, you need to explicitly call the C<< |
2135 |
->destroy >> method. |
2136 |
|
2137 |
=item I get different callback invocations in TLS mode/Why can't I pause |
2138 |
reading? |
2139 |
|
2140 |
Unlike, say, TCP, TLS connections do not consist of two independent |
2141 |
communication channels, one for each direction. Or put differently, the |
2142 |
read and write directions are not independent of each other: you cannot |
2143 |
write data unless you are also prepared to read, and vice versa. |
2144 |
|
2145 |
This means that, in TLS mode, you might get C<on_error> or C<on_eof> |
2146 |
callback invocations when you are not expecting any read data - the reason |
2147 |
is that AnyEvent::Handle always reads in TLS mode. |
2148 |
|
2149 |
During the connection, you have to make sure that you always have a |
2150 |
non-empty read-queue, or an C<on_read> watcher. At the end of the |
2151 |
connection (or when you no longer want to use it) you can call the |
2152 |
C<destroy> method. |
2153 |
|
2154 |
=item How do I read data until the other side closes the connection? |
2155 |
|
2156 |
If you just want to read your data into a perl scalar, the easiest way |
2157 |
to achieve this is by setting an C<on_read> callback that does nothing, |
2158 |
clearing the C<on_eof> callback and in the C<on_error> callback, the data |
2159 |
will be in C<$_[0]{rbuf}>: |
2160 |
|
2161 |
$handle->on_read (sub { }); |
2162 |
$handle->on_eof (undef); |
2163 |
$handle->on_error (sub { |
2164 |
my $data = delete $_[0]{rbuf}; |
2165 |
}); |
2166 |
|
2167 |
The reason to use C<on_error> is that TCP connections, due to latencies |
2168 |
and packets loss, might get closed quite violently with an error, when in |
2169 |
fact all data has been received. |
2170 |
|
2171 |
It is usually better to use acknowledgements when transferring data, |
2172 |
to make sure the other side hasn't just died and you got the data |
2173 |
intact. This is also one reason why so many internet protocols have an |
2174 |
explicit QUIT command. |
2175 |
|
2176 |
=item I don't want to destroy the handle too early - how do I wait until |
2177 |
all data has been written? |
2178 |
|
2179 |
After writing your last bits of data, set the C<on_drain> callback |
2180 |
and destroy the handle in there - with the default setting of |
2181 |
C<low_water_mark> this will be called precisely when all data has been |
2182 |
written to the socket: |
2183 |
|
2184 |
$handle->push_write (...); |
2185 |
$handle->on_drain (sub { |
2186 |
warn "all data submitted to the kernel\n"; |
2187 |
undef $handle; |
2188 |
}); |
2189 |
|
2190 |
If you just want to queue some data and then signal EOF to the other side, |
2191 |
consider using C<< ->push_shutdown >> instead. |
2192 |
|
2193 |
=item I want to contact a TLS/SSL server, I don't care about security. |
2194 |
|
2195 |
If your TLS server is a pure TLS server (e.g. HTTPS) that only speaks TLS, |
2196 |
connect to it and then create the AnyEvent::Handle with the C<tls> |
2197 |
parameter: |
2198 |
|
2199 |
tcp_connect $host, $port, sub { |
2200 |
my ($fh) = @_; |
2201 |
|
2202 |
my $handle = new AnyEvent::Handle |
2203 |
fh => $fh, |
2204 |
tls => "connect", |
2205 |
on_error => sub { ... }; |
2206 |
|
2207 |
$handle->push_write (...); |
2208 |
}; |
2209 |
|
2210 |
=item I want to contact a TLS/SSL server, I do care about security. |
2211 |
|
2212 |
Then you should additionally enable certificate verification, including |
2213 |
peername verification, if the protocol you use supports it (see |
2214 |
L<AnyEvent::TLS>, C<verify_peername>). |
2215 |
|
2216 |
E.g. for HTTPS: |
2217 |
|
2218 |
tcp_connect $host, $port, sub { |
2219 |
my ($fh) = @_; |
2220 |
|
2221 |
my $handle = new AnyEvent::Handle |
2222 |
fh => $fh, |
2223 |
peername => $host, |
2224 |
tls => "connect", |
2225 |
tls_ctx => { verify => 1, verify_peername => "https" }, |
2226 |
... |
2227 |
|
2228 |
Note that you must specify the hostname you connected to (or whatever |
2229 |
"peername" the protocol needs) as the C<peername> argument, otherwise no |
2230 |
peername verification will be done. |
2231 |
|
2232 |
The above will use the system-dependent default set of trusted CA |
2233 |
certificates. If you want to check against a specific CA, add the |
2234 |
C<ca_file> (or C<ca_cert>) arguments to C<tls_ctx>: |
2235 |
|
2236 |
tls_ctx => { |
2237 |
verify => 1, |
2238 |
verify_peername => "https", |
2239 |
ca_file => "my-ca-cert.pem", |
2240 |
}, |
2241 |
|
2242 |
=item I want to create a TLS/SSL server, how do I do that? |
2243 |
|
2244 |
Well, you first need to get a server certificate and key. You have |
2245 |
three options: a) ask a CA (buy one, use cacert.org etc.) b) create a |
2246 |
self-signed certificate (cheap. check the search engine of your choice, |
2247 |
there are many tutorials on the net) or c) make your own CA (tinyca2 is a |
2248 |
nice program for that purpose). |
2249 |
|
2250 |
Then create a file with your private key (in PEM format, see |
2251 |
L<AnyEvent::TLS>), followed by the certificate (also in PEM format). The |
2252 |
file should then look like this: |
2253 |
|
2254 |
-----BEGIN RSA PRIVATE KEY----- |
2255 |
...header data |
2256 |
... lots of base64'y-stuff |
2257 |
-----END RSA PRIVATE KEY----- |
2258 |
|
2259 |
-----BEGIN CERTIFICATE----- |
2260 |
... lots of base64'y-stuff |
2261 |
-----END CERTIFICATE----- |
2262 |
|
2263 |
The important bits are the "PRIVATE KEY" and "CERTIFICATE" parts. Then |
2264 |
specify this file as C<cert_file>: |
2265 |
|
2266 |
tcp_server undef, $port, sub { |
2267 |
my ($fh) = @_; |
2268 |
|
2269 |
my $handle = new AnyEvent::Handle |
2270 |
fh => $fh, |
2271 |
tls => "accept", |
2272 |
tls_ctx => { cert_file => "my-server-keycert.pem" }, |
2273 |
... |
2274 |
|
2275 |
When you have intermediate CA certificates that your clients might not |
2276 |
know about, just append them to the C<cert_file>. |
2277 |
|
2278 |
=back |
2279 |
|
2280 |
|
2281 |
=head1 SUBCLASSING AnyEvent::Handle |
2282 |
|
2283 |
In many cases, you might want to subclass AnyEvent::Handle. |
2284 |
|
2285 |
To make this easier, a given version of AnyEvent::Handle uses these |
2286 |
conventions: |
2287 |
|
2288 |
=over 4 |
2289 |
|
2290 |
=item * all constructor arguments become object members. |
2291 |
|
2292 |
At least initially, when you pass a C<tls>-argument to the constructor it |
2293 |
will end up in C<< $handle->{tls} >>. Those members might be changed or |
2294 |
mutated later on (for example C<tls> will hold the TLS connection object). |
2295 |
|
2296 |
=item * other object member names are prefixed with an C<_>. |
2297 |
|
2298 |
All object members not explicitly documented (internal use) are prefixed |
2299 |
with an underscore character, so the remaining non-C<_>-namespace is free |
2300 |
for use for subclasses. |
2301 |
|
2302 |
=item * all members not documented here and not prefixed with an underscore |
2303 |
are free to use in subclasses. |
2304 |
|
2305 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
2306 |
member variables, but that's just life. At least it is documented. |
2307 |
|
2308 |
=back |
2309 |
|
2310 |
=head1 AUTHOR |
2311 |
|
2312 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
2313 |
|
2314 |
=cut |
2315 |
|
2316 |
1; # End of AnyEvent::Handle |