1 |
=head1 NAME |
2 |
|
3 |
AnyEvent::Handle - non-blocking I/O on streaming handles via AnyEvent |
4 |
|
5 |
=head1 SYNOPSIS |
6 |
|
7 |
use AnyEvent; |
8 |
use AnyEvent::Handle; |
9 |
|
10 |
my $cv = AnyEvent->condvar; |
11 |
|
12 |
my $hdl; $hdl = new AnyEvent::Handle |
13 |
fh => \*STDIN, |
14 |
on_error => sub { |
15 |
my ($hdl, $fatal, $msg) = @_; |
16 |
AE::log error => $msg; |
17 |
$hdl->destroy; |
18 |
$cv->send; |
19 |
}; |
20 |
|
21 |
# send some request line |
22 |
$hdl->push_write ("getinfo\015\012"); |
23 |
|
24 |
# read the response line |
25 |
$hdl->push_read (line => sub { |
26 |
my ($hdl, $line) = @_; |
27 |
say "got line <$line>"; |
28 |
$cv->send; |
29 |
}); |
30 |
|
31 |
$cv->recv; |
32 |
|
33 |
=head1 DESCRIPTION |
34 |
|
35 |
This is a helper module to make it easier to do event-based I/O on |
36 |
stream-based filehandles (sockets, pipes, and other stream things). |
37 |
|
38 |
The L<AnyEvent::Intro> tutorial contains some well-documented |
39 |
AnyEvent::Handle examples. |
40 |
|
41 |
In the following, where the documentation refers to "bytes", it means |
42 |
characters. As sysread and syswrite are used for all I/O, their |
43 |
treatment of characters applies to this module as well. |
44 |
|
45 |
At the very minimum, you should specify C<fh> or C<connect>, and the |
46 |
C<on_error> callback. |
47 |
|
48 |
All callbacks will be invoked with the handle object as their first |
49 |
argument. |
50 |
|
51 |
=cut |
52 |
|
53 |
package AnyEvent::Handle; |
54 |
|
55 |
use Scalar::Util (); |
56 |
use List::Util (); |
57 |
use Carp (); |
58 |
use Errno qw(EAGAIN EINTR); |
59 |
|
60 |
use AnyEvent (); BEGIN { AnyEvent::common_sense } |
61 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
62 |
|
63 |
our $VERSION = $AnyEvent::VERSION; |
64 |
|
65 |
sub _load_func($) { |
66 |
my $func = $_[0]; |
67 |
|
68 |
unless (defined &$func) { |
69 |
my $pkg = $func; |
70 |
do { |
71 |
$pkg =~ s/::[^:]+$// |
72 |
or return; |
73 |
eval "require $pkg"; |
74 |
} until defined &$func; |
75 |
} |
76 |
|
77 |
\&$func |
78 |
} |
79 |
|
80 |
sub MAX_READ_SIZE() { 131072 } |
81 |
|
82 |
=head1 METHODS |
83 |
|
84 |
=over 4 |
85 |
|
86 |
=item $handle = B<new> AnyEvent::Handle fh => $filehandle, key => value... |
87 |
|
88 |
The constructor supports these arguments (all as C<< key => value >> pairs). |
89 |
|
90 |
=over 4 |
91 |
|
92 |
=item fh => $filehandle [C<fh> or C<connect> MANDATORY] |
93 |
|
94 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
95 |
NOTE: The filehandle will be set to non-blocking mode (using |
96 |
C<AnyEvent::Util::fh_nonblocking>) by the constructor and needs to stay in |
97 |
that mode. |
98 |
|
99 |
=item connect => [$host, $service] [C<fh> or C<connect> MANDATORY] |
100 |
|
101 |
Try to connect to the specified host and service (port), using |
102 |
C<AnyEvent::Socket::tcp_connect>. The C<$host> additionally becomes the |
103 |
default C<peername>. |
104 |
|
105 |
You have to specify either this parameter, or C<fh>, above. |
106 |
|
107 |
It is possible to push requests on the read and write queues, and modify |
108 |
properties of the stream, even while AnyEvent::Handle is connecting. |
109 |
|
110 |
When this parameter is specified, then the C<on_prepare>, |
111 |
C<on_connect_error> and C<on_connect> callbacks will be called under the |
112 |
appropriate circumstances: |
113 |
|
114 |
=over 4 |
115 |
|
116 |
=item on_prepare => $cb->($handle) |
117 |
|
118 |
This (rarely used) callback is called before a new connection is |
119 |
attempted, but after the file handle has been created (you can access that |
120 |
file handle via C<< $handle->{fh} >>). It could be used to prepare the |
121 |
file handle with parameters required for the actual connect (as opposed to |
122 |
settings that can be changed when the connection is already established). |
123 |
|
124 |
The return value of this callback should be the connect timeout value in |
125 |
seconds (or C<0>, or C<undef>, or the empty list, to indicate that the |
126 |
default timeout is to be used). |
127 |
|
128 |
=item on_connect => $cb->($handle, $host, $port, $retry->()) |
129 |
|
130 |
This callback is called when a connection has been successfully established. |
131 |
|
132 |
The peer's numeric host and port (the socket peername) are passed as |
133 |
parameters, together with a retry callback. At the time it is called the |
134 |
read and write queues, EOF status, TLS status and similar properties of |
135 |
the handle will have been reset. |
136 |
|
137 |
It is not allowed to use the read or write queues while the handle object |
138 |
is connecting. |
139 |
|
140 |
If, for some reason, the handle is not acceptable, calling C<$retry> will |
141 |
continue with the next connection target (in case of multi-homed hosts or |
142 |
SRV records there can be multiple connection endpoints). The C<$retry> |
143 |
callback can be invoked after the connect callback returns, i.e. one can |
144 |
start a handshake and then decide to retry with the next host if the |
145 |
handshake fails. |
146 |
|
147 |
In most cases, you should ignore the C<$retry> parameter. |
148 |
|
149 |
=item on_connect_error => $cb->($handle, $message) |
150 |
|
151 |
This callback is called when the connection could not be |
152 |
established. C<$!> will contain the relevant error code, and C<$message> a |
153 |
message describing it (usually the same as C<"$!">). |
154 |
|
155 |
If this callback isn't specified, then C<on_error> will be called with a |
156 |
fatal error instead. |
157 |
|
158 |
=back |
159 |
|
160 |
=item on_error => $cb->($handle, $fatal, $message) |
161 |
|
162 |
This is the error callback, which is called when, well, some error |
163 |
occured, such as not being able to resolve the hostname, failure to |
164 |
connect, or a read error. |
165 |
|
166 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
167 |
fatal errors the handle object will be destroyed (by a call to C<< -> |
168 |
destroy >>) after invoking the error callback (which means you are free to |
169 |
examine the handle object). Examples of fatal errors are an EOF condition |
170 |
with active (but unsatisfiable) read watchers (C<EPIPE>) or I/O errors. In |
171 |
cases where the other side can close the connection at will, it is |
172 |
often easiest to not report C<EPIPE> errors in this callback. |
173 |
|
174 |
AnyEvent::Handle tries to find an appropriate error code for you to check |
175 |
against, but in some cases (TLS errors), this does not work well. |
176 |
|
177 |
If you report the error to the user, it is recommended to always output |
178 |
the C<$message> argument in human-readable error messages (you don't need |
179 |
to report C<"$!"> if you report C<$message>). |
180 |
|
181 |
If you want to react programmatically to the error, then looking at C<$!> |
182 |
and comparing it against some of the documented C<Errno> values is usually |
183 |
better than looking at the C<$message>. |
184 |
|
185 |
Non-fatal errors can be retried by returning, but it is recommended |
186 |
to simply ignore this parameter and instead abondon the handle object |
187 |
when this callback is invoked. Examples of non-fatal errors are timeouts |
188 |
C<ETIMEDOUT>) or badly-formatted data (C<EBADMSG>). |
189 |
|
190 |
On entry to the callback, the value of C<$!> contains the operating |
191 |
system error code (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT>, C<EBADMSG> or |
192 |
C<EPROTO>). |
193 |
|
194 |
While not mandatory, it is I<highly> recommended to set this callback, as |
195 |
you will not be notified of errors otherwise. The default just calls |
196 |
C<croak>. |
197 |
|
198 |
=item on_read => $cb->($handle) |
199 |
|
200 |
This sets the default read callback, which is called when data arrives |
201 |
and no read request is in the queue (unlike read queue callbacks, this |
202 |
callback will only be called when at least one octet of data is in the |
203 |
read buffer). |
204 |
|
205 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
206 |
method or access the C<< $handle->{rbuf} >> member directly. Note that you |
207 |
must not enlarge or modify the read buffer, you can only remove data at |
208 |
the beginning from it. |
209 |
|
210 |
You can also call C<< ->push_read (...) >> or any other function that |
211 |
modifies the read queue. Or do both. Or ... |
212 |
|
213 |
When an EOF condition is detected, AnyEvent::Handle will first try to |
214 |
feed all the remaining data to the queued callbacks and C<on_read> before |
215 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
216 |
error will be raised (with C<$!> set to C<EPIPE>). |
217 |
|
218 |
Note that, unlike requests in the read queue, an C<on_read> callback |
219 |
doesn't mean you I<require> some data: if there is an EOF and there |
220 |
are outstanding read requests then an error will be flagged. With an |
221 |
C<on_read> callback, the C<on_eof> callback will be invoked. |
222 |
|
223 |
=item on_eof => $cb->($handle) |
224 |
|
225 |
Set the callback to be called when an end-of-file condition is detected, |
226 |
i.e. in the case of a socket, when the other side has closed the |
227 |
connection cleanly, and there are no outstanding read requests in the |
228 |
queue (if there are read requests, then an EOF counts as an unexpected |
229 |
connection close and will be flagged as an error). |
230 |
|
231 |
For sockets, this just means that the other side has stopped sending data, |
232 |
you can still try to write data, and, in fact, one can return from the EOF |
233 |
callback and continue writing data, as only the read part has been shut |
234 |
down. |
235 |
|
236 |
If an EOF condition has been detected but no C<on_eof> callback has been |
237 |
set, then a fatal error will be raised with C<$!> set to <0>. |
238 |
|
239 |
=item on_drain => $cb->($handle) |
240 |
|
241 |
This sets the callback that is called once when the write buffer becomes |
242 |
empty (and immediately when the handle object is created). |
243 |
|
244 |
To append to the write buffer, use the C<< ->push_write >> method. |
245 |
|
246 |
This callback is useful when you don't want to put all of your write data |
247 |
into the queue at once, for example, when you want to write the contents |
248 |
of some file to the socket you might not want to read the whole file into |
249 |
memory and push it into the queue, but instead only read more data from |
250 |
the file when the write queue becomes empty. |
251 |
|
252 |
=item timeout => $fractional_seconds |
253 |
|
254 |
=item rtimeout => $fractional_seconds |
255 |
|
256 |
=item wtimeout => $fractional_seconds |
257 |
|
258 |
If non-zero, then these enables an "inactivity" timeout: whenever this |
259 |
many seconds pass without a successful read or write on the underlying |
260 |
file handle (or a call to C<timeout_reset>), the C<on_timeout> callback |
261 |
will be invoked (and if that one is missing, a non-fatal C<ETIMEDOUT> |
262 |
error will be raised). |
263 |
|
264 |
There are three variants of the timeouts that work independently of each |
265 |
other, for both read and write (triggered when nothing was read I<OR> |
266 |
written), just read (triggered when nothing was read), and just write: |
267 |
C<timeout>, C<rtimeout> and C<wtimeout>, with corresponding callbacks |
268 |
C<on_timeout>, C<on_rtimeout> and C<on_wtimeout>, and reset functions |
269 |
C<timeout_reset>, C<rtimeout_reset>, and C<wtimeout_reset>. |
270 |
|
271 |
Note that timeout processing is active even when you do not have any |
272 |
outstanding read or write requests: If you plan to keep the connection |
273 |
idle then you should disable the timeout temporarily or ignore the |
274 |
timeout in the corresponding C<on_timeout> callback, in which case |
275 |
AnyEvent::Handle will simply restart the timeout. |
276 |
|
277 |
Zero (the default) disables the corresponding timeout. |
278 |
|
279 |
=item on_timeout => $cb->($handle) |
280 |
|
281 |
=item on_rtimeout => $cb->($handle) |
282 |
|
283 |
=item on_wtimeout => $cb->($handle) |
284 |
|
285 |
Called whenever the inactivity timeout passes. If you return from this |
286 |
callback, then the timeout will be reset as if some activity had happened, |
287 |
so this condition is not fatal in any way. |
288 |
|
289 |
=item rbuf_max => <bytes> |
290 |
|
291 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
292 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
293 |
avoid some forms of denial-of-service attacks. |
294 |
|
295 |
For example, a server accepting connections from untrusted sources should |
296 |
be configured to accept only so-and-so much data that it cannot act on |
297 |
(for example, when expecting a line, an attacker could send an unlimited |
298 |
amount of data without a callback ever being called as long as the line |
299 |
isn't finished). |
300 |
|
301 |
=item wbuf_max => <bytes> |
302 |
|
303 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
304 |
when the write buffer ever (strictly) exceeds this size. This is useful to |
305 |
avoid some forms of denial-of-service attacks. |
306 |
|
307 |
Although the units of this parameter is bytes, this is the I<raw> number |
308 |
of bytes not yet accepted by the kernel. This can make a difference when |
309 |
you e.g. use TLS, as TLS typically makes your write data larger (but it |
310 |
can also make it smaller due to compression). |
311 |
|
312 |
As an example of when this limit is useful, take a chat server that sends |
313 |
chat messages to a client. If the client does not read those in a timely |
314 |
manner then the send buffer in the server would grow unbounded. |
315 |
|
316 |
=item autocork => <boolean> |
317 |
|
318 |
When disabled (the default), C<push_write> will try to immediately |
319 |
write the data to the handle if possible. This avoids having to register |
320 |
a write watcher and wait for the next event loop iteration, but can |
321 |
be inefficient if you write multiple small chunks (on the wire, this |
322 |
disadvantage is usually avoided by your kernel's nagle algorithm, see |
323 |
C<no_delay>, but this option can save costly syscalls). |
324 |
|
325 |
When enabled, writes will always be queued till the next event loop |
326 |
iteration. This is efficient when you do many small writes per iteration, |
327 |
but less efficient when you do a single write only per iteration (or when |
328 |
the write buffer often is full). It also increases write latency. |
329 |
|
330 |
=item no_delay => <boolean> |
331 |
|
332 |
When doing small writes on sockets, your operating system kernel might |
333 |
wait a bit for more data before actually sending it out. This is called |
334 |
the Nagle algorithm, and usually it is beneficial. |
335 |
|
336 |
In some situations you want as low a delay as possible, which can be |
337 |
accomplishd by setting this option to a true value. |
338 |
|
339 |
The default is your operating system's default behaviour (most likely |
340 |
enabled). This option explicitly enables or disables it, if possible. |
341 |
|
342 |
=item keepalive => <boolean> |
343 |
|
344 |
Enables (default disable) the SO_KEEPALIVE option on the stream socket: |
345 |
normally, TCP connections have no time-out once established, so TCP |
346 |
connections, once established, can stay alive forever even when the other |
347 |
side has long gone. TCP keepalives are a cheap way to take down long-lived |
348 |
TCP connections when the other side becomes unreachable. While the default |
349 |
is OS-dependent, TCP keepalives usually kick in after around two hours, |
350 |
and, if the other side doesn't reply, take down the TCP connection some 10 |
351 |
to 15 minutes later. |
352 |
|
353 |
It is harmless to specify this option for file handles that do not support |
354 |
keepalives, and enabling it on connections that are potentially long-lived |
355 |
is usually a good idea. |
356 |
|
357 |
=item oobinline => <boolean> |
358 |
|
359 |
BSD majorly fucked up the implementation of TCP urgent data. The result |
360 |
is that almost no OS implements TCP according to the specs, and every OS |
361 |
implements it slightly differently. |
362 |
|
363 |
If you want to handle TCP urgent data, then setting this flag (the default |
364 |
is enabled) gives you the most portable way of getting urgent data, by |
365 |
putting it into the stream. |
366 |
|
367 |
Since BSD emulation of OOB data on top of TCP's urgent data can have |
368 |
security implications, AnyEvent::Handle sets this flag automatically |
369 |
unless explicitly specified. Note that setting this flag after |
370 |
establishing a connection I<may> be a bit too late (data loss could |
371 |
already have occured on BSD systems), but at least it will protect you |
372 |
from most attacks. |
373 |
|
374 |
=item read_size => <bytes> |
375 |
|
376 |
The initial read block size, the number of bytes this module will try |
377 |
to read during each loop iteration. Each handle object will consume |
378 |
at least this amount of memory for the read buffer as well, so when |
379 |
handling many connections watch out for memory requirements). See also |
380 |
C<max_read_size>. Default: C<2048>. |
381 |
|
382 |
=item max_read_size => <bytes> |
383 |
|
384 |
The maximum read buffer size used by the dynamic adjustment |
385 |
algorithm: Each time AnyEvent::Handle can read C<read_size> bytes in |
386 |
one go it will double C<read_size> up to the maximum given by this |
387 |
option. Default: C<131072> or C<read_size>, whichever is higher. |
388 |
|
389 |
=item low_water_mark => <bytes> |
390 |
|
391 |
Sets the number of bytes (default: C<0>) that make up an "empty" write |
392 |
buffer: If the buffer reaches this size or gets even samller it is |
393 |
considered empty. |
394 |
|
395 |
Sometimes it can be beneficial (for performance reasons) to add data to |
396 |
the write buffer before it is fully drained, but this is a rare case, as |
397 |
the operating system kernel usually buffers data as well, so the default |
398 |
is good in almost all cases. |
399 |
|
400 |
=item linger => <seconds> |
401 |
|
402 |
If this is non-zero (default: C<3600>), the destructor of the |
403 |
AnyEvent::Handle object will check whether there is still outstanding |
404 |
write data and will install a watcher that will write this data to the |
405 |
socket. No errors will be reported (this mostly matches how the operating |
406 |
system treats outstanding data at socket close time). |
407 |
|
408 |
This will not work for partial TLS data that could not be encoded |
409 |
yet. This data will be lost. Calling the C<stoptls> method in time might |
410 |
help. |
411 |
|
412 |
=item peername => $string |
413 |
|
414 |
A string used to identify the remote site - usually the DNS hostname |
415 |
(I<not> IDN!) used to create the connection, rarely the IP address. |
416 |
|
417 |
Apart from being useful in error messages, this string is also used in TLS |
418 |
peername verification (see C<verify_peername> in L<AnyEvent::TLS>). This |
419 |
verification will be skipped when C<peername> is not specified or is |
420 |
C<undef>. |
421 |
|
422 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
423 |
|
424 |
When this parameter is given, it enables TLS (SSL) mode, that means |
425 |
AnyEvent will start a TLS handshake as soon as the connection has been |
426 |
established and will transparently encrypt/decrypt data afterwards. |
427 |
|
428 |
All TLS protocol errors will be signalled as C<EPROTO>, with an |
429 |
appropriate error message. |
430 |
|
431 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
432 |
automatically when you try to create a TLS handle): this module doesn't |
433 |
have a dependency on that module, so if your module requires it, you have |
434 |
to add the dependency yourself. If Net::SSLeay cannot be loaded or is too |
435 |
old, you get an C<EPROTO> error. |
436 |
|
437 |
Unlike TCP, TLS has a server and client side: for the TLS server side, use |
438 |
C<accept>, and for the TLS client side of a connection, use C<connect> |
439 |
mode. |
440 |
|
441 |
You can also provide your own TLS connection object, but you have |
442 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
443 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
444 |
AnyEvent::Handle. Also, this module will take ownership of this connection |
445 |
object. |
446 |
|
447 |
At some future point, AnyEvent::Handle might switch to another TLS |
448 |
implementation, then the option to use your own session object will go |
449 |
away. |
450 |
|
451 |
B<IMPORTANT:> since Net::SSLeay "objects" are really only integers, |
452 |
passing in the wrong integer will lead to certain crash. This most often |
453 |
happens when one uses a stylish C<< tls => 1 >> and is surprised about the |
454 |
segmentation fault. |
455 |
|
456 |
Use the C<< ->starttls >> method if you need to start TLS negotiation later. |
457 |
|
458 |
=item tls_ctx => $anyevent_tls |
459 |
|
460 |
Use the given C<AnyEvent::TLS> object to create the new TLS connection |
461 |
(unless a connection object was specified directly). If this |
462 |
parameter is missing (or C<undef>), then AnyEvent::Handle will use |
463 |
C<AnyEvent::Handle::TLS_CTX>. |
464 |
|
465 |
Instead of an object, you can also specify a hash reference with C<< key |
466 |
=> value >> pairs. Those will be passed to L<AnyEvent::TLS> to create a |
467 |
new TLS context object. |
468 |
|
469 |
=item on_starttls => $cb->($handle, $success[, $error_message]) |
470 |
|
471 |
This callback will be invoked when the TLS/SSL handshake has finished. If |
472 |
C<$success> is true, then the TLS handshake succeeded, otherwise it failed |
473 |
(C<on_stoptls> will not be called in this case). |
474 |
|
475 |
The session in C<< $handle->{tls} >> can still be examined in this |
476 |
callback, even when the handshake was not successful. |
477 |
|
478 |
TLS handshake failures will not cause C<on_error> to be invoked when this |
479 |
callback is in effect, instead, the error message will be passed to C<on_starttls>. |
480 |
|
481 |
Without this callback, handshake failures lead to C<on_error> being |
482 |
called as usual. |
483 |
|
484 |
Note that you cannot just call C<starttls> again in this callback. If you |
485 |
need to do that, start an zero-second timer instead whose callback can |
486 |
then call C<< ->starttls >> again. |
487 |
|
488 |
=item on_stoptls => $cb->($handle) |
489 |
|
490 |
When a SSLv3/TLS shutdown/close notify/EOF is detected and this callback is |
491 |
set, then it will be invoked after freeing the TLS session. If it is not, |
492 |
then a TLS shutdown condition will be treated like a normal EOF condition |
493 |
on the handle. |
494 |
|
495 |
The session in C<< $handle->{tls} >> can still be examined in this |
496 |
callback. |
497 |
|
498 |
This callback will only be called on TLS shutdowns, not when the |
499 |
underlying handle signals EOF. |
500 |
|
501 |
=item json => JSON or JSON::XS object |
502 |
|
503 |
This is the json coder object used by the C<json> read and write types. |
504 |
|
505 |
If you don't supply it, then AnyEvent::Handle will create and use a |
506 |
suitable one (on demand), which will write and expect UTF-8 encoded JSON |
507 |
texts. |
508 |
|
509 |
Note that you are responsible to depend on the JSON module if you want to |
510 |
use this functionality, as AnyEvent does not have a dependency itself. |
511 |
|
512 |
=back |
513 |
|
514 |
=cut |
515 |
|
516 |
sub new { |
517 |
my $class = shift; |
518 |
my $self = bless { @_ }, $class; |
519 |
|
520 |
if ($self->{fh}) { |
521 |
$self->_start; |
522 |
return unless $self->{fh}; # could be gone by now |
523 |
|
524 |
} elsif ($self->{connect}) { |
525 |
require AnyEvent::Socket; |
526 |
|
527 |
$self->{peername} = $self->{connect}[0] |
528 |
unless exists $self->{peername}; |
529 |
|
530 |
$self->{_skip_drain_rbuf} = 1; |
531 |
|
532 |
{ |
533 |
Scalar::Util::weaken (my $self = $self); |
534 |
|
535 |
$self->{_connect} = |
536 |
AnyEvent::Socket::tcp_connect ( |
537 |
$self->{connect}[0], |
538 |
$self->{connect}[1], |
539 |
sub { |
540 |
my ($fh, $host, $port, $retry) = @_; |
541 |
|
542 |
delete $self->{_connect}; # no longer needed |
543 |
|
544 |
if ($fh) { |
545 |
$self->{fh} = $fh; |
546 |
|
547 |
delete $self->{_skip_drain_rbuf}; |
548 |
$self->_start; |
549 |
|
550 |
$self->{on_connect} |
551 |
and $self->{on_connect}($self, $host, $port, sub { |
552 |
delete @$self{qw(fh _tw _rtw _wtw _ww _rw _eof _queue rbuf _wbuf tls _tls_rbuf _tls_wbuf)}; |
553 |
$self->{_skip_drain_rbuf} = 1; |
554 |
&$retry; |
555 |
}); |
556 |
|
557 |
} else { |
558 |
if ($self->{on_connect_error}) { |
559 |
$self->{on_connect_error}($self, "$!"); |
560 |
$self->destroy if $self; |
561 |
} else { |
562 |
$self->_error ($!, 1); |
563 |
} |
564 |
} |
565 |
}, |
566 |
sub { |
567 |
local $self->{fh} = $_[0]; |
568 |
|
569 |
$self->{on_prepare} |
570 |
? $self->{on_prepare}->($self) |
571 |
: () |
572 |
} |
573 |
); |
574 |
} |
575 |
|
576 |
} else { |
577 |
Carp::croak "AnyEvent::Handle: either an existing fh or the connect parameter must be specified"; |
578 |
} |
579 |
|
580 |
$self |
581 |
} |
582 |
|
583 |
sub _start { |
584 |
my ($self) = @_; |
585 |
|
586 |
# too many clueless people try to use udp and similar sockets |
587 |
# with AnyEvent::Handle, do them a favour. |
588 |
my $type = getsockopt $self->{fh}, Socket::SOL_SOCKET (), Socket::SO_TYPE (); |
589 |
Carp::croak "AnyEvent::Handle: only stream sockets supported, anything else will NOT work!" |
590 |
if Socket::SOCK_STREAM () != (unpack "I", $type) && defined $type; |
591 |
|
592 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
593 |
|
594 |
$self->{_activity} = |
595 |
$self->{_ractivity} = |
596 |
$self->{_wactivity} = AE::now; |
597 |
|
598 |
$self->{read_size} ||= 2048; |
599 |
$self->{max_read_size} = $self->{read_size} |
600 |
if $self->{read_size} > ($self->{max_read_size} || MAX_READ_SIZE); |
601 |
|
602 |
$self->timeout (delete $self->{timeout} ) if $self->{timeout}; |
603 |
$self->rtimeout (delete $self->{rtimeout} ) if $self->{rtimeout}; |
604 |
$self->wtimeout (delete $self->{wtimeout} ) if $self->{wtimeout}; |
605 |
|
606 |
$self->no_delay (delete $self->{no_delay} ) if exists $self->{no_delay} && $self->{no_delay}; |
607 |
$self->keepalive (delete $self->{keepalive}) if exists $self->{keepalive} && $self->{keepalive}; |
608 |
|
609 |
$self->oobinline (exists $self->{oobinline} ? delete $self->{oobinline} : 1); |
610 |
|
611 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}) |
612 |
if $self->{tls}; |
613 |
|
614 |
$self->on_drain (delete $self->{on_drain} ) if $self->{on_drain}; |
615 |
|
616 |
$self->start_read |
617 |
if $self->{on_read} || @{ $self->{_queue} }; |
618 |
|
619 |
$self->_drain_wbuf; |
620 |
} |
621 |
|
622 |
sub _error { |
623 |
my ($self, $errno, $fatal, $message) = @_; |
624 |
|
625 |
$! = $errno; |
626 |
$message ||= "$!"; |
627 |
|
628 |
if ($self->{on_error}) { |
629 |
$self->{on_error}($self, $fatal, $message); |
630 |
$self->destroy if $fatal; |
631 |
} elsif ($self->{fh} || $self->{connect}) { |
632 |
$self->destroy; |
633 |
Carp::croak "AnyEvent::Handle uncaught error: $message"; |
634 |
} |
635 |
} |
636 |
|
637 |
=item $fh = $handle->fh |
638 |
|
639 |
This method returns the file handle used to create the L<AnyEvent::Handle> object. |
640 |
|
641 |
=cut |
642 |
|
643 |
sub fh { $_[0]{fh} } |
644 |
|
645 |
=item $handle->on_error ($cb) |
646 |
|
647 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
648 |
|
649 |
=cut |
650 |
|
651 |
sub on_error { |
652 |
$_[0]{on_error} = $_[1]; |
653 |
} |
654 |
|
655 |
=item $handle->on_eof ($cb) |
656 |
|
657 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
658 |
|
659 |
=cut |
660 |
|
661 |
sub on_eof { |
662 |
$_[0]{on_eof} = $_[1]; |
663 |
} |
664 |
|
665 |
=item $handle->on_timeout ($cb) |
666 |
|
667 |
=item $handle->on_rtimeout ($cb) |
668 |
|
669 |
=item $handle->on_wtimeout ($cb) |
670 |
|
671 |
Replace the current C<on_timeout>, C<on_rtimeout> or C<on_wtimeout> |
672 |
callback, or disables the callback (but not the timeout) if C<$cb> = |
673 |
C<undef>. See the C<timeout> constructor argument and method. |
674 |
|
675 |
=cut |
676 |
|
677 |
# see below |
678 |
|
679 |
=item $handle->autocork ($boolean) |
680 |
|
681 |
Enables or disables the current autocork behaviour (see C<autocork> |
682 |
constructor argument). Changes will only take effect on the next write. |
683 |
|
684 |
=cut |
685 |
|
686 |
sub autocork { |
687 |
$_[0]{autocork} = $_[1]; |
688 |
} |
689 |
|
690 |
=item $handle->no_delay ($boolean) |
691 |
|
692 |
Enables or disables the C<no_delay> setting (see constructor argument of |
693 |
the same name for details). |
694 |
|
695 |
=cut |
696 |
|
697 |
sub no_delay { |
698 |
$_[0]{no_delay} = $_[1]; |
699 |
|
700 |
setsockopt $_[0]{fh}, Socket::IPPROTO_TCP (), Socket::TCP_NODELAY (), int $_[1] |
701 |
if $_[0]{fh}; |
702 |
} |
703 |
|
704 |
=item $handle->keepalive ($boolean) |
705 |
|
706 |
Enables or disables the C<keepalive> setting (see constructor argument of |
707 |
the same name for details). |
708 |
|
709 |
=cut |
710 |
|
711 |
sub keepalive { |
712 |
$_[0]{keepalive} = $_[1]; |
713 |
|
714 |
eval { |
715 |
local $SIG{__DIE__}; |
716 |
setsockopt $_[0]{fh}, Socket::SOL_SOCKET (), Socket::SO_KEEPALIVE (), int $_[1] |
717 |
if $_[0]{fh}; |
718 |
}; |
719 |
} |
720 |
|
721 |
=item $handle->oobinline ($boolean) |
722 |
|
723 |
Enables or disables the C<oobinline> setting (see constructor argument of |
724 |
the same name for details). |
725 |
|
726 |
=cut |
727 |
|
728 |
sub oobinline { |
729 |
$_[0]{oobinline} = $_[1]; |
730 |
|
731 |
eval { |
732 |
local $SIG{__DIE__}; |
733 |
setsockopt $_[0]{fh}, Socket::SOL_SOCKET (), Socket::SO_OOBINLINE (), int $_[1] |
734 |
if $_[0]{fh}; |
735 |
}; |
736 |
} |
737 |
|
738 |
=item $handle->keepalive ($boolean) |
739 |
|
740 |
Enables or disables the C<keepalive> setting (see constructor argument of |
741 |
the same name for details). |
742 |
|
743 |
=cut |
744 |
|
745 |
sub keepalive { |
746 |
$_[0]{keepalive} = $_[1]; |
747 |
|
748 |
eval { |
749 |
local $SIG{__DIE__}; |
750 |
setsockopt $_[0]{fh}, Socket::SOL_SOCKET (), Socket::SO_KEEPALIVE (), int $_[1] |
751 |
if $_[0]{fh}; |
752 |
}; |
753 |
} |
754 |
|
755 |
=item $handle->on_starttls ($cb) |
756 |
|
757 |
Replace the current C<on_starttls> callback (see the C<on_starttls> constructor argument). |
758 |
|
759 |
=cut |
760 |
|
761 |
sub on_starttls { |
762 |
$_[0]{on_starttls} = $_[1]; |
763 |
} |
764 |
|
765 |
=item $handle->on_stoptls ($cb) |
766 |
|
767 |
Replace the current C<on_stoptls> callback (see the C<on_stoptls> constructor argument). |
768 |
|
769 |
=cut |
770 |
|
771 |
sub on_stoptls { |
772 |
$_[0]{on_stoptls} = $_[1]; |
773 |
} |
774 |
|
775 |
=item $handle->rbuf_max ($max_octets) |
776 |
|
777 |
Configures the C<rbuf_max> setting (C<undef> disables it). |
778 |
|
779 |
=item $handle->wbuf_max ($max_octets) |
780 |
|
781 |
Configures the C<wbuf_max> setting (C<undef> disables it). |
782 |
|
783 |
=cut |
784 |
|
785 |
sub rbuf_max { |
786 |
$_[0]{rbuf_max} = $_[1]; |
787 |
} |
788 |
|
789 |
sub wbuf_max { |
790 |
$_[0]{wbuf_max} = $_[1]; |
791 |
} |
792 |
|
793 |
############################################################################# |
794 |
|
795 |
=item $handle->timeout ($seconds) |
796 |
|
797 |
=item $handle->rtimeout ($seconds) |
798 |
|
799 |
=item $handle->wtimeout ($seconds) |
800 |
|
801 |
Configures (or disables) the inactivity timeout. |
802 |
|
803 |
The timeout will be checked instantly, so this method might destroy the |
804 |
handle before it returns. |
805 |
|
806 |
=item $handle->timeout_reset |
807 |
|
808 |
=item $handle->rtimeout_reset |
809 |
|
810 |
=item $handle->wtimeout_reset |
811 |
|
812 |
Reset the activity timeout, as if data was received or sent. |
813 |
|
814 |
These methods are cheap to call. |
815 |
|
816 |
=cut |
817 |
|
818 |
for my $dir ("", "r", "w") { |
819 |
my $timeout = "${dir}timeout"; |
820 |
my $tw = "_${dir}tw"; |
821 |
my $on_timeout = "on_${dir}timeout"; |
822 |
my $activity = "_${dir}activity"; |
823 |
my $cb; |
824 |
|
825 |
*$on_timeout = sub { |
826 |
$_[0]{$on_timeout} = $_[1]; |
827 |
}; |
828 |
|
829 |
*$timeout = sub { |
830 |
my ($self, $new_value) = @_; |
831 |
|
832 |
$new_value >= 0 |
833 |
or Carp::croak "AnyEvent::Handle->$timeout called with negative timeout ($new_value), caught"; |
834 |
|
835 |
$self->{$timeout} = $new_value; |
836 |
delete $self->{$tw}; &$cb; |
837 |
}; |
838 |
|
839 |
*{"${dir}timeout_reset"} = sub { |
840 |
$_[0]{$activity} = AE::now; |
841 |
}; |
842 |
|
843 |
# main workhorse: |
844 |
# reset the timeout watcher, as neccessary |
845 |
# also check for time-outs |
846 |
$cb = sub { |
847 |
my ($self) = @_; |
848 |
|
849 |
if ($self->{$timeout} && $self->{fh}) { |
850 |
my $NOW = AE::now; |
851 |
|
852 |
# when would the timeout trigger? |
853 |
my $after = $self->{$activity} + $self->{$timeout} - $NOW; |
854 |
|
855 |
# now or in the past already? |
856 |
if ($after <= 0) { |
857 |
$self->{$activity} = $NOW; |
858 |
|
859 |
if ($self->{$on_timeout}) { |
860 |
$self->{$on_timeout}($self); |
861 |
} else { |
862 |
$self->_error (Errno::ETIMEDOUT); |
863 |
} |
864 |
|
865 |
# callback could have changed timeout value, optimise |
866 |
return unless $self->{$timeout}; |
867 |
|
868 |
# calculate new after |
869 |
$after = $self->{$timeout}; |
870 |
} |
871 |
|
872 |
Scalar::Util::weaken $self; |
873 |
return unless $self; # ->error could have destroyed $self |
874 |
|
875 |
$self->{$tw} ||= AE::timer $after, 0, sub { |
876 |
delete $self->{$tw}; |
877 |
$cb->($self); |
878 |
}; |
879 |
} else { |
880 |
delete $self->{$tw}; |
881 |
} |
882 |
} |
883 |
} |
884 |
|
885 |
############################################################################# |
886 |
|
887 |
=back |
888 |
|
889 |
=head2 WRITE QUEUE |
890 |
|
891 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
892 |
for reading. |
893 |
|
894 |
The write queue is very simple: you can add data to its end, and |
895 |
AnyEvent::Handle will automatically try to get rid of it for you. |
896 |
|
897 |
When data could be written and the write buffer is shorter then the low |
898 |
water mark, the C<on_drain> callback will be invoked once. |
899 |
|
900 |
=over 4 |
901 |
|
902 |
=item $handle->on_drain ($cb) |
903 |
|
904 |
Sets the C<on_drain> callback or clears it (see the description of |
905 |
C<on_drain> in the constructor). |
906 |
|
907 |
This method may invoke callbacks (and therefore the handle might be |
908 |
destroyed after it returns). |
909 |
|
910 |
=cut |
911 |
|
912 |
sub on_drain { |
913 |
my ($self, $cb) = @_; |
914 |
|
915 |
$self->{on_drain} = $cb; |
916 |
|
917 |
$cb->($self) |
918 |
if $cb && $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}); |
919 |
} |
920 |
|
921 |
=item $handle->push_write ($data) |
922 |
|
923 |
Queues the given scalar to be written. You can push as much data as |
924 |
you want (only limited by the available memory and C<wbuf_max>), as |
925 |
C<AnyEvent::Handle> buffers it independently of the kernel. |
926 |
|
927 |
This method may invoke callbacks (and therefore the handle might be |
928 |
destroyed after it returns). |
929 |
|
930 |
=cut |
931 |
|
932 |
sub _drain_wbuf { |
933 |
my ($self) = @_; |
934 |
|
935 |
if (!$self->{_ww} && length $self->{wbuf}) { |
936 |
|
937 |
Scalar::Util::weaken $self; |
938 |
|
939 |
my $cb = sub { |
940 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
941 |
|
942 |
if (defined $len) { |
943 |
substr $self->{wbuf}, 0, $len, ""; |
944 |
|
945 |
$self->{_activity} = $self->{_wactivity} = AE::now; |
946 |
|
947 |
$self->{on_drain}($self) |
948 |
if $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}) |
949 |
&& $self->{on_drain}; |
950 |
|
951 |
delete $self->{_ww} unless length $self->{wbuf}; |
952 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
953 |
$self->_error ($!, 1); |
954 |
} |
955 |
}; |
956 |
|
957 |
# try to write data immediately |
958 |
$cb->() unless $self->{autocork}; |
959 |
|
960 |
# if still data left in wbuf, we need to poll |
961 |
$self->{_ww} = AE::io $self->{fh}, 1, $cb |
962 |
if length $self->{wbuf}; |
963 |
|
964 |
if ( |
965 |
defined $self->{wbuf_max} |
966 |
&& $self->{wbuf_max} < length $self->{wbuf} |
967 |
) { |
968 |
$self->_error (Errno::ENOSPC, 1), return; |
969 |
} |
970 |
}; |
971 |
} |
972 |
|
973 |
our %WH; |
974 |
|
975 |
# deprecated |
976 |
sub register_write_type($$) { |
977 |
$WH{$_[0]} = $_[1]; |
978 |
} |
979 |
|
980 |
sub push_write { |
981 |
my $self = shift; |
982 |
|
983 |
if (@_ > 1) { |
984 |
my $type = shift; |
985 |
|
986 |
@_ = ($WH{$type} ||= _load_func "$type\::anyevent_write_type" |
987 |
or Carp::croak "unsupported/unloadable type '$type' passed to AnyEvent::Handle::push_write") |
988 |
->($self, @_); |
989 |
} |
990 |
|
991 |
# we downgrade here to avoid hard-to-track-down bugs, |
992 |
# and diagnose the problem earlier and better. |
993 |
|
994 |
if ($self->{tls}) { |
995 |
utf8::downgrade $self->{_tls_wbuf} .= $_[0]; |
996 |
&_dotls ($self) if $self->{fh}; |
997 |
} else { |
998 |
utf8::downgrade $self->{wbuf} .= $_[0]; |
999 |
$self->_drain_wbuf if $self->{fh}; |
1000 |
} |
1001 |
} |
1002 |
|
1003 |
=item $handle->push_write (type => @args) |
1004 |
|
1005 |
Instead of formatting your data yourself, you can also let this module |
1006 |
do the job by specifying a type and type-specific arguments. You |
1007 |
can also specify the (fully qualified) name of a package, in which |
1008 |
case AnyEvent tries to load the package and then expects to find the |
1009 |
C<anyevent_write_type> function inside (see "custom write types", below). |
1010 |
|
1011 |
Predefined types are (if you have ideas for additional types, feel free to |
1012 |
drop by and tell us): |
1013 |
|
1014 |
=over 4 |
1015 |
|
1016 |
=item netstring => $string |
1017 |
|
1018 |
Formats the given value as netstring |
1019 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
1020 |
|
1021 |
=cut |
1022 |
|
1023 |
register_write_type netstring => sub { |
1024 |
my ($self, $string) = @_; |
1025 |
|
1026 |
(length $string) . ":$string," |
1027 |
}; |
1028 |
|
1029 |
=item packstring => $format, $data |
1030 |
|
1031 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1032 |
uses the same format as a Perl C<pack> format, but must specify a single |
1033 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1034 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1035 |
|
1036 |
=cut |
1037 |
|
1038 |
register_write_type packstring => sub { |
1039 |
my ($self, $format, $string) = @_; |
1040 |
|
1041 |
pack "$format/a*", $string |
1042 |
}; |
1043 |
|
1044 |
=item json => $array_or_hashref |
1045 |
|
1046 |
Encodes the given hash or array reference into a JSON object. Unless you |
1047 |
provide your own JSON object, this means it will be encoded to JSON text |
1048 |
in UTF-8. |
1049 |
|
1050 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
1051 |
one end of a handle and read them at the other end without using any |
1052 |
additional framing. |
1053 |
|
1054 |
The generated JSON text is guaranteed not to contain any newlines: While |
1055 |
this module doesn't need delimiters after or between JSON texts to be |
1056 |
able to read them, many other languages depend on that. |
1057 |
|
1058 |
A simple RPC protocol that interoperates easily with others is to send |
1059 |
JSON arrays (or objects, although arrays are usually the better choice as |
1060 |
they mimic how function argument passing works) and a newline after each |
1061 |
JSON text: |
1062 |
|
1063 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
1064 |
$handle->push_write ("\012"); |
1065 |
|
1066 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
1067 |
rely on the fact that the newline will be skipped as leading whitespace: |
1068 |
|
1069 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
1070 |
|
1071 |
Other languages could read single lines terminated by a newline and pass |
1072 |
this line into their JSON decoder of choice. |
1073 |
|
1074 |
=cut |
1075 |
|
1076 |
sub json_coder() { |
1077 |
eval { require JSON::XS; JSON::XS->new->utf8 } |
1078 |
|| do { require JSON; JSON->new->utf8 } |
1079 |
} |
1080 |
|
1081 |
register_write_type json => sub { |
1082 |
my ($self, $ref) = @_; |
1083 |
|
1084 |
my $json = $self->{json} ||= json_coder; |
1085 |
|
1086 |
$json->encode ($ref) |
1087 |
}; |
1088 |
|
1089 |
=item storable => $reference |
1090 |
|
1091 |
Freezes the given reference using L<Storable> and writes it to the |
1092 |
handle. Uses the C<nfreeze> format. |
1093 |
|
1094 |
=cut |
1095 |
|
1096 |
register_write_type storable => sub { |
1097 |
my ($self, $ref) = @_; |
1098 |
|
1099 |
require Storable unless $Storable::VERSION; |
1100 |
|
1101 |
pack "w/a*", Storable::nfreeze ($ref) |
1102 |
}; |
1103 |
|
1104 |
=back |
1105 |
|
1106 |
=item $handle->push_shutdown |
1107 |
|
1108 |
Sometimes you know you want to close the socket after writing your data |
1109 |
before it was actually written. One way to do that is to replace your |
1110 |
C<on_drain> handler by a callback that shuts down the socket (and set |
1111 |
C<low_water_mark> to C<0>). This method is a shorthand for just that, and |
1112 |
replaces the C<on_drain> callback with: |
1113 |
|
1114 |
sub { shutdown $_[0]{fh}, 1 } |
1115 |
|
1116 |
This simply shuts down the write side and signals an EOF condition to the |
1117 |
the peer. |
1118 |
|
1119 |
You can rely on the normal read queue and C<on_eof> handling |
1120 |
afterwards. This is the cleanest way to close a connection. |
1121 |
|
1122 |
This method may invoke callbacks (and therefore the handle might be |
1123 |
destroyed after it returns). |
1124 |
|
1125 |
=cut |
1126 |
|
1127 |
sub push_shutdown { |
1128 |
my ($self) = @_; |
1129 |
|
1130 |
delete $self->{low_water_mark}; |
1131 |
$self->on_drain (sub { shutdown $_[0]{fh}, 1 }); |
1132 |
} |
1133 |
|
1134 |
=item custom write types - Package::anyevent_write_type $handle, @args |
1135 |
|
1136 |
Instead of one of the predefined types, you can also specify the name of |
1137 |
a package. AnyEvent will try to load the package and then expects to find |
1138 |
a function named C<anyevent_write_type> inside. If it isn't found, it |
1139 |
progressively tries to load the parent package until it either finds the |
1140 |
function (good) or runs out of packages (bad). |
1141 |
|
1142 |
Whenever the given C<type> is used, C<push_write> will the function with |
1143 |
the handle object and the remaining arguments. |
1144 |
|
1145 |
The function is supposed to return a single octet string that will be |
1146 |
appended to the write buffer, so you can mentally treat this function as a |
1147 |
"arguments to on-the-wire-format" converter. |
1148 |
|
1149 |
Example: implement a custom write type C<join> that joins the remaining |
1150 |
arguments using the first one. |
1151 |
|
1152 |
$handle->push_write (My::Type => " ", 1,2,3); |
1153 |
|
1154 |
# uses the following package, which can be defined in the "My::Type" or in |
1155 |
# the "My" modules to be auto-loaded, or just about anywhere when the |
1156 |
# My::Type::anyevent_write_type is defined before invoking it. |
1157 |
|
1158 |
package My::Type; |
1159 |
|
1160 |
sub anyevent_write_type { |
1161 |
my ($handle, $delim, @args) = @_; |
1162 |
|
1163 |
join $delim, @args |
1164 |
} |
1165 |
|
1166 |
=cut |
1167 |
|
1168 |
############################################################################# |
1169 |
|
1170 |
=back |
1171 |
|
1172 |
=head2 READ QUEUE |
1173 |
|
1174 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
1175 |
for reading. |
1176 |
|
1177 |
The read queue is more complex than the write queue. It can be used in two |
1178 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
1179 |
a queue. |
1180 |
|
1181 |
In the simple case, you just install an C<on_read> callback and whenever |
1182 |
new data arrives, it will be called. You can then remove some data (if |
1183 |
enough is there) from the read buffer (C<< $handle->rbuf >>). Or you can |
1184 |
leave the data there if you want to accumulate more (e.g. when only a |
1185 |
partial message has been received so far), or change the read queue with |
1186 |
e.g. C<push_read>. |
1187 |
|
1188 |
In the more complex case, you want to queue multiple callbacks. In this |
1189 |
case, AnyEvent::Handle will call the first queued callback each time new |
1190 |
data arrives (also the first time it is queued) and remove it when it has |
1191 |
done its job (see C<push_read>, below). |
1192 |
|
1193 |
This way you can, for example, push three line-reads, followed by reading |
1194 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
1195 |
|
1196 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
1197 |
the specified number of bytes which give an XML datagram. |
1198 |
|
1199 |
# in the default state, expect some header bytes |
1200 |
$handle->on_read (sub { |
1201 |
# some data is here, now queue the length-header-read (4 octets) |
1202 |
shift->unshift_read (chunk => 4, sub { |
1203 |
# header arrived, decode |
1204 |
my $len = unpack "N", $_[1]; |
1205 |
|
1206 |
# now read the payload |
1207 |
shift->unshift_read (chunk => $len, sub { |
1208 |
my $xml = $_[1]; |
1209 |
# handle xml |
1210 |
}); |
1211 |
}); |
1212 |
}); |
1213 |
|
1214 |
Example 2: Implement a client for a protocol that replies either with "OK" |
1215 |
and another line or "ERROR" for the first request that is sent, and 64 |
1216 |
bytes for the second request. Due to the availability of a queue, we can |
1217 |
just pipeline sending both requests and manipulate the queue as necessary |
1218 |
in the callbacks. |
1219 |
|
1220 |
When the first callback is called and sees an "OK" response, it will |
1221 |
C<unshift> another line-read. This line-read will be queued I<before> the |
1222 |
64-byte chunk callback. |
1223 |
|
1224 |
# request one, returns either "OK + extra line" or "ERROR" |
1225 |
$handle->push_write ("request 1\015\012"); |
1226 |
|
1227 |
# we expect "ERROR" or "OK" as response, so push a line read |
1228 |
$handle->push_read (line => sub { |
1229 |
# if we got an "OK", we have to _prepend_ another line, |
1230 |
# so it will be read before the second request reads its 64 bytes |
1231 |
# which are already in the queue when this callback is called |
1232 |
# we don't do this in case we got an error |
1233 |
if ($_[1] eq "OK") { |
1234 |
$_[0]->unshift_read (line => sub { |
1235 |
my $response = $_[1]; |
1236 |
... |
1237 |
}); |
1238 |
} |
1239 |
}); |
1240 |
|
1241 |
# request two, simply returns 64 octets |
1242 |
$handle->push_write ("request 2\015\012"); |
1243 |
|
1244 |
# simply read 64 bytes, always |
1245 |
$handle->push_read (chunk => 64, sub { |
1246 |
my $response = $_[1]; |
1247 |
... |
1248 |
}); |
1249 |
|
1250 |
=over 4 |
1251 |
|
1252 |
=cut |
1253 |
|
1254 |
sub _drain_rbuf { |
1255 |
my ($self) = @_; |
1256 |
|
1257 |
# avoid recursion |
1258 |
return if $self->{_skip_drain_rbuf}; |
1259 |
local $self->{_skip_drain_rbuf} = 1; |
1260 |
|
1261 |
while () { |
1262 |
# we need to use a separate tls read buffer, as we must not receive data while |
1263 |
# we are draining the buffer, and this can only happen with TLS. |
1264 |
$self->{rbuf} .= delete $self->{_tls_rbuf} |
1265 |
if exists $self->{_tls_rbuf}; |
1266 |
|
1267 |
my $len = length $self->{rbuf}; |
1268 |
|
1269 |
if (my $cb = shift @{ $self->{_queue} }) { |
1270 |
unless ($cb->($self)) { |
1271 |
# no progress can be made |
1272 |
# (not enough data and no data forthcoming) |
1273 |
$self->_error (Errno::EPIPE, 1), return |
1274 |
if $self->{_eof}; |
1275 |
|
1276 |
unshift @{ $self->{_queue} }, $cb; |
1277 |
last; |
1278 |
} |
1279 |
} elsif ($self->{on_read}) { |
1280 |
last unless $len; |
1281 |
|
1282 |
$self->{on_read}($self); |
1283 |
|
1284 |
if ( |
1285 |
$len == length $self->{rbuf} # if no data has been consumed |
1286 |
&& !@{ $self->{_queue} } # and the queue is still empty |
1287 |
&& $self->{on_read} # but we still have on_read |
1288 |
) { |
1289 |
# no further data will arrive |
1290 |
# so no progress can be made |
1291 |
$self->_error (Errno::EPIPE, 1), return |
1292 |
if $self->{_eof}; |
1293 |
|
1294 |
last; # more data might arrive |
1295 |
} |
1296 |
} else { |
1297 |
# read side becomes idle |
1298 |
delete $self->{_rw} unless $self->{tls}; |
1299 |
last; |
1300 |
} |
1301 |
} |
1302 |
|
1303 |
if ($self->{_eof}) { |
1304 |
$self->{on_eof} |
1305 |
? $self->{on_eof}($self) |
1306 |
: $self->_error (0, 1, "Unexpected end-of-file"); |
1307 |
|
1308 |
return; |
1309 |
} |
1310 |
|
1311 |
if ( |
1312 |
defined $self->{rbuf_max} |
1313 |
&& $self->{rbuf_max} < length $self->{rbuf} |
1314 |
) { |
1315 |
$self->_error (Errno::ENOSPC, 1), return; |
1316 |
} |
1317 |
|
1318 |
# may need to restart read watcher |
1319 |
unless ($self->{_rw}) { |
1320 |
$self->start_read |
1321 |
if $self->{on_read} || @{ $self->{_queue} }; |
1322 |
} |
1323 |
} |
1324 |
|
1325 |
=item $handle->on_read ($cb) |
1326 |
|
1327 |
This replaces the currently set C<on_read> callback, or clears it (when |
1328 |
the new callback is C<undef>). See the description of C<on_read> in the |
1329 |
constructor. |
1330 |
|
1331 |
This method may invoke callbacks (and therefore the handle might be |
1332 |
destroyed after it returns). |
1333 |
|
1334 |
=cut |
1335 |
|
1336 |
sub on_read { |
1337 |
my ($self, $cb) = @_; |
1338 |
|
1339 |
$self->{on_read} = $cb; |
1340 |
$self->_drain_rbuf if $cb; |
1341 |
} |
1342 |
|
1343 |
=item $handle->rbuf |
1344 |
|
1345 |
Returns the read buffer (as a modifiable lvalue). You can also access the |
1346 |
read buffer directly as the C<< ->{rbuf} >> member, if you want (this is |
1347 |
much faster, and no less clean). |
1348 |
|
1349 |
The only operation allowed on the read buffer (apart from looking at it) |
1350 |
is removing data from its beginning. Otherwise modifying or appending to |
1351 |
it is not allowed and will lead to hard-to-track-down bugs. |
1352 |
|
1353 |
NOTE: The read buffer should only be used or modified in the C<on_read> |
1354 |
callback or when C<push_read> or C<unshift_read> are used with a single |
1355 |
callback (i.e. untyped). Typed C<push_read> and C<unshift_read> methods |
1356 |
will manage the read buffer on their own. |
1357 |
|
1358 |
=cut |
1359 |
|
1360 |
sub rbuf : lvalue { |
1361 |
$_[0]{rbuf} |
1362 |
} |
1363 |
|
1364 |
=item $handle->push_read ($cb) |
1365 |
|
1366 |
=item $handle->unshift_read ($cb) |
1367 |
|
1368 |
Append the given callback to the end of the queue (C<push_read>) or |
1369 |
prepend it (C<unshift_read>). |
1370 |
|
1371 |
The callback is called each time some additional read data arrives. |
1372 |
|
1373 |
It must check whether enough data is in the read buffer already. |
1374 |
|
1375 |
If not enough data is available, it must return the empty list or a false |
1376 |
value, in which case it will be called repeatedly until enough data is |
1377 |
available (or an error condition is detected). |
1378 |
|
1379 |
If enough data was available, then the callback must remove all data it is |
1380 |
interested in (which can be none at all) and return a true value. After returning |
1381 |
true, it will be removed from the queue. |
1382 |
|
1383 |
These methods may invoke callbacks (and therefore the handle might be |
1384 |
destroyed after it returns). |
1385 |
|
1386 |
=cut |
1387 |
|
1388 |
our %RH; |
1389 |
|
1390 |
sub register_read_type($$) { |
1391 |
$RH{$_[0]} = $_[1]; |
1392 |
} |
1393 |
|
1394 |
sub push_read { |
1395 |
my $self = shift; |
1396 |
my $cb = pop; |
1397 |
|
1398 |
if (@_) { |
1399 |
my $type = shift; |
1400 |
|
1401 |
$cb = ($RH{$type} ||= _load_func "$type\::anyevent_read_type" |
1402 |
or Carp::croak "unsupported/unloadable type '$type' passed to AnyEvent::Handle::push_read") |
1403 |
->($self, $cb, @_); |
1404 |
} |
1405 |
|
1406 |
push @{ $self->{_queue} }, $cb; |
1407 |
$self->_drain_rbuf; |
1408 |
} |
1409 |
|
1410 |
sub unshift_read { |
1411 |
my $self = shift; |
1412 |
my $cb = pop; |
1413 |
|
1414 |
if (@_) { |
1415 |
my $type = shift; |
1416 |
|
1417 |
$cb = ($RH{$type} ||= _load_func "$type\::anyevent_read_type" |
1418 |
or Carp::croak "unsupported/unloadable type '$type' passed to AnyEvent::Handle::unshift_read") |
1419 |
->($self, $cb, @_); |
1420 |
} |
1421 |
|
1422 |
unshift @{ $self->{_queue} }, $cb; |
1423 |
$self->_drain_rbuf; |
1424 |
} |
1425 |
|
1426 |
=item $handle->push_read (type => @args, $cb) |
1427 |
|
1428 |
=item $handle->unshift_read (type => @args, $cb) |
1429 |
|
1430 |
Instead of providing a callback that parses the data itself you can chose |
1431 |
between a number of predefined parsing formats, for chunks of data, lines |
1432 |
etc. You can also specify the (fully qualified) name of a package, in |
1433 |
which case AnyEvent tries to load the package and then expects to find the |
1434 |
C<anyevent_read_type> function inside (see "custom read types", below). |
1435 |
|
1436 |
Predefined types are (if you have ideas for additional types, feel free to |
1437 |
drop by and tell us): |
1438 |
|
1439 |
=over 4 |
1440 |
|
1441 |
=item chunk => $octets, $cb->($handle, $data) |
1442 |
|
1443 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
1444 |
data read to the callback. The callback will never be called with less |
1445 |
data. |
1446 |
|
1447 |
Example: read 2 bytes. |
1448 |
|
1449 |
$handle->push_read (chunk => 2, sub { |
1450 |
say "yay " . unpack "H*", $_[1]; |
1451 |
}); |
1452 |
|
1453 |
=cut |
1454 |
|
1455 |
register_read_type chunk => sub { |
1456 |
my ($self, $cb, $len) = @_; |
1457 |
|
1458 |
sub { |
1459 |
$len <= length $_[0]{rbuf} or return; |
1460 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
1461 |
1 |
1462 |
} |
1463 |
}; |
1464 |
|
1465 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
1466 |
|
1467 |
The callback will be called only once a full line (including the end of |
1468 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
1469 |
marker) will be passed to the callback as second argument (C<$line>), and |
1470 |
the end of line marker as the third argument (C<$eol>). |
1471 |
|
1472 |
The end of line marker, C<$eol>, can be either a string, in which case it |
1473 |
will be interpreted as a fixed record end marker, or it can be a regex |
1474 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
1475 |
regular expression. |
1476 |
|
1477 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
1478 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
1479 |
protocols). |
1480 |
|
1481 |
Partial lines at the end of the stream will never be returned, as they are |
1482 |
not marked by the end of line marker. |
1483 |
|
1484 |
=cut |
1485 |
|
1486 |
register_read_type line => sub { |
1487 |
my ($self, $cb, $eol) = @_; |
1488 |
|
1489 |
if (@_ < 3) { |
1490 |
# this is more than twice as fast as the generic code below |
1491 |
sub { |
1492 |
$_[0]{rbuf} =~ s/^([^\015\012]*)(\015?\012)// or return; |
1493 |
|
1494 |
$cb->($_[0], "$1", "$2"); |
1495 |
1 |
1496 |
} |
1497 |
} else { |
1498 |
$eol = quotemeta $eol unless ref $eol; |
1499 |
$eol = qr|^(.*?)($eol)|s; |
1500 |
|
1501 |
sub { |
1502 |
$_[0]{rbuf} =~ s/$eol// or return; |
1503 |
|
1504 |
$cb->($_[0], "$1", "$2"); |
1505 |
1 |
1506 |
} |
1507 |
} |
1508 |
}; |
1509 |
|
1510 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
1511 |
|
1512 |
Makes a regex match against the regex object C<$accept> and returns |
1513 |
everything up to and including the match. |
1514 |
|
1515 |
Example: read a single line terminated by '\n'. |
1516 |
|
1517 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
1518 |
|
1519 |
If C<$reject> is given and not undef, then it determines when the data is |
1520 |
to be rejected: it is matched against the data when the C<$accept> regex |
1521 |
does not match and generates an C<EBADMSG> error when it matches. This is |
1522 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
1523 |
receive buffer overflow). |
1524 |
|
1525 |
Example: expect a single decimal number followed by whitespace, reject |
1526 |
anything else (not the use of an anchor). |
1527 |
|
1528 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
1529 |
|
1530 |
If C<$skip> is given and not C<undef>, then it will be matched against |
1531 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
1532 |
and everything preceding and including the match will be accepted |
1533 |
unconditionally. This is useful to skip large amounts of data that you |
1534 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
1535 |
have to start matching from the beginning. This is purely an optimisation |
1536 |
and is usually worth it only when you expect more than a few kilobytes. |
1537 |
|
1538 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
1539 |
expect the header to be very large (it isn't in practice, but...), we use |
1540 |
a skip regex to skip initial portions. The skip regex is tricky in that |
1541 |
it only accepts something not ending in either \015 or \012, as these are |
1542 |
required for the accept regex. |
1543 |
|
1544 |
$handle->push_read (regex => |
1545 |
qr<\015\012\015\012>, |
1546 |
undef, # no reject |
1547 |
qr<^.*[^\015\012]>, |
1548 |
sub { ... }); |
1549 |
|
1550 |
=cut |
1551 |
|
1552 |
register_read_type regex => sub { |
1553 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
1554 |
|
1555 |
my $data; |
1556 |
my $rbuf = \$self->{rbuf}; |
1557 |
|
1558 |
sub { |
1559 |
# accept |
1560 |
if ($$rbuf =~ $accept) { |
1561 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1562 |
$cb->($_[0], $data); |
1563 |
return 1; |
1564 |
} |
1565 |
|
1566 |
# reject |
1567 |
if ($reject && $$rbuf =~ $reject) { |
1568 |
$_[0]->_error (Errno::EBADMSG); |
1569 |
} |
1570 |
|
1571 |
# skip |
1572 |
if ($skip && $$rbuf =~ $skip) { |
1573 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1574 |
} |
1575 |
|
1576 |
() |
1577 |
} |
1578 |
}; |
1579 |
|
1580 |
=item netstring => $cb->($handle, $string) |
1581 |
|
1582 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
1583 |
|
1584 |
Throws an error with C<$!> set to EBADMSG on format violations. |
1585 |
|
1586 |
=cut |
1587 |
|
1588 |
register_read_type netstring => sub { |
1589 |
my ($self, $cb) = @_; |
1590 |
|
1591 |
sub { |
1592 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
1593 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
1594 |
$_[0]->_error (Errno::EBADMSG); |
1595 |
} |
1596 |
return; |
1597 |
} |
1598 |
|
1599 |
my $len = $1; |
1600 |
|
1601 |
$_[0]->unshift_read (chunk => $len, sub { |
1602 |
my $string = $_[1]; |
1603 |
$_[0]->unshift_read (chunk => 1, sub { |
1604 |
if ($_[1] eq ",") { |
1605 |
$cb->($_[0], $string); |
1606 |
} else { |
1607 |
$_[0]->_error (Errno::EBADMSG); |
1608 |
} |
1609 |
}); |
1610 |
}); |
1611 |
|
1612 |
1 |
1613 |
} |
1614 |
}; |
1615 |
|
1616 |
=item packstring => $format, $cb->($handle, $string) |
1617 |
|
1618 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1619 |
uses the same format as a Perl C<pack> format, but must specify a single |
1620 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1621 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1622 |
|
1623 |
For example, DNS over TCP uses a prefix of C<n> (2 octet network order), |
1624 |
EPP uses a prefix of C<N> (4 octtes). |
1625 |
|
1626 |
Example: read a block of data prefixed by its length in BER-encoded |
1627 |
format (very efficient). |
1628 |
|
1629 |
$handle->push_read (packstring => "w", sub { |
1630 |
my ($handle, $data) = @_; |
1631 |
}); |
1632 |
|
1633 |
=cut |
1634 |
|
1635 |
register_read_type packstring => sub { |
1636 |
my ($self, $cb, $format) = @_; |
1637 |
|
1638 |
sub { |
1639 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1640 |
defined (my $len = eval { unpack $format, $_[0]{rbuf} }) |
1641 |
or return; |
1642 |
|
1643 |
$format = length pack $format, $len; |
1644 |
|
1645 |
# bypass unshift if we already have the remaining chunk |
1646 |
if ($format + $len <= length $_[0]{rbuf}) { |
1647 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1648 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1649 |
$cb->($_[0], $data); |
1650 |
} else { |
1651 |
# remove prefix |
1652 |
substr $_[0]{rbuf}, 0, $format, ""; |
1653 |
|
1654 |
# read remaining chunk |
1655 |
$_[0]->unshift_read (chunk => $len, $cb); |
1656 |
} |
1657 |
|
1658 |
1 |
1659 |
} |
1660 |
}; |
1661 |
|
1662 |
=item json => $cb->($handle, $hash_or_arrayref) |
1663 |
|
1664 |
Reads a JSON object or array, decodes it and passes it to the |
1665 |
callback. When a parse error occurs, an C<EBADMSG> error will be raised. |
1666 |
|
1667 |
If a C<json> object was passed to the constructor, then that will be used |
1668 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1669 |
|
1670 |
This read type uses the incremental parser available with JSON version |
1671 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1672 |
dependency on your own: this module will load the JSON module, but |
1673 |
AnyEvent does not depend on it itself. |
1674 |
|
1675 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1676 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1677 |
the C<json> write type description, above, for an actual example. |
1678 |
|
1679 |
=cut |
1680 |
|
1681 |
register_read_type json => sub { |
1682 |
my ($self, $cb) = @_; |
1683 |
|
1684 |
my $json = $self->{json} ||= json_coder; |
1685 |
|
1686 |
my $data; |
1687 |
my $rbuf = \$self->{rbuf}; |
1688 |
|
1689 |
sub { |
1690 |
my $ref = eval { $json->incr_parse ($_[0]{rbuf}) }; |
1691 |
|
1692 |
if ($ref) { |
1693 |
$_[0]{rbuf} = $json->incr_text; |
1694 |
$json->incr_text = ""; |
1695 |
$cb->($_[0], $ref); |
1696 |
|
1697 |
1 |
1698 |
} elsif ($@) { |
1699 |
# error case |
1700 |
$json->incr_skip; |
1701 |
|
1702 |
$_[0]{rbuf} = $json->incr_text; |
1703 |
$json->incr_text = ""; |
1704 |
|
1705 |
$_[0]->_error (Errno::EBADMSG); |
1706 |
|
1707 |
() |
1708 |
} else { |
1709 |
$_[0]{rbuf} = ""; |
1710 |
|
1711 |
() |
1712 |
} |
1713 |
} |
1714 |
}; |
1715 |
|
1716 |
=item storable => $cb->($handle, $ref) |
1717 |
|
1718 |
Deserialises a L<Storable> frozen representation as written by the |
1719 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1720 |
data). |
1721 |
|
1722 |
Raises C<EBADMSG> error if the data could not be decoded. |
1723 |
|
1724 |
=cut |
1725 |
|
1726 |
register_read_type storable => sub { |
1727 |
my ($self, $cb) = @_; |
1728 |
|
1729 |
require Storable unless $Storable::VERSION; |
1730 |
|
1731 |
sub { |
1732 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1733 |
defined (my $len = eval { unpack "w", $_[0]{rbuf} }) |
1734 |
or return; |
1735 |
|
1736 |
my $format = length pack "w", $len; |
1737 |
|
1738 |
# bypass unshift if we already have the remaining chunk |
1739 |
if ($format + $len <= length $_[0]{rbuf}) { |
1740 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1741 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1742 |
|
1743 |
eval { $cb->($_[0], Storable::thaw ($data)); 1 } |
1744 |
or return $_[0]->_error (Errno::EBADMSG); |
1745 |
} else { |
1746 |
# remove prefix |
1747 |
substr $_[0]{rbuf}, 0, $format, ""; |
1748 |
|
1749 |
# read remaining chunk |
1750 |
$_[0]->unshift_read (chunk => $len, sub { |
1751 |
eval { $cb->($_[0], Storable::thaw ($_[1])); 1 } |
1752 |
or $_[0]->_error (Errno::EBADMSG); |
1753 |
}); |
1754 |
} |
1755 |
|
1756 |
1 |
1757 |
} |
1758 |
}; |
1759 |
|
1760 |
=item tls_detect => $cb->($handle, $detect, $major, $minor) |
1761 |
|
1762 |
Checks the input stream for a valid SSL or TLS handshake TLSPaintext |
1763 |
record without consuming anything. Only SSL version 3 or higher |
1764 |
is handled, up to the fictituous protocol 4.x (but both SSL3+ and |
1765 |
SSL2-compatible framing is supported). |
1766 |
|
1767 |
If it detects that the input data is likely TLS, it calls the callback |
1768 |
with a true value for C<$detect> and the (on-wire) TLS version as second |
1769 |
and third argument (C<$major> is C<3>, and C<$minor> is 0..3 for SSL |
1770 |
3.0, TLS 1.0, 1.1 and 1.2, respectively). If it detects the input to |
1771 |
be definitely not TLS, it calls the callback with a false value for |
1772 |
C<$detect>. |
1773 |
|
1774 |
The callback could use this information to decide whether or not to start |
1775 |
TLS negotiation. |
1776 |
|
1777 |
In all cases the data read so far is passed to the following read |
1778 |
handlers. |
1779 |
|
1780 |
Usually you want to use the C<tls_autostart> read type instead. |
1781 |
|
1782 |
If you want to design a protocol that works in the presence of TLS |
1783 |
dtection, make sure that any non-TLS data doesn't start with the octet 22 |
1784 |
(ASCII SYN, 16 hex) or 128-255 (i.e. highest bit set). The checks this |
1785 |
read type does are a bit more strict, but might losen in the future to |
1786 |
accomodate protocol changes. |
1787 |
|
1788 |
This read type does not rely on L<AnyEvent::TLS> (and thus, not on |
1789 |
L<Net::SSLeay>). |
1790 |
|
1791 |
=item tls_autostart => $tls[, $tls_ctx] |
1792 |
|
1793 |
Tries to detect a valid SSL or TLS handshake. If one is detected, it tries |
1794 |
to start tls by calling C<starttls> with the given arguments. |
1795 |
|
1796 |
In practise, C<$tls> must be C<accept>, or a Net::SSLeay context that has |
1797 |
been configured to accept, as servers do not normally send a handshake on |
1798 |
their own and ths cannot be detected in this way. |
1799 |
|
1800 |
See C<tls_detect> above for more details. |
1801 |
|
1802 |
Example: give the client a chance to start TLS before accepting a text |
1803 |
line. |
1804 |
|
1805 |
$hdl->push_read (tls_detect => "accept"); |
1806 |
$hdl->push_read (line => sub { |
1807 |
print "received ", ($_[0]{tls} ? "encrypted" : "cleartext"), " <$_[1]>\n"; |
1808 |
}); |
1809 |
|
1810 |
=cut |
1811 |
|
1812 |
register_read_type tls_detect => sub { |
1813 |
my ($self, $cb) = @_; |
1814 |
|
1815 |
sub { |
1816 |
# this regex matches a full or partial tls record |
1817 |
if ( |
1818 |
# ssl3+: type(22=handshake) major(=3) minor(any) length_hi |
1819 |
$self->{rbuf} =~ /^(?:\z| \x16 (\z| [\x03\x04] (?:\z| . (?:\z| [\x00-\x40] ))))/xs |
1820 |
# ssl2 comapatible: len_hi len_lo type(1) major minor dummy(forlength) |
1821 |
or $self->{rbuf} =~ /^(?:\z| [\x80-\xff] (?:\z| . (?:\z| \x01 (\z| [\x03\x04] (?:\z| . (?:\z| . ))))))/xs |
1822 |
) { |
1823 |
return if 3 != length $1; # partial match, can't decide yet |
1824 |
|
1825 |
# full match, valid TLS record |
1826 |
my ($major, $minor) = unpack "CC", $1; |
1827 |
$cb->($self, "accept", $major + $minor * 0.1); |
1828 |
} else { |
1829 |
# mismatch == guaranteed not TLS |
1830 |
$cb->($self, undef); |
1831 |
} |
1832 |
|
1833 |
1 |
1834 |
} |
1835 |
}; |
1836 |
|
1837 |
register_read_type tls_autostart => sub { |
1838 |
my ($self, @tls) = @_; |
1839 |
|
1840 |
$RH{tls_detect}($self, sub { |
1841 |
return unless $_[1]; |
1842 |
$_[0]->starttls (@tls); |
1843 |
}) |
1844 |
}; |
1845 |
|
1846 |
=back |
1847 |
|
1848 |
=item custom read types - Package::anyevent_read_type $handle, $cb, @args |
1849 |
|
1850 |
Instead of one of the predefined types, you can also specify the name |
1851 |
of a package. AnyEvent will try to load the package and then expects to |
1852 |
find a function named C<anyevent_read_type> inside. If it isn't found, it |
1853 |
progressively tries to load the parent package until it either finds the |
1854 |
function (good) or runs out of packages (bad). |
1855 |
|
1856 |
Whenever this type is used, C<push_read> will invoke the function with the |
1857 |
handle object, the original callback and the remaining arguments. |
1858 |
|
1859 |
The function is supposed to return a callback (usually a closure) that |
1860 |
works as a plain read callback (see C<< ->push_read ($cb) >>), so you can |
1861 |
mentally treat the function as a "configurable read type to read callback" |
1862 |
converter. |
1863 |
|
1864 |
It should invoke the original callback when it is done reading (remember |
1865 |
to pass C<$handle> as first argument as all other callbacks do that, |
1866 |
although there is no strict requirement on this). |
1867 |
|
1868 |
For examples, see the source of this module (F<perldoc -m |
1869 |
AnyEvent::Handle>, search for C<register_read_type>)). |
1870 |
|
1871 |
=item $handle->stop_read |
1872 |
|
1873 |
=item $handle->start_read |
1874 |
|
1875 |
In rare cases you actually do not want to read anything from the |
1876 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1877 |
any queued callbacks will be executed then. To start reading again, call |
1878 |
C<start_read>. |
1879 |
|
1880 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1881 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1882 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1883 |
there are any read requests in the queue. |
1884 |
|
1885 |
In older versions of this module (<= 5.3), these methods had no effect, |
1886 |
as TLS does not support half-duplex connections. In current versions they |
1887 |
work as expected, as this behaviour is required to avoid certain resource |
1888 |
attacks, where the program would be forced to read (and buffer) arbitrary |
1889 |
amounts of data before being able to send some data. The drawback is that |
1890 |
some readings of the the SSL/TLS specifications basically require this |
1891 |
attack to be working, as SSL/TLS implementations might stall sending data |
1892 |
during a rehandshake. |
1893 |
|
1894 |
As a guideline, during the initial handshake, you should not stop reading, |
1895 |
and as a client, it might cause problems, depending on your application. |
1896 |
|
1897 |
=cut |
1898 |
|
1899 |
sub stop_read { |
1900 |
my ($self) = @_; |
1901 |
|
1902 |
delete $self->{_rw}; |
1903 |
} |
1904 |
|
1905 |
sub start_read { |
1906 |
my ($self) = @_; |
1907 |
|
1908 |
unless ($self->{_rw} || $self->{_eof} || !$self->{fh}) { |
1909 |
Scalar::Util::weaken $self; |
1910 |
|
1911 |
$self->{_rw} = AE::io $self->{fh}, 0, sub { |
1912 |
my $rbuf = \($self->{tls} ? my $buf : $self->{rbuf}); |
1913 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size}, length $$rbuf; |
1914 |
|
1915 |
if ($len > 0) { |
1916 |
$self->{_activity} = $self->{_ractivity} = AE::now; |
1917 |
|
1918 |
if ($self->{tls}) { |
1919 |
Net::SSLeay::BIO_write ($self->{_rbio}, $$rbuf); |
1920 |
|
1921 |
&_dotls ($self); |
1922 |
} else { |
1923 |
$self->_drain_rbuf; |
1924 |
} |
1925 |
|
1926 |
if ($len == $self->{read_size}) { |
1927 |
$self->{read_size} *= 2; |
1928 |
$self->{read_size} = $self->{max_read_size} || MAX_READ_SIZE |
1929 |
if $self->{read_size} > ($self->{max_read_size} || MAX_READ_SIZE); |
1930 |
} |
1931 |
|
1932 |
} elsif (defined $len) { |
1933 |
delete $self->{_rw}; |
1934 |
$self->{_eof} = 1; |
1935 |
$self->_drain_rbuf; |
1936 |
|
1937 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1938 |
return $self->_error ($!, 1); |
1939 |
} |
1940 |
}; |
1941 |
} |
1942 |
} |
1943 |
|
1944 |
our $ERROR_SYSCALL; |
1945 |
our $ERROR_WANT_READ; |
1946 |
|
1947 |
sub _tls_error { |
1948 |
my ($self, $err) = @_; |
1949 |
|
1950 |
return $self->_error ($!, 1) |
1951 |
if $err == Net::SSLeay::ERROR_SYSCALL (); |
1952 |
|
1953 |
my $err = Net::SSLeay::ERR_error_string (Net::SSLeay::ERR_get_error ()); |
1954 |
|
1955 |
# reduce error string to look less scary |
1956 |
$err =~ s/^error:[0-9a-fA-F]{8}:[^:]+:([^:]+):/\L$1: /; |
1957 |
|
1958 |
if ($self->{_on_starttls}) { |
1959 |
(delete $self->{_on_starttls})->($self, undef, $err); |
1960 |
&_freetls; |
1961 |
} else { |
1962 |
&_freetls; |
1963 |
$self->_error (Errno::EPROTO, 1, $err); |
1964 |
} |
1965 |
} |
1966 |
|
1967 |
# poll the write BIO and send the data if applicable |
1968 |
# also decode read data if possible |
1969 |
# this is basiclaly our TLS state machine |
1970 |
# more efficient implementations are possible with openssl, |
1971 |
# but not with the buggy and incomplete Net::SSLeay. |
1972 |
sub _dotls { |
1973 |
my ($self) = @_; |
1974 |
|
1975 |
my $tmp; |
1976 |
|
1977 |
if (length $self->{_tls_wbuf}) { |
1978 |
while (($tmp = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1979 |
substr $self->{_tls_wbuf}, 0, $tmp, ""; |
1980 |
} |
1981 |
|
1982 |
$tmp = Net::SSLeay::get_error ($self->{tls}, $tmp); |
1983 |
return $self->_tls_error ($tmp) |
1984 |
if $tmp != $ERROR_WANT_READ |
1985 |
&& ($tmp != $ERROR_SYSCALL || $!); |
1986 |
} |
1987 |
|
1988 |
while (defined ($tmp = Net::SSLeay::read ($self->{tls}))) { |
1989 |
unless (length $tmp) { |
1990 |
$self->{_on_starttls} |
1991 |
and (delete $self->{_on_starttls})->($self, undef, "EOF during handshake"); # ??? |
1992 |
&_freetls; |
1993 |
|
1994 |
if ($self->{on_stoptls}) { |
1995 |
$self->{on_stoptls}($self); |
1996 |
return; |
1997 |
} else { |
1998 |
# let's treat SSL-eof as we treat normal EOF |
1999 |
delete $self->{_rw}; |
2000 |
$self->{_eof} = 1; |
2001 |
} |
2002 |
} |
2003 |
|
2004 |
$self->{_tls_rbuf} .= $tmp; |
2005 |
$self->_drain_rbuf; |
2006 |
$self->{tls} or return; # tls session might have gone away in callback |
2007 |
} |
2008 |
|
2009 |
$tmp = Net::SSLeay::get_error ($self->{tls}, -1); |
2010 |
return $self->_tls_error ($tmp) |
2011 |
if $tmp != $ERROR_WANT_READ |
2012 |
&& ($tmp != $ERROR_SYSCALL || $!); |
2013 |
|
2014 |
while (length ($tmp = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
2015 |
$self->{wbuf} .= $tmp; |
2016 |
$self->_drain_wbuf; |
2017 |
$self->{tls} or return; # tls session might have gone away in callback |
2018 |
} |
2019 |
|
2020 |
$self->{_on_starttls} |
2021 |
and Net::SSLeay::state ($self->{tls}) == Net::SSLeay::ST_OK () |
2022 |
and (delete $self->{_on_starttls})->($self, 1, "TLS/SSL connection established"); |
2023 |
} |
2024 |
|
2025 |
=item $handle->starttls ($tls[, $tls_ctx]) |
2026 |
|
2027 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
2028 |
object is created, you can also do that at a later time by calling |
2029 |
C<starttls>. See the C<tls> constructor argument for general info. |
2030 |
|
2031 |
Starting TLS is currently an asynchronous operation - when you push some |
2032 |
write data and then call C<< ->starttls >> then TLS negotiation will start |
2033 |
immediately, after which the queued write data is then sent. This might |
2034 |
change in future versions, so best make sure you have no outstanding write |
2035 |
data when calling this method. |
2036 |
|
2037 |
The first argument is the same as the C<tls> constructor argument (either |
2038 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
2039 |
|
2040 |
The second argument is the optional C<AnyEvent::TLS> object that is used |
2041 |
when AnyEvent::Handle has to create its own TLS connection object, or |
2042 |
a hash reference with C<< key => value >> pairs that will be used to |
2043 |
construct a new context. |
2044 |
|
2045 |
The TLS connection object will end up in C<< $handle->{tls} >>, the TLS |
2046 |
context in C<< $handle->{tls_ctx} >> after this call and can be used or |
2047 |
changed to your liking. Note that the handshake might have already started |
2048 |
when this function returns. |
2049 |
|
2050 |
Due to bugs in OpenSSL, it might or might not be possible to do multiple |
2051 |
handshakes on the same stream. It is best to not attempt to use the |
2052 |
stream after stopping TLS. |
2053 |
|
2054 |
This method may invoke callbacks (and therefore the handle might be |
2055 |
destroyed after it returns). |
2056 |
|
2057 |
=cut |
2058 |
|
2059 |
our %TLS_CACHE; #TODO not yet documented, should we? |
2060 |
|
2061 |
sub starttls { |
2062 |
my ($self, $tls, $ctx) = @_; |
2063 |
|
2064 |
Carp::croak "It is an error to call starttls on an AnyEvent::Handle object while TLS is already active, caught" |
2065 |
if $self->{tls}; |
2066 |
|
2067 |
unless (defined $AnyEvent::TLS::VERSION) { |
2068 |
eval { |
2069 |
require Net::SSLeay; |
2070 |
require AnyEvent::TLS; |
2071 |
1 |
2072 |
} or return $self->_error (Errno::EPROTO, 1, "TLS support not available on this system"); |
2073 |
} |
2074 |
|
2075 |
$self->{tls} = $tls; |
2076 |
$self->{tls_ctx} = $ctx if @_ > 2; |
2077 |
|
2078 |
return unless $self->{fh}; |
2079 |
|
2080 |
$ERROR_SYSCALL = Net::SSLeay::ERROR_SYSCALL (); |
2081 |
$ERROR_WANT_READ = Net::SSLeay::ERROR_WANT_READ (); |
2082 |
|
2083 |
$tls = delete $self->{tls}; |
2084 |
$ctx = $self->{tls_ctx}; |
2085 |
|
2086 |
local $Carp::CarpLevel = 1; # skip ourselves when creating a new context or session |
2087 |
|
2088 |
if ("HASH" eq ref $ctx) { |
2089 |
if ($ctx->{cache}) { |
2090 |
my $key = $ctx+0; |
2091 |
$ctx = $TLS_CACHE{$key} ||= new AnyEvent::TLS %$ctx; |
2092 |
} else { |
2093 |
$ctx = new AnyEvent::TLS %$ctx; |
2094 |
} |
2095 |
} |
2096 |
|
2097 |
$self->{tls_ctx} = $ctx || TLS_CTX (); |
2098 |
$self->{tls} = $tls = $self->{tls_ctx}->_get_session ($tls, $self, $self->{peername}); |
2099 |
|
2100 |
# basically, this is deep magic (because SSL_read should have the same issues) |
2101 |
# but the openssl maintainers basically said: "trust us, it just works". |
2102 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
2103 |
# and mismaintained ssleay-module doesn't even offer them). |
2104 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
2105 |
# |
2106 |
# in short: this is a mess. |
2107 |
# |
2108 |
# note that we do not try to keep the length constant between writes as we are required to do. |
2109 |
# we assume that most (but not all) of this insanity only applies to non-blocking cases, |
2110 |
# and we drive openssl fully in blocking mode here. Or maybe we don't - openssl seems to |
2111 |
# have identity issues in that area. |
2112 |
# Net::SSLeay::CTX_set_mode ($ssl, |
2113 |
# (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
2114 |
# | (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
2115 |
Net::SSLeay::CTX_set_mode ($tls, 1|2); |
2116 |
|
2117 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
2118 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
2119 |
|
2120 |
Net::SSLeay::BIO_write ($self->{_rbio}, $self->{rbuf}); |
2121 |
$self->{rbuf} = ""; |
2122 |
|
2123 |
Net::SSLeay::set_bio ($tls, $self->{_rbio}, $self->{_wbio}); |
2124 |
|
2125 |
$self->{_on_starttls} = sub { $_[0]{on_starttls}(@_) } |
2126 |
if $self->{on_starttls}; |
2127 |
|
2128 |
&_dotls; # need to trigger the initial handshake |
2129 |
$self->start_read; # make sure we actually do read |
2130 |
} |
2131 |
|
2132 |
=item $handle->stoptls |
2133 |
|
2134 |
Shuts down the SSL connection - this makes a proper EOF handshake by |
2135 |
sending a close notify to the other side, but since OpenSSL doesn't |
2136 |
support non-blocking shut downs, it is not guaranteed that you can re-use |
2137 |
the stream afterwards. |
2138 |
|
2139 |
This method may invoke callbacks (and therefore the handle might be |
2140 |
destroyed after it returns). |
2141 |
|
2142 |
=cut |
2143 |
|
2144 |
sub stoptls { |
2145 |
my ($self) = @_; |
2146 |
|
2147 |
if ($self->{tls} && $self->{fh}) { |
2148 |
Net::SSLeay::shutdown ($self->{tls}); |
2149 |
|
2150 |
&_dotls; |
2151 |
|
2152 |
# # we don't give a shit. no, we do, but we can't. no...#d# |
2153 |
# # we, we... have to use openssl :/#d# |
2154 |
# &_freetls;#d# |
2155 |
} |
2156 |
} |
2157 |
|
2158 |
sub _freetls { |
2159 |
my ($self) = @_; |
2160 |
|
2161 |
return unless $self->{tls}; |
2162 |
|
2163 |
$self->{tls_ctx}->_put_session (delete $self->{tls}) |
2164 |
if $self->{tls} > 0; |
2165 |
|
2166 |
delete @$self{qw(_rbio _wbio _tls_wbuf _on_starttls)}; |
2167 |
} |
2168 |
|
2169 |
=item $handle->resettls |
2170 |
|
2171 |
This rarely-used method simply resets and TLS state on the handle, usually |
2172 |
causing data loss. |
2173 |
|
2174 |
One case where it may be useful is when you want to skip over the data in |
2175 |
the stream but you are not interested in interpreting it, so data loss is |
2176 |
no concern. |
2177 |
|
2178 |
=cut |
2179 |
|
2180 |
*resettls = \&_freetls; |
2181 |
|
2182 |
sub DESTROY { |
2183 |
my ($self) = @_; |
2184 |
|
2185 |
&_freetls; |
2186 |
|
2187 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
2188 |
|
2189 |
if ($linger && length $self->{wbuf} && $self->{fh}) { |
2190 |
my $fh = delete $self->{fh}; |
2191 |
my $wbuf = delete $self->{wbuf}; |
2192 |
|
2193 |
my @linger; |
2194 |
|
2195 |
push @linger, AE::io $fh, 1, sub { |
2196 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
2197 |
|
2198 |
if ($len > 0) { |
2199 |
substr $wbuf, 0, $len, ""; |
2200 |
} elsif (defined $len || ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK)) { |
2201 |
@linger = (); # end |
2202 |
} |
2203 |
}; |
2204 |
push @linger, AE::timer $linger, 0, sub { |
2205 |
@linger = (); |
2206 |
}; |
2207 |
} |
2208 |
} |
2209 |
|
2210 |
=item $handle->destroy |
2211 |
|
2212 |
Shuts down the handle object as much as possible - this call ensures that |
2213 |
no further callbacks will be invoked and as many resources as possible |
2214 |
will be freed. Any method you will call on the handle object after |
2215 |
destroying it in this way will be silently ignored (and it will return the |
2216 |
empty list). |
2217 |
|
2218 |
Normally, you can just "forget" any references to an AnyEvent::Handle |
2219 |
object and it will simply shut down. This works in fatal error and EOF |
2220 |
callbacks, as well as code outside. It does I<NOT> work in a read or write |
2221 |
callback, so when you want to destroy the AnyEvent::Handle object from |
2222 |
within such an callback. You I<MUST> call C<< ->destroy >> explicitly in |
2223 |
that case. |
2224 |
|
2225 |
Destroying the handle object in this way has the advantage that callbacks |
2226 |
will be removed as well, so if those are the only reference holders (as |
2227 |
is common), then one doesn't need to do anything special to break any |
2228 |
reference cycles. |
2229 |
|
2230 |
The handle might still linger in the background and write out remaining |
2231 |
data, as specified by the C<linger> option, however. |
2232 |
|
2233 |
=cut |
2234 |
|
2235 |
sub destroy { |
2236 |
my ($self) = @_; |
2237 |
|
2238 |
$self->DESTROY; |
2239 |
%$self = (); |
2240 |
bless $self, "AnyEvent::Handle::destroyed"; |
2241 |
} |
2242 |
|
2243 |
sub AnyEvent::Handle::destroyed::AUTOLOAD { |
2244 |
#nop |
2245 |
} |
2246 |
|
2247 |
=item $handle->destroyed |
2248 |
|
2249 |
Returns false as long as the handle hasn't been destroyed by a call to C<< |
2250 |
->destroy >>, true otherwise. |
2251 |
|
2252 |
Can be useful to decide whether the handle is still valid after some |
2253 |
callback possibly destroyed the handle. For example, C<< ->push_write >>, |
2254 |
C<< ->starttls >> and other methods can call user callbacks, which in turn |
2255 |
can destroy the handle, so work can be avoided by checking sometimes: |
2256 |
|
2257 |
$hdl->starttls ("accept"); |
2258 |
return if $hdl->destroyed; |
2259 |
$hdl->push_write (... |
2260 |
|
2261 |
Note that the call to C<push_write> will silently be ignored if the handle |
2262 |
has been destroyed, so often you can just ignore the possibility of the |
2263 |
handle being destroyed. |
2264 |
|
2265 |
=cut |
2266 |
|
2267 |
sub destroyed { 0 } |
2268 |
sub AnyEvent::Handle::destroyed::destroyed { 1 } |
2269 |
|
2270 |
=item AnyEvent::Handle::TLS_CTX |
2271 |
|
2272 |
This function creates and returns the AnyEvent::TLS object used by default |
2273 |
for TLS mode. |
2274 |
|
2275 |
The context is created by calling L<AnyEvent::TLS> without any arguments. |
2276 |
|
2277 |
=cut |
2278 |
|
2279 |
our $TLS_CTX; |
2280 |
|
2281 |
sub TLS_CTX() { |
2282 |
$TLS_CTX ||= do { |
2283 |
require AnyEvent::TLS; |
2284 |
|
2285 |
new AnyEvent::TLS |
2286 |
} |
2287 |
} |
2288 |
|
2289 |
=back |
2290 |
|
2291 |
|
2292 |
=head1 NONFREQUENTLY ASKED QUESTIONS |
2293 |
|
2294 |
=over 4 |
2295 |
|
2296 |
=item I C<undef> the AnyEvent::Handle reference inside my callback and |
2297 |
still get further invocations! |
2298 |
|
2299 |
That's because AnyEvent::Handle keeps a reference to itself when handling |
2300 |
read or write callbacks. |
2301 |
|
2302 |
It is only safe to "forget" the reference inside EOF or error callbacks, |
2303 |
from within all other callbacks, you need to explicitly call the C<< |
2304 |
->destroy >> method. |
2305 |
|
2306 |
=item Why is my C<on_eof> callback never called? |
2307 |
|
2308 |
Probably because your C<on_error> callback is being called instead: When |
2309 |
you have outstanding requests in your read queue, then an EOF is |
2310 |
considered an error as you clearly expected some data. |
2311 |
|
2312 |
To avoid this, make sure you have an empty read queue whenever your handle |
2313 |
is supposed to be "idle" (i.e. connection closes are O.K.). You can set |
2314 |
an C<on_read> handler that simply pushes the first read requests in the |
2315 |
queue. |
2316 |
|
2317 |
See also the next question, which explains this in a bit more detail. |
2318 |
|
2319 |
=item How can I serve requests in a loop? |
2320 |
|
2321 |
Most protocols consist of some setup phase (authentication for example) |
2322 |
followed by a request handling phase, where the server waits for requests |
2323 |
and handles them, in a loop. |
2324 |
|
2325 |
There are two important variants: The first (traditional, better) variant |
2326 |
handles requests until the server gets some QUIT command, causing it to |
2327 |
close the connection first (highly desirable for a busy TCP server). A |
2328 |
client dropping the connection is an error, which means this variant can |
2329 |
detect an unexpected detection close. |
2330 |
|
2331 |
To handle this case, always make sure you have a non-empty read queue, by |
2332 |
pushing the "read request start" handler on it: |
2333 |
|
2334 |
# we assume a request starts with a single line |
2335 |
my @start_request; @start_request = (line => sub { |
2336 |
my ($hdl, $line) = @_; |
2337 |
|
2338 |
... handle request |
2339 |
|
2340 |
# push next request read, possibly from a nested callback |
2341 |
$hdl->push_read (@start_request); |
2342 |
}); |
2343 |
|
2344 |
# auth done, now go into request handling loop |
2345 |
# now push the first @start_request |
2346 |
$hdl->push_read (@start_request); |
2347 |
|
2348 |
By always having an outstanding C<push_read>, the handle always expects |
2349 |
some data and raises the C<EPIPE> error when the connction is dropped |
2350 |
unexpectedly. |
2351 |
|
2352 |
The second variant is a protocol where the client can drop the connection |
2353 |
at any time. For TCP, this means that the server machine may run out of |
2354 |
sockets easier, and in general, it means you cannot distinguish a protocl |
2355 |
failure/client crash from a normal connection close. Nevertheless, these |
2356 |
kinds of protocols are common (and sometimes even the best solution to the |
2357 |
problem). |
2358 |
|
2359 |
Having an outstanding read request at all times is possible if you ignore |
2360 |
C<EPIPE> errors, but this doesn't help with when the client drops the |
2361 |
connection during a request, which would still be an error. |
2362 |
|
2363 |
A better solution is to push the initial request read in an C<on_read> |
2364 |
callback. This avoids an error, as when the server doesn't expect data |
2365 |
(i.e. is idly waiting for the next request, an EOF will not raise an |
2366 |
error, but simply result in an C<on_eof> callback. It is also a bit slower |
2367 |
and simpler: |
2368 |
|
2369 |
# auth done, now go into request handling loop |
2370 |
$hdl->on_read (sub { |
2371 |
my ($hdl) = @_; |
2372 |
|
2373 |
# called each time we receive data but the read queue is empty |
2374 |
# simply start read the request |
2375 |
|
2376 |
$hdl->push_read (line => sub { |
2377 |
my ($hdl, $line) = @_; |
2378 |
|
2379 |
... handle request |
2380 |
|
2381 |
# do nothing special when the request has been handled, just |
2382 |
# let the request queue go empty. |
2383 |
}); |
2384 |
}); |
2385 |
|
2386 |
=item I get different callback invocations in TLS mode/Why can't I pause |
2387 |
reading? |
2388 |
|
2389 |
Unlike, say, TCP, TLS connections do not consist of two independent |
2390 |
communication channels, one for each direction. Or put differently, the |
2391 |
read and write directions are not independent of each other: you cannot |
2392 |
write data unless you are also prepared to read, and vice versa. |
2393 |
|
2394 |
This means that, in TLS mode, you might get C<on_error> or C<on_eof> |
2395 |
callback invocations when you are not expecting any read data - the reason |
2396 |
is that AnyEvent::Handle always reads in TLS mode. |
2397 |
|
2398 |
During the connection, you have to make sure that you always have a |
2399 |
non-empty read-queue, or an C<on_read> watcher. At the end of the |
2400 |
connection (or when you no longer want to use it) you can call the |
2401 |
C<destroy> method. |
2402 |
|
2403 |
=item How do I read data until the other side closes the connection? |
2404 |
|
2405 |
If you just want to read your data into a perl scalar, the easiest way |
2406 |
to achieve this is by setting an C<on_read> callback that does nothing, |
2407 |
clearing the C<on_eof> callback and in the C<on_error> callback, the data |
2408 |
will be in C<$_[0]{rbuf}>: |
2409 |
|
2410 |
$handle->on_read (sub { }); |
2411 |
$handle->on_eof (undef); |
2412 |
$handle->on_error (sub { |
2413 |
my $data = delete $_[0]{rbuf}; |
2414 |
}); |
2415 |
|
2416 |
Note that this example removes the C<rbuf> member from the handle object, |
2417 |
which is not normally allowed by the API. It is expressly permitted in |
2418 |
this case only, as the handle object needs to be destroyed afterwards. |
2419 |
|
2420 |
The reason to use C<on_error> is that TCP connections, due to latencies |
2421 |
and packets loss, might get closed quite violently with an error, when in |
2422 |
fact all data has been received. |
2423 |
|
2424 |
It is usually better to use acknowledgements when transferring data, |
2425 |
to make sure the other side hasn't just died and you got the data |
2426 |
intact. This is also one reason why so many internet protocols have an |
2427 |
explicit QUIT command. |
2428 |
|
2429 |
=item I don't want to destroy the handle too early - how do I wait until |
2430 |
all data has been written? |
2431 |
|
2432 |
After writing your last bits of data, set the C<on_drain> callback |
2433 |
and destroy the handle in there - with the default setting of |
2434 |
C<low_water_mark> this will be called precisely when all data has been |
2435 |
written to the socket: |
2436 |
|
2437 |
$handle->push_write (...); |
2438 |
$handle->on_drain (sub { |
2439 |
AE::log debug => "All data submitted to the kernel."; |
2440 |
undef $handle; |
2441 |
}); |
2442 |
|
2443 |
If you just want to queue some data and then signal EOF to the other side, |
2444 |
consider using C<< ->push_shutdown >> instead. |
2445 |
|
2446 |
=item I want to contact a TLS/SSL server, I don't care about security. |
2447 |
|
2448 |
If your TLS server is a pure TLS server (e.g. HTTPS) that only speaks TLS, |
2449 |
connect to it and then create the AnyEvent::Handle with the C<tls> |
2450 |
parameter: |
2451 |
|
2452 |
tcp_connect $host, $port, sub { |
2453 |
my ($fh) = @_; |
2454 |
|
2455 |
my $handle = new AnyEvent::Handle |
2456 |
fh => $fh, |
2457 |
tls => "connect", |
2458 |
on_error => sub { ... }; |
2459 |
|
2460 |
$handle->push_write (...); |
2461 |
}; |
2462 |
|
2463 |
=item I want to contact a TLS/SSL server, I do care about security. |
2464 |
|
2465 |
Then you should additionally enable certificate verification, including |
2466 |
peername verification, if the protocol you use supports it (see |
2467 |
L<AnyEvent::TLS>, C<verify_peername>). |
2468 |
|
2469 |
E.g. for HTTPS: |
2470 |
|
2471 |
tcp_connect $host, $port, sub { |
2472 |
my ($fh) = @_; |
2473 |
|
2474 |
my $handle = new AnyEvent::Handle |
2475 |
fh => $fh, |
2476 |
peername => $host, |
2477 |
tls => "connect", |
2478 |
tls_ctx => { verify => 1, verify_peername => "https" }, |
2479 |
... |
2480 |
|
2481 |
Note that you must specify the hostname you connected to (or whatever |
2482 |
"peername" the protocol needs) as the C<peername> argument, otherwise no |
2483 |
peername verification will be done. |
2484 |
|
2485 |
The above will use the system-dependent default set of trusted CA |
2486 |
certificates. If you want to check against a specific CA, add the |
2487 |
C<ca_file> (or C<ca_cert>) arguments to C<tls_ctx>: |
2488 |
|
2489 |
tls_ctx => { |
2490 |
verify => 1, |
2491 |
verify_peername => "https", |
2492 |
ca_file => "my-ca-cert.pem", |
2493 |
}, |
2494 |
|
2495 |
=item I want to create a TLS/SSL server, how do I do that? |
2496 |
|
2497 |
Well, you first need to get a server certificate and key. You have |
2498 |
three options: a) ask a CA (buy one, use cacert.org etc.) b) create a |
2499 |
self-signed certificate (cheap. check the search engine of your choice, |
2500 |
there are many tutorials on the net) or c) make your own CA (tinyca2 is a |
2501 |
nice program for that purpose). |
2502 |
|
2503 |
Then create a file with your private key (in PEM format, see |
2504 |
L<AnyEvent::TLS>), followed by the certificate (also in PEM format). The |
2505 |
file should then look like this: |
2506 |
|
2507 |
-----BEGIN RSA PRIVATE KEY----- |
2508 |
...header data |
2509 |
... lots of base64'y-stuff |
2510 |
-----END RSA PRIVATE KEY----- |
2511 |
|
2512 |
-----BEGIN CERTIFICATE----- |
2513 |
... lots of base64'y-stuff |
2514 |
-----END CERTIFICATE----- |
2515 |
|
2516 |
The important bits are the "PRIVATE KEY" and "CERTIFICATE" parts. Then |
2517 |
specify this file as C<cert_file>: |
2518 |
|
2519 |
tcp_server undef, $port, sub { |
2520 |
my ($fh) = @_; |
2521 |
|
2522 |
my $handle = new AnyEvent::Handle |
2523 |
fh => $fh, |
2524 |
tls => "accept", |
2525 |
tls_ctx => { cert_file => "my-server-keycert.pem" }, |
2526 |
... |
2527 |
|
2528 |
When you have intermediate CA certificates that your clients might not |
2529 |
know about, just append them to the C<cert_file>. |
2530 |
|
2531 |
=back |
2532 |
|
2533 |
=head1 SUBCLASSING AnyEvent::Handle |
2534 |
|
2535 |
In many cases, you might want to subclass AnyEvent::Handle. |
2536 |
|
2537 |
To make this easier, a given version of AnyEvent::Handle uses these |
2538 |
conventions: |
2539 |
|
2540 |
=over 4 |
2541 |
|
2542 |
=item * all constructor arguments become object members. |
2543 |
|
2544 |
At least initially, when you pass a C<tls>-argument to the constructor it |
2545 |
will end up in C<< $handle->{tls} >>. Those members might be changed or |
2546 |
mutated later on (for example C<tls> will hold the TLS connection object). |
2547 |
|
2548 |
=item * other object member names are prefixed with an C<_>. |
2549 |
|
2550 |
All object members not explicitly documented (internal use) are prefixed |
2551 |
with an underscore character, so the remaining non-C<_>-namespace is free |
2552 |
for use for subclasses. |
2553 |
|
2554 |
=item * all members not documented here and not prefixed with an underscore |
2555 |
are free to use in subclasses. |
2556 |
|
2557 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
2558 |
member variables, but that's just life. At least it is documented. |
2559 |
|
2560 |
=back |
2561 |
|
2562 |
=head1 AUTHOR |
2563 |
|
2564 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
2565 |
|
2566 |
=cut |
2567 |
|
2568 |
1 |
2569 |
|