Coro/Coro.pm

=head1 NAME

Coro - coroutine process abstraction

=head1 SYNOPSIS

  use Coro;
  
  async {
     # some asynchronous thread of execution
     print "2\n";
     cede; # yield back to main
     print "4\n";
  };
  print "1\n";
  cede; # yield to coroutine
  print "3\n";
  cede; # and again
  
  # use locking
  my $lock = new Coro::Semaphore;
  my $locked;
  
  $lock->down;
  $locked = 1;
  $lock->up;

=head1 DESCRIPTION

This module collection manages coroutines. Coroutines are similar
to threads but don't run in parallel at the same time even on SMP
machines. The specific flavor of coroutine used in this module also
guarantees you that it will not switch between coroutines unless
necessary, at easily-identified points in your program, so locking and
parallel access are rarely an issue, making coroutine programming much
safer than threads programming.

(Perl, however, does not natively support real threads but instead does a
very slow and memory-intensive emulation of processes using threads. This
is a performance win on Windows machines, and a loss everywhere else).

In this module, coroutines are defined as "callchain + lexical variables +
@_ + $_ + $@ + $/ + C stack), that is, a coroutine has its own callchain,
its own set of lexicals and its own set of perls most important global
variables (see L<Coro::State> for more configuration).

=cut

package Coro;

use strict;
no warnings "uninitialized";

use Coro::State;

use base qw(Coro::State Exporter);

our $idle;    # idle handler
our $main;    # main coroutine
our $current; # current coroutine

our $VERSION = 4.6;

our @EXPORT = qw(async async_pool cede schedule terminate current unblock_sub);
our %EXPORT_TAGS = (
      prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
);
our @EXPORT_OK = (@{$EXPORT_TAGS{prio}}, qw(nready));

=over 4

=item $main

This coroutine represents the main program.

=cut

$main = new Coro;

=item $current (or as function: current)

The current coroutine (the last coroutine switched to). The initial value
is C<$main> (of course).

This variable is B<strictly> I<read-only>. It is provided for performance
reasons. If performance is not essential you are encouraged to use the
C<Coro::current> function instead.

=cut

$main->{desc} = "[main::]";

# maybe some other module used Coro::Specific before...
$main->{_specific} = $current->{_specific}
   if $current;

_set_current $main;

sub current() { $current }

=item $idle

A callback that is called whenever the scheduler finds no ready coroutines
to run. The default implementation prints "FATAL: deadlock detected" and
exits, because the program has no other way to continue.

This hook is overwritten by modules such as C<Coro::Timer> and
C<Coro::Event> to wait on an external event that hopefully wake up a
coroutine so the scheduler can run it.

Please note that if your callback recursively invokes perl (e.g. for event
handlers), then it must be prepared to be called recursively itself.

=cut

$idle = sub {
   require Carp;
   Carp::croak ("FATAL: deadlock detected");
};

sub _cancel {
   my ($self) = @_;

   # free coroutine data and mark as destructed
   $self->_destroy
      or return;

   # call all destruction callbacks
   $_->(@{$self->{_status}})
      for @{(delete $self->{_on_destroy}) || []};
}

# this coroutine is necessary because a coroutine
# cannot destroy itself.
my @destroy;
my $manager;

$manager = new Coro sub {
   while () {
      (shift @destroy)->_cancel
         while @destroy;

      &schedule;
   }
};
$manager->desc ("[coro manager]");
$manager->prio (PRIO_MAX);

=back

=head2 STATIC METHODS

Static methods are actually functions that operate on the current coroutine only.

=over 4

=item async { ... } [@args...]

Create a new asynchronous coroutine and return it's coroutine object
(usually unused). When the sub returns the new coroutine is automatically
terminated.

See the C<Coro::State::new> constructor for info about the coroutine
environment in which coroutines run.

Calling C<exit> in a coroutine will do the same as calling exit outside
the coroutine. Likewise, when the coroutine dies, the program will exit,
just as it would in the main program.

   # create a new coroutine that just prints its arguments
   async {
      print "@_\n";
   } 1,2,3,4;

=cut

sub async(&@) {
   my $coro = new Coro @_;
   $coro->ready;
   $coro
}

