Coro/Coro.pm

=head1 NAME

Coro - coroutine process abstraction

=head1 SYNOPSIS

 use Coro;

 async {
    # some asynchronous thread of execution
 };

 # alternatively create an async coroutine like this:

 sub some_func : Coro {
    # some more async code
 }

 cede;

=head1 DESCRIPTION

This module collection manages coroutines. Coroutines are similar
to threads but don't run in parallel at the same time even on SMP
machines. The specific flavor of coroutine used in this module also
guarantees you that it will not switch between coroutines unless
necessary, at easily-identified points in your program, so locking and
parallel access are rarely an issue, making coroutine programming much
safer than threads programming.

(Perl, however, does not natively support real threads but instead does a
very slow and memory-intensive emulation of processes using threads. This
is a performance win on Windows machines, and a loss everywhere else).

In this module, coroutines are defined as "callchain + lexical variables +
@_ + $_ + $@ + $/ + C stack), that is, a coroutine has its own callchain,
its own set of lexicals and its own set of perls most important global
variables.

=cut

package Coro;

use strict;
no warnings "uninitialized";

use Coro::State;

use base qw(Coro::State Exporter);

our $idle;    # idle handler
our $main;    # main coroutine
our $current; # current coroutine

our $VERSION = '3.7';

our @EXPORT = qw(async async_pool cede schedule terminate current unblock_sub);
our %EXPORT_TAGS = (
      prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
);
our @EXPORT_OK = (@{$EXPORT_TAGS{prio}}, qw(nready));

{
   my @async;
   my $init;

   # this way of handling attributes simply is NOT scalable ;()
   sub import {
      no strict 'refs';

      Coro->export_to_level (1, @_);

      my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
      *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
         my ($package, $ref) = (shift, shift);
         my @attrs;
         for (@_) {
            if ($_ eq "Coro") {
               push @async, $ref;
               unless ($init++) {
                  eval q{
                     sub INIT {
                        &async(pop @async) while @async;
                     }
                  };
               }
            } else {
               push @attrs, $_;
            }
         }
         return $old ? $old->($package, $ref, @attrs) : @attrs;
      };
   }

}

=over 4

=item $main

This coroutine represents the main program.

=cut

$main = new Coro;

=item $current (or as function: current)

The current coroutine (the last coroutine switched to). The initial value
is C<$main> (of course).

This variable is B<strictly> I<read-only>. It is provided for performance
reasons. If performance is not essential you are encouraged to use the
C<Coro::current> function instead.

=cut

# maybe some other module used Coro::Specific before...
$main->{specific} = $current->{specific}
   if $current;

_set_current $main;

sub current() { $current }

=item $idle

A callback that is called whenever the scheduler finds no ready coroutines
to run. The default implementation prints "FATAL: deadlock detected" and
exits, because the program has no other way to continue.

This hook is overwritten by modules such as C<Coro::Timer> and
C<Coro::Event> to wait on an external event that hopefully wake up a
coroutine so the scheduler can run it.

Please note that if your callback recursively invokes perl (e.g. for event
handlers), then it must be prepared to be called recursively.

=cut

$idle = sub {
   require Carp;
   Carp::croak ("FATAL: deadlock detected");
};

sub _cancel {
   my ($self) = @_;

   # free coroutine data and mark as destructed
   $self->_destroy
      or return;

   # call all destruction callbacks
   $_->(@{$self->{status}})
      for @{(delete $self->{destroy_cb}) || []};
}

# this coroutine is necessary because a coroutine
# cannot destroy itself.
my @destroy;
my $manager;

$manager = new Coro sub {
   $current->desc ("[coro manager]");

   while () {
      (shift @destroy)->_cancel
         while @destroy;

      &schedule;
   }
};

$manager->prio (PRIO_MAX);

# static methods. not really.

=back

=head2 STATIC METHODS

Static methods are actually functions that operate on the current coroutine only.

=over 4

=item async { ... } [@args...]

Create a new asynchronous coroutine and return it's coroutine object
(usually unused). When the sub returns the new coroutine is automatically
terminated.

Calling C<exit> in a coroutine will do the same as calling exit outside
the coroutine. Likewise, when the coroutine dies, the program will exit,
just as it would in the main program.

   # create a new coroutine that just prints its arguments
   async {
      print "@_\n";
   } 1,2,3,4;

=cut

