Coro/Coro.pm

=head1 NAME

Coro - coroutine process abstraction

=head1 SYNOPSIS

 use Coro;

 async {
    # some asynchronous thread of execution
 };

 # alternatively create an async coroutine like this:

 sub some_func : Coro {
    # some more async code
 }

 cede;

=head1 DESCRIPTION

This module collection manages coroutines. Coroutines are similar
to threads but don't run in parallel at the same time even on SMP
machines. The specific flavor of coroutine use din this module also
guarentees you that it will not switch between coroutines unless
necessary, at easily-identified points in your program, so locking and
parallel access are rarely an issue, making coroutine programming much
safer than threads programming.

(Perl, however, does not natively support real threads but instead does a
very slow and memory-intensive emulation of processes using threads. This
is a performance win on Windows machines, and a loss everywhere else).

In this module, coroutines are defined as "callchain + lexical variables +
@_ + $_ + $@ + $/ + C stack), that is, a coroutine has its own callchain,
its own set of lexicals and its own set of perls most important global
variables.

=cut

package Coro;

use strict;
no warnings "uninitialized";

use Coro::State;

use base qw(Coro::State Exporter);

our $idle;    # idle handler
our $main;    # main coroutine
our $current; # current coroutine

our $VERSION = '3.3';

our @EXPORT = qw(async cede schedule terminate current unblock_sub);
our %EXPORT_TAGS = (
      prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
);
our @EXPORT_OK = (@{$EXPORT_TAGS{prio}}, qw(nready));

{
   my @async;
   my $init;

   # this way of handling attributes simply is NOT scalable ;()
   sub import {
      no strict 'refs';

      Coro->export_to_level (1, @_);

      my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
      *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
         my ($package, $ref) = (shift, shift);
         my @attrs;
         for (@_) {
            if ($_ eq "Coro") {
               push @async, $ref;
               unless ($init++) {
                  eval q{
                     sub INIT {
                        &async(pop @async) while @async;
                     }
                  };
               }
            } else {
               push @attrs, $_;
            }
         }
         return $old ? $old->($package, $ref, @attrs) : @attrs;
      };
   }

}

=over 4

=item $main

This coroutine represents the main program.

=cut

$main = new Coro;

=item $current (or as function: current)

The current coroutine (the last coroutine switched to). The initial value
is C<$main> (of course).

This variable is B<strictly> I<read-only>. It is provided for performance
reasons. If performance is not essentiel you are encouraged to use the
C<Coro::current> function instead.

=cut

# maybe some other module used Coro::Specific before...
$main->{specific} = $current->{specific}
   if $current;

_set_current $main;

sub current() { $current }

=item $idle

A callback that is called whenever the scheduler finds no ready coroutines
to run. The default implementation prints "FATAL: deadlock detected" and
exits, because the program has no other way to continue.

This hook is overwritten by modules such as C<Coro::Timer> and
C<Coro::Event> to wait on an external event that hopefully wake up a
coroutine so the scheduler can run it.

Please note that if your callback recursively invokes perl (e.g. for event
handlers), then it must be prepared to be called recursively.

=cut

$idle = sub {
   require Carp;
   Carp::croak ("FATAL: deadlock detected");
};

sub _cancel {
   my ($self) = @_;

   # free coroutine data and mark as destructed
   $self->_destroy
      or return;

   # call all destruction callbacks
   $_->(@{$self->{status}})
      for @{(delete $self->{destroy_cb}) || []};
}

# this coroutine is necessary because a coroutine
# cannot destroy itself.
my @destroy;
my $manager;

$manager = new Coro sub {
   while () {
      (shift @destroy)->_cancel
         while @destroy;

      &schedule;
   }
};

$manager->prio (PRIO_MAX);

# static methods. not really.

=back

=head2 STATIC METHODS

Static methods are actually functions that operate on the current coroutine only.

=over 4

=item async { ... } [@args...]

Create a new asynchronous coroutine and return it's coroutine object
(usually unused). When the sub returns the new coroutine is automatically
terminated.

Calling C<exit> in a coroutine will not work correctly, so do not do that.

When the coroutine dies, the program will exit, just as in the main
program.

   # create a new coroutine that just prints its arguments
   async {
      print "@_\n";
   } 1,2,3,4;

=cut

sub async(&@) {
   my $pid = new Coro @_;
   $pid->ready;
   $pid
}

=item schedule

