Coro/Coro.pm

=head1 NAME

Coro - coroutine process abstraction

=head1 SYNOPSIS

 use Coro;

 async {
    # some asynchronous thread of execution
 };

 # alternatively create an async process like this:

 sub some_func : Coro {
    # some more async code
 }

 cede;

=head1 DESCRIPTION

This module collection manages coroutines. Coroutines are similar to
threads but don't run in parallel.

In this module, coroutines are defined as "callchain + lexical variables
+ @_ + $_ + $@ + $^W + C stack), that is, a coroutine has it's own
callchain, it's own set of lexicals and it's own set of perl's most
important global variables.

=cut

package Coro;

use strict;
no warnings "uninitialized";

use Coro::State;

use base qw(Coro::State Exporter);

our $idle;    # idle handler
our $main;    # main coroutine
our $current; # current coroutine

our $VERSION = '2.5';

our @EXPORT = qw(async cede schedule terminate current);
our %EXPORT_TAGS = (
      prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
);
our @EXPORT_OK = @{$EXPORT_TAGS{prio}};

{
   my @async;
   my $init;

   # this way of handling attributes simply is NOT scalable ;()
   sub import {
      no strict 'refs';

      Coro->export_to_level(1, @_);

      my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
      *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
         my ($package, $ref) = (shift, shift);
         my @attrs;
         for (@_) {
            if ($_ eq "Coro") {
               push @async, $ref;
               unless ($init++) {
                  eval q{
                     sub INIT {
                        &async(pop @async) while @async;
                     }
                  };
               }
            } else {
               push @attrs, $_;
            }
         }
         return $old ? $old->($package, $ref, @attrs) : @attrs;
      };
   }

}

=over 4

=item $main

This coroutine represents the main program.

=cut

$main = new Coro;

=item $current (or as function: current)

The current coroutine (the last coroutine switched to). The initial value
is C<$main> (of course).

This variable is B<strictly> I<read-only>. It is provided for performance
reasons. If performance is not essentiel you are encouraged to use the
C<Coro::current> function instead.

=cut

# maybe some other module used Coro::Specific before...
if ($current) {
   $main->{specific} = $current->{specific};
}

$current = $main;

sub current() { $current }

=item $idle

A callback that is called whenever the scheduler finds no ready coroutines
to run. The default implementation prints "FATAL: deadlock detected" and
exits.

This hook is overwritten by modules such as C<Coro::Timer> and
C<Coro::Event> to wait on an external event that hopefully wakes up some
coroutine.

=cut

$idle = sub {
   print STDERR "FATAL: deadlock detected\n";
   exit (51);
};

# this coroutine is necessary because a coroutine
# cannot destroy itself.
my @destroy;
my $manager; $manager = new Coro sub {
   while () {
      # by overwriting the state object with the manager we destroy it
      # while still being able to schedule this coroutine (in case it has
      # been readied multiple times. this is harmless since the manager
      # can be called as many times as neccessary and will always
      # remove itself from the runqueue
      while (@destroy) {
         my $coro = pop @destroy;
         $coro->{status} ||= [];
         $_->ready for @{delete $coro->{join} || []};

         # the next line destroys the coro state, but keeps the
         # process itself intact (we basically make it a zombie
         # process that always runs the manager thread, so it's possible
         # to transfer() to this process).
         $coro->_clone_state_from ($manager);
      }
      &schedule;
   }
};

# static methods. not really.

=back

=head2 STATIC METHODS

Static methods are actually functions that operate on the current process only.

=over 4

=item async { ... } [@args...]

Create a new asynchronous process and return it's process object
(usually unused). When the sub returns the new process is automatically
terminated.

When the coroutine dies, the program will exit, just as in the main
program.

   # create a new coroutine that just prints its arguments
   async {
      print "@_\n";
   } 1,2,3,4;

=cut