sub async(&@) {
   my $coro = new Coro @_;
   $coro->ready;
   $coro
}

=item async_pool { ... } [@args...]

Similar to C<async>, but uses a coroutine pool, so you should not call
terminate or join (although you are allowed to), and you get a coroutine
that might have executed other code already (which can be good or bad :).

Also, the block is executed in an C<eval> context and a warning will be
issued in case of an exception instead of terminating the program, as
C<async> does. As the coroutine is being reused, stuff like C<on_destroy>
will not work in the expected way, unless you call terminate or cancel,
which somehow defeats the purpose of pooling.

The priority will be reset to C<0> after each job, otherwise the coroutine
will be re-used "as-is".

The pool size is limited to 8 idle coroutines (this can be adjusted by
changing $Coro::POOL_SIZE), and there can be as many non-idle coros as
required.

If you are concerned about pooled coroutines growing a lot because a
single C<async_pool> used a lot of stackspace you can e.g. C<async_pool {
terminate }> once per second or so to slowly replenish the pool.

=cut

our $POOL_SIZE = 8;
our @pool;

sub pool_handler {
   while () {
      $current->{desc} = "[async_pool]";

      eval {
         my ($cb, @arg) = @{ delete $current->{_invoke} or return };
         $cb->(@arg);
      };
      warn $@ if $@;

      last if @pool >= $POOL_SIZE;

      push @pool, $current;
      $current->{desc} = "[async_pool idle]";
      $current->save (Coro::State::SAVE_DEF);
      $current->prio (0);
      schedule;
   }
}

sub async_pool(&@) {
   # this is also inlined into the unlock_scheduler
   my $coro = (pop @pool) || new Coro \&pool_handler;;

   $coro->{_invoke} = [@_];
   $coro->ready;

   $coro
}

=item schedule

Calls the scheduler. Please note that the current coroutine will not be put
into the ready queue, so calling this function usually means you will
never be called again unless something else (e.g. an event handler) calls
ready.

The canonical way to wait on external events is this:

   {
      # remember current coroutine
      my $current = $Coro::current;

      # register a hypothetical event handler
      on_event_invoke sub {
         # wake up sleeping coroutine
         $current->ready;
         undef $current;
      };

      # call schedule until event occurred.
      # in case we are woken up for other reasons
      # (current still defined), loop.
      Coro::schedule while $current;
   }

=item cede

"Cede" to other coroutines. This function puts the current coroutine into the
ready queue and calls C<schedule>, which has the effect of giving up the
current "timeslice" to other coroutines of the same or higher priority.

Returns true if at least one coroutine switch has happened.

=item Coro::cede_notself

Works like cede, but is not exported by default and will cede to any
coroutine, regardless of priority, once.

Returns true if at least one coroutine switch has happened.

=item terminate [arg...]

Terminates the current coroutine with the given status values (see L<cancel>).

=cut

sub terminate {
   $current->cancel (@_);
}

=back

# dynamic methods

=head2 COROUTINE METHODS

These are the methods you can call on coroutine objects.

=over 4

=item new Coro \&sub [, @args...]

Create a new coroutine and return it. When the sub returns the coroutine
automatically terminates as if C<terminate> with the returned values were
called. To make the coroutine run you must first put it into the ready queue
by calling the ready method.

See C<async> for additional discussion.

=cut

sub _run_coro {
   terminate &{+shift};
}

sub new {
   my $class = shift;

   $class->SUPER::new (\&_run_coro, @_)
}

=item $success = $coroutine->ready