Calls the scheduler. Please note that the current coroutine will not be put
into the ready queue, so calling this function usually means you will
never be called again unless something else (e.g. an event handler) calls
ready.

The canonical way to wait on external events is this:

   {
      # remember current coroutine
      my $current = $Coro::current;

      # register a hypothetical event handler
      on_event_invoke sub {
         # wake up sleeping coroutine
         $current->ready;
         undef $current;
      };

      # call schedule until event occured.
      # in case we are woken up for other reasons
      # (current still defined), loop.
      Coro::schedule while $current;
   }

=item cede

"Cede" to other coroutines. This function puts the current coroutine into the
ready queue and calls C<schedule>, which has the effect of giving up the
current "timeslice" to other coroutines of the same or higher priority.

=item Coro::cede_notself

Works like cede, but is not exported by default and will cede to any
coroutine, regardless of priority, once.

=item terminate [arg...]

Terminates the current coroutine with the given status values (see L<cancel>).

=cut

sub terminate {
   $current->cancel (@_);
}

=back

# dynamic methods

=head2 COROUTINE METHODS

These are the methods you can call on coroutine objects.

=over 4

=item new Coro \&sub [, @args...]

Create a new coroutine and return it. When the sub returns the coroutine
automatically terminates as if C<terminate> with the returned values were
called. To make the coroutine run you must first put it into the ready queue
by calling the ready method.

Calling C<exit> in a coroutine will not work correctly, so do not do that.

=cut

sub _run_coro {
   terminate &{+shift};
}

sub new {
   my $class = shift;

   $class->SUPER::new (\&_run_coro, @_)
}

=item $success = $coroutine->ready

