Coro/Coro.pm

=head1 NAME

Coro - coroutine process abstraction

=head1 SYNOPSIS

 use Coro;

 async {
    # some asynchronous thread of execution
 };

 # alternatively create an async process like this:

 sub some_func : Coro {
    # some more async code
 }

 cede;

=head1 DESCRIPTION

This module collection manages coroutines. Coroutines are similar to
threads but don't run in parallel.

In this module, coroutines are defined as "callchain + lexical variables
+ @_ + $_ + $@ + $^W + C stack), that is, a coroutine has it's own
callchain, it's own set of lexicals and it's own set of perl's most
important global variables.

=cut

package Coro;

use strict;
no warnings "uninitialized";

use Coro::State;

use base Exporter::;

our $idle;    # idle coroutine
our $main;    # main coroutine
our $current; # current coroutine

our $VERSION = '2.5';

our @EXPORT = qw(async cede schedule terminate current);
our %EXPORT_TAGS = (
      prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
);
our @EXPORT_OK = @{$EXPORT_TAGS{prio}};

{
   my @async;
   my $init;

   # this way of handling attributes simply is NOT scalable ;()
   sub import {
      no strict 'refs';

      Coro->export_to_level(1, @_);

      my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
      *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
         my ($package, $ref) = (shift, shift);
         my @attrs;
         for (@_) {
            if ($_ eq "Coro") {
               push @async, $ref;
               unless ($init++) {
                  eval q{
                     sub INIT {
                        &async(pop @async) while @async;
                     }
                  };
               }
            } else {
               push @attrs, $_;
            }
         }
         return $old ? $old->($package, $ref, @attrs) : @attrs;
      };
   }

}

=over 4

=item $main

This coroutine represents the main program.

=cut

$main = new Coro;

=item $current (or as function: current)

The current coroutine (the last coroutine switched to). The initial value is C<$main> (of course).

=cut

# maybe some other module used Coro::Specific before...
if ($current) {
   $main->{specific} = $current->{specific};
}

$current = $main;

sub current() { $current }

=item $idle

The coroutine to switch to when no other coroutine is running. The default
implementation prints "FATAL: deadlock detected" and exits.

=cut

# should be done using priorities :(
$idle = new Coro sub {
   print STDERR "FATAL: deadlock detected\n";
   exit(51);
};

# this coroutine is necessary because a coroutine
# cannot destroy itself.
my @destroy;
my $manager;
$manager = new Coro sub {
   while () {
      # by overwriting the state object with the manager we destroy it
      # while still being able to schedule this coroutine (in case it has
      # been readied multiple times. this is harmless since the manager
      # can be called as many times as neccessary and will always
      # remove itself from the runqueue
      while (@destroy) {
         my $coro = pop @destroy;
         $coro->{status} ||= [];
         $_->ready for @{delete $coro->{join} || []};

         # the next line destroys the _coro_state, but keeps the
         # process itself intact (we basically make it a zombie
         # process that always runs the manager thread, so it's possible
         # to transfer() to this process).
         $coro->{_coro_state} = $manager->{_coro_state};
      }
      &schedule;
   }
};

# static methods. not really.

=back

=head2 STATIC METHODS

Static methods are actually functions that operate on the current process only.

=over 4

=item async { ... } [@args...]

Create a new asynchronous process and return it's process object
(usually unused). When the sub returns the new process is automatically
terminated.

When the coroutine dies, the program will exit, just as in the main
program.

   # create a new coroutine that just prints its arguments
   async {
      print "@_\n";
   } 1,2,3,4;

=cut

sub async(&@) {
   my $pid = new Coro @_;
   $manager->ready; # this ensures that the stack is cloned from the manager
   $pid->ready;
   $pid;
}

=item schedule

Calls the scheduler. Please note that the current process will not be put
into the ready queue, so calling this function usually means you will
never be called again.

=cut

=item cede

"Cede" to other processes. This function puts the current process into the
ready queue and calls C<schedule>, which has the effect of giving up the
current "timeslice" to other coroutines of the same or higher priority.

=cut

=item terminate [arg...]

Terminates the current process with the given status values (see L<cancel>).

