Coro/Coro.pm

=head1 NAME

Coro - coroutine process abstraction

=head1 SYNOPSIS

 use Coro;

 async {
    # some asynchronous thread of execution
 };

 # alternatively create an async process like this:

 sub some_func : Coro {
    # some more async code
 }

 cede;

=head1 DESCRIPTION

This module collection manages coroutines. Coroutines are similar to
Threads but don't run in parallel.

This module is still experimental, see the BUGS section below.

In this module, coroutines are defined as "callchain + lexical variables
+ @_ + $_ + $@ + $^W + C stack), that is, a coroutine has it's own
callchain, it's own set of lexicals and it's own set of perl's most
important global variables.

=cut

package Coro;

use Coro::State;

use base Exporter;

$VERSION = 0.10;

@EXPORT = qw(async cede schedule terminate current);
@EXPORT_OK = qw($current);

{
   my @async;

   # this way of handling attributes simply is NOT scalable ;()
   sub import {
      Coro->export_to_level(1, @_);
      my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
      *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
         my ($package, $ref) = (shift, shift);
         my @attrs;
         for (@_) {
            if ($_ eq "Coro") {
               push @async, $ref;
            } else {
               push @attrs, $_;
            }
         }
         return $old ? $old->($package, $ref, @attrs) : @attrs;
      };
   }

   sub INIT {
      &async(pop @async) while @async;
   }
}

=item $main

This coroutine represents the main program.

=cut

our $main = new Coro;

=item $current (or as function: current)

The current coroutine (the last coroutine switched to). The initial value is C<$main> (of course).

=cut

# maybe some other module used Coro::Specific before...
if ($current) {
   $main->{specific} = $current->{specific};
}

our $current = $main;

sub current() { $current }

=item $idle

The coroutine to switch to when no other coroutine is running. The default
implementation prints "FATAL: deadlock detected" and exits.

=cut

# should be done using priorities :(
our $idle = new Coro sub {
   print STDERR "FATAL: deadlock detected\n";
   exit(51);
};

# we really need priorities...
my @ready; # the ready queue. hehe, rather broken ;)

# static methods. not really.

=head2 STATIC METHODS

Static methods are actually functions that operate on the current process only.

=over 4

=item async { ... } [@args...]

Create a new asynchronous process and return it's process object
(usually unused). When the sub returns the new process is automatically
terminated.

   # create a new coroutine that just prints its arguments
   async {
      print "@_\n";
   } 1,2,3,4;

The coderef you submit MUST NOT be a closure that refers to variables
in an outer scope. This does NOT work. Pass arguments into it instead.

=cut

sub async(&@) {
   my $pid = new Coro @_;
   $pid->ready;
   $pid;
}

=item schedule

Calls the scheduler. Please note that the current process will not be put
into the ready queue, so calling this function usually means you will
never be called again.

=cut

my $prev;

sub schedule {
   # should be done using priorities :(
   ($prev, $current) = ($current, shift @ready || $idle);
   Coro::State::transfer($prev, $current);
}

=item cede

"Cede" to other processes. This function puts the current process into the
ready queue and calls C<schedule>, which has the effect of giving up the
current "timeslice" to other coroutines of the same or higher priority.

=cut

sub cede {
   $current->ready;
   &schedule;
}

=item terminate

Terminates the current process.

Future versions of this function will allow result arguments.

=cut

# this coroutine is necessary because a coroutine
# cannot destroy itself.
my @destroy;
my $terminate = new Coro sub {
   while() {
      delete ((pop @destroy)->{_coro_state}) while @destroy;
      &schedule;
   }
};

sub terminate {
   push @destroy, $current;
   $terminate->ready;
   &schedule;
   # NORETURN
}

=back

# dynamic methods

=head2 PROCESS METHODS

These are the methods you can call on process objects.

=over 4

=item new Coro \&sub [, @args...]

Create a new process and return it. When the sub returns the process
automatically terminates. To start the process you must first put it into
the ready queue by calling the ready method.

The coderef you submit MUST NOT be a closure that refers to variables
in an outer scope. This does NOT work. Pass arguments into it instead.