Put the given coroutine into the ready queue (according to it's priority)
and return true. If the coroutine is already in the ready queue, do nothing
and return false.

=item $is_ready = $coroutine->is_ready

Return wether the coroutine is currently the ready queue or not,

=item $coroutine->cancel (arg...)

Terminates the given coroutine and makes it return the given arguments as
status (default: the empty list). Never returns if the coroutine is the
current coroutine.

=cut

sub cancel {
   my $self = shift;
   $self->{status} = [@_];

   if ($current == $self) {
      push @destroy, $self;
      $manager->ready;
      &schedule while 1;
   } else {
      $self->_cancel;
   }
}

=item $coroutine->join

Wait until the coroutine terminates and return any values given to the
C<terminate> or C<cancel> functions. C<join> can be called multiple times
from multiple coroutine.

=cut

sub join {
   my $self = shift;

   unless ($self->{status}) {
      my $current = $current;

      push @{$self->{destroy_cb}}, sub {
         $current->ready;
         undef $current;
      };

      &schedule while $current;
   }

   wantarray ? @{$self->{status}} : $self->{status}[0];
}

=item $coroutine->on_destroy (\&cb)

Registers a callback that is called when this coroutine gets destroyed,
but before it is joined. The callback gets passed the terminate arguments,
if any.

=cut

sub on_destroy {
   my ($self, $cb) = @_;

   push @{ $self->{destroy_cb} }, $cb;
}

=item $oldprio = $coroutine->prio ($newprio)

Sets (or gets, if the argument is missing) the priority of the
coroutine. Higher priority coroutines get run before lower priority
coroutines. Priorities are small signed integers (currently -4 .. +3),
that you can refer to using PRIO_xxx constants (use the import tag :prio
to get then):

   PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
       3    >     1     >      0      >    -1    >    -3     >    -4

   # set priority to HIGH
   current->prio(PRIO_HIGH);

The idle coroutine ($Coro::idle) always has a lower priority than any
existing coroutine.

Changing the priority of the current coroutine will take effect immediately,
but changing the priority of coroutines in the ready queue (but not
running) will only take effect after the next schedule (of that
coroutine). This is a bug that will be fixed in some future version.

=item $newprio = $coroutine->nice ($change)

Similar to C<prio>, but subtract the given value from the priority (i.e.
higher values mean lower priority, just as in unix).

=item $olddesc = $coroutine->desc ($newdesc)

Sets (or gets in case the argument is missing) the description for this
coroutine. This is just a free-form string you can associate with a coroutine.

=cut

sub desc {
   my $old = $_[0]{desc};
   $_[0]{desc} = $_[1] if @_ > 1;
   $old;
}

=back

=head2 GLOBAL FUNCTIONS

=over 4

=item Coro::nready

Returns the number of coroutines that are currently in the ready state,
i.e. that can be switched to. The value C<0> means that the only runnable
coroutine is the currently running one, so C<cede> would have no effect,
and C<schedule> would cause a deadlock unless there is an idle handler
that wakes up some coroutines.

=item my $guard = Coro::guard { ... }

This creates and returns a guard object. Nothing happens until the object
gets destroyed, in which case the codeblock given as argument will be
executed. This is useful to free locks or other resources in case of a
runtime error or when the coroutine gets canceled, as in both cases the
guard block will be executed. The guard object supports only one method,
C<< ->cancel >>, which will keep the codeblock from being executed.

Example: set some flag and clear it again when the coroutine gets canceled
or the function returns:

   sub do_something {
      my $guard = Coro::guard { $busy = 0 };
      $busy = 1;

      # do something that requires $busy to be true
   }

=cut

sub guard(&) {
   bless \(my $cb = $_[0]), "Coro::guard"
}

sub Coro::guard::cancel {
   ${$_[0]} = sub { };
}

sub Coro::guard::DESTROY {
   ${$_[0]}->();
}


=item unblock_sub { ... }

This utility function takes a BLOCK or code reference and "unblocks" it,
returning the new coderef. This means that the new coderef will return
immediately without blocking, returning nothing, while the original code
ref will be called (with parameters) from within its own coroutine.

The reason this function exists is that many event libraries (such as the
venerable L<Event|Event> module) are not coroutine-safe (a weaker form
of thread-safety). This means you must not block within event callbacks,
otherwise you might suffer from crashes or worse.

This function allows your callbacks to block by executing them in another
coroutine where it is safe to block. One example where blocking is handy
is when you use the L<Coro::AIO|Coro::AIO> functions to save results to
disk.

In short: simply use C<unblock_sub { ... }> instead of C<sub { ... }> when
creating event callbacks that want to block.

=cut

our @unblock_queue;

# we create a special coro because we want to cede,
# to reduce pressure on the coro pool (because most callbacks
# return immediately and can be reused) and because we cannot cede
# inside an event callback.
our $unblock_scheduler = async {
   $current->desc ("[unblock_sub scheduler]");
   while () {
      while (my $cb = pop @unblock_queue) {
         # this is an inlined copy of async_pool
         my $coro = (pop @pool or new Coro \&pool_handler);

         $coro->{_invoke} = $cb;
         $coro->ready;
         cede; # for short-lived callbacks, this reduces pressure on the coro pool
      }
      schedule; # sleep well
   }
};

sub unblock_sub(&) {
   my $cb = shift;

   sub {
      unshift @unblock_queue, [$cb, @_];
      $unblock_scheduler->ready;
   }
}

=back

=cut

1;

=head1 BUGS/LIMITATIONS

 - you must make very sure that no coro is still active on global
   destruction. very bad things might happen otherwise (usually segfaults).

 - this module is not thread-safe. You should only ever use this module
   from the same thread (this requirement might be loosened in the future
   to allow per-thread schedulers, but Coro::State does not yet allow
   this).

=head1 SEE ALSO

Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.

Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.

Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.

Embedding: L<Coro:MakeMaker>

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

Revision:	1.129
Committed:	Wed Sep 19 22:33:08 2007 UTC (16 years, 8 months ago) by root
Branch:	MAIN
Changes since 1.128:	+8 -6 lines
Log Message:	* empty log message *
#	Content
1	=head1 NAME
2
3	Coro - coroutine process abstraction
4
5	=head1 SYNOPSIS
6
7	use Coro;
8
9	async {
10	# some asynchronous thread of execution
11	};
12
13	# alternatively create an async coroutine like this:
14
15	sub some_func : Coro {
16	# some more async code
17	}
18
19	cede;
20
21	=head1 DESCRIPTION
22
23	This module collection manages coroutines. Coroutines are similar
24	to threads but don't run in parallel at the same time even on SMP
25	machines. The specific flavor of coroutine used in this module also
26	guarantees you that it will not switch between coroutines unless
27	necessary, at easily-identified points in your program, so locking and
28	parallel access are rarely an issue, making coroutine programming much
29	safer than threads programming.
30
31	(Perl, however, does not natively support real threads but instead does a
32	very slow and memory-intensive emulation of processes using threads. This
33	is a performance win on Windows machines, and a loss everywhere else).
34
35	In this module, coroutines are defined as "callchain + lexical variables +
36	@_ + $_ + $@ + $/ + C stack), that is, a coroutine has its own callchain,
37	its own set of lexicals and its own set of perls most important global
38	variables.
39
40	=cut
41
42	package Coro;
43
44	use strict;
45	no warnings "uninitialized";
46
47	use Coro::State;
48
49	use base qw(Coro::State Exporter);
50
51	our $idle; # idle handler
52	our $main; # main coroutine
53	our $current; # current coroutine
54
55	our $VERSION = '3.7';
56
57	our @EXPORT = qw(async async_pool cede schedule terminate current unblock_sub);
58	our %EXPORT_TAGS = (
59	prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
60	);
61	our @EXPORT_OK = (@{$EXPORT_TAGS{prio}}, qw(nready));
62
63	{
64	my @async;
65	my $init;
66
67	# this way of handling attributes simply is NOT scalable ;()
68	sub import {
69	no strict 'refs';
70
71	Coro->export_to_level (1, @_);
72
73	my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
74	*{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
75	my ($package, $ref) = (shift, shift);
76	my @attrs;
77	for (@_) {
78	if ($_ eq "Coro") {
79	push @async, $ref;
80	unless ($init++) {
81	eval q{
82	sub INIT {
83	&async(pop @async) while @async;
84	}
85	};
86	}
87	} else {
88	push @attrs, $_;
89	}
90	}
91	return $old ? $old->($package, $ref, @attrs) : @attrs;
92	};
93	}
94
95	}
96
97	=over 4
98
99	=item $main
100
101	This coroutine represents the main program.
102
103	=cut
104
105	$main = new Coro;
106
107	=item $current (or as function: current)
108
109	The current coroutine (the last coroutine switched to). The initial value
110	is C<$main> (of course).
111
112	This variable is B<strictly> I<read-only>. It is provided for performance
113	reasons. If performance is not essential you are encouraged to use the
114	C<Coro::current> function instead.
115
116	=cut
117
118	# maybe some other module used Coro::Specific before...
119	$main->{specific} = $current->{specific}
120	if $current;
121
122	_set_current $main;
123
124	sub current() { $current }
125
126	=item $idle
127
128	A callback that is called whenever the scheduler finds no ready coroutines
129	to run. The default implementation prints "FATAL: deadlock detected" and
130	exits, because the program has no other way to continue.
131
132	This hook is overwritten by modules such as C<Coro::Timer> and
133	C<Coro::Event> to wait on an external event that hopefully wake up a
134	coroutine so the scheduler can run it.
135
136	Please note that if your callback recursively invokes perl (e.g. for event
137	handlers), then it must be prepared to be called recursively.
138
139	=cut
140
141	$idle = sub {
142	require Carp;
143	Carp::croak ("FATAL: deadlock detected");
144	};
145
146	sub _cancel {
147	my ($self) = @_;
148
149	# free coroutine data and mark as destructed
150	$self->_destroy
151	or return;
152
153	# call all destruction callbacks
154	$_->(@{$self->{status}})
155	for @{(delete $self->{destroy_cb}) \|\| []};
156	}
157
158	# this coroutine is necessary because a coroutine
159	# cannot destroy itself.
160	my @destroy;
161	my $manager;
162
163	$manager = new Coro sub {
164	$current->desc ("[coro manager]");
165
166	while () {
167	(shift @destroy)->_cancel
168	while @destroy;
169
170	&schedule;
171	}
172	};
173
174	$manager->prio (PRIO_MAX);
175
176	# static methods. not really.
177
178	=back
179
180	=head2 STATIC METHODS
181
182	Static methods are actually functions that operate on the current coroutine only.
183
184	=over 4
185
186	=item async { ... } [@args...]
187
188	Create a new asynchronous coroutine and return it's coroutine object
189	(usually unused). When the sub returns the new coroutine is automatically
190	terminated.
191
192	Calling C<exit> in a coroutine will do the same as calling exit outside
193	the coroutine. Likewise, when the coroutine dies, the program will exit,
194	just as it would in the main program.
195
196	# create a new coroutine that just prints its arguments
197	async {
198	print "@_\n";
199	} 1,2,3,4;
200
201	=cut
202
203	sub async(&@) {
204	my $coro = new Coro @_;
205	$coro->ready;
206	$coro
207	}
208
209	=item async_pool { ... } [@args...]
210
211	Similar to C<async>, but uses a coroutine pool, so you should not call
212	terminate or join (although you are allowed to), and you get a coroutine
213	that might have executed other code already (which can be good or bad :).
214
215	Also, the block is executed in an C<eval> context and a warning will be
216	issued in case of an exception instead of terminating the program, as
217	C<async> does. As the coroutine is being reused, stuff like C<on_destroy>
218	will not work in the expected way, unless you call terminate or cancel,
219	which somehow defeats the purpose of pooling.
220
221	The priority will be reset to C<0> after each job, otherwise the coroutine
222	will be re-used "as-is".
223
224	The pool size is limited to 8 idle coroutines (this can be adjusted by
225	changing $Coro::POOL_SIZE), and there can be as many non-idle coros as
226	required.
227
228	If you are concerned about pooled coroutines growing a lot because a
229	single C<async_pool> used a lot of stackspace you can e.g. C<async_pool {
230	terminate }> once per second or so to slowly replenish the pool.
231
232	=cut
233
234	our $POOL_SIZE = 8;
235	our @pool;
236
237	sub pool_handler {
238	while () {
239	$current->{desc} = "[async_pool]";
240
241	eval {
242	my ($cb, @arg) = @{ delete $current->{_invoke} or return };
243	$cb->(@arg);
244	};
245	warn $@ if $@;
246
247	last if @pool >= $POOL_SIZE;
248
249	push @pool, $current;
250	$current->{desc} = "[async_pool idle]";
251	$current->save (Coro::State::SAVE_DEF);
252	$current->prio (0);
253	schedule;
254	}
255	}
256
257	sub async_pool(&@) {
258	# this is also inlined into the unlock_scheduler
259	my $coro = (pop @pool) \|\| new Coro \&pool_handler;;
260
261	$coro->{_invoke} = [@_];
262	$coro->ready;
263
264	$coro
265	}
266
267	=item schedule
268
269	Calls the scheduler. Please note that the current coroutine will not be put
270	into the ready queue, so calling this function usually means you will
271	never be called again unless something else (e.g. an event handler) calls
272	ready.
273
274	The canonical way to wait on external events is this:
275
276	{
277	# remember current coroutine
278	my $current = $Coro::current;
279
280	# register a hypothetical event handler
281	on_event_invoke sub {
282	# wake up sleeping coroutine
283	$current->ready;
284	undef $current;
285	};
286
287	# call schedule until event occurred.
288	# in case we are woken up for other reasons
289	# (current still defined), loop.
290	Coro::schedule while $current;
291	}
292
293	=item cede
294
295	"Cede" to other coroutines. This function puts the current coroutine into the
296	ready queue and calls C<schedule>, which has the effect of giving up the
297	current "timeslice" to other coroutines of the same or higher priority.
298
299	Returns true if at least one coroutine switch has happened.
300
301	=item Coro::cede_notself
302
303	Works like cede, but is not exported by default and will cede to any
304	coroutine, regardless of priority, once.
305
306	Returns true if at least one coroutine switch has happened.
307
308	=item terminate [arg...]
309
310	Terminates the current coroutine with the given status values (see L<cancel>).
311
312	=cut
313
314	sub terminate {
315	$current->cancel (@_);
316	}
317
318	=back
319
320	# dynamic methods
321
322	=head2 COROUTINE METHODS
323
324	These are the methods you can call on coroutine objects.
325
326	=over 4
327
328	=item new Coro \&sub [, @args...]
329
330	Create a new coroutine and return it. When the sub returns the coroutine
331	automatically terminates as if C<terminate> with the returned values were
332	called. To make the coroutine run you must first put it into the ready queue
333	by calling the ready method.
334
335	See C<async> for additional discussion.
336
337	=cut
338
339	sub _run_coro {
340	terminate &{+shift};
341	}
342
343	sub new {
344	my $class = shift;
345
346	$class->SUPER::new (\&_run_coro, @_)
347	}
348
349	=item $success = $coroutine->ready
350
351	Put the given coroutine into the ready queue (according to it's priority)
352	and return true. If the coroutine is already in the ready queue, do nothing
353	and return false.
354
355	=item $is_ready = $coroutine->is_ready
356
357	Return wether the coroutine is currently the ready queue or not,
358
359	=item $coroutine->cancel (arg...)
360
361	Terminates the given coroutine and makes it return the given arguments as
362	status (default: the empty list). Never returns if the coroutine is the
363	current coroutine.
364
365	=cut
366
367	sub cancel {
368	my $self = shift;
369	$self->{status} = [@_];
370
371	if ($current == $self) {
372	push @destroy, $self;
373	$manager->ready;
374	&schedule while 1;
375	} else {
376	$self->_cancel;
377	}
378	}
379
380	=item $coroutine->join
381
382	Wait until the coroutine terminates and return any values given to the
383	C<terminate> or C<cancel> functions. C<join> can be called multiple times
384	from multiple coroutine.
385
386	=cut
387
388	sub join {
389	my $self = shift;
390
391	unless ($self->{status}) {
392	my $current = $current;
393
394	push @{$self->{destroy_cb}}, sub {
395	$current->ready;
396	undef $current;
397	};
398
399	&schedule while $current;
400	}
401
402	wantarray ? @{$self->{status}} : $self->{status}[0];
403	}
404
405	=item $coroutine->on_destroy (\&cb)
406
407	Registers a callback that is called when this coroutine gets destroyed,
408	but before it is joined. The callback gets passed the terminate arguments,
409	if any.
410
411	=cut
412
413	sub on_destroy {
414	my ($self, $cb) = @_;
415
416	push @{ $self->{destroy_cb} }, $cb;
417	}
418
419	=item $oldprio = $coroutine->prio ($newprio)
420
421	Sets (or gets, if the argument is missing) the priority of the
422	coroutine. Higher priority coroutines get run before lower priority
423	coroutines. Priorities are small signed integers (currently -4 .. +3),
424	that you can refer to using PRIO_xxx constants (use the import tag :prio
425	to get then):
426
427	PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
428	3 > 1 > 0 > -1 > -3 > -4
429
430	# set priority to HIGH
431	current->prio(PRIO_HIGH);
432
433	The idle coroutine ($Coro::idle) always has a lower priority than any
434	existing coroutine.
435
436	Changing the priority of the current coroutine will take effect immediately,
437	but changing the priority of coroutines in the ready queue (but not
438	running) will only take effect after the next schedule (of that
439	coroutine). This is a bug that will be fixed in some future version.
440
441	=item $newprio = $coroutine->nice ($change)
442
443	Similar to C<prio>, but subtract the given value from the priority (i.e.
444	higher values mean lower priority, just as in unix).
445
446	=item $olddesc = $coroutine->desc ($newdesc)
447
448	Sets (or gets in case the argument is missing) the description for this
449	coroutine. This is just a free-form string you can associate with a coroutine.
450
451	=cut
452
453	sub desc {
454	my $old = $_[0]{desc};
455	$_[0]{desc} = $_[1] if @_ > 1;
456	$old;
457	}
458
459	=back
460
461	=head2 GLOBAL FUNCTIONS
462
463	=over 4
464
465	=item Coro::nready
466
467	Returns the number of coroutines that are currently in the ready state,
468	i.e. that can be switched to. The value C<0> means that the only runnable
469	coroutine is the currently running one, so C<cede> would have no effect,
470	and C<schedule> would cause a deadlock unless there is an idle handler
471	that wakes up some coroutines.
472
473	=item my $guard = Coro::guard { ... }
474
475	This creates and returns a guard object. Nothing happens until the object
476	gets destroyed, in which case the codeblock given as argument will be
477	executed. This is useful to free locks or other resources in case of a
478	runtime error or when the coroutine gets canceled, as in both cases the
479	guard block will be executed. The guard object supports only one method,
480	C<< ->cancel >>, which will keep the codeblock from being executed.
481
482	Example: set some flag and clear it again when the coroutine gets canceled
483	or the function returns:
484
485	sub do_something {
486	my $guard = Coro::guard { $busy = 0 };
487	$busy = 1;
488
489	# do something that requires $busy to be true
490	}
491
492	=cut
493
494	sub guard(&) {
495	bless \(my $cb = $_[0]), "Coro::guard"
496	}
497
498	sub Coro::guard::cancel {
499	${$_[0]} = sub { };
500	}
501
502	sub Coro::guard::DESTROY {
503	${$_[0]}->();
504	}
505
506
507	=item unblock_sub { ... }
508
509	This utility function takes a BLOCK or code reference and "unblocks" it,
510	returning the new coderef. This means that the new coderef will return
511	immediately without blocking, returning nothing, while the original code
512	ref will be called (with parameters) from within its own coroutine.
513
514	The reason this function exists is that many event libraries (such as the
515	venerable L<Event\|Event> module) are not coroutine-safe (a weaker form
516	of thread-safety). This means you must not block within event callbacks,
517	otherwise you might suffer from crashes or worse.
518
519	This function allows your callbacks to block by executing them in another
520	coroutine where it is safe to block. One example where blocking is handy
521	is when you use the L<Coro::AIO\|Coro::AIO> functions to save results to
522	disk.
523
524	In short: simply use C<unblock_sub { ... }> instead of C<sub { ... }> when
525	creating event callbacks that want to block.
526
527	=cut
528
529	our @unblock_queue;
530
531	# we create a special coro because we want to cede,
532	# to reduce pressure on the coro pool (because most callbacks
533	# return immediately and can be reused) and because we cannot cede
534	# inside an event callback.
535	our $unblock_scheduler = async {
536	$current->desc ("[unblock_sub scheduler]");
537	while () {
538	while (my $cb = pop @unblock_queue) {
539	# this is an inlined copy of async_pool
540	my $coro = (pop @pool or new Coro \&pool_handler);
541
542	$coro->{_invoke} = $cb;
543	$coro->ready;
544	cede; # for short-lived callbacks, this reduces pressure on the coro pool
545	}
546	schedule; # sleep well
547	}
548	};
549
550	sub unblock_sub(&) {
551	my $cb = shift;
552
553	sub {
554	unshift @unblock_queue, [$cb, @_];
555	$unblock_scheduler->ready;
556	}
557	}
558
559	=back
560
561	=cut
562
563	1;
564
565	=head1 BUGS/LIMITATIONS
566
567	- you must make very sure that no coro is still active on global
568	destruction. very bad things might happen otherwise (usually segfaults).
569
570	- this module is not thread-safe. You should only ever use this module
571	from the same thread (this requirement might be loosened in the future
572	to allow per-thread schedulers, but Coro::State does not yet allow
573	this).
574
575	=head1 SEE ALSO
576
577	Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.
578
579	Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.
580
581	Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.
582
583	Embedding: L<Coro:MakeMaker>
584
585	=head1 AUTHOR
586
587	Marc Lehmann <schmorp@schmorp.de>
588	http://home.schmorp.de/
589
590	=cut
591