Put the given coroutine into the ready queue (according to it's priority)
and return true. If the coroutine is already in the ready queue, do nothing
and return false.

=item $is_ready = $coroutine->is_ready

Return wether the coroutine is currently the ready queue or not,

=item $coroutine->cancel (arg...)

Terminates the given coroutine and makes it return the given arguments as
status (default: the empty list). Never returns if the coroutine is the
current coroutine.

=cut

sub cancel {
   my $self = shift;
   $self->{status} = [@_];

   if ($current == $self) {
      push @destroy, $self;
      $manager->ready;
      &schedule while 1;
   } else {
      $self->_cancel;
   }
}

=item $coroutine->join

Wait until the coroutine terminates and return any values given to the
C<terminate> or C<cancel> functions. C<join> can be called multiple times
from multiple coroutine.

=cut

sub join {
   my $self = shift;

   unless ($self->{status}) {
      my $current = $current;

      push @{$self->{destroy_cb}}, sub {
         $current->ready;
         undef $current;
      };

      &schedule while $current;
   }

   wantarray ? @{$self->{status}} : $self->{status}[0];
}

=item $coroutine->on_destroy (\&cb)

Registers a callback that is called when this coroutine gets destroyed,
but before it is joined. The callback gets passed the terminate arguments,
if any.

=cut

sub on_destroy {
   my ($self, $cb) = @_;

   push @{ $self->{destroy_cb} }, $cb;
}

=item $oldprio = $coroutine->prio ($newprio)

Sets (or gets, if the argument is missing) the priority of the
coroutine. Higher priority coroutines get run before lower priority
coroutines. Priorities are small signed integers (currently -4 .. +3),
that you can refer to using PRIO_xxx constants (use the import tag :prio
to get then):

   PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
       3    >     1     >      0      >    -1    >    -3     >    -4

   # set priority to HIGH
   current->prio(PRIO_HIGH);

The idle coroutine ($Coro::idle) always has a lower priority than any
existing coroutine.

Changing the priority of the current coroutine will take effect immediately,
but changing the priority of coroutines in the ready queue (but not
running) will only take effect after the next schedule (of that
coroutine). This is a bug that will be fixed in some future version.

=item $newprio = $coroutine->nice ($change)

Similar to C<prio>, but subtract the given value from the priority (i.e.
higher values mean lower priority, just as in unix).

=item $olddesc = $coroutine->desc ($newdesc)

Sets (or gets in case the argument is missing) the description for this
coroutine. This is just a free-form string you can associate with a coroutine.

=cut

sub desc {
   my $old = $_[0]{desc};
   $_[0]{desc} = $_[1] if @_ > 1;
   $old;
}

=back

=head2 GLOBAL FUNCTIONS

=over 4

=item Coro::nready

Returns the number of coroutines that are currently in the ready state,
i.e. that can be swicthed to. The value C<0> means that the only runnable
coroutine is the currently running one, so C<cede> would have no effect,
and C<schedule> would cause a deadlock unless there is an idle handler
that wakes up some coroutines.

=item my $guard = Coro::guard { ... }

This creates and returns a guard object. Nothing happens until the objetc
gets destroyed, in which case the codeblock given as argument will be
executed. This is useful to free locks or other resources in case of a
runtime error or when the coroutine gets canceled, as in both cases the
guard block will be executed. The guard object supports only one method,
C<< ->cancel >>, which will keep the codeblock from being executed.

Example: set some flag and clear it again when the coroutine gets canceled
or the function returns:

   sub do_something {
      my $guard = Coro::guard { $busy = 0 };
      $busy = 1;

      # do something that requires $busy to be true
   }

=cut

sub guard(&) {
   bless \(my $cb = $_[0]), "Coro::guard"
}

sub Coro::guard::cancel {
   ${$_[0]} = sub { };
}

sub Coro::guard::DESTROY {
   ${$_[0]}->();
}


=item unblock_sub { ... }

This utility function takes a BLOCK or code reference and "unblocks" it,
returning the new coderef. This means that the new coderef will return
immediately without blocking, returning nothing, while the original code
ref will be called (with parameters) from within its own coroutine.

The reason this fucntion exists is that many event libraries (such as the
venerable L<Event|Event> module) are not coroutine-safe (a weaker form
of thread-safety). This means you must not block within event callbacks,
otherwise you might suffer from crashes or worse.

This function allows your callbacks to block by executing them in another
coroutine where it is safe to block. One example where blocking is handy
is when you use the L<Coro::AIO|Coro::AIO> functions to save results to
disk.

In short: simply use C<unblock_sub { ... }> instead of C<sub { ... }> when
creating event callbacks that want to block.

=cut

our @unblock_pool;
our @unblock_queue;
our $UNBLOCK_POOL_SIZE = 2;

sub unblock_handler_ {
   while () {
      my ($cb, @arg) = @{ delete $Coro::current->{arg} };
      $cb->(@arg);

      last if @unblock_pool >= $UNBLOCK_POOL_SIZE;
      push @unblock_pool, $Coro::current;
      schedule;
   }        
}           

our $unblock_scheduler = async {
   while () {
      while (my $cb = pop @unblock_queue) {
         my $handler = (pop @unblock_pool or new Coro \&unblock_handler_);
         $handler->{arg} = $cb;
         $handler->ready;
         cede;
      }

      schedule;
   }
};

sub unblock_sub(&) {
   my $cb = shift;

   sub {
      push @unblock_queue, [$cb, @_];
      $unblock_scheduler->ready;
   }
}

=back

=cut

1;

=head1 BUGS/LIMITATIONS

 - you must make very sure that no coro is still active on global
   destruction. very bad things might happen otherwise (usually segfaults).

 - this module is not thread-safe. You should only ever use this module
   from the same thread (this requirement might be losened in the future
   to allow per-thread schedulers, but Coro::State does not yet allow
   this).

=head1 SEE ALSO

Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.

Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.

Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.

Embedding: L<Coro:MakeMaker>

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

Revision:	1.103
Committed:	Thu Jan 4 20:14:19 2007 UTC (17 years, 5 months ago) by root
Branch:	MAIN
Changes since 1.102:	+74 -26 lines
Log Message:	* empty log message *
#	Content
1	=head1 NAME
2
3	Coro - coroutine process abstraction
4
5	=head1 SYNOPSIS
6
7	use Coro;
8
9	async {
10	# some asynchronous thread of execution
11	};
12
13	# alternatively create an async coroutine like this:
14
15	sub some_func : Coro {
16	# some more async code
17	}
18
19	cede;
20
21	=head1 DESCRIPTION
22
23	This module collection manages coroutines. Coroutines are similar
24	to threads but don't run in parallel at the same time even on SMP
25	machines. The specific flavor of coroutine use din this module also
26	guarentees you that it will not switch between coroutines unless
27	necessary, at easily-identified points in your program, so locking and
28	parallel access are rarely an issue, making coroutine programming much
29	safer than threads programming.
30
31	(Perl, however, does not natively support real threads but instead does a
32	very slow and memory-intensive emulation of processes using threads. This
33	is a performance win on Windows machines, and a loss everywhere else).
34
35	In this module, coroutines are defined as "callchain + lexical variables +
36	@_ + $_ + $@ + $/ + C stack), that is, a coroutine has its own callchain,
37	its own set of lexicals and its own set of perls most important global
38	variables.
39
40	=cut
41
42	package Coro;
43
44	use strict;
45	no warnings "uninitialized";
46
47	use Coro::State;
48
49	use base qw(Coro::State Exporter);
50
51	our $idle; # idle handler
52	our $main; # main coroutine
53	our $current; # current coroutine
54
55	our $VERSION = '3.3';
56
57	our @EXPORT = qw(async cede schedule terminate current unblock_sub);
58	our %EXPORT_TAGS = (
59	prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
60	);
61	our @EXPORT_OK = (@{$EXPORT_TAGS{prio}}, qw(nready));
62
63	{
64	my @async;
65	my $init;
66
67	# this way of handling attributes simply is NOT scalable ;()
68	sub import {
69	no strict 'refs';
70
71	Coro->export_to_level (1, @_);
72
73	my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
74	*{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
75	my ($package, $ref) = (shift, shift);
76	my @attrs;
77	for (@_) {
78	if ($_ eq "Coro") {
79	push @async, $ref;
80	unless ($init++) {
81	eval q{
82	sub INIT {
83	&async(pop @async) while @async;
84	}
85	};
86	}
87	} else {
88	push @attrs, $_;
89	}
90	}
91	return $old ? $old->($package, $ref, @attrs) : @attrs;
92	};
93	}
94
95	}
96
97	=over 4
98
99	=item $main
100
101	This coroutine represents the main program.
102
103	=cut
104
105	$main = new Coro;
106
107	=item $current (or as function: current)
108
109	The current coroutine (the last coroutine switched to). The initial value
110	is C<$main> (of course).
111
112	This variable is B<strictly> I<read-only>. It is provided for performance
113	reasons. If performance is not essentiel you are encouraged to use the
114	C<Coro::current> function instead.
115
116	=cut
117
118	# maybe some other module used Coro::Specific before...
119	$main->{specific} = $current->{specific}
120	if $current;
121
122	_set_current $main;
123
124	sub current() { $current }
125
126	=item $idle
127
128	A callback that is called whenever the scheduler finds no ready coroutines
129	to run. The default implementation prints "FATAL: deadlock detected" and
130	exits, because the program has no other way to continue.
131
132	This hook is overwritten by modules such as C<Coro::Timer> and
133	C<Coro::Event> to wait on an external event that hopefully wake up a
134	coroutine so the scheduler can run it.
135
136	Please note that if your callback recursively invokes perl (e.g. for event
137	handlers), then it must be prepared to be called recursively.
138
139	=cut
140
141	$idle = sub {
142	require Carp;
143	Carp::croak ("FATAL: deadlock detected");
144	};
145
146	sub _cancel {
147	my ($self) = @_;
148
149	# free coroutine data and mark as destructed
150	$self->_destroy
151	or return;
152
153	# call all destruction callbacks
154	$_->(@{$self->{status}})
155	for @{(delete $self->{destroy_cb}) \|\| []};
156	}
157
158	# this coroutine is necessary because a coroutine
159	# cannot destroy itself.
160	my @destroy;
161	my $manager;
162
163	$manager = new Coro sub {
164	while () {
165	(shift @destroy)->_cancel
166	while @destroy;
167
168	&schedule;
169	}
170	};
171
172	$manager->prio (PRIO_MAX);
173
174	# static methods. not really.
175
176	=back
177
178	=head2 STATIC METHODS
179
180	Static methods are actually functions that operate on the current coroutine only.
181
182	=over 4
183
184	=item async { ... } [@args...]
185
186	Create a new asynchronous coroutine and return it's coroutine object
187	(usually unused). When the sub returns the new coroutine is automatically
188	terminated.
189
190	Calling C<exit> in a coroutine will not work correctly, so do not do that.
191
192	When the coroutine dies, the program will exit, just as in the main
193	program.
194
195	# create a new coroutine that just prints its arguments
196	async {
197	print "@_\n";
198	} 1,2,3,4;
199
200	=cut
201
202	sub async(&@) {
203	my $pid = new Coro @_;
204	$pid->ready;
205	$pid
206	}
207
208	=item schedule
209
210	Calls the scheduler. Please note that the current coroutine will not be put
211	into the ready queue, so calling this function usually means you will
212	never be called again unless something else (e.g. an event handler) calls
213	ready.
214
215	The canonical way to wait on external events is this:
216
217	{
218	# remember current coroutine
219	my $current = $Coro::current;
220
221	# register a hypothetical event handler
222	on_event_invoke sub {
223	# wake up sleeping coroutine
224	$current->ready;
225	undef $current;
226	};
227
228	# call schedule until event occured.
229	# in case we are woken up for other reasons
230	# (current still defined), loop.
231	Coro::schedule while $current;
232	}
233
234	=item cede
235
236	"Cede" to other coroutines. This function puts the current coroutine into the
237	ready queue and calls C<schedule>, which has the effect of giving up the
238	current "timeslice" to other coroutines of the same or higher priority.
239
240	=item Coro::cede_notself
241
242	Works like cede, but is not exported by default and will cede to any
243	coroutine, regardless of priority, once.
244
245	=item terminate [arg...]
246
247	Terminates the current coroutine with the given status values (see L<cancel>).
248
249	=cut
250
251	sub terminate {
252	$current->cancel (@_);
253	}
254
255	=back
256
257	# dynamic methods
258
259	=head2 COROUTINE METHODS
260
261	These are the methods you can call on coroutine objects.
262
263	=over 4
264
265	=item new Coro \&sub [, @args...]
266
267	Create a new coroutine and return it. When the sub returns the coroutine
268	automatically terminates as if C<terminate> with the returned values were
269	called. To make the coroutine run you must first put it into the ready queue
270	by calling the ready method.
271
272	Calling C<exit> in a coroutine will not work correctly, so do not do that.
273
274	=cut
275
276	sub _run_coro {
277	terminate &{+shift};
278	}
279
280	sub new {
281	my $class = shift;
282
283	$class->SUPER::new (\&_run_coro, @_)
284	}
285
286	=item $success = $coroutine->ready
287
288	Put the given coroutine into the ready queue (according to it's priority)
289	and return true. If the coroutine is already in the ready queue, do nothing
290	and return false.
291
292	=item $is_ready = $coroutine->is_ready
293
294	Return wether the coroutine is currently the ready queue or not,
295
296	=item $coroutine->cancel (arg...)
297
298	Terminates the given coroutine and makes it return the given arguments as
299	status (default: the empty list). Never returns if the coroutine is the
300	current coroutine.
301
302	=cut
303
304	sub cancel {
305	my $self = shift;
306	$self->{status} = [@_];
307
308	if ($current == $self) {
309	push @destroy, $self;
310	$manager->ready;
311	&schedule while 1;
312	} else {
313	$self->_cancel;
314	}
315	}
316
317	=item $coroutine->join
318
319	Wait until the coroutine terminates and return any values given to the
320	C<terminate> or C<cancel> functions. C<join> can be called multiple times
321	from multiple coroutine.
322
323	=cut
324
325	sub join {
326	my $self = shift;
327
328	unless ($self->{status}) {
329	my $current = $current;
330
331	push @{$self->{destroy_cb}}, sub {
332	$current->ready;
333	undef $current;
334	};
335
336	&schedule while $current;
337	}
338
339	wantarray ? @{$self->{status}} : $self->{status}[0];
340	}
341
342	=item $coroutine->on_destroy (\&cb)
343
344	Registers a callback that is called when this coroutine gets destroyed,
345	but before it is joined. The callback gets passed the terminate arguments,
346	if any.
347
348	=cut
349
350	sub on_destroy {
351	my ($self, $cb) = @_;
352
353	push @{ $self->{destroy_cb} }, $cb;
354	}
355
356	=item $oldprio = $coroutine->prio ($newprio)
357
358	Sets (or gets, if the argument is missing) the priority of the
359	coroutine. Higher priority coroutines get run before lower priority
360	coroutines. Priorities are small signed integers (currently -4 .. +3),
361	that you can refer to using PRIO_xxx constants (use the import tag :prio
362	to get then):
363
364	PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
365	3 > 1 > 0 > -1 > -3 > -4
366
367	# set priority to HIGH
368	current->prio(PRIO_HIGH);
369
370	The idle coroutine ($Coro::idle) always has a lower priority than any
371	existing coroutine.
372
373	Changing the priority of the current coroutine will take effect immediately,
374	but changing the priority of coroutines in the ready queue (but not
375	running) will only take effect after the next schedule (of that
376	coroutine). This is a bug that will be fixed in some future version.
377
378	=item $newprio = $coroutine->nice ($change)
379
380	Similar to C<prio>, but subtract the given value from the priority (i.e.
381	higher values mean lower priority, just as in unix).
382
383	=item $olddesc = $coroutine->desc ($newdesc)
384
385	Sets (or gets in case the argument is missing) the description for this
386	coroutine. This is just a free-form string you can associate with a coroutine.
387
388	=cut
389
390	sub desc {
391	my $old = $_[0]{desc};
392	$_[0]{desc} = $_[1] if @_ > 1;
393	$old;
394	}
395
396	=back
397
398	=head2 GLOBAL FUNCTIONS
399
400	=over 4
401
402	=item Coro::nready
403
404	Returns the number of coroutines that are currently in the ready state,
405	i.e. that can be swicthed to. The value C<0> means that the only runnable
406	coroutine is the currently running one, so C<cede> would have no effect,
407	and C<schedule> would cause a deadlock unless there is an idle handler
408	that wakes up some coroutines.
409
410	=item my $guard = Coro::guard { ... }
411
412	This creates and returns a guard object. Nothing happens until the objetc
413	gets destroyed, in which case the codeblock given as argument will be
414	executed. This is useful to free locks or other resources in case of a
415	runtime error or when the coroutine gets canceled, as in both cases the
416	guard block will be executed. The guard object supports only one method,
417	C<< ->cancel >>, which will keep the codeblock from being executed.
418
419	Example: set some flag and clear it again when the coroutine gets canceled
420	or the function returns:
421
422	sub do_something {
423	my $guard = Coro::guard { $busy = 0 };
424	$busy = 1;
425
426	# do something that requires $busy to be true
427	}
428
429	=cut
430
431	sub guard(&) {
432	bless \(my $cb = $_[0]), "Coro::guard"
433	}
434
435	sub Coro::guard::cancel {
436	${$_[0]} = sub { };
437	}
438
439	sub Coro::guard::DESTROY {
440	${$_[0]}->();
441	}
442
443
444	=item unblock_sub { ... }
445
446	This utility function takes a BLOCK or code reference and "unblocks" it,
447	returning the new coderef. This means that the new coderef will return
448	immediately without blocking, returning nothing, while the original code
449	ref will be called (with parameters) from within its own coroutine.
450
451	The reason this fucntion exists is that many event libraries (such as the
452	venerable L<Event\|Event> module) are not coroutine-safe (a weaker form
453	of thread-safety). This means you must not block within event callbacks,
454	otherwise you might suffer from crashes or worse.
455
456	This function allows your callbacks to block by executing them in another
457	coroutine where it is safe to block. One example where blocking is handy
458	is when you use the L<Coro::AIO\|Coro::AIO> functions to save results to
459	disk.
460
461	In short: simply use C<unblock_sub { ... }> instead of C<sub { ... }> when
462	creating event callbacks that want to block.
463
464	=cut
465
466	our @unblock_pool;
467	our @unblock_queue;
468	our $UNBLOCK_POOL_SIZE = 2;
469
470	sub unblock_handler_ {
471	while () {
472	my ($cb, @arg) = @{ delete $Coro::current->{arg} };
473	$cb->(@arg);
474
475	last if @unblock_pool >= $UNBLOCK_POOL_SIZE;
476	push @unblock_pool, $Coro::current;
477	schedule;
478	}
479	}
480
481	our $unblock_scheduler = async {
482	while () {
483	while (my $cb = pop @unblock_queue) {
484	my $handler = (pop @unblock_pool or new Coro \&unblock_handler_);
485	$handler->{arg} = $cb;
486	$handler->ready;
487	cede;
488	}
489
490	schedule;
491	}
492	};
493
494	sub unblock_sub(&) {
495	my $cb = shift;
496
497	sub {
498	push @unblock_queue, [$cb, @_];
499	$unblock_scheduler->ready;
500	}
501	}
502
503	=back
504
505	=cut
506
507	1;
508
509	=head1 BUGS/LIMITATIONS
510
511	- you must make very sure that no coro is still active on global
512	destruction. very bad things might happen otherwise (usually segfaults).
513
514	- this module is not thread-safe. You should only ever use this module
515	from the same thread (this requirement might be losened in the future
516	to allow per-thread schedulers, but Coro::State does not yet allow
517	this).
518
519	=head1 SEE ALSO
520
521	Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.
522
523	Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.
524
525	Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.
526
527	Embedding: L<Coro:MakeMaker>
528
529	=head1 AUTHOR
530
531	Marc Lehmann <schmorp@schmorp.de>
532	http://home.schmorp.de/
533
534	=cut
535