sub async(&@) {
   my $pid = new Coro @_;
   $pid->ready;
   $pid
}

=item schedule

Calls the scheduler. Please note that the current process will not be put
into the ready queue, so calling this function usually means you will
never be called again.

=cut

=item cede

"Cede" to other processes. This function puts the current process into the
ready queue and calls C<schedule>, which has the effect of giving up the
current "timeslice" to other coroutines of the same or higher priority.

=cut

=item terminate [arg...]

Terminates the current process with the given status values (see L<cancel>).

=cut

sub terminate {
   $current->cancel (@_);
}

=back

# dynamic methods

=head2 PROCESS METHODS

These are the methods you can call on process objects.

=over 4

=item new Coro \&sub [, @args...]

Create a new process and return it. When the sub returns the process
automatically terminates as if C<terminate> with the returned values were
called. To make the process run you must first put it into the ready queue
by calling the ready method.

=cut

sub _new_coro {
   $current->_clear_idle_sp; # (re-)set the idle sp on the following cede
   _set_cede_self;  # ensures that cede cede's us first
   cede;
   terminate &{+shift};
}

sub new {
   my $class = shift;

   $class->SUPER::new (\&_new_coro, @_)
}

=item $process->ready

Put the given process into the ready queue.

=cut

=item $process->cancel (arg...)

Terminates the given process and makes it return the given arguments as
status (default: the empty list).

=cut

sub cancel {
   my $self = shift;
   $self->{status} = [@_];
   push @destroy, $self;
   $manager->ready;
   &schedule if $current == $self;
}

=item $process->join

Wait until the coroutine terminates and return any values given to the
C<terminate> or C<cancel> functions. C<join> can be called multiple times
from multiple processes.

=cut

sub join {
   my $self = shift;
   unless ($self->{status}) {
      push @{$self->{join}}, $current;
      &schedule;
   }
   wantarray ? @{$self->{status}} : $self->{status}[0];
}

=item $oldprio = $process->prio ($newprio)

Sets (or gets, if the argument is missing) the priority of the
process. Higher priority processes get run before lower priority
processes. Priorities are small signed integers (currently -4 .. +3),
that you can refer to using PRIO_xxx constants (use the import tag :prio
to get then):

   PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
       3    >     1     >      0      >    -1    >    -3     >    -4

   # set priority to HIGH
   current->prio(PRIO_HIGH);

The idle coroutine ($Coro::idle) always has a lower priority than any
existing coroutine.

Changing the priority of the current process will take effect immediately,
but changing the priority of processes in the ready queue (but not
running) will only take effect after the next schedule (of that
process). This is a bug that will be fixed in some future version.

=item $newprio = $process->nice ($change)

Similar to C<prio>, but subtract the given value from the priority (i.e.
higher values mean lower priority, just as in unix).

=item $olddesc = $process->desc ($newdesc)

Sets (or gets in case the argument is missing) the description for this
process. This is just a free-form string you can associate with a process.

=cut

sub desc {
   my $old = $_[0]{desc};
   $_[0]{desc} = $_[1] if @_ > 1;
   $old;
}

=back

=cut

1;

=head1 BUGS/LIMITATIONS

 - you must make very sure that no coro is still active on global
   destruction. very bad things might happen otherwise (usually segfaults).

 - this module is not thread-safe. You should only ever use this module
   from the same thread (this requirement might be losened in the future
   to allow per-thread schedulers, but Coro::State does not yet allow
   this).

=head1 SEE ALSO

Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.

Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.

Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.

Embedding: L<Coro:MakeMaker>

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

