1 |
package AnyEvent::Handle; |
2 |
|
3 |
use Scalar::Util (); |
4 |
use Carp (); |
5 |
use Errno qw(EAGAIN EINTR); |
6 |
|
7 |
use AnyEvent (); BEGIN { AnyEvent::common_sense } |
8 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
9 |
|
10 |
=head1 NAME |
11 |
|
12 |
AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent |
13 |
|
14 |
=cut |
15 |
|
16 |
our $VERSION = 4.86; |
17 |
|
18 |
=head1 SYNOPSIS |
19 |
|
20 |
use AnyEvent; |
21 |
use AnyEvent::Handle; |
22 |
|
23 |
my $cv = AnyEvent->condvar; |
24 |
|
25 |
my $hdl; $hdl = new AnyEvent::Handle |
26 |
fh => \*STDIN, |
27 |
on_error => sub { |
28 |
my ($hdl, $fatal, $msg) = @_; |
29 |
warn "got error $msg\n"; |
30 |
$hdl->destroy; |
31 |
$cv->send; |
32 |
); |
33 |
|
34 |
# send some request line |
35 |
$hdl->push_write ("getinfo\015\012"); |
36 |
|
37 |
# read the response line |
38 |
$hdl->push_read (line => sub { |
39 |
my ($hdl, $line) = @_; |
40 |
warn "got line <$line>\n"; |
41 |
$cv->send; |
42 |
}); |
43 |
|
44 |
$cv->recv; |
45 |
|
46 |
=head1 DESCRIPTION |
47 |
|
48 |
This module is a helper module to make it easier to do event-based I/O on |
49 |
filehandles. For utility functions for doing non-blocking connects and accepts |
50 |
on sockets see L<AnyEvent::Util>. |
51 |
|
52 |
The L<AnyEvent::Intro> tutorial contains some well-documented |
53 |
AnyEvent::Handle examples. |
54 |
|
55 |
In the following, when the documentation refers to of "bytes" then this |
56 |
means characters. As sysread and syswrite are used for all I/O, their |
57 |
treatment of characters applies to this module as well. |
58 |
|
59 |
All callbacks will be invoked with the handle object as their first |
60 |
argument. |
61 |
|
62 |
=head1 METHODS |
63 |
|
64 |
=over 4 |
65 |
|
66 |
=item $handle = B<new> AnyEvent::TLS fh => $filehandle, key => value... |
67 |
|
68 |
The constructor supports these arguments (all as C<< key => value >> pairs). |
69 |
|
70 |
=over 4 |
71 |
|
72 |
=item fh => $filehandle [MANDATORY] |
73 |
|
74 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
75 |
|
76 |
NOTE: The filehandle will be set to non-blocking mode (using |
77 |
C<AnyEvent::Util::fh_nonblocking>) by the constructor and needs to stay in |
78 |
that mode. |
79 |
|
80 |
=item on_eof => $cb->($handle) |
81 |
|
82 |
Set the callback to be called when an end-of-file condition is detected, |
83 |
i.e. in the case of a socket, when the other side has closed the |
84 |
connection cleanly, and there are no outstanding read requests in the |
85 |
queue (if there are read requests, then an EOF counts as an unexpected |
86 |
connection close and will be flagged as an error). |
87 |
|
88 |
For sockets, this just means that the other side has stopped sending data, |
89 |
you can still try to write data, and, in fact, one can return from the EOF |
90 |
callback and continue writing data, as only the read part has been shut |
91 |
down. |
92 |
|
93 |
If an EOF condition has been detected but no C<on_eof> callback has been |
94 |
set, then a fatal error will be raised with C<$!> set to <0>. |
95 |
|
96 |
=item on_error => $cb->($handle, $fatal, $message) |
97 |
|
98 |
This is the error callback, which is called when, well, some error |
99 |
occured, such as not being able to resolve the hostname, failure to |
100 |
connect or a read error. |
101 |
|
102 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
103 |
fatal errors the handle object will be destroyed (by a call to C<< -> |
104 |
destroy >>) after invoking the error callback (which means you are free to |
105 |
examine the handle object). Examples of fatal errors are an EOF condition |
106 |
with active (but unsatisifable) read watchers (C<EPIPE>) or I/O errors. |
107 |
|
108 |
AnyEvent::Handle tries to find an appropriate error code for you to check |
109 |
against, but in some cases (TLS errors), this does not work well. It is |
110 |
recommended to always output the C<$message> argument in human-readable |
111 |
error messages (it's usually the same as C<"$!">). |
112 |
|
113 |
Non-fatal errors can be retried by simply returning, but it is recommended |
114 |
to simply ignore this parameter and instead abondon the handle object |
115 |
when this callback is invoked. Examples of non-fatal errors are timeouts |
116 |
C<ETIMEDOUT>) or badly-formatted data (C<EBADMSG>). |
117 |
|
118 |
On callback entrance, the value of C<$!> contains the operating system |
119 |
error code (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT>, C<EBADMSG> or |
120 |
C<EPROTO>). |
121 |
|
122 |
While not mandatory, it is I<highly> recommended to set this callback, as |
123 |
you will not be notified of errors otherwise. The default simply calls |
124 |
C<croak>. |
125 |
|
126 |
=item on_read => $cb->($handle) |
127 |
|
128 |
This sets the default read callback, which is called when data arrives |
129 |
and no read request is in the queue (unlike read queue callbacks, this |
130 |
callback will only be called when at least one octet of data is in the |
131 |
read buffer). |
132 |
|
133 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
134 |
method or access the C<< $handle->{rbuf} >> member directly. Note that you |
135 |
must not enlarge or modify the read buffer, you can only remove data at |
136 |
the beginning from it. |
137 |
|
138 |
When an EOF condition is detected then AnyEvent::Handle will first try to |
139 |
feed all the remaining data to the queued callbacks and C<on_read> before |
140 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
141 |
error will be raised (with C<$!> set to C<EPIPE>). |
142 |
|
143 |
Note that, unlike requests in the read queue, an C<on_read> callback |
144 |
doesn't mean you I<require> some data: if there is an EOF and there |
145 |
are outstanding read requests then an error will be flagged. With an |
146 |
C<on_read> callback, the C<on_eof> callback will be invoked. |
147 |
|
148 |
=item on_drain => $cb->($handle) |
149 |
|
150 |
This sets the callback that is called when the write buffer becomes empty |
151 |
(or when the callback is set and the buffer is empty already). |
152 |
|
153 |
To append to the write buffer, use the C<< ->push_write >> method. |
154 |
|
155 |
This callback is useful when you don't want to put all of your write data |
156 |
into the queue at once, for example, when you want to write the contents |
157 |
of some file to the socket you might not want to read the whole file into |
158 |
memory and push it into the queue, but instead only read more data from |
159 |
the file when the write queue becomes empty. |
160 |
|
161 |
=item timeout => $fractional_seconds |
162 |
|
163 |
If non-zero, then this enables an "inactivity" timeout: whenever this many |
164 |
seconds pass without a successful read or write on the underlying file |
165 |
handle, the C<on_timeout> callback will be invoked (and if that one is |
166 |
missing, a non-fatal C<ETIMEDOUT> error will be raised). |
167 |
|
168 |
Note that timeout processing is also active when you currently do not have |
169 |
any outstanding read or write requests: If you plan to keep the connection |
170 |
idle then you should disable the timout temporarily or ignore the timeout |
171 |
in the C<on_timeout> callback, in which case AnyEvent::Handle will simply |
172 |
restart the timeout. |
173 |
|
174 |
Zero (the default) disables this timeout. |
175 |
|
176 |
=item on_timeout => $cb->($handle) |
177 |
|
178 |
Called whenever the inactivity timeout passes. If you return from this |
179 |
callback, then the timeout will be reset as if some activity had happened, |
180 |
so this condition is not fatal in any way. |
181 |
|
182 |
=item rbuf_max => <bytes> |
183 |
|
184 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
185 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
186 |
avoid some forms of denial-of-service attacks. |
187 |
|
188 |
For example, a server accepting connections from untrusted sources should |
189 |
be configured to accept only so-and-so much data that it cannot act on |
190 |
(for example, when expecting a line, an attacker could send an unlimited |
191 |
amount of data without a callback ever being called as long as the line |
192 |
isn't finished). |
193 |
|
194 |
=item autocork => <boolean> |
195 |
|
196 |
When disabled (the default), then C<push_write> will try to immediately |
197 |
write the data to the handle, if possible. This avoids having to register |
198 |
a write watcher and wait for the next event loop iteration, but can |
199 |
be inefficient if you write multiple small chunks (on the wire, this |
200 |
disadvantage is usually avoided by your kernel's nagle algorithm, see |
201 |
C<no_delay>, but this option can save costly syscalls). |
202 |
|
203 |
When enabled, then writes will always be queued till the next event loop |
204 |
iteration. This is efficient when you do many small writes per iteration, |
205 |
but less efficient when you do a single write only per iteration (or when |
206 |
the write buffer often is full). It also increases write latency. |
207 |
|
208 |
=item no_delay => <boolean> |
209 |
|
210 |
When doing small writes on sockets, your operating system kernel might |
211 |
wait a bit for more data before actually sending it out. This is called |
212 |
the Nagle algorithm, and usually it is beneficial. |
213 |
|
214 |
In some situations you want as low a delay as possible, which can be |
215 |
accomplishd by setting this option to a true value. |
216 |
|
217 |
The default is your opertaing system's default behaviour (most likely |
218 |
enabled), this option explicitly enables or disables it, if possible. |
219 |
|
220 |
=item read_size => <bytes> |
221 |
|
222 |
The default read block size (the amount of bytes this module will |
223 |
try to read during each loop iteration, which affects memory |
224 |
requirements). Default: C<8192>. |
225 |
|
226 |
=item low_water_mark => <bytes> |
227 |
|
228 |
Sets the amount of bytes (default: C<0>) that make up an "empty" write |
229 |
buffer: If the write reaches this size or gets even samller it is |
230 |
considered empty. |
231 |
|
232 |
Sometimes it can be beneficial (for performance reasons) to add data to |
233 |
the write buffer before it is fully drained, but this is a rare case, as |
234 |
the operating system kernel usually buffers data as well, so the default |
235 |
is good in almost all cases. |
236 |
|
237 |
=item linger => <seconds> |
238 |
|
239 |
If non-zero (default: C<3600>), then the destructor of the |
240 |
AnyEvent::Handle object will check whether there is still outstanding |
241 |
write data and will install a watcher that will write this data to the |
242 |
socket. No errors will be reported (this mostly matches how the operating |
243 |
system treats outstanding data at socket close time). |
244 |
|
245 |
This will not work for partial TLS data that could not be encoded |
246 |
yet. This data will be lost. Calling the C<stoptls> method in time might |
247 |
help. |
248 |
|
249 |
=item peername => $string |
250 |
|
251 |
A string used to identify the remote site - usually the DNS hostname |
252 |
(I<not> IDN!) used to create the connection, rarely the IP address. |
253 |
|
254 |
Apart from being useful in error messages, this string is also used in TLS |
255 |
peername verification (see C<verify_peername> in L<AnyEvent::TLS>). This |
256 |
verification will be skipped when C<peername> is not specified or |
257 |
C<undef>. |
258 |
|
259 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
260 |
|
261 |
When this parameter is given, it enables TLS (SSL) mode, that means |
262 |
AnyEvent will start a TLS handshake as soon as the conenction has been |
263 |
established and will transparently encrypt/decrypt data afterwards. |
264 |
|
265 |
All TLS protocol errors will be signalled as C<EPROTO>, with an |
266 |
appropriate error message. |
267 |
|
268 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
269 |
automatically when you try to create a TLS handle): this module doesn't |
270 |
have a dependency on that module, so if your module requires it, you have |
271 |
to add the dependency yourself. |
272 |
|
273 |
Unlike TCP, TLS has a server and client side: for the TLS server side, use |
274 |
C<accept>, and for the TLS client side of a connection, use C<connect> |
275 |
mode. |
276 |
|
277 |
You can also provide your own TLS connection object, but you have |
278 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
279 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
280 |
AnyEvent::Handle. Also, this module will take ownership of this connection |
281 |
object. |
282 |
|
283 |
At some future point, AnyEvent::Handle might switch to another TLS |
284 |
implementation, then the option to use your own session object will go |
285 |
away. |
286 |
|
287 |
B<IMPORTANT:> since Net::SSLeay "objects" are really only integers, |
288 |
passing in the wrong integer will lead to certain crash. This most often |
289 |
happens when one uses a stylish C<< tls => 1 >> and is surprised about the |
290 |
segmentation fault. |
291 |
|
292 |
See the C<< ->starttls >> method for when need to start TLS negotiation later. |
293 |
|
294 |
=item tls_ctx => $anyevent_tls |
295 |
|
296 |
Use the given C<AnyEvent::TLS> object to create the new TLS connection |
297 |
(unless a connection object was specified directly). If this parameter is |
298 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
299 |
|
300 |
Instead of an object, you can also specify a hash reference with C<< key |
301 |
=> value >> pairs. Those will be passed to L<AnyEvent::TLS> to create a |
302 |
new TLS context object. |
303 |
|
304 |
=item on_starttls => $cb->($handle, $success[, $error_message]) |
305 |
|
306 |
This callback will be invoked when the TLS/SSL handshake has finished. If |
307 |
C<$success> is true, then the TLS handshake succeeded, otherwise it failed |
308 |
(C<on_stoptls> will not be called in this case). |
309 |
|
310 |
The session in C<< $handle->{tls} >> can still be examined in this |
311 |
callback, even when the handshake was not successful. |
312 |
|
313 |
TLS handshake failures will not cause C<on_error> to be invoked when this |
314 |
callback is in effect, instead, the error message will be passed to C<on_starttls>. |
315 |
|
316 |
Without this callback, handshake failures lead to C<on_error> being |
317 |
called, as normal. |
318 |
|
319 |
Note that you cannot call C<starttls> right again in this callback. If you |
320 |
need to do that, start an zero-second timer instead whose callback can |
321 |
then call C<< ->starttls >> again. |
322 |
|
323 |
=item on_stoptls => $cb->($handle) |
324 |
|
325 |
When a SSLv3/TLS shutdown/close notify/EOF is detected and this callback is |
326 |
set, then it will be invoked after freeing the TLS session. If it is not, |
327 |
then a TLS shutdown condition will be treated like a normal EOF condition |
328 |
on the handle. |
329 |
|
330 |
The session in C<< $handle->{tls} >> can still be examined in this |
331 |
callback. |
332 |
|
333 |
This callback will only be called on TLS shutdowns, not when the |
334 |
underlying handle signals EOF. |
335 |
|
336 |
=item json => JSON or JSON::XS object |
337 |
|
338 |
This is the json coder object used by the C<json> read and write types. |
339 |
|
340 |
If you don't supply it, then AnyEvent::Handle will create and use a |
341 |
suitable one (on demand), which will write and expect UTF-8 encoded JSON |
342 |
texts. |
343 |
|
344 |
Note that you are responsible to depend on the JSON module if you want to |
345 |
use this functionality, as AnyEvent does not have a dependency itself. |
346 |
|
347 |
=back |
348 |
|
349 |
=cut |
350 |
|
351 |
sub new { |
352 |
my $class = shift; |
353 |
my $self = bless { @_ }, $class; |
354 |
|
355 |
$self->{fh} or Carp::croak "mandatory argument fh is missing"; |
356 |
|
357 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
358 |
|
359 |
$self->{_activity} = AnyEvent->now; |
360 |
$self->_timeout; |
361 |
|
362 |
$self->no_delay (delete $self->{no_delay}) if exists $self->{no_delay}; |
363 |
|
364 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}) |
365 |
if $self->{tls}; |
366 |
|
367 |
$self->on_drain (delete $self->{on_drain}) if $self->{on_drain}; |
368 |
|
369 |
$self->start_read |
370 |
if $self->{on_read}; |
371 |
|
372 |
$self->{fh} && $self |
373 |
} |
374 |
|
375 |
#sub _shutdown { |
376 |
# my ($self) = @_; |
377 |
# |
378 |
# delete @$self{qw(_tw _rw _ww fh wbuf on_read _queue)}; |
379 |
# $self->{_eof} = 1; # tell starttls et. al to stop trying |
380 |
# |
381 |
# &_freetls; |
382 |
#} |
383 |
|
384 |
sub _error { |
385 |
my ($self, $errno, $fatal, $message) = @_; |
386 |
|
387 |
$! = $errno; |
388 |
$message ||= "$!"; |
389 |
|
390 |
if ($self->{on_error}) { |
391 |
$self->{on_error}($self, $fatal, $message); |
392 |
$self->destroy if $fatal; |
393 |
} elsif ($self->{fh}) { |
394 |
$self->destroy; |
395 |
Carp::croak "AnyEvent::Handle uncaught error: $message"; |
396 |
} |
397 |
} |
398 |
|
399 |
=item $fh = $handle->fh |
400 |
|
401 |
This method returns the file handle used to create the L<AnyEvent::Handle> object. |
402 |
|
403 |
=cut |
404 |
|
405 |
sub fh { $_[0]{fh} } |
406 |
|
407 |
=item $handle->on_error ($cb) |
408 |
|
409 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
410 |
|
411 |
=cut |
412 |
|
413 |
sub on_error { |
414 |
$_[0]{on_error} = $_[1]; |
415 |
} |
416 |
|
417 |
=item $handle->on_eof ($cb) |
418 |
|
419 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
420 |
|
421 |
=cut |
422 |
|
423 |
sub on_eof { |
424 |
$_[0]{on_eof} = $_[1]; |
425 |
} |
426 |
|
427 |
=item $handle->on_timeout ($cb) |
428 |
|
429 |
Replace the current C<on_timeout> callback, or disables the callback (but |
430 |
not the timeout) if C<$cb> = C<undef>. See the C<timeout> constructor |
431 |
argument and method. |
432 |
|
433 |
=cut |
434 |
|
435 |
sub on_timeout { |
436 |
$_[0]{on_timeout} = $_[1]; |
437 |
} |
438 |
|
439 |
=item $handle->autocork ($boolean) |
440 |
|
441 |
Enables or disables the current autocork behaviour (see C<autocork> |
442 |
constructor argument). Changes will only take effect on the next write. |
443 |
|
444 |
=cut |
445 |
|
446 |
sub autocork { |
447 |
$_[0]{autocork} = $_[1]; |
448 |
} |
449 |
|
450 |
=item $handle->no_delay ($boolean) |
451 |
|
452 |
Enables or disables the C<no_delay> setting (see constructor argument of |
453 |
the same name for details). |
454 |
|
455 |
=cut |
456 |
|
457 |
sub no_delay { |
458 |
$_[0]{no_delay} = $_[1]; |
459 |
|
460 |
eval { |
461 |
local $SIG{__DIE__}; |
462 |
setsockopt $_[0]{fh}, &Socket::IPPROTO_TCP, &Socket::TCP_NODELAY, int $_[1]; |
463 |
}; |
464 |
} |
465 |
|
466 |
=item $handle->on_starttls ($cb) |
467 |
|
468 |
Replace the current C<on_starttls> callback (see the C<on_starttls> constructor argument). |
469 |
|
470 |
=cut |
471 |
|
472 |
sub on_starttls { |
473 |
$_[0]{on_starttls} = $_[1]; |
474 |
} |
475 |
|
476 |
=item $handle->on_stoptls ($cb) |
477 |
|
478 |
Replace the current C<on_stoptls> callback (see the C<on_stoptls> constructor argument). |
479 |
|
480 |
=cut |
481 |
|
482 |
sub on_starttls { |
483 |
$_[0]{on_stoptls} = $_[1]; |
484 |
} |
485 |
|
486 |
############################################################################# |
487 |
|
488 |
=item $handle->timeout ($seconds) |
489 |
|
490 |
Configures (or disables) the inactivity timeout. |
491 |
|
492 |
=cut |
493 |
|
494 |
sub timeout { |
495 |
my ($self, $timeout) = @_; |
496 |
|
497 |
$self->{timeout} = $timeout; |
498 |
$self->_timeout; |
499 |
} |
500 |
|
501 |
# reset the timeout watcher, as neccessary |
502 |
# also check for time-outs |
503 |
sub _timeout { |
504 |
my ($self) = @_; |
505 |
|
506 |
if ($self->{timeout}) { |
507 |
my $NOW = AnyEvent->now; |
508 |
|
509 |
# when would the timeout trigger? |
510 |
my $after = $self->{_activity} + $self->{timeout} - $NOW; |
511 |
|
512 |
# now or in the past already? |
513 |
if ($after <= 0) { |
514 |
$self->{_activity} = $NOW; |
515 |
|
516 |
if ($self->{on_timeout}) { |
517 |
$self->{on_timeout}($self); |
518 |
} else { |
519 |
$self->_error (Errno::ETIMEDOUT); |
520 |
} |
521 |
|
522 |
# callback could have changed timeout value, optimise |
523 |
return unless $self->{timeout}; |
524 |
|
525 |
# calculate new after |
526 |
$after = $self->{timeout}; |
527 |
} |
528 |
|
529 |
Scalar::Util::weaken $self; |
530 |
return unless $self; # ->error could have destroyed $self |
531 |
|
532 |
$self->{_tw} ||= AnyEvent->timer (after => $after, cb => sub { |
533 |
delete $self->{_tw}; |
534 |
$self->_timeout; |
535 |
}); |
536 |
} else { |
537 |
delete $self->{_tw}; |
538 |
} |
539 |
} |
540 |
|
541 |
############################################################################# |
542 |
|
543 |
=back |
544 |
|
545 |
=head2 WRITE QUEUE |
546 |
|
547 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
548 |
for reading. |
549 |
|
550 |
The write queue is very simple: you can add data to its end, and |
551 |
AnyEvent::Handle will automatically try to get rid of it for you. |
552 |
|
553 |
When data could be written and the write buffer is shorter then the low |
554 |
water mark, the C<on_drain> callback will be invoked. |
555 |
|
556 |
=over 4 |
557 |
|
558 |
=item $handle->on_drain ($cb) |
559 |
|
560 |
Sets the C<on_drain> callback or clears it (see the description of |
561 |
C<on_drain> in the constructor). |
562 |
|
563 |
=cut |
564 |
|
565 |
sub on_drain { |
566 |
my ($self, $cb) = @_; |
567 |
|
568 |
$self->{on_drain} = $cb; |
569 |
|
570 |
$cb->($self) |
571 |
if $cb && $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}); |
572 |
} |
573 |
|
574 |
=item $handle->push_write ($data) |
575 |
|
576 |
Queues the given scalar to be written. You can push as much data as you |
577 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
578 |
buffers it independently of the kernel. |
579 |
|
580 |
=cut |
581 |
|
582 |
sub _drain_wbuf { |
583 |
my ($self) = @_; |
584 |
|
585 |
if (!$self->{_ww} && length $self->{wbuf}) { |
586 |
|
587 |
Scalar::Util::weaken $self; |
588 |
|
589 |
my $cb = sub { |
590 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
591 |
|
592 |
if (defined $len) { |
593 |
substr $self->{wbuf}, 0, $len, ""; |
594 |
|
595 |
$self->{_activity} = AnyEvent->now; |
596 |
|
597 |
$self->{on_drain}($self) |
598 |
if $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}) |
599 |
&& $self->{on_drain}; |
600 |
|
601 |
delete $self->{_ww} unless length $self->{wbuf}; |
602 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
603 |
$self->_error ($!, 1); |
604 |
} |
605 |
}; |
606 |
|
607 |
# try to write data immediately |
608 |
$cb->() unless $self->{autocork}; |
609 |
|
610 |
# if still data left in wbuf, we need to poll |
611 |
$self->{_ww} = AnyEvent->io (fh => $self->{fh}, poll => "w", cb => $cb) |
612 |
if length $self->{wbuf}; |
613 |
}; |
614 |
} |
615 |
|
616 |
our %WH; |
617 |
|
618 |
sub register_write_type($$) { |
619 |
$WH{$_[0]} = $_[1]; |
620 |
} |
621 |
|
622 |
sub push_write { |
623 |
my $self = shift; |
624 |
|
625 |
if (@_ > 1) { |
626 |
my $type = shift; |
627 |
|
628 |
@_ = ($WH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_write") |
629 |
->($self, @_); |
630 |
} |
631 |
|
632 |
if ($self->{tls}) { |
633 |
$self->{_tls_wbuf} .= $_[0]; |
634 |
|
635 |
&_dotls ($self); |
636 |
} else { |
637 |
$self->{wbuf} .= $_[0]; |
638 |
$self->_drain_wbuf; |
639 |
} |
640 |
} |
641 |
|
642 |
=item $handle->push_write (type => @args) |
643 |
|
644 |
Instead of formatting your data yourself, you can also let this module do |
645 |
the job by specifying a type and type-specific arguments. |
646 |
|
647 |
Predefined types are (if you have ideas for additional types, feel free to |
648 |
drop by and tell us): |
649 |
|
650 |
=over 4 |
651 |
|
652 |
=item netstring => $string |
653 |
|
654 |
Formats the given value as netstring |
655 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
656 |
|
657 |
=cut |
658 |
|
659 |
register_write_type netstring => sub { |
660 |
my ($self, $string) = @_; |
661 |
|
662 |
(length $string) . ":$string," |
663 |
}; |
664 |
|
665 |
=item packstring => $format, $data |
666 |
|
667 |
An octet string prefixed with an encoded length. The encoding C<$format> |
668 |
uses the same format as a Perl C<pack> format, but must specify a single |
669 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
670 |
optional C<!>, C<< < >> or C<< > >> modifier). |
671 |
|
672 |
=cut |
673 |
|
674 |
register_write_type packstring => sub { |
675 |
my ($self, $format, $string) = @_; |
676 |
|
677 |
pack "$format/a*", $string |
678 |
}; |
679 |
|
680 |
=item json => $array_or_hashref |
681 |
|
682 |
Encodes the given hash or array reference into a JSON object. Unless you |
683 |
provide your own JSON object, this means it will be encoded to JSON text |
684 |
in UTF-8. |
685 |
|
686 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
687 |
one end of a handle and read them at the other end without using any |
688 |
additional framing. |
689 |
|
690 |
The generated JSON text is guaranteed not to contain any newlines: While |
691 |
this module doesn't need delimiters after or between JSON texts to be |
692 |
able to read them, many other languages depend on that. |
693 |
|
694 |
A simple RPC protocol that interoperates easily with others is to send |
695 |
JSON arrays (or objects, although arrays are usually the better choice as |
696 |
they mimic how function argument passing works) and a newline after each |
697 |
JSON text: |
698 |
|
699 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
700 |
$handle->push_write ("\012"); |
701 |
|
702 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
703 |
rely on the fact that the newline will be skipped as leading whitespace: |
704 |
|
705 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
706 |
|
707 |
Other languages could read single lines terminated by a newline and pass |
708 |
this line into their JSON decoder of choice. |
709 |
|
710 |
=cut |
711 |
|
712 |
register_write_type json => sub { |
713 |
my ($self, $ref) = @_; |
714 |
|
715 |
require JSON; |
716 |
|
717 |
$self->{json} ? $self->{json}->encode ($ref) |
718 |
: JSON::encode_json ($ref) |
719 |
}; |
720 |
|
721 |
=item storable => $reference |
722 |
|
723 |
Freezes the given reference using L<Storable> and writes it to the |
724 |
handle. Uses the C<nfreeze> format. |
725 |
|
726 |
=cut |
727 |
|
728 |
register_write_type storable => sub { |
729 |
my ($self, $ref) = @_; |
730 |
|
731 |
require Storable; |
732 |
|
733 |
pack "w/a*", Storable::nfreeze ($ref) |
734 |
}; |
735 |
|
736 |
=back |
737 |
|
738 |
=item $handle->push_shutdown |
739 |
|
740 |
Sometimes you know you want to close the socket after writing your data |
741 |
before it was actually written. One way to do that is to replace your |
742 |
C<on_drain> handler by a callback that shuts down the socket (and set |
743 |
C<low_water_mark> to C<0>). This method is a shorthand for just that, and |
744 |
replaces the C<on_drain> callback with: |
745 |
|
746 |
sub { shutdown $_[0]{fh}, 1 } # for push_shutdown |
747 |
|
748 |
This simply shuts down the write side and signals an EOF condition to the |
749 |
the peer. |
750 |
|
751 |
You can rely on the normal read queue and C<on_eof> handling |
752 |
afterwards. This is the cleanest way to close a connection. |
753 |
|
754 |
=cut |
755 |
|
756 |
sub push_shutdown { |
757 |
my ($self) = @_; |
758 |
|
759 |
delete $self->{low_water_mark}; |
760 |
$self->on_drain (sub { shutdown $_[0]{fh}, 1 }); |
761 |
} |
762 |
|
763 |
=item AnyEvent::Handle::register_write_type type => $coderef->($handle, @args) |
764 |
|
765 |
This function (not method) lets you add your own types to C<push_write>. |
766 |
Whenever the given C<type> is used, C<push_write> will invoke the code |
767 |
reference with the handle object and the remaining arguments. |
768 |
|
769 |
The code reference is supposed to return a single octet string that will |
770 |
be appended to the write buffer. |
771 |
|
772 |
Note that this is a function, and all types registered this way will be |
773 |
global, so try to use unique names. |
774 |
|
775 |
=cut |
776 |
|
777 |
############################################################################# |
778 |
|
779 |
=back |
780 |
|
781 |
=head2 READ QUEUE |
782 |
|
783 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
784 |
for reading. |
785 |
|
786 |
The read queue is more complex than the write queue. It can be used in two |
787 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
788 |
a queue. |
789 |
|
790 |
In the simple case, you just install an C<on_read> callback and whenever |
791 |
new data arrives, it will be called. You can then remove some data (if |
792 |
enough is there) from the read buffer (C<< $handle->rbuf >>). Or you cna |
793 |
leave the data there if you want to accumulate more (e.g. when only a |
794 |
partial message has been received so far). |
795 |
|
796 |
In the more complex case, you want to queue multiple callbacks. In this |
797 |
case, AnyEvent::Handle will call the first queued callback each time new |
798 |
data arrives (also the first time it is queued) and removes it when it has |
799 |
done its job (see C<push_read>, below). |
800 |
|
801 |
This way you can, for example, push three line-reads, followed by reading |
802 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
803 |
|
804 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
805 |
the specified number of bytes which give an XML datagram. |
806 |
|
807 |
# in the default state, expect some header bytes |
808 |
$handle->on_read (sub { |
809 |
# some data is here, now queue the length-header-read (4 octets) |
810 |
shift->unshift_read (chunk => 4, sub { |
811 |
# header arrived, decode |
812 |
my $len = unpack "N", $_[1]; |
813 |
|
814 |
# now read the payload |
815 |
shift->unshift_read (chunk => $len, sub { |
816 |
my $xml = $_[1]; |
817 |
# handle xml |
818 |
}); |
819 |
}); |
820 |
}); |
821 |
|
822 |
Example 2: Implement a client for a protocol that replies either with "OK" |
823 |
and another line or "ERROR" for the first request that is sent, and 64 |
824 |
bytes for the second request. Due to the availability of a queue, we can |
825 |
just pipeline sending both requests and manipulate the queue as necessary |
826 |
in the callbacks. |
827 |
|
828 |
When the first callback is called and sees an "OK" response, it will |
829 |
C<unshift> another line-read. This line-read will be queued I<before> the |
830 |
64-byte chunk callback. |
831 |
|
832 |
# request one, returns either "OK + extra line" or "ERROR" |
833 |
$handle->push_write ("request 1\015\012"); |
834 |
|
835 |
# we expect "ERROR" or "OK" as response, so push a line read |
836 |
$handle->push_read (line => sub { |
837 |
# if we got an "OK", we have to _prepend_ another line, |
838 |
# so it will be read before the second request reads its 64 bytes |
839 |
# which are already in the queue when this callback is called |
840 |
# we don't do this in case we got an error |
841 |
if ($_[1] eq "OK") { |
842 |
$_[0]->unshift_read (line => sub { |
843 |
my $response = $_[1]; |
844 |
... |
845 |
}); |
846 |
} |
847 |
}); |
848 |
|
849 |
# request two, simply returns 64 octets |
850 |
$handle->push_write ("request 2\015\012"); |
851 |
|
852 |
# simply read 64 bytes, always |
853 |
$handle->push_read (chunk => 64, sub { |
854 |
my $response = $_[1]; |
855 |
... |
856 |
}); |
857 |
|
858 |
=over 4 |
859 |
|
860 |
=cut |
861 |
|
862 |
sub _drain_rbuf { |
863 |
my ($self) = @_; |
864 |
|
865 |
local $self->{_in_drain} = 1; |
866 |
|
867 |
if ( |
868 |
defined $self->{rbuf_max} |
869 |
&& $self->{rbuf_max} < length $self->{rbuf} |
870 |
) { |
871 |
$self->_error (Errno::ENOSPC, 1), return; |
872 |
} |
873 |
|
874 |
while () { |
875 |
# we need to use a separate tls read buffer, as we must not receive data while |
876 |
# we are draining the buffer, and this can only happen with TLS. |
877 |
$self->{rbuf} .= delete $self->{_tls_rbuf} if exists $self->{_tls_rbuf}; |
878 |
|
879 |
my $len = length $self->{rbuf}; |
880 |
|
881 |
if (my $cb = shift @{ $self->{_queue} }) { |
882 |
unless ($cb->($self)) { |
883 |
if ($self->{_eof}) { |
884 |
# no progress can be made (not enough data and no data forthcoming) |
885 |
$self->_error (Errno::EPIPE, 1), return; |
886 |
} |
887 |
|
888 |
unshift @{ $self->{_queue} }, $cb; |
889 |
last; |
890 |
} |
891 |
} elsif ($self->{on_read}) { |
892 |
last unless $len; |
893 |
|
894 |
$self->{on_read}($self); |
895 |
|
896 |
if ( |
897 |
$len == length $self->{rbuf} # if no data has been consumed |
898 |
&& !@{ $self->{_queue} } # and the queue is still empty |
899 |
&& $self->{on_read} # but we still have on_read |
900 |
) { |
901 |
# no further data will arrive |
902 |
# so no progress can be made |
903 |
$self->_error (Errno::EPIPE, 1), return |
904 |
if $self->{_eof}; |
905 |
|
906 |
last; # more data might arrive |
907 |
} |
908 |
} else { |
909 |
# read side becomes idle |
910 |
delete $self->{_rw} unless $self->{tls}; |
911 |
last; |
912 |
} |
913 |
} |
914 |
|
915 |
if ($self->{_eof}) { |
916 |
if ($self->{on_eof}) { |
917 |
$self->{on_eof}($self) |
918 |
} else { |
919 |
$self->_error (0, 1, "Unexpected end-of-file"); |
920 |
} |
921 |
} |
922 |
|
923 |
# may need to restart read watcher |
924 |
unless ($self->{_rw}) { |
925 |
$self->start_read |
926 |
if $self->{on_read} || @{ $self->{_queue} }; |
927 |
} |
928 |
} |
929 |
|
930 |
=item $handle->on_read ($cb) |
931 |
|
932 |
This replaces the currently set C<on_read> callback, or clears it (when |
933 |
the new callback is C<undef>). See the description of C<on_read> in the |
934 |
constructor. |
935 |
|
936 |
=cut |
937 |
|
938 |
sub on_read { |
939 |
my ($self, $cb) = @_; |
940 |
|
941 |
$self->{on_read} = $cb; |
942 |
$self->_drain_rbuf if $cb && !$self->{_in_drain}; |
943 |
} |
944 |
|
945 |
=item $handle->rbuf |
946 |
|
947 |
Returns the read buffer (as a modifiable lvalue). |
948 |
|
949 |
You can access the read buffer directly as the C<< ->{rbuf} >> |
950 |
member, if you want. However, the only operation allowed on the |
951 |
read buffer (apart from looking at it) is removing data from its |
952 |
beginning. Otherwise modifying or appending to it is not allowed and will |
953 |
lead to hard-to-track-down bugs. |
954 |
|
955 |
NOTE: The read buffer should only be used or modified if the C<on_read>, |
956 |
C<push_read> or C<unshift_read> methods are used. The other read methods |
957 |
automatically manage the read buffer. |
958 |
|
959 |
=cut |
960 |
|
961 |
sub rbuf : lvalue { |
962 |
$_[0]{rbuf} |
963 |
} |
964 |
|
965 |
=item $handle->push_read ($cb) |
966 |
|
967 |
=item $handle->unshift_read ($cb) |
968 |
|
969 |
Append the given callback to the end of the queue (C<push_read>) or |
970 |
prepend it (C<unshift_read>). |
971 |
|
972 |
The callback is called each time some additional read data arrives. |
973 |
|
974 |
It must check whether enough data is in the read buffer already. |
975 |
|
976 |
If not enough data is available, it must return the empty list or a false |
977 |
value, in which case it will be called repeatedly until enough data is |
978 |
available (or an error condition is detected). |
979 |
|
980 |
If enough data was available, then the callback must remove all data it is |
981 |
interested in (which can be none at all) and return a true value. After returning |
982 |
true, it will be removed from the queue. |
983 |
|
984 |
=cut |
985 |
|
986 |
our %RH; |
987 |
|
988 |
sub register_read_type($$) { |
989 |
$RH{$_[0]} = $_[1]; |
990 |
} |
991 |
|
992 |
sub push_read { |
993 |
my $self = shift; |
994 |
my $cb = pop; |
995 |
|
996 |
if (@_) { |
997 |
my $type = shift; |
998 |
|
999 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_read") |
1000 |
->($self, $cb, @_); |
1001 |
} |
1002 |
|
1003 |
push @{ $self->{_queue} }, $cb; |
1004 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1005 |
} |
1006 |
|
1007 |
sub unshift_read { |
1008 |
my $self = shift; |
1009 |
my $cb = pop; |
1010 |
|
1011 |
if (@_) { |
1012 |
my $type = shift; |
1013 |
|
1014 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::unshift_read") |
1015 |
->($self, $cb, @_); |
1016 |
} |
1017 |
|
1018 |
|
1019 |
unshift @{ $self->{_queue} }, $cb; |
1020 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1021 |
} |
1022 |
|
1023 |
=item $handle->push_read (type => @args, $cb) |
1024 |
|
1025 |
=item $handle->unshift_read (type => @args, $cb) |
1026 |
|
1027 |
Instead of providing a callback that parses the data itself you can chose |
1028 |
between a number of predefined parsing formats, for chunks of data, lines |
1029 |
etc. |
1030 |
|
1031 |
Predefined types are (if you have ideas for additional types, feel free to |
1032 |
drop by and tell us): |
1033 |
|
1034 |
=over 4 |
1035 |
|
1036 |
=item chunk => $octets, $cb->($handle, $data) |
1037 |
|
1038 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
1039 |
data read to the callback. The callback will never be called with less |
1040 |
data. |
1041 |
|
1042 |
Example: read 2 bytes. |
1043 |
|
1044 |
$handle->push_read (chunk => 2, sub { |
1045 |
warn "yay ", unpack "H*", $_[1]; |
1046 |
}); |
1047 |
|
1048 |
=cut |
1049 |
|
1050 |
register_read_type chunk => sub { |
1051 |
my ($self, $cb, $len) = @_; |
1052 |
|
1053 |
sub { |
1054 |
$len <= length $_[0]{rbuf} or return; |
1055 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
1056 |
1 |
1057 |
} |
1058 |
}; |
1059 |
|
1060 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
1061 |
|
1062 |
The callback will be called only once a full line (including the end of |
1063 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
1064 |
marker) will be passed to the callback as second argument (C<$line>), and |
1065 |
the end of line marker as the third argument (C<$eol>). |
1066 |
|
1067 |
The end of line marker, C<$eol>, can be either a string, in which case it |
1068 |
will be interpreted as a fixed record end marker, or it can be a regex |
1069 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
1070 |
regular expression. |
1071 |
|
1072 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
1073 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
1074 |
protocols). |
1075 |
|
1076 |
Partial lines at the end of the stream will never be returned, as they are |
1077 |
not marked by the end of line marker. |
1078 |
|
1079 |
=cut |
1080 |
|
1081 |
register_read_type line => sub { |
1082 |
my ($self, $cb, $eol) = @_; |
1083 |
|
1084 |
if (@_ < 3) { |
1085 |
# this is more than twice as fast as the generic code below |
1086 |
sub { |
1087 |
$_[0]{rbuf} =~ s/^([^\015\012]*)(\015?\012)// or return; |
1088 |
|
1089 |
$cb->($_[0], $1, $2); |
1090 |
1 |
1091 |
} |
1092 |
} else { |
1093 |
$eol = quotemeta $eol unless ref $eol; |
1094 |
$eol = qr|^(.*?)($eol)|s; |
1095 |
|
1096 |
sub { |
1097 |
$_[0]{rbuf} =~ s/$eol// or return; |
1098 |
|
1099 |
$cb->($_[0], $1, $2); |
1100 |
1 |
1101 |
} |
1102 |
} |
1103 |
}; |
1104 |
|
1105 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
1106 |
|
1107 |
Makes a regex match against the regex object C<$accept> and returns |
1108 |
everything up to and including the match. |
1109 |
|
1110 |
Example: read a single line terminated by '\n'. |
1111 |
|
1112 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
1113 |
|
1114 |
If C<$reject> is given and not undef, then it determines when the data is |
1115 |
to be rejected: it is matched against the data when the C<$accept> regex |
1116 |
does not match and generates an C<EBADMSG> error when it matches. This is |
1117 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
1118 |
receive buffer overflow). |
1119 |
|
1120 |
Example: expect a single decimal number followed by whitespace, reject |
1121 |
anything else (not the use of an anchor). |
1122 |
|
1123 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
1124 |
|
1125 |
If C<$skip> is given and not C<undef>, then it will be matched against |
1126 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
1127 |
and everything preceding and including the match will be accepted |
1128 |
unconditionally. This is useful to skip large amounts of data that you |
1129 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
1130 |
have to start matching from the beginning. This is purely an optimisation |
1131 |
and is usually worth only when you expect more than a few kilobytes. |
1132 |
|
1133 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
1134 |
expect the header to be very large (it isn't in practise, but...), we use |
1135 |
a skip regex to skip initial portions. The skip regex is tricky in that |
1136 |
it only accepts something not ending in either \015 or \012, as these are |
1137 |
required for the accept regex. |
1138 |
|
1139 |
$handle->push_read (regex => |
1140 |
qr<\015\012\015\012>, |
1141 |
undef, # no reject |
1142 |
qr<^.*[^\015\012]>, |
1143 |
sub { ... }); |
1144 |
|
1145 |
=cut |
1146 |
|
1147 |
register_read_type regex => sub { |
1148 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
1149 |
|
1150 |
my $data; |
1151 |
my $rbuf = \$self->{rbuf}; |
1152 |
|
1153 |
sub { |
1154 |
# accept |
1155 |
if ($$rbuf =~ $accept) { |
1156 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1157 |
$cb->($self, $data); |
1158 |
return 1; |
1159 |
} |
1160 |
|
1161 |
# reject |
1162 |
if ($reject && $$rbuf =~ $reject) { |
1163 |
$self->_error (Errno::EBADMSG); |
1164 |
} |
1165 |
|
1166 |
# skip |
1167 |
if ($skip && $$rbuf =~ $skip) { |
1168 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1169 |
} |
1170 |
|
1171 |
() |
1172 |
} |
1173 |
}; |
1174 |
|
1175 |
=item netstring => $cb->($handle, $string) |
1176 |
|
1177 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
1178 |
|
1179 |
Throws an error with C<$!> set to EBADMSG on format violations. |
1180 |
|
1181 |
=cut |
1182 |
|
1183 |
register_read_type netstring => sub { |
1184 |
my ($self, $cb) = @_; |
1185 |
|
1186 |
sub { |
1187 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
1188 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
1189 |
$self->_error (Errno::EBADMSG); |
1190 |
} |
1191 |
return; |
1192 |
} |
1193 |
|
1194 |
my $len = $1; |
1195 |
|
1196 |
$self->unshift_read (chunk => $len, sub { |
1197 |
my $string = $_[1]; |
1198 |
$_[0]->unshift_read (chunk => 1, sub { |
1199 |
if ($_[1] eq ",") { |
1200 |
$cb->($_[0], $string); |
1201 |
} else { |
1202 |
$self->_error (Errno::EBADMSG); |
1203 |
} |
1204 |
}); |
1205 |
}); |
1206 |
|
1207 |
1 |
1208 |
} |
1209 |
}; |
1210 |
|
1211 |
=item packstring => $format, $cb->($handle, $string) |
1212 |
|
1213 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1214 |
uses the same format as a Perl C<pack> format, but must specify a single |
1215 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1216 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1217 |
|
1218 |
For example, DNS over TCP uses a prefix of C<n> (2 octet network order), |
1219 |
EPP uses a prefix of C<N> (4 octtes). |
1220 |
|
1221 |
Example: read a block of data prefixed by its length in BER-encoded |
1222 |
format (very efficient). |
1223 |
|
1224 |
$handle->push_read (packstring => "w", sub { |
1225 |
my ($handle, $data) = @_; |
1226 |
}); |
1227 |
|
1228 |
=cut |
1229 |
|
1230 |
register_read_type packstring => sub { |
1231 |
my ($self, $cb, $format) = @_; |
1232 |
|
1233 |
sub { |
1234 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1235 |
defined (my $len = eval { unpack $format, $_[0]{rbuf} }) |
1236 |
or return; |
1237 |
|
1238 |
$format = length pack $format, $len; |
1239 |
|
1240 |
# bypass unshift if we already have the remaining chunk |
1241 |
if ($format + $len <= length $_[0]{rbuf}) { |
1242 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1243 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1244 |
$cb->($_[0], $data); |
1245 |
} else { |
1246 |
# remove prefix |
1247 |
substr $_[0]{rbuf}, 0, $format, ""; |
1248 |
|
1249 |
# read remaining chunk |
1250 |
$_[0]->unshift_read (chunk => $len, $cb); |
1251 |
} |
1252 |
|
1253 |
1 |
1254 |
} |
1255 |
}; |
1256 |
|
1257 |
=item json => $cb->($handle, $hash_or_arrayref) |
1258 |
|
1259 |
Reads a JSON object or array, decodes it and passes it to the |
1260 |
callback. When a parse error occurs, an C<EBADMSG> error will be raised. |
1261 |
|
1262 |
If a C<json> object was passed to the constructor, then that will be used |
1263 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1264 |
|
1265 |
This read type uses the incremental parser available with JSON version |
1266 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1267 |
dependency on your own: this module will load the JSON module, but |
1268 |
AnyEvent does not depend on it itself. |
1269 |
|
1270 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1271 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1272 |
the C<json> write type description, above, for an actual example. |
1273 |
|
1274 |
=cut |
1275 |
|
1276 |
register_read_type json => sub { |
1277 |
my ($self, $cb) = @_; |
1278 |
|
1279 |
my $json = $self->{json} ||= |
1280 |
eval { require JSON::XS; JSON::XS->new->utf8 } |
1281 |
|| do { require JSON; JSON->new->utf8 }; |
1282 |
|
1283 |
my $data; |
1284 |
my $rbuf = \$self->{rbuf}; |
1285 |
|
1286 |
sub { |
1287 |
my $ref = eval { $json->incr_parse ($self->{rbuf}) }; |
1288 |
|
1289 |
if ($ref) { |
1290 |
$self->{rbuf} = $json->incr_text; |
1291 |
$json->incr_text = ""; |
1292 |
$cb->($self, $ref); |
1293 |
|
1294 |
1 |
1295 |
} elsif ($@) { |
1296 |
# error case |
1297 |
$json->incr_skip; |
1298 |
|
1299 |
$self->{rbuf} = $json->incr_text; |
1300 |
$json->incr_text = ""; |
1301 |
|
1302 |
$self->_error (Errno::EBADMSG); |
1303 |
|
1304 |
() |
1305 |
} else { |
1306 |
$self->{rbuf} = ""; |
1307 |
|
1308 |
() |
1309 |
} |
1310 |
} |
1311 |
}; |
1312 |
|
1313 |
=item storable => $cb->($handle, $ref) |
1314 |
|
1315 |
Deserialises a L<Storable> frozen representation as written by the |
1316 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1317 |
data). |
1318 |
|
1319 |
Raises C<EBADMSG> error if the data could not be decoded. |
1320 |
|
1321 |
=cut |
1322 |
|
1323 |
register_read_type storable => sub { |
1324 |
my ($self, $cb) = @_; |
1325 |
|
1326 |
require Storable; |
1327 |
|
1328 |
sub { |
1329 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1330 |
defined (my $len = eval { unpack "w", $_[0]{rbuf} }) |
1331 |
or return; |
1332 |
|
1333 |
my $format = length pack "w", $len; |
1334 |
|
1335 |
# bypass unshift if we already have the remaining chunk |
1336 |
if ($format + $len <= length $_[0]{rbuf}) { |
1337 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1338 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1339 |
$cb->($_[0], Storable::thaw ($data)); |
1340 |
} else { |
1341 |
# remove prefix |
1342 |
substr $_[0]{rbuf}, 0, $format, ""; |
1343 |
|
1344 |
# read remaining chunk |
1345 |
$_[0]->unshift_read (chunk => $len, sub { |
1346 |
if (my $ref = eval { Storable::thaw ($_[1]) }) { |
1347 |
$cb->($_[0], $ref); |
1348 |
} else { |
1349 |
$self->_error (Errno::EBADMSG); |
1350 |
} |
1351 |
}); |
1352 |
} |
1353 |
|
1354 |
1 |
1355 |
} |
1356 |
}; |
1357 |
|
1358 |
=back |
1359 |
|
1360 |
=item AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args) |
1361 |
|
1362 |
This function (not method) lets you add your own types to C<push_read>. |
1363 |
|
1364 |
Whenever the given C<type> is used, C<push_read> will invoke the code |
1365 |
reference with the handle object, the callback and the remaining |
1366 |
arguments. |
1367 |
|
1368 |
The code reference is supposed to return a callback (usually a closure) |
1369 |
that works as a plain read callback (see C<< ->push_read ($cb) >>). |
1370 |
|
1371 |
It should invoke the passed callback when it is done reading (remember to |
1372 |
pass C<$handle> as first argument as all other callbacks do that). |
1373 |
|
1374 |
Note that this is a function, and all types registered this way will be |
1375 |
global, so try to use unique names. |
1376 |
|
1377 |
For examples, see the source of this module (F<perldoc -m AnyEvent::Handle>, |
1378 |
search for C<register_read_type>)). |
1379 |
|
1380 |
=item $handle->stop_read |
1381 |
|
1382 |
=item $handle->start_read |
1383 |
|
1384 |
In rare cases you actually do not want to read anything from the |
1385 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1386 |
any queued callbacks will be executed then. To start reading again, call |
1387 |
C<start_read>. |
1388 |
|
1389 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1390 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1391 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1392 |
there are any read requests in the queue. |
1393 |
|
1394 |
These methods will have no effect when in TLS mode (as TLS doesn't support |
1395 |
half-duplex connections). |
1396 |
|
1397 |
=cut |
1398 |
|
1399 |
sub stop_read { |
1400 |
my ($self) = @_; |
1401 |
|
1402 |
delete $self->{_rw} unless $self->{tls}; |
1403 |
} |
1404 |
|
1405 |
sub start_read { |
1406 |
my ($self) = @_; |
1407 |
|
1408 |
unless ($self->{_rw} || $self->{_eof}) { |
1409 |
Scalar::Util::weaken $self; |
1410 |
|
1411 |
$self->{_rw} = AnyEvent->io (fh => $self->{fh}, poll => "r", cb => sub { |
1412 |
my $rbuf = \($self->{tls} ? my $buf : $self->{rbuf}); |
1413 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size} || 8192, length $$rbuf; |
1414 |
|
1415 |
if ($len > 0) { |
1416 |
$self->{_activity} = AnyEvent->now; |
1417 |
|
1418 |
if ($self->{tls}) { |
1419 |
Net::SSLeay::BIO_write ($self->{_rbio}, $$rbuf); |
1420 |
|
1421 |
&_dotls ($self); |
1422 |
} else { |
1423 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1424 |
} |
1425 |
|
1426 |
} elsif (defined $len) { |
1427 |
delete $self->{_rw}; |
1428 |
$self->{_eof} = 1; |
1429 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1430 |
|
1431 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1432 |
return $self->_error ($!, 1); |
1433 |
} |
1434 |
}); |
1435 |
} |
1436 |
} |
1437 |
|
1438 |
our $ERROR_SYSCALL; |
1439 |
our $ERROR_WANT_READ; |
1440 |
|
1441 |
sub _tls_error { |
1442 |
my ($self, $err) = @_; |
1443 |
|
1444 |
return $self->_error ($!, 1) |
1445 |
if $err == Net::SSLeay::ERROR_SYSCALL (); |
1446 |
|
1447 |
my $err =Net::SSLeay::ERR_error_string (Net::SSLeay::ERR_get_error ()); |
1448 |
|
1449 |
# reduce error string to look less scary |
1450 |
$err =~ s/^error:[0-9a-fA-F]{8}:[^:]+:([^:]+):/\L$1: /; |
1451 |
|
1452 |
if ($self->{_on_starttls}) { |
1453 |
(delete $self->{_on_starttls})->($self, undef, $err); |
1454 |
&_freetls; |
1455 |
} else { |
1456 |
&_freetls; |
1457 |
$self->_error (Errno::EPROTO, 1, $err); |
1458 |
} |
1459 |
} |
1460 |
|
1461 |
# poll the write BIO and send the data if applicable |
1462 |
# also decode read data if possible |
1463 |
# this is basiclaly our TLS state machine |
1464 |
# more efficient implementations are possible with openssl, |
1465 |
# but not with the buggy and incomplete Net::SSLeay. |
1466 |
sub _dotls { |
1467 |
my ($self) = @_; |
1468 |
|
1469 |
my $tmp; |
1470 |
|
1471 |
if (length $self->{_tls_wbuf}) { |
1472 |
while (($tmp = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1473 |
substr $self->{_tls_wbuf}, 0, $tmp, ""; |
1474 |
} |
1475 |
|
1476 |
$tmp = Net::SSLeay::get_error ($self->{tls}, $tmp); |
1477 |
return $self->_tls_error ($tmp) |
1478 |
if $tmp != $ERROR_WANT_READ |
1479 |
&& ($tmp != $ERROR_SYSCALL || $!); |
1480 |
} |
1481 |
|
1482 |
while (defined ($tmp = Net::SSLeay::read ($self->{tls}))) { |
1483 |
unless (length $tmp) { |
1484 |
$self->{_on_starttls} |
1485 |
and (delete $self->{_on_starttls})->($self, undef, "EOF during handshake"); # ??? |
1486 |
&_freetls; |
1487 |
|
1488 |
if ($self->{on_stoptls}) { |
1489 |
$self->{on_stoptls}($self); |
1490 |
return; |
1491 |
} else { |
1492 |
# let's treat SSL-eof as we treat normal EOF |
1493 |
delete $self->{_rw}; |
1494 |
$self->{_eof} = 1; |
1495 |
} |
1496 |
} |
1497 |
|
1498 |
$self->{_tls_rbuf} .= $tmp; |
1499 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1500 |
$self->{tls} or return; # tls session might have gone away in callback |
1501 |
} |
1502 |
|
1503 |
$tmp = Net::SSLeay::get_error ($self->{tls}, -1); |
1504 |
return $self->_tls_error ($tmp) |
1505 |
if $tmp != $ERROR_WANT_READ |
1506 |
&& ($tmp != $ERROR_SYSCALL || $!); |
1507 |
|
1508 |
while (length ($tmp = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1509 |
$self->{wbuf} .= $tmp; |
1510 |
$self->_drain_wbuf; |
1511 |
} |
1512 |
|
1513 |
$self->{_on_starttls} |
1514 |
and Net::SSLeay::state ($self->{tls}) == Net::SSLeay::ST_OK () |
1515 |
and (delete $self->{_on_starttls})->($self, 1, "TLS/SSL connection established"); |
1516 |
} |
1517 |
|
1518 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1519 |
|
1520 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1521 |
object is created, you can also do that at a later time by calling |
1522 |
C<starttls>. |
1523 |
|
1524 |
Starting TLS is currently an asynchronous operation - when you push some |
1525 |
write data and then call C<< ->starttls >> then TLS negotiation will start |
1526 |
immediately, after which the queued write data is then sent. |
1527 |
|
1528 |
The first argument is the same as the C<tls> constructor argument (either |
1529 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1530 |
|
1531 |
The second argument is the optional C<AnyEvent::TLS> object that is used |
1532 |
when AnyEvent::Handle has to create its own TLS connection object, or |
1533 |
a hash reference with C<< key => value >> pairs that will be used to |
1534 |
construct a new context. |
1535 |
|
1536 |
The TLS connection object will end up in C<< $handle->{tls} >>, the TLS |
1537 |
context in C<< $handle->{tls_ctx} >> after this call and can be used or |
1538 |
changed to your liking. Note that the handshake might have already started |
1539 |
when this function returns. |
1540 |
|
1541 |
If it an error to start a TLS handshake more than once per |
1542 |
AnyEvent::Handle object (this is due to bugs in OpenSSL). |
1543 |
|
1544 |
=cut |
1545 |
|
1546 |
our %TLS_CACHE; #TODO not yet documented, should we? |
1547 |
|
1548 |
sub starttls { |
1549 |
my ($self, $ssl, $ctx) = @_; |
1550 |
|
1551 |
require Net::SSLeay; |
1552 |
|
1553 |
Carp::croak "it is an error to call starttls more than once on an AnyEvent::Handle object" |
1554 |
if $self->{tls}; |
1555 |
|
1556 |
$ERROR_SYSCALL = Net::SSLeay::ERROR_SYSCALL (); |
1557 |
$ERROR_WANT_READ = Net::SSLeay::ERROR_WANT_READ (); |
1558 |
|
1559 |
$ctx ||= $self->{tls_ctx}; |
1560 |
|
1561 |
local $Carp::CarpLevel = 1; # skip ourselves when creating a new context or session |
1562 |
|
1563 |
if ("HASH" eq ref $ctx) { |
1564 |
require AnyEvent::TLS; |
1565 |
|
1566 |
if ($ctx->{cache}) { |
1567 |
my $key = $ctx+0; |
1568 |
$ctx = $TLS_CACHE{$key} ||= new AnyEvent::TLS %$ctx; |
1569 |
} else { |
1570 |
$ctx = new AnyEvent::TLS %$ctx; |
1571 |
} |
1572 |
} |
1573 |
|
1574 |
$self->{tls_ctx} = $ctx || TLS_CTX (); |
1575 |
$self->{tls} = $ssl = $self->{tls_ctx}->_get_session ($ssl, $self, $self->{peername}); |
1576 |
|
1577 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1578 |
# but the openssl maintainers basically said: "trust us, it just works". |
1579 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1580 |
# and mismaintained ssleay-module doesn't even offer them). |
1581 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1582 |
# |
1583 |
# in short: this is a mess. |
1584 |
# |
1585 |
# note that we do not try to keep the length constant between writes as we are required to do. |
1586 |
# we assume that most (but not all) of this insanity only applies to non-blocking cases, |
1587 |
# and we drive openssl fully in blocking mode here. Or maybe we don't - openssl seems to |
1588 |
# have identity issues in that area. |
1589 |
# Net::SSLeay::CTX_set_mode ($ssl, |
1590 |
# (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1591 |
# | (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1592 |
Net::SSLeay::CTX_set_mode ($ssl, 1|2); |
1593 |
|
1594 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1595 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1596 |
|
1597 |
Net::SSLeay::set_bio ($ssl, $self->{_rbio}, $self->{_wbio}); |
1598 |
|
1599 |
$self->{_on_starttls} = sub { $_[0]{on_starttls}(@_) } |
1600 |
if $self->{on_starttls}; |
1601 |
|
1602 |
&_dotls; # need to trigger the initial handshake |
1603 |
$self->start_read; # make sure we actually do read |
1604 |
} |
1605 |
|
1606 |
=item $handle->stoptls |
1607 |
|
1608 |
Shuts down the SSL connection - this makes a proper EOF handshake by |
1609 |
sending a close notify to the other side, but since OpenSSL doesn't |
1610 |
support non-blocking shut downs, it is not possible to re-use the stream |
1611 |
afterwards. |
1612 |
|
1613 |
=cut |
1614 |
|
1615 |
sub stoptls { |
1616 |
my ($self) = @_; |
1617 |
|
1618 |
if ($self->{tls}) { |
1619 |
Net::SSLeay::shutdown ($self->{tls}); |
1620 |
|
1621 |
&_dotls; |
1622 |
|
1623 |
# # we don't give a shit. no, we do, but we can't. no...#d# |
1624 |
# # we, we... have to use openssl :/#d# |
1625 |
# &_freetls;#d# |
1626 |
} |
1627 |
} |
1628 |
|
1629 |
sub _freetls { |
1630 |
my ($self) = @_; |
1631 |
|
1632 |
return unless $self->{tls}; |
1633 |
|
1634 |
$self->{tls_ctx}->_put_session (delete $self->{tls}); |
1635 |
|
1636 |
delete @$self{qw(_rbio _wbio _tls_wbuf _on_starttls)}; |
1637 |
} |
1638 |
|
1639 |
sub DESTROY { |
1640 |
my ($self) = @_; |
1641 |
|
1642 |
&_freetls; |
1643 |
|
1644 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
1645 |
|
1646 |
if ($linger && length $self->{wbuf} && $self->{fh}) { |
1647 |
my $fh = delete $self->{fh}; |
1648 |
my $wbuf = delete $self->{wbuf}; |
1649 |
|
1650 |
my @linger; |
1651 |
|
1652 |
push @linger, AnyEvent->io (fh => $fh, poll => "w", cb => sub { |
1653 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
1654 |
|
1655 |
if ($len > 0) { |
1656 |
substr $wbuf, 0, $len, ""; |
1657 |
} else { |
1658 |
@linger = (); # end |
1659 |
} |
1660 |
}); |
1661 |
push @linger, AnyEvent->timer (after => $linger, cb => sub { |
1662 |
@linger = (); |
1663 |
}); |
1664 |
} |
1665 |
} |
1666 |
|
1667 |
=item $handle->destroy |
1668 |
|
1669 |
Shuts down the handle object as much as possible - this call ensures that |
1670 |
no further callbacks will be invoked and as many resources as possible |
1671 |
will be freed. You must not call any methods on the object afterwards. |
1672 |
|
1673 |
Normally, you can just "forget" any references to an AnyEvent::Handle |
1674 |
object and it will simply shut down. This works in fatal error and EOF |
1675 |
callbacks, as well as code outside. It does I<NOT> work in a read or write |
1676 |
callback, so when you want to destroy the AnyEvent::Handle object from |
1677 |
within such an callback. You I<MUST> call C<< ->destroy >> explicitly in |
1678 |
that case. |
1679 |
|
1680 |
Destroying the handle object in this way has the advantage that callbacks |
1681 |
will be removed as well, so if those are the only reference holders (as |
1682 |
is common), then one doesn't need to do anything special to break any |
1683 |
reference cycles. |
1684 |
|
1685 |
The handle might still linger in the background and write out remaining |
1686 |
data, as specified by the C<linger> option, however. |
1687 |
|
1688 |
=cut |
1689 |
|
1690 |
sub destroy { |
1691 |
my ($self) = @_; |
1692 |
|
1693 |
$self->DESTROY; |
1694 |
%$self = (); |
1695 |
} |
1696 |
|
1697 |
=item AnyEvent::Handle::TLS_CTX |
1698 |
|
1699 |
This function creates and returns the AnyEvent::TLS object used by default |
1700 |
for TLS mode. |
1701 |
|
1702 |
The context is created by calling L<AnyEvent::TLS> without any arguments. |
1703 |
|
1704 |
=cut |
1705 |
|
1706 |
our $TLS_CTX; |
1707 |
|
1708 |
sub TLS_CTX() { |
1709 |
$TLS_CTX ||= do { |
1710 |
require AnyEvent::TLS; |
1711 |
|
1712 |
new AnyEvent::TLS |
1713 |
} |
1714 |
} |
1715 |
|
1716 |
=back |
1717 |
|
1718 |
|
1719 |
=head1 NONFREQUENTLY ASKED QUESTIONS |
1720 |
|
1721 |
=over 4 |
1722 |
|
1723 |
=item I C<undef> the AnyEvent::Handle reference inside my callback and |
1724 |
still get further invocations! |
1725 |
|
1726 |
That's because AnyEvent::Handle keeps a reference to itself when handling |
1727 |
read or write callbacks. |
1728 |
|
1729 |
It is only safe to "forget" the reference inside EOF or error callbacks, |
1730 |
from within all other callbacks, you need to explicitly call the C<< |
1731 |
->destroy >> method. |
1732 |
|
1733 |
=item I get different callback invocations in TLS mode/Why can't I pause |
1734 |
reading? |
1735 |
|
1736 |
Unlike, say, TCP, TLS connections do not consist of two independent |
1737 |
communication channels, one for each direction. Or put differently. The |
1738 |
read and write directions are not independent of each other: you cannot |
1739 |
write data unless you are also prepared to read, and vice versa. |
1740 |
|
1741 |
This can mean than, in TLS mode, you might get C<on_error> or C<on_eof> |
1742 |
callback invocations when you are not expecting any read data - the reason |
1743 |
is that AnyEvent::Handle always reads in TLS mode. |
1744 |
|
1745 |
During the connection, you have to make sure that you always have a |
1746 |
non-empty read-queue, or an C<on_read> watcher. At the end of the |
1747 |
connection (or when you no longer want to use it) you can call the |
1748 |
C<destroy> method. |
1749 |
|
1750 |
=item How do I read data until the other side closes the connection? |
1751 |
|
1752 |
If you just want to read your data into a perl scalar, the easiest way |
1753 |
to achieve this is by setting an C<on_read> callback that does nothing, |
1754 |
clearing the C<on_eof> callback and in the C<on_error> callback, the data |
1755 |
will be in C<$_[0]{rbuf}>: |
1756 |
|
1757 |
$handle->on_read (sub { }); |
1758 |
$handle->on_eof (undef); |
1759 |
$handle->on_error (sub { |
1760 |
my $data = delete $_[0]{rbuf}; |
1761 |
}); |
1762 |
|
1763 |
The reason to use C<on_error> is that TCP connections, due to latencies |
1764 |
and packets loss, might get closed quite violently with an error, when in |
1765 |
fact, all data has been received. |
1766 |
|
1767 |
It is usually better to use acknowledgements when transferring data, |
1768 |
to make sure the other side hasn't just died and you got the data |
1769 |
intact. This is also one reason why so many internet protocols have an |
1770 |
explicit QUIT command. |
1771 |
|
1772 |
=item I don't want to destroy the handle too early - how do I wait until |
1773 |
all data has been written? |
1774 |
|
1775 |
After writing your last bits of data, set the C<on_drain> callback |
1776 |
and destroy the handle in there - with the default setting of |
1777 |
C<low_water_mark> this will be called precisely when all data has been |
1778 |
written to the socket: |
1779 |
|
1780 |
$handle->push_write (...); |
1781 |
$handle->on_drain (sub { |
1782 |
warn "all data submitted to the kernel\n"; |
1783 |
undef $handle; |
1784 |
}); |
1785 |
|
1786 |
If you just want to queue some data and then signal EOF to the other side, |
1787 |
consider using C<< ->push_shutdown >> instead. |
1788 |
|
1789 |
=item I want to contact a TLS/SSL server, I don't care about security. |
1790 |
|
1791 |
If your TLS server is a pure TLS server (e.g. HTTPS) that only speaks TLS, |
1792 |
simply connect to it and then create the AnyEvent::Handle with the C<tls> |
1793 |
parameter: |
1794 |
|
1795 |
tcp_connect $host, $port, sub { |
1796 |
my ($fh) = @_; |
1797 |
|
1798 |
my $handle = new AnyEvent::Handle |
1799 |
fh => $fh, |
1800 |
tls => "connect", |
1801 |
on_error => sub { ... }; |
1802 |
|
1803 |
$handle->push_write (...); |
1804 |
}; |
1805 |
|
1806 |
=item I want to contact a TLS/SSL server, I do care about security. |
1807 |
|
1808 |
Then you should additionally enable certificate verification, including |
1809 |
peername verification, if the protocol you use supports it (see |
1810 |
L<AnyEvent::TLS>, C<verify_peername>). |
1811 |
|
1812 |
E.g. for HTTPS: |
1813 |
|
1814 |
tcp_connect $host, $port, sub { |
1815 |
my ($fh) = @_; |
1816 |
|
1817 |
my $handle = new AnyEvent::Handle |
1818 |
fh => $fh, |
1819 |
peername => $host, |
1820 |
tls => "connect", |
1821 |
tls_ctx => { verify => 1, verify_peername => "https" }, |
1822 |
... |
1823 |
|
1824 |
Note that you must specify the hostname you connected to (or whatever |
1825 |
"peername" the protocol needs) as the C<peername> argument, otherwise no |
1826 |
peername verification will be done. |
1827 |
|
1828 |
The above will use the system-dependent default set of trusted CA |
1829 |
certificates. If you want to check against a specific CA, add the |
1830 |
C<ca_file> (or C<ca_cert>) arguments to C<tls_ctx>: |
1831 |
|
1832 |
tls_ctx => { |
1833 |
verify => 1, |
1834 |
verify_peername => "https", |
1835 |
ca_file => "my-ca-cert.pem", |
1836 |
}, |
1837 |
|
1838 |
=item I want to create a TLS/SSL server, how do I do that? |
1839 |
|
1840 |
Well, you first need to get a server certificate and key. You have |
1841 |
three options: a) ask a CA (buy one, use cacert.org etc.) b) create a |
1842 |
self-signed certificate (cheap. check the search engine of your choice, |
1843 |
there are many tutorials on the net) or c) make your own CA (tinyca2 is a |
1844 |
nice program for that purpose). |
1845 |
|
1846 |
Then create a file with your private key (in PEM format, see |
1847 |
L<AnyEvent::TLS>), followed by the certificate (also in PEM format). The |
1848 |
file should then look like this: |
1849 |
|
1850 |
-----BEGIN RSA PRIVATE KEY----- |
1851 |
...header data |
1852 |
... lots of base64'y-stuff |
1853 |
-----END RSA PRIVATE KEY----- |
1854 |
|
1855 |
-----BEGIN CERTIFICATE----- |
1856 |
... lots of base64'y-stuff |
1857 |
-----END CERTIFICATE----- |
1858 |
|
1859 |
The important bits are the "PRIVATE KEY" and "CERTIFICATE" parts. Then |
1860 |
specify this file as C<cert_file>: |
1861 |
|
1862 |
tcp_server undef, $port, sub { |
1863 |
my ($fh) = @_; |
1864 |
|
1865 |
my $handle = new AnyEvent::Handle |
1866 |
fh => $fh, |
1867 |
tls => "accept", |
1868 |
tls_ctx => { cert_file => "my-server-keycert.pem" }, |
1869 |
... |
1870 |
|
1871 |
When you have intermediate CA certificates that your clients might not |
1872 |
know about, just append them to the C<cert_file>. |
1873 |
|
1874 |
=back |
1875 |
|
1876 |
|
1877 |
=head1 SUBCLASSING AnyEvent::Handle |
1878 |
|
1879 |
In many cases, you might want to subclass AnyEvent::Handle. |
1880 |
|
1881 |
To make this easier, a given version of AnyEvent::Handle uses these |
1882 |
conventions: |
1883 |
|
1884 |
=over 4 |
1885 |
|
1886 |
=item * all constructor arguments become object members. |
1887 |
|
1888 |
At least initially, when you pass a C<tls>-argument to the constructor it |
1889 |
will end up in C<< $handle->{tls} >>. Those members might be changed or |
1890 |
mutated later on (for example C<tls> will hold the TLS connection object). |
1891 |
|
1892 |
=item * other object member names are prefixed with an C<_>. |
1893 |
|
1894 |
All object members not explicitly documented (internal use) are prefixed |
1895 |
with an underscore character, so the remaining non-C<_>-namespace is free |
1896 |
for use for subclasses. |
1897 |
|
1898 |
=item * all members not documented here and not prefixed with an underscore |
1899 |
are free to use in subclasses. |
1900 |
|
1901 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
1902 |
member variables, but thats just life, at least it is documented. |
1903 |
|
1904 |
=back |
1905 |
|
1906 |
=head1 AUTHOR |
1907 |
|
1908 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
1909 |
|
1910 |
=cut |
1911 |
|
1912 |
1; # End of AnyEvent::Handle |