| 1 |
use Coro; |
| 2 |
use Coro::Semaphore; |
| 3 |
use Coro::Event; |
| 4 |
use Coro::Socket; |
| 5 |
use Coro::Signal; |
| 6 |
|
| 7 |
use HTTP::Date; |
| 8 |
|
| 9 |
no utf8; |
| 10 |
use bytes; |
| 11 |
|
| 12 |
# at least on my machine, this thingy serves files |
| 13 |
# quite a bit faster than apache, ;) |
| 14 |
# and quite a bit slower than thttpd :( |
| 15 |
|
| 16 |
$SIG{PIPE} = 'IGNORE'; |
| 17 |
|
| 18 |
our $accesslog; |
| 19 |
|
| 20 |
if ($ACCESS_LOG) { |
| 21 |
use IO::Handle; |
| 22 |
open $accesslog, ">>$ACCESS_LOG" |
| 23 |
or die "$ACCESS_LOG: $!"; |
| 24 |
$accesslog->autoflush(1); |
| 25 |
} |
| 26 |
|
| 27 |
sub slog { |
| 28 |
my $level = shift; |
| 29 |
my $format = shift; |
| 30 |
printf "---: $format\n", @_; |
| 31 |
} |
| 32 |
|
| 33 |
our $connections = new Coro::Semaphore $MAX_CONNECTS || 250; |
| 34 |
our $httpevent = new Coro::Signal; |
| 35 |
|
| 36 |
our $wait_factor = 0.95; |
| 37 |
|
| 38 |
our @transfers = ( |
| 39 |
[(new Coro::Semaphore $MAX_TRANSFERS_SMALL || 50), 1], |
| 40 |
[(new Coro::Semaphore $MAX_TRANSFERS_LARGE || 50), 1], |
| 41 |
); |
| 42 |
|
| 43 |
my @newcons; |
| 44 |
my @pool; |
| 45 |
|
| 46 |
# one "execution thread" |
| 47 |
sub handler { |
| 48 |
while () { |
| 49 |
if (@newcons) { |
| 50 |
eval { |
| 51 |
conn->new(@{pop @newcons})->handle; |
| 52 |
}; |
| 53 |
slog 1, "$@" if $@ && !ref $@; |
| 54 |
$connections->up; |
| 55 |
} else { |
| 56 |
last if @pool >= $MAX_POOL; |
| 57 |
push @pool, $Coro::current; |
| 58 |
schedule; |
| 59 |
} |
| 60 |
} |
| 61 |
} |
| 62 |
|
| 63 |
sub listen_on { |
| 64 |
my $listen = $_[0]; |
| 65 |
|
| 66 |
push @listen_sockets, $listen; |
| 67 |
|
| 68 |
# the "main thread" |
| 69 |
async { |
| 70 |
slog 1, "accepting connections"; |
| 71 |
while () { |
| 72 |
$connections->down; |
| 73 |
push @newcons, [$listen->accept]; |
| 74 |
#slog 3, "accepted @$connections ".scalar(@pool); |
| 75 |
if (@pool) { |
| 76 |
(pop @pool)->ready; |
| 77 |
} else { |
| 78 |
async \&handler; |
| 79 |
} |
| 80 |
|
| 81 |
} |
| 82 |
}; |
| 83 |
} |
| 84 |
|
| 85 |
my $http_port = new Coro::Socket |
| 86 |
LocalAddr => $SERVER_HOST, |
| 87 |
LocalPort => $SERVER_PORT, |
| 88 |
ReuseAddr => 1, |
| 89 |
Listen => 50, |
| 90 |
or die "unable to start server"; |
| 91 |
|
| 92 |
listen_on $http_port; |
| 93 |
|
| 94 |
if ($SERVER_PORT2) { |
| 95 |
my $http_port = new Coro::Socket |
| 96 |
LocalAddr => $SERVER_HOST, |
| 97 |
LocalPort => $SERVER_PORT2, |
| 98 |
ReuseAddr => 1, |
| 99 |
Listen => 50, |
| 100 |
or die "unable to start server"; |
| 101 |
|
| 102 |
listen_on $http_port; |
| 103 |
} |
| 104 |
|
| 105 |
our $NOW; |
| 106 |
our $HTTP_NOW; |
| 107 |
|
| 108 |
Event->timer(interval => 1, hard => 1, cb => sub { |
| 109 |
$NOW = time; |
| 110 |
$HTTP_NOW = time2str $NOW; |
| 111 |
})->now; |
| 112 |
|
| 113 |
package conn; |
| 114 |
|
| 115 |
use Socket; |
| 116 |
use HTTP::Date; |
| 117 |
use Convert::Scalar 'weaken'; |
| 118 |
use Linux::AIO; |
| 119 |
|
| 120 |
Linux::AIO::min_parallel $::AIO_PARALLEL; |
| 121 |
|
| 122 |
Event->io(fd => Linux::AIO::poll_fileno, |
| 123 |
poll => 'r', async => 1, |
| 124 |
cb => \&Linux::AIO::poll_cb); |
| 125 |
|
| 126 |
our %conn; # $conn{ip}{self} => connobj |
| 127 |
our %uri; # $uri{ip}{uri}{self} |
| 128 |
our %blocked; |
| 129 |
our %mimetype; |
| 130 |
|
| 131 |
sub read_mimetypes { |
| 132 |
local *M; |
| 133 |
if (open M, "<mime_types") { |
| 134 |
while (<M>) { |
| 135 |
if (/^([^#]\S+)\t+(\S+)$/) { |
| 136 |
$mimetype{lc $1} = $2; |
| 137 |
} |
| 138 |
} |
| 139 |
} else { |
| 140 |
print "cannot open mime_types\n"; |
| 141 |
} |
| 142 |
} |
| 143 |
|
| 144 |
read_mimetypes; |
| 145 |
|
| 146 |
sub new { |
| 147 |
my $class = shift; |
| 148 |
my $fh = shift; |
| 149 |
my $peername = shift; |
| 150 |
my $self = bless { fh => $fh }, $class; |
| 151 |
my (undef, $iaddr) = unpack_sockaddr_in $peername |
| 152 |
or $self->err(500, "unable to decode peername"); |
| 153 |
|
| 154 |
$self->{remote_addr} = inet_ntoa $iaddr; |
| 155 |
$self->{time} = $::NOW; |
| 156 |
|
| 157 |
$::conns++; |
| 158 |
|
| 159 |
$self; |
| 160 |
} |
| 161 |
|
| 162 |
sub DESTROY { |
| 163 |
my $self = shift; |
| 164 |
$::conns--; |
| 165 |
$self->eoconn; |
| 166 |
} |
| 167 |
|
| 168 |
# end of connection |
| 169 |
sub eoconn { |
| 170 |
my $self = shift; |
| 171 |
|
| 172 |
# clean up hints |
| 173 |
delete $conn{$self->{remote_id}}{$self*1}; |
| 174 |
delete $uri{$self->{remote_id}}{$self->{uri}}{$self*1}; |
| 175 |
|
| 176 |
$httpevent->broadcast; |
| 177 |
} |
| 178 |
|
| 179 |
sub slog { |
| 180 |
my $self = shift; |
| 181 |
main::slog($_[0], ($self->{remote_id} || $self->{remote_addr}) ."> $_[1]"); |
| 182 |
} |
| 183 |
|
| 184 |
sub response { |
| 185 |
my ($self, $code, $msg, $hdr, $content) = @_; |
| 186 |
my $res = "HTTP/1.1 $code $msg\015\012"; |
| 187 |
|
| 188 |
if (exists $hdr->{Connection}) { |
| 189 |
if ($hdr->{Connection} =~ /close/) { |
| 190 |
$self->{h}{connection} = "close" |
| 191 |
} |
| 192 |
} else { |
| 193 |
if ($self->{version} < 1.1) { |
| 194 |
if ($self->{h}{connection} =~ /keep-alive/i) { |
| 195 |
$hdr->{Connection} = "Keep-Alive"; |
| 196 |
} else { |
| 197 |
$self->{h}{connection} = "close" |
| 198 |
} |
| 199 |
} |
| 200 |
} |
| 201 |
|
| 202 |
$res .= "Date: $HTTP_NOW\015\012"; |
| 203 |
|
| 204 |
while (my ($h, $v) = each %$hdr) { |
| 205 |
$res .= "$h: $v\015\012" |
| 206 |
} |
| 207 |
$res .= "\015\012"; |
| 208 |
|
| 209 |
$res .= $content if defined $content and $self->{method} ne "HEAD"; |
| 210 |
|
| 211 |
my $log = "$self->{remote_addr} \"$self->{uri}\" $code ".$hdr->{"Content-Length"}." \"$self->{h}{referer}\"\n"; |
| 212 |
|
| 213 |
print $accesslog $log if $accesslog; |
| 214 |
print STDERR $log; |
| 215 |
|
| 216 |
$self->{written} += |
| 217 |
print {$self->{fh}} $res; |
| 218 |
} |
| 219 |
|
| 220 |
sub err { |
| 221 |
my $self = shift; |
| 222 |
my ($code, $msg, $hdr, $content) = @_; |
| 223 |
|
| 224 |
unless (defined $content) { |
| 225 |
$content = "$code $msg\n"; |
| 226 |
$hdr->{"Content-Type"} = "text/plain"; |
| 227 |
$hdr->{"Content-Length"} = length $content; |
| 228 |
} |
| 229 |
$hdr->{"Connection"} = "close"; |
| 230 |
|
| 231 |
$self->response($code, $msg, $hdr, $content); |
| 232 |
|
| 233 |
die bless {}, err::; |
| 234 |
} |
| 235 |
|
| 236 |
sub handle { |
| 237 |
my $self = shift; |
| 238 |
my $fh = $self->{fh}; |
| 239 |
|
| 240 |
my $host; |
| 241 |
|
| 242 |
$fh->timeout($::REQ_TIMEOUT); |
| 243 |
while() { |
| 244 |
$self->{reqs}++; |
| 245 |
|
| 246 |
# read request and parse first line |
| 247 |
my $req = $fh->readline("\015\012\015\012"); |
| 248 |
|
| 249 |
unless (defined $req) { |
| 250 |
if (exists $self->{version}) { |
| 251 |
last; |
| 252 |
} else { |
| 253 |
$self->err(408, "request timeout"); |
| 254 |
} |
| 255 |
} |
| 256 |
|
| 257 |
$self->{h} = {}; |
| 258 |
|
| 259 |
$fh->timeout($::RES_TIMEOUT); |
| 260 |
|
| 261 |
$req =~ /^(?:\015\012)? |
| 262 |
(GET|HEAD) \040+ |
| 263 |
([^\040]+) \040+ |
| 264 |
HTTP\/([0-9]+\.[0-9]+) |
| 265 |
\015\012/gx |
| 266 |
or $self->err(405, "method not allowed", { Allow => "GET,HEAD" }); |
| 267 |
|
| 268 |
$self->{method} = $1; |
| 269 |
$self->{uri} = $2; |
| 270 |
$self->{version} = $3; |
| 271 |
|
| 272 |
$3 =~ /^1\./ |
| 273 |
or $self->err(506, "http protocol version $3 not supported"); |
| 274 |
|
| 275 |
# parse headers |
| 276 |
{ |
| 277 |
my (%hdr, $h, $v); |
| 278 |
|
| 279 |
$hdr{lc $1} .= ",$2" |
| 280 |
while $req =~ /\G |
| 281 |
([^:\000-\040]+): |
| 282 |
[\008\040]* |
| 283 |
((?: [^\015\012]+ | \015\012[\008\040] )*) |
| 284 |
\015\012 |
| 285 |
/gxc; |
| 286 |
|
| 287 |
$req =~ /\G\015\012$/ |
| 288 |
or $self->err(400, "bad request"); |
| 289 |
|
| 290 |
$self->{h}{$h} = substr $v, 1 |
| 291 |
while ($h, $v) = each %hdr; |
| 292 |
} |
| 293 |
|
| 294 |
# remote id should be unique per user |
| 295 |
my $id = $self->{remote_addr}; |
| 296 |
|
| 297 |
if (exists $self->{h}{"client-ip"}) { |
| 298 |
$id .= "[".$self->{h}{"client-ip"}."]"; |
| 299 |
} elsif (exists $self->{h}{"x-forwarded-for"}) { |
| 300 |
$id .= "[".$self->{h}{"x-forwarded-for"}."]"; |
| 301 |
} |
| 302 |
|
| 303 |
$self->{remote_id} = $id; |
| 304 |
|
| 305 |
if ($blocked{$id}) { |
| 306 |
$self->err_blocked($blocked{$id}) |
| 307 |
if $blocked{$id} > $::NOW; |
| 308 |
|
| 309 |
delete $blocked{$id}; |
| 310 |
} |
| 311 |
|
| 312 |
if (%{$conn{$id}} >= $::MAX_CONN_IP) { |
| 313 |
my $delay = $::PER_TIMEOUT + $::NOW + 15; |
| 314 |
while (%{$conn{$id}} >= $::MAX_CONN_IP) { |
| 315 |
if ($delay < $::NOW) { |
| 316 |
$self->slog(2, "blocked ip $id"); |
| 317 |
$self->err_blocked; |
| 318 |
} else { |
| 319 |
$httpevent->wait; |
| 320 |
} |
| 321 |
} |
| 322 |
} |
| 323 |
|
| 324 |
# find out server name and port |
| 325 |
if ($self->{uri} =~ s/^http:\/\/([^\/?#]*)//i) { |
| 326 |
$host = $1; |
| 327 |
} else { |
| 328 |
$host = $self->{h}{host}; |
| 329 |
} |
| 330 |
|
| 331 |
if (defined $host) { |
| 332 |
$self->{server_port} = $host =~ s/:([0-9]+)$// ? $1 : 80; |
| 333 |
} else { |
| 334 |
($self->{server_port}, $host) |
| 335 |
= unpack_sockaddr_in $self->{fh}->sockname |
| 336 |
or $self->err(500, "unable to get socket name"); |
| 337 |
$host = inet_ntoa $host; |
| 338 |
} |
| 339 |
|
| 340 |
$self->{server_name} = $host; |
| 341 |
|
| 342 |
# enter ourselves into various lists |
| 343 |
weaken ($conn{$id}{$self*1} = $self); |
| 344 |
weaken ($uri{$id}{$self->{uri}}{$self*1} = $self); |
| 345 |
|
| 346 |
eval { |
| 347 |
$self->map_uri; |
| 348 |
$self->respond; |
| 349 |
}; |
| 350 |
|
| 351 |
$self->eoconn; |
| 352 |
|
| 353 |
die if $@ && !ref $@; |
| 354 |
|
| 355 |
last if $self->{h}{connection} =~ /close/; |
| 356 |
|
| 357 |
$httpevent->broadcast; |
| 358 |
|
| 359 |
$fh->timeout($::PER_TIMEOUT); |
| 360 |
} |
| 361 |
} |
| 362 |
|
| 363 |
# uri => path mapping |
| 364 |
sub map_uri { |
| 365 |
my $self = shift; |
| 366 |
my $host = $self->{server_name}; |
| 367 |
my $uri = $self->{uri}; |
| 368 |
|
| 369 |
# some massaging, also makes it more secure |
| 370 |
$uri =~ s/%([0-9a-fA-F][0-9a-fA-F])/chr hex $1/ge; |
| 371 |
$uri =~ s%//+%/%g; |
| 372 |
$uri =~ s%/\.(?=/|$)%%g; |
| 373 |
1 while $uri =~ s%/[^/]+/\.\.(?=/|$)%%; |
| 374 |
|
| 375 |
$uri =~ m%^/?\.\.(?=/|$)% |
| 376 |
and $self->err(400, "bad request"); |
| 377 |
|
| 378 |
$self->{name} = $uri; |
| 379 |
|
| 380 |
# now do the path mapping |
| 381 |
$self->{path} = "$::DOCROOT/$host$uri"; |
| 382 |
|
| 383 |
$self->access_check; |
| 384 |
} |
| 385 |
|
| 386 |
sub _cgi { |
| 387 |
my $self = shift; |
| 388 |
my $path = shift; |
| 389 |
my $fh; |
| 390 |
|
| 391 |
# no two-way xxx supported |
| 392 |
if (0 == fork) { |
| 393 |
open STDOUT, ">&".fileno($self->{fh}); |
| 394 |
if (chdir $::DOCROOT) { |
| 395 |
$ENV{SERVER_SOFTWARE} = "thttpd-myhttpd"; # we are thttpd-alike |
| 396 |
$ENV{HTTP_HOST} = $self->{server_name}; |
| 397 |
$ENV{HTTP_PORT} = $self->{server_port}; |
| 398 |
$ENV{SCRIPT_NAME} = $self->{name}; |
| 399 |
exec $path; |
| 400 |
} |
| 401 |
Coro::State::_exit(0); |
| 402 |
} else { |
| 403 |
die; |
| 404 |
} |
| 405 |
} |
| 406 |
|
| 407 |
sub server_hostport { |
| 408 |
$_[0]{server_port} == 80 |
| 409 |
? $_[0]{server_name} |
| 410 |
: "$_[0]{server_name}:$_[0]{server_port}"; |
| 411 |
} |
| 412 |
|
| 413 |
sub respond { |
| 414 |
my $self = shift; |
| 415 |
my $path = $self->{path}; |
| 416 |
|
| 417 |
stat $path |
| 418 |
or $self->err(404, "not found"); |
| 419 |
|
| 420 |
$self->{stat} = [stat _]; |
| 421 |
|
| 422 |
# idiotic netscape sends idiotic headers AGAIN |
| 423 |
my $ims = $self->{h}{"if-modified-since"} =~ /^([^;]+)/ |
| 424 |
? str2time $1 : 0; |
| 425 |
|
| 426 |
if (-d _ && -r _) { |
| 427 |
# directory |
| 428 |
if ($path !~ /\/$/) { |
| 429 |
# create a redirect to get the trailing "/" |
| 430 |
# we don't try to avoid the :80 |
| 431 |
$self->err(301, "moved permanently", { Location => "http://".$self->server_hostport."$self->{uri}/" }); |
| 432 |
} else { |
| 433 |
$ims < $self->{stat}[9] |
| 434 |
or $self->err(304, "not modified"); |
| 435 |
|
| 436 |
if (-r "$path/index.html") { |
| 437 |
# replace directory "size" by index.html filesize |
| 438 |
$self->{stat}[7] = (stat ($self->{path} .= "/index.html"))[7]; |
| 439 |
$self->handle_file; |
| 440 |
} else { |
| 441 |
$self->handle_dir; |
| 442 |
} |
| 443 |
} |
| 444 |
} elsif (-f _ && -r _) { |
| 445 |
-x _ and $self->err(403, "forbidden"); |
| 446 |
$self->handle_file; |
| 447 |
} else { |
| 448 |
$self->err(404, "not found"); |
| 449 |
} |
| 450 |
} |
| 451 |
|
| 452 |
sub handle_dir { |
| 453 |
my $self = shift; |
| 454 |
my $idx = $self->diridx; |
| 455 |
|
| 456 |
$self->response(200, "ok", |
| 457 |
{ |
| 458 |
"Content-Type" => "text/html", |
| 459 |
"Content-Length" => length $idx, |
| 460 |
}, |
| 461 |
$idx); |
| 462 |
} |
| 463 |
|
| 464 |
sub handle_file { |
| 465 |
my $self = shift; |
| 466 |
my $length = $self->{stat}[7]; |
| 467 |
my $queue = $::transfers[$length >= $::TRANSFER_SMALL]; |
| 468 |
my $hdr = { |
| 469 |
"Last-Modified" => time2str ((stat _)[9]), |
| 470 |
}; |
| 471 |
|
| 472 |
my @code = (200, "ok"); |
| 473 |
my ($l, $h); |
| 474 |
|
| 475 |
if ($self->{h}{range} =~ /^bytes=(.*)$/) { |
| 476 |
for (split /,/, $1) { |
| 477 |
if (/^-(\d+)$/) { |
| 478 |
($l, $h) = ($length - $1, $length - 1); |
| 479 |
} elsif (/^(\d+)-(\d*)$/) { |
| 480 |
($l, $h) = ($1, ($2 ne "" || $2 >= $length) ? $2 : $length - 1); |
| 481 |
} else { |
| 482 |
($l, $h) = (0, $length - 1); |
| 483 |
goto ignore; |
| 484 |
} |
| 485 |
goto satisfiable if $l >= 0 && $l < $length && $h >= 0 && $h >= $l; |
| 486 |
} |
| 487 |
$hdr->{"Content-Range"} = "bytes */$length"; |
| 488 |
$hdr->{"Content-Length"} = $length; |
| 489 |
$self->err(416, "not satisfiable", $hdr, ""); |
| 490 |
|
| 491 |
satisfiable: |
| 492 |
# check for segmented downloads |
| 493 |
if ($l && $::NO_SEGMENTED) { |
| 494 |
my $delay = $::NOW + $::PER_TIMEOUT + 15; |
| 495 |
while (%{$uri{$self->{remote_id}}{$self->{uri}}} > 1) { |
| 496 |
if ($delay <= $::NOW) { |
| 497 |
$self->err_segmented_download; |
| 498 |
} else { |
| 499 |
$httpevent->wait; |
| 500 |
} |
| 501 |
} |
| 502 |
} |
| 503 |
|
| 504 |
$hdr->{"Content-Range"} = "bytes $l-$h/$length"; |
| 505 |
@code = (206, "partial content"); |
| 506 |
$length = $h - $l + 1; |
| 507 |
|
| 508 |
ignore: |
| 509 |
} else { |
| 510 |
($l, $h) = (0, $length - 1); |
| 511 |
} |
| 512 |
|
| 513 |
$self->{path} =~ /\.([^.]+)$/; |
| 514 |
$hdr->{"Content-Type"} = $mimetype{lc $1} || "application/octet-stream"; |
| 515 |
$hdr->{"Content-Length"} = $length; |
| 516 |
|
| 517 |
$self->response(@code, $hdr, ""); |
| 518 |
|
| 519 |
if ($self->{method} eq "GET") { |
| 520 |
$self->{time} = $::NOW; |
| 521 |
|
| 522 |
my $fudge = $queue->[0]->waiters; |
| 523 |
$fudge = $fudge ? ($fudge+1)/$fudge : 1; |
| 524 |
|
| 525 |
$queue->[1] *= $fudge; |
| 526 |
my $transfer = $queue->[0]->guard; |
| 527 |
|
| 528 |
if ($fudge != 1) { |
| 529 |
$queue->[1] /= $fudge; |
| 530 |
$queue->[1] = $queue->[1] * $::wait_factor |
| 531 |
+ ($::NOW - $self->{time}) * (1 - $::wait_factor); |
| 532 |
} |
| 533 |
$self->{time} = $::NOW; |
| 534 |
|
| 535 |
$self->{fh}->writable or return; |
| 536 |
|
| 537 |
my ($fh, $buf, $r); |
| 538 |
my $current = $Coro::current; |
| 539 |
open $fh, "<", $self->{path} |
| 540 |
or die "$self->{path}: late open failure ($!)"; |
| 541 |
|
| 542 |
$h -= $l - 1; |
| 543 |
|
| 544 |
if (0) { |
| 545 |
if ($l) { |
| 546 |
sysseek $fh, $l, 0; |
| 547 |
} |
| 548 |
} |
| 549 |
|
| 550 |
while ($h > 0) { |
| 551 |
if (0) { |
| 552 |
sysread $fh, $buf, $h > $::BUFSIZE ? $::BUFSIZE : $h |
| 553 |
or last; |
| 554 |
} else { |
| 555 |
aio_read($fh, $l, ($h > $::BUFSIZE ? $::BUFSIZE : $h), |
| 556 |
$buf, 0, sub { |
| 557 |
$r = $_[0]; |
| 558 |
Coro::ready($current); |
| 559 |
}); |
| 560 |
&Coro::schedule; |
| 561 |
last unless $r; |
| 562 |
} |
| 563 |
my $w = syswrite $self->{fh}, $buf |
| 564 |
or last; |
| 565 |
$::written += $w; |
| 566 |
$self->{written} += $w; |
| 567 |
$l += $r; |
| 568 |
} |
| 569 |
|
| 570 |
close $fh; |
| 571 |
} |
| 572 |
} |
| 573 |
|
| 574 |
1; |
