Coro/Coro.pm

=head1 NAME

Coro - coroutine process abstraction

=head1 SYNOPSIS

 use Coro;

 async {
    # some asynchronous thread of execution
 };

 # alternatively create an async coroutine like this:

 sub some_func : Coro {
    # some more async code
 }

 cede;

=head1 DESCRIPTION

This module collection manages coroutines. Coroutines are similar
to threads but don't run in parallel at the same time even on SMP
machines. The specific flavor of coroutine used in this module also
guarantees you that it will not switch between coroutines unless
necessary, at easily-identified points in your program, so locking and
parallel access are rarely an issue, making coroutine programming much
safer than threads programming.

(Perl, however, does not natively support real threads but instead does a
very slow and memory-intensive emulation of processes using threads. This
is a performance win on Windows machines, and a loss everywhere else).

In this module, coroutines are defined as "callchain + lexical variables +
@_ + $_ + $@ + $/ + C stack), that is, a coroutine has its own callchain,
its own set of lexicals and its own set of perls most important global
variables.

=cut

package Coro;

use strict;
no warnings "uninitialized";

use Coro::State;

use base qw(Coro::State Exporter);

our $idle;    # idle handler
our $main;    # main coroutine
our $current; # current coroutine

our $VERSION = '3.7';

our @EXPORT = qw(async async_pool cede schedule terminate current unblock_sub);
our %EXPORT_TAGS = (
      prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
);
our @EXPORT_OK = (@{$EXPORT_TAGS{prio}}, qw(nready));

{
   my @async;
   my $init;

   # this way of handling attributes simply is NOT scalable ;()
   sub import {
      no strict 'refs';

      Coro->export_to_level (1, @_);

      my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
      *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
         my ($package, $ref) = (shift, shift);
         my @attrs;
         for (@_) {
            if ($_ eq "Coro") {
               push @async, $ref;
               unless ($init++) {
                  eval q{
                     sub INIT {
                        &async(pop @async) while @async;
                     }
                  };
               }
            } else {
               push @attrs, $_;
            }
         }
         return $old ? $old->($package, $ref, @attrs) : @attrs;
      };
   }

}

=over 4

=item $main

This coroutine represents the main program.

=cut

$main = new Coro;

=item $current (or as function: current)

The current coroutine (the last coroutine switched to). The initial value
is C<$main> (of course).

This variable is B<strictly> I<read-only>. It is provided for performance
reasons. If performance is not essential you are encouraged to use the
C<Coro::current> function instead.

=cut

$main->{desc} = "[main::]";

# maybe some other module used Coro::Specific before...
$main->{specific} = $current->{specific}
   if $current;

_set_current $main;

sub current() { $current }

=item $idle

A callback that is called whenever the scheduler finds no ready coroutines
to run. The default implementation prints "FATAL: deadlock detected" and
exits, because the program has no other way to continue.

This hook is overwritten by modules such as C<Coro::Timer> and
C<Coro::Event> to wait on an external event that hopefully wake up a
coroutine so the scheduler can run it.

Please note that if your callback recursively invokes perl (e.g. for event
handlers), then it must be prepared to be called recursively.

=cut

$idle = sub {
   require Carp;
   Carp::croak ("FATAL: deadlock detected");
};

sub _cancel {
   my ($self) = @_;

   # free coroutine data and mark as destructed
   $self->_destroy
      or return;

   # call all destruction callbacks
   $_->(@{$self->{status}})
      for @{(delete $self->{destroy_cb}) || []};
}

# this coroutine is necessary because a coroutine
# cannot destroy itself.
my @destroy;
my $manager;

$manager = new Coro sub {
   $current->desc ("[coro manager]");

   while () {
      (shift @destroy)->_cancel
         while @destroy;

      &schedule;
   }
};

$manager->prio (PRIO_MAX);

# static methods. not really.

=back

=head2 STATIC METHODS

Static methods are actually functions that operate on the current coroutine only.

=over 4

=item async { ... } [@args...]

Create a new asynchronous coroutine and return it's coroutine object
(usually unused). When the sub returns the new coroutine is automatically
terminated.

Calling C<exit> in a coroutine will do the same as calling exit outside
the coroutine. Likewise, when the coroutine dies, the program will exit,
just as it would in the main program.

   # create a new coroutine that just prints its arguments
   async {
      print "@_\n";
   } 1,2,3,4;

=cut

