Coro/Coro.pm

=head1 NAME

Coro - coroutine process abstraction

=head1 SYNOPSIS

 use Coro;

 async {
    # some asynchronous thread of execution
 };

 # alternatively create an async process like this:

 sub some_func : Coro {
    # some more async code
 }

 cede;

=head1 DESCRIPTION

This module collection manages coroutines. Coroutines are similar to
threads but don't run in parallel.

In this module, coroutines are defined as "callchain + lexical variables
+ @_ + $_ + $@ + $^W + C stack), that is, a coroutine has it's own
callchain, it's own set of lexicals and it's own set of perl's most
important global variables.

=cut

package Coro;

use strict;
no warnings "uninitialized";

use Coro::State;

use base qw(Coro::State Exporter);

our $idle;    # idle handler
our $main;    # main coroutine
our $current; # current coroutine

our $VERSION = '2.5';

our @EXPORT = qw(async cede schedule terminate current);
our %EXPORT_TAGS = (
      prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
);
our @EXPORT_OK = @{$EXPORT_TAGS{prio}};

{
   my @async;
   my $init;

   # this way of handling attributes simply is NOT scalable ;()
   sub import {
      no strict 'refs';

      Coro->export_to_level(1, @_);

      my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
      *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
         my ($package, $ref) = (shift, shift);
         my @attrs;
         for (@_) {
            if ($_ eq "Coro") {
               push @async, $ref;
               unless ($init++) {
                  eval q{
                     sub INIT {
                        &async(pop @async) while @async;
                     }
                  };
               }
            } else {
               push @attrs, $_;
            }
         }
         return $old ? $old->($package, $ref, @attrs) : @attrs;
      };
   }

}

=over 4

=item $main

This coroutine represents the main program.

=cut

$main = new Coro;

=item $current (or as function: current)

The current coroutine (the last coroutine switched to). The initial value
is C<$main> (of course).

This variable is B<strictly> I<read-only>. It is provided for performance
reasons. If performance is not essentiel you are encouraged to use the
C<Coro::current> function instead.

=cut

# maybe some other module used Coro::Specific before...
if ($current) {
   $main->{specific} = $current->{specific};
}

$current = $main;

sub current() { $current }

=item $idle

A callback that is called whenever the scheduler finds no ready coroutines
to run. The default implementation prints "FATAL: deadlock detected" and
exits.

This hook is overwritten by modules such as C<Coro::Timer> and
C<Coro::Event> to wait on an external event that hopefully wakes up some
coroutine.

=cut

$idle = sub {
   print STDERR "FATAL: deadlock detected\n";
   exit (51);
};

# this coroutine is necessary because a coroutine
# cannot destroy itself.
my @destroy;
my $manager; $manager = new Coro sub {
   while () {
      # by overwriting the state object with the manager we destroy it
      # while still being able to schedule this coroutine (in case it has
      # been readied multiple times. this is harmless since the manager
      # can be called as many times as neccessary and will always
      # remove itself from the runqueue
      while (@destroy) {
         my $coro = pop @destroy;
         $coro->{status} ||= [];
         $_->ready for @{delete $coro->{join} || []};

         # the next line destroys the coro state, but keeps the
         # process itself intact (we basically make it a zombie
         # process that always runs the manager thread, so it's possible
         # to transfer() to this process).
         $coro->_clone_state_from ($manager);
      }
      &schedule;
   }
};

# static methods. not really.

=back

=head2 STATIC METHODS

Static methods are actually functions that operate on the current process only.

=over 4

=item async { ... } [@args...]

Create a new asynchronous process and return it's process object
(usually unused). When the sub returns the new process is automatically
terminated.

When the coroutine dies, the program will exit, just as in the main
program.

   # create a new coroutine that just prints its arguments
   async {
      print "@_\n";
   } 1,2,3,4;

=cut

sub async(&@) {
   my $pid = new Coro @_;
   $pid->ready;
   $pid
}

=item schedule

Calls the scheduler. Please note that the current process will not be put
into the ready queue, so calling this function usually means you will
never be called again.

=cut

=item cede

