1 |
=head1 NAME |
2 |
|
3 |
AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent |
4 |
|
5 |
=head1 SYNOPSIS |
6 |
|
7 |
use AnyEvent; |
8 |
use AnyEvent::Handle; |
9 |
|
10 |
my $cv = AnyEvent->condvar; |
11 |
|
12 |
my $hdl; $hdl = new AnyEvent::Handle |
13 |
fh => \*STDIN, |
14 |
on_error => sub { |
15 |
my ($hdl, $fatal, $msg) = @_; |
16 |
warn "got error $msg\n"; |
17 |
$hdl->destroy; |
18 |
$cv->send; |
19 |
); |
20 |
|
21 |
# send some request line |
22 |
$hdl->push_write ("getinfo\015\012"); |
23 |
|
24 |
# read the response line |
25 |
$hdl->push_read (line => sub { |
26 |
my ($hdl, $line) = @_; |
27 |
warn "got line <$line>\n"; |
28 |
$cv->send; |
29 |
}); |
30 |
|
31 |
$cv->recv; |
32 |
|
33 |
=head1 DESCRIPTION |
34 |
|
35 |
This module is a helper module to make it easier to do event-based I/O on |
36 |
filehandles. |
37 |
|
38 |
The L<AnyEvent::Intro> tutorial contains some well-documented |
39 |
AnyEvent::Handle examples. |
40 |
|
41 |
In the following, when the documentation refers to of "bytes" then this |
42 |
means characters. As sysread and syswrite are used for all I/O, their |
43 |
treatment of characters applies to this module as well. |
44 |
|
45 |
At the very minimum, you should specify C<fh> or C<connect>, and the |
46 |
C<on_error> callback. |
47 |
|
48 |
All callbacks will be invoked with the handle object as their first |
49 |
argument. |
50 |
|
51 |
=cut |
52 |
|
53 |
package AnyEvent::Handle; |
54 |
|
55 |
use Scalar::Util (); |
56 |
use List::Util (); |
57 |
use Carp (); |
58 |
use Errno qw(EAGAIN EINTR); |
59 |
|
60 |
use AnyEvent (); BEGIN { AnyEvent::common_sense } |
61 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
62 |
|
63 |
our $VERSION = $AnyEvent::VERSION; |
64 |
|
65 |
=head1 METHODS |
66 |
|
67 |
=over 4 |
68 |
|
69 |
=item $handle = B<new> AnyEvent::TLS fh => $filehandle, key => value... |
70 |
|
71 |
The constructor supports these arguments (all as C<< key => value >> pairs). |
72 |
|
73 |
=over 4 |
74 |
|
75 |
=item fh => $filehandle [C<fh> or C<connect> MANDATORY] |
76 |
|
77 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
78 |
NOTE: The filehandle will be set to non-blocking mode (using |
79 |
C<AnyEvent::Util::fh_nonblocking>) by the constructor and needs to stay in |
80 |
that mode. |
81 |
|
82 |
=item connect => [$host, $service] [C<fh> or C<connect> MANDATORY] |
83 |
|
84 |
Try to connect to the specified host and service (port), using |
85 |
C<AnyEvent::Socket::tcp_connect>. The C<$host> additionally becomes the |
86 |
default C<peername>. |
87 |
|
88 |
You have to specify either this parameter, or C<fh>, above. |
89 |
|
90 |
It is possible to push requests on the read and write queues, and modify |
91 |
properties of the stream, even while AnyEvent::Handle is connecting. |
92 |
|
93 |
When this parameter is specified, then the C<on_prepare>, |
94 |
C<on_connect_error> and C<on_connect> callbacks will be called under the |
95 |
appropriate circumstances: |
96 |
|
97 |
=over 4 |
98 |
|
99 |
=item on_prepare => $cb->($handle) |
100 |
|
101 |
This (rarely used) callback is called before a new connection is |
102 |
attempted, but after the file handle has been created. It could be used to |
103 |
prepare the file handle with parameters required for the actual connect |
104 |
(as opposed to settings that can be changed when the connection is already |
105 |
established). |
106 |
|
107 |
The return value of this callback should be the connect timeout value in |
108 |
seconds (or C<0>, or C<undef>, or the empty list, to indicate the default |
109 |
timeout is to be used). |
110 |
|
111 |
=item on_connect => $cb->($handle, $host, $port, $retry->()) |
112 |
|
113 |
This callback is called when a connection has been successfully established. |
114 |
|
115 |
The actual numeric host and port (the socket peername) are passed as |
116 |
parameters, together with a retry callback. |
117 |
|
118 |
When, for some reason, the handle is not acceptable, then calling |
119 |
C<$retry> will continue with the next conenction target (in case of |
120 |
multi-homed hosts or SRV records there can be multiple connection |
121 |
endpoints). When it is called then the read and write queues, eof status, |
122 |
tls status and similar properties of the handle are being reset. |
123 |
|
124 |
In most cases, ignoring the C<$retry> parameter is the way to go. |
125 |
|
126 |
=item on_connect_error => $cb->($handle, $message) |
127 |
|
128 |
This callback is called when the conenction could not be |
129 |
established. C<$!> will contain the relevant error code, and C<$message> a |
130 |
message describing it (usually the same as C<"$!">). |
131 |
|
132 |
If this callback isn't specified, then C<on_error> will be called with a |
133 |
fatal error instead. |
134 |
|
135 |
=back |
136 |
|
137 |
=item on_error => $cb->($handle, $fatal, $message) |
138 |
|
139 |
This is the error callback, which is called when, well, some error |
140 |
occured, such as not being able to resolve the hostname, failure to |
141 |
connect or a read error. |
142 |
|
143 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
144 |
fatal errors the handle object will be destroyed (by a call to C<< -> |
145 |
destroy >>) after invoking the error callback (which means you are free to |
146 |
examine the handle object). Examples of fatal errors are an EOF condition |
147 |
with active (but unsatisifable) read watchers (C<EPIPE>) or I/O errors. In |
148 |
cases where the other side can close the connection at their will it is |
149 |
often easiest to not report C<EPIPE> errors in this callback. |
150 |
|
151 |
AnyEvent::Handle tries to find an appropriate error code for you to check |
152 |
against, but in some cases (TLS errors), this does not work well. It is |
153 |
recommended to always output the C<$message> argument in human-readable |
154 |
error messages (it's usually the same as C<"$!">). |
155 |
|
156 |
Non-fatal errors can be retried by simply returning, but it is recommended |
157 |
to simply ignore this parameter and instead abondon the handle object |
158 |
when this callback is invoked. Examples of non-fatal errors are timeouts |
159 |
C<ETIMEDOUT>) or badly-formatted data (C<EBADMSG>). |
160 |
|
161 |
On callback entrance, the value of C<$!> contains the operating system |
162 |
error code (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT>, C<EBADMSG> or |
163 |
C<EPROTO>). |
164 |
|
165 |
While not mandatory, it is I<highly> recommended to set this callback, as |
166 |
you will not be notified of errors otherwise. The default simply calls |
167 |
C<croak>. |
168 |
|
169 |
=item on_read => $cb->($handle) |
170 |
|
171 |
This sets the default read callback, which is called when data arrives |
172 |
and no read request is in the queue (unlike read queue callbacks, this |
173 |
callback will only be called when at least one octet of data is in the |
174 |
read buffer). |
175 |
|
176 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
177 |
method or access the C<< $handle->{rbuf} >> member directly. Note that you |
178 |
must not enlarge or modify the read buffer, you can only remove data at |
179 |
the beginning from it. |
180 |
|
181 |
When an EOF condition is detected then AnyEvent::Handle will first try to |
182 |
feed all the remaining data to the queued callbacks and C<on_read> before |
183 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
184 |
error will be raised (with C<$!> set to C<EPIPE>). |
185 |
|
186 |
Note that, unlike requests in the read queue, an C<on_read> callback |
187 |
doesn't mean you I<require> some data: if there is an EOF and there |
188 |
are outstanding read requests then an error will be flagged. With an |
189 |
C<on_read> callback, the C<on_eof> callback will be invoked. |
190 |
|
191 |
=item on_eof => $cb->($handle) |
192 |
|
193 |
Set the callback to be called when an end-of-file condition is detected, |
194 |
i.e. in the case of a socket, when the other side has closed the |
195 |
connection cleanly, and there are no outstanding read requests in the |
196 |
queue (if there are read requests, then an EOF counts as an unexpected |
197 |
connection close and will be flagged as an error). |
198 |
|
199 |
For sockets, this just means that the other side has stopped sending data, |
200 |
you can still try to write data, and, in fact, one can return from the EOF |
201 |
callback and continue writing data, as only the read part has been shut |
202 |
down. |
203 |
|
204 |
If an EOF condition has been detected but no C<on_eof> callback has been |
205 |
set, then a fatal error will be raised with C<$!> set to <0>. |
206 |
|
207 |
=item on_drain => $cb->($handle) |
208 |
|
209 |
This sets the callback that is called when the write buffer becomes empty |
210 |
(or when the callback is set and the buffer is empty already). |
211 |
|
212 |
To append to the write buffer, use the C<< ->push_write >> method. |
213 |
|
214 |
This callback is useful when you don't want to put all of your write data |
215 |
into the queue at once, for example, when you want to write the contents |
216 |
of some file to the socket you might not want to read the whole file into |
217 |
memory and push it into the queue, but instead only read more data from |
218 |
the file when the write queue becomes empty. |
219 |
|
220 |
=item timeout => $fractional_seconds |
221 |
|
222 |
=item rtimeout => $fractional_seconds |
223 |
|
224 |
=item wtimeout => $fractional_seconds |
225 |
|
226 |
If non-zero, then these enables an "inactivity" timeout: whenever this |
227 |
many seconds pass without a successful read or write on the underlying |
228 |
file handle (or a call to C<timeout_reset>), the C<on_timeout> callback |
229 |
will be invoked (and if that one is missing, a non-fatal C<ETIMEDOUT> |
230 |
error will be raised). |
231 |
|
232 |
There are three variants of the timeouts that work fully independent |
233 |
of each other, for both read and write, just read, and just write: |
234 |
C<timeout>, C<rtimeout> and C<wtimeout>, with corresponding callbacks |
235 |
C<on_timeout>, C<on_rtimeout> and C<on_wtimeout>, and reset functions |
236 |
C<timeout_reset>, C<rtimeout_reset>, and C<wtimeout_reset>. |
237 |
|
238 |
Note that timeout processing is also active when you currently do not have |
239 |
any outstanding read or write requests: If you plan to keep the connection |
240 |
idle then you should disable the timout temporarily or ignore the timeout |
241 |
in the C<on_timeout> callback, in which case AnyEvent::Handle will simply |
242 |
restart the timeout. |
243 |
|
244 |
Zero (the default) disables this timeout. |
245 |
|
246 |
=item on_timeout => $cb->($handle) |
247 |
|
248 |
Called whenever the inactivity timeout passes. If you return from this |
249 |
callback, then the timeout will be reset as if some activity had happened, |
250 |
so this condition is not fatal in any way. |
251 |
|
252 |
=item rbuf_max => <bytes> |
253 |
|
254 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
255 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
256 |
avoid some forms of denial-of-service attacks. |
257 |
|
258 |
For example, a server accepting connections from untrusted sources should |
259 |
be configured to accept only so-and-so much data that it cannot act on |
260 |
(for example, when expecting a line, an attacker could send an unlimited |
261 |
amount of data without a callback ever being called as long as the line |
262 |
isn't finished). |
263 |
|
264 |
=item autocork => <boolean> |
265 |
|
266 |
When disabled (the default), then C<push_write> will try to immediately |
267 |
write the data to the handle, if possible. This avoids having to register |
268 |
a write watcher and wait for the next event loop iteration, but can |
269 |
be inefficient if you write multiple small chunks (on the wire, this |
270 |
disadvantage is usually avoided by your kernel's nagle algorithm, see |
271 |
C<no_delay>, but this option can save costly syscalls). |
272 |
|
273 |
When enabled, then writes will always be queued till the next event loop |
274 |
iteration. This is efficient when you do many small writes per iteration, |
275 |
but less efficient when you do a single write only per iteration (or when |
276 |
the write buffer often is full). It also increases write latency. |
277 |
|
278 |
=item no_delay => <boolean> |
279 |
|
280 |
When doing small writes on sockets, your operating system kernel might |
281 |
wait a bit for more data before actually sending it out. This is called |
282 |
the Nagle algorithm, and usually it is beneficial. |
283 |
|
284 |
In some situations you want as low a delay as possible, which can be |
285 |
accomplishd by setting this option to a true value. |
286 |
|
287 |
The default is your opertaing system's default behaviour (most likely |
288 |
enabled), this option explicitly enables or disables it, if possible. |
289 |
|
290 |
=item read_size => <bytes> |
291 |
|
292 |
The default read block size (the amount of bytes this module will |
293 |
try to read during each loop iteration, which affects memory |
294 |
requirements). Default: C<8192>. |
295 |
|
296 |
=item low_water_mark => <bytes> |
297 |
|
298 |
Sets the amount of bytes (default: C<0>) that make up an "empty" write |
299 |
buffer: If the write reaches this size or gets even samller it is |
300 |
considered empty. |
301 |
|
302 |
Sometimes it can be beneficial (for performance reasons) to add data to |
303 |
the write buffer before it is fully drained, but this is a rare case, as |
304 |
the operating system kernel usually buffers data as well, so the default |
305 |
is good in almost all cases. |
306 |
|
307 |
=item linger => <seconds> |
308 |
|
309 |
If non-zero (default: C<3600>), then the destructor of the |
310 |
AnyEvent::Handle object will check whether there is still outstanding |
311 |
write data and will install a watcher that will write this data to the |
312 |
socket. No errors will be reported (this mostly matches how the operating |
313 |
system treats outstanding data at socket close time). |
314 |
|
315 |
This will not work for partial TLS data that could not be encoded |
316 |
yet. This data will be lost. Calling the C<stoptls> method in time might |
317 |
help. |
318 |
|
319 |
=item peername => $string |
320 |
|
321 |
A string used to identify the remote site - usually the DNS hostname |
322 |
(I<not> IDN!) used to create the connection, rarely the IP address. |
323 |
|
324 |
Apart from being useful in error messages, this string is also used in TLS |
325 |
peername verification (see C<verify_peername> in L<AnyEvent::TLS>). This |
326 |
verification will be skipped when C<peername> is not specified or |
327 |
C<undef>. |
328 |
|
329 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
330 |
|
331 |
When this parameter is given, it enables TLS (SSL) mode, that means |
332 |
AnyEvent will start a TLS handshake as soon as the conenction has been |
333 |
established and will transparently encrypt/decrypt data afterwards. |
334 |
|
335 |
All TLS protocol errors will be signalled as C<EPROTO>, with an |
336 |
appropriate error message. |
337 |
|
338 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
339 |
automatically when you try to create a TLS handle): this module doesn't |
340 |
have a dependency on that module, so if your module requires it, you have |
341 |
to add the dependency yourself. |
342 |
|
343 |
Unlike TCP, TLS has a server and client side: for the TLS server side, use |
344 |
C<accept>, and for the TLS client side of a connection, use C<connect> |
345 |
mode. |
346 |
|
347 |
You can also provide your own TLS connection object, but you have |
348 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
349 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
350 |
AnyEvent::Handle. Also, this module will take ownership of this connection |
351 |
object. |
352 |
|
353 |
At some future point, AnyEvent::Handle might switch to another TLS |
354 |
implementation, then the option to use your own session object will go |
355 |
away. |
356 |
|
357 |
B<IMPORTANT:> since Net::SSLeay "objects" are really only integers, |
358 |
passing in the wrong integer will lead to certain crash. This most often |
359 |
happens when one uses a stylish C<< tls => 1 >> and is surprised about the |
360 |
segmentation fault. |
361 |
|
362 |
See the C<< ->starttls >> method for when need to start TLS negotiation later. |
363 |
|
364 |
=item tls_ctx => $anyevent_tls |
365 |
|
366 |
Use the given C<AnyEvent::TLS> object to create the new TLS connection |
367 |
(unless a connection object was specified directly). If this parameter is |
368 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
369 |
|
370 |
Instead of an object, you can also specify a hash reference with C<< key |
371 |
=> value >> pairs. Those will be passed to L<AnyEvent::TLS> to create a |
372 |
new TLS context object. |
373 |
|
374 |
=item on_starttls => $cb->($handle, $success[, $error_message]) |
375 |
|
376 |
This callback will be invoked when the TLS/SSL handshake has finished. If |
377 |
C<$success> is true, then the TLS handshake succeeded, otherwise it failed |
378 |
(C<on_stoptls> will not be called in this case). |
379 |
|
380 |
The session in C<< $handle->{tls} >> can still be examined in this |
381 |
callback, even when the handshake was not successful. |
382 |
|
383 |
TLS handshake failures will not cause C<on_error> to be invoked when this |
384 |
callback is in effect, instead, the error message will be passed to C<on_starttls>. |
385 |
|
386 |
Without this callback, handshake failures lead to C<on_error> being |
387 |
called, as normal. |
388 |
|
389 |
Note that you cannot call C<starttls> right again in this callback. If you |
390 |
need to do that, start an zero-second timer instead whose callback can |
391 |
then call C<< ->starttls >> again. |
392 |
|
393 |
=item on_stoptls => $cb->($handle) |
394 |
|
395 |
When a SSLv3/TLS shutdown/close notify/EOF is detected and this callback is |
396 |
set, then it will be invoked after freeing the TLS session. If it is not, |
397 |
then a TLS shutdown condition will be treated like a normal EOF condition |
398 |
on the handle. |
399 |
|
400 |
The session in C<< $handle->{tls} >> can still be examined in this |
401 |
callback. |
402 |
|
403 |
This callback will only be called on TLS shutdowns, not when the |
404 |
underlying handle signals EOF. |
405 |
|
406 |
=item json => JSON or JSON::XS object |
407 |
|
408 |
This is the json coder object used by the C<json> read and write types. |
409 |
|
410 |
If you don't supply it, then AnyEvent::Handle will create and use a |
411 |
suitable one (on demand), which will write and expect UTF-8 encoded JSON |
412 |
texts. |
413 |
|
414 |
Note that you are responsible to depend on the JSON module if you want to |
415 |
use this functionality, as AnyEvent does not have a dependency itself. |
416 |
|
417 |
=back |
418 |
|
419 |
=cut |
420 |
|
421 |
sub new { |
422 |
my $class = shift; |
423 |
my $self = bless { @_ }, $class; |
424 |
|
425 |
if ($self->{fh}) { |
426 |
$self->_start; |
427 |
return unless $self->{fh}; # could be gone by now |
428 |
|
429 |
} elsif ($self->{connect}) { |
430 |
require AnyEvent::Socket; |
431 |
|
432 |
$self->{peername} = $self->{connect}[0] |
433 |
unless exists $self->{peername}; |
434 |
|
435 |
$self->{_skip_drain_rbuf} = 1; |
436 |
|
437 |
{ |
438 |
Scalar::Util::weaken (my $self = $self); |
439 |
|
440 |
$self->{_connect} = |
441 |
AnyEvent::Socket::tcp_connect ( |
442 |
$self->{connect}[0], |
443 |
$self->{connect}[1], |
444 |
sub { |
445 |
my ($fh, $host, $port, $retry) = @_; |
446 |
|
447 |
if ($fh) { |
448 |
$self->{fh} = $fh; |
449 |
|
450 |
delete $self->{_skip_drain_rbuf}; |
451 |
$self->_start; |
452 |
|
453 |
$self->{on_connect} |
454 |
and $self->{on_connect}($self, $host, $port, sub { |
455 |
delete @$self{qw(fh _tw _rtw _wtw _ww _rw _eof _queue rbuf _wbuf tls _tls_rbuf _tls_wbuf)}; |
456 |
$self->{_skip_drain_rbuf} = 1; |
457 |
&$retry; |
458 |
}); |
459 |
|
460 |
} else { |
461 |
if ($self->{on_connect_error}) { |
462 |
$self->{on_connect_error}($self, "$!"); |
463 |
$self->destroy; |
464 |
} else { |
465 |
$self->_error ($!, 1); |
466 |
} |
467 |
} |
468 |
}, |
469 |
sub { |
470 |
local $self->{fh} = $_[0]; |
471 |
|
472 |
$self->{on_prepare} |
473 |
? $self->{on_prepare}->($self) |
474 |
: () |
475 |
} |
476 |
); |
477 |
} |
478 |
|
479 |
} else { |
480 |
Carp::croak "AnyEvent::Handle: either an existing fh or the connect parameter must be specified"; |
481 |
} |
482 |
|
483 |
$self |
484 |
} |
485 |
|
486 |
sub _start { |
487 |
my ($self) = @_; |
488 |
|
489 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
490 |
|
491 |
$self->{_activity} = |
492 |
$self->{_ractivity} = |
493 |
$self->{_wactivity} = AE::now; |
494 |
|
495 |
$self->timeout (delete $self->{timeout} ) if $self->{timeout}; |
496 |
$self->rtimeout (delete $self->{rtimeout}) if $self->{rtimeout}; |
497 |
$self->wtimeout (delete $self->{wtimeout}) if $self->{wtimeout}; |
498 |
|
499 |
$self->no_delay (delete $self->{no_delay}) if exists $self->{no_delay}; |
500 |
|
501 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}) |
502 |
if $self->{tls}; |
503 |
|
504 |
$self->on_drain (delete $self->{on_drain}) if $self->{on_drain}; |
505 |
|
506 |
$self->start_read |
507 |
if $self->{on_read} || @{ $self->{_queue} }; |
508 |
|
509 |
$self->_drain_wbuf; |
510 |
} |
511 |
|
512 |
sub _error { |
513 |
my ($self, $errno, $fatal, $message) = @_; |
514 |
|
515 |
$! = $errno; |
516 |
$message ||= "$!"; |
517 |
|
518 |
if ($self->{on_error}) { |
519 |
$self->{on_error}($self, $fatal, $message); |
520 |
$self->destroy if $fatal; |
521 |
} elsif ($self->{fh}) { |
522 |
$self->destroy; |
523 |
Carp::croak "AnyEvent::Handle uncaught error: $message"; |
524 |
} |
525 |
} |
526 |
|
527 |
=item $fh = $handle->fh |
528 |
|
529 |
This method returns the file handle used to create the L<AnyEvent::Handle> object. |
530 |
|
531 |
=cut |
532 |
|
533 |
sub fh { $_[0]{fh} } |
534 |
|
535 |
=item $handle->on_error ($cb) |
536 |
|
537 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
538 |
|
539 |
=cut |
540 |
|
541 |
sub on_error { |
542 |
$_[0]{on_error} = $_[1]; |
543 |
} |
544 |
|
545 |
=item $handle->on_eof ($cb) |
546 |
|
547 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
548 |
|
549 |
=cut |
550 |
|
551 |
sub on_eof { |
552 |
$_[0]{on_eof} = $_[1]; |
553 |
} |
554 |
|
555 |
=item $handle->on_timeout ($cb) |
556 |
|
557 |
=item $handle->on_rtimeout ($cb) |
558 |
|
559 |
=item $handle->on_wtimeout ($cb) |
560 |
|
561 |
Replace the current C<on_timeout>, C<on_rtimeout> or C<on_wtimeout> |
562 |
callback, or disables the callback (but not the timeout) if C<$cb> = |
563 |
C<undef>. See the C<timeout> constructor argument and method. |
564 |
|
565 |
=cut |
566 |
|
567 |
# see below |
568 |
|
569 |
=item $handle->autocork ($boolean) |
570 |
|
571 |
Enables or disables the current autocork behaviour (see C<autocork> |
572 |
constructor argument). Changes will only take effect on the next write. |
573 |
|
574 |
=cut |
575 |
|
576 |
sub autocork { |
577 |
$_[0]{autocork} = $_[1]; |
578 |
} |
579 |
|
580 |
=item $handle->no_delay ($boolean) |
581 |
|
582 |
Enables or disables the C<no_delay> setting (see constructor argument of |
583 |
the same name for details). |
584 |
|
585 |
=cut |
586 |
|
587 |
sub no_delay { |
588 |
$_[0]{no_delay} = $_[1]; |
589 |
|
590 |
eval { |
591 |
local $SIG{__DIE__}; |
592 |
setsockopt $_[0]{fh}, &Socket::IPPROTO_TCP, &Socket::TCP_NODELAY, int $_[1] |
593 |
if $_[0]{fh}; |
594 |
}; |
595 |
} |
596 |
|
597 |
=item $handle->on_starttls ($cb) |
598 |
|
599 |
Replace the current C<on_starttls> callback (see the C<on_starttls> constructor argument). |
600 |
|
601 |
=cut |
602 |
|
603 |
sub on_starttls { |
604 |
$_[0]{on_starttls} = $_[1]; |
605 |
} |
606 |
|
607 |
=item $handle->on_stoptls ($cb) |
608 |
|
609 |
Replace the current C<on_stoptls> callback (see the C<on_stoptls> constructor argument). |
610 |
|
611 |
=cut |
612 |
|
613 |
sub on_starttls { |
614 |
$_[0]{on_stoptls} = $_[1]; |
615 |
} |
616 |
|
617 |
=item $handle->rbuf_max ($max_octets) |
618 |
|
619 |
Configures the C<rbuf_max> setting (C<undef> disables it). |
620 |
|
621 |
=cut |
622 |
|
623 |
sub rbuf_max { |
624 |
$_[0]{rbuf_max} = $_[1]; |
625 |
} |
626 |
|
627 |
############################################################################# |
628 |
|
629 |
=item $handle->timeout ($seconds) |
630 |
|
631 |
=item $handle->rtimeout ($seconds) |
632 |
|
633 |
=item $handle->wtimeout ($seconds) |
634 |
|
635 |
Configures (or disables) the inactivity timeout. |
636 |
|
637 |
=item $handle->timeout_reset |
638 |
|
639 |
=item $handle->rtimeout_reset |
640 |
|
641 |
=item $handle->wtimeout_reset |
642 |
|
643 |
Reset the activity timeout, as if data was received or sent. |
644 |
|
645 |
These methods are cheap to call. |
646 |
|
647 |
=cut |
648 |
|
649 |
for my $dir ("", "r", "w") { |
650 |
my $timeout = "${dir}timeout"; |
651 |
my $tw = "_${dir}tw"; |
652 |
my $on_timeout = "on_${dir}timeout"; |
653 |
my $activity = "_${dir}activity"; |
654 |
my $cb; |
655 |
|
656 |
*$on_timeout = sub { |
657 |
$_[0]{$on_timeout} = $_[1]; |
658 |
}; |
659 |
|
660 |
*$timeout = sub { |
661 |
my ($self, $new_value) = @_; |
662 |
|
663 |
$self->{$timeout} = $new_value; |
664 |
delete $self->{$tw}; &$cb; |
665 |
}; |
666 |
|
667 |
*{"${dir}timeout_reset"} = sub { |
668 |
$_[0]{$activity} = AE::now; |
669 |
}; |
670 |
|
671 |
# main workhorse: |
672 |
# reset the timeout watcher, as neccessary |
673 |
# also check for time-outs |
674 |
$cb = sub { |
675 |
my ($self) = @_; |
676 |
|
677 |
if ($self->{$timeout} && $self->{fh}) { |
678 |
my $NOW = AE::now; |
679 |
|
680 |
# when would the timeout trigger? |
681 |
my $after = $self->{$activity} + $self->{$timeout} - $NOW; |
682 |
|
683 |
# now or in the past already? |
684 |
if ($after <= 0) { |
685 |
$self->{$activity} = $NOW; |
686 |
|
687 |
if ($self->{$on_timeout}) { |
688 |
$self->{$on_timeout}($self); |
689 |
} else { |
690 |
$self->_error (Errno::ETIMEDOUT); |
691 |
} |
692 |
|
693 |
# callback could have changed timeout value, optimise |
694 |
return unless $self->{$timeout}; |
695 |
|
696 |
# calculate new after |
697 |
$after = $self->{$timeout}; |
698 |
} |
699 |
|
700 |
Scalar::Util::weaken $self; |
701 |
return unless $self; # ->error could have destroyed $self |
702 |
|
703 |
$self->{$tw} ||= AE::timer $after, 0, sub { |
704 |
delete $self->{$tw}; |
705 |
$cb->($self); |
706 |
}; |
707 |
} else { |
708 |
delete $self->{$tw}; |
709 |
} |
710 |
} |
711 |
} |
712 |
|
713 |
############################################################################# |
714 |
|
715 |
=back |
716 |
|
717 |
=head2 WRITE QUEUE |
718 |
|
719 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
720 |
for reading. |
721 |
|
722 |
The write queue is very simple: you can add data to its end, and |
723 |
AnyEvent::Handle will automatically try to get rid of it for you. |
724 |
|
725 |
When data could be written and the write buffer is shorter then the low |
726 |
water mark, the C<on_drain> callback will be invoked. |
727 |
|
728 |
=over 4 |
729 |
|
730 |
=item $handle->on_drain ($cb) |
731 |
|
732 |
Sets the C<on_drain> callback or clears it (see the description of |
733 |
C<on_drain> in the constructor). |
734 |
|
735 |
=cut |
736 |
|
737 |
sub on_drain { |
738 |
my ($self, $cb) = @_; |
739 |
|
740 |
$self->{on_drain} = $cb; |
741 |
|
742 |
$cb->($self) |
743 |
if $cb && $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}); |
744 |
} |
745 |
|
746 |
=item $handle->push_write ($data) |
747 |
|
748 |
Queues the given scalar to be written. You can push as much data as you |
749 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
750 |
buffers it independently of the kernel. |
751 |
|
752 |
=cut |
753 |
|
754 |
sub _drain_wbuf { |
755 |
my ($self) = @_; |
756 |
|
757 |
if (!$self->{_ww} && length $self->{wbuf}) { |
758 |
|
759 |
Scalar::Util::weaken $self; |
760 |
|
761 |
my $cb = sub { |
762 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
763 |
|
764 |
if (defined $len) { |
765 |
substr $self->{wbuf}, 0, $len, ""; |
766 |
|
767 |
$self->{_activity} = $self->{_wactivity} = AE::now; |
768 |
|
769 |
$self->{on_drain}($self) |
770 |
if $self->{low_water_mark} >= (length $self->{wbuf}) + (length $self->{_tls_wbuf}) |
771 |
&& $self->{on_drain}; |
772 |
|
773 |
delete $self->{_ww} unless length $self->{wbuf}; |
774 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
775 |
$self->_error ($!, 1); |
776 |
} |
777 |
}; |
778 |
|
779 |
# try to write data immediately |
780 |
$cb->() unless $self->{autocork}; |
781 |
|
782 |
# if still data left in wbuf, we need to poll |
783 |
$self->{_ww} = AE::io $self->{fh}, 1, $cb |
784 |
if length $self->{wbuf}; |
785 |
}; |
786 |
} |
787 |
|
788 |
our %WH; |
789 |
|
790 |
sub register_write_type($$) { |
791 |
$WH{$_[0]} = $_[1]; |
792 |
} |
793 |
|
794 |
sub push_write { |
795 |
my $self = shift; |
796 |
|
797 |
if (@_ > 1) { |
798 |
my $type = shift; |
799 |
|
800 |
@_ = ($WH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_write") |
801 |
->($self, @_); |
802 |
} |
803 |
|
804 |
if ($self->{tls}) { |
805 |
$self->{_tls_wbuf} .= $_[0]; |
806 |
&_dotls ($self) if $self->{fh}; |
807 |
} else { |
808 |
$self->{wbuf} .= $_[0]; |
809 |
$self->_drain_wbuf if $self->{fh}; |
810 |
} |
811 |
} |
812 |
|
813 |
=item $handle->push_write (type => @args) |
814 |
|
815 |
Instead of formatting your data yourself, you can also let this module do |
816 |
the job by specifying a type and type-specific arguments. |
817 |
|
818 |
Predefined types are (if you have ideas for additional types, feel free to |
819 |
drop by and tell us): |
820 |
|
821 |
=over 4 |
822 |
|
823 |
=item netstring => $string |
824 |
|
825 |
Formats the given value as netstring |
826 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
827 |
|
828 |
=cut |
829 |
|
830 |
register_write_type netstring => sub { |
831 |
my ($self, $string) = @_; |
832 |
|
833 |
(length $string) . ":$string," |
834 |
}; |
835 |
|
836 |
=item packstring => $format, $data |
837 |
|
838 |
An octet string prefixed with an encoded length. The encoding C<$format> |
839 |
uses the same format as a Perl C<pack> format, but must specify a single |
840 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
841 |
optional C<!>, C<< < >> or C<< > >> modifier). |
842 |
|
843 |
=cut |
844 |
|
845 |
register_write_type packstring => sub { |
846 |
my ($self, $format, $string) = @_; |
847 |
|
848 |
pack "$format/a*", $string |
849 |
}; |
850 |
|
851 |
=item json => $array_or_hashref |
852 |
|
853 |
Encodes the given hash or array reference into a JSON object. Unless you |
854 |
provide your own JSON object, this means it will be encoded to JSON text |
855 |
in UTF-8. |
856 |
|
857 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
858 |
one end of a handle and read them at the other end without using any |
859 |
additional framing. |
860 |
|
861 |
The generated JSON text is guaranteed not to contain any newlines: While |
862 |
this module doesn't need delimiters after or between JSON texts to be |
863 |
able to read them, many other languages depend on that. |
864 |
|
865 |
A simple RPC protocol that interoperates easily with others is to send |
866 |
JSON arrays (or objects, although arrays are usually the better choice as |
867 |
they mimic how function argument passing works) and a newline after each |
868 |
JSON text: |
869 |
|
870 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
871 |
$handle->push_write ("\012"); |
872 |
|
873 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
874 |
rely on the fact that the newline will be skipped as leading whitespace: |
875 |
|
876 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
877 |
|
878 |
Other languages could read single lines terminated by a newline and pass |
879 |
this line into their JSON decoder of choice. |
880 |
|
881 |
=cut |
882 |
|
883 |
register_write_type json => sub { |
884 |
my ($self, $ref) = @_; |
885 |
|
886 |
require JSON; |
887 |
|
888 |
$self->{json} ? $self->{json}->encode ($ref) |
889 |
: JSON::encode_json ($ref) |
890 |
}; |
891 |
|
892 |
=item storable => $reference |
893 |
|
894 |
Freezes the given reference using L<Storable> and writes it to the |
895 |
handle. Uses the C<nfreeze> format. |
896 |
|
897 |
=cut |
898 |
|
899 |
register_write_type storable => sub { |
900 |
my ($self, $ref) = @_; |
901 |
|
902 |
require Storable; |
903 |
|
904 |
pack "w/a*", Storable::nfreeze ($ref) |
905 |
}; |
906 |
|
907 |
=back |
908 |
|
909 |
=item $handle->push_shutdown |
910 |
|
911 |
Sometimes you know you want to close the socket after writing your data |
912 |
before it was actually written. One way to do that is to replace your |
913 |
C<on_drain> handler by a callback that shuts down the socket (and set |
914 |
C<low_water_mark> to C<0>). This method is a shorthand for just that, and |
915 |
replaces the C<on_drain> callback with: |
916 |
|
917 |
sub { shutdown $_[0]{fh}, 1 } # for push_shutdown |
918 |
|
919 |
This simply shuts down the write side and signals an EOF condition to the |
920 |
the peer. |
921 |
|
922 |
You can rely on the normal read queue and C<on_eof> handling |
923 |
afterwards. This is the cleanest way to close a connection. |
924 |
|
925 |
=cut |
926 |
|
927 |
sub push_shutdown { |
928 |
my ($self) = @_; |
929 |
|
930 |
delete $self->{low_water_mark}; |
931 |
$self->on_drain (sub { shutdown $_[0]{fh}, 1 }); |
932 |
} |
933 |
|
934 |
=item AnyEvent::Handle::register_write_type type => $coderef->($handle, @args) |
935 |
|
936 |
This function (not method) lets you add your own types to C<push_write>. |
937 |
Whenever the given C<type> is used, C<push_write> will invoke the code |
938 |
reference with the handle object and the remaining arguments. |
939 |
|
940 |
The code reference is supposed to return a single octet string that will |
941 |
be appended to the write buffer. |
942 |
|
943 |
Note that this is a function, and all types registered this way will be |
944 |
global, so try to use unique names. |
945 |
|
946 |
=cut |
947 |
|
948 |
############################################################################# |
949 |
|
950 |
=back |
951 |
|
952 |
=head2 READ QUEUE |
953 |
|
954 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
955 |
for reading. |
956 |
|
957 |
The read queue is more complex than the write queue. It can be used in two |
958 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
959 |
a queue. |
960 |
|
961 |
In the simple case, you just install an C<on_read> callback and whenever |
962 |
new data arrives, it will be called. You can then remove some data (if |
963 |
enough is there) from the read buffer (C<< $handle->rbuf >>). Or you cna |
964 |
leave the data there if you want to accumulate more (e.g. when only a |
965 |
partial message has been received so far). |
966 |
|
967 |
In the more complex case, you want to queue multiple callbacks. In this |
968 |
case, AnyEvent::Handle will call the first queued callback each time new |
969 |
data arrives (also the first time it is queued) and removes it when it has |
970 |
done its job (see C<push_read>, below). |
971 |
|
972 |
This way you can, for example, push three line-reads, followed by reading |
973 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
974 |
|
975 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
976 |
the specified number of bytes which give an XML datagram. |
977 |
|
978 |
# in the default state, expect some header bytes |
979 |
$handle->on_read (sub { |
980 |
# some data is here, now queue the length-header-read (4 octets) |
981 |
shift->unshift_read (chunk => 4, sub { |
982 |
# header arrived, decode |
983 |
my $len = unpack "N", $_[1]; |
984 |
|
985 |
# now read the payload |
986 |
shift->unshift_read (chunk => $len, sub { |
987 |
my $xml = $_[1]; |
988 |
# handle xml |
989 |
}); |
990 |
}); |
991 |
}); |
992 |
|
993 |
Example 2: Implement a client for a protocol that replies either with "OK" |
994 |
and another line or "ERROR" for the first request that is sent, and 64 |
995 |
bytes for the second request. Due to the availability of a queue, we can |
996 |
just pipeline sending both requests and manipulate the queue as necessary |
997 |
in the callbacks. |
998 |
|
999 |
When the first callback is called and sees an "OK" response, it will |
1000 |
C<unshift> another line-read. This line-read will be queued I<before> the |
1001 |
64-byte chunk callback. |
1002 |
|
1003 |
# request one, returns either "OK + extra line" or "ERROR" |
1004 |
$handle->push_write ("request 1\015\012"); |
1005 |
|
1006 |
# we expect "ERROR" or "OK" as response, so push a line read |
1007 |
$handle->push_read (line => sub { |
1008 |
# if we got an "OK", we have to _prepend_ another line, |
1009 |
# so it will be read before the second request reads its 64 bytes |
1010 |
# which are already in the queue when this callback is called |
1011 |
# we don't do this in case we got an error |
1012 |
if ($_[1] eq "OK") { |
1013 |
$_[0]->unshift_read (line => sub { |
1014 |
my $response = $_[1]; |
1015 |
... |
1016 |
}); |
1017 |
} |
1018 |
}); |
1019 |
|
1020 |
# request two, simply returns 64 octets |
1021 |
$handle->push_write ("request 2\015\012"); |
1022 |
|
1023 |
# simply read 64 bytes, always |
1024 |
$handle->push_read (chunk => 64, sub { |
1025 |
my $response = $_[1]; |
1026 |
... |
1027 |
}); |
1028 |
|
1029 |
=over 4 |
1030 |
|
1031 |
=cut |
1032 |
|
1033 |
sub _drain_rbuf { |
1034 |
my ($self) = @_; |
1035 |
|
1036 |
# avoid recursion |
1037 |
return if $self->{_skip_drain_rbuf}; |
1038 |
local $self->{_skip_drain_rbuf} = 1; |
1039 |
|
1040 |
while () { |
1041 |
# we need to use a separate tls read buffer, as we must not receive data while |
1042 |
# we are draining the buffer, and this can only happen with TLS. |
1043 |
$self->{rbuf} .= delete $self->{_tls_rbuf} |
1044 |
if exists $self->{_tls_rbuf}; |
1045 |
|
1046 |
my $len = length $self->{rbuf}; |
1047 |
|
1048 |
if (my $cb = shift @{ $self->{_queue} }) { |
1049 |
unless ($cb->($self)) { |
1050 |
# no progress can be made |
1051 |
# (not enough data and no data forthcoming) |
1052 |
$self->_error (Errno::EPIPE, 1), return |
1053 |
if $self->{_eof}; |
1054 |
|
1055 |
unshift @{ $self->{_queue} }, $cb; |
1056 |
last; |
1057 |
} |
1058 |
} elsif ($self->{on_read}) { |
1059 |
last unless $len; |
1060 |
|
1061 |
$self->{on_read}($self); |
1062 |
|
1063 |
if ( |
1064 |
$len == length $self->{rbuf} # if no data has been consumed |
1065 |
&& !@{ $self->{_queue} } # and the queue is still empty |
1066 |
&& $self->{on_read} # but we still have on_read |
1067 |
) { |
1068 |
# no further data will arrive |
1069 |
# so no progress can be made |
1070 |
$self->_error (Errno::EPIPE, 1), return |
1071 |
if $self->{_eof}; |
1072 |
|
1073 |
last; # more data might arrive |
1074 |
} |
1075 |
} else { |
1076 |
# read side becomes idle |
1077 |
delete $self->{_rw} unless $self->{tls}; |
1078 |
last; |
1079 |
} |
1080 |
} |
1081 |
|
1082 |
if ($self->{_eof}) { |
1083 |
$self->{on_eof} |
1084 |
? $self->{on_eof}($self) |
1085 |
: $self->_error (0, 1, "Unexpected end-of-file"); |
1086 |
|
1087 |
return; |
1088 |
} |
1089 |
|
1090 |
if ( |
1091 |
defined $self->{rbuf_max} |
1092 |
&& $self->{rbuf_max} < length $self->{rbuf} |
1093 |
) { |
1094 |
$self->_error (Errno::ENOSPC, 1), return; |
1095 |
} |
1096 |
|
1097 |
# may need to restart read watcher |
1098 |
unless ($self->{_rw}) { |
1099 |
$self->start_read |
1100 |
if $self->{on_read} || @{ $self->{_queue} }; |
1101 |
} |
1102 |
} |
1103 |
|
1104 |
=item $handle->on_read ($cb) |
1105 |
|
1106 |
This replaces the currently set C<on_read> callback, or clears it (when |
1107 |
the new callback is C<undef>). See the description of C<on_read> in the |
1108 |
constructor. |
1109 |
|
1110 |
=cut |
1111 |
|
1112 |
sub on_read { |
1113 |
my ($self, $cb) = @_; |
1114 |
|
1115 |
$self->{on_read} = $cb; |
1116 |
$self->_drain_rbuf if $cb; |
1117 |
} |
1118 |
|
1119 |
=item $handle->rbuf |
1120 |
|
1121 |
Returns the read buffer (as a modifiable lvalue). |
1122 |
|
1123 |
You can access the read buffer directly as the C<< ->{rbuf} >> |
1124 |
member, if you want. However, the only operation allowed on the |
1125 |
read buffer (apart from looking at it) is removing data from its |
1126 |
beginning. Otherwise modifying or appending to it is not allowed and will |
1127 |
lead to hard-to-track-down bugs. |
1128 |
|
1129 |
NOTE: The read buffer should only be used or modified if the C<on_read>, |
1130 |
C<push_read> or C<unshift_read> methods are used. The other read methods |
1131 |
automatically manage the read buffer. |
1132 |
|
1133 |
=cut |
1134 |
|
1135 |
sub rbuf : lvalue { |
1136 |
$_[0]{rbuf} |
1137 |
} |
1138 |
|
1139 |
=item $handle->push_read ($cb) |
1140 |
|
1141 |
=item $handle->unshift_read ($cb) |
1142 |
|
1143 |
Append the given callback to the end of the queue (C<push_read>) or |
1144 |
prepend it (C<unshift_read>). |
1145 |
|
1146 |
The callback is called each time some additional read data arrives. |
1147 |
|
1148 |
It must check whether enough data is in the read buffer already. |
1149 |
|
1150 |
If not enough data is available, it must return the empty list or a false |
1151 |
value, in which case it will be called repeatedly until enough data is |
1152 |
available (or an error condition is detected). |
1153 |
|
1154 |
If enough data was available, then the callback must remove all data it is |
1155 |
interested in (which can be none at all) and return a true value. After returning |
1156 |
true, it will be removed from the queue. |
1157 |
|
1158 |
=cut |
1159 |
|
1160 |
our %RH; |
1161 |
|
1162 |
sub register_read_type($$) { |
1163 |
$RH{$_[0]} = $_[1]; |
1164 |
} |
1165 |
|
1166 |
sub push_read { |
1167 |
my $self = shift; |
1168 |
my $cb = pop; |
1169 |
|
1170 |
if (@_) { |
1171 |
my $type = shift; |
1172 |
|
1173 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_read") |
1174 |
->($self, $cb, @_); |
1175 |
} |
1176 |
|
1177 |
push @{ $self->{_queue} }, $cb; |
1178 |
$self->_drain_rbuf; |
1179 |
} |
1180 |
|
1181 |
sub unshift_read { |
1182 |
my $self = shift; |
1183 |
my $cb = pop; |
1184 |
|
1185 |
if (@_) { |
1186 |
my $type = shift; |
1187 |
|
1188 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::unshift_read") |
1189 |
->($self, $cb, @_); |
1190 |
} |
1191 |
|
1192 |
|
1193 |
unshift @{ $self->{_queue} }, $cb; |
1194 |
$self->_drain_rbuf; |
1195 |
} |
1196 |
|
1197 |
=item $handle->push_read (type => @args, $cb) |
1198 |
|
1199 |
=item $handle->unshift_read (type => @args, $cb) |
1200 |
|
1201 |
Instead of providing a callback that parses the data itself you can chose |
1202 |
between a number of predefined parsing formats, for chunks of data, lines |
1203 |
etc. |
1204 |
|
1205 |
Predefined types are (if you have ideas for additional types, feel free to |
1206 |
drop by and tell us): |
1207 |
|
1208 |
=over 4 |
1209 |
|
1210 |
=item chunk => $octets, $cb->($handle, $data) |
1211 |
|
1212 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
1213 |
data read to the callback. The callback will never be called with less |
1214 |
data. |
1215 |
|
1216 |
Example: read 2 bytes. |
1217 |
|
1218 |
$handle->push_read (chunk => 2, sub { |
1219 |
warn "yay ", unpack "H*", $_[1]; |
1220 |
}); |
1221 |
|
1222 |
=cut |
1223 |
|
1224 |
register_read_type chunk => sub { |
1225 |
my ($self, $cb, $len) = @_; |
1226 |
|
1227 |
sub { |
1228 |
$len <= length $_[0]{rbuf} or return; |
1229 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
1230 |
1 |
1231 |
} |
1232 |
}; |
1233 |
|
1234 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
1235 |
|
1236 |
The callback will be called only once a full line (including the end of |
1237 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
1238 |
marker) will be passed to the callback as second argument (C<$line>), and |
1239 |
the end of line marker as the third argument (C<$eol>). |
1240 |
|
1241 |
The end of line marker, C<$eol>, can be either a string, in which case it |
1242 |
will be interpreted as a fixed record end marker, or it can be a regex |
1243 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
1244 |
regular expression. |
1245 |
|
1246 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
1247 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
1248 |
protocols). |
1249 |
|
1250 |
Partial lines at the end of the stream will never be returned, as they are |
1251 |
not marked by the end of line marker. |
1252 |
|
1253 |
=cut |
1254 |
|
1255 |
register_read_type line => sub { |
1256 |
my ($self, $cb, $eol) = @_; |
1257 |
|
1258 |
if (@_ < 3) { |
1259 |
# this is more than twice as fast as the generic code below |
1260 |
sub { |
1261 |
$_[0]{rbuf} =~ s/^([^\015\012]*)(\015?\012)// or return; |
1262 |
|
1263 |
$cb->($_[0], $1, $2); |
1264 |
1 |
1265 |
} |
1266 |
} else { |
1267 |
$eol = quotemeta $eol unless ref $eol; |
1268 |
$eol = qr|^(.*?)($eol)|s; |
1269 |
|
1270 |
sub { |
1271 |
$_[0]{rbuf} =~ s/$eol// or return; |
1272 |
|
1273 |
$cb->($_[0], $1, $2); |
1274 |
1 |
1275 |
} |
1276 |
} |
1277 |
}; |
1278 |
|
1279 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
1280 |
|
1281 |
Makes a regex match against the regex object C<$accept> and returns |
1282 |
everything up to and including the match. |
1283 |
|
1284 |
Example: read a single line terminated by '\n'. |
1285 |
|
1286 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
1287 |
|
1288 |
If C<$reject> is given and not undef, then it determines when the data is |
1289 |
to be rejected: it is matched against the data when the C<$accept> regex |
1290 |
does not match and generates an C<EBADMSG> error when it matches. This is |
1291 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
1292 |
receive buffer overflow). |
1293 |
|
1294 |
Example: expect a single decimal number followed by whitespace, reject |
1295 |
anything else (not the use of an anchor). |
1296 |
|
1297 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
1298 |
|
1299 |
If C<$skip> is given and not C<undef>, then it will be matched against |
1300 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
1301 |
and everything preceding and including the match will be accepted |
1302 |
unconditionally. This is useful to skip large amounts of data that you |
1303 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
1304 |
have to start matching from the beginning. This is purely an optimisation |
1305 |
and is usually worth only when you expect more than a few kilobytes. |
1306 |
|
1307 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
1308 |
expect the header to be very large (it isn't in practise, but...), we use |
1309 |
a skip regex to skip initial portions. The skip regex is tricky in that |
1310 |
it only accepts something not ending in either \015 or \012, as these are |
1311 |
required for the accept regex. |
1312 |
|
1313 |
$handle->push_read (regex => |
1314 |
qr<\015\012\015\012>, |
1315 |
undef, # no reject |
1316 |
qr<^.*[^\015\012]>, |
1317 |
sub { ... }); |
1318 |
|
1319 |
=cut |
1320 |
|
1321 |
register_read_type regex => sub { |
1322 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
1323 |
|
1324 |
my $data; |
1325 |
my $rbuf = \$self->{rbuf}; |
1326 |
|
1327 |
sub { |
1328 |
# accept |
1329 |
if ($$rbuf =~ $accept) { |
1330 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1331 |
$cb->($self, $data); |
1332 |
return 1; |
1333 |
} |
1334 |
|
1335 |
# reject |
1336 |
if ($reject && $$rbuf =~ $reject) { |
1337 |
$self->_error (Errno::EBADMSG); |
1338 |
} |
1339 |
|
1340 |
# skip |
1341 |
if ($skip && $$rbuf =~ $skip) { |
1342 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1343 |
} |
1344 |
|
1345 |
() |
1346 |
} |
1347 |
}; |
1348 |
|
1349 |
=item netstring => $cb->($handle, $string) |
1350 |
|
1351 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
1352 |
|
1353 |
Throws an error with C<$!> set to EBADMSG on format violations. |
1354 |
|
1355 |
=cut |
1356 |
|
1357 |
register_read_type netstring => sub { |
1358 |
my ($self, $cb) = @_; |
1359 |
|
1360 |
sub { |
1361 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
1362 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
1363 |
$self->_error (Errno::EBADMSG); |
1364 |
} |
1365 |
return; |
1366 |
} |
1367 |
|
1368 |
my $len = $1; |
1369 |
|
1370 |
$self->unshift_read (chunk => $len, sub { |
1371 |
my $string = $_[1]; |
1372 |
$_[0]->unshift_read (chunk => 1, sub { |
1373 |
if ($_[1] eq ",") { |
1374 |
$cb->($_[0], $string); |
1375 |
} else { |
1376 |
$self->_error (Errno::EBADMSG); |
1377 |
} |
1378 |
}); |
1379 |
}); |
1380 |
|
1381 |
1 |
1382 |
} |
1383 |
}; |
1384 |
|
1385 |
=item packstring => $format, $cb->($handle, $string) |
1386 |
|
1387 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1388 |
uses the same format as a Perl C<pack> format, but must specify a single |
1389 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1390 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1391 |
|
1392 |
For example, DNS over TCP uses a prefix of C<n> (2 octet network order), |
1393 |
EPP uses a prefix of C<N> (4 octtes). |
1394 |
|
1395 |
Example: read a block of data prefixed by its length in BER-encoded |
1396 |
format (very efficient). |
1397 |
|
1398 |
$handle->push_read (packstring => "w", sub { |
1399 |
my ($handle, $data) = @_; |
1400 |
}); |
1401 |
|
1402 |
=cut |
1403 |
|
1404 |
register_read_type packstring => sub { |
1405 |
my ($self, $cb, $format) = @_; |
1406 |
|
1407 |
sub { |
1408 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1409 |
defined (my $len = eval { unpack $format, $_[0]{rbuf} }) |
1410 |
or return; |
1411 |
|
1412 |
$format = length pack $format, $len; |
1413 |
|
1414 |
# bypass unshift if we already have the remaining chunk |
1415 |
if ($format + $len <= length $_[0]{rbuf}) { |
1416 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1417 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1418 |
$cb->($_[0], $data); |
1419 |
} else { |
1420 |
# remove prefix |
1421 |
substr $_[0]{rbuf}, 0, $format, ""; |
1422 |
|
1423 |
# read remaining chunk |
1424 |
$_[0]->unshift_read (chunk => $len, $cb); |
1425 |
} |
1426 |
|
1427 |
1 |
1428 |
} |
1429 |
}; |
1430 |
|
1431 |
=item json => $cb->($handle, $hash_or_arrayref) |
1432 |
|
1433 |
Reads a JSON object or array, decodes it and passes it to the |
1434 |
callback. When a parse error occurs, an C<EBADMSG> error will be raised. |
1435 |
|
1436 |
If a C<json> object was passed to the constructor, then that will be used |
1437 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1438 |
|
1439 |
This read type uses the incremental parser available with JSON version |
1440 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1441 |
dependency on your own: this module will load the JSON module, but |
1442 |
AnyEvent does not depend on it itself. |
1443 |
|
1444 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1445 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1446 |
the C<json> write type description, above, for an actual example. |
1447 |
|
1448 |
=cut |
1449 |
|
1450 |
register_read_type json => sub { |
1451 |
my ($self, $cb) = @_; |
1452 |
|
1453 |
my $json = $self->{json} ||= |
1454 |
eval { require JSON::XS; JSON::XS->new->utf8 } |
1455 |
|| do { require JSON; JSON->new->utf8 }; |
1456 |
|
1457 |
my $data; |
1458 |
my $rbuf = \$self->{rbuf}; |
1459 |
|
1460 |
sub { |
1461 |
my $ref = eval { $json->incr_parse ($self->{rbuf}) }; |
1462 |
|
1463 |
if ($ref) { |
1464 |
$self->{rbuf} = $json->incr_text; |
1465 |
$json->incr_text = ""; |
1466 |
$cb->($self, $ref); |
1467 |
|
1468 |
1 |
1469 |
} elsif ($@) { |
1470 |
# error case |
1471 |
$json->incr_skip; |
1472 |
|
1473 |
$self->{rbuf} = $json->incr_text; |
1474 |
$json->incr_text = ""; |
1475 |
|
1476 |
$self->_error (Errno::EBADMSG); |
1477 |
|
1478 |
() |
1479 |
} else { |
1480 |
$self->{rbuf} = ""; |
1481 |
|
1482 |
() |
1483 |
} |
1484 |
} |
1485 |
}; |
1486 |
|
1487 |
=item storable => $cb->($handle, $ref) |
1488 |
|
1489 |
Deserialises a L<Storable> frozen representation as written by the |
1490 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1491 |
data). |
1492 |
|
1493 |
Raises C<EBADMSG> error if the data could not be decoded. |
1494 |
|
1495 |
=cut |
1496 |
|
1497 |
register_read_type storable => sub { |
1498 |
my ($self, $cb) = @_; |
1499 |
|
1500 |
require Storable; |
1501 |
|
1502 |
sub { |
1503 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1504 |
defined (my $len = eval { unpack "w", $_[0]{rbuf} }) |
1505 |
or return; |
1506 |
|
1507 |
my $format = length pack "w", $len; |
1508 |
|
1509 |
# bypass unshift if we already have the remaining chunk |
1510 |
if ($format + $len <= length $_[0]{rbuf}) { |
1511 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1512 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1513 |
$cb->($_[0], Storable::thaw ($data)); |
1514 |
} else { |
1515 |
# remove prefix |
1516 |
substr $_[0]{rbuf}, 0, $format, ""; |
1517 |
|
1518 |
# read remaining chunk |
1519 |
$_[0]->unshift_read (chunk => $len, sub { |
1520 |
if (my $ref = eval { Storable::thaw ($_[1]) }) { |
1521 |
$cb->($_[0], $ref); |
1522 |
} else { |
1523 |
$self->_error (Errno::EBADMSG); |
1524 |
} |
1525 |
}); |
1526 |
} |
1527 |
|
1528 |
1 |
1529 |
} |
1530 |
}; |
1531 |
|
1532 |
=back |
1533 |
|
1534 |
=item AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args) |
1535 |
|
1536 |
This function (not method) lets you add your own types to C<push_read>. |
1537 |
|
1538 |
Whenever the given C<type> is used, C<push_read> will invoke the code |
1539 |
reference with the handle object, the callback and the remaining |
1540 |
arguments. |
1541 |
|
1542 |
The code reference is supposed to return a callback (usually a closure) |
1543 |
that works as a plain read callback (see C<< ->push_read ($cb) >>). |
1544 |
|
1545 |
It should invoke the passed callback when it is done reading (remember to |
1546 |
pass C<$handle> as first argument as all other callbacks do that). |
1547 |
|
1548 |
Note that this is a function, and all types registered this way will be |
1549 |
global, so try to use unique names. |
1550 |
|
1551 |
For examples, see the source of this module (F<perldoc -m AnyEvent::Handle>, |
1552 |
search for C<register_read_type>)). |
1553 |
|
1554 |
=item $handle->stop_read |
1555 |
|
1556 |
=item $handle->start_read |
1557 |
|
1558 |
In rare cases you actually do not want to read anything from the |
1559 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1560 |
any queued callbacks will be executed then. To start reading again, call |
1561 |
C<start_read>. |
1562 |
|
1563 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1564 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1565 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1566 |
there are any read requests in the queue. |
1567 |
|
1568 |
These methods will have no effect when in TLS mode (as TLS doesn't support |
1569 |
half-duplex connections). |
1570 |
|
1571 |
=cut |
1572 |
|
1573 |
sub stop_read { |
1574 |
my ($self) = @_; |
1575 |
|
1576 |
delete $self->{_rw} unless $self->{tls}; |
1577 |
} |
1578 |
|
1579 |
sub start_read { |
1580 |
my ($self) = @_; |
1581 |
|
1582 |
unless ($self->{_rw} || $self->{_eof}) { |
1583 |
Scalar::Util::weaken $self; |
1584 |
|
1585 |
$self->{_rw} = AE::io $self->{fh}, 0, sub { |
1586 |
my $rbuf = \($self->{tls} ? my $buf : $self->{rbuf}); |
1587 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size} || 8192, length $$rbuf; |
1588 |
|
1589 |
if ($len > 0) { |
1590 |
$self->{_activity} = $self->{_ractivity} = AE::now; |
1591 |
|
1592 |
if ($self->{tls}) { |
1593 |
Net::SSLeay::BIO_write ($self->{_rbio}, $$rbuf); |
1594 |
|
1595 |
&_dotls ($self); |
1596 |
} else { |
1597 |
$self->_drain_rbuf; |
1598 |
} |
1599 |
|
1600 |
} elsif (defined $len) { |
1601 |
delete $self->{_rw}; |
1602 |
$self->{_eof} = 1; |
1603 |
$self->_drain_rbuf; |
1604 |
|
1605 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1606 |
return $self->_error ($!, 1); |
1607 |
} |
1608 |
}; |
1609 |
} |
1610 |
} |
1611 |
|
1612 |
our $ERROR_SYSCALL; |
1613 |
our $ERROR_WANT_READ; |
1614 |
|
1615 |
sub _tls_error { |
1616 |
my ($self, $err) = @_; |
1617 |
|
1618 |
return $self->_error ($!, 1) |
1619 |
if $err == Net::SSLeay::ERROR_SYSCALL (); |
1620 |
|
1621 |
my $err =Net::SSLeay::ERR_error_string (Net::SSLeay::ERR_get_error ()); |
1622 |
|
1623 |
# reduce error string to look less scary |
1624 |
$err =~ s/^error:[0-9a-fA-F]{8}:[^:]+:([^:]+):/\L$1: /; |
1625 |
|
1626 |
if ($self->{_on_starttls}) { |
1627 |
(delete $self->{_on_starttls})->($self, undef, $err); |
1628 |
&_freetls; |
1629 |
} else { |
1630 |
&_freetls; |
1631 |
$self->_error (Errno::EPROTO, 1, $err); |
1632 |
} |
1633 |
} |
1634 |
|
1635 |
# poll the write BIO and send the data if applicable |
1636 |
# also decode read data if possible |
1637 |
# this is basiclaly our TLS state machine |
1638 |
# more efficient implementations are possible with openssl, |
1639 |
# but not with the buggy and incomplete Net::SSLeay. |
1640 |
sub _dotls { |
1641 |
my ($self) = @_; |
1642 |
|
1643 |
my $tmp; |
1644 |
|
1645 |
if (length $self->{_tls_wbuf}) { |
1646 |
while (($tmp = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1647 |
substr $self->{_tls_wbuf}, 0, $tmp, ""; |
1648 |
} |
1649 |
|
1650 |
$tmp = Net::SSLeay::get_error ($self->{tls}, $tmp); |
1651 |
return $self->_tls_error ($tmp) |
1652 |
if $tmp != $ERROR_WANT_READ |
1653 |
&& ($tmp != $ERROR_SYSCALL || $!); |
1654 |
} |
1655 |
|
1656 |
while (defined ($tmp = Net::SSLeay::read ($self->{tls}))) { |
1657 |
unless (length $tmp) { |
1658 |
$self->{_on_starttls} |
1659 |
and (delete $self->{_on_starttls})->($self, undef, "EOF during handshake"); # ??? |
1660 |
&_freetls; |
1661 |
|
1662 |
if ($self->{on_stoptls}) { |
1663 |
$self->{on_stoptls}($self); |
1664 |
return; |
1665 |
} else { |
1666 |
# let's treat SSL-eof as we treat normal EOF |
1667 |
delete $self->{_rw}; |
1668 |
$self->{_eof} = 1; |
1669 |
} |
1670 |
} |
1671 |
|
1672 |
$self->{_tls_rbuf} .= $tmp; |
1673 |
$self->_drain_rbuf; |
1674 |
$self->{tls} or return; # tls session might have gone away in callback |
1675 |
} |
1676 |
|
1677 |
$tmp = Net::SSLeay::get_error ($self->{tls}, -1); |
1678 |
return $self->_tls_error ($tmp) |
1679 |
if $tmp != $ERROR_WANT_READ |
1680 |
&& ($tmp != $ERROR_SYSCALL || $!); |
1681 |
|
1682 |
while (length ($tmp = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1683 |
$self->{wbuf} .= $tmp; |
1684 |
$self->_drain_wbuf; |
1685 |
} |
1686 |
|
1687 |
$self->{_on_starttls} |
1688 |
and Net::SSLeay::state ($self->{tls}) == Net::SSLeay::ST_OK () |
1689 |
and (delete $self->{_on_starttls})->($self, 1, "TLS/SSL connection established"); |
1690 |
} |
1691 |
|
1692 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1693 |
|
1694 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1695 |
object is created, you can also do that at a later time by calling |
1696 |
C<starttls>. |
1697 |
|
1698 |
Starting TLS is currently an asynchronous operation - when you push some |
1699 |
write data and then call C<< ->starttls >> then TLS negotiation will start |
1700 |
immediately, after which the queued write data is then sent. |
1701 |
|
1702 |
The first argument is the same as the C<tls> constructor argument (either |
1703 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1704 |
|
1705 |
The second argument is the optional C<AnyEvent::TLS> object that is used |
1706 |
when AnyEvent::Handle has to create its own TLS connection object, or |
1707 |
a hash reference with C<< key => value >> pairs that will be used to |
1708 |
construct a new context. |
1709 |
|
1710 |
The TLS connection object will end up in C<< $handle->{tls} >>, the TLS |
1711 |
context in C<< $handle->{tls_ctx} >> after this call and can be used or |
1712 |
changed to your liking. Note that the handshake might have already started |
1713 |
when this function returns. |
1714 |
|
1715 |
Due to bugs in OpenSSL, it might or might not be possible to do multiple |
1716 |
handshakes on the same stream. Best do not attempt to use the stream after |
1717 |
stopping TLS. |
1718 |
|
1719 |
=cut |
1720 |
|
1721 |
our %TLS_CACHE; #TODO not yet documented, should we? |
1722 |
|
1723 |
sub starttls { |
1724 |
my ($self, $tls, $ctx) = @_; |
1725 |
|
1726 |
Carp::croak "It is an error to call starttls on an AnyEvent::Handle object while TLS is already active, caught" |
1727 |
if $self->{tls}; |
1728 |
|
1729 |
$self->{tls} = $tls; |
1730 |
$self->{tls_ctx} = $ctx if @_ > 2; |
1731 |
|
1732 |
return unless $self->{fh}; |
1733 |
|
1734 |
require Net::SSLeay; |
1735 |
|
1736 |
$ERROR_SYSCALL = Net::SSLeay::ERROR_SYSCALL (); |
1737 |
$ERROR_WANT_READ = Net::SSLeay::ERROR_WANT_READ (); |
1738 |
|
1739 |
$tls = $self->{tls}; |
1740 |
$ctx = $self->{tls_ctx}; |
1741 |
|
1742 |
local $Carp::CarpLevel = 1; # skip ourselves when creating a new context or session |
1743 |
|
1744 |
if ("HASH" eq ref $ctx) { |
1745 |
require AnyEvent::TLS; |
1746 |
|
1747 |
if ($ctx->{cache}) { |
1748 |
my $key = $ctx+0; |
1749 |
$ctx = $TLS_CACHE{$key} ||= new AnyEvent::TLS %$ctx; |
1750 |
} else { |
1751 |
$ctx = new AnyEvent::TLS %$ctx; |
1752 |
} |
1753 |
} |
1754 |
|
1755 |
$self->{tls_ctx} = $ctx || TLS_CTX (); |
1756 |
$self->{tls} = $tls = $self->{tls_ctx}->_get_session ($tls, $self, $self->{peername}); |
1757 |
|
1758 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1759 |
# but the openssl maintainers basically said: "trust us, it just works". |
1760 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1761 |
# and mismaintained ssleay-module doesn't even offer them). |
1762 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1763 |
# |
1764 |
# in short: this is a mess. |
1765 |
# |
1766 |
# note that we do not try to keep the length constant between writes as we are required to do. |
1767 |
# we assume that most (but not all) of this insanity only applies to non-blocking cases, |
1768 |
# and we drive openssl fully in blocking mode here. Or maybe we don't - openssl seems to |
1769 |
# have identity issues in that area. |
1770 |
# Net::SSLeay::CTX_set_mode ($ssl, |
1771 |
# (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1772 |
# | (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1773 |
Net::SSLeay::CTX_set_mode ($tls, 1|2); |
1774 |
|
1775 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1776 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1777 |
|
1778 |
Net::SSLeay::BIO_write ($self->{_rbio}, delete $self->{rbuf}); |
1779 |
|
1780 |
Net::SSLeay::set_bio ($tls, $self->{_rbio}, $self->{_wbio}); |
1781 |
|
1782 |
$self->{_on_starttls} = sub { $_[0]{on_starttls}(@_) } |
1783 |
if $self->{on_starttls}; |
1784 |
|
1785 |
&_dotls; # need to trigger the initial handshake |
1786 |
$self->start_read; # make sure we actually do read |
1787 |
} |
1788 |
|
1789 |
=item $handle->stoptls |
1790 |
|
1791 |
Shuts down the SSL connection - this makes a proper EOF handshake by |
1792 |
sending a close notify to the other side, but since OpenSSL doesn't |
1793 |
support non-blocking shut downs, it is not guarenteed that you can re-use |
1794 |
the stream afterwards. |
1795 |
|
1796 |
=cut |
1797 |
|
1798 |
sub stoptls { |
1799 |
my ($self) = @_; |
1800 |
|
1801 |
if ($self->{tls}) { |
1802 |
Net::SSLeay::shutdown ($self->{tls}); |
1803 |
|
1804 |
&_dotls; |
1805 |
|
1806 |
# # we don't give a shit. no, we do, but we can't. no...#d# |
1807 |
# # we, we... have to use openssl :/#d# |
1808 |
# &_freetls;#d# |
1809 |
} |
1810 |
} |
1811 |
|
1812 |
sub _freetls { |
1813 |
my ($self) = @_; |
1814 |
|
1815 |
return unless $self->{tls}; |
1816 |
|
1817 |
$self->{tls_ctx}->_put_session (delete $self->{tls}) |
1818 |
if $self->{tls} > 0; |
1819 |
|
1820 |
delete @$self{qw(_rbio _wbio _tls_wbuf _on_starttls)}; |
1821 |
} |
1822 |
|
1823 |
sub DESTROY { |
1824 |
my ($self) = @_; |
1825 |
|
1826 |
&_freetls; |
1827 |
|
1828 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
1829 |
|
1830 |
if ($linger && length $self->{wbuf} && $self->{fh}) { |
1831 |
my $fh = delete $self->{fh}; |
1832 |
my $wbuf = delete $self->{wbuf}; |
1833 |
|
1834 |
my @linger; |
1835 |
|
1836 |
push @linger, AE::io $fh, 1, sub { |
1837 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
1838 |
|
1839 |
if ($len > 0) { |
1840 |
substr $wbuf, 0, $len, ""; |
1841 |
} else { |
1842 |
@linger = (); # end |
1843 |
} |
1844 |
}; |
1845 |
push @linger, AE::timer $linger, 0, sub { |
1846 |
@linger = (); |
1847 |
}; |
1848 |
} |
1849 |
} |
1850 |
|
1851 |
=item $handle->destroy |
1852 |
|
1853 |
Shuts down the handle object as much as possible - this call ensures that |
1854 |
no further callbacks will be invoked and as many resources as possible |
1855 |
will be freed. Any method you will call on the handle object after |
1856 |
destroying it in this way will be silently ignored (and it will return the |
1857 |
empty list). |
1858 |
|
1859 |
Normally, you can just "forget" any references to an AnyEvent::Handle |
1860 |
object and it will simply shut down. This works in fatal error and EOF |
1861 |
callbacks, as well as code outside. It does I<NOT> work in a read or write |
1862 |
callback, so when you want to destroy the AnyEvent::Handle object from |
1863 |
within such an callback. You I<MUST> call C<< ->destroy >> explicitly in |
1864 |
that case. |
1865 |
|
1866 |
Destroying the handle object in this way has the advantage that callbacks |
1867 |
will be removed as well, so if those are the only reference holders (as |
1868 |
is common), then one doesn't need to do anything special to break any |
1869 |
reference cycles. |
1870 |
|
1871 |
The handle might still linger in the background and write out remaining |
1872 |
data, as specified by the C<linger> option, however. |
1873 |
|
1874 |
=cut |
1875 |
|
1876 |
sub destroy { |
1877 |
my ($self) = @_; |
1878 |
|
1879 |
$self->DESTROY; |
1880 |
%$self = (); |
1881 |
bless $self, "AnyEvent::Handle::destroyed"; |
1882 |
} |
1883 |
|
1884 |
sub AnyEvent::Handle::destroyed::AUTOLOAD { |
1885 |
#nop |
1886 |
} |
1887 |
|
1888 |
=item AnyEvent::Handle::TLS_CTX |
1889 |
|
1890 |
This function creates and returns the AnyEvent::TLS object used by default |
1891 |
for TLS mode. |
1892 |
|
1893 |
The context is created by calling L<AnyEvent::TLS> without any arguments. |
1894 |
|
1895 |
=cut |
1896 |
|
1897 |
our $TLS_CTX; |
1898 |
|
1899 |
sub TLS_CTX() { |
1900 |
$TLS_CTX ||= do { |
1901 |
require AnyEvent::TLS; |
1902 |
|
1903 |
new AnyEvent::TLS |
1904 |
} |
1905 |
} |
1906 |
|
1907 |
=back |
1908 |
|
1909 |
|
1910 |
=head1 NONFREQUENTLY ASKED QUESTIONS |
1911 |
|
1912 |
=over 4 |
1913 |
|
1914 |
=item I C<undef> the AnyEvent::Handle reference inside my callback and |
1915 |
still get further invocations! |
1916 |
|
1917 |
That's because AnyEvent::Handle keeps a reference to itself when handling |
1918 |
read or write callbacks. |
1919 |
|
1920 |
It is only safe to "forget" the reference inside EOF or error callbacks, |
1921 |
from within all other callbacks, you need to explicitly call the C<< |
1922 |
->destroy >> method. |
1923 |
|
1924 |
=item I get different callback invocations in TLS mode/Why can't I pause |
1925 |
reading? |
1926 |
|
1927 |
Unlike, say, TCP, TLS connections do not consist of two independent |
1928 |
communication channels, one for each direction. Or put differently. The |
1929 |
read and write directions are not independent of each other: you cannot |
1930 |
write data unless you are also prepared to read, and vice versa. |
1931 |
|
1932 |
This can mean than, in TLS mode, you might get C<on_error> or C<on_eof> |
1933 |
callback invocations when you are not expecting any read data - the reason |
1934 |
is that AnyEvent::Handle always reads in TLS mode. |
1935 |
|
1936 |
During the connection, you have to make sure that you always have a |
1937 |
non-empty read-queue, or an C<on_read> watcher. At the end of the |
1938 |
connection (or when you no longer want to use it) you can call the |
1939 |
C<destroy> method. |
1940 |
|
1941 |
=item How do I read data until the other side closes the connection? |
1942 |
|
1943 |
If you just want to read your data into a perl scalar, the easiest way |
1944 |
to achieve this is by setting an C<on_read> callback that does nothing, |
1945 |
clearing the C<on_eof> callback and in the C<on_error> callback, the data |
1946 |
will be in C<$_[0]{rbuf}>: |
1947 |
|
1948 |
$handle->on_read (sub { }); |
1949 |
$handle->on_eof (undef); |
1950 |
$handle->on_error (sub { |
1951 |
my $data = delete $_[0]{rbuf}; |
1952 |
}); |
1953 |
|
1954 |
The reason to use C<on_error> is that TCP connections, due to latencies |
1955 |
and packets loss, might get closed quite violently with an error, when in |
1956 |
fact, all data has been received. |
1957 |
|
1958 |
It is usually better to use acknowledgements when transferring data, |
1959 |
to make sure the other side hasn't just died and you got the data |
1960 |
intact. This is also one reason why so many internet protocols have an |
1961 |
explicit QUIT command. |
1962 |
|
1963 |
=item I don't want to destroy the handle too early - how do I wait until |
1964 |
all data has been written? |
1965 |
|
1966 |
After writing your last bits of data, set the C<on_drain> callback |
1967 |
and destroy the handle in there - with the default setting of |
1968 |
C<low_water_mark> this will be called precisely when all data has been |
1969 |
written to the socket: |
1970 |
|
1971 |
$handle->push_write (...); |
1972 |
$handle->on_drain (sub { |
1973 |
warn "all data submitted to the kernel\n"; |
1974 |
undef $handle; |
1975 |
}); |
1976 |
|
1977 |
If you just want to queue some data and then signal EOF to the other side, |
1978 |
consider using C<< ->push_shutdown >> instead. |
1979 |
|
1980 |
=item I want to contact a TLS/SSL server, I don't care about security. |
1981 |
|
1982 |
If your TLS server is a pure TLS server (e.g. HTTPS) that only speaks TLS, |
1983 |
simply connect to it and then create the AnyEvent::Handle with the C<tls> |
1984 |
parameter: |
1985 |
|
1986 |
tcp_connect $host, $port, sub { |
1987 |
my ($fh) = @_; |
1988 |
|
1989 |
my $handle = new AnyEvent::Handle |
1990 |
fh => $fh, |
1991 |
tls => "connect", |
1992 |
on_error => sub { ... }; |
1993 |
|
1994 |
$handle->push_write (...); |
1995 |
}; |
1996 |
|
1997 |
=item I want to contact a TLS/SSL server, I do care about security. |
1998 |
|
1999 |
Then you should additionally enable certificate verification, including |
2000 |
peername verification, if the protocol you use supports it (see |
2001 |
L<AnyEvent::TLS>, C<verify_peername>). |
2002 |
|
2003 |
E.g. for HTTPS: |
2004 |
|
2005 |
tcp_connect $host, $port, sub { |
2006 |
my ($fh) = @_; |
2007 |
|
2008 |
my $handle = new AnyEvent::Handle |
2009 |
fh => $fh, |
2010 |
peername => $host, |
2011 |
tls => "connect", |
2012 |
tls_ctx => { verify => 1, verify_peername => "https" }, |
2013 |
... |
2014 |
|
2015 |
Note that you must specify the hostname you connected to (or whatever |
2016 |
"peername" the protocol needs) as the C<peername> argument, otherwise no |
2017 |
peername verification will be done. |
2018 |
|
2019 |
The above will use the system-dependent default set of trusted CA |
2020 |
certificates. If you want to check against a specific CA, add the |
2021 |
C<ca_file> (or C<ca_cert>) arguments to C<tls_ctx>: |
2022 |
|
2023 |
tls_ctx => { |
2024 |
verify => 1, |
2025 |
verify_peername => "https", |
2026 |
ca_file => "my-ca-cert.pem", |
2027 |
}, |
2028 |
|
2029 |
=item I want to create a TLS/SSL server, how do I do that? |
2030 |
|
2031 |
Well, you first need to get a server certificate and key. You have |
2032 |
three options: a) ask a CA (buy one, use cacert.org etc.) b) create a |
2033 |
self-signed certificate (cheap. check the search engine of your choice, |
2034 |
there are many tutorials on the net) or c) make your own CA (tinyca2 is a |
2035 |
nice program for that purpose). |
2036 |
|
2037 |
Then create a file with your private key (in PEM format, see |
2038 |
L<AnyEvent::TLS>), followed by the certificate (also in PEM format). The |
2039 |
file should then look like this: |
2040 |
|
2041 |
-----BEGIN RSA PRIVATE KEY----- |
2042 |
...header data |
2043 |
... lots of base64'y-stuff |
2044 |
-----END RSA PRIVATE KEY----- |
2045 |
|
2046 |
-----BEGIN CERTIFICATE----- |
2047 |
... lots of base64'y-stuff |
2048 |
-----END CERTIFICATE----- |
2049 |
|
2050 |
The important bits are the "PRIVATE KEY" and "CERTIFICATE" parts. Then |
2051 |
specify this file as C<cert_file>: |
2052 |
|
2053 |
tcp_server undef, $port, sub { |
2054 |
my ($fh) = @_; |
2055 |
|
2056 |
my $handle = new AnyEvent::Handle |
2057 |
fh => $fh, |
2058 |
tls => "accept", |
2059 |
tls_ctx => { cert_file => "my-server-keycert.pem" }, |
2060 |
... |
2061 |
|
2062 |
When you have intermediate CA certificates that your clients might not |
2063 |
know about, just append them to the C<cert_file>. |
2064 |
|
2065 |
=back |
2066 |
|
2067 |
|
2068 |
=head1 SUBCLASSING AnyEvent::Handle |
2069 |
|
2070 |
In many cases, you might want to subclass AnyEvent::Handle. |
2071 |
|
2072 |
To make this easier, a given version of AnyEvent::Handle uses these |
2073 |
conventions: |
2074 |
|
2075 |
=over 4 |
2076 |
|
2077 |
=item * all constructor arguments become object members. |
2078 |
|
2079 |
At least initially, when you pass a C<tls>-argument to the constructor it |
2080 |
will end up in C<< $handle->{tls} >>. Those members might be changed or |
2081 |
mutated later on (for example C<tls> will hold the TLS connection object). |
2082 |
|
2083 |
=item * other object member names are prefixed with an C<_>. |
2084 |
|
2085 |
All object members not explicitly documented (internal use) are prefixed |
2086 |
with an underscore character, so the remaining non-C<_>-namespace is free |
2087 |
for use for subclasses. |
2088 |
|
2089 |
=item * all members not documented here and not prefixed with an underscore |
2090 |
are free to use in subclasses. |
2091 |
|
2092 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
2093 |
member variables, but thats just life, at least it is documented. |
2094 |
|
2095 |
=back |
2096 |
|
2097 |
=head1 AUTHOR |
2098 |
|
2099 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
2100 |
|
2101 |
=cut |
2102 |
|
2103 |
1; # End of AnyEvent::Handle |