| 1 |
use Coro; |
| 2 |
use Coro::Semaphore; |
| 3 |
use Coro::Event; |
| 4 |
use Coro::Socket; |
| 5 |
use Coro::Signal; |
| 6 |
|
| 7 |
use HTTP::Date; |
| 8 |
use POSIX (); |
| 9 |
|
| 10 |
no utf8; |
| 11 |
use bytes; |
| 12 |
|
| 13 |
# at least on my machine, this thingy serves files |
| 14 |
# quite a bit faster than apache, ;) |
| 15 |
# and quite a bit slower than thttpd :( |
| 16 |
|
| 17 |
$SIG{PIPE} = 'IGNORE'; |
| 18 |
|
| 19 |
our $accesslog; |
| 20 |
our $errorlog; |
| 21 |
|
| 22 |
our $NOW; |
| 23 |
our $HTTP_NOW; |
| 24 |
|
| 25 |
Event->timer(interval => 1, hard => 1, cb => sub { |
| 26 |
$NOW = time; |
| 27 |
$HTTP_NOW = time2str $NOW; |
| 28 |
})->now; |
| 29 |
|
| 30 |
if ($ERROR_LOG) { |
| 31 |
use IO::Handle; |
| 32 |
open $errorlog, ">>$ERROR_LOG" |
| 33 |
or die "$ERROR_LOG: $!"; |
| 34 |
$errorlog->autoflush(1); |
| 35 |
} |
| 36 |
|
| 37 |
if ($ACCESS_LOG) { |
| 38 |
use IO::Handle; |
| 39 |
open $accesslog, ">>$ACCESS_LOG" |
| 40 |
or die "$ACCESS_LOG: $!"; |
| 41 |
$accesslog->autoflush(1); |
| 42 |
} |
| 43 |
|
| 44 |
sub slog { |
| 45 |
my $level = shift; |
| 46 |
my $format = shift; |
| 47 |
my $NOW = (POSIX::strftime "%Y-%m-%d %H:%M:%S", gmtime $::NOW); |
| 48 |
printf "$NOW: $format\n", @_; |
| 49 |
printf $errorlog "$NOW: $format\n", @_ if $errorlog; |
| 50 |
} |
| 51 |
|
| 52 |
our $connections = new Coro::Semaphore $MAX_CONNECTS || 250; |
| 53 |
our $httpevent = new Coro::Signal; |
| 54 |
|
| 55 |
our $queue_file = new transferqueue slots => $MAX_TRANSFERS, maxsize => 256*1024*1024; |
| 56 |
our $queue_index = new transferqueue slots => 10; |
| 57 |
|
| 58 |
my @newcons; |
| 59 |
my @pool; |
| 60 |
|
| 61 |
# one "execution thread" |
| 62 |
sub handler { |
| 63 |
while () { |
| 64 |
if (@newcons) { |
| 65 |
eval { |
| 66 |
conn->new(@{pop @newcons})->handle; |
| 67 |
}; |
| 68 |
slog 1, "$@" if $@ && !ref $@; |
| 69 |
|
| 70 |
$httpevent->broadcast; # only for testing, but doesn't matter much |
| 71 |
|
| 72 |
$connections->up; |
| 73 |
} else { |
| 74 |
last if @pool >= $MAX_POOL; |
| 75 |
push @pool, $Coro::current; |
| 76 |
schedule; |
| 77 |
} |
| 78 |
} |
| 79 |
} |
| 80 |
|
| 81 |
sub listen_on { |
| 82 |
my $listen = $_[0]; |
| 83 |
|
| 84 |
push @listen_sockets, $listen; |
| 85 |
|
| 86 |
# the "main thread" |
| 87 |
async { |
| 88 |
slog 1, "accepting connections"; |
| 89 |
while () { |
| 90 |
$connections->down; |
| 91 |
push @newcons, [$listen->accept]; |
| 92 |
#slog 3, "accepted @$connections ".scalar(@pool); |
| 93 |
if (@pool) { |
| 94 |
(pop @pool)->ready; |
| 95 |
} else { |
| 96 |
async \&handler; |
| 97 |
} |
| 98 |
|
| 99 |
} |
| 100 |
}; |
| 101 |
} |
| 102 |
|
| 103 |
my $http_port = new Coro::Socket |
| 104 |
LocalAddr => $SERVER_HOST, |
| 105 |
LocalPort => $SERVER_PORT, |
| 106 |
ReuseAddr => 1, |
| 107 |
Listen => 50, |
| 108 |
or die "unable to start server"; |
| 109 |
|
| 110 |
listen_on $http_port; |
| 111 |
|
| 112 |
if ($SERVER_PORT2) { |
| 113 |
my $http_port = new Coro::Socket |
| 114 |
LocalAddr => $SERVER_HOST, |
| 115 |
LocalPort => $SERVER_PORT2, |
| 116 |
ReuseAddr => 1, |
| 117 |
Listen => 50, |
| 118 |
or die "unable to start server"; |
| 119 |
|
| 120 |
listen_on $http_port; |
| 121 |
} |
| 122 |
|
| 123 |
package conn; |
| 124 |
|
| 125 |
use Socket; |
| 126 |
use HTTP::Date; |
| 127 |
use Convert::Scalar 'weaken'; |
| 128 |
use Linux::AIO; |
| 129 |
|
| 130 |
Linux::AIO::min_parallel $::AIO_PARALLEL; |
| 131 |
|
| 132 |
Event->io(fd => Linux::AIO::poll_fileno, |
| 133 |
poll => 'r', async => 1, |
| 134 |
cb => \&Linux::AIO::poll_cb); |
| 135 |
|
| 136 |
our %conn; # $conn{ip}{self} => connobj |
| 137 |
our %uri; # $uri{ip}{uri}{self} |
| 138 |
our %blocked; |
| 139 |
our %mimetype; |
| 140 |
|
| 141 |
sub read_mimetypes { |
| 142 |
local *M; |
| 143 |
if (open M, "<mime_types") { |
| 144 |
while (<M>) { |
| 145 |
if (/^([^#]\S+)\t+(\S+)$/) { |
| 146 |
$mimetype{lc $1} = $2; |
| 147 |
} |
| 148 |
} |
| 149 |
} else { |
| 150 |
print "cannot open mime_types\n"; |
| 151 |
} |
| 152 |
} |
| 153 |
|
| 154 |
read_mimetypes; |
| 155 |
|
| 156 |
sub new { |
| 157 |
my $class = shift; |
| 158 |
my $fh = shift; |
| 159 |
my $peername = shift; |
| 160 |
my $self = bless { fh => $fh }, $class; |
| 161 |
my (undef, $iaddr) = unpack_sockaddr_in $peername |
| 162 |
or $self->err(500, "unable to decode peername"); |
| 163 |
|
| 164 |
$self->{remote_addr} = |
| 165 |
$self->{remote_id} = inet_ntoa $iaddr; |
| 166 |
|
| 167 |
$self->{time} = $::NOW; |
| 168 |
|
| 169 |
weaken ($Coro::current->{conn} = $self); |
| 170 |
|
| 171 |
$::conns++; |
| 172 |
$::maxconns = $::conns if $::conns > $::maxconns; |
| 173 |
|
| 174 |
$self; |
| 175 |
} |
| 176 |
|
| 177 |
sub DESTROY { |
| 178 |
#my $self = shift; |
| 179 |
$::conns--; |
| 180 |
} |
| 181 |
|
| 182 |
sub slog { |
| 183 |
my $self = shift; |
| 184 |
main::slog($_[0], "$self->{remote_id}> $_[1]"); |
| 185 |
} |
| 186 |
|
| 187 |
sub response { |
| 188 |
my ($self, $code, $msg, $hdr, $content) = @_; |
| 189 |
my $res = "HTTP/1.1 $code $msg\015\012"; |
| 190 |
|
| 191 |
if (exists $hdr->{Connection}) { |
| 192 |
if ($hdr->{Connection} =~ /close/) { |
| 193 |
$self->{h}{connection} = "close" |
| 194 |
} |
| 195 |
} else { |
| 196 |
if ($self->{version} < 1.1) { |
| 197 |
if ($self->{h}{connection} =~ /keep-alive/i) { |
| 198 |
$hdr->{Connection} = "Keep-Alive"; |
| 199 |
} else { |
| 200 |
$self->{h}{connection} = "close" |
| 201 |
} |
| 202 |
} |
| 203 |
} |
| 204 |
|
| 205 |
$res .= "Date: $HTTP_NOW\015\012"; |
| 206 |
|
| 207 |
while (my ($h, $v) = each %$hdr) { |
| 208 |
$res .= "$h: $v\015\012" |
| 209 |
} |
| 210 |
$res .= "\015\012"; |
| 211 |
|
| 212 |
$res .= $content if defined $content and $self->{method} ne "HEAD"; |
| 213 |
|
| 214 |
my $log = (POSIX::strftime "%Y-%m-%d %H:%M:%S", gmtime $NOW). |
| 215 |
" $self->{remote_id} \"$self->{uri}\" $code ".$hdr->{"Content-Length"}. |
| 216 |
" \"$self->{h}{referer}\"\n"; |
| 217 |
|
| 218 |
print $accesslog $log if $accesslog; |
| 219 |
print STDERR $log; |
| 220 |
|
| 221 |
$self->{written} += |
| 222 |
print {$self->{fh}} $res; |
| 223 |
} |
| 224 |
|
| 225 |
sub err { |
| 226 |
my $self = shift; |
| 227 |
my ($code, $msg, $hdr, $content) = @_; |
| 228 |
|
| 229 |
unless (defined $content) { |
| 230 |
$content = "$code $msg\n"; |
| 231 |
$hdr->{"Content-Type"} = "text/plain"; |
| 232 |
$hdr->{"Content-Length"} = length $content; |
| 233 |
} |
| 234 |
$hdr->{"Connection"} = "close"; |
| 235 |
|
| 236 |
$self->response($code, $msg, $hdr, $content); |
| 237 |
|
| 238 |
die bless {}, err::; |
| 239 |
} |
| 240 |
|
| 241 |
sub handle { |
| 242 |
my $self = shift; |
| 243 |
my $fh = $self->{fh}; |
| 244 |
|
| 245 |
my $host; |
| 246 |
|
| 247 |
$fh->timeout($::REQ_TIMEOUT); |
| 248 |
while() { |
| 249 |
$self->{reqs}++; |
| 250 |
|
| 251 |
# read request and parse first line |
| 252 |
my $req = $fh->readline("\015\012\015\012"); |
| 253 |
|
| 254 |
unless (defined $req) { |
| 255 |
if (exists $self->{version}) { |
| 256 |
last; |
| 257 |
} else { |
| 258 |
$self->err(408, "request timeout"); |
| 259 |
} |
| 260 |
} |
| 261 |
|
| 262 |
$self->{h} = {}; |
| 263 |
|
| 264 |
$fh->timeout($::RES_TIMEOUT); |
| 265 |
|
| 266 |
$req =~ /^(?:\015\012)? |
| 267 |
(GET|HEAD) \040+ |
| 268 |
([^\040]+) \040+ |
| 269 |
HTTP\/([0-9]+\.[0-9]+) |
| 270 |
\015\012/gx |
| 271 |
or $self->err(405, "method not allowed", { Allow => "GET,HEAD" }); |
| 272 |
|
| 273 |
$self->{method} = $1; |
| 274 |
$self->{uri} = $2; |
| 275 |
$self->{version} = $3; |
| 276 |
|
| 277 |
$3 =~ /^1\./ |
| 278 |
or $self->err(506, "http protocol version $3 not supported"); |
| 279 |
|
| 280 |
# parse headers |
| 281 |
{ |
| 282 |
my (%hdr, $h, $v); |
| 283 |
|
| 284 |
$hdr{lc $1} .= ",$2" |
| 285 |
while $req =~ /\G |
| 286 |
([^:\000-\040]+): |
| 287 |
[\008\040]* |
| 288 |
((?: [^\015\012]+ | \015\012[\008\040] )*) |
| 289 |
\015\012 |
| 290 |
/gxc; |
| 291 |
|
| 292 |
$req =~ /\G\015\012$/ |
| 293 |
or $self->err(400, "bad request"); |
| 294 |
|
| 295 |
$self->{h}{$h} = substr $v, 1 |
| 296 |
while ($h, $v) = each %hdr; |
| 297 |
} |
| 298 |
|
| 299 |
# remote id should be unique per user |
| 300 |
my $id = $self->{remote_addr}; |
| 301 |
|
| 302 |
if (exists $self->{h}{"client-ip"}) { |
| 303 |
$id .= "[".$self->{h}{"client-ip"}."]"; |
| 304 |
} elsif (exists $self->{h}{"x-forwarded-for"}) { |
| 305 |
$id .= "[".$self->{h}{"x-forwarded-for"}."]"; |
| 306 |
} |
| 307 |
|
| 308 |
$self->{remote_id} = $id; |
| 309 |
|
| 310 |
weaken (local $conn{$id}{$self*1} = $self); |
| 311 |
|
| 312 |
if ($blocked{$id}) { |
| 313 |
$self->err_blocked |
| 314 |
if $blocked{$id}[0] > $::NOW; |
| 315 |
|
| 316 |
delete $blocked{$id}; |
| 317 |
} |
| 318 |
|
| 319 |
# find out server name and port |
| 320 |
if ($self->{uri} =~ s/^http:\/\/([^\/?#]*)//i) { |
| 321 |
$host = $1; |
| 322 |
} else { |
| 323 |
$host = $self->{h}{host}; |
| 324 |
} |
| 325 |
|
| 326 |
if (defined $host) { |
| 327 |
$self->{server_port} = $host =~ s/:([0-9]+)$// ? $1 : 80; |
| 328 |
} else { |
| 329 |
($self->{server_port}, $host) |
| 330 |
= unpack_sockaddr_in $self->{fh}->sockname |
| 331 |
or $self->err(500, "unable to get socket name"); |
| 332 |
$host = inet_ntoa $host; |
| 333 |
} |
| 334 |
|
| 335 |
$self->{server_name} = $host; |
| 336 |
|
| 337 |
weaken (local $uri{$id}{$self->{uri}}{$self*1} = $self); |
| 338 |
|
| 339 |
eval { |
| 340 |
$self->map_uri; |
| 341 |
$self->respond; |
| 342 |
}; |
| 343 |
|
| 344 |
die if $@ && !ref $@; |
| 345 |
|
| 346 |
last if $self->{h}{connection} =~ /close/i; |
| 347 |
|
| 348 |
$httpevent->broadcast; |
| 349 |
|
| 350 |
$fh->timeout($::PER_TIMEOUT); |
| 351 |
} |
| 352 |
} |
| 353 |
|
| 354 |
sub block { |
| 355 |
my $self = shift; |
| 356 |
|
| 357 |
$blocked{$self->{remote_id}} = [$::NOW + $_[0], $_[1]]; |
| 358 |
$self->slog(2, "blocked ip $self->{remote_id}"); |
| 359 |
$self->err_blocked; |
| 360 |
} |
| 361 |
|
| 362 |
# uri => path mapping |
| 363 |
sub map_uri { |
| 364 |
my $self = shift; |
| 365 |
my $host = $self->{server_name}; |
| 366 |
my $uri = $self->{uri}; |
| 367 |
|
| 368 |
# some massaging, also makes it more secure |
| 369 |
$uri =~ s/%([0-9a-fA-F][0-9a-fA-F])/chr hex $1/ge; |
| 370 |
$uri =~ s%//+%/%g; |
| 371 |
$uri =~ s%/\.(?=/|$)%%g; |
| 372 |
1 while $uri =~ s%/[^/]+/\.\.(?=/|$)%%; |
| 373 |
|
| 374 |
$uri =~ m%^/?\.\.(?=/|$)% |
| 375 |
and $self->err(400, "bad request"); |
| 376 |
|
| 377 |
$self->{name} = $uri; |
| 378 |
|
| 379 |
# now do the path mapping |
| 380 |
$self->{path} = "$::DOCROOT/$host$uri"; |
| 381 |
|
| 382 |
$self->access_check; |
| 383 |
} |
| 384 |
|
| 385 |
sub _cgi { |
| 386 |
my $self = shift; |
| 387 |
my $path = shift; |
| 388 |
my $fh; |
| 389 |
|
| 390 |
# no two-way xxx supported |
| 391 |
if (0 == fork) { |
| 392 |
open STDOUT, ">&".fileno($self->{fh}); |
| 393 |
if (chdir $::DOCROOT) { |
| 394 |
$ENV{SERVER_SOFTWARE} = "thttpd-myhttpd"; # we are thttpd-alike |
| 395 |
$ENV{HTTP_HOST} = $self->{server_name}; |
| 396 |
$ENV{HTTP_PORT} = $self->{server_port}; |
| 397 |
$ENV{SCRIPT_NAME} = $self->{name}; |
| 398 |
exec $path; |
| 399 |
} |
| 400 |
Coro::State::_exit(0); |
| 401 |
} else { |
| 402 |
die; |
| 403 |
} |
| 404 |
} |
| 405 |
|
| 406 |
sub server_hostport { |
| 407 |
$_[0]{server_port} == 80 |
| 408 |
? $_[0]{server_name} |
| 409 |
: "$_[0]{server_name}:$_[0]{server_port}"; |
| 410 |
} |
| 411 |
|
| 412 |
sub respond { |
| 413 |
my $self = shift; |
| 414 |
my $path = $self->{path}; |
| 415 |
|
| 416 |
if ($self->{name} =~ s%^/internal/([^/]+)%%) { |
| 417 |
if ($::internal{$1}) { |
| 418 |
$::internal{$1}->($self); |
| 419 |
} else { |
| 420 |
$self->err(404, "not found"); |
| 421 |
} |
| 422 |
} else { |
| 423 |
|
| 424 |
stat $path |
| 425 |
or $self->err(404, "not found"); |
| 426 |
|
| 427 |
$self->{stat} = [stat _]; |
| 428 |
|
| 429 |
# idiotic netscape sends idiotic headers AGAIN |
| 430 |
my $ims = $self->{h}{"if-modified-since"} =~ /^([^;]+)/ |
| 431 |
? str2time $1 : 0; |
| 432 |
|
| 433 |
if (-d _ && -r _) { |
| 434 |
# directory |
| 435 |
if ($path !~ /\/$/) { |
| 436 |
# create a redirect to get the trailing "/" |
| 437 |
# we don't try to avoid the :80 |
| 438 |
$self->err(301, "moved permanently", { Location => "http://".$self->server_hostport."$self->{uri}/" }); |
| 439 |
} else { |
| 440 |
$ims < $self->{stat}[9] |
| 441 |
or $self->err(304, "not modified"); |
| 442 |
|
| 443 |
if (-r "$path/index.html") { |
| 444 |
# replace directory "size" by index.html filesize |
| 445 |
$self->{stat} = [stat ($self->{path} .= "/index.html")]; |
| 446 |
$self->handle_file($queue_index); |
| 447 |
} else { |
| 448 |
$self->handle_dir; |
| 449 |
} |
| 450 |
} |
| 451 |
} elsif (-f _ && -r _) { |
| 452 |
-x _ and $self->err(403, "forbidden"); |
| 453 |
|
| 454 |
if (keys %{$conn{$self->{remote_id}}} > $::MAX_TRANSFERS_IP) { |
| 455 |
my $timeout = $::NOW + 10; |
| 456 |
while (keys %{$conn{$self->{remote_id}}} > $::MAX_TRANSFERS_IP) { |
| 457 |
if ($timeout < $::NOW) { |
| 458 |
$self->block($::BLOCKTIME, "too many connections"); |
| 459 |
} else { |
| 460 |
$httpevent->wait; |
| 461 |
} |
| 462 |
} |
| 463 |
} |
| 464 |
|
| 465 |
$self->handle_file($queue_file); |
| 466 |
} else { |
| 467 |
$self->err(404, "not found"); |
| 468 |
} |
| 469 |
} |
| 470 |
} |
| 471 |
|
| 472 |
sub handle_dir { |
| 473 |
my $self = shift; |
| 474 |
my $idx = $self->diridx; |
| 475 |
|
| 476 |
$self->response(200, "ok", |
| 477 |
{ |
| 478 |
"Content-Type" => "text/html", |
| 479 |
"Content-Length" => length $idx, |
| 480 |
"Last-Modified" => time2str ($self->{stat}[9]), |
| 481 |
}, |
| 482 |
$idx); |
| 483 |
} |
| 484 |
|
| 485 |
sub handle_file { |
| 486 |
my ($self, $queue) = @_; |
| 487 |
my $length = $self->{stat}[7]; |
| 488 |
my $hdr = { |
| 489 |
"Last-Modified" => time2str ((stat _)[9]), |
| 490 |
}; |
| 491 |
|
| 492 |
my @code = (200, "ok"); |
| 493 |
my ($l, $h); |
| 494 |
|
| 495 |
if ($self->{h}{range} =~ /^bytes=(.*)$/) { |
| 496 |
for (split /,/, $1) { |
| 497 |
if (/^-(\d+)$/) { |
| 498 |
($l, $h) = ($length - $1, $length - 1); |
| 499 |
} elsif (/^(\d+)-(\d*)$/) { |
| 500 |
($l, $h) = ($1, ($2 ne "" || $2 >= $length) ? $2 : $length - 1); |
| 501 |
} else { |
| 502 |
($l, $h) = (0, $length - 1); |
| 503 |
goto ignore; |
| 504 |
} |
| 505 |
goto satisfiable if $l >= 0 && $l < $length && $h >= 0 && $h >= $l; |
| 506 |
} |
| 507 |
$hdr->{"Content-Range"} = "bytes */$length"; |
| 508 |
$hdr->{"Content-Length"} = $length; |
| 509 |
$self->err(416, "not satisfiable", $hdr, ""); |
| 510 |
|
| 511 |
satisfiable: |
| 512 |
# check for segmented downloads |
| 513 |
if ($l && $::NO_SEGMENTED) { |
| 514 |
my $timeout = $::NOW + 15; |
| 515 |
while (keys %{$uri{$self->{remote_id}}{$self->{uri}}} > 1) { |
| 516 |
if ($timeout <= $::NOW) { |
| 517 |
$self->block($::BLOCKTIME, "segmented downloads are forbidden"); |
| 518 |
#$self->err_segmented_download; |
| 519 |
} else { |
| 520 |
$httpevent->wait; |
| 521 |
} |
| 522 |
} |
| 523 |
} |
| 524 |
|
| 525 |
$hdr->{"Content-Range"} = "bytes $l-$h/$length"; |
| 526 |
@code = (206, "partial content"); |
| 527 |
$length = $h - $l + 1; |
| 528 |
|
| 529 |
ignore: |
| 530 |
} else { |
| 531 |
($l, $h) = (0, $length - 1); |
| 532 |
} |
| 533 |
|
| 534 |
$self->{path} =~ /\.([^.]+)$/; |
| 535 |
$hdr->{"Content-Type"} = $mimetype{lc $1} || "application/octet-stream"; |
| 536 |
$hdr->{"Content-Length"} = $length; |
| 537 |
|
| 538 |
$self->response(@code, $hdr, ""); |
| 539 |
|
| 540 |
if ($self->{method} eq "GET") { |
| 541 |
$self->{time} = $::NOW; |
| 542 |
|
| 543 |
my $current = $Coro::current; |
| 544 |
|
| 545 |
my ($fh, $buf, $r); |
| 546 |
|
| 547 |
open $fh, "<", $self->{path} |
| 548 |
or die "$self->{path}: late open failure ($!)"; |
| 549 |
|
| 550 |
$h -= $l - 1; |
| 551 |
|
| 552 |
if (0) { # !AIO |
| 553 |
if ($l) { |
| 554 |
sysseek $fh, $l, 0; |
| 555 |
} |
| 556 |
} |
| 557 |
|
| 558 |
my $transfer = $queue->start_transfer($h); |
| 559 |
my $locked; |
| 560 |
my $bufsize = $::WAIT_BUFSIZE; # initial buffer size |
| 561 |
|
| 562 |
while ($h > 0) { |
| 563 |
unless ($locked) { |
| 564 |
if ($locked ||= $transfer->try($::WAIT_INTERVAL)) { |
| 565 |
$bufsize = $::BUFSIZE; |
| 566 |
$self->{time} = $::NOW; |
| 567 |
} |
| 568 |
} |
| 569 |
|
| 570 |
if ($blocked{$self->{remote_id}}) { |
| 571 |
$self->{h}{connection} = "close"; |
| 572 |
die bless {}, err::; |
| 573 |
} |
| 574 |
|
| 575 |
if (0) { # !AIO |
| 576 |
sysread $fh, $buf, $h > $bufsize ? $bufsize : $h |
| 577 |
or last; |
| 578 |
} else { |
| 579 |
aio_read($fh, $l, ($h > $bufsize ? $bufsize : $h), |
| 580 |
$buf, 0, sub { |
| 581 |
$r = $_[0]; |
| 582 |
Coro::ready($current); |
| 583 |
}); |
| 584 |
&Coro::schedule; |
| 585 |
last unless $r; |
| 586 |
} |
| 587 |
my $w = syswrite $self->{fh}, $buf |
| 588 |
or last; |
| 589 |
$::written += $w; |
| 590 |
$self->{written} += $w; |
| 591 |
$l += $r; |
| 592 |
} |
| 593 |
|
| 594 |
close $fh; |
| 595 |
} |
| 596 |
} |
| 597 |
|
| 598 |
1; |