"Cede" to other processes. This function puts the current process into the
ready queue and calls C<schedule>, which has the effect of giving up the
current "timeslice" to other coroutines of the same or higher priority.

=cut

=item terminate [arg...]

Terminates the current process with the given status values (see L<cancel>).

=cut

sub terminate {
   $current->cancel (@_);
}

=back

# dynamic methods

=head2 PROCESS METHODS

These are the methods you can call on process objects.

=over 4

=item new Coro \&sub [, @args...]

Create a new process and return it. When the sub returns the process
automatically terminates as if C<terminate> with the returned values were
called. To make the process run you must first put it into the ready queue
by calling the ready method.

=cut

sub _new_coro {
   terminate &{+shift};
}

sub new {
   my $class = shift;

   $class->SUPER::new (\&_new_coro, @_)
}

=item $process->ready

Put the given process into the ready queue.

=cut

=item $process->cancel (arg...)

Terminates the given process and makes it return the given arguments as
status (default: the empty list).

=cut

sub cancel {
   my $self = shift;
   $self->{status} = [@_];
   push @destroy, $self;
   $manager->ready;
   &schedule if $current == $self;
}

=item $process->join

Wait until the coroutine terminates and return any values given to the
C<terminate> or C<cancel> functions. C<join> can be called multiple times
from multiple processes.

=cut

sub join {
   my $self = shift;
   unless ($self->{status}) {
      push @{$self->{join}}, $current;
      &schedule;
   }
   wantarray ? @{$self->{status}} : $self->{status}[0];
}

=item $oldprio = $process->prio ($newprio)

Sets (or gets, if the argument is missing) the priority of the
process. Higher priority processes get run before lower priority
processes. Priorities are small signed integers (currently -4 .. +3),
that you can refer to using PRIO_xxx constants (use the import tag :prio
to get then):

   PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
       3    >     1     >      0      >    -1    >    -3     >    -4

   # set priority to HIGH
   current->prio(PRIO_HIGH);

The idle coroutine ($Coro::idle) always has a lower priority than any
existing coroutine.

Changing the priority of the current process will take effect immediately,
but changing the priority of processes in the ready queue (but not
running) will only take effect after the next schedule (of that
process). This is a bug that will be fixed in some future version.

=item $newprio = $process->nice ($change)

Similar to C<prio>, but subtract the given value from the priority (i.e.
higher values mean lower priority, just as in unix).

=item $olddesc = $process->desc ($newdesc)

Sets (or gets in case the argument is missing) the description for this
process. This is just a free-form string you can associate with a process.

=cut

sub desc {
   my $old = $_[0]{desc};
   $_[0]{desc} = $_[1] if @_ > 1;
   $old;
}

=back

=cut

1;

=head1 BUGS/LIMITATIONS

 - you must make very sure that no coro is still active on global
   destruction. very bad things might happen otherwise (usually segfaults).

 - this module is not thread-safe. You should only ever use this module
   from the same thread (this requirement might be losened in the future
   to allow per-thread schedulers, but Coro::State does not yet allow
   this).

=head1 SEE ALSO

Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.

Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.

Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.

Embedding: L<Coro:MakeMaker>

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