=cut

sub terminate {
   $current->cancel (@_);
}

=back

# dynamic methods

=head2 PROCESS METHODS

These are the methods you can call on process objects.

=over 4

=item new Coro \&sub [, @args...]

Create a new process and return it. When the sub returns the process
automatically terminates as if C<terminate> with the returned values were
called. To make the process run you must first put it into the ready queue
by calling the ready method.

=cut

sub _newcoro {
   terminate &{+shift};
}

sub new {
   my $class = shift;
   bless {
      _coro_state => (new Coro::State $_[0] && \&_newcoro, @_),
   }, $class;
}

=item $process->ready

Put the given process into the ready queue.

=cut

=item $process->cancel (arg...)

Terminates the given process and makes it return the given arguments as
status (default: the empty list).

=cut

sub cancel {
   my $self = shift;
   $self->{status} = [@_];
   push @destroy, $self;
   $manager->ready;
   &schedule if $current == $self;
}

=item $process->join

Wait until the coroutine terminates and return any values given to the
C<terminate> or C<cancel> functions. C<join> can be called multiple times
from multiple processes.

=cut

sub join {
   my $self = shift;
   unless ($self->{status}) {
      push @{$self->{join}}, $current;
      &schedule;
   }
   wantarray ? @{$self->{status}} : $self->{status}[0];
}

=item $oldprio = $process->prio($newprio)

Sets (or gets, if the argument is missing) the priority of the
process. Higher priority processes get run before lower priority
processes. Priorities are small signed integers (currently -4 .. +3),
that you can refer to using PRIO_xxx constants (use the import tag :prio
to get then):

   PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
       3    >     1     >      0      >    -1    >    -3     >    -4

   # set priority to HIGH
   current->prio(PRIO_HIGH);

The idle coroutine ($Coro::idle) always has a lower priority than any
existing coroutine.

Changing the priority of the current process will take effect immediately,
but changing the priority of processes in the ready queue (but not
running) will only take effect after the next schedule (of that
process). This is a bug that will be fixed in some future version.

=cut

sub prio {
   my $old = $_[0]{prio};
   $_[0]{prio} = $_[1] if @_ > 1;
   $old;
}

=item $newprio = $process->nice($change)

Similar to C<prio>, but subtract the given value from the priority (i.e.
higher values mean lower priority, just as in unix).

=cut

sub nice {
   $_[0]{prio} -= $_[1];
}

=item $olddesc = $process->desc($newdesc)

Sets (or gets in case the argument is missing) the description for this
process. This is just a free-form string you can associate with a process.

=cut

sub desc {
   my $old = $_[0]{desc};
   $_[0]{desc} = $_[1] if @_ > 1;
   $old;
}

=back

=cut

1;

=head1 BUGS/LIMITATIONS

 - you must make very sure that no coro is still active on global
   destruction. very bad things might happen otherwise (usually segfaults).

 - this module is not thread-safe. You should only ever use this module
   from the same thread (this requirement might be losened in the future
   to allow per-thread schedulers, but Coro::State does not yet allow
   this).

=head1 SEE ALSO

Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.

Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.

Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.

Embedding: L<Coro:MakeMaker>

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