=item async_pool { ... } [@args...]

Similar to C<async>, but uses a coroutine pool, so you should not call
terminate or join (although you are allowed to), and you get a coroutine
that might have executed other code already (which can be good or bad :).

Also, the block is executed in an C<eval> context and a warning will be
issued in case of an exception instead of terminating the program, as
C<async> does. As the coroutine is being reused, stuff like C<on_destroy>
will not work in the expected way, unless you call terminate or cancel,
which somehow defeats the purpose of pooling.

The priority will be reset to C<0> after each job, tracing will be
disabled, the description will be reset and the default output filehandle
gets restored, so you can change alkl these. Otherwise the coroutine will
be re-used "as-is": most notably if you change other per-coroutine global
stuff such as C<$/> you need to revert that change, which is most simply
done by using local as in C< local $/ >.

The pool size is limited to 8 idle coroutines (this can be adjusted by
changing $Coro::POOL_SIZE), and there can be as many non-idle coros as
required.

If you are concerned about pooled coroutines growing a lot because a
single C<async_pool> used a lot of stackspace you can e.g. C<async_pool
{ terminate }> once per second or so to slowly replenish the pool. In
addition to that, when the stacks used by a handler grows larger than 16kb
(adjustable with $Coro::POOL_RSS) it will also exit.

=cut

our $POOL_SIZE = 8;
our $POOL_RSS  = 16 * 1024;
our @async_pool;

sub pool_handler {
   my $cb;

   while () {
      eval {
         while () {
            _pool_1 $cb;
            &$cb;
            _pool_2 $cb;
            &schedule;
         }
      };

      last if $@ eq "\3async_pool terminate\2\n";
      warn $@ if $@;
   }
}

sub async_pool(&@) {
   # this is also inlined into the unlock_scheduler
   my $coro = (pop @async_pool) || new Coro \&pool_handler;

   $coro->{_invoke} = [@_];
   $coro->ready;

   $coro
}

=item schedule

Calls the scheduler. Please note that the current coroutine will not be put
into the ready queue, so calling this function usually means you will
never be called again unless something else (e.g. an event handler) calls
ready.

The canonical way to wait on external events is this:

   {
      # remember current coroutine
      my $current = $Coro::current;

      # register a hypothetical event handler
      on_event_invoke sub {
         # wake up sleeping coroutine
         $current->ready;
         undef $current;
      };

      # call schedule until event occurred.
      # in case we are woken up for other reasons
      # (current still defined), loop.
      Coro::schedule while $current;
   }

=item cede

"Cede" to other coroutines. This function puts the current coroutine into the
ready queue and calls C<schedule>, which has the effect of giving up the
current "timeslice" to other coroutines of the same or higher priority.

=item Coro::cede_notself

Works like cede, but is not exported by default and will cede to any
coroutine, regardless of priority, once.

=item terminate [arg...]

Terminates the current coroutine with the given status values (see L<cancel>).

=item killall

Kills/terminates/cancels all coroutines except the currently running
one. This is useful after a fork, either in the child or the parent, as
usually only one of them should inherit the running coroutines.

=cut

sub terminate {
   $current->cancel (@_);
}

sub killall {
   for (Coro::State::list) {
      $_->cancel
         if $_ != $current && UNIVERSAL::isa $_, "Coro";
   }
}

=back

=head2 COROUTINE METHODS

These are the methods you can call on coroutine objects.

=over 4

=item new Coro \&sub [, @args...]

Create a new coroutine and return it. When the sub returns the coroutine
automatically terminates as if C<terminate> with the returned values were
called. To make the coroutine run you must first put it into the ready queue
by calling the ready method.

See C<async> and C<Coro::State::new> for additional info about the
coroutine environment.

=cut

sub _run_coro {
   terminate &{+shift};
}

sub new {
   my $class = shift;

   $class->SUPER::new (\&_run_coro, @_)
}

=item $success = $coroutine->ready