Revision:	1.87
Committed:	Sun Nov 26 02:16:19 2006 UTC (17 years, 6 months ago) by root
Branch:	MAIN
Changes since 1.86:	+0 -3 lines
Log Message:	we are getting closer to perfection
#	Content
1	=head1 NAME
2
3	Coro - coroutine process abstraction
4
5	=head1 SYNOPSIS
6
7	use Coro;
8
9	async {
10	# some asynchronous thread of execution
11	};
12
13	# alternatively create an async process like this:
14
15	sub some_func : Coro {
16	# some more async code
17	}
18
19	cede;
20
21	=head1 DESCRIPTION
22
23	This module collection manages coroutines. Coroutines are similar to
24	threads but don't run in parallel.
25
26	In this module, coroutines are defined as "callchain + lexical variables
27	+ @_ + $_ + $@ + $^W + C stack), that is, a coroutine has it's own
28	callchain, it's own set of lexicals and it's own set of perl's most
29	important global variables.
30
31	=cut
32
33	package Coro;
34
35	use strict;
36	no warnings "uninitialized";
37
38	use Coro::State;
39
40	use base qw(Coro::State Exporter);
41
42	our $idle; # idle handler
43	our $main; # main coroutine
44	our $current; # current coroutine
45
46	our $VERSION = '2.5';
47
48	our @EXPORT = qw(async cede schedule terminate current);
49	our %EXPORT_TAGS = (
50	prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
51	);
52	our @EXPORT_OK = @{$EXPORT_TAGS{prio}};
53
54	{
55	my @async;
56	my $init;
57
58	# this way of handling attributes simply is NOT scalable ;()
59	sub import {
60	no strict 'refs';
61
62	Coro->export_to_level(1, @_);
63
64	my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
65	*{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
66	my ($package, $ref) = (shift, shift);
67	my @attrs;
68	for (@_) {
69	if ($_ eq "Coro") {
70	push @async, $ref;
71	unless ($init++) {
72	eval q{
73	sub INIT {
74	&async(pop @async) while @async;
75	}
76	};
77	}
78	} else {
79	push @attrs, $_;
80	}
81	}
82	return $old ? $old->($package, $ref, @attrs) : @attrs;
83	};
84	}
85
86	}
87
88	=over 4
89
90	=item $main
91
92	This coroutine represents the main program.
93
94	=cut
95
96	$main = new Coro;
97
98	=item $current (or as function: current)
99
100	The current coroutine (the last coroutine switched to). The initial value
101	is C<$main> (of course).
102
103	This variable is B<strictly> I<read-only>. It is provided for performance
104	reasons. If performance is not essentiel you are encouraged to use the
105	C<Coro::current> function instead.
106
107	=cut
108
109	# maybe some other module used Coro::Specific before...
110	if ($current) {
111	$main->{specific} = $current->{specific};
112	}
113
114	$current = $main;
115
116	sub current() { $current }
117
118	=item $idle
119
120	A callback that is called whenever the scheduler finds no ready coroutines
121	to run. The default implementation prints "FATAL: deadlock detected" and
122	exits.
123
124	This hook is overwritten by modules such as C<Coro::Timer> and
125	C<Coro::Event> to wait on an external event that hopefully wakes up some
126	coroutine.
127
128	=cut
129
130	$idle = sub {
131	print STDERR "FATAL: deadlock detected\n";
132	exit (51);
133	};
134
135	# this coroutine is necessary because a coroutine
136	# cannot destroy itself.
137	my @destroy;
138	my $manager; $manager = new Coro sub {
139	while () {
140	# by overwriting the state object with the manager we destroy it
141	# while still being able to schedule this coroutine (in case it has
142	# been readied multiple times. this is harmless since the manager
143	# can be called as many times as neccessary and will always
144	# remove itself from the runqueue
145	while (@destroy) {
146	my $coro = pop @destroy;
147	$coro->{status} \|\|= [];
148	$_->ready for @{delete $coro->{join} \|\| []};
149
150	# the next line destroys the coro state, but keeps the
151	# process itself intact (we basically make it a zombie
152	# process that always runs the manager thread, so it's possible
153	# to transfer() to this process).
154	$coro->_clone_state_from ($manager);
155	}
156	&schedule;
157	}
158	};
159
160	# static methods. not really.
161
162	=back
163
164	=head2 STATIC METHODS
165
166	Static methods are actually functions that operate on the current process only.
167
168	=over 4
169
170	=item async { ... } [@args...]
171
172	Create a new asynchronous process and return it's process object
173	(usually unused). When the sub returns the new process is automatically
174	terminated.
175
176	When the coroutine dies, the program will exit, just as in the main
177	program.
178
179	# create a new coroutine that just prints its arguments
180	async {
181	print "@_\n";
182	} 1,2,3,4;
183
184	=cut
185
186	sub async(&@) {
187	my $pid = new Coro @_;
188	$pid->ready;
189	$pid
190	}
191
192	=item schedule
193
194	Calls the scheduler. Please note that the current process will not be put
195	into the ready queue, so calling this function usually means you will
196	never be called again.
197
198	=cut
199
200	=item cede
201
202	"Cede" to other processes. This function puts the current process into the
203	ready queue and calls C<schedule>, which has the effect of giving up the
204	current "timeslice" to other coroutines of the same or higher priority.
205
206	=cut
207
208	=item terminate [arg...]
209
210	Terminates the current process with the given status values (see L<cancel>).
211
212	=cut
213
214	sub terminate {
215	$current->cancel (@_);
216	}
217
218	=back
219
220	# dynamic methods
221
222	=head2 PROCESS METHODS
223
224	These are the methods you can call on process objects.
225
226	=over 4
227
228	=item new Coro \&sub [, @args...]
229
230	Create a new process and return it. When the sub returns the process
231	automatically terminates as if C<terminate> with the returned values were
232	called. To make the process run you must first put it into the ready queue
233	by calling the ready method.
234
235	=cut
236
237	sub _new_coro {
238	terminate &{+shift};
239	}
240
241	sub new {
242	my $class = shift;
243
244	$class->SUPER::new (\&_new_coro, @_)
245	}
246
247	=item $process->ready
248
249	Put the given process into the ready queue.
250
251	=cut
252
253	=item $process->cancel (arg...)
254
255	Terminates the given process and makes it return the given arguments as
256	status (default: the empty list).
257
258	=cut
259
260	sub cancel {
261	my $self = shift;
262	$self->{status} = [@_];
263	push @destroy, $self;
264	$manager->ready;
265	&schedule if $current == $self;
266	}
267
268	=item $process->join
269
270	Wait until the coroutine terminates and return any values given to the
271	C<terminate> or C<cancel> functions. C<join> can be called multiple times
272	from multiple processes.
273
274	=cut
275
276	sub join {
277	my $self = shift;
278	unless ($self->{status}) {
279	push @{$self->{join}}, $current;
280	&schedule;
281	}
282	wantarray ? @{$self->{status}} : $self->{status}[0];
283	}
284
285	=item $oldprio = $process->prio ($newprio)
286
287	Sets (or gets, if the argument is missing) the priority of the
288	process. Higher priority processes get run before lower priority
289	processes. Priorities are small signed integers (currently -4 .. +3),
290	that you can refer to using PRIO_xxx constants (use the import tag :prio
291	to get then):
292
293	PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
294	3 > 1 > 0 > -1 > -3 > -4
295
296	# set priority to HIGH
297	current->prio(PRIO_HIGH);
298
299	The idle coroutine ($Coro::idle) always has a lower priority than any
300	existing coroutine.
301
302	Changing the priority of the current process will take effect immediately,
303	but changing the priority of processes in the ready queue (but not
304	running) will only take effect after the next schedule (of that
305	process). This is a bug that will be fixed in some future version.
306
307	=item $newprio = $process->nice ($change)
308
309	Similar to C<prio>, but subtract the given value from the priority (i.e.
310	higher values mean lower priority, just as in unix).
311
312	=item $olddesc = $process->desc ($newdesc)
313
314	Sets (or gets in case the argument is missing) the description for this
315	process. This is just a free-form string you can associate with a process.
316
317	=cut
318
319	sub desc {
320	my $old = $_[0]{desc};
321	$_[0]{desc} = $_[1] if @_ > 1;
322	$old;
323	}
324
325	=back
326
327	=cut
328
329	1;
330
331	=head1 BUGS/LIMITATIONS
332
333	- you must make very sure that no coro is still active on global
334	destruction. very bad things might happen otherwise (usually segfaults).
335
336	- this module is not thread-safe. You should only ever use this module
337	from the same thread (this requirement might be losened in the future
338	to allow per-thread schedulers, but Coro::State does not yet allow
339	this).
340
341	=head1 SEE ALSO
342
343	Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.
344
345	Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.
346
347	Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.
348
349	Embedding: L<Coro:MakeMaker>
350
351	=head1 AUTHOR
352
353	Marc Lehmann <schmorp@schmorp.de>
354	http://home.schmorp.de/
355
356	=cut
357