Coro/Coro.pm

=head1 NAME

Coro - coroutine process abstraction

=head1 SYNOPSIS

 use Coro;

 async {
    # some asynchronous thread of execution
 };

 # alternatively create an async process like this:

 sub some_func : Coro {
    # some more async code
 }

 cede;

=head1 DESCRIPTION

This module collection manages coroutines. Coroutines are similar to
threads but don't run in parallel.

In this module, coroutines are defined as "callchain + lexical variables
+ @_ + $_ + $@ + $^W + C stack), that is, a coroutine has it's own
callchain, it's own set of lexicals and it's own set of perl's most
important global variables.

=cut

package Coro;

use strict;
no warnings "uninitialized";

use Coro::State;

use base qw(Coro::State Exporter);

our $idle;    # idle handler
our $main;    # main coroutine
our $current; # current coroutine

our $VERSION = '3.0';

our @EXPORT = qw(async cede schedule terminate current);
our %EXPORT_TAGS = (
      prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
);
our @EXPORT_OK = @{$EXPORT_TAGS{prio}};

{
   my @async;
   my $init;

   # this way of handling attributes simply is NOT scalable ;()
   sub import {
      no strict 'refs';

      Coro->export_to_level(1, @_);

      my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
      *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
         my ($package, $ref) = (shift, shift);
         my @attrs;
         for (@_) {
            if ($_ eq "Coro") {
               push @async, $ref;
               unless ($init++) {
                  eval q{
                     sub INIT {
                        &async(pop @async) while @async;
                     }
                  };
               }
            } else {
               push @attrs, $_;
            }
         }
         return $old ? $old->($package, $ref, @attrs) : @attrs;
      };
   }

}

=over 4

=item $main

This coroutine represents the main program.

=cut

$main = new Coro;

=item $current (or as function: current)

The current coroutine (the last coroutine switched to). The initial value
is C<$main> (of course).

This variable is B<strictly> I<read-only>. It is provided for performance
reasons. If performance is not essentiel you are encouraged to use the
C<Coro::current> function instead.

=cut

# maybe some other module used Coro::Specific before...
if ($current) {
   $main->{specific} = $current->{specific};
}

$current = $main;

sub current() { $current }

=item $idle

A callback that is called whenever the scheduler finds no ready coroutines
to run. The default implementation prints "FATAL: deadlock detected" and
exits, because the program has no other way to continue.

This hook is overwritten by modules such as C<Coro::Timer> and
C<Coro::Event> to wait on an external event that hopefully wake up a
coroutine so the scheduler can run it.

Please note that if your callback recursively invokes perl (e.g. for event
handlers), then it must be prepared to be called recursively.

=cut

$idle = sub {
   print STDERR "FATAL: deadlock detected\n";
   exit (51);
};

# this coroutine is necessary because a coroutine
# cannot destroy itself.
my @destroy;
my $manager; $manager = new Coro sub {
   while () {
      # by overwriting the state object with the manager we destroy it
      # while still being able to schedule this coroutine (in case it has
      # been readied multiple times. this is harmless since the manager
      # can be called as many times as neccessary and will always
      # remove itself from the runqueue
      while (@destroy) {
         my $coro = pop @destroy;
         $coro->{status} ||= [];
         $_->ready for @{delete $coro->{join} || []};

         # the next line destroys the coro state, but keeps the
         # process itself intact (we basically make it a zombie
         # process that always runs the manager thread, so it's possible
         # to transfer() to this process).
         $coro->_clone_state_from ($manager);
      }
      &schedule;
   }
};

# static methods. not really.

=back

=head2 STATIC METHODS

Static methods are actually functions that operate on the current process only.

=over 4

=item async { ... } [@args...]

Create a new asynchronous process and return it's process object
(usually unused). When the sub returns the new process is automatically
terminated.

Calling C<exit> in a coroutine will not work correctly, so do not do that.

When the coroutine dies, the program will exit, just as in the main
program.

   # create a new coroutine that just prints its arguments
   async {
      print "@_\n";
   } 1,2,3,4;

=cut

sub async(&@) {
   my $pid = new Coro @_;
   $pid->ready;
   $pid
}

=item schedule

Calls the scheduler. Please note that the current process will not be put
into the ready queue, so calling this function usually means you will
never be called again unless something else (e.g. an event handler) calls
ready.

The canonical way to wait on external events is this:

   {
      # remember current process
      my $current = $Coro::current;

      # register a hypothetical event handler
      on_event_invoke sub {
         # wake up sleeping coroutine
         $current->ready;
         undef $current;
      };

      # call schedule until event occured.
      # in case we are woken up for other reasons
      # (current still defined), loop.
      Coro::schedule while $current;
   }