sub async(&@) {
   my $coro = new Coro @_;
   $coro->ready;
   $coro
}

=item async_pool { ... } [@args...]

Similar to C<async>, but uses a coroutine pool, so you should not call
terminate or join (although you are allowed to), and you get a coroutine
that might have executed other code already (which can be good or bad :).

Also, the block is executed in an C<eval> context and a warning will be
issued in case of an exception instead of terminating the program, as
C<async> does. As the coroutine is being reused, stuff like C<on_destroy>
will not work in the expected way, unless you call terminate or cancel,
which somehow defeats the purpose of pooling.

The priority will be reset to C<0> after each job, otherwise the coroutine
will be re-used "as-is".

The pool size is limited to 8 idle coroutines (this can be adjusted by
changing $Coro::POOL_SIZE), and there can be as many non-idle coros as
required.

If you are concerned about pooled coroutines growing a lot because a
single C<async_pool> used a lot of stackspace you can e.g. C<async_pool {
terminate }> once per second or so to slowly replenish the pool.

=cut

our $POOL_SIZE = 8;
our $MAX_POOL_RSS = 64 * 1024;
our @pool;

sub pool_handler {
   while () {
      $current->{desc} = "[async_pool]";

      eval {
         my ($cb, @arg) = @{ delete $current->{_invoke} or return };
         $cb->(@arg);
      };
      warn $@ if $@;

      last if @pool >= $POOL_SIZE || $current->rss >= $MAX_POOL_RSS;

      push @pool, $current;
      $current->{desc} = "[async_pool idle]";
      $current->save (Coro::State::SAVE_DEF);
      $current->prio (0);
      schedule;
   }
}

sub async_pool(&@) {
   # this is also inlined into the unlock_scheduler
   my $coro = (pop @pool) || new Coro \&pool_handler;;

   $coro->{_invoke} = [@_];
   $coro->ready;

   $coro
}

=item schedule

Calls the scheduler. Please note that the current coroutine will not be put
into the ready queue, so calling this function usually means you will
never be called again unless something else (e.g. an event handler) calls
ready.

The canonical way to wait on external events is this:

   {
      # remember current coroutine
      my $current = $Coro::current;

      # register a hypothetical event handler
      on_event_invoke sub {
         # wake up sleeping coroutine
         $current->ready;
         undef $current;
      };

      # call schedule until event occurred.
      # in case we are woken up for other reasons
      # (current still defined), loop.
      Coro::schedule while $current;
   }

=item cede

"Cede" to other coroutines. This function puts the current coroutine into the
ready queue and calls C<schedule>, which has the effect of giving up the
current "timeslice" to other coroutines of the same or higher priority.

Returns true if at least one coroutine switch has happened.

=item Coro::cede_notself

Works like cede, but is not exported by default and will cede to any
coroutine, regardless of priority, once.

Returns true if at least one coroutine switch has happened.

=item terminate [arg...]

Terminates the current coroutine with the given status values (see L<cancel>).

=cut

sub terminate {
   $current->cancel (@_);
}

=back

# dynamic methods

=head2 COROUTINE METHODS

These are the methods you can call on coroutine objects.

=over 4

=item new Coro \&sub [, @args...]

Create a new coroutine and return it. When the sub returns the coroutine
automatically terminates as if C<terminate> with the returned values were
called. To make the coroutine run you must first put it into the ready queue
by calling the ready method.

See C<async> for additional discussion.

=cut

sub _run_coro {
   terminate &{+shift};
}

sub new {
   my $class = shift;

   $class->SUPER::new (\&_run_coro, @_)
}

=item $success = $coroutine->ready