Put the given coroutine into the ready queue (according to it's priority)
and return true. If the coroutine is already in the ready queue, do nothing
and return false.

=item $is_ready = $coroutine->is_ready

Return wether the coroutine is currently the ready queue or not,

=item $coroutine->cancel (arg...)

Terminates the given coroutine and makes it return the given arguments as
status (default: the empty list). Never returns if the coroutine is the
current coroutine.

=cut

sub cancel {
   my $self = shift;
   $self->{_status} = [@_];

   if ($current == $self) {
      push @destroy, $self;
      $manager->ready;
      &schedule while 1;
   } else {
      $self->_cancel;
   }
}

=item $coroutine->join

Wait until the coroutine terminates and return any values given to the
C<terminate> or C<cancel> functions. C<join> can be called concurrently
from multiple coroutines.

=cut

sub join {
   my $self = shift;

   unless ($self->{_status}) {
      my $current = $current;

      push @{$self->{_on_destroy}}, sub {
         $current->ready;
         undef $current;
      };

      &schedule while $current;
   }

   wantarray ? @{$self->{_status}} : $self->{_status}[0];
}

=item $coroutine->on_destroy (\&cb)

Registers a callback that is called when this coroutine gets destroyed,
but before it is joined. The callback gets passed the terminate arguments,
if any.

=cut

sub on_destroy {
   my ($self, $cb) = @_;

   push @{ $self->{_on_destroy} }, $cb;
}

=item $oldprio = $coroutine->prio ($newprio)

Sets (or gets, if the argument is missing) the priority of the
coroutine. Higher priority coroutines get run before lower priority
coroutines. Priorities are small signed integers (currently -4 .. +3),
that you can refer to using PRIO_xxx constants (use the import tag :prio
to get then):

   PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
       3    >     1     >      0      >    -1    >    -3     >    -4

   # set priority to HIGH
   current->prio(PRIO_HIGH);

The idle coroutine ($Coro::idle) always has a lower priority than any
existing coroutine.

Changing the priority of the current coroutine will take effect immediately,
but changing the priority of coroutines in the ready queue (but not
running) will only take effect after the next schedule (of that
coroutine). This is a bug that will be fixed in some future version.

=item $newprio = $coroutine->nice ($change)

Similar to C<prio>, but subtract the given value from the priority (i.e.
higher values mean lower priority, just as in unix).

=item $olddesc = $coroutine->desc ($newdesc)

Sets (or gets in case the argument is missing) the description for this
coroutine. This is just a free-form string you can associate with a coroutine.

This method simply sets the C<< $coroutine->{desc} >> member to the given string. You
can modify this member directly if you wish.

=item $coroutine->throw ([$scalar])

If C<$throw> is specified and defined, it will be thrown as an exception
inside the coroutine at the next convinient point in time (usually after
it gains control at the next schedule/transfer/cede). Otherwise clears the
exception object.

The exception object will be thrown "as is" with the specified scalar in
C<$@>, i.e. if it is a string, no line number or newline will be appended
(unlike with C<die>).

This can be used as a softer means than C<cancel> to ask a coroutine to
end itself, although there is no guarentee that the exception will lead to
termination, and if the exception isn't caught it might well end the whole
program.

=cut

sub desc {
   my $old = $_[0]{desc};
   $_[0]{desc} = $_[1] if @_ > 1;
   $old;
}

=back

=head2 GLOBAL FUNCTIONS

=over 4

=item Coro::nready

Returns the number of coroutines that are currently in the ready state,
i.e. that can be switched to. The value C<0> means that the only runnable
coroutine is the currently running one, so C<cede> would have no effect,
and C<schedule> would cause a deadlock unless there is an idle handler
that wakes up some coroutines.

=item my $guard = Coro::guard { ... }

This creates and returns a guard object. Nothing happens until the object
gets destroyed, in which case the codeblock given as argument will be
executed. This is useful to free locks or other resources in case of a
runtime error or when the coroutine gets canceled, as in both cases the
guard block will be executed. The guard object supports only one method,
C<< ->cancel >>, which will keep the codeblock from being executed.

Example: set some flag and clear it again when the coroutine gets canceled
or the function returns:

   sub do_something {
      my $guard = Coro::guard { $busy = 0 };
      $busy = 1;

      # do something that requires $busy to be true
   }

=cut

sub guard(&) {
   bless \(my $cb = $_[0]), "Coro::guard"
}

sub Coro::guard::cancel {
   ${$_[0]} = sub { };
}

sub Coro::guard::DESTROY {
   ${$_[0]}->();
}


=item unblock_sub { ... }

This utility function takes a BLOCK or code reference and "unblocks" it,
returning the new coderef. This means that the new coderef will return
immediately without blocking, returning nothing, while the original code
ref will be called (with parameters) from within its own coroutine.

The reason this function exists is that many event libraries (such as the
venerable L<Event|Event> module) are not coroutine-safe (a weaker form
of thread-safety). This means you must not block within event callbacks,
otherwise you might suffer from crashes or worse.

This function allows your callbacks to block by executing them in another
coroutine where it is safe to block. One example where blocking is handy
is when you use the L<Coro::AIO|Coro::AIO> functions to save results to
disk.

In short: simply use C<unblock_sub { ... }> instead of C<sub { ... }> when
creating event callbacks that want to block.

=cut

our @unblock_queue;

# we create a special coro because we want to cede,
# to reduce pressure on the coro pool (because most callbacks
# return immediately and can be reused) and because we cannot cede
# inside an event callback.
our $unblock_scheduler = new Coro sub {
   while () {
      while (my $cb = pop @unblock_queue) {
         # this is an inlined copy of async_pool
         my $coro = (pop @async_pool) || new Coro \&pool_handler;

         $coro->{_invoke} = $cb;
         $coro->ready;
         cede; # for short-lived callbacks, this reduces pressure on the coro pool
      }
      schedule; # sleep well
   }
};
$unblock_scheduler->desc ("[unblock_sub scheduler]");

sub unblock_sub(&) {
   my $cb = shift;

   sub {
      unshift @unblock_queue, [$cb, @_];
      $unblock_scheduler->ready;
   }
}

=back

=cut

1;

=head1 BUGS/LIMITATIONS

 - you must make very sure that no coro is still active on global
   destruction. very bad things might happen otherwise (usually segfaults).

 - this module is not thread-safe. You should only ever use this module
   from the same thread (this requirement might be loosened in the future
   to allow per-thread schedulers, but Coro::State does not yet allow
   this).

=head1 SEE ALSO

Lower level Configuration, Coroutine Environment: L<Coro::State>.

Debugging: L<Coro::Debug>.

Support/Utility: L<Coro::Specific>, L<Coro::Util>.

Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.

Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>.

Compatibility: L<Coro::LWP>, L<Coro::Storable>, L<Coro::Select>.

Embedding: L<Coro::MakeMaker>.

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

Revision:	1.180
Committed:	Fri Apr 25 04:28:50 2008 UTC (16 years, 1 month ago) by root
Branch:	MAIN
Changes since 1.179:	+1 -1 lines
Log Message:	* empty log message *
#	Content
1	=head1 NAME
2
3	Coro - coroutine process abstraction
4
5	=head1 SYNOPSIS
6
7	use Coro;
8
9	async {
10	# some asynchronous thread of execution
11	print "2\n";
12	cede; # yield back to main
13	print "4\n";
14	};
15	print "1\n";
16	cede; # yield to coroutine
17	print "3\n";
18	cede; # and again
19
20	# use locking
21	my $lock = new Coro::Semaphore;
22	my $locked;
23
24	$lock->down;
25	$locked = 1;
26	$lock->up;
27
28	=head1 DESCRIPTION
29
30	This module collection manages coroutines. Coroutines are similar
31	to threads but don't run in parallel at the same time even on SMP
32	machines. The specific flavor of coroutine used in this module also
33	guarantees you that it will not switch between coroutines unless
34	necessary, at easily-identified points in your program, so locking and
35	parallel access are rarely an issue, making coroutine programming much
36	safer than threads programming.
37
38	(Perl, however, does not natively support real threads but instead does a
39	very slow and memory-intensive emulation of processes using threads. This
40	is a performance win on Windows machines, and a loss everywhere else).
41
42	In this module, coroutines are defined as "callchain + lexical variables +
43	@_ + $_ + $@ + $/ + C stack), that is, a coroutine has its own callchain,
44	its own set of lexicals and its own set of perls most important global
45	variables (see L<Coro::State> for more configuration).
46
47	=cut
48
49	package Coro;
50
51	use strict;
52	no warnings "uninitialized";
53
54	use Coro::State;
55
56	use base qw(Coro::State Exporter);
57
58	our $idle; # idle handler
59	our $main; # main coroutine
60	our $current; # current coroutine
61
62	our $VERSION = 4.6;
63
64	our @EXPORT = qw(async async_pool cede schedule terminate current unblock_sub);
65	our %EXPORT_TAGS = (
66	prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
67	);
68	our @EXPORT_OK = (@{$EXPORT_TAGS{prio}}, qw(nready));
69
70	=over 4
71
72	=item $main
73
74	This coroutine represents the main program.
75
76	=cut
77
78	$main = new Coro;
79
80	=item $current (or as function: current)
81
82	The current coroutine (the last coroutine switched to). The initial value
83	is C<$main> (of course).
84
85	This variable is B<strictly> I<read-only>. It is provided for performance
86	reasons. If performance is not essential you are encouraged to use the
87	C<Coro::current> function instead.
88
89	=cut
90
91	$main->{desc} = "[main::]";
92
93	# maybe some other module used Coro::Specific before...
94	$main->{_specific} = $current->{_specific}
95	if $current;
96
97	_set_current $main;
98
99	sub current() { $current }
100
101	=item $idle
102
103	A callback that is called whenever the scheduler finds no ready coroutines
104	to run. The default implementation prints "FATAL: deadlock detected" and
105	exits, because the program has no other way to continue.
106
107	This hook is overwritten by modules such as C<Coro::Timer> and
108	C<Coro::Event> to wait on an external event that hopefully wake up a
109	coroutine so the scheduler can run it.
110
111	Please note that if your callback recursively invokes perl (e.g. for event
112	handlers), then it must be prepared to be called recursively itself.
113
114	=cut
115
116	$idle = sub {
117	require Carp;
118	Carp::croak ("FATAL: deadlock detected");
119	};
120
121	sub _cancel {
122	my ($self) = @_;
123
124	# free coroutine data and mark as destructed
125	$self->_destroy
126	or return;
127
128	# call all destruction callbacks
129	$_->(@{$self->{_status}})
130	for @{(delete $self->{_on_destroy}) \|\| []};
131	}
132
133	# this coroutine is necessary because a coroutine
134	# cannot destroy itself.
135	my @destroy;
136	my $manager;
137
138	$manager = new Coro sub {
139	while () {
140	(shift @destroy)->_cancel
141	while @destroy;
142
143	&schedule;
144	}
145	};
146	$manager->desc ("[coro manager]");
147	$manager->prio (PRIO_MAX);
148
149	=back
150
151	=head2 STATIC METHODS
152
153	Static methods are actually functions that operate on the current coroutine only.
154
155	=over 4
156
157	=item async { ... } [@args...]
158
159	Create a new asynchronous coroutine and return it's coroutine object
160	(usually unused). When the sub returns the new coroutine is automatically
161	terminated.
162
163	See the C<Coro::State::new> constructor for info about the coroutine
164	environment in which coroutines run.
165
166	Calling C<exit> in a coroutine will do the same as calling exit outside
167	the coroutine. Likewise, when the coroutine dies, the program will exit,
168	just as it would in the main program.
169
170	# create a new coroutine that just prints its arguments
171	async {
172	print "@_\n";
173	} 1,2,3,4;
174
175	=cut
176
177	sub async(&@) {
178	my $coro = new Coro @_;
179	$coro->ready;
180	$coro
181	}
182
183	=item async_pool { ... } [@args...]
184
185	Similar to C<async>, but uses a coroutine pool, so you should not call
186	terminate or join (although you are allowed to), and you get a coroutine
187	that might have executed other code already (which can be good or bad :).
188
189	Also, the block is executed in an C<eval> context and a warning will be
190	issued in case of an exception instead of terminating the program, as
191	C<async> does. As the coroutine is being reused, stuff like C<on_destroy>
192	will not work in the expected way, unless you call terminate or cancel,
193	which somehow defeats the purpose of pooling.
194
195	The priority will be reset to C<0> after each job, tracing will be
196	disabled, the description will be reset and the default output filehandle
197	gets restored, so you can change alkl these. Otherwise the coroutine will
198	be re-used "as-is": most notably if you change other per-coroutine global
199	stuff such as C<$/> you need to revert that change, which is most simply
200	done by using local as in C< local $/ >.
201
202	The pool size is limited to 8 idle coroutines (this can be adjusted by
203	changing $Coro::POOL_SIZE), and there can be as many non-idle coros as
204	required.
205
206	If you are concerned about pooled coroutines growing a lot because a
207	single C<async_pool> used a lot of stackspace you can e.g. C<async_pool
208	{ terminate }> once per second or so to slowly replenish the pool. In
209	addition to that, when the stacks used by a handler grows larger than 16kb
210	(adjustable with $Coro::POOL_RSS) it will also exit.
211
212	=cut
213
214	our $POOL_SIZE = 8;
215	our $POOL_RSS = 16 * 1024;
216	our @async_pool;
217
218	sub pool_handler {
219	my $cb;
220
221	while () {
222	eval {
223	while () {
224	_pool_1 $cb;
225	&$cb;
226	_pool_2 $cb;
227	&schedule;
228	}
229	};
230
231	last if $@ eq "\3async_pool terminate\2\n";
232	warn $@ if $@;
233	}
234	}
235
236	sub async_pool(&@) {
237	# this is also inlined into the unlock_scheduler
238	my $coro = (pop @async_pool) \|\| new Coro \&pool_handler;
239
240	$coro->{_invoke} = [@_];
241	$coro->ready;
242
243	$coro
244	}
245
246	=item schedule
247
248	Calls the scheduler. Please note that the current coroutine will not be put
249	into the ready queue, so calling this function usually means you will
250	never be called again unless something else (e.g. an event handler) calls
251	ready.
252
253	The canonical way to wait on external events is this:
254
255	{
256	# remember current coroutine
257	my $current = $Coro::current;
258
259	# register a hypothetical event handler
260	on_event_invoke sub {
261	# wake up sleeping coroutine
262	$current->ready;
263	undef $current;
264	};
265
266	# call schedule until event occurred.
267	# in case we are woken up for other reasons
268	# (current still defined), loop.
269	Coro::schedule while $current;
270	}
271
272	=item cede
273
274	"Cede" to other coroutines. This function puts the current coroutine into the
275	ready queue and calls C<schedule>, which has the effect of giving up the
276	current "timeslice" to other coroutines of the same or higher priority.
277
278	=item Coro::cede_notself
279
280	Works like cede, but is not exported by default and will cede to any
281	coroutine, regardless of priority, once.
282
283	=item terminate [arg...]
284
285	Terminates the current coroutine with the given status values (see L<cancel>).
286
287	=item killall
288
289	Kills/terminates/cancels all coroutines except the currently running
290	one. This is useful after a fork, either in the child or the parent, as
291	usually only one of them should inherit the running coroutines.
292
293	=cut
294
295	sub terminate {
296	$current->cancel (@_);
297	}
298
299	sub killall {
300	for (Coro::State::list) {
301	$_->cancel
302	if $_ != $current && UNIVERSAL::isa $_, "Coro";
303	}
304	}
305
306	=back
307
308	=head2 COROUTINE METHODS
309
310	These are the methods you can call on coroutine objects.
311
312	=over 4
313
314	=item new Coro \&sub [, @args...]
315
316	Create a new coroutine and return it. When the sub returns the coroutine
317	automatically terminates as if C<terminate> with the returned values were
318	called. To make the coroutine run you must first put it into the ready queue
319	by calling the ready method.
320
321	See C<async> and C<Coro::State::new> for additional info about the
322	coroutine environment.
323
324	=cut
325
326	sub _run_coro {
327	terminate &{+shift};
328	}
329
330	sub new {
331	my $class = shift;
332
333	$class->SUPER::new (\&_run_coro, @_)
334	}
335
336	=item $success = $coroutine->ready
337
338	Put the given coroutine into the ready queue (according to it's priority)
339	and return true. If the coroutine is already in the ready queue, do nothing
340	and return false.
341
342	=item $is_ready = $coroutine->is_ready
343
344	Return wether the coroutine is currently the ready queue or not,
345
346	=item $coroutine->cancel (arg...)
347
348	Terminates the given coroutine and makes it return the given arguments as
349	status (default: the empty list). Never returns if the coroutine is the
350	current coroutine.
351
352	=cut
353
354	sub cancel {
355	my $self = shift;
356	$self->{_status} = [@_];
357
358	if ($current == $self) {
359	push @destroy, $self;
360	$manager->ready;
361	&schedule while 1;
362	} else {
363	$self->_cancel;
364	}
365	}
366
367	=item $coroutine->join
368
369	Wait until the coroutine terminates and return any values given to the
370	C<terminate> or C<cancel> functions. C<join> can be called concurrently
371	from multiple coroutines.
372
373	=cut
374
375	sub join {
376	my $self = shift;
377
378	unless ($self->{_status}) {
379	my $current = $current;
380
381	push @{$self->{_on_destroy}}, sub {
382	$current->ready;
383	undef $current;
384	};
385
386	&schedule while $current;
387	}
388
389	wantarray ? @{$self->{_status}} : $self->{_status}[0];
390	}
391
392	=item $coroutine->on_destroy (\&cb)
393
394	Registers a callback that is called when this coroutine gets destroyed,
395	but before it is joined. The callback gets passed the terminate arguments,
396	if any.
397
398	=cut
399
400	sub on_destroy {
401	my ($self, $cb) = @_;
402
403	push @{ $self->{_on_destroy} }, $cb;
404	}
405
406	=item $oldprio = $coroutine->prio ($newprio)
407
408	Sets (or gets, if the argument is missing) the priority of the
409	coroutine. Higher priority coroutines get run before lower priority
410	coroutines. Priorities are small signed integers (currently -4 .. +3),
411	that you can refer to using PRIO_xxx constants (use the import tag :prio
412	to get then):
413
414	PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
415	3 > 1 > 0 > -1 > -3 > -4
416
417	# set priority to HIGH
418	current->prio(PRIO_HIGH);
419
420	The idle coroutine ($Coro::idle) always has a lower priority than any
421	existing coroutine.
422
423	Changing the priority of the current coroutine will take effect immediately,
424	but changing the priority of coroutines in the ready queue (but not
425	running) will only take effect after the next schedule (of that
426	coroutine). This is a bug that will be fixed in some future version.
427
428	=item $newprio = $coroutine->nice ($change)
429
430	Similar to C<prio>, but subtract the given value from the priority (i.e.
431	higher values mean lower priority, just as in unix).
432
433	=item $olddesc = $coroutine->desc ($newdesc)
434
435	Sets (or gets in case the argument is missing) the description for this
436	coroutine. This is just a free-form string you can associate with a coroutine.
437
438	This method simply sets the C<< $coroutine->{desc} >> member to the given string. You
439	can modify this member directly if you wish.
440
441	=item $coroutine->throw ([$scalar])
442
443	If C<$throw> is specified and defined, it will be thrown as an exception
444	inside the coroutine at the next convinient point in time (usually after
445	it gains control at the next schedule/transfer/cede). Otherwise clears the
446	exception object.
447
448	The exception object will be thrown "as is" with the specified scalar in
449	C<$@>, i.e. if it is a string, no line number or newline will be appended
450	(unlike with C<die>).
451
452	This can be used as a softer means than C<cancel> to ask a coroutine to
453	end itself, although there is no guarentee that the exception will lead to
454	termination, and if the exception isn't caught it might well end the whole
455	program.
456
457	=cut
458
459	sub desc {
460	my $old = $_[0]{desc};
461	$_[0]{desc} = $_[1] if @_ > 1;
462	$old;
463	}
464
465	=back
466
467	=head2 GLOBAL FUNCTIONS
468
469	=over 4
470
471	=item Coro::nready
472
473	Returns the number of coroutines that are currently in the ready state,
474	i.e. that can be switched to. The value C<0> means that the only runnable
475	coroutine is the currently running one, so C<cede> would have no effect,
476	and C<schedule> would cause a deadlock unless there is an idle handler
477	that wakes up some coroutines.
478
479	=item my $guard = Coro::guard { ... }
480
481	This creates and returns a guard object. Nothing happens until the object
482	gets destroyed, in which case the codeblock given as argument will be
483	executed. This is useful to free locks or other resources in case of a
484	runtime error or when the coroutine gets canceled, as in both cases the
485	guard block will be executed. The guard object supports only one method,
486	C<< ->cancel >>, which will keep the codeblock from being executed.
487
488	Example: set some flag and clear it again when the coroutine gets canceled
489	or the function returns:
490
491	sub do_something {
492	my $guard = Coro::guard { $busy = 0 };
493	$busy = 1;
494
495	# do something that requires $busy to be true
496	}
497
498	=cut
499
500	sub guard(&) {
501	bless \(my $cb = $_[0]), "Coro::guard"
502	}
503
504	sub Coro::guard::cancel {
505	${$_[0]} = sub { };
506	}
507
508	sub Coro::guard::DESTROY {
509	${$_[0]}->();
510	}
511
512
513	=item unblock_sub { ... }
514
515	This utility function takes a BLOCK or code reference and "unblocks" it,
516	returning the new coderef. This means that the new coderef will return
517	immediately without blocking, returning nothing, while the original code
518	ref will be called (with parameters) from within its own coroutine.
519
520	The reason this function exists is that many event libraries (such as the
521	venerable L<Event\|Event> module) are not coroutine-safe (a weaker form
522	of thread-safety). This means you must not block within event callbacks,
523	otherwise you might suffer from crashes or worse.
524
525	This function allows your callbacks to block by executing them in another
526	coroutine where it is safe to block. One example where blocking is handy
527	is when you use the L<Coro::AIO\|Coro::AIO> functions to save results to
528	disk.
529
530	In short: simply use C<unblock_sub { ... }> instead of C<sub { ... }> when
531	creating event callbacks that want to block.
532
533	=cut
534
535	our @unblock_queue;
536
537	# we create a special coro because we want to cede,
538	# to reduce pressure on the coro pool (because most callbacks
539	# return immediately and can be reused) and because we cannot cede
540	# inside an event callback.
541	our $unblock_scheduler = new Coro sub {
542	while () {
543	while (my $cb = pop @unblock_queue) {
544	# this is an inlined copy of async_pool
545	my $coro = (pop @async_pool) \|\| new Coro \&pool_handler;
546
547	$coro->{_invoke} = $cb;
548	$coro->ready;
549	cede; # for short-lived callbacks, this reduces pressure on the coro pool
550	}
551	schedule; # sleep well
552	}
553	};
554	$unblock_scheduler->desc ("[unblock_sub scheduler]");
555
556	sub unblock_sub(&) {
557	my $cb = shift;
558
559	sub {
560	unshift @unblock_queue, [$cb, @_];
561	$unblock_scheduler->ready;
562	}
563	}
564
565	=back
566
567	=cut
568
569	1;
570
571	=head1 BUGS/LIMITATIONS
572
573	- you must make very sure that no coro is still active on global
574	destruction. very bad things might happen otherwise (usually segfaults).
575
576	- this module is not thread-safe. You should only ever use this module
577	from the same thread (this requirement might be loosened in the future
578	to allow per-thread schedulers, but Coro::State does not yet allow
579	this).
580
581	=head1 SEE ALSO
582
583	Lower level Configuration, Coroutine Environment: L<Coro::State>.
584
585	Debugging: L<Coro::Debug>.
586
587	Support/Utility: L<Coro::Specific>, L<Coro::Util>.
588
589	Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.
590
591	Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>.
592
593	Compatibility: L<Coro::LWP>, L<Coro::Storable>, L<Coro::Select>.
594
595	Embedding: L<Coro::MakeMaker>.
596
597	=head1 AUTHOR
598
599	Marc Lehmann <schmorp@schmorp.de>
600	http://home.schmorp.de/
601
602	=cut
603