Coro/Coro.pm

=head1 NAME

Coro - coroutine process abstraction

=head1 SYNOPSIS

 use Coro;

 async {
    # some asynchronous thread of execution
 };

 # alternatively create an async coroutine like this:

 sub some_func : Coro {
    # some more async code
 }

 cede;

=head1 DESCRIPTION

This module collection manages coroutines. Coroutines are similar to
threads but don't run in parallel.

In this module, coroutines are defined as "callchain + lexical variables
+ @_ + $_ + $@ + $^W + C stack), that is, a coroutine has it's own
callchain, it's own set of lexicals and it's own set of perl's most
important global variables.

=cut

package Coro;

use strict;
no warnings "uninitialized";

use Coro::State;

use base qw(Coro::State Exporter);

our $idle;    # idle handler
our $main;    # main coroutine
our $current; # current coroutine

our $VERSION = '3.01';

our @EXPORT = qw(async cede schedule terminate current unblock_sub);
our %EXPORT_TAGS = (
      prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
);
our @EXPORT_OK = (@{$EXPORT_TAGS{prio}}, qw(nready));

{
   my @async;
   my $init;

   # this way of handling attributes simply is NOT scalable ;()
   sub import {
      no strict 'refs';

      Coro->export_to_level (1, @_);

      my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
      *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
         my ($package, $ref) = (shift, shift);
         my @attrs;
         for (@_) {
            if ($_ eq "Coro") {
               push @async, $ref;
               unless ($init++) {
                  eval q{
                     sub INIT {
                        &async(pop @async) while @async;
                     }
                  };
               }
            } else {
               push @attrs, $_;
            }
         }
         return $old ? $old->($package, $ref, @attrs) : @attrs;
      };
   }

}

=over 4

=item $main

This coroutine represents the main program.

=cut

$main = new Coro;

=item $current (or as function: current)

The current coroutine (the last coroutine switched to). The initial value
is C<$main> (of course).

This variable is B<strictly> I<read-only>. It is provided for performance
reasons. If performance is not essentiel you are encouraged to use the
C<Coro::current> function instead.

=cut

# maybe some other module used Coro::Specific before...
$main->{specific} = $current->{specific}
   if $current;

_set_current $main;

sub current() { $current }

=item $idle

A callback that is called whenever the scheduler finds no ready coroutines
to run. The default implementation prints "FATAL: deadlock detected" and
exits, because the program has no other way to continue.

This hook is overwritten by modules such as C<Coro::Timer> and
C<Coro::Event> to wait on an external event that hopefully wake up a
coroutine so the scheduler can run it.

Please note that if your callback recursively invokes perl (e.g. for event
handlers), then it must be prepared to be called recursively.

=cut

$idle = sub {
   require Carp;
   Carp::croak ("FATAL: deadlock detected");
};

# this coroutine is necessary because a coroutine
# cannot destroy itself.
my @destroy;
my $manager; $manager = new Coro sub {
   while () {
      # by overwriting the state object with the manager we destroy it
      # while still being able to schedule this coroutine (in case it has
      # been readied multiple times. this is harmless since the manager
      # can be called as many times as neccessary and will always
      # remove itself from the runqueue
      while (@destroy) {
         my $coro = pop @destroy;
         $coro->{status} ||= [];
         $_->ready for @{delete $coro->{join} || []};

         # the next line destroys the coro state, but keeps the
         # coroutine itself intact (we basically make it a zombie
         # coroutine that always runs the manager thread, so it's possible
         # to transfer() to this coroutine).
         $coro->_clone_state_from ($manager);
      }
      &schedule;
   }
};

# static methods. not really.

=back

=head2 STATIC METHODS

Static methods are actually functions that operate on the current coroutine only.

=over 4

=item async { ... } [@args...]

Create a new asynchronous coroutine and return it's coroutine object
(usually unused). When the sub returns the new coroutine is automatically
terminated.

Calling C<exit> in a coroutine will not work correctly, so do not do that.

When the coroutine dies, the program will exit, just as in the main
program.

   # create a new coroutine that just prints its arguments
   async {
      print "@_\n";
   } 1,2,3,4;

=cut

sub async(&@) {
   my $pid = new Coro @_;
   $pid->ready;
   $pid
}

=item schedule

Calls the scheduler. Please note that the current coroutine will not be put
into the ready queue, so calling this function usually means you will
never be called again unless something else (e.g. an event handler) calls
ready.

The canonical way to wait on external events is this:

   {
      # remember current coroutine
      my $current = $Coro::current;

      # register a hypothetical event handler
      on_event_invoke sub {
         # wake up sleeping coroutine
         $current->ready;
         undef $current;
      };

      # call schedule until event occured.
      # in case we are woken up for other reasons
      # (current still defined), loop.
      Coro::schedule while $current;
   }