Put the given coroutine into the ready queue (according to it's priority)
and return true. If the coroutine is already in the ready queue, do nothing
and return false.

=item $is_ready = $coroutine->is_ready

Return wether the coroutine is currently the ready queue or not,

=item $coroutine->cancel (arg...)

Terminates the given coroutine and makes it return the given arguments as
status (default: the empty list). Never returns if the coroutine is the
current coroutine.

=cut

sub cancel {
   my $self = shift;
   $self->{status} = [@_];

   if ($current == $self) {
      push @destroy, $self;
      $manager->ready;
      &schedule while 1;
   } else {
      $self->_cancel;
   }
}

=item $coroutine->join

Wait until the coroutine terminates and return any values given to the
C<terminate> or C<cancel> functions. C<join> can be called multiple times
from multiple coroutine.

=cut

sub join {
   my $self = shift;

   unless ($self->{status}) {
      my $current = $current;

      push @{$self->{destroy_cb}}, sub {
         $current->ready;
         undef $current;
      };

      &schedule while $current;
   }

   wantarray ? @{$self->{status}} : $self->{status}[0];
}

=item $coroutine->on_destroy (\&cb)

Registers a callback that is called when this coroutine gets destroyed,
but before it is joined. The callback gets passed the terminate arguments,
if any.

=cut

sub on_destroy {
   my ($self, $cb) = @_;

   push @{ $self->{destroy_cb} }, $cb;
}

=item $oldprio = $coroutine->prio ($newprio)

Sets (or gets, if the argument is missing) the priority of the
coroutine. Higher priority coroutines get run before lower priority
coroutines. Priorities are small signed integers (currently -4 .. +3),
that you can refer to using PRIO_xxx constants (use the import tag :prio
to get then):

   PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
       3    >     1     >      0      >    -1    >    -3     >    -4

   # set priority to HIGH
   current->prio(PRIO_HIGH);

The idle coroutine ($Coro::idle) always has a lower priority than any
existing coroutine.

Changing the priority of the current coroutine will take effect immediately,
but changing the priority of coroutines in the ready queue (but not
running) will only take effect after the next schedule (of that
coroutine). This is a bug that will be fixed in some future version.

=item $newprio = $coroutine->nice ($change)

Similar to C<prio>, but subtract the given value from the priority (i.e.
higher values mean lower priority, just as in unix).

=item $olddesc = $coroutine->desc ($newdesc)

Sets (or gets in case the argument is missing) the description for this
coroutine. This is just a free-form string you can associate with a coroutine.

=cut

sub desc {
   my $old = $_[0]{desc};
   $_[0]{desc} = $_[1] if @_ > 1;
   $old;
}

=back

=head2 GLOBAL FUNCTIONS

=over 4

=item Coro::nready

Returns the number of coroutines that are currently in the ready state,
i.e. that can be switched to. The value C<0> means that the only runnable
coroutine is the currently running one, so C<cede> would have no effect,
and C<schedule> would cause a deadlock unless there is an idle handler
that wakes up some coroutines.

=item my $guard = Coro::guard { ... }

This creates and returns a guard object. Nothing happens until the object
gets destroyed, in which case the codeblock given as argument will be
executed. This is useful to free locks or other resources in case of a
runtime error or when the coroutine gets canceled, as in both cases the
guard block will be executed. The guard object supports only one method,
C<< ->cancel >>, which will keep the codeblock from being executed.

Example: set some flag and clear it again when the coroutine gets canceled
or the function returns:

   sub do_something {
      my $guard = Coro::guard { $busy = 0 };
      $busy = 1;

      # do something that requires $busy to be true
   }

=cut

sub guard(&) {
   bless \(my $cb = $_[0]), "Coro::guard"
}

sub Coro::guard::cancel {
   ${$_[0]} = sub { };
}

sub Coro::guard::DESTROY {
   ${$_[0]}->();
}


=item unblock_sub { ... }

This utility function takes a BLOCK or code reference and "unblocks" it,
returning the new coderef. This means that the new coderef will return
immediately without blocking, returning nothing, while the original code
ref will be called (with parameters) from within its own coroutine.

The reason this function exists is that many event libraries (such as the
venerable L<Event|Event> module) are not coroutine-safe (a weaker form
of thread-safety). This means you must not block within event callbacks,
otherwise you might suffer from crashes or worse.

This function allows your callbacks to block by executing them in another
coroutine where it is safe to block. One example where blocking is handy
is when you use the L<Coro::AIO|Coro::AIO> functions to save results to
disk.

In short: simply use C<unblock_sub { ... }> instead of C<sub { ... }> when
creating event callbacks that want to block.

=cut

our @unblock_queue;

# we create a special coro because we want to cede,
# to reduce pressure on the coro pool (because most callbacks
# return immediately and can be reused) and because we cannot cede
# inside an event callback.
our $unblock_scheduler = async {
   $current->desc ("[unblock_sub scheduler]");
   while () {
      while (my $cb = pop @unblock_queue) {
         # this is an inlined copy of async_pool
         my $coro = (pop @pool or new Coro \&pool_handler);

         $coro->{_invoke} = $cb;
         $coro->ready;
         cede; # for short-lived callbacks, this reduces pressure on the coro pool
      }
      schedule; # sleep well
   }
};

sub unblock_sub(&) {
   my $cb = shift;

   sub {
      unshift @unblock_queue, [$cb, @_];
      $unblock_scheduler->ready;
   }
}

=back

=cut

1;

=head1 BUGS/LIMITATIONS

 - you must make very sure that no coro is still active on global
   destruction. very bad things might happen otherwise (usually segfaults).

 - this module is not thread-safe. You should only ever use this module
   from the same thread (this requirement might be loosened in the future
   to allow per-thread schedulers, but Coro::State does not yet allow
   this).

=head1 SEE ALSO

Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.

Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.

Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.

Embedding: L<Coro:MakeMaker>

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

Revision:	1.131
Committed:	Thu Sep 20 12:24:42 2007 UTC (16 years, 8 months ago) by root
Branch:	MAIN
Changes since 1.130:	+2 -0 lines
Log Message:	* empty log message *
#	Content
1	=head1 NAME
2
3	Coro - coroutine process abstraction
4
5	=head1 SYNOPSIS
6
7	use Coro;
8
9	async {
10	# some asynchronous thread of execution
11	};
12
13	# alternatively create an async coroutine like this:
14
15	sub some_func : Coro {
16	# some more async code
17	}
18
19	cede;
20
21	=head1 DESCRIPTION
22
23	This module collection manages coroutines. Coroutines are similar
24	to threads but don't run in parallel at the same time even on SMP
25	machines. The specific flavor of coroutine used in this module also
26	guarantees you that it will not switch between coroutines unless
27	necessary, at easily-identified points in your program, so locking and
28	parallel access are rarely an issue, making coroutine programming much
29	safer than threads programming.
30
31	(Perl, however, does not natively support real threads but instead does a
32	very slow and memory-intensive emulation of processes using threads. This
33	is a performance win on Windows machines, and a loss everywhere else).
34
35	In this module, coroutines are defined as "callchain + lexical variables +
36	@_ + $_ + $@ + $/ + C stack), that is, a coroutine has its own callchain,
37	its own set of lexicals and its own set of perls most important global
38	variables.
39
40	=cut
41
42	package Coro;
43
44	use strict;
45	no warnings "uninitialized";
46
47	use Coro::State;
48
49	use base qw(Coro::State Exporter);
50
51	our $idle; # idle handler
52	our $main; # main coroutine
53	our $current; # current coroutine
54
55	our $VERSION = '3.7';
56
57	our @EXPORT = qw(async async_pool cede schedule terminate current unblock_sub);
58	our %EXPORT_TAGS = (
59	prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
60	);
61	our @EXPORT_OK = (@{$EXPORT_TAGS{prio}}, qw(nready));
62
63	{
64	my @async;
65	my $init;
66
67	# this way of handling attributes simply is NOT scalable ;()
68	sub import {
69	no strict 'refs';
70
71	Coro->export_to_level (1, @_);
72
73	my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
74	*{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
75	my ($package, $ref) = (shift, shift);
76	my @attrs;
77	for (@_) {
78	if ($_ eq "Coro") {
79	push @async, $ref;
80	unless ($init++) {
81	eval q{
82	sub INIT {
83	&async(pop @async) while @async;
84	}
85	};
86	}
87	} else {
88	push @attrs, $_;
89	}
90	}
91	return $old ? $old->($package, $ref, @attrs) : @attrs;
92	};
93	}
94
95	}
96
97	=over 4
98
99	=item $main
100
101	This coroutine represents the main program.
102
103	=cut
104
105	$main = new Coro;
106
107	=item $current (or as function: current)
108
109	The current coroutine (the last coroutine switched to). The initial value
110	is C<$main> (of course).
111
112	This variable is B<strictly> I<read-only>. It is provided for performance
113	reasons. If performance is not essential you are encouraged to use the
114	C<Coro::current> function instead.
115
116	=cut
117
118	$main->{desc} = "[main::]";
119
120	# maybe some other module used Coro::Specific before...
121	$main->{specific} = $current->{specific}
122	if $current;
123
124	_set_current $main;
125
126	sub current() { $current }
127
128	=item $idle
129
130	A callback that is called whenever the scheduler finds no ready coroutines
131	to run. The default implementation prints "FATAL: deadlock detected" and
132	exits, because the program has no other way to continue.
133
134	This hook is overwritten by modules such as C<Coro::Timer> and
135	C<Coro::Event> to wait on an external event that hopefully wake up a
136	coroutine so the scheduler can run it.
137
138	Please note that if your callback recursively invokes perl (e.g. for event
139	handlers), then it must be prepared to be called recursively.
140
141	=cut
142
143	$idle = sub {
144	require Carp;
145	Carp::croak ("FATAL: deadlock detected");
146	};
147
148	sub _cancel {
149	my ($self) = @_;
150
151	# free coroutine data and mark as destructed
152	$self->_destroy
153	or return;
154
155	# call all destruction callbacks
156	$_->(@{$self->{status}})
157	for @{(delete $self->{destroy_cb}) \|\| []};
158	}
159
160	# this coroutine is necessary because a coroutine
161	# cannot destroy itself.
162	my @destroy;
163	my $manager;
164
165	$manager = new Coro sub {
166	$current->desc ("[coro manager]");
167
168	while () {
169	(shift @destroy)->_cancel
170	while @destroy;
171
172	&schedule;
173	}
174	};
175
176	$manager->prio (PRIO_MAX);
177
178	# static methods. not really.
179
180	=back
181
182	=head2 STATIC METHODS
183
184	Static methods are actually functions that operate on the current coroutine only.
185
186	=over 4
187
188	=item async { ... } [@args...]
189
190	Create a new asynchronous coroutine and return it's coroutine object
191	(usually unused). When the sub returns the new coroutine is automatically
192	terminated.
193
194	Calling C<exit> in a coroutine will do the same as calling exit outside
195	the coroutine. Likewise, when the coroutine dies, the program will exit,
196	just as it would in the main program.
197
198	# create a new coroutine that just prints its arguments
199	async {
200	print "@_\n";
201	} 1,2,3,4;
202
203	=cut
204
205	sub async(&@) {
206	my $coro = new Coro @_;
207	$coro->ready;
208	$coro
209	}
210
211	=item async_pool { ... } [@args...]
212
213	Similar to C<async>, but uses a coroutine pool, so you should not call
214	terminate or join (although you are allowed to), and you get a coroutine
215	that might have executed other code already (which can be good or bad :).
216
217	Also, the block is executed in an C<eval> context and a warning will be
218	issued in case of an exception instead of terminating the program, as
219	C<async> does. As the coroutine is being reused, stuff like C<on_destroy>
220	will not work in the expected way, unless you call terminate or cancel,
221	which somehow defeats the purpose of pooling.
222
223	The priority will be reset to C<0> after each job, otherwise the coroutine
224	will be re-used "as-is".
225
226	The pool size is limited to 8 idle coroutines (this can be adjusted by
227	changing $Coro::POOL_SIZE), and there can be as many non-idle coros as
228	required.
229
230	If you are concerned about pooled coroutines growing a lot because a
231	single C<async_pool> used a lot of stackspace you can e.g. C<async_pool {
232	terminate }> once per second or so to slowly replenish the pool.
233
234	=cut
235
236	our $POOL_SIZE = 8;
237	our $MAX_POOL_RSS = 64 * 1024;
238	our @pool;
239
240	sub pool_handler {
241	while () {
242	$current->{desc} = "[async_pool]";
243
244	eval {
245	my ($cb, @arg) = @{ delete $current->{_invoke} or return };
246	$cb->(@arg);
247	};
248	warn $@ if $@;
249
250	last if @pool >= $POOL_SIZE \|\| $current->rss >= $MAX_POOL_RSS;
251
252	push @pool, $current;
253	$current->{desc} = "[async_pool idle]";
254	$current->save (Coro::State::SAVE_DEF);
255	$current->prio (0);
256	schedule;
257	}
258	}
259
260	sub async_pool(&@) {
261	# this is also inlined into the unlock_scheduler
262	my $coro = (pop @pool) \|\| new Coro \&pool_handler;;
263
264	$coro->{_invoke} = [@_];
265	$coro->ready;
266
267	$coro
268	}
269
270	=item schedule
271
272	Calls the scheduler. Please note that the current coroutine will not be put
273	into the ready queue, so calling this function usually means you will
274	never be called again unless something else (e.g. an event handler) calls
275	ready.
276
277	The canonical way to wait on external events is this:
278
279	{
280	# remember current coroutine
281	my $current = $Coro::current;
282
283	# register a hypothetical event handler
284	on_event_invoke sub {
285	# wake up sleeping coroutine
286	$current->ready;
287	undef $current;
288	};
289
290	# call schedule until event occurred.
291	# in case we are woken up for other reasons
292	# (current still defined), loop.
293	Coro::schedule while $current;
294	}
295
296	=item cede
297
298	"Cede" to other coroutines. This function puts the current coroutine into the
299	ready queue and calls C<schedule>, which has the effect of giving up the
300	current "timeslice" to other coroutines of the same or higher priority.
301
302	Returns true if at least one coroutine switch has happened.
303
304	=item Coro::cede_notself
305
306	Works like cede, but is not exported by default and will cede to any
307	coroutine, regardless of priority, once.
308
309	Returns true if at least one coroutine switch has happened.
310
311	=item terminate [arg...]
312
313	Terminates the current coroutine with the given status values (see L<cancel>).
314
315	=cut
316
317	sub terminate {
318	$current->cancel (@_);
319	}
320
321	=back
322
323	# dynamic methods
324
325	=head2 COROUTINE METHODS
326
327	These are the methods you can call on coroutine objects.
328
329	=over 4
330
331	=item new Coro \&sub [, @args...]
332
333	Create a new coroutine and return it. When the sub returns the coroutine
334	automatically terminates as if C<terminate> with the returned values were
335	called. To make the coroutine run you must first put it into the ready queue
336	by calling the ready method.
337
338	See C<async> for additional discussion.
339
340	=cut
341
342	sub _run_coro {
343	terminate &{+shift};
344	}
345
346	sub new {
347	my $class = shift;
348
349	$class->SUPER::new (\&_run_coro, @_)
350	}
351
352	=item $success = $coroutine->ready
353
354	Put the given coroutine into the ready queue (according to it's priority)
355	and return true. If the coroutine is already in the ready queue, do nothing
356	and return false.
357
358	=item $is_ready = $coroutine->is_ready
359
360	Return wether the coroutine is currently the ready queue or not,
361
362	=item $coroutine->cancel (arg...)
363
364	Terminates the given coroutine and makes it return the given arguments as
365	status (default: the empty list). Never returns if the coroutine is the
366	current coroutine.
367
368	=cut
369
370	sub cancel {
371	my $self = shift;
372	$self->{status} = [@_];
373
374	if ($current == $self) {
375	push @destroy, $self;
376	$manager->ready;
377	&schedule while 1;
378	} else {
379	$self->_cancel;
380	}
381	}
382
383	=item $coroutine->join
384
385	Wait until the coroutine terminates and return any values given to the
386	C<terminate> or C<cancel> functions. C<join> can be called multiple times
387	from multiple coroutine.
388
389	=cut
390
391	sub join {
392	my $self = shift;
393
394	unless ($self->{status}) {
395	my $current = $current;
396
397	push @{$self->{destroy_cb}}, sub {
398	$current->ready;
399	undef $current;
400	};
401
402	&schedule while $current;
403	}
404
405	wantarray ? @{$self->{status}} : $self->{status}[0];
406	}
407
408	=item $coroutine->on_destroy (\&cb)
409
410	Registers a callback that is called when this coroutine gets destroyed,
411	but before it is joined. The callback gets passed the terminate arguments,
412	if any.
413
414	=cut
415
416	sub on_destroy {
417	my ($self, $cb) = @_;
418
419	push @{ $self->{destroy_cb} }, $cb;
420	}
421
422	=item $oldprio = $coroutine->prio ($newprio)
423
424	Sets (or gets, if the argument is missing) the priority of the
425	coroutine. Higher priority coroutines get run before lower priority
426	coroutines. Priorities are small signed integers (currently -4 .. +3),
427	that you can refer to using PRIO_xxx constants (use the import tag :prio
428	to get then):
429
430	PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
431	3 > 1 > 0 > -1 > -3 > -4
432
433	# set priority to HIGH
434	current->prio(PRIO_HIGH);
435
436	The idle coroutine ($Coro::idle) always has a lower priority than any
437	existing coroutine.
438
439	Changing the priority of the current coroutine will take effect immediately,
440	but changing the priority of coroutines in the ready queue (but not
441	running) will only take effect after the next schedule (of that
442	coroutine). This is a bug that will be fixed in some future version.
443
444	=item $newprio = $coroutine->nice ($change)
445
446	Similar to C<prio>, but subtract the given value from the priority (i.e.
447	higher values mean lower priority, just as in unix).
448
449	=item $olddesc = $coroutine->desc ($newdesc)
450
451	Sets (or gets in case the argument is missing) the description for this
452	coroutine. This is just a free-form string you can associate with a coroutine.
453
454	=cut
455
456	sub desc {
457	my $old = $_[0]{desc};
458	$_[0]{desc} = $_[1] if @_ > 1;
459	$old;
460	}
461
462	=back
463
464	=head2 GLOBAL FUNCTIONS
465
466	=over 4
467
468	=item Coro::nready
469
470	Returns the number of coroutines that are currently in the ready state,
471	i.e. that can be switched to. The value C<0> means that the only runnable
472	coroutine is the currently running one, so C<cede> would have no effect,
473	and C<schedule> would cause a deadlock unless there is an idle handler
474	that wakes up some coroutines.
475
476	=item my $guard = Coro::guard { ... }
477
478	This creates and returns a guard object. Nothing happens until the object
479	gets destroyed, in which case the codeblock given as argument will be
480	executed. This is useful to free locks or other resources in case of a
481	runtime error or when the coroutine gets canceled, as in both cases the
482	guard block will be executed. The guard object supports only one method,
483	C<< ->cancel >>, which will keep the codeblock from being executed.
484
485	Example: set some flag and clear it again when the coroutine gets canceled
486	or the function returns:
487
488	sub do_something {
489	my $guard = Coro::guard { $busy = 0 };
490	$busy = 1;
491
492	# do something that requires $busy to be true
493	}
494
495	=cut
496
497	sub guard(&) {
498	bless \(my $cb = $_[0]), "Coro::guard"
499	}
500
501	sub Coro::guard::cancel {
502	${$_[0]} = sub { };
503	}
504
505	sub Coro::guard::DESTROY {
506	${$_[0]}->();
507	}
508
509
510	=item unblock_sub { ... }
511
512	This utility function takes a BLOCK or code reference and "unblocks" it,
513	returning the new coderef. This means that the new coderef will return
514	immediately without blocking, returning nothing, while the original code
515	ref will be called (with parameters) from within its own coroutine.
516
517	The reason this function exists is that many event libraries (such as the
518	venerable L<Event\|Event> module) are not coroutine-safe (a weaker form
519	of thread-safety). This means you must not block within event callbacks,
520	otherwise you might suffer from crashes or worse.
521
522	This function allows your callbacks to block by executing them in another
523	coroutine where it is safe to block. One example where blocking is handy
524	is when you use the L<Coro::AIO\|Coro::AIO> functions to save results to
525	disk.
526
527	In short: simply use C<unblock_sub { ... }> instead of C<sub { ... }> when
528	creating event callbacks that want to block.
529
530	=cut
531
532	our @unblock_queue;
533
534	# we create a special coro because we want to cede,
535	# to reduce pressure on the coro pool (because most callbacks
536	# return immediately and can be reused) and because we cannot cede
537	# inside an event callback.
538	our $unblock_scheduler = async {
539	$current->desc ("[unblock_sub scheduler]");
540	while () {
541	while (my $cb = pop @unblock_queue) {
542	# this is an inlined copy of async_pool
543	my $coro = (pop @pool or new Coro \&pool_handler);
544
545	$coro->{_invoke} = $cb;
546	$coro->ready;
547	cede; # for short-lived callbacks, this reduces pressure on the coro pool
548	}
549	schedule; # sleep well
550	}
551	};
552
553	sub unblock_sub(&) {
554	my $cb = shift;
555
556	sub {
557	unshift @unblock_queue, [$cb, @_];
558	$unblock_scheduler->ready;
559	}
560	}
561
562	=back
563
564	=cut
565
566	1;
567
568	=head1 BUGS/LIMITATIONS
569
570	- you must make very sure that no coro is still active on global
571	destruction. very bad things might happen otherwise (usually segfaults).
572
573	- this module is not thread-safe. You should only ever use this module
574	from the same thread (this requirement might be loosened in the future
575	to allow per-thread schedulers, but Coro::State does not yet allow
576	this).
577
578	=head1 SEE ALSO
579
580	Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.
581
582	Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.
583
584	Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.
585
586	Embedding: L<Coro:MakeMaker>
587
588	=head1 AUTHOR
589
590	Marc Lehmann <schmorp@schmorp.de>
591	http://home.schmorp.de/
592
593	=cut
594