Coro/myhttpd/httpd.pl

use Coro;
use Coro::Semaphore;
use Coro::Event;
use Coro::Socket;

use HTTP::Date;

no utf8;
use bytes;

# at least on my machine, this thingy serves files
# quite a bit faster than apache, ;)
# and quite a bit slower than thttpd :(

$SIG{PIPE} = 'IGNORE';

our $accesslog;

if ($ACCESS_LOG) {
   use IO::Handle;
   open $accesslog, ">>$ACCESS_LOG"
     or die "$ACCESS_LOG: $!";
   $accesslog->autoflush(1);
}

sub slog {
   my $level = shift;
   my $format = shift;
   printf "---: $format\n", @_;
}

our $connections = new Coro::Semaphore $MAX_CONNECTS || 250;

our $wait_factor = 0.95;

our @transfers = (
  [(new Coro::Semaphore $MAX_TRANSFERS_SMALL || 50), 1],
  [(new Coro::Semaphore $MAX_TRANSFERS_LARGE || 50), 1],
);

my @newcons;
my @pool;

# one "execution thread"
sub handler {
   while () {
      if (@newcons) {
         eval {
            conn->new(@{pop @newcons})->handle;
         };
         slog 1, "$@" if $@ && !ref $@;
         $connections->up;
      } else {
         last if @pool >= $MAX_POOL;
         push @pool, $Coro::current;
         schedule;
      }
   }
}

my $http_port = new Coro::Socket
        LocalAddr => $SERVER_HOST,
        LocalPort => $SERVER_PORT,
        ReuseAddr => 1,
        Listen => 50,
   or die "unable to start server";

push @listen_sockets, $http_port;

our $NOW;
our $HTTP_NOW;

Event->timer(interval => 1, hard => 1, cb => sub {
   $NOW = time;
   $HTTP_NOW = time2str $NOW;
})->now;

# the "main thread"
async {
   slog 1, "accepting connections";
   while () {
      $connections->down;
      push @newcons, [$http_port->accept];
      #slog 3, "accepted @$connections ".scalar(@pool);
      if (@pool) {
         (pop @pool)->ready;
      } else {
         async \&handler;
      }

   }
};

package conn;

use Socket;
use HTTP::Date;
use Convert::Scalar 'weaken';
use Linux::AIO;

Linux::AIO::min_parallel $::AIO_PARALLEL;

Event->io(fd => Linux::AIO::poll_fileno,
          poll => 'r', async => 1,
          cb => \&Linux::AIO::poll_cb);

our %conn; # $conn{ip}{self} => connobj
our %uri;  # $uri{ip}{uri}{self}
our %blocked;
our %mimetype;