=cut

=item cede

"Cede" to other processes. This function puts the current process into the
ready queue and calls C<schedule>, which has the effect of giving up the
current "timeslice" to other coroutines of the same or higher priority.

=cut

=item terminate [arg...]

Terminates the current process with the given status values (see L<cancel>).

=cut

sub terminate {
   $current->cancel (@_);
}

=back

# dynamic methods

=head2 PROCESS METHODS

These are the methods you can call on process objects.

=over 4

=item new Coro \&sub [, @args...]

Create a new process and return it. When the sub returns the process
automatically terminates as if C<terminate> with the returned values were
called. To make the process run you must first put it into the ready queue
by calling the ready method.

Calling C<exit> in a coroutine will not work correctly, so do not do that.

=cut

sub _new_coro {
   terminate &{+shift};
}

sub new {
   my $class = shift;

   $class->SUPER::new (\&_new_coro, @_)
}

=item $success = $process->ready

Put the given process into the ready queue (according to it's priority)
and return true. If the process is already in the ready queue, do nothing
and return false.

=item $is_ready = $process->is_ready

Return wether the process is currently the ready queue or not,

=item $process->cancel (arg...)

Terminates the given process and makes it return the given arguments as
status (default: the empty list).

=cut

sub cancel {
   my $self = shift;
   $self->{status} = [@_];
   push @destroy, $self;
   $manager->ready;
   &schedule if $current == $self;
}

=item $process->join

Wait until the coroutine terminates and return any values given to the
C<terminate> or C<cancel> functions. C<join> can be called multiple times
from multiple processes.

=cut

sub join {
   my $self = shift;
   unless ($self->{status}) {
      push @{$self->{join}}, $current;
      &schedule;
   }
   wantarray ? @{$self->{status}} : $self->{status}[0];
}

=item $oldprio = $process->prio ($newprio)

Sets (or gets, if the argument is missing) the priority of the
process. Higher priority processes get run before lower priority
processes. Priorities are small signed integers (currently -4 .. +3),
that you can refer to using PRIO_xxx constants (use the import tag :prio
to get then):

   PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
       3    >     1     >      0      >    -1    >    -3     >    -4

   # set priority to HIGH
   current->prio(PRIO_HIGH);

The idle coroutine ($Coro::idle) always has a lower priority than any
existing coroutine.

Changing the priority of the current process will take effect immediately,
but changing the priority of processes in the ready queue (but not
running) will only take effect after the next schedule (of that
process). This is a bug that will be fixed in some future version.

=item $newprio = $process->nice ($change)

Similar to C<prio>, but subtract the given value from the priority (i.e.
higher values mean lower priority, just as in unix).

=item $olddesc = $process->desc ($newdesc)

Sets (or gets in case the argument is missing) the description for this
process. This is just a free-form string you can associate with a process.

=cut

sub desc {
   my $old = $_[0]{desc};
   $_[0]{desc} = $_[1] if @_ > 1;
   $old;
}

=back

=cut

1;

=head1 BUGS/LIMITATIONS

 - you must make very sure that no coro is still active on global
   destruction. very bad things might happen otherwise (usually segfaults).

 - this module is not thread-safe. You should only ever use this module
   from the same thread (this requirement might be losened in the future
   to allow per-thread schedulers, but Coro::State does not yet allow
   this).

=head1 SEE ALSO

Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.

Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.

Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.

Embedding: L<Coro:MakeMaker>

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

Revision:	1.91
Committed:	Fri Dec 1 02:17:37 2006 UTC (17 years, 6 months ago) by root
Branch:	MAIN
Changes since 1.90:	+27 -4 lines
Log Message:	* empty log message *
#	Content
1	=head1 NAME
2
3	Coro - coroutine process abstraction
4
5	=head1 SYNOPSIS
6
7	use Coro;
8
9	async {
10	# some asynchronous thread of execution
11	};
12
13	# alternatively create an async process like this:
14
15	sub some_func : Coro {
16	# some more async code
17	}
18
19	cede;
20
21	=head1 DESCRIPTION
22
23	This module collection manages coroutines. Coroutines are similar to
24	threads but don't run in parallel.
25
26	In this module, coroutines are defined as "callchain + lexical variables
27	+ @_ + $_ + $@ + $^W + C stack), that is, a coroutine has it's own
28	callchain, it's own set of lexicals and it's own set of perl's most
29	important global variables.
30
31	=cut
32
33	package Coro;
34
35	use strict;
36	no warnings "uninitialized";
37
38	use Coro::State;
39
40	use base qw(Coro::State Exporter);
41
42	our $idle; # idle handler
43	our $main; # main coroutine
44	our $current; # current coroutine
45
46	our $VERSION = '3.0';
47
48	our @EXPORT = qw(async cede schedule terminate current);
49	our %EXPORT_TAGS = (
50	prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
51	);
52	our @EXPORT_OK = @{$EXPORT_TAGS{prio}};
53
54	{
55	my @async;
56	my $init;
57
58	# this way of handling attributes simply is NOT scalable ;()
59	sub import {
60	no strict 'refs';
61
62	Coro->export_to_level(1, @_);
63
64	my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
65	*{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
66	my ($package, $ref) = (shift, shift);
67	my @attrs;
68	for (@_) {
69	if ($_ eq "Coro") {
70	push @async, $ref;
71	unless ($init++) {
72	eval q{
73	sub INIT {
74	&async(pop @async) while @async;
75	}
76	};
77	}
78	} else {
79	push @attrs, $_;
80	}
81	}
82	return $old ? $old->($package, $ref, @attrs) : @attrs;
83	};
84	}
85
86	}
87
88	=over 4
89
90	=item $main
91
92	This coroutine represents the main program.
93
94	=cut
95
96	$main = new Coro;
97
98	=item $current (or as function: current)
99
100	The current coroutine (the last coroutine switched to). The initial value
101	is C<$main> (of course).
102
103	This variable is B<strictly> I<read-only>. It is provided for performance
104	reasons. If performance is not essentiel you are encouraged to use the
105	C<Coro::current> function instead.
106
107	=cut
108
109	# maybe some other module used Coro::Specific before...
110	if ($current) {
111	$main->{specific} = $current->{specific};
112	}
113
114	$current = $main;
115
116	sub current() { $current }
117
118	=item $idle
119
120	A callback that is called whenever the scheduler finds no ready coroutines
121	to run. The default implementation prints "FATAL: deadlock detected" and
122	exits, because the program has no other way to continue.
123
124	This hook is overwritten by modules such as C<Coro::Timer> and
125	C<Coro::Event> to wait on an external event that hopefully wake up a
126	coroutine so the scheduler can run it.
127
128	Please note that if your callback recursively invokes perl (e.g. for event
129	handlers), then it must be prepared to be called recursively.
130
131	=cut
132
133	$idle = sub {
134	print STDERR "FATAL: deadlock detected\n";
135	exit (51);
136	};
137
138	# this coroutine is necessary because a coroutine
139	# cannot destroy itself.
140	my @destroy;
141	my $manager; $manager = new Coro sub {
142	while () {
143	# by overwriting the state object with the manager we destroy it
144	# while still being able to schedule this coroutine (in case it has
145	# been readied multiple times. this is harmless since the manager
146	# can be called as many times as neccessary and will always
147	# remove itself from the runqueue
148	while (@destroy) {
149	my $coro = pop @destroy;
150	$coro->{status} \|\|= [];
151	$_->ready for @{delete $coro->{join} \|\| []};
152
153	# the next line destroys the coro state, but keeps the
154	# process itself intact (we basically make it a zombie
155	# process that always runs the manager thread, so it's possible
156	# to transfer() to this process).
157	$coro->_clone_state_from ($manager);
158	}
159	&schedule;
160	}
161	};
162
163	# static methods. not really.
164
165	=back
166
167	=head2 STATIC METHODS
168
169	Static methods are actually functions that operate on the current process only.
170
171	=over 4
172
173	=item async { ... } [@args...]
174
175	Create a new asynchronous process and return it's process object
176	(usually unused). When the sub returns the new process is automatically
177	terminated.
178
179	Calling C<exit> in a coroutine will not work correctly, so do not do that.
180
181	When the coroutine dies, the program will exit, just as in the main
182	program.
183
184	# create a new coroutine that just prints its arguments
185	async {
186	print "@_\n";
187	} 1,2,3,4;
188
189	=cut
190
191	sub async(&@) {
192	my $pid = new Coro @_;
193	$pid->ready;
194	$pid
195	}
196
197	=item schedule
198
199	Calls the scheduler. Please note that the current process will not be put
200	into the ready queue, so calling this function usually means you will
201	never be called again unless something else (e.g. an event handler) calls
202	ready.
203
204	The canonical way to wait on external events is this:
205
206	{
207	# remember current process
208	my $current = $Coro::current;
209
210	# register a hypothetical event handler
211	on_event_invoke sub {
212	# wake up sleeping coroutine
213	$current->ready;
214	undef $current;
215	};
216
217	# call schedule until event occured.
218	# in case we are woken up for other reasons
219	# (current still defined), loop.
220	Coro::schedule while $current;
221	}
222
223	=cut
224
225	=item cede
226
227	"Cede" to other processes. This function puts the current process into the
228	ready queue and calls C<schedule>, which has the effect of giving up the
229	current "timeslice" to other coroutines of the same or higher priority.
230
231	=cut
232
233	=item terminate [arg...]
234
235	Terminates the current process with the given status values (see L<cancel>).
236
237	=cut
238
239	sub terminate {
240	$current->cancel (@_);
241	}
242
243	=back
244
245	# dynamic methods
246
247	=head2 PROCESS METHODS
248
249	These are the methods you can call on process objects.
250
251	=over 4
252
253	=item new Coro \&sub [, @args...]
254
255	Create a new process and return it. When the sub returns the process
256	automatically terminates as if C<terminate> with the returned values were
257	called. To make the process run you must first put it into the ready queue
258	by calling the ready method.
259
260	Calling C<exit> in a coroutine will not work correctly, so do not do that.
261
262	=cut
263
264	sub _new_coro {
265	terminate &{+shift};
266	}
267
268	sub new {
269	my $class = shift;
270
271	$class->SUPER::new (\&_new_coro, @_)
272	}
273
274	=item $success = $process->ready
275
276	Put the given process into the ready queue (according to it's priority)
277	and return true. If the process is already in the ready queue, do nothing
278	and return false.
279
280	=item $is_ready = $process->is_ready
281
282	Return wether the process is currently the ready queue or not,
283
284	=item $process->cancel (arg...)
285
286	Terminates the given process and makes it return the given arguments as
287	status (default: the empty list).
288
289	=cut
290
291	sub cancel {
292	my $self = shift;
293	$self->{status} = [@_];
294	push @destroy, $self;
295	$manager->ready;
296	&schedule if $current == $self;
297	}
298
299	=item $process->join
300
301	Wait until the coroutine terminates and return any values given to the
302	C<terminate> or C<cancel> functions. C<join> can be called multiple times
303	from multiple processes.
304
305	=cut
306
307	sub join {
308	my $self = shift;
309	unless ($self->{status}) {
310	push @{$self->{join}}, $current;
311	&schedule;
312	}
313	wantarray ? @{$self->{status}} : $self->{status}[0];
314	}
315
316	=item $oldprio = $process->prio ($newprio)
317
318	Sets (or gets, if the argument is missing) the priority of the
319	process. Higher priority processes get run before lower priority
320	processes. Priorities are small signed integers (currently -4 .. +3),
321	that you can refer to using PRIO_xxx constants (use the import tag :prio
322	to get then):
323
324	PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
325	3 > 1 > 0 > -1 > -3 > -4
326
327	# set priority to HIGH
328	current->prio(PRIO_HIGH);
329
330	The idle coroutine ($Coro::idle) always has a lower priority than any
331	existing coroutine.
332
333	Changing the priority of the current process will take effect immediately,
334	but changing the priority of processes in the ready queue (but not
335	running) will only take effect after the next schedule (of that
336	process). This is a bug that will be fixed in some future version.
337
338	=item $newprio = $process->nice ($change)
339
340	Similar to C<prio>, but subtract the given value from the priority (i.e.
341	higher values mean lower priority, just as in unix).
342
343	=item $olddesc = $process->desc ($newdesc)
344
345	Sets (or gets in case the argument is missing) the description for this
346	process. This is just a free-form string you can associate with a process.
347
348	=cut
349
350	sub desc {
351	my $old = $_[0]{desc};
352	$_[0]{desc} = $_[1] if @_ > 1;
353	$old;
354	}
355
356	=back
357
358	=cut
359
360	1;
361
362	=head1 BUGS/LIMITATIONS
363
364	- you must make very sure that no coro is still active on global
365	destruction. very bad things might happen otherwise (usually segfaults).
366
367	- this module is not thread-safe. You should only ever use this module
368	from the same thread (this requirement might be losened in the future
369	to allow per-thread schedulers, but Coro::State does not yet allow
370	this).
371
372	=head1 SEE ALSO
373
374	Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.
375
376	Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.
377
378	Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.
379
380	Embedding: L<Coro:MakeMaker>
381
382	=head1 AUTHOR
383
384	Marc Lehmann <schmorp@schmorp.de>
385	http://home.schmorp.de/
386
387	=cut
388