Revision:	1.86
Committed:	Sat Nov 25 01:14:11 2006 UTC (17 years, 6 months ago) by root
Branch:	MAIN
Changes since 1.85:	+2 -3 lines
Log Message:	* empty log message *
#	User	Rev	Content
1	root	1.1	=head1 NAME
2
3	root	1.8	Coro - coroutine process abstraction
4	root	1.1
5			=head1 SYNOPSIS
6
7			use Coro;
8
9	root	1.8	async {
10			# some asynchronous thread of execution
11	root	1.2	};
12
13	root	1.8	# alternatively create an async process like this:
14	root	1.6
15	root	1.8	sub some_func : Coro {
16			# some more async code
17			}
18
19	root	1.22	cede;
20	root	1.2
21	root	1.1	=head1 DESCRIPTION
22
23	root	1.14	This module collection manages coroutines. Coroutines are similar to
24	root	1.42	threads but don't run in parallel.
25	root	1.14
26	root	1.20	In this module, coroutines are defined as "callchain + lexical variables
27	root	1.23	+ @_ + $_ + $@ + $^W + C stack), that is, a coroutine has it's own
28			callchain, it's own set of lexicals and it's own set of perl's most
29			important global variables.
30	root	1.22
31	root	1.8	=cut
32
33			package Coro;
34
35	root	1.71	use strict;
36			no warnings "uninitialized";
37	root	1.36
38	root	1.8	use Coro::State;
39
40	root	1.83	use base qw(Coro::State Exporter);
41	pcg	1.55
42	root	1.83	our $idle; # idle handler
43	root	1.71	our $main; # main coroutine
44			our $current; # current coroutine
45	root	1.8
46	root	1.80	our $VERSION = '2.5';
47	root	1.8
48	root	1.71	our @EXPORT = qw(async cede schedule terminate current);
49			our %EXPORT_TAGS = (
50	root	1.31	prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
51			);
52	root	1.71	our @EXPORT_OK = @{$EXPORT_TAGS{prio}};
53	root	1.8
54			{
55			my @async;
56	root	1.26	my $init;
57	root	1.8
58			# this way of handling attributes simply is NOT scalable ;()
59			sub import {
60	root	1.71	no strict 'refs';
61
62	root	1.8	Coro->export_to_level(1, @_);
63	root	1.71
64	root	1.8	my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
65			*{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
66			my ($package, $ref) = (shift, shift);
67			my @attrs;
68			for (@_) {
69			if ($_ eq "Coro") {
70			push @async, $ref;
71	root	1.26	unless ($init++) {
72			eval q{
73			sub INIT {
74			&async(pop @async) while @async;
75			}
76			};
77			}
78	root	1.8	} else {
79	root	1.17	push @attrs, $_;
80	root	1.8	}
81			}
82	root	1.17	return $old ? $old->($package, $ref, @attrs) : @attrs;
83	root	1.8	};
84			}
85
86			}
87
88	root	1.43	=over 4
89
90	root	1.8	=item $main
91	root	1.2
92	root	1.8	This coroutine represents the main program.
93	root	1.1
94			=cut
95
96	pcg	1.55	$main = new Coro;
97	root	1.8
98	root	1.19	=item $current (or as function: current)
99	root	1.1
100	root	1.83	The current coroutine (the last coroutine switched to). The initial value
101			is C<$main> (of course).
102
103			This variable is B<strictly> I<read-only>. It is provided for performance
104			reasons. If performance is not essentiel you are encouraged to use the
105			C<Coro::current> function instead.
106	root	1.1
107	root	1.8	=cut
108
109			# maybe some other module used Coro::Specific before...
110			if ($current) {
111			$main->{specific} = $current->{specific};
112	root	1.1	}
113
114	pcg	1.55	$current = $main;
115	root	1.19
116			sub current() { $current }
117	root	1.9
118			=item $idle
119
120	root	1.83	A callback that is called whenever the scheduler finds no ready coroutines
121			to run. The default implementation prints "FATAL: deadlock detected" and
122			exits.
123
124			This hook is overwritten by modules such as C<Coro::Timer> and
125			C<Coro::Event> to wait on an external event that hopefully wakes up some
126			coroutine.
127	root	1.9
128			=cut
129
130	root	1.83	$idle = sub {
131	root	1.9	print STDERR "FATAL: deadlock detected\n";
132	root	1.83	exit (51);
133	root	1.9	};
134	root	1.8
135	root	1.24	# this coroutine is necessary because a coroutine
136			# cannot destroy itself.
137			my @destroy;
138	root	1.86	my $manager; $manager = new Coro sub {
139	pcg	1.57	while () {
140	root	1.37	# by overwriting the state object with the manager we destroy it
141			# while still being able to schedule this coroutine (in case it has
142			# been readied multiple times. this is harmless since the manager
143			# can be called as many times as neccessary and will always
144			# remove itself from the runqueue
145	root	1.40	while (@destroy) {
146			my $coro = pop @destroy;
147			$coro->{status} \|\|= [];
148			$_->ready for @{delete $coro->{join} \|\| []};
149	pcg	1.59
150	root	1.83	# the next line destroys the coro state, but keeps the
151	pcg	1.59	# process itself intact (we basically make it a zombie
152			# process that always runs the manager thread, so it's possible
153			# to transfer() to this process).
154	root	1.83	$coro->_clone_state_from ($manager);
155	root	1.40	}
156	root	1.24	&schedule;
157			}
158			};
159
160	root	1.8	# static methods. not really.
161	root	1.43
162			=back
163	root	1.8
164			=head2 STATIC METHODS
165
166			Static methods are actually functions that operate on the current process only.
167
168			=over 4
169
170	root	1.13	=item async { ... } [@args...]
171	root	1.8
172			Create a new asynchronous process and return it's process object
173			(usually unused). When the sub returns the new process is automatically
174			terminated.
175
176	root	1.79	When the coroutine dies, the program will exit, just as in the main
177			program.
178
179	root	1.13	# create a new coroutine that just prints its arguments
180			async {
181			print "@_\n";
182			} 1,2,3,4;
183
184	root	1.8	=cut
185
186	root	1.13	sub async(&@) {
187			my $pid = new Coro @_;
188	root	1.11	$pid->ready;
189	root	1.85	$pid
190	root	1.8	}
191	root	1.1
192	root	1.8	=item schedule
193	root	1.6
194	root	1.8	Calls the scheduler. Please note that the current process will not be put
195			into the ready queue, so calling this function usually means you will
196			never be called again.
197	root	1.1
198			=cut
199
200	root	1.22	=item cede
201	root	1.1
202	root	1.22	"Cede" to other processes. This function puts the current process into the
203			ready queue and calls C<schedule>, which has the effect of giving up the
204			current "timeslice" to other coroutines of the same or higher priority.
205	root	1.7
206	root	1.8	=cut
207
208	root	1.40	=item terminate [arg...]
209	root	1.7
210	pcg	1.59	Terminates the current process with the given status values (see L<cancel>).
211	root	1.13
212	root	1.1	=cut
213
214	root	1.8	sub terminate {
215	pcg	1.59	$current->cancel (@_);
216	root	1.1	}
217	root	1.6
218	root	1.8	=back
219
220			# dynamic methods
221
222			=head2 PROCESS METHODS
223
224			These are the methods you can call on process objects.
225	root	1.6
226	root	1.8	=over 4
227
228	root	1.13	=item new Coro \&sub [, @args...]
229	root	1.8
230			Create a new process and return it. When the sub returns the process
231	root	1.40	automatically terminates as if C<terminate> with the returned values were
232	root	1.41	called. To make the process run you must first put it into the ready queue
233			by calling the ready method.
234	root	1.13
235	root	1.6	=cut
236
237	root	1.84	sub _new_coro {
238	root	1.86	$current->_clear_idle_sp; # (re-)set the idle sp on the following cede
239	root	1.84	_set_cede_self; # ensures that cede cede's us first
240			cede;
241	root	1.13	terminate &{+shift};
242			}
243
244	root	1.8	sub new {
245			my $class = shift;
246	root	1.83
247	root	1.84	$class->SUPER::new (\&_new_coro, @_)
248	root	1.8	}
249	root	1.6
250	root	1.8	=item $process->ready
251	root	1.1
252	root	1.39	Put the given process into the ready queue.
253	root	1.1
254	root	1.8	=cut
255	root	1.28
256	pcg	1.59	=item $process->cancel (arg...)
257	root	1.28
258	root	1.79	Terminates the given process and makes it return the given arguments as
259	pcg	1.59	status (default: the empty list).
260	root	1.28
261			=cut
262
263			sub cancel {
264	pcg	1.59	my $self = shift;
265			$self->{status} = [@_];
266			push @destroy, $self;
267	root	1.28	$manager->ready;
268	pcg	1.59	&schedule if $current == $self;
269	root	1.40	}
270
271			=item $process->join
272
273			Wait until the coroutine terminates and return any values given to the
274	pcg	1.59	C<terminate> or C<cancel> functions. C<join> can be called multiple times
275			from multiple processes.
276	root	1.40
277			=cut
278
279			sub join {
280			my $self = shift;
281			unless ($self->{status}) {
282			push @{$self->{join}}, $current;
283			&schedule;
284			}
285			wantarray ? @{$self->{status}} : $self->{status}[0];
286	root	1.31	}
287
288	root	1.82	=item $oldprio = $process->prio ($newprio)
289	root	1.31
290	root	1.41	Sets (or gets, if the argument is missing) the priority of the
291			process. Higher priority processes get run before lower priority
292	root	1.52	processes. Priorities are small signed integers (currently -4 .. +3),
293	root	1.41	that you can refer to using PRIO_xxx constants (use the import tag :prio
294			to get then):
295	root	1.31
296			PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
297			3 > 1 > 0 > -1 > -3 > -4
298
299			# set priority to HIGH
300			current->prio(PRIO_HIGH);
301
302			The idle coroutine ($Coro::idle) always has a lower priority than any
303			existing coroutine.
304
305			Changing the priority of the current process will take effect immediately,
306			but changing the priority of processes in the ready queue (but not
307			running) will only take effect after the next schedule (of that
308			process). This is a bug that will be fixed in some future version.
309
310	root	1.82	=item $newprio = $process->nice ($change)
311	root	1.31
312			Similar to C<prio>, but subtract the given value from the priority (i.e.
313			higher values mean lower priority, just as in unix).
314
315	root	1.82	=item $olddesc = $process->desc ($newdesc)
316	root	1.41
317			Sets (or gets in case the argument is missing) the description for this
318			process. This is just a free-form string you can associate with a process.
319
320			=cut
321
322			sub desc {
323			my $old = $_[0]{desc};
324			$_[0]{desc} = $_[1] if @_ > 1;
325			$old;
326	root	1.8	}
327	root	1.1
328	root	1.8	=back
329	root	1.2
330	root	1.8	=cut
331	root	1.2
332	root	1.8	1;
333	root	1.14
334	root	1.17	=head1 BUGS/LIMITATIONS
335	root	1.14
336	root	1.52	- you must make very sure that no coro is still active on global
337	root	1.53	destruction. very bad things might happen otherwise (usually segfaults).
338	root	1.52
339			- this module is not thread-safe. You should only ever use this module
340			from the same thread (this requirement might be losened in the future
341			to allow per-thread schedulers, but Coro::State does not yet allow
342			this).
343	root	1.9
344			=head1 SEE ALSO
345
346	root	1.67	Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.
347
348			Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.
349
350			Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.
351
352			Embedding: L<Coro:MakeMaker>
353	root	1.1
354			=head1 AUTHOR
355
356	root	1.66	Marc Lehmann <schmorp@schmorp.de>
357	root	1.64	http://home.schmorp.de/
358	root	1.1
359			=cut
360