Revision:	1.80
Committed:	Mon Nov 6 19:56:26 2006 UTC (17 years, 7 months ago) by root
Branch:	MAIN
CVS Tags:	rel-2_5
Changes since 1.79:	+1 -1 lines
Log Message:	* empty log message *
#	Content
1	=head1 NAME
2
3	Coro - coroutine process abstraction
4
5	=head1 SYNOPSIS
6
7	use Coro;
8
9	async {
10	# some asynchronous thread of execution
11	};
12
13	# alternatively create an async process like this:
14
15	sub some_func : Coro {
16	# some more async code
17	}
18
19	cede;
20
21	=head1 DESCRIPTION
22
23	This module collection manages coroutines. Coroutines are similar to
24	threads but don't run in parallel.
25
26	In this module, coroutines are defined as "callchain + lexical variables
27	+ @_ + $_ + $@ + $^W + C stack), that is, a coroutine has it's own
28	callchain, it's own set of lexicals and it's own set of perl's most
29	important global variables.
30
31	=cut
32
33	package Coro;
34
35	use strict;
36	no warnings "uninitialized";
37
38	use Coro::State;
39
40	use base Exporter::;
41
42	our $idle; # idle coroutine
43	our $main; # main coroutine
44	our $current; # current coroutine
45
46	our $VERSION = '2.5';
47
48	our @EXPORT = qw(async cede schedule terminate current);
49	our %EXPORT_TAGS = (
50	prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
51	);
52	our @EXPORT_OK = @{$EXPORT_TAGS{prio}};
53
54	{
55	my @async;
56	my $init;
57
58	# this way of handling attributes simply is NOT scalable ;()
59	sub import {
60	no strict 'refs';
61
62	Coro->export_to_level(1, @_);
63
64	my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
65	*{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
66	my ($package, $ref) = (shift, shift);
67	my @attrs;
68	for (@_) {
69	if ($_ eq "Coro") {
70	push @async, $ref;
71	unless ($init++) {
72	eval q{
73	sub INIT {
74	&async(pop @async) while @async;
75	}
76	};
77	}
78	} else {
79	push @attrs, $_;
80	}
81	}
82	return $old ? $old->($package, $ref, @attrs) : @attrs;
83	};
84	}
85
86	}
87
88	=over 4
89
90	=item $main
91
92	This coroutine represents the main program.
93
94	=cut
95
96	$main = new Coro;
97
98	=item $current (or as function: current)
99
100	The current coroutine (the last coroutine switched to). The initial value is C<$main> (of course).
101
102	=cut
103
104	# maybe some other module used Coro::Specific before...
105	if ($current) {
106	$main->{specific} = $current->{specific};
107	}
108
109	$current = $main;
110
111	sub current() { $current }
112
113	=item $idle
114
115	The coroutine to switch to when no other coroutine is running. The default
116	implementation prints "FATAL: deadlock detected" and exits.
117
118	=cut
119
120	# should be done using priorities :(
121	$idle = new Coro sub {
122	print STDERR "FATAL: deadlock detected\n";
123	exit(51);
124	};
125
126	# this coroutine is necessary because a coroutine
127	# cannot destroy itself.
128	my @destroy;
129	my $manager;
130	$manager = new Coro sub {
131	while () {
132	# by overwriting the state object with the manager we destroy it
133	# while still being able to schedule this coroutine (in case it has
134	# been readied multiple times. this is harmless since the manager
135	# can be called as many times as neccessary and will always
136	# remove itself from the runqueue
137	while (@destroy) {
138	my $coro = pop @destroy;
139	$coro->{status} \|\|= [];
140	$_->ready for @{delete $coro->{join} \|\| []};
141
142	# the next line destroys the _coro_state, but keeps the
143	# process itself intact (we basically make it a zombie
144	# process that always runs the manager thread, so it's possible
145	# to transfer() to this process).
146	$coro->{_coro_state} = $manager->{_coro_state};
147	}
148	&schedule;
149	}
150	};
151
152	# static methods. not really.
153
154	=back
155
156	=head2 STATIC METHODS
157
158	Static methods are actually functions that operate on the current process only.
159
160	=over 4
161
162	=item async { ... } [@args...]
163
164	Create a new asynchronous process and return it's process object
165	(usually unused). When the sub returns the new process is automatically
166	terminated.
167
168	When the coroutine dies, the program will exit, just as in the main
169	program.
170
171	# create a new coroutine that just prints its arguments
172	async {
173	print "@_\n";
174	} 1,2,3,4;
175
176	=cut
177
178	sub async(&@) {
179	my $pid = new Coro @_;
180	$manager->ready; # this ensures that the stack is cloned from the manager
181	$pid->ready;
182	$pid;
183	}
184
185	=item schedule
186
187	Calls the scheduler. Please note that the current process will not be put
188	into the ready queue, so calling this function usually means you will
189	never be called again.
190
191	=cut
192
193	=item cede
194
195	"Cede" to other processes. This function puts the current process into the
196	ready queue and calls C<schedule>, which has the effect of giving up the
197	current "timeslice" to other coroutines of the same or higher priority.
198
199	=cut
200
201	=item terminate [arg...]
202
203	Terminates the current process with the given status values (see L<cancel>).
204
205	=cut
206
207	sub terminate {
208	$current->cancel (@_);
209	}
210
211	=back
212
213	# dynamic methods
214
215	=head2 PROCESS METHODS
216
217	These are the methods you can call on process objects.
218
219	=over 4
220
221	=item new Coro \&sub [, @args...]
222
223	Create a new process and return it. When the sub returns the process
224	automatically terminates as if C<terminate> with the returned values were
225	called. To make the process run you must first put it into the ready queue
226	by calling the ready method.
227
228	=cut
229
230	sub _newcoro {
231	terminate &{+shift};
232	}
233
234	sub new {
235	my $class = shift;
236	bless {
237	_coro_state => (new Coro::State $_[0] && \&_newcoro, @_),
238	}, $class;
239	}
240
241	=item $process->ready
242
243	Put the given process into the ready queue.
244
245	=cut
246
247	=item $process->cancel (arg...)
248
249	Terminates the given process and makes it return the given arguments as
250	status (default: the empty list).
251
252	=cut
253
254	sub cancel {
255	my $self = shift;
256	$self->{status} = [@_];
257	push @destroy, $self;
258	$manager->ready;
259	&schedule if $current == $self;
260	}
261
262	=item $process->join
263
264	Wait until the coroutine terminates and return any values given to the
265	C<terminate> or C<cancel> functions. C<join> can be called multiple times
266	from multiple processes.
267
268	=cut
269
270	sub join {
271	my $self = shift;
272	unless ($self->{status}) {
273	push @{$self->{join}}, $current;
274	&schedule;
275	}
276	wantarray ? @{$self->{status}} : $self->{status}[0];
277	}
278
279	=item $oldprio = $process->prio($newprio)
280
281	Sets (or gets, if the argument is missing) the priority of the
282	process. Higher priority processes get run before lower priority
283	processes. Priorities are small signed integers (currently -4 .. +3),
284	that you can refer to using PRIO_xxx constants (use the import tag :prio
285	to get then):
286
287	PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
288	3 > 1 > 0 > -1 > -3 > -4
289
290	# set priority to HIGH
291	current->prio(PRIO_HIGH);
292
293	The idle coroutine ($Coro::idle) always has a lower priority than any
294	existing coroutine.
295
296	Changing the priority of the current process will take effect immediately,
297	but changing the priority of processes in the ready queue (but not
298	running) will only take effect after the next schedule (of that
299	process). This is a bug that will be fixed in some future version.
300
301	=cut
302
303	sub prio {
304	my $old = $_[0]{prio};
305	$_[0]{prio} = $_[1] if @_ > 1;
306	$old;
307	}
308
309	=item $newprio = $process->nice($change)
310
311	Similar to C<prio>, but subtract the given value from the priority (i.e.
312	higher values mean lower priority, just as in unix).
313
314	=cut
315
316	sub nice {
317	$_[0]{prio} -= $_[1];
318	}
319
320	=item $olddesc = $process->desc($newdesc)
321
322	Sets (or gets in case the argument is missing) the description for this
323	process. This is just a free-form string you can associate with a process.
324
325	=cut
326
327	sub desc {
328	my $old = $_[0]{desc};
329	$_[0]{desc} = $_[1] if @_ > 1;
330	$old;
331	}
332
333	=back
334
335	=cut
336
337	1;
338
339	=head1 BUGS/LIMITATIONS
340
341	- you must make very sure that no coro is still active on global
342	destruction. very bad things might happen otherwise (usually segfaults).
343
344	- this module is not thread-safe. You should only ever use this module
345	from the same thread (this requirement might be losened in the future
346	to allow per-thread schedulers, but Coro::State does not yet allow
347	this).
348
349	=head1 SEE ALSO
350
351	Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.
352
353	Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.
354
355	Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.
356
357	Embedding: L<Coro:MakeMaker>
358
359	=head1 AUTHOR
360
361	Marc Lehmann <schmorp@schmorp.de>
362	http://home.schmorp.de/
363
364	=cut
365