Coro/Coro/Semaphore.pm

=head1 NAME

Coro::Semaphore - non-binary semaphores

=head1 SYNOPSIS

 use Coro::Semaphore;

 $sig = new Coro::Semaphore [initial value];

 $sig->down; # wait for signal

 # ... some other "thread"

 $sig->up;

=head1 DESCRIPTION

This module implements counting semaphores. You can initialize a mutex
with any level of parallel users, that is, you can intialize a sempahore
that can be C<down>ed more than once until it blocks. There is no owner
associated with semaphores, so one coroutine can C<down> it while another
can C<up> it.

Counting semaphores are typically used to coordinate access to
resources, with the semaphore count initialized to the number of free
resources. Coroutines then increment the count when resources are added
and decrement the count when resources are removed.

=over 4

=cut

package Coro::Semaphore;

use Coro ();

$VERSION = 0.45;

=item new [inital count]

Creates a new sempahore object with the given initial lock count. The
default lock count is 1, which means it is unlocked by default. Zero (or
negative values) are also allowed, in which case the semaphore is locked
by default.

=cut

sub new {
   bless [defined $_[1] ? $_[1] : 1], $_[0];
}

=item $sem->down

Decrement the counter, therefore "locking" the semaphore. This method
waits until the semaphore is available if the counter is zero.

=cut

sub down {
   my $self = shift;
   while ($self->[0] <= 0) {
      push @{$self->[1]}, $Coro::current;
      Coro::schedule;
   }
   --$self->[0];
}

=item $sem->up

Unlock the semaphore again.

=cut

sub up {
   my $self = shift;
   if (++$self->[0] > 0) {
      (shift @{$self->[1]})->ready if @{$self->[1]};
   }
}

=item $sem->try

Try to C<down> the semaphore. Returns true when this was possible,
otherwise return false and leave the semaphore unchanged.

=cut

sub try {
   my $self = shift;
   if ($self->[0] > 0) {
      --$self->[0];
      return 1;
   } else {
      return 0;
   }
}

=item $sem->waiters

In scalar context, returns the number of coroutines waiting for this
semaphore.

=cut

sub waiters {
   @{$_[0][1]};
}

=item $guard = $sem->guard

This method calls C<down> and then creates a guard object. When the guard
object is destroyed it automatically calls C<up>.

=cut

sub guard {
   &down;
   # double indirection because bless works on the referenced
   # object, not (only) on the reference itself.
   bless \\$_[0], Coro::Semaphore::Guard::;
}

sub Coro::Semaphore::Guard::DESTROY {
   &up(${${$_[0]}});
}

1;

=back

=head1 AUTHOR

 Marc Lehmann <pcg@goof.com>
 http://www.goof.com/pcg/marc/

=cut

Revision:	1.16
Committed:	Thu Aug 30 02:58:17 2001 UTC (22 years, 9 months ago) by root
Branch:	MAIN
Changes since 1.15:	+4 -4 lines
Log Message:	* empty log message *
#	Content
1	=head1 NAME
2
3	Coro::Semaphore - non-binary semaphores
4
5	=head1 SYNOPSIS
6
7	use Coro::Semaphore;
8
9	$sig = new Coro::Semaphore [initial value];
10
11	$sig->down; # wait for signal
12
13	# ... some other "thread"
14
15	$sig->up;
16
17	=head1 DESCRIPTION
18
19	This module implements counting semaphores. You can initialize a mutex
20	with any level of parallel users, that is, you can intialize a sempahore
21	that can be C<down>ed more than once until it blocks. There is no owner
22	associated with semaphores, so one coroutine can C<down> it while another
23	can C<up> it.
24
25	Counting semaphores are typically used to coordinate access to
26	resources, with the semaphore count initialized to the number of free
27	resources. Coroutines then increment the count when resources are added
28	and decrement the count when resources are removed.
29
30	=over 4
31
32	=cut
33
34	package Coro::Semaphore;
35
36	use Coro ();
37
38	$VERSION = 0.45;
39
40	=item new [inital count]
41
42	Creates a new sempahore object with the given initial lock count. The
43	default lock count is 1, which means it is unlocked by default. Zero (or
44	negative values) are also allowed, in which case the semaphore is locked
45	by default.
46
47	=cut
48
49	sub new {
50	bless [defined $_[1] ? $_[1] : 1], $_[0];
51	}
52
53	=item $sem->down
54
55	Decrement the counter, therefore "locking" the semaphore. This method
56	waits until the semaphore is available if the counter is zero.
57
58	=cut
59
60	sub down {
61	my $self = shift;
62	while ($self->[0] <= 0) {
63	push @{$self->[1]}, $Coro::current;
64	Coro::schedule;
65	}
66	--$self->[0];
67	}
68
69	=item $sem->up
70
71	Unlock the semaphore again.
72
73	=cut
74
75	sub up {
76	my $self = shift;
77	if (++$self->[0] > 0) {
78	(shift @{$self->[1]})->ready if @{$self->[1]};
79	}
80	}
81
82	=item $sem->try
83
84	Try to C<down> the semaphore. Returns true when this was possible,
85	otherwise return false and leave the semaphore unchanged.
86
87	=cut
88
89	sub try {
90	my $self = shift;
91	if ($self->[0] > 0) {
92	--$self->[0];
93	return 1;
94	} else {
95	return 0;
96	}
97	}
98
99	=item $sem->waiters
100
101	In scalar context, returns the number of coroutines waiting for this
102	semaphore.
103
104	=cut
105
106	sub waiters {
107	@{$_[0][1]};
108	}
109
110	=item $guard = $sem->guard
111
112	This method calls C<down> and then creates a guard object. When the guard
113	object is destroyed it automatically calls C<up>.
114
115	=cut
116
117	sub guard {
118	&down;
119	# double indirection because bless works on the referenced
120	# object, not (only) on the reference itself.
121	bless \\$_[0], Coro::Semaphore::Guard::;
122	}
123
124	sub Coro::Semaphore::Guard::DESTROY {
125	&up(${${$_[0]}});
126	}
127
128	1;
129
130	=back
131
132	=head1 AUTHOR
133
134	Marc Lehmann <pcg@goof.com>
135	http://www.goof.com/pcg/marc/
136
137	=cut
138