#!/opt/bin/perl

use Gtk2 -init;
use Gtk2::Gdk::Keysyms;

use Gtk2::CV::ImageWindow;
use Gtk2::CV::Schnauzer;

require Gtk2::CV::Plugin;
require "$ENV{HOME}/.cvrc" if -r "$ENV{HOME}/.cvrc";

$VERSION = 0.1;

my $viewer;

package cluster;

use Glib::Object::Subclass Gtk2::Window;

use Gtk2::SimpleList;

sub INIT_INSTANCE {
   my ($self) = @_;
   
   $self->set_default_size (900, 700);

   my $box = new Gtk2::HPaned;
   $self->add ($box);

   $box->child2_resize (1);
   $box->set (position => 260);

   $box->add (my $sw = new Gtk2::ScrolledWindow);
   $sw->add (
      $self->{list} = new Gtk2::SimpleList
         "#"    => "int",
         "Name" => "text",
   );

   $box->add ($self->{schnauzer} = new Gtk2::CV::Schnauzer);
   $self->{schnauzer}->set_geometry_hints;
   $self->{schnauzer}->signal_connect (activate => sub { $viewer->load_image ($_[1]) });

   Gtk2::CV::Plugin->call (new_schnauzer => $self->{schnauzer});

   $self->{list}->get_column(0)->set_sort_column_id(0);
   $self->{list}->get_column(1)->set_sort_column_id(1);

   $self->{list}->signal_connect (key_press_event => sub {
      my $key = $_[1]->keyval;
      my $state = $_[1]->state;

      my $ctrl = grep $_ eq "control-mask", @{$_[1]->state};

      if ($key == $Gtk2::Gdk::Keysyms{Up}) {
         return 0;
      } elsif ($key == $Gtk2::Gdk::Keysyms{Down}) {
         return 0;
      } else {
         return $self->{schnauzer}->signal_emit (key_press_event => $_[1]);
      }
      return 1;

   });

   $self->{list}->signal_connect (cursor_changed => sub {
      my $row = scalar +($_[0]->get_selection->get_selected_rows)[0]->get_indices;

      my $k = $_[0]{data}[$row][1];
      $k = $self->{cluster}{$k};

      $self->{schnauzer}->set_paths (
         [map "$self->{path}/$_", @$k],
      );

      1;

   });
}

sub analyse {
   my ($self, $path) = @_;

   opendir my $dir, $path
      or die "$path: $!";

   $self->{path} = $path;

   my @files = map {
                     my $path = $_ = Glib::filename_to_unicode $_;
                     s/[\-_ ]+/ /g;
                     s/\.[^\.]+$//g;
                     s/(?<=[0-9 ])(?:fc|bc|front|back|cover|lq|hq)?[a-z]{0,3}$//;
                     s/(?<=[0-9])\[\d+\]$//;
                     s/ +$//;
                     [$_, $path]
                   }
                   grep !/\.(sfv|crc|par|par2)$/i, readdir $dir;

   my %cluster;
   $self->{cluster} = \%cluster;

   my @regexps = (
      qr<^(\d\d\d\w?) >,

      qr<((?:199[0-9]|200[0-9])(?:0[1-9]|1[012])(?:0[1-9]|[12][0-9]|3[01]))>,
      qr<((?:0[1-9]|[12][0-9]|3[01])(?:0[1-9]|1[012])(?:199[0-9]|200[0-9]))>,
      qr<^(\d*[^0-9].*?)\ *[0-9_ ]+$>,
      qr<^(\d*[^0-9].*?)\ *\([0-9_ ]+\)$>,
      qr<^[0-9_ ]+\ *([^0-9].*)$>,
      qr<^(.*)[_ \-]+.*?$>,
      qr<^.*?[_ \-]+(.*)$>,
      qr<^(.*)[_ \-]+\d+[_ \-]+.*?$>,
   );

   for my $re (@regexps) {
      for (@files) {
         #print "$_->[0]\n" if $_->[1] =~ /^kisa.tan/;
         #if ($_->[0] =~ $re && $_->[0] =~ $info->[1]) {
         if ($_->[0] =~ $re) {
            $cluster{$1}{$_->[1]} = 1;
            # print "PUSH $1 : $_->[1] $_->[0] $re $info->[1] \n";
         }
      }
   }
   #push @{$cluster{"THE REST"}->[1]}, $_ for keys %chk_files;

   my %file_sorted;

   my @rest;
   for my $k (keys %cluster) {
      my @v = keys %{ $cluster{$k }};
      $cluster{$k} = \@v;
      if (@v > 2) {
         push @{$self->{list}{data}}, [scalar @v, $k];
         $file_sorted{$_} = 1 for @v;
      }
   }

   my @remaining = grep !$file_sorted{$_},
                        map $_->[1],
                            @files;
   $cluster{"REMAINING FILES"} = \@remaining;
   push @{$self->{list}{data}}, [(scalar @remaining), "REMAINING FILES"];
}

package main;

sub new_schnauzer {
   my $w = new Gtk2::Window;
   $w->add (my $s = new Gtk2::CV::Schnauzer);

   $s->signal_connect (activate => sub { $viewer->load_image ($_[1]) });
   $s->signal_connect (key_press_event => \&std_keys);

   $s->set_dir (".");
   $w->show_all;

   $w;
}

sub std_keys {
   my $key = $_[1]->keyval;

   my $ctrl = grep $_ eq "control-mask", @{$_[1]->state};

   if ($key == $Gtk2::Gdk::Keysyms{q}) {
      main_quit Gtk2;
   } elsif ($ctrl && $key == $Gtk2::Gdk::Keysyms{v}) {
      new_schnauzer;
   } else {
      return 0;
   }

   1;
}

$viewer = new Gtk2::CV::ImageWindow;
$viewer->signal_connect (key_press_event => \&std_keys);
$viewer->signal_connect (delete_event => sub { main_quit Gtk2 });
Gtk2::CV::Plugin->call (new_imagewindow => $viewer);
$viewer->show_all;

my $cluster = new cluster;

$cluster->analyse ($ARGV[0]);
$cluster->show_all;

main Gtk2;