sub read_mimetypes {
   local *M;
   if (open M, "<mime_types") {
      while (<M>) {
         if (/^([^#]\S+)\t+(\S+)$/) {
            $mimetype{lc $1} = $2;
         }
      }
   } else {
      print "cannot open mime_types\n";
   }
}

read_mimetypes;

sub new {
   my $class = shift;
   my $peername = shift;
   my $fh = shift;
   my $self = bless { fh => $fh }, $class;
   my (undef, $iaddr) = unpack_sockaddr_in $peername
      or $self->err(500, "unable to decode peername");

   $self->{remote_addr} = inet_ntoa $iaddr;
   $self->{time} = $::NOW;

   $::conns++;

   $self;
}

sub DESTROY {
   my $self = shift;

   $::conns--;

   $self->eoconn;
}

# end of connection
sub eoconn {
   my $self = shift;

   # clean up hints
   delete $conn{$self->{remote_id}}{$self*1};
   delete $uri{$self->{remote_id}}{$self->{uri}}{$self*1};
}

sub slog {
   my $self = shift;
   main::slog($_[0], ($self->{remote_id} || $self->{remote_addr}) ."> $_[1]");
}

sub response {
   my ($self, $code, $msg, $hdr, $content) = @_;
   my $res = "HTTP/1.1 $code $msg\015\012";

   $self->{h}{connection} ||= $hdr->{Connection};

   $res .= "Date: $HTTP_NOW\015\012";

   while (my ($h, $v) = each %$hdr) {
      $res .= "$h: $v\015\012"
   }
   $res .= "\015\012";

   $res .= $content if defined $content and $self->{method} ne "HEAD";

   my $log = "$self->{remote_addr} \"$self->{uri}\" $code ".$hdr->{"Content-Length"}." \"$self->{h}{referer}\"\n";

   print $accesslog $log if $accesslog;
   print STDERR $log;

   $self->{written} +=
      print {$self->{fh}} $res;
}

sub err {
   my $self = shift;
   my ($code, $msg, $hdr, $content) = @_;

   unless (defined $content) {
      $content = "$code $msg\n";
      $hdr->{"Content-Type"} = "text/plain";
      $hdr->{"Content-Length"} = length $content;
   }
   $hdr->{"Connection"} = "close";

   $self->response($code, $msg, $hdr, $content);

   die bless {}, err::;
}

sub handle {
   my $self = shift;
   my $fh = $self->{fh};

   my $host;

   $fh->timeout($::REQ_TIMEOUT);
   while() {
      $self->{reqs}++;

      # read request and parse first line
      my $req = $fh->readline("\015\012\015\012");

      unless (defined $req) {
         if (exists $self->{version}) {
            last;
         } else {
            $self->err(408, "request timeout");
         }
      }

      $self->{h} = {};

      $fh->timeout($::RES_TIMEOUT);

      $req =~ /^(?:\015\012)?
                (GET|HEAD) \040+
                ([^\040]+) \040+
                HTTP\/([0-9]+\.[0-9]+)
                \015\012/gx
         or $self->err(405, "method not allowed", { Allow => "GET,HEAD" });

      $self->{method} = $1;
      $self->{uri} = $2;
      $self->{version} = $3;

      $3 =~ /^1\./
         or $self->err(506, "http protocol version $3 not supported");

      # parse headers
      {
         my (%hdr, $h, $v);

         $hdr{lc $1} .= ",$2"
            while $req =~ /\G
                  ([^:\000-\040]+):
                  [\008\040]*
                  ((?: [^\015\012]+ | \015\012[\008\040] )*)
                  \015\012
               /gxc;

         $req =~ /\G\015\012$/
            or $self->err(400, "bad request");

         $self->{h}{$h} = substr $v, 1
            while ($h, $v) = each %hdr;
      }

      # remote id should be unique per user
      my $id = $self->{remote_addr};

      if (exists $self->{h}{"client-ip"}) {
         $id .= "[".$self->{h}{"client-ip"}."]";
      } elsif (exists $self->{h}{"x-forwarded-for"}) {
         $id .= "[".$self->{h}{"x-forwarded-for"}."]";
      }

      $self->{remote_id} = $id;

      if ($blocked{$id}) {
         $self->err_blocked($blocked{$id})
            if $blocked{$id} > $::NOW;

         delete $blocked{$id};
      }

      if (%{$conn{$id}} >= $::MAX_CONN_IP) {
         my $delay = $::PER_TIMEOUT + 15;
         while (%{$conn{$id}} >= $::MAX_CONN_IP) {
            if ($delay <= 0) {
               $self->slog(2, "blocked ip $id");
               $self->err_blocked;
            } else {
               Coro::Event::do_timer(after => 4); $delay -= 4;
            }
         }
      }

      # find out server name and port
      if ($self->{uri} =~ s/^http:\/\/([^\/?#]*)//i) {
         $host = $1;
      } else {
         $host = $self->{h}{host};
      }

      if (defined $host) {
         $self->{server_port} = $host =~ s/:([0-9]+)$// ? $1 : 80;
      } else {
         ($self->{server_port}, $host)
            = unpack_sockaddr_in $self->{fh}->getsockname
               or $self->err(500, "unable to get socket name");
         $host = inet_ntoa $host;
      }

      $self->{server_name} = $host;

      # enter ourselves into various lists
      weaken ($conn{$id}{$self*1} = $self);
      weaken ($uri{$id}{$self->{uri}}{$self*1} = $self);

      eval {
         $self->map_uri;
         $self->respond;
      };

      $self->eoconn;

      die if $@ && !ref $@;

      last if $self->{h}{connection} =~ /close/ || $self->{version} < 1.1;

      $fh->timeout($::PER_TIMEOUT);
   }
}

# uri => path mapping
sub map_uri {
   my $self = shift;
   my $host = $self->{server_name};
   my $uri = $self->{uri};

   # some massaging, also makes it more secure
   $uri =~ s/%([0-9a-fA-F][0-9a-fA-F])/chr hex $1/ge;
   $uri =~ s%//+%/%g;
   $uri =~ s%/\.(?=/|$)%%g;
   1 while $uri =~ s%/[^/]+/\.\.(?=/|$)%%;

   $uri =~ m%^/?\.\.(?=/|$)%
      and $self->err(400, "bad request");

   $self->{name} = $uri;

   # now do the path mapping
   $self->{path} = "$::DOCROOT/$host$uri";

   $self->access_check;
}

sub _cgi {
   my $self = shift;
   my $path = shift;
   my $fh;

   # no two-way xxx supported
   if (0 == fork) {
      open STDOUT, ">&".fileno($self->{fh});
      if (chdir $::DOCROOT) {
         $ENV{SERVER_SOFTWARE} = "thttpd-myhttpd"; # we are thttpd-alike
         $ENV{HTTP_HOST}       = $self->{server_name};
         $ENV{HTTP_PORT}       = $self->{server_port};
         $ENV{SCRIPT_NAME}     = $self->{name};
         exec $path;
      }
      Coro::State::_exit(0);
   } else {
      die;
   }
}

sub server_hostport {
   $_[0]{server_port} == 80
      ? $_[0]{server_name}
      : "$_[0]{server_name}:$_[0]{server_port}";
}

sub respond {
   my $self = shift;
   my $path = $self->{path};

   stat $path
      or $self->err(404, "not found");

   $self->{stat} = [stat _];

   # idiotic netscape sends idiotic headers AGAIN
   my $ims = $self->{h}{"if-modified-since"} =~ /^([^;]+)/
             ? str2time $1 : 0;

   if (-d _ && -r _) {
      # directory
      if ($path !~ /\/$/) {
         # create a redirect to get the trailing "/"
         # we don't try to avoid the :80
         $self->err(301, "moved permanently", { Location =>  "http://".$self->server_hostport."$self->{uri}/" });
      } else {
         $ims < $self->{stat}[9]
            or $self->err(304, "not modified");

         if (-r "$path/index.html") {
            $self->{path} .= "/index.html";
            $self->handle_file;
         } else {
            $self->handle_dir;
         }
      }
   } elsif (-f _ && -r _) {
      -x _ and $self->err(403, "forbidden");
      $self->handle_file;
   } else {
      $self->err(404, "not found");
   }
}

sub handle_dir {
   my $self = shift;
   my $idx = $self->diridx;

   $self->response(200, "ok",
         {
            "Content-Type"   => "text/html",
            "Content-Length" => length $idx,
         },
         $idx);
}

sub handle_file {
   my $self = shift;
   my $length = $self->{stat}[7];
   my $queue = $::transfers[$length >= $::TRANSFER_SMALL];
   my $hdr = {
      "Last-Modified"  => time2str ((stat _)[9]),
   };

   my @code = (200, "ok");
   my ($l, $h);

   if ($self->{h}{range} =~ /^bytes=(.*)$/) {
      for (split /,/, $1) {
         if (/^-(\d+)$/) {
            ($l, $h) = ($length - $1, $length - 1);
         } elsif (/^(\d+)-(\d*)$/) {
            ($l, $h) = ($1, ($2 ne "" || $2 >= $length) ? $2 : $length - 1);
         } else {
            ($l, $h) = (0, $length - 1);
            goto ignore;
         }
         goto satisfiable if $l >= 0 && $l < $length && $h >= 0 && $h >= $l;
      }
      $hdr->{"Content-Range"} = "bytes */$length";
      $hdr->{"Content-Length"} = $length;
      $self->err(416, "not satisfiable", $hdr, "");

satisfiable:
      # check for segmented downloads
      if ($l && $::NO_SEGMENTED) {
         my $delay = $::PER_TIMEOUT + 15;
         while (%{$uri{$self->{remote_id}}{$self->{uri}}} > 1) {
            if ($delay <= 0) {
               $self->err_segmented_download;
            } else {
               Coro::Event::do_timer(after => 4); $delay -= 4;
            }
         }
      }

      $hdr->{"Content-Range"} = "bytes $l-$h/$length";
      @code = (206, "partial content");
      $length = $h - $l + 1;

ignore:
   } else {
      ($l, $h) = (0, $length - 1);
   }

   $self->{path} =~ /\.([^.]+)$/;
   $hdr->{"Content-Type"} = $mimetype{lc $1} || "application/octet-stream";
   $hdr->{"Content-Length"} = $length;

   $self->response(@code, $hdr, "");

   if ($self->{method} eq "GET") {
      $self->{time} = $::NOW;

      my $fudge = $queue->[0]->waiters;
      $fudge = $fudge ? ($fudge+1)/$fudge : 1;

      $queue->[1] *= $fudge;
      my $transfer = $queue->[0]->guard;

      if ($fudge != 1) {
         $queue->[1] /= $fudge;
         $queue->[1] = $queue->[1] * $::wait_factor
                     + ($::NOW - $self->{time}) * (1 - $::wait_factor);
      }
      $self->{time} = $::NOW;

      $self->{fh}->writable or return;

      my ($fh, $buf, $r);
      my $current = $Coro::current;
      open $fh, "<", $self->{path}
         or die "$self->{path}: late open failure ($!)";

      $h -= $l - 1;

      if (0) {
         if ($l) {
            sysseek $fh, $l, 0;
         }
      }

      while ($h > 0) {
         if (0) {
            sysread $fh, $buf, $h > $::BUFSIZE ? $::BUFSIZE : $h
               or last;
         } else {
            aio_read($fh, $l, ($h > $::BUFSIZE ? $::BUFSIZE : $h),
                     $buf, 0, sub {
                        $r = $_[0];
                        Coro::ready($current);
                     });
            &Coro::schedule;
            last unless $r;
         }
         my $w = syswrite $self->{fh}, $buf
            or last;
         $::written += $w;
         $self->{written} += $w;
         $l += $r;
      }

      close $fh;
   }
}

1;
Revision:	1.38
Committed:	Sun Sep 2 02:27:51 2001 UTC (22 years, 10 months ago) by root
Content type:	text/plain
Branch:	MAIN
Changes since 1.37:	+2 -3 lines
Log Message:	* empty log message *
#	User	Rev	Content
1	root	1.1	use Coro;
2			use Coro::Semaphore;
3			use Coro::Event;
4			use Coro::Socket;
5
6	root	1.32	use HTTP::Date;
7
8	root	1.1	no utf8;
9			use bytes;
10
11			# at least on my machine, this thingy serves files
12			# quite a bit faster than apache, ;)
13			# and quite a bit slower than thttpd :(
14
15			$SIG{PIPE} = 'IGNORE';
16	root	1.27
17			our $accesslog;
18
19			if ($ACCESS_LOG) {
20			use IO::Handle;
21			open $accesslog, ">>$ACCESS_LOG"
22			or die "$ACCESS_LOG: $!";
23			$accesslog->autoflush(1);
24			}
25
26	root	1.1	sub slog {
27			my $level = shift;
28			my $format = shift;
29			printf "---: $format\n", @_;
30			}
31
32	root	1.32	our $connections = new Coro::Semaphore $MAX_CONNECTS \|\| 250;
33	root	1.34
34			our $wait_factor = 0.95;
35
36			our @transfers = (
37	root	1.35	[(new Coro::Semaphore $MAX_TRANSFERS_SMALL \|\| 50), 1],
38			[(new Coro::Semaphore $MAX_TRANSFERS_LARGE \|\| 50), 1],
39	root	1.34	);
40	root	1.1
41	root	1.6	my @newcons;
42	root	1.1	my @pool;
43
44	root	1.2	# one "execution thread"
45	root	1.1	sub handler {
46			while () {
47	root	1.38	if (@newcons) {
48	root	1.1	eval {
49	root	1.38	conn->new(@{pop @newcons})->handle;
50	root	1.1	};
51			slog 1, "$@" if $@ && !ref $@;
52			$connections->up;
53			} else {
54			last if @pool >= $MAX_POOL;
55			push @pool, $Coro::current;
56			schedule;
57			}
58			}
59			}
60
61	root	1.4	my $http_port = new Coro::Socket
62			LocalAddr => $SERVER_HOST,
63			LocalPort => $SERVER_PORT,
64			ReuseAddr => 1,
65	root	1.13	Listen => 50,
66	root	1.4	or die "unable to start server";
67
68			push @listen_sockets, $http_port;
69
70	root	1.32	our $NOW;
71			our $HTTP_NOW;
72
73			Event->timer(interval => 1, hard => 1, cb => sub {
74			$NOW = time;
75			$HTTP_NOW = time2str $NOW;
76	root	1.34	})->now;
77	root	1.32
78	root	1.2	# the "main thread"
79	root	1.1	async {
80			slog 1, "accepting connections";
81			while () {
82			$connections->down;
83	root	1.6	push @newcons, [$http_port->accept];
84	root	1.1	#slog 3, "accepted @$connections ".scalar(@pool);
85			if (@pool) {
86			(pop @pool)->ready;
87			} else {
88			async \&handler;
89			}
90
91			}
92			};
93
94			package conn;
95
96			use Socket;
97			use HTTP::Date;
98	root	1.2	use Convert::Scalar 'weaken';
99	root	1.16	use Linux::AIO;
100
101			Linux::AIO::min_parallel $::AIO_PARALLEL;
102
103			Event->io(fd => Linux::AIO::poll_fileno,
104	root	1.17	poll => 'r', async => 1,
105	root	1.21	cb => \&Linux::AIO::poll_cb);
106	root	1.16
107	root	1.26	our %conn; # $conn{ip}{self} => connobj
108			our %uri; # $uri{ip}{uri}{self}
109	root	1.3	our %blocked;
110	root	1.9	our %mimetype;
111
112			sub read_mimetypes {
113			local *M;
114	root	1.10	if (open M, "<mime_types") {
115	root	1.9	while (<M>) {
116			if (/^([^#]\S+)\t+(\S+)$/) {
117			$mimetype{lc $1} = $2;
118			}
119			}
120			} else {
121	root	1.10	print "cannot open mime_types\n";
122	root	1.9	}
123			}
124	root	1.1
125	root	1.10	read_mimetypes;
126
127	root	1.1	sub new {
128			my $class = shift;
129	root	1.6	my $peername = shift;
130	root	1.1	my $fh = shift;
131	root	1.2	my $self = bless { fh => $fh }, $class;
132	root	1.6	my (undef, $iaddr) = unpack_sockaddr_in $peername
133			or $self->err(500, "unable to decode peername");
134	root	1.7
135	root	1.3	$self->{remote_addr} = inet_ntoa $iaddr;
136	root	1.11	$self->{time} = $::NOW;
137	root	1.2
138	root	1.13	$::conns++;
139
140	root	1.2	$self;
141			}
142
143			sub DESTROY {
144			my $self = shift;
145	root	1.13
146			$::conns--;
147
148	root	1.19	$self->eoconn;
149			}
150
151			# end of connection
152			sub eoconn {
153	root	1.26	my $self = shift;
154	root	1.36
155			# clean up hints
156			delete $conn{$self->{remote_id}}{$self*1};
157			delete $uri{$self->{remote_id}}{$self->{uri}}{$self*1};
158	root	1.1	}
159
160			sub slog {
161	root	1.4	my $self = shift;
162	root	1.29	main::slog($_[0], ($self->{remote_id} \|\| $self->{remote_addr}) ."> $_[1]");
163	root	1.1	}
164
165	root	1.4	sub response {
166	root	1.1	my ($self, $code, $msg, $hdr, $content) = @_;
167	root	1.17	my $res = "HTTP/1.1 $code $msg\015\012";
168	root	1.1
169	root	1.28	$self->{h}{connection} \|\|= $hdr->{Connection};
170
171	root	1.32	$res .= "Date: $HTTP_NOW\015\012";
172	root	1.1
173			while (my ($h, $v) = each %$hdr) {
174			$res .= "$h: $v\015\012"
175			}
176	root	1.10	$res .= "\015\012";
177	root	1.4
178	root	1.13	$res .= $content if defined $content and $self->{method} ne "HEAD";
179	root	1.1
180	root	1.27	my $log = "$self->{remote_addr} \"$self->{uri}\" $code ".$hdr->{"Content-Length"}." \"$self->{h}{referer}\"\n";
181
182			print $accesslog $log if $accesslog;
183			print STDERR $log;
184	root	1.2
185	root	1.11	$self->{written} +=
186			print {$self->{fh}} $res;
187	root	1.1	}
188
189			sub err {
190			my $self = shift;
191			my ($code, $msg, $hdr, $content) = @_;
192
193			unless (defined $content) {
194	root	1.35	$content = "$code $msg\n";
195	root	1.1	$hdr->{"Content-Type"} = "text/plain";
196			$hdr->{"Content-Length"} = length $content;
197			}
198	root	1.17	$hdr->{"Connection"} = "close";
199	root	1.1
200	root	1.4	$self->response($code, $msg, $hdr, $content);
201	root	1.1
202			die bless {}, err::;
203			}
204
205			sub handle {
206			my $self = shift;
207			my $fh = $self->{fh};
208
209	root	1.29	my $host;
210
211	root	1.17	$fh->timeout($::REQ_TIMEOUT);
212			while() {
213			$self->{reqs}++;
214	root	1.1
215			# read request and parse first line
216			my $req = $fh->readline("\015\012\015\012");
217
218	root	1.17	unless (defined $req) {
219			if (exists $self->{version}) {
220			last;
221			} else {
222			$self->err(408, "request timeout");
223			}
224			}
225
226			$self->{h} = {};
227	root	1.1
228	root	1.17	$fh->timeout($::RES_TIMEOUT);
229	root	1.3
230	root	1.1	$req =~ /^(?:\015\012)?
231			(GET\|HEAD) \040+
232			([^\040]+) \040+
233			HTTP\/([0-9]+\.[0-9]+)
234			\015\012/gx
235	root	1.14	or $self->err(405, "method not allowed", { Allow => "GET,HEAD" });
236	root	1.1
237			$self->{method} = $1;
238			$self->{uri} = $2;
239	root	1.17	$self->{version} = $3;
240
241	root	1.20	$3 =~ /^1\./
242	root	1.17	or $self->err(506, "http protocol version $3 not supported");
243	root	1.1
244			# parse headers
245			{
246			my (%hdr, $h, $v);
247
248			$hdr{lc $1} .= ",$2"
249			while $req =~ /\G
250			([^:\000-\040]+):
251			[\008\040]*
252			((?: [^\015\012]+ \| \015\012[\008\040] )*)
253			\015\012
254			/gxc;
255
256			$req =~ /\G\015\012$/
257			or $self->err(400, "bad request");
258
259			$self->{h}{$h} = substr $v, 1
260			while ($h, $v) = each %hdr;
261			}
262
263	root	1.36	# remote id should be unique per user
264			my $id = $self->{remote_addr};
265
266			if (exists $self->{h}{"client-ip"}) {
267			$id .= "[".$self->{h}{"client-ip"}."]";
268			} elsif (exists $self->{h}{"x-forwarded-for"}) {
269			$id .= "[".$self->{h}{"x-forwarded-for"}."]";
270			}
271
272			$self->{remote_id} = $id;
273
274			if ($blocked{$id}) {
275			$self->err_blocked($blocked{$id})
276			if $blocked{$id} > $::NOW;
277
278			delete $blocked{$id};
279			}
280
281			if (%{$conn{$id}} >= $::MAX_CONN_IP) {
282			my $delay = $::PER_TIMEOUT + 15;
283			while (%{$conn{$id}} >= $::MAX_CONN_IP) {
284			if ($delay <= 0) {
285			$self->slog(2, "blocked ip $id");
286			$self->err_blocked;
287			} else {
288			Coro::Event::do_timer(after => 4); $delay -= 4;
289			}
290			}
291			}
292
293	root	1.29	# find out server name and port
294			if ($self->{uri} =~ s/^http:\/\/([^\/?#]*)//i) {
295			$host = $1;
296			} else {
297			$host = $self->{h}{host};
298			}
299
300			if (defined $host) {
301			$self->{server_port} = $host =~ s/:([0-9]+)$// ? $1 : 80;
302			} else {
303			($self->{server_port}, $host)
304			= unpack_sockaddr_in $self->{fh}->getsockname
305			or $self->err(500, "unable to get socket name");
306			$host = inet_ntoa $host;
307			}
308
309			$self->{server_name} = $host;
310
311	root	1.36	# enter ourselves into various lists
312			weaken ($conn{$id}{$self*1} = $self);
313			weaken ($uri{$id}{$self->{uri}}{$self*1} = $self);
314	root	1.1
315	root	1.24	eval {
316			$self->map_uri;
317			$self->respond;
318			};
319
320	root	1.26	$self->eoconn;
321
322	root	1.24	die if $@ && !ref $@;
323	root	1.17
324	root	1.29	last if $self->{h}{connection} =~ /close/ \|\| $self->{version} < 1.1;
325	root	1.17
326			$fh->timeout($::PER_TIMEOUT);
327			}
328	root	1.1	}
329
330			# uri => path mapping
331			sub map_uri {
332			my $self = shift;
333	root	1.29	my $host = $self->{server_name};
334	root	1.1	my $uri = $self->{uri};
335
336			# some massaging, also makes it more secure
337			$uri =~ s/%([0-9a-fA-F][0-9a-fA-F])/chr hex $1/ge;
338			$uri =~ s%//+%/%g;
339			$uri =~ s%/\.(?=/\|$)%%g;
340			1 while $uri =~ s%/[^/]+/\.\.(?=/\|$)%%;
341
342			$uri =~ m%^/?\.\.(?=/\|$)%
343			and $self->err(400, "bad request");
344
345			$self->{name} = $uri;
346
347			# now do the path mapping
348			$self->{path} = "$::DOCROOT/$host$uri";
349	root	1.7
350			$self->access_check;
351	root	1.1	}
352
353			sub _cgi {
354			my $self = shift;
355			my $path = shift;
356			my $fh;
357
358			# no two-way xxx supported
359			if (0 == fork) {
360			open STDOUT, ">&".fileno($self->{fh});
361			if (chdir $::DOCROOT) {
362			$ENV{SERVER_SOFTWARE} = "thttpd-myhttpd"; # we are thttpd-alike
363	root	1.29	$ENV{HTTP_HOST} = $self->{server_name};
364			$ENV{HTTP_PORT} = $self->{server_port};
365	root	1.1	$ENV{SCRIPT_NAME} = $self->{name};
366	root	1.10	exec $path;
367	root	1.1	}
368			Coro::State::_exit(0);
369			} else {
370	root	1.29	die;
371	root	1.1	}
372			}
373
374	root	1.29	sub server_hostport {
375			$_[0]{server_port} == 80
376			? $_[0]{server_name}
377			: "$_[0]{server_name}:$_[0]{server_port}";
378			}
379
380	root	1.1	sub respond {
381			my $self = shift;
382			my $path = $self->{path};
383
384			stat $path
385			or $self->err(404, "not found");
386
387	root	1.10	$self->{stat} = [stat _];
388
389	root	1.1	# idiotic netscape sends idiotic headers AGAIN
390			my $ims = $self->{h}{"if-modified-since"} =~ /^([^;]+)/
391			? str2time $1 : 0;
392
393			if (-d _ && -r _) {
394			# directory
395			if ($path !~ /\/$/) {
396			# create a redirect to get the trailing "/"
397	root	1.29	# we don't try to avoid the :80
398			$self->err(301, "moved permanently", { Location => "http://".$self->server_hostport."$self->{uri}/" });
399	root	1.1	} else {
400	root	1.10	$ims < $self->{stat}[9]
401	root	1.1	or $self->err(304, "not modified");
402
403	root	1.25	if (-r "$path/index.html") {
404			$self->{path} .= "/index.html";
405			$self->handle_file;
406			} else {
407			$self->handle_dir;
408	root	1.1	}
409			}
410			} elsif (-f _ && -r _) {
411			-x _ and $self->err(403, "forbidden");
412			$self->handle_file;
413			} else {
414			$self->err(404, "not found");
415			}
416			}
417
418			sub handle_dir {
419			my $self = shift;
420	root	1.10	my $idx = $self->diridx;
421
422			$self->response(200, "ok",
423			{
424			"Content-Type" => "text/html",
425			"Content-Length" => length $idx,
426			},
427			$idx);
428	root	1.1	}
429
430			sub handle_file {
431			my $self = shift;
432	root	1.34	my $length = $self->{stat}[7];
433			my $queue = $::transfers[$length >= $::TRANSFER_SMALL];
434	root	1.1	my $hdr = {
435			"Last-Modified" => time2str ((stat _)[9]),
436			};
437
438			my @code = (200, "ok");
439			my ($l, $h);
440
441			if ($self->{h}{range} =~ /^bytes=(.*)$/) {
442			for (split /,/, $1) {
443			if (/^-(\d+)$/) {
444			($l, $h) = ($length - $1, $length - 1);
445			} elsif (/^(\d+)-(\d*)$/) {
446			($l, $h) = ($1, ($2 ne "" \|\| $2 >= $length) ? $2 : $length - 1);
447			} else {
448			($l, $h) = (0, $length - 1);
449			goto ignore;
450			}
451	root	1.26	goto satisfiable if $l >= 0 && $l < $length && $h >= 0 && $h >= $l;
452	root	1.1	}
453			$hdr->{"Content-Range"} = "bytes */$length";
454	root	1.24	$hdr->{"Content-Length"} = $length;
455			$self->err(416, "not satisfiable", $hdr, "");
456	root	1.1
457			satisfiable:
458	root	1.4	# check for segmented downloads
459	root	1.10	if ($l && $::NO_SEGMENTED) {
460	root	1.36	my $delay = $::PER_TIMEOUT + 15;
461			while (%{$uri{$self->{remote_id}}{$self->{uri}}} > 1) {
462	root	1.29	if ($delay <= 0) {
463	root	1.30	$self->err_segmented_download;
464	root	1.29	} else {
465	root	1.36	Coro::Event::do_timer(after => 4); $delay -= 4;
466	root	1.29	}
467	root	1.4	}
468			}
469
470	root	1.1	$hdr->{"Content-Range"} = "bytes $l-$h/$length";
471			@code = (206, "partial content");
472			$length = $h - $l + 1;
473
474			ignore:
475			} else {
476			($l, $h) = (0, $length - 1);
477			}
478
479	root	1.9	$self->{path} =~ /\.([^.]+)$/;
480			$hdr->{"Content-Type"} = $mimetype{lc $1} \|\| "application/octet-stream";
481	root	1.1	$hdr->{"Content-Length"} = $length;
482
483	root	1.4	$self->response(@code, $hdr, "");
484	root	1.1
485			if ($self->{method} eq "GET") {
486	root	1.32	$self->{time} = $::NOW;
487
488	root	1.35	my $fudge = $queue->[0]->waiters;
489			$fudge = $fudge ? ($fudge+1)/$fudge : 1;
490
491			$queue->[1] *= $fudge;
492	root	1.34	my $transfer = $queue->[0]->guard;
493	root	1.32
494	root	1.35	if ($fudge != 1) {
495			$queue->[1] /= $fudge;
496			$queue->[1] = $queue->[1] * $::wait_factor
497			+ ($::NOW - $self->{time}) * (1 - $::wait_factor);
498			}
499	root	1.32	$self->{time} = $::NOW;
500	root	1.35
501			$self->{fh}->writable or return;
502	root	1.32
503	root	1.16	my ($fh, $buf, $r);
504			my $current = $Coro::current;
505	root	1.1	open $fh, "<", $self->{path}
506			or die "$self->{path}: late open failure ($!)";
507
508			$h -= $l - 1;
509
510	root	1.19	if (0) {
511			if ($l) {
512			sysseek $fh, $l, 0;
513			}
514			}
515
516	root	1.1	while ($h > 0) {
517	root	1.19	if (0) {
518			sysread $fh, $buf, $h > $::BUFSIZE ? $::BUFSIZE : $h
519			or last;
520			} else {
521			aio_read($fh, $l, ($h > $::BUFSIZE ? $::BUFSIZE : $h),
522			$buf, 0, sub {
523			$r = $_[0];
524	root	1.37	Coro::ready($current);
525	root	1.19	});
526			&Coro::schedule;
527			last unless $r;
528			}
529	root	1.37	my $w = syswrite $self->{fh}, $buf
530	root	1.1	or last;
531	root	1.11	$::written += $w;
532			$self->{written} += $w;
533	root	1.16	$l += $r;
534	root	1.1	}
535	root	1.32
536			close $fh;
537	root	1.1	}
538	root	1.7	}
539
540	root	1.2	1;