=cut

sub _newcoro {
   terminate &{+shift};
}

sub new {
   my $class = shift;
   bless {
      _coro_state => (new Coro::State $_[0] && \&_newcoro, @_),
   }, $class;
}

=item $process->ready

Put the current process into the ready queue.

=cut

sub ready {
   push @ready, $_[0];
}

=back

=cut

1;

=head1 BUGS/LIMITATIONS

 - could be faster, especially when the core would introduce special
   support for coroutines (like it does for threads).
 - there is still a memleak on coroutine termination that I could not
   identify. Could be as small as a single SV.
 - this module is not well-tested.
 - if variables or arguments "disappear" (become undef) or become
   corrupted please contact the author so he cen iron out the
   remaining bugs.
 - this module is not thread-safe. You must only ever use this module from
   the same thread (this requirement might be loosened in the future to
   allow per-thread schedulers, but Coro::State does not yet allow this).

=head1 SEE ALSO

L<Coro::Channel>, L<Coro::Cont>, L<Coro::Specific>, L<Coro::Semaphore>,
L<Coro::Signal>, L<Coro::State>, L<Coro::Event>.

=head1 AUTHOR

 Marc Lehmann <pcg@goof.com>
 http://www.goof.com/pcg/marc/

=cut

Revision:	1.23
Committed:	Mon Jul 23 04:23:32 2001 UTC (22 years, 10 months ago) by root
Branch:	MAIN
Changes since 1.22:	+17 -25 lines
Log Message:	* empty log message *
#	Content
1	=head1 NAME
2
3	Coro - coroutine process abstraction
4
5	=head1 SYNOPSIS
6
7	use Coro;
8
9	async {
10	# some asynchronous thread of execution
11	};
12
13	# alternatively create an async process like this:
14
15	sub some_func : Coro {
16	# some more async code
17	}
18
19	cede;
20
21	=head1 DESCRIPTION
22
23	This module collection manages coroutines. Coroutines are similar to
24	Threads but don't run in parallel.
25
26	This module is still experimental, see the BUGS section below.
27
28	In this module, coroutines are defined as "callchain + lexical variables
29	+ @_ + $_ + $@ + $^W + C stack), that is, a coroutine has it's own
30	callchain, it's own set of lexicals and it's own set of perl's most
31	important global variables.
32
33	=cut
34
35	package Coro;
36
37	use Coro::State;
38
39	use base Exporter;
40
41	$VERSION = 0.10;
42
43	@EXPORT = qw(async cede schedule terminate current);
44	@EXPORT_OK = qw($current);
45
46	{
47	my @async;
48
49	# this way of handling attributes simply is NOT scalable ;()
50	sub import {
51	Coro->export_to_level(1, @_);
52	my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
53	*{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
54	my ($package, $ref) = (shift, shift);
55	my @attrs;
56	for (@_) {
57	if ($_ eq "Coro") {
58	push @async, $ref;
59	} else {
60	push @attrs, $_;
61	}
62	}
63	return $old ? $old->($package, $ref, @attrs) : @attrs;
64	};
65	}
66
67	sub INIT {
68	&async(pop @async) while @async;
69	}
70	}
71
72	=item $main
73
74	This coroutine represents the main program.
75
76	=cut
77
78	our $main = new Coro;
79
80	=item $current (or as function: current)
81
82	The current coroutine (the last coroutine switched to). The initial value is C<$main> (of course).
83
84	=cut
85
86	# maybe some other module used Coro::Specific before...
87	if ($current) {
88	$main->{specific} = $current->{specific};
89	}
90
91	our $current = $main;
92
93	sub current() { $current }
94
95	=item $idle
96
97	The coroutine to switch to when no other coroutine is running. The default
98	implementation prints "FATAL: deadlock detected" and exits.
99
100	=cut
101
102	# should be done using priorities :(
103	our $idle = new Coro sub {
104	print STDERR "FATAL: deadlock detected\n";
105	exit(51);
106	};
107
108	# we really need priorities...
109	my @ready; # the ready queue. hehe, rather broken ;)
110
111	# static methods. not really.
112
113	=head2 STATIC METHODS
114
115	Static methods are actually functions that operate on the current process only.
116
117	=over 4
118
119	=item async { ... } [@args...]
120
121	Create a new asynchronous process and return it's process object
122	(usually unused). When the sub returns the new process is automatically
123	terminated.
124
125	# create a new coroutine that just prints its arguments
126	async {
127	print "@_\n";
128	} 1,2,3,4;
129
130	The coderef you submit MUST NOT be a closure that refers to variables
131	in an outer scope. This does NOT work. Pass arguments into it instead.
132
133	=cut
134
135	sub async(&@) {
136	my $pid = new Coro @_;
137	$pid->ready;
138	$pid;
139	}
140
141	=item schedule
142
143	Calls the scheduler. Please note that the current process will not be put
144	into the ready queue, so calling this function usually means you will
145	never be called again.
146
147	=cut
148
149	my $prev;
150
151	sub schedule {
152	# should be done using priorities :(
153	($prev, $current) = ($current, shift @ready \|\| $idle);
154	Coro::State::transfer($prev, $current);
155	}
156
157	=item cede
158
159	"Cede" to other processes. This function puts the current process into the
160	ready queue and calls C<schedule>, which has the effect of giving up the
161	current "timeslice" to other coroutines of the same or higher priority.
162
163	=cut
164
165	sub cede {
166	$current->ready;
167	&schedule;
168	}
169
170	=item terminate
171
172	Terminates the current process.
173
174	Future versions of this function will allow result arguments.
175
176	=cut
177
178	# this coroutine is necessary because a coroutine
179	# cannot destroy itself.
180	my @destroy;
181	my $terminate = new Coro sub {
182	while() {
183	delete ((pop @destroy)->{_coro_state}) while @destroy;
184	&schedule;
185	}
186	};
187
188	sub terminate {
189	push @destroy, $current;
190	$terminate->ready;
191	&schedule;
192	# NORETURN
193	}
194
195	=back
196
197	# dynamic methods
198
199	=head2 PROCESS METHODS
200
201	These are the methods you can call on process objects.
202
203	=over 4
204
205	=item new Coro \&sub [, @args...]
206
207	Create a new process and return it. When the sub returns the process
208	automatically terminates. To start the process you must first put it into
209	the ready queue by calling the ready method.
210
211	The coderef you submit MUST NOT be a closure that refers to variables
212	in an outer scope. This does NOT work. Pass arguments into it instead.
213
214	=cut
215
216	sub _newcoro {
217	terminate &{+shift};
218	}
219
220	sub new {
221	my $class = shift;
222	bless {
223	_coro_state => (new Coro::State $_[0] && \&_newcoro, @_),
224	}, $class;
225	}
226
227	=item $process->ready
228
229	Put the current process into the ready queue.
230
231	=cut
232
233	sub ready {
234	push @ready, $_[0];
235	}
236
237	=back
238
239	=cut
240
241	1;
242
243	=head1 BUGS/LIMITATIONS
244
245	- could be faster, especially when the core would introduce special
246	support for coroutines (like it does for threads).
247	- there is still a memleak on coroutine termination that I could not
248	identify. Could be as small as a single SV.
249	- this module is not well-tested.
250	- if variables or arguments "disappear" (become undef) or become
251	corrupted please contact the author so he cen iron out the
252	remaining bugs.
253	- this module is not thread-safe. You must only ever use this module from
254	the same thread (this requirement might be loosened in the future to
255	allow per-thread schedulers, but Coro::State does not yet allow this).
256
257	=head1 SEE ALSO
258
259	L<Coro::Channel>, L<Coro::Cont>, L<Coro::Specific>, L<Coro::Semaphore>,
260	L<Coro::Signal>, L<Coro::State>, L<Coro::Event>.
261
262	=head1 AUTHOR
263
264	Marc Lehmann <pcg@goof.com>
265	http://www.goof.com/pcg/marc/
266
267	=cut
268