=item cede

"Cede" to other coroutines. This function puts the current coroutine into the
ready queue and calls C<schedule>, which has the effect of giving up the
current "timeslice" to other coroutines of the same or higher priority.

=item terminate [arg...]

Terminates the current coroutine with the given status values (see L<cancel>).

=cut

sub terminate {
   $current->cancel (@_);
}

=back

# dynamic methods

=head2 COROUTINE METHODS

These are the methods you can call on coroutine objects.

=over 4

=item new Coro \&sub [, @args...]

Create a new coroutine and return it. When the sub returns the coroutine
automatically terminates as if C<terminate> with the returned values were
called. To make the coroutine run you must first put it into the ready queue
by calling the ready method.

Calling C<exit> in a coroutine will not work correctly, so do not do that.

=cut

sub _run_coro {
   terminate &{+shift};
}

sub new {
   my $class = shift;

   $class->SUPER::new (\&_run_coro, @_)
}

=item $success = $coroutine->ready

Put the given coroutine into the ready queue (according to it's priority)
and return true. If the coroutine is already in the ready queue, do nothing
and return false.

=item $is_ready = $coroutine->is_ready

Return wether the coroutine is currently the ready queue or not,

=item $coroutine->cancel (arg...)

Terminates the given coroutine and makes it return the given arguments as
status (default: the empty list).

=cut

sub cancel {
   my $self = shift;
   $self->{status} = [@_];
   push @destroy, $self;
   $manager->ready;
   &schedule if $current == $self;
}

=item $coroutine->join

Wait until the coroutine terminates and return any values given to the
C<terminate> or C<cancel> functions. C<join> can be called multiple times
from multiple coroutine.

=cut

sub join {
   my $self = shift;
   unless ($self->{status}) {
      push @{$self->{join}}, $current;
      &schedule;
   }
   wantarray ? @{$self->{status}} : $self->{status}[0];
}

=item $oldprio = $coroutine->prio ($newprio)

Sets (or gets, if the argument is missing) the priority of the
coroutine. Higher priority coroutines get run before lower priority
coroutines. Priorities are small signed integers (currently -4 .. +3),
that you can refer to using PRIO_xxx constants (use the import tag :prio
to get then):

   PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
       3    >     1     >      0      >    -1    >    -3     >    -4

   # set priority to HIGH
   current->prio(PRIO_HIGH);

The idle coroutine ($Coro::idle) always has a lower priority than any
existing coroutine.

Changing the priority of the current coroutine will take effect immediately,
but changing the priority of coroutines in the ready queue (but not
running) will only take effect after the next schedule (of that
coroutine). This is a bug that will be fixed in some future version.

=item $newprio = $coroutine->nice ($change)

Similar to C<prio>, but subtract the given value from the priority (i.e.
higher values mean lower priority, just as in unix).

=item $olddesc = $coroutine->desc ($newdesc)

Sets (or gets in case the argument is missing) the description for this
coroutine. This is just a free-form string you can associate with a coroutine.

=cut

sub desc {
   my $old = $_[0]{desc};
   $_[0]{desc} = $_[1] if @_ > 1;
   $old;
}

=back

=head2 GLOBAL FUNCTIONS

=over 4

=item Coro::nready

Returns the number of coroutines that are currently in the ready state,
i.e. that can be swicthed to. The value C<0> means that the only runnable
coroutine is the currently running one, so C<cede> would have no effect,
and C<schedule> would cause a deadlock unless there is an idle handler
that wakes up some coroutines.

=item unblock_sub { ... }

This utility function takes a BLOCK or code reference and "unblocks" it,
returning the new coderef. This means that the new coderef will return
immediately without blocking, returning nothing, while the original code
ref will be called (with parameters) from within its own coroutine.

The reason this fucntion exists is that many event libraries (such as the
venerable L<Event|Event> module) are not coroutine-safe (a weaker form
of thread-safety). This means you must not block within event callbacks,
otherwise you might suffer from crashes or worse.

This function allows your callbacks to block by executing them in another
coroutine where it is safe to block. One example where blocking is handy
is when you use the L<Coro::AIO|Coro::AIO> functions to save results to
disk.

In short: simply use C<unblock_sub { ... }> instead of C<sub { ... }> when
creating event callbacks that want to block.

=cut

our @unblock_pool;
our @unblock_queue;
our $UNBLOCK_POOL_SIZE = 2;

sub unblock_handler_ {
   while () {
      my ($cb, @arg) = @{ delete $Coro::current->{arg} };
      $cb->(@arg);

      last if @unblock_pool >= $UNBLOCK_POOL_SIZE;
      push @unblock_pool, $Coro::current;
      schedule;
   }        
}           

our $unblock_scheduler = async {
   while () {
      while (my $cb = pop @unblock_queue) {
         my $handler = (pop @unblock_pool or new Coro \&unblock_handler_);
         $handler->{arg} = $cb;
         $handler->ready;
         cede;
      }

      schedule;
   }
};

sub unblock_sub(&) {
   my $cb = shift;

   sub {
      push @unblock_queue, [$cb, @_];
      $unblock_scheduler->ready;
   }
}

=back

=cut

1;

=head1 BUGS/LIMITATIONS

 - you must make very sure that no coro is still active on global
   destruction. very bad things might happen otherwise (usually segfaults).

 - this module is not thread-safe. You should only ever use this module
   from the same thread (this requirement might be losened in the future
   to allow per-thread schedulers, but Coro::State does not yet allow
   this).

=head1 SEE ALSO

Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.

Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.

Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.

Embedding: L<Coro:MakeMaker>

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

Revision:	1.97
Committed:	Mon Dec 4 13:47:56 2006 UTC (17 years, 6 months ago) by root
Branch:	MAIN
Changes since 1.96:	+10 -2 lines
Log Message:	* empty log message *
#	Content
1	=head1 NAME
2
3	Coro - coroutine process abstraction
4
5	=head1 SYNOPSIS
6
7	use Coro;
8
9	async {
10	# some asynchronous thread of execution
11	};
12
13	# alternatively create an async coroutine like this:
14
15	sub some_func : Coro {
16	# some more async code
17	}
18
19	cede;
20
21	=head1 DESCRIPTION
22
23	This module collection manages coroutines. Coroutines are similar to
24	threads but don't run in parallel.
25
26	In this module, coroutines are defined as "callchain + lexical variables
27	+ @_ + $_ + $@ + $^W + C stack), that is, a coroutine has it's own
28	callchain, it's own set of lexicals and it's own set of perl's most
29	important global variables.
30
31	=cut
32
33	package Coro;
34
35	use strict;
36	no warnings "uninitialized";
37
38	use Coro::State;
39
40	use base qw(Coro::State Exporter);
41
42	our $idle; # idle handler
43	our $main; # main coroutine
44	our $current; # current coroutine
45
46	our $VERSION = '3.01';
47
48	our @EXPORT = qw(async cede schedule terminate current unblock_sub);
49	our %EXPORT_TAGS = (
50	prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)],
51	);
52	our @EXPORT_OK = (@{$EXPORT_TAGS{prio}}, qw(nready));
53
54	{
55	my @async;
56	my $init;
57
58	# this way of handling attributes simply is NOT scalable ;()
59	sub import {
60	no strict 'refs';
61
62	Coro->export_to_level (1, @_);
63
64	my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE};
65	*{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub {
66	my ($package, $ref) = (shift, shift);
67	my @attrs;
68	for (@_) {
69	if ($_ eq "Coro") {
70	push @async, $ref;
71	unless ($init++) {
72	eval q{
73	sub INIT {
74	&async(pop @async) while @async;
75	}
76	};
77	}
78	} else {
79	push @attrs, $_;
80	}
81	}
82	return $old ? $old->($package, $ref, @attrs) : @attrs;
83	};
84	}
85
86	}
87
88	=over 4
89
90	=item $main
91
92	This coroutine represents the main program.
93
94	=cut
95
96	$main = new Coro;
97
98	=item $current (or as function: current)
99
100	The current coroutine (the last coroutine switched to). The initial value
101	is C<$main> (of course).
102
103	This variable is B<strictly> I<read-only>. It is provided for performance
104	reasons. If performance is not essentiel you are encouraged to use the
105	C<Coro::current> function instead.
106
107	=cut
108
109	# maybe some other module used Coro::Specific before...
110	$main->{specific} = $current->{specific}
111	if $current;
112
113	_set_current $main;
114
115	sub current() { $current }
116
117	=item $idle
118
119	A callback that is called whenever the scheduler finds no ready coroutines
120	to run. The default implementation prints "FATAL: deadlock detected" and
121	exits, because the program has no other way to continue.
122
123	This hook is overwritten by modules such as C<Coro::Timer> and
124	C<Coro::Event> to wait on an external event that hopefully wake up a
125	coroutine so the scheduler can run it.
126
127	Please note that if your callback recursively invokes perl (e.g. for event
128	handlers), then it must be prepared to be called recursively.
129
130	=cut
131
132	$idle = sub {
133	require Carp;
134	Carp::croak ("FATAL: deadlock detected");
135	};
136
137	# this coroutine is necessary because a coroutine
138	# cannot destroy itself.
139	my @destroy;
140	my $manager; $manager = new Coro sub {
141	while () {
142	# by overwriting the state object with the manager we destroy it
143	# while still being able to schedule this coroutine (in case it has
144	# been readied multiple times. this is harmless since the manager
145	# can be called as many times as neccessary and will always
146	# remove itself from the runqueue
147	while (@destroy) {
148	my $coro = pop @destroy;
149	$coro->{status} \|\|= [];
150	$_->ready for @{delete $coro->{join} \|\| []};
151
152	# the next line destroys the coro state, but keeps the
153	# coroutine itself intact (we basically make it a zombie
154	# coroutine that always runs the manager thread, so it's possible
155	# to transfer() to this coroutine).
156	$coro->_clone_state_from ($manager);
157	}
158	&schedule;
159	}
160	};
161
162	# static methods. not really.
163
164	=back
165
166	=head2 STATIC METHODS
167
168	Static methods are actually functions that operate on the current coroutine only.
169
170	=over 4
171
172	=item async { ... } [@args...]
173
174	Create a new asynchronous coroutine and return it's coroutine object
175	(usually unused). When the sub returns the new coroutine is automatically
176	terminated.
177
178	Calling C<exit> in a coroutine will not work correctly, so do not do that.
179
180	When the coroutine dies, the program will exit, just as in the main
181	program.
182
183	# create a new coroutine that just prints its arguments
184	async {
185	print "@_\n";
186	} 1,2,3,4;
187
188	=cut
189
190	sub async(&@) {
191	my $pid = new Coro @_;
192	$pid->ready;
193	$pid
194	}
195
196	=item schedule
197
198	Calls the scheduler. Please note that the current coroutine will not be put
199	into the ready queue, so calling this function usually means you will
200	never be called again unless something else (e.g. an event handler) calls
201	ready.
202
203	The canonical way to wait on external events is this:
204
205	{
206	# remember current coroutine
207	my $current = $Coro::current;
208
209	# register a hypothetical event handler
210	on_event_invoke sub {
211	# wake up sleeping coroutine
212	$current->ready;
213	undef $current;
214	};
215
216	# call schedule until event occured.
217	# in case we are woken up for other reasons
218	# (current still defined), loop.
219	Coro::schedule while $current;
220	}
221
222	=item cede
223
224	"Cede" to other coroutines. This function puts the current coroutine into the
225	ready queue and calls C<schedule>, which has the effect of giving up the
226	current "timeslice" to other coroutines of the same or higher priority.
227
228	=item terminate [arg...]
229
230	Terminates the current coroutine with the given status values (see L<cancel>).
231
232	=cut
233
234	sub terminate {
235	$current->cancel (@_);
236	}
237
238	=back
239
240	# dynamic methods
241
242	=head2 COROUTINE METHODS
243
244	These are the methods you can call on coroutine objects.
245
246	=over 4
247
248	=item new Coro \&sub [, @args...]
249
250	Create a new coroutine and return it. When the sub returns the coroutine
251	automatically terminates as if C<terminate> with the returned values were
252	called. To make the coroutine run you must first put it into the ready queue
253	by calling the ready method.
254
255	Calling C<exit> in a coroutine will not work correctly, so do not do that.
256
257	=cut
258
259	sub _run_coro {
260	terminate &{+shift};
261	}
262
263	sub new {
264	my $class = shift;
265
266	$class->SUPER::new (\&_run_coro, @_)
267	}
268
269	=item $success = $coroutine->ready
270
271	Put the given coroutine into the ready queue (according to it's priority)
272	and return true. If the coroutine is already in the ready queue, do nothing
273	and return false.
274
275	=item $is_ready = $coroutine->is_ready
276
277	Return wether the coroutine is currently the ready queue or not,
278
279	=item $coroutine->cancel (arg...)
280
281	Terminates the given coroutine and makes it return the given arguments as
282	status (default: the empty list).
283
284	=cut
285
286	sub cancel {
287	my $self = shift;
288	$self->{status} = [@_];
289	push @destroy, $self;
290	$manager->ready;
291	&schedule if $current == $self;
292	}
293
294	=item $coroutine->join
295
296	Wait until the coroutine terminates and return any values given to the
297	C<terminate> or C<cancel> functions. C<join> can be called multiple times
298	from multiple coroutine.
299
300	=cut
301
302	sub join {
303	my $self = shift;
304	unless ($self->{status}) {
305	push @{$self->{join}}, $current;
306	&schedule;
307	}
308	wantarray ? @{$self->{status}} : $self->{status}[0];
309	}
310
311	=item $oldprio = $coroutine->prio ($newprio)
312
313	Sets (or gets, if the argument is missing) the priority of the
314	coroutine. Higher priority coroutines get run before lower priority
315	coroutines. Priorities are small signed integers (currently -4 .. +3),
316	that you can refer to using PRIO_xxx constants (use the import tag :prio
317	to get then):
318
319	PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN
320	3 > 1 > 0 > -1 > -3 > -4
321
322	# set priority to HIGH
323	current->prio(PRIO_HIGH);
324
325	The idle coroutine ($Coro::idle) always has a lower priority than any
326	existing coroutine.
327
328	Changing the priority of the current coroutine will take effect immediately,
329	but changing the priority of coroutines in the ready queue (but not
330	running) will only take effect after the next schedule (of that
331	coroutine). This is a bug that will be fixed in some future version.
332
333	=item $newprio = $coroutine->nice ($change)
334
335	Similar to C<prio>, but subtract the given value from the priority (i.e.
336	higher values mean lower priority, just as in unix).
337
338	=item $olddesc = $coroutine->desc ($newdesc)
339
340	Sets (or gets in case the argument is missing) the description for this
341	coroutine. This is just a free-form string you can associate with a coroutine.
342
343	=cut
344
345	sub desc {
346	my $old = $_[0]{desc};
347	$_[0]{desc} = $_[1] if @_ > 1;
348	$old;
349	}
350
351	=back
352
353	=head2 GLOBAL FUNCTIONS
354
355	=over 4
356
357	=item Coro::nready
358
359	Returns the number of coroutines that are currently in the ready state,
360	i.e. that can be swicthed to. The value C<0> means that the only runnable
361	coroutine is the currently running one, so C<cede> would have no effect,
362	and C<schedule> would cause a deadlock unless there is an idle handler
363	that wakes up some coroutines.
364
365	=item unblock_sub { ... }
366
367	This utility function takes a BLOCK or code reference and "unblocks" it,
368	returning the new coderef. This means that the new coderef will return
369	immediately without blocking, returning nothing, while the original code
370	ref will be called (with parameters) from within its own coroutine.
371
372	The reason this fucntion exists is that many event libraries (such as the
373	venerable L<Event\|Event> module) are not coroutine-safe (a weaker form
374	of thread-safety). This means you must not block within event callbacks,
375	otherwise you might suffer from crashes or worse.
376
377	This function allows your callbacks to block by executing them in another
378	coroutine where it is safe to block. One example where blocking is handy
379	is when you use the L<Coro::AIO\|Coro::AIO> functions to save results to
380	disk.
381
382	In short: simply use C<unblock_sub { ... }> instead of C<sub { ... }> when
383	creating event callbacks that want to block.
384
385	=cut
386
387	our @unblock_pool;
388	our @unblock_queue;
389	our $UNBLOCK_POOL_SIZE = 2;
390
391	sub unblock_handler_ {
392	while () {
393	my ($cb, @arg) = @{ delete $Coro::current->{arg} };
394	$cb->(@arg);
395
396	last if @unblock_pool >= $UNBLOCK_POOL_SIZE;
397	push @unblock_pool, $Coro::current;
398	schedule;
399	}
400	}
401
402	our $unblock_scheduler = async {
403	while () {
404	while (my $cb = pop @unblock_queue) {
405	my $handler = (pop @unblock_pool or new Coro \&unblock_handler_);
406	$handler->{arg} = $cb;
407	$handler->ready;
408	cede;
409	}
410
411	schedule;
412	}
413	};
414
415	sub unblock_sub(&) {
416	my $cb = shift;
417
418	sub {
419	push @unblock_queue, [$cb, @_];
420	$unblock_scheduler->ready;
421	}
422	}
423
424	=back
425
426	=cut
427
428	1;
429
430	=head1 BUGS/LIMITATIONS
431
432	- you must make very sure that no coro is still active on global
433	destruction. very bad things might happen otherwise (usually segfaults).
434
435	- this module is not thread-safe. You should only ever use this module
436	from the same thread (this requirement might be losened in the future
437	to allow per-thread schedulers, but Coro::State does not yet allow
438	this).
439
440	=head1 SEE ALSO
441
442	Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>.
443
444	Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>.
445
446	Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>.
447
448	Embedding: L<Coro:MakeMaker>
449
450	=head1 AUTHOR
451
452	Marc Lehmann <schmorp@schmorp.de>
453	http://home.schmorp.de/
454
